src/Pure/drule.ML
author wenzelm
Tue May 07 14:26:32 2002 +0200 (2002-05-07)
changeset 13105 3d1e7a199bdc
parent 12908 53bfe07a7916
child 13198 3e40f48a500f
permissions -rw-r--r--
use eq_thm_prop instead of slightly inadequate eq_thm;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val skip_flexpairs    : cterm -> cterm
    18   val strip_imp_prems   : cterm -> cterm list
    19   val strip_imp_concl   : cterm -> cterm
    20   val cprems_of         : thm -> cterm list
    21   val read_insts        :
    22           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> string list -> (string*string)list
    25                   -> (indexname*ctyp)list * (cterm*cterm)list
    26   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    27   val strip_shyps_warning : thm -> thm
    28   val forall_intr_list  : cterm list -> thm -> thm
    29   val forall_intr_frees : thm -> thm
    30   val forall_intr_vars  : thm -> thm
    31   val forall_elim_list  : cterm list -> thm -> thm
    32   val forall_elim_var   : int -> thm -> thm
    33   val forall_elim_vars  : int -> thm -> thm
    34   val gen_all           : thm -> thm
    35   val freeze_thaw       : thm -> thm * (thm -> thm)
    36   val implies_elim_list : thm -> thm list -> thm
    37   val implies_intr_list : cterm list -> thm -> thm
    38   val instantiate       :
    39     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes  : thm -> thm
    41   val standard          : thm -> thm
    42   val standard'         : thm -> thm
    43   val rotate_prems      : int -> thm -> thm
    44   val rearrange_prems   : int list -> thm -> thm
    45   val assume_ax         : theory -> string -> thm
    46   val RSN               : thm * (int * thm) -> thm
    47   val RS                : thm * thm -> thm
    48   val RLN               : thm list * (int * thm list) -> thm list
    49   val RL                : thm list * thm list -> thm list
    50   val MRS               : thm list * thm -> thm
    51   val MRL               : thm list list * thm list -> thm list
    52   val OF                : thm * thm list -> thm
    53   val compose           : thm * int * thm -> thm list
    54   val COMP              : thm * thm -> thm
    55   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    56   val read_instantiate  : (string*string)list -> thm -> thm
    57   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    58   val eq_thm_sg         : thm * thm -> bool
    59   val eq_thm_prop	: thm * thm -> bool
    60   val weak_eq_thm       : thm * thm -> bool
    61   val size_of_thm       : thm -> int
    62   val reflexive_thm     : thm
    63   val symmetric_thm     : thm
    64   val transitive_thm    : thm
    65   val refl_implies      : thm
    66   val symmetric_fun     : thm -> thm
    67   val extensional       : thm -> thm
    68   val imp_cong          : thm
    69   val swap_prems_eq     : thm
    70   val equal_abs_elim    : cterm  -> thm -> thm
    71   val equal_abs_elim_list: cterm list -> thm -> thm
    72   val flexpair_abs_elim_list: cterm list -> thm -> thm
    73   val asm_rl            : thm
    74   val cut_rl            : thm
    75   val revcut_rl         : thm
    76   val thin_rl           : thm
    77   val triv_forall_equality: thm
    78   val swap_prems_rl     : thm
    79   val equal_intr_rule   : thm
    80   val inst              : string -> string -> thm -> thm
    81   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    82   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    83 end;
    84 
    85 signature DRULE =
    86 sig
    87   include BASIC_DRULE
    88   val strip_comb: cterm -> cterm * cterm list
    89   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    90   val tag_rule: tag -> thm -> thm
    91   val untag_rule: string -> thm -> thm
    92   val tag: tag -> 'a attribute
    93   val untag: string -> 'a attribute
    94   val get_kind: thm -> string
    95   val kind: string -> 'a attribute
    96   val theoremK: string
    97   val lemmaK: string
    98   val corollaryK: string
    99   val internalK: string
   100   val kind_internal: 'a attribute
   101   val has_internal: tag list -> bool
   102   val impose_hyps: cterm list -> thm -> thm
   103   val close_derivation: thm -> thm
   104   val local_standard: thm -> thm
   105   val compose_single: thm * int * thm -> thm
   106   val add_rule: thm -> thm list -> thm list
   107   val del_rule: thm -> thm list -> thm list
   108   val add_rules: thm list -> thm list -> thm list
   109   val del_rules: thm list -> thm list -> thm list
   110   val merge_rules: thm list * thm list -> thm list
   111   val norm_hhf_eq: thm
   112   val is_norm_hhf: term -> bool
   113   val norm_hhf: Sign.sg -> term -> term
   114   val triv_goal: thm
   115   val rev_triv_goal: thm
   116   val implies_intr_goals: cterm list -> thm -> thm
   117   val freeze_all: thm -> thm
   118   val mk_triv_goal: cterm -> thm
   119   val tvars_of_terms: term list -> (indexname * sort) list
   120   val vars_of_terms: term list -> (indexname * typ) list
   121   val tvars_of: thm -> (indexname * sort) list
   122   val vars_of: thm -> (indexname * typ) list
   123   val unvarifyT: thm -> thm
   124   val unvarify: thm -> thm
   125   val tvars_intr_list: string list -> thm -> thm * (string * indexname) list
   126   val remdups_rl: thm
   127   val conj_intr: thm -> thm -> thm
   128   val conj_intr_list: thm list -> thm
   129   val conj_elim: thm -> thm * thm
   130   val conj_elim_list: thm -> thm list
   131   val conj_elim_precise: int -> thm -> thm list
   132   val conj_intr_thm: thm
   133 end;
   134 
   135 structure Drule: DRULE =
   136 struct
   137 
   138 
   139 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   140 
   141 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   142 
   143 (*dest_implies for cterms. Note T=prop below*)
   144 fun dest_implies ct =
   145     case term_of ct of
   146         (Const("==>", _) $ _ $ _) =>
   147             let val (ct1,ct2) = Thm.dest_comb ct
   148             in  (#2 (Thm.dest_comb ct1), ct2)  end
   149       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   150 
   151 fun dest_equals ct =
   152     case term_of ct of
   153         (Const("==", _) $ _ $ _) =>
   154             let val (ct1,ct2) = Thm.dest_comb ct
   155             in  (#2 (Thm.dest_comb ct1), ct2)  end
   156       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   157 
   158 
   159 (*Discard flexflex pairs; return a cterm*)
   160 fun skip_flexpairs ct =
   161     case term_of ct of
   162         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   163             skip_flexpairs (#2 (dest_implies ct))
   164       | _ => ct;
   165 
   166 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   167 fun strip_imp_prems ct =
   168     let val (cA,cB) = dest_implies ct
   169     in  cA :: strip_imp_prems cB  end
   170     handle TERM _ => [];
   171 
   172 (* A1==>...An==>B  goes to B, where B is not an implication *)
   173 fun strip_imp_concl ct =
   174     case term_of ct of (Const("==>", _) $ _ $ _) =>
   175         strip_imp_concl (#2 (Thm.dest_comb ct))
   176   | _ => ct;
   177 
   178 (*The premises of a theorem, as a cterm list*)
   179 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   180 
   181 val proto_sign = Theory.sign_of ProtoPure.thy;
   182 
   183 val implies = cterm_of proto_sign Term.implies;
   184 
   185 (*cterm version of mk_implies*)
   186 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   187 
   188 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   189 fun list_implies([], B) = B
   190   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   191 
   192 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   193 fun strip_comb ct = 
   194   let
   195     fun stripc (p as (ct, cts)) =
   196       let val (ct1, ct2) = Thm.dest_comb ct
   197       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   198   in stripc (ct, []) end;
   199 
   200 
   201 (** reading of instantiations **)
   202 
   203 fun absent ixn =
   204   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   205 
   206 fun inst_failure ixn =
   207   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   208 
   209 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   210 let
   211     fun split([],tvs,vs) = (tvs,vs)
   212       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   213                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   214                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   215     val (tvs,vs) = split(insts,[],[]);
   216     fun readT((a,i),st) =
   217         let val ixn = ("'" ^ a,i);
   218             val S = case rsorts ixn of Some S => S | None => absent ixn;
   219             val T = Sign.read_typ (sign,sorts) st;
   220         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   221            else inst_failure ixn
   222         end
   223     val tye = map readT tvs;
   224     fun mkty(ixn,st) = (case rtypes ixn of
   225                           Some T => (ixn,(st,typ_subst_TVars tye T))
   226                         | None => absent ixn);
   227     val ixnsTs = map mkty vs;
   228     val ixns = map fst ixnsTs
   229     and sTs  = map snd ixnsTs
   230     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   231     fun mkcVar(ixn,T) =
   232         let val U = typ_subst_TVars tye2 T
   233         in cterm_of sign (Var(ixn,U)) end
   234     val ixnTs = ListPair.zip(ixns, map snd sTs)
   235 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   236     ListPair.zip(map mkcVar ixnTs,cts))
   237 end;
   238 
   239 
   240 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   241      Used for establishing default types (of variables) and sorts (of
   242      type variables) when reading another term.
   243      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   244 ***)
   245 
   246 fun types_sorts thm =
   247     let val {prop,hyps,...} = rep_thm thm;
   248         val big = list_comb(prop,hyps); (* bogus term! *)
   249         val vars = map dest_Var (term_vars big);
   250         val frees = map dest_Free (term_frees big);
   251         val tvars = term_tvars big;
   252         val tfrees = term_tfrees big;
   253         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   254         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   255     in (typ,sort) end;
   256 
   257 
   258 
   259 (** basic attributes **)
   260 
   261 (* dependent rules *)
   262 
   263 fun rule_attribute f (x, thm) = (x, (f x thm));
   264 
   265 
   266 (* add / delete tags *)
   267 
   268 fun map_tags f thm =
   269   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   270 
   271 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   272 fun untag_rule s = map_tags (filter_out (equal s o #1));
   273 
   274 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   275 fun untag s x = rule_attribute (K (untag_rule s)) x;
   276 
   277 fun simple_tag name x = tag (name, []) x;
   278 
   279 
   280 (* theorem kinds *)
   281 
   282 val theoremK = "theorem";
   283 val lemmaK = "lemma";
   284 val corollaryK = "corollary";
   285 val internalK = "internal";
   286 
   287 fun get_kind thm =
   288   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   289     Some (k :: _) => k
   290   | _ => "unknown");
   291 
   292 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   293 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   294 fun kind_internal x = kind internalK x;
   295 fun has_internal tags = exists (equal internalK o fst) tags;
   296 
   297 
   298 
   299 (** Standardization of rules **)
   300 
   301 (*Strip extraneous shyps as far as possible*)
   302 fun strip_shyps_warning thm =
   303   let
   304     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   305     val thm' = Thm.strip_shyps thm;
   306     val xshyps = Thm.extra_shyps thm';
   307   in
   308     if null xshyps then ()
   309     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   310     thm'
   311   end;
   312 
   313 (*Generalization over a list of variables, IGNORING bad ones*)
   314 fun forall_intr_list [] th = th
   315   | forall_intr_list (y::ys) th =
   316         let val gth = forall_intr_list ys th
   317         in  forall_intr y gth   handle THM _ =>  gth  end;
   318 
   319 (*Generalization over all suitable Free variables*)
   320 fun forall_intr_frees th =
   321     let val {prop,sign,...} = rep_thm th
   322     in  forall_intr_list
   323          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   324          th
   325     end;
   326 
   327 val forall_elim_var = PureThy.forall_elim_var;
   328 val forall_elim_vars = PureThy.forall_elim_vars;
   329 
   330 fun gen_all thm =
   331   let
   332     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   333     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   334     val vs = Term.strip_all_vars prop;
   335   in foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   336 
   337 (*Specialization over a list of cterms*)
   338 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   339 
   340 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   341 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   342 
   343 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   344 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   345 
   346 (* maps |- B to A1,...,An |- B *)
   347 fun impose_hyps chyps th =
   348   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   349   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   350 
   351 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   352 fun zero_var_indexes th =
   353     let val {prop,sign,...} = rep_thm th;
   354         val vars = term_vars prop
   355         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   356         val inrs = add_term_tvars(prop,[]);
   357         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   358         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   359                      (inrs, nms')
   360         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   361         fun varpairs([],[]) = []
   362           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   363                 let val T' = typ_subst_TVars tye T
   364                 in (cterm_of sign (Var(v,T')),
   365                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   366                 end
   367           | varpairs _ = raise TERM("varpairs", []);
   368     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   369 
   370 
   371 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   372     all generality expressed by Vars having index 0.*)
   373 
   374 fun close_derivation thm =
   375   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   376   else thm;
   377 
   378 fun standard' th =
   379   let val {maxidx,...} = rep_thm th in
   380     th
   381     |> implies_intr_hyps
   382     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   383     |> strip_shyps_warning
   384     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   385   end;
   386 
   387 val standard = close_derivation o standard';
   388 
   389 fun local_standard th =
   390   th |> strip_shyps |> zero_var_indexes
   391   |> Thm.compress |> close_derivation;
   392 
   393 
   394 (*Convert all Vars in a theorem to Frees.  Also return a function for
   395   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   396   Similar code in type/freeze_thaw*)
   397 fun freeze_thaw th =
   398  let val fth = freezeT th
   399      val {prop,sign,...} = rep_thm fth
   400  in
   401    case term_vars prop of
   402        [] => (fth, fn x => x)
   403      | vars =>
   404          let fun newName (Var(ix,_), (pairs,used)) =
   405                    let val v = variant used (string_of_indexname ix)
   406                    in  ((ix,v)::pairs, v::used)  end;
   407              val (alist, _) = foldr newName
   408                                 (vars, ([], add_term_names (prop, [])))
   409              fun mk_inst (Var(v,T)) =
   410                  (cterm_of sign (Var(v,T)),
   411                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   412              val insts = map mk_inst vars
   413              fun thaw th' =
   414                  th' |> forall_intr_list (map #2 insts)
   415                      |> forall_elim_list (map #1 insts)
   416          in  (Thm.instantiate ([],insts) fth, thaw)  end
   417  end;
   418 
   419 
   420 (*Rotates a rule's premises to the left by k*)
   421 val rotate_prems = permute_prems 0;
   422 
   423 (* permute prems, where the i-th position in the argument list (counting from 0)
   424    gives the position within the original thm to be transferred to position i.
   425    Any remaining trailing positions are left unchanged. *)
   426 val rearrange_prems = let
   427   fun rearr new []      thm = thm
   428   |   rearr new (p::ps) thm = rearr (new+1)
   429      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   430      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   431   in rearr 0 end;
   432 
   433 (*Assume a new formula, read following the same conventions as axioms.
   434   Generalizes over Free variables,
   435   creates the assumption, and then strips quantifiers.
   436   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   437              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   438 fun assume_ax thy sP =
   439     let val sign = Theory.sign_of thy
   440         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   441     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   442 
   443 (*Resolution: exactly one resolvent must be produced.*)
   444 fun tha RSN (i,thb) =
   445   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   446       ([th],_) => th
   447     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   448     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   449 
   450 (*resolution: P==>Q, Q==>R gives P==>R. *)
   451 fun tha RS thb = tha RSN (1,thb);
   452 
   453 (*For joining lists of rules*)
   454 fun thas RLN (i,thbs) =
   455   let val resolve = biresolution false (map (pair false) thas) i
   456       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   457   in  List.concat (map resb thbs)  end;
   458 
   459 fun thas RL thbs = thas RLN (1,thbs);
   460 
   461 (*Resolve a list of rules against bottom_rl from right to left;
   462   makes proof trees*)
   463 fun rls MRS bottom_rl =
   464   let fun rs_aux i [] = bottom_rl
   465         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   466   in  rs_aux 1 rls  end;
   467 
   468 (*As above, but for rule lists*)
   469 fun rlss MRL bottom_rls =
   470   let fun rs_aux i [] = bottom_rls
   471         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   472   in  rs_aux 1 rlss  end;
   473 
   474 (*A version of MRS with more appropriate argument order*)
   475 fun bottom_rl OF rls = rls MRS bottom_rl;
   476 
   477 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   478   with no lifting or renaming!  Q may contain ==> or meta-quants
   479   ALWAYS deletes premise i *)
   480 fun compose(tha,i,thb) =
   481     Seq.list_of (bicompose false (false,tha,0) i thb);
   482 
   483 fun compose_single (tha,i,thb) =
   484   (case compose (tha,i,thb) of
   485     [th] => th
   486   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   487 
   488 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   489 fun tha COMP thb =
   490     case compose(tha,1,thb) of
   491         [th] => th
   492       | _ =>   raise THM("COMP", 1, [tha,thb]);
   493 
   494 
   495 (** theorem equality **)
   496 
   497 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   498 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   499 
   500 (*Useful "distance" function for BEST_FIRST*)
   501 val size_of_thm = size_of_term o prop_of;
   502 
   503 (*maintain lists of theorems --- preserving canonical order*)
   504 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   505 fun add_rules rs rules = rs @ del_rules rs rules;
   506 val del_rule = del_rules o single;
   507 val add_rule = add_rules o single;
   508 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   509 
   510 
   511 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   512     (some) type variable renaming **)
   513 
   514  (* Can't use term_vars, because it sorts the resulting list of variable names.
   515     We instead need the unique list noramlised by the order of appearance
   516     in the term. *)
   517 fun term_vars' (t as Var(v,T)) = [t]
   518   | term_vars' (Abs(_,_,b)) = term_vars' b
   519   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   520   | term_vars' _ = [];
   521 
   522 fun forall_intr_vars th =
   523   let val {prop,sign,...} = rep_thm th;
   524       val vars = distinct (term_vars' prop);
   525   in forall_intr_list (map (cterm_of sign) vars) th end;
   526 
   527 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   528 
   529 
   530 (*** Meta-Rewriting Rules ***)
   531 
   532 fun read_prop s = read_cterm proto_sign (s, propT);
   533 
   534 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   535 fun store_standard_thm name thm = store_thm name (standard thm);
   536 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   537 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   538 
   539 val reflexive_thm =
   540   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   541   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   542 
   543 val symmetric_thm =
   544   let val xy = read_prop "x::'a::logic == y"
   545   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   546 
   547 val transitive_thm =
   548   let val xy = read_prop "x::'a::logic == y"
   549       val yz = read_prop "y::'a::logic == z"
   550       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   551   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   552 
   553 fun symmetric_fun thm = thm RS symmetric_thm;
   554 
   555 fun extensional eq =
   556   let val eq' =
   557     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   558   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   559 
   560 val imp_cong =
   561   let
   562     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   563     val AB = read_prop "PROP A ==> PROP B"
   564     val AC = read_prop "PROP A ==> PROP C"
   565     val A = read_prop "PROP A"
   566   in
   567     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   568       (implies_intr AB (implies_intr A
   569         (equal_elim (implies_elim (assume ABC) (assume A))
   570           (implies_elim (assume AB) (assume A)))))
   571       (implies_intr AC (implies_intr A
   572         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   573           (implies_elim (assume AC) (assume A)))))))
   574   end;
   575 
   576 val swap_prems_eq =
   577   let
   578     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   579     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   580     val A = read_prop "PROP A"
   581     val B = read_prop "PROP B"
   582   in
   583     store_standard_thm_open "swap_prems_eq" (equal_intr
   584       (implies_intr ABC (implies_intr B (implies_intr A
   585         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   586       (implies_intr BAC (implies_intr A (implies_intr B
   587         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   588   end;
   589 
   590 val refl_implies = reflexive implies;
   591 
   592 
   593 (*** Some useful meta-theorems ***)
   594 
   595 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   596 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   597 val _ = store_thm "_" asm_rl;
   598 
   599 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   600 val cut_rl =
   601   store_standard_thm_open "cut_rl"
   602     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   603 
   604 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   605      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   606 val revcut_rl =
   607   let val V = read_prop "PROP V"
   608       and VW = read_prop "PROP V ==> PROP W";
   609   in
   610     store_standard_thm_open "revcut_rl"
   611       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   612   end;
   613 
   614 (*for deleting an unwanted assumption*)
   615 val thin_rl =
   616   let val V = read_prop "PROP V"
   617       and W = read_prop "PROP W";
   618   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   619 
   620 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   621 val triv_forall_equality =
   622   let val V  = read_prop "PROP V"
   623       and QV = read_prop "!!x::'a. PROP V"
   624       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   625   in
   626     store_standard_thm_open "triv_forall_equality"
   627       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   628         (implies_intr V  (forall_intr x (assume V))))
   629   end;
   630 
   631 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   632    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   633    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   634 *)
   635 val swap_prems_rl =
   636   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   637       val major = assume cmajor;
   638       val cminor1 = read_prop "PROP PhiA";
   639       val minor1 = assume cminor1;
   640       val cminor2 = read_prop "PROP PhiB";
   641       val minor2 = assume cminor2;
   642   in store_standard_thm_open "swap_prems_rl"
   643        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   644          (implies_elim (implies_elim major minor1) minor2))))
   645   end;
   646 
   647 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   648    ==> PROP ?phi == PROP ?psi
   649    Introduction rule for == as a meta-theorem.
   650 *)
   651 val equal_intr_rule =
   652   let val PQ = read_prop "PROP phi ==> PROP psi"
   653       and QP = read_prop "PROP psi ==> PROP phi"
   654   in
   655     store_standard_thm_open "equal_intr_rule"
   656       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   657   end;
   658 
   659 
   660 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   661 
   662 val remdups_rl =
   663   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   664   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   665 
   666 
   667 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   668   Rewrite rule for HHF normalization.*)
   669 
   670 val norm_hhf_eq =
   671   let
   672     val cert = Thm.cterm_of proto_sign;
   673     val aT = TFree ("'a", Term.logicS);
   674     val all = Term.all aT;
   675     val x = Free ("x", aT);
   676     val phi = Free ("phi", propT);
   677     val psi = Free ("psi", aT --> propT);
   678 
   679     val cx = cert x;
   680     val cphi = cert phi;
   681     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   682     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   683   in
   684     Thm.equal_intr
   685       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   686         |> Thm.forall_elim cx
   687         |> Thm.implies_intr cphi
   688         |> Thm.forall_intr cx
   689         |> Thm.implies_intr lhs)
   690       (Thm.implies_elim
   691           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   692         |> Thm.forall_intr cx
   693         |> Thm.implies_intr cphi
   694         |> Thm.implies_intr rhs)
   695     |> store_standard_thm_open "norm_hhf_eq"
   696   end;
   697 
   698 fun is_norm_hhf tm =
   699   let
   700     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   701       | is_norm (t $ u) = is_norm t andalso is_norm u
   702       | is_norm (Abs (_, _, t)) = is_norm t
   703       | is_norm _ = true;
   704   in is_norm (Pattern.beta_eta_contract tm) end;
   705 
   706 fun norm_hhf sg t =
   707   if is_norm_hhf t then t
   708   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] t;
   709 
   710 
   711 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   712 
   713 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   714 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   715 
   716 fun read_instantiate_sg sg sinsts th =
   717     let val ts = types_sorts th;
   718         val used = add_term_tvarnames (prop_of th, []);
   719     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   720 
   721 (*Instantiate theorem th, reading instantiations under theory of th*)
   722 fun read_instantiate sinsts th =
   723     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   724 
   725 
   726 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   727   Instantiates distinct Vars by terms, inferring type instantiations. *)
   728 local
   729   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   730     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   731         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   732         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   733         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   734         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) (tye, maxi) (T, U)
   735           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   736     in  (sign', tye', maxi')  end;
   737 in
   738 fun cterm_instantiate ctpairs0 th =
   739   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   740       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   741                          in (cterm_fun inst ct, cterm_fun inst cu) end
   742       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   743   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   744   handle TERM _ =>
   745            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   746        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   747 end;
   748 
   749 
   750 (** Derived rules mainly for METAHYPS **)
   751 
   752 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   753 fun equal_abs_elim ca eqth =
   754   let val {sign=signa, t=a, ...} = rep_cterm ca
   755       and combth = combination eqth (reflexive ca)
   756       val {sign,prop,...} = rep_thm eqth
   757       val (abst,absu) = Logic.dest_equals prop
   758       val cterm = cterm_of (Sign.merge (sign,signa))
   759   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   760            (transitive combth (beta_conversion false (cterm (absu$a))))
   761   end
   762   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   763 
   764 (*Calling equal_abs_elim with multiple terms*)
   765 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   766 
   767 local
   768   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   769   fun err th = raise THM("flexpair_inst: ", 0, [th])
   770   fun flexpair_inst def th =
   771     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   772         val cterm = cterm_of sign
   773         fun cvar a = cterm(Var((a,0),alpha))
   774         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   775                    def
   776     in  equal_elim def' th
   777     end
   778     handle THM _ => err th | Bind => err th
   779 in
   780 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   781 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   782 end;
   783 
   784 (*Version for flexflex pairs -- this supports lifting.*)
   785 fun flexpair_abs_elim_list cts =
   786     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   787 
   788 
   789 (*** Goal (PROP A) <==> PROP A ***)
   790 
   791 local
   792   val cert = Thm.cterm_of proto_sign;
   793   val A = Free ("A", propT);
   794   val G = Logic.mk_goal A;
   795   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   796 in
   797   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   798       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   799   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   800       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   801 end;
   802 
   803 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   804 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   805 
   806 fun implies_intr_goals cprops thm =
   807   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   808   |> implies_intr_list (map mk_cgoal cprops);
   809 
   810 
   811 
   812 (** variations on instantiate **)
   813 
   814 (*shorthand for instantiating just one variable in the current theory*)
   815 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   816 
   817 
   818 (* collect vars in left-to-right order *)
   819 
   820 fun tvars_of_terms ts = rev (foldl Term.add_tvars ([], ts));
   821 fun vars_of_terms ts = rev (foldl Term.add_vars ([], ts));
   822 
   823 fun tvars_of thm = tvars_of_terms [prop_of thm];
   824 fun vars_of thm = vars_of_terms [prop_of thm];
   825 
   826 
   827 (* instantiate by left-to-right occurrence of variables *)
   828 
   829 fun instantiate' cTs cts thm =
   830   let
   831     fun err msg =
   832       raise TYPE ("instantiate': " ^ msg,
   833         mapfilter (apsome Thm.typ_of) cTs,
   834         mapfilter (apsome Thm.term_of) cts);
   835 
   836     fun inst_of (v, ct) =
   837       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   838         handle TYPE (msg, _, _) => err msg;
   839 
   840     fun zip_vars _ [] = []
   841       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   842       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   843       | zip_vars [] _ = err "more instantiations than variables in thm";
   844 
   845     (*instantiate types first!*)
   846     val thm' =
   847       if forall is_none cTs then thm
   848       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   849     in
   850       if forall is_none cts then thm'
   851       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   852     end;
   853 
   854 
   855 (* unvarify(T) *)
   856 
   857 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   858 
   859 fun unvarifyT thm =
   860   let
   861     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   862     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   863   in instantiate' tfrees [] thm end;
   864 
   865 fun unvarify raw_thm =
   866   let
   867     val thm = unvarifyT raw_thm;
   868     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   869     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   870   in instantiate' [] frees thm end;
   871 
   872 
   873 (* tvars_intr_list *)
   874 
   875 fun tfrees_of thm =
   876   let val {hyps, prop, ...} = Thm.rep_thm thm
   877   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   878 
   879 fun tvars_intr_list tfrees thm =
   880   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   881 
   882 
   883 (* increment var indexes *)
   884 
   885 fun incr_indexes_wrt is cTs cts thms =
   886   let
   887     val maxidx =
   888       foldl Int.max (~1, is @
   889         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   890         map (#maxidx o Thm.rep_cterm) cts @
   891         map (#maxidx o Thm.rep_thm) thms);
   892   in Thm.incr_indexes (maxidx + 1) end;
   893 
   894 
   895 (* freeze_all *)
   896 
   897 (*freeze all (T)Vars; assumes thm in standard form*)
   898 
   899 fun freeze_all_TVars thm =
   900   (case tvars_of thm of
   901     [] => thm
   902   | tvars =>
   903       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   904       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   905 
   906 fun freeze_all_Vars thm =
   907   (case vars_of thm of
   908     [] => thm
   909   | vars =>
   910       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   911       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   912 
   913 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   914 
   915 
   916 (* mk_triv_goal *)
   917 
   918 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   919 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   920 
   921 
   922 
   923 (** meta-level conjunction **)
   924 
   925 local
   926   val A = read_prop "PROP A";
   927   val B = read_prop "PROP B";
   928   val C = read_prop "PROP C";
   929   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   930 
   931   val proj1 =
   932     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   933     |> forall_elim_vars 0;
   934 
   935   val proj2 =
   936     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   937     |> forall_elim_vars 0;
   938 
   939   val conj_intr_rule =
   940     forall_intr_list [A, B] (implies_intr_list [A, B]
   941       (Thm.forall_intr C (Thm.implies_intr ABC
   942         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   943     |> forall_elim_vars 0;
   944 
   945   val incr = incr_indexes_wrt [] [] [];
   946 in
   947 
   948 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   949 
   950 fun conj_intr_list [] = asm_rl
   951   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
   952 
   953 fun conj_elim th =
   954   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
   955   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
   956 
   957 fun conj_elim_list th =
   958   let val (th1, th2) = conj_elim th
   959   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
   960 
   961 fun conj_elim_precise 0 _ = []
   962   | conj_elim_precise 1 th = [th]
   963   | conj_elim_precise n th =
   964       let val (th1, th2) = conj_elim th
   965       in th1 :: conj_elim_precise (n - 1) th2 end;
   966 
   967 val conj_intr_thm = store_standard_thm_open "conjunctionI"
   968   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
   969 
   970 end;
   971 
   972 end;
   973 
   974 structure BasicDrule: BASIC_DRULE = Drule;
   975 open BasicDrule;