src/HOL/HOL.thy
author paulson
Tue Jan 27 15:39:51 2004 +0100 (2004-01-27)
changeset 14365 3d4df8c166ae
parent 14361 ad2f5da643b4
child 14398 c5c47703f763
permissions -rw-r--r--
replacing HOL/Real/PRat, PNat by the rational number development
of Markus Wenzel
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* The basis of Higher-Order Logic *}
     8 
     9 theory HOL = CPure
    10 files ("HOL_lemmas.ML") ("cladata.ML") ("blastdata.ML") ("simpdata.ML"):
    11 
    12 
    13 subsection {* Primitive logic *}
    14 
    15 subsubsection {* Core syntax *}
    16 
    17 classes type < logic
    18 defaultsort type
    19 
    20 global
    21 
    22 typedecl bool
    23 
    24 arities
    25   bool :: type
    26   fun :: (type, type) type
    27 
    28 judgment
    29   Trueprop      :: "bool => prop"                   ("(_)" 5)
    30 
    31 consts
    32   Not           :: "bool => bool"                   ("~ _" [40] 40)
    33   True          :: bool
    34   False         :: bool
    35   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    36   arbitrary     :: 'a
    37 
    38   The           :: "('a => bool) => 'a"
    39   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    40   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    41   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    42   Let           :: "['a, 'a => 'b] => 'b"
    43 
    44   "="           :: "['a, 'a] => bool"               (infixl 50)
    45   &             :: "[bool, bool] => bool"           (infixr 35)
    46   "|"           :: "[bool, bool] => bool"           (infixr 30)
    47   -->           :: "[bool, bool] => bool"           (infixr 25)
    48 
    49 local
    50 
    51 
    52 subsubsection {* Additional concrete syntax *}
    53 
    54 nonterminals
    55   letbinds  letbind
    56   case_syn  cases_syn
    57 
    58 syntax
    59   "_not_equal"  :: "['a, 'a] => bool"                    (infixl "~=" 50)
    60   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
    61 
    62   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
    63   ""            :: "letbind => letbinds"                 ("_")
    64   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
    65   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
    66 
    67   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
    68   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
    69   ""            :: "case_syn => cases_syn"               ("_")
    70   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
    71 
    72 translations
    73   "x ~= y"                == "~ (x = y)"
    74   "THE x. P"              == "The (%x. P)"
    75   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
    76   "let x = a in e"        == "Let a (%x. e)"
    77 
    78 print_translation {*
    79 (* To avoid eta-contraction of body: *)
    80 [("The", fn [Abs abs] =>
    81      let val (x,t) = atomic_abs_tr' abs
    82      in Syntax.const "_The" $ x $ t end)]
    83 *}
    84 
    85 syntax (output)
    86   "="           :: "['a, 'a] => bool"                    (infix 50)
    87   "_not_equal"  :: "['a, 'a] => bool"                    (infix "~=" 50)
    88 
    89 syntax (xsymbols)
    90   Not           :: "bool => bool"                        ("\<not> _" [40] 40)
    91   "op &"        :: "[bool, bool] => bool"                (infixr "\<and>" 35)
    92   "op |"        :: "[bool, bool] => bool"                (infixr "\<or>" 30)
    93   "op -->"      :: "[bool, bool] => bool"                (infixr "\<longrightarrow>" 25)
    94   "_not_equal"  :: "['a, 'a] => bool"                    (infix "\<noteq>" 50)
    95   "ALL "        :: "[idts, bool] => bool"                ("(3\<forall>_./ _)" [0, 10] 10)
    96   "EX "         :: "[idts, bool] => bool"                ("(3\<exists>_./ _)" [0, 10] 10)
    97   "EX! "        :: "[idts, bool] => bool"                ("(3\<exists>!_./ _)" [0, 10] 10)
    98   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
    99 (*"_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ \<orelse> _")*)
   100 
   101 syntax (xsymbols output)
   102   "_not_equal"  :: "['a, 'a] => bool"                    (infix "\<noteq>" 50)
   103 
   104 syntax (HTML output)
   105   Not           :: "bool => bool"                        ("\<not> _" [40] 40)
   106 
   107 syntax (HOL)
   108   "ALL "        :: "[idts, bool] => bool"                ("(3! _./ _)" [0, 10] 10)
   109   "EX "         :: "[idts, bool] => bool"                ("(3? _./ _)" [0, 10] 10)
   110   "EX! "        :: "[idts, bool] => bool"                ("(3?! _./ _)" [0, 10] 10)
   111 
   112 
   113 subsubsection {* Axioms and basic definitions *}
   114 
   115 axioms
   116   eq_reflection: "(x=y) ==> (x==y)"
   117 
   118   refl:         "t = (t::'a)"
   119   subst:        "[| s = t; P(s) |] ==> P(t::'a)"
   120 
   121   ext:          "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   122     -- {* Extensionality is built into the meta-logic, and this rule expresses *}
   123     -- {* a related property.  It is an eta-expanded version of the traditional *}
   124     -- {* rule, and similar to the ABS rule of HOL *}
   125 
   126   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   127 
   128   impI:         "(P ==> Q) ==> P-->Q"
   129   mp:           "[| P-->Q;  P |] ==> Q"
   130 
   131 defs
   132   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   133   All_def:      "All(P)    == (P = (%x. True))"
   134   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   135   False_def:    "False     == (!P. P)"
   136   not_def:      "~ P       == P-->False"
   137   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   138   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   139   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   140 
   141 axioms
   142   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   143   True_or_False:  "(P=True) | (P=False)"
   144 
   145 defs
   146   Let_def:      "Let s f == f(s)"
   147   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   148 
   149 finalconsts
   150   "op ="
   151   "op -->"
   152   The
   153   arbitrary
   154 
   155 subsubsection {* Generic algebraic operations *}
   156 
   157 axclass zero < type
   158 axclass one < type
   159 axclass plus < type
   160 axclass minus < type
   161 axclass times < type
   162 axclass inverse < type
   163 
   164 global
   165 
   166 consts
   167   "0"           :: "'a::zero"                       ("0")
   168   "1"           :: "'a::one"                        ("1")
   169   "+"           :: "['a::plus, 'a]  => 'a"          (infixl 65)
   170   -             :: "['a::minus, 'a] => 'a"          (infixl 65)
   171   uminus        :: "['a::minus] => 'a"              ("- _" [81] 80)
   172   *             :: "['a::times, 'a] => 'a"          (infixl 70)
   173 
   174 syntax
   175   "_index1"  :: index    ("\<^sub>1")
   176 translations
   177   (index) "\<^sub>1" == "_index 1"
   178 
   179 local
   180 
   181 typed_print_translation {*
   182   let
   183     fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   184       if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   185       else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   186   in [tr' "0", tr' "1"] end;
   187 *} -- {* show types that are presumably too general *}
   188 
   189 
   190 consts
   191   abs           :: "'a::minus => 'a"
   192   inverse       :: "'a::inverse => 'a"
   193   divide        :: "['a::inverse, 'a] => 'a"        (infixl "'/" 70)
   194 
   195 syntax (xsymbols)
   196   abs :: "'a::minus => 'a"    ("\<bar>_\<bar>")
   197 syntax (HTML output)
   198   abs :: "'a::minus => 'a"    ("\<bar>_\<bar>")
   199 
   200 axclass plus_ac0 < plus, zero
   201   commute: "x + y = y + x"
   202   assoc:   "(x + y) + z = x + (y + z)"
   203   zero:    "0 + x = x"
   204 
   205 
   206 subsection {* Theory and package setup *}
   207 
   208 subsubsection {* Basic lemmas *}
   209 
   210 use "HOL_lemmas.ML"
   211 theorems case_split = case_split_thm [case_names True False]
   212 
   213 
   214 subsubsection {* Intuitionistic Reasoning *}
   215 
   216 lemma impE':
   217   assumes 1: "P --> Q"
   218     and 2: "Q ==> R"
   219     and 3: "P --> Q ==> P"
   220   shows R
   221 proof -
   222   from 3 and 1 have P .
   223   with 1 have Q by (rule impE)
   224   with 2 show R .
   225 qed
   226 
   227 lemma allE':
   228   assumes 1: "ALL x. P x"
   229     and 2: "P x ==> ALL x. P x ==> Q"
   230   shows Q
   231 proof -
   232   from 1 have "P x" by (rule spec)
   233   from this and 1 show Q by (rule 2)
   234 qed
   235 
   236 lemma notE':
   237   assumes 1: "~ P"
   238     and 2: "~ P ==> P"
   239   shows R
   240 proof -
   241   from 2 and 1 have P .
   242   with 1 show R by (rule notE)
   243 qed
   244 
   245 lemmas [CPure.elim!] = disjE iffE FalseE conjE exE
   246   and [CPure.intro!] = iffI conjI impI TrueI notI allI refl
   247   and [CPure.elim 2] = allE notE' impE'
   248   and [CPure.intro] = exI disjI2 disjI1
   249 
   250 lemmas [trans] = trans
   251   and [sym] = sym not_sym
   252   and [CPure.elim?] = iffD1 iffD2 impE
   253 
   254 
   255 subsubsection {* Atomizing meta-level connectives *}
   256 
   257 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   258 proof
   259   assume "!!x. P x"
   260   show "ALL x. P x" by (rule allI)
   261 next
   262   assume "ALL x. P x"
   263   thus "!!x. P x" by (rule allE)
   264 qed
   265 
   266 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   267 proof
   268   assume r: "A ==> B"
   269   show "A --> B" by (rule impI) (rule r)
   270 next
   271   assume "A --> B" and A
   272   thus B by (rule mp)
   273 qed
   274 
   275 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   276 proof
   277   assume "x == y"
   278   show "x = y" by (unfold prems) (rule refl)
   279 next
   280   assume "x = y"
   281   thus "x == y" by (rule eq_reflection)
   282 qed
   283 
   284 lemma atomize_conj [atomize]:
   285   "(!!C. (A ==> B ==> PROP C) ==> PROP C) == Trueprop (A & B)"
   286 proof
   287   assume "!!C. (A ==> B ==> PROP C) ==> PROP C"
   288   show "A & B" by (rule conjI)
   289 next
   290   fix C
   291   assume "A & B"
   292   assume "A ==> B ==> PROP C"
   293   thus "PROP C"
   294   proof this
   295     show A by (rule conjunct1)
   296     show B by (rule conjunct2)
   297   qed
   298 qed
   299 
   300 lemmas [symmetric, rulify] = atomize_all atomize_imp
   301 
   302 
   303 subsubsection {* Classical Reasoner setup *}
   304 
   305 use "cladata.ML"
   306 setup hypsubst_setup
   307 
   308 ML_setup {*
   309   Context.>> (ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac));
   310 *}
   311 
   312 setup Classical.setup
   313 setup clasetup
   314 
   315 lemmas [intro?] = ext
   316   and [elim?] = ex1_implies_ex
   317 
   318 use "blastdata.ML"
   319 setup Blast.setup
   320 
   321 
   322 subsubsection {* Simplifier setup *}
   323 
   324 lemma meta_eq_to_obj_eq: "x == y ==> x = y"
   325 proof -
   326   assume r: "x == y"
   327   show "x = y" by (unfold r) (rule refl)
   328 qed
   329 
   330 lemma eta_contract_eq: "(%s. f s) = f" ..
   331 
   332 lemma simp_thms:
   333   shows not_not: "(~ ~ P) = P"
   334   and
   335     "(P ~= Q) = (P = (~Q))"
   336     "(P | ~P) = True"    "(~P | P) = True"
   337     "((~P) = (~Q)) = (P=Q)"
   338     "(x = x) = True"
   339     "(~True) = False"  "(~False) = True"
   340     "(~P) ~= P"  "P ~= (~P)"
   341     "(True=P) = P"  "(P=True) = P"  "(False=P) = (~P)"  "(P=False) = (~P)"
   342     "(True --> P) = P"  "(False --> P) = True"
   343     "(P --> True) = True"  "(P --> P) = True"
   344     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   345     "(P & True) = P"  "(True & P) = P"
   346     "(P & False) = False"  "(False & P) = False"
   347     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   348     "(P & ~P) = False"    "(~P & P) = False"
   349     "(P | True) = True"  "(True | P) = True"
   350     "(P | False) = P"  "(False | P) = P"
   351     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   352     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   353     -- {* needed for the one-point-rule quantifier simplification procs *}
   354     -- {* essential for termination!! *} and
   355     "!!P. (EX x. x=t & P(x)) = P(t)"
   356     "!!P. (EX x. t=x & P(x)) = P(t)"
   357     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   358     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   359   by (blast, blast, blast, blast, blast, rules+)
   360 
   361 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
   362   by rules
   363 
   364 lemma ex_simps:
   365   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
   366   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
   367   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
   368   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
   369   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
   370   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
   371   -- {* Miniscoping: pushing in existential quantifiers. *}
   372   by (rules | blast)+
   373 
   374 lemma all_simps:
   375   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
   376   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
   377   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
   378   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
   379   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
   380   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
   381   -- {* Miniscoping: pushing in universal quantifiers. *}
   382   by (rules | blast)+
   383 
   384 lemma disj_absorb: "(A | A) = A"
   385   by blast
   386 
   387 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   388   by blast
   389 
   390 lemma conj_absorb: "(A & A) = A"
   391   by blast
   392 
   393 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   394   by blast
   395 
   396 lemma eq_ac:
   397   shows eq_commute: "(a=b) = (b=a)"
   398     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   399     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (rules, blast+)
   400 lemma neq_commute: "(a~=b) = (b~=a)" by rules
   401 
   402 lemma conj_comms:
   403   shows conj_commute: "(P&Q) = (Q&P)"
   404     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by rules+
   405 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by rules
   406 
   407 lemma disj_comms:
   408   shows disj_commute: "(P|Q) = (Q|P)"
   409     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by rules+
   410 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by rules
   411 
   412 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by rules
   413 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by rules
   414 
   415 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by rules
   416 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by rules
   417 
   418 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by rules
   419 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by rules
   420 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by rules
   421 
   422 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
   423 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
   424 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
   425 
   426 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
   427 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
   428 
   429 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by rules
   430 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
   431 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
   432 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
   433 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
   434 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
   435   by blast
   436 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
   437 
   438 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by rules
   439 
   440 
   441 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
   442   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
   443   -- {* cases boil down to the same thing. *}
   444   by blast
   445 
   446 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
   447 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
   448 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by rules
   449 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by rules
   450 
   451 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by rules
   452 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by rules
   453 
   454 text {*
   455   \medskip The @{text "&"} congruence rule: not included by default!
   456   May slow rewrite proofs down by as much as 50\% *}
   457 
   458 lemma conj_cong:
   459     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
   460   by rules
   461 
   462 lemma rev_conj_cong:
   463     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
   464   by rules
   465 
   466 text {* The @{text "|"} congruence rule: not included by default! *}
   467 
   468 lemma disj_cong:
   469     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
   470   by blast
   471 
   472 lemma eq_sym_conv: "(x = y) = (y = x)"
   473   by rules
   474 
   475 
   476 text {* \medskip if-then-else rules *}
   477 
   478 lemma if_True: "(if True then x else y) = x"
   479   by (unfold if_def) blast
   480 
   481 lemma if_False: "(if False then x else y) = y"
   482   by (unfold if_def) blast
   483 
   484 lemma if_P: "P ==> (if P then x else y) = x"
   485   by (unfold if_def) blast
   486 
   487 lemma if_not_P: "~P ==> (if P then x else y) = y"
   488   by (unfold if_def) blast
   489 
   490 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
   491   apply (rule case_split [of Q])
   492    apply (subst if_P)
   493     prefer 3 apply (subst if_not_P, blast+)
   494   done
   495 
   496 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
   497 by (subst split_if, blast)
   498 
   499 lemmas if_splits = split_if split_if_asm
   500 
   501 lemma if_def2: "(if Q then x else y) = ((Q --> x) & (~ Q --> y))"
   502   by (rule split_if)
   503 
   504 lemma if_cancel: "(if c then x else x) = x"
   505 by (subst split_if, blast)
   506 
   507 lemma if_eq_cancel: "(if x = y then y else x) = x"
   508 by (subst split_if, blast)
   509 
   510 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
   511   -- {* This form is useful for expanding @{text if}s on the RIGHT of the @{text "==>"} symbol. *}
   512   by (rule split_if)
   513 
   514 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
   515   -- {* And this form is useful for expanding @{text if}s on the LEFT. *}
   516   apply (subst split_if, blast)
   517   done
   518 
   519 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) rules
   520 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) rules
   521 
   522 subsubsection {* Actual Installation of the Simplifier *}
   523 
   524 use "simpdata.ML"
   525 setup Simplifier.setup
   526 setup "Simplifier.method_setup Splitter.split_modifiers" setup simpsetup
   527 setup Splitter.setup setup Clasimp.setup
   528 
   529 declare disj_absorb [simp] conj_absorb [simp] 
   530 
   531 lemma ex1_eq[iff]: "EX! x. x = t" "EX! x. t = x"
   532 by blast+
   533 
   534 theorem choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
   535   apply (rule iffI)
   536   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
   537   apply (fast dest!: theI')
   538   apply (fast intro: ext the1_equality [symmetric])
   539   apply (erule ex1E)
   540   apply (rule allI)
   541   apply (rule ex1I)
   542   apply (erule spec)
   543   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
   544   apply (erule impE)
   545   apply (rule allI)
   546   apply (rule_tac P = "xa = x" in case_split_thm)
   547   apply (drule_tac [3] x = x in fun_cong, simp_all)
   548   done
   549 
   550 text{*Needs only HOL-lemmas:*}
   551 lemma mk_left_commute:
   552   assumes a: "\<And>x y z. f (f x y) z = f x (f y z)" and
   553           c: "\<And>x y. f x y = f y x"
   554   shows "f x (f y z) = f y (f x z)"
   555 by(rule trans[OF trans[OF c a] arg_cong[OF c, of "f y"]])
   556 
   557 
   558 subsubsection {* Generic cases and induction *}
   559 
   560 constdefs
   561   induct_forall :: "('a => bool) => bool"
   562   "induct_forall P == \<forall>x. P x"
   563   induct_implies :: "bool => bool => bool"
   564   "induct_implies A B == A --> B"
   565   induct_equal :: "'a => 'a => bool"
   566   "induct_equal x y == x = y"
   567   induct_conj :: "bool => bool => bool"
   568   "induct_conj A B == A & B"
   569 
   570 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
   571   by (simp only: atomize_all induct_forall_def)
   572 
   573 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
   574   by (simp only: atomize_imp induct_implies_def)
   575 
   576 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
   577   by (simp only: atomize_eq induct_equal_def)
   578 
   579 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
   580     induct_conj (induct_forall A) (induct_forall B)"
   581   by (unfold induct_forall_def induct_conj_def) rules
   582 
   583 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
   584     induct_conj (induct_implies C A) (induct_implies C B)"
   585   by (unfold induct_implies_def induct_conj_def) rules
   586 
   587 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
   588 proof
   589   assume r: "induct_conj A B ==> PROP C" and A B
   590   show "PROP C" by (rule r) (simp! add: induct_conj_def)
   591 next
   592   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
   593   show "PROP C" by (rule r) (simp! add: induct_conj_def)+
   594 qed
   595 
   596 lemma induct_impliesI: "(A ==> B) ==> induct_implies A B"
   597   by (simp add: induct_implies_def)
   598 
   599 lemmas induct_atomize = atomize_conj induct_forall_eq induct_implies_eq induct_equal_eq
   600 lemmas induct_rulify1 [symmetric, standard] = induct_forall_eq induct_implies_eq induct_equal_eq
   601 lemmas induct_rulify2 = induct_forall_def induct_implies_def induct_equal_def induct_conj_def
   602 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
   603 
   604 hide const induct_forall induct_implies induct_equal induct_conj
   605 
   606 
   607 text {* Method setup. *}
   608 
   609 ML {*
   610   structure InductMethod = InductMethodFun
   611   (struct
   612     val dest_concls = HOLogic.dest_concls;
   613     val cases_default = thm "case_split";
   614     val local_impI = thm "induct_impliesI";
   615     val conjI = thm "conjI";
   616     val atomize = thms "induct_atomize";
   617     val rulify1 = thms "induct_rulify1";
   618     val rulify2 = thms "induct_rulify2";
   619     val localize = [Thm.symmetric (thm "induct_implies_def")];
   620   end);
   621 *}
   622 
   623 setup InductMethod.setup
   624 
   625 
   626 subsection {* Order signatures and orders *}
   627 
   628 axclass
   629   ord < type
   630 
   631 syntax
   632   "op <"        :: "['a::ord, 'a] => bool"             ("op <")
   633   "op <="       :: "['a::ord, 'a] => bool"             ("op <=")
   634 
   635 global
   636 
   637 consts
   638   "op <"        :: "['a::ord, 'a] => bool"             ("(_/ < _)"  [50, 51] 50)
   639   "op <="       :: "['a::ord, 'a] => bool"             ("(_/ <= _)" [50, 51] 50)
   640 
   641 local
   642 
   643 syntax (xsymbols)
   644   "op <="       :: "['a::ord, 'a] => bool"             ("op \<le>")
   645   "op <="       :: "['a::ord, 'a] => bool"             ("(_/ \<le> _)"  [50, 51] 50)
   646 
   647 
   648 lemma Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   649 by blast
   650 
   651 subsubsection {* Monotonicity *}
   652 
   653 locale mono =
   654   fixes f
   655   assumes mono: "A <= B ==> f A <= f B"
   656 
   657 lemmas monoI [intro?] = mono.intro
   658   and monoD [dest?] = mono.mono
   659 
   660 constdefs
   661   min :: "['a::ord, 'a] => 'a"
   662   "min a b == (if a <= b then a else b)"
   663   max :: "['a::ord, 'a] => 'a"
   664   "max a b == (if a <= b then b else a)"
   665 
   666 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   667   by (simp add: min_def)
   668 
   669 lemma min_of_mono:
   670     "ALL x y. (f x <= f y) = (x <= y) ==> min (f m) (f n) = f (min m n)"
   671   by (simp add: min_def)
   672 
   673 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   674   by (simp add: max_def)
   675 
   676 lemma max_of_mono:
   677     "ALL x y. (f x <= f y) = (x <= y) ==> max (f m) (f n) = f (max m n)"
   678   by (simp add: max_def)
   679 
   680 
   681 subsubsection "Orders"
   682 
   683 axclass order < ord
   684   order_refl [iff]: "x <= x"
   685   order_trans: "x <= y ==> y <= z ==> x <= z"
   686   order_antisym: "x <= y ==> y <= x ==> x = y"
   687   order_less_le: "(x < y) = (x <= y & x ~= y)"
   688 
   689 
   690 text {* Reflexivity. *}
   691 
   692 lemma order_eq_refl: "!!x::'a::order. x = y ==> x <= y"
   693     -- {* This form is useful with the classical reasoner. *}
   694   apply (erule ssubst)
   695   apply (rule order_refl)
   696   done
   697 
   698 lemma order_less_irrefl [iff]: "~ x < (x::'a::order)"
   699   by (simp add: order_less_le)
   700 
   701 lemma order_le_less: "((x::'a::order) <= y) = (x < y | x = y)"
   702     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   703   apply (simp add: order_less_le, blast)
   704   done
   705 
   706 lemmas order_le_imp_less_or_eq = order_le_less [THEN iffD1, standard]
   707 
   708 lemma order_less_imp_le: "!!x::'a::order. x < y ==> x <= y"
   709   by (simp add: order_less_le)
   710 
   711 
   712 text {* Asymmetry. *}
   713 
   714 lemma order_less_not_sym: "(x::'a::order) < y ==> ~ (y < x)"
   715   by (simp add: order_less_le order_antisym)
   716 
   717 lemma order_less_asym: "x < (y::'a::order) ==> (~P ==> y < x) ==> P"
   718   apply (drule order_less_not_sym)
   719   apply (erule contrapos_np, simp)
   720   done
   721 
   722 lemma order_eq_iff: "!!x::'a::order. (x = y) = (x \<le> y & y \<le> x)"  
   723 by (blast intro: order_antisym)
   724 
   725 
   726 text {* Transitivity. *}
   727 
   728 lemma order_less_trans: "!!x::'a::order. [| x < y; y < z |] ==> x < z"
   729   apply (simp add: order_less_le)
   730   apply (blast intro: order_trans order_antisym)
   731   done
   732 
   733 lemma order_le_less_trans: "!!x::'a::order. [| x <= y; y < z |] ==> x < z"
   734   apply (simp add: order_less_le)
   735   apply (blast intro: order_trans order_antisym)
   736   done
   737 
   738 lemma order_less_le_trans: "!!x::'a::order. [| x < y; y <= z |] ==> x < z"
   739   apply (simp add: order_less_le)
   740   apply (blast intro: order_trans order_antisym)
   741   done
   742 
   743 
   744 text {* Useful for simplification, but too risky to include by default. *}
   745 
   746 lemma order_less_imp_not_less: "(x::'a::order) < y ==>  (~ y < x) = True"
   747   by (blast elim: order_less_asym)
   748 
   749 lemma order_less_imp_triv: "(x::'a::order) < y ==>  (y < x --> P) = True"
   750   by (blast elim: order_less_asym)
   751 
   752 lemma order_less_imp_not_eq: "(x::'a::order) < y ==>  (x = y) = False"
   753   by auto
   754 
   755 lemma order_less_imp_not_eq2: "(x::'a::order) < y ==>  (y = x) = False"
   756   by auto
   757 
   758 
   759 text {* Other operators. *}
   760 
   761 lemma min_leastR: "(!!x::'a::order. least <= x) ==> min x least = least"
   762   apply (simp add: min_def)
   763   apply (blast intro: order_antisym)
   764   done
   765 
   766 lemma max_leastR: "(!!x::'a::order. least <= x) ==> max x least = x"
   767   apply (simp add: max_def)
   768   apply (blast intro: order_antisym)
   769   done
   770 
   771 
   772 subsubsection {* Least value operator *}
   773 
   774 constdefs
   775   Least :: "('a::ord => bool) => 'a"               (binder "LEAST " 10)
   776   "Least P == THE x. P x & (ALL y. P y --> x <= y)"
   777     -- {* We can no longer use LeastM because the latter requires Hilbert-AC. *}
   778 
   779 lemma LeastI2:
   780   "[| P (x::'a::order);
   781       !!y. P y ==> x <= y;
   782       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   783    ==> Q (Least P)"
   784   apply (unfold Least_def)
   785   apply (rule theI2)
   786     apply (blast intro: order_antisym)+
   787   done
   788 
   789 lemma Least_equality:
   790     "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   791   apply (simp add: Least_def)
   792   apply (rule the_equality)
   793   apply (auto intro!: order_antisym)
   794   done
   795 
   796 
   797 subsubsection "Linear / total orders"
   798 
   799 axclass linorder < order
   800   linorder_linear: "x <= y | y <= x"
   801 
   802 lemma linorder_less_linear: "!!x::'a::linorder. x<y | x=y | y<x"
   803   apply (simp add: order_less_le)
   804   apply (insert linorder_linear, blast)
   805   done
   806 
   807 lemma linorder_le_cases [case_names le ge]:
   808     "((x::'a::linorder) \<le> y ==> P) ==> (y \<le> x ==> P) ==> P"
   809   by (insert linorder_linear, blast)
   810 
   811 lemma linorder_cases [case_names less equal greater]:
   812     "((x::'a::linorder) < y ==> P) ==> (x = y ==> P) ==> (y < x ==> P) ==> P"
   813   by (insert linorder_less_linear, blast)
   814 
   815 lemma linorder_not_less: "!!x::'a::linorder. (~ x < y) = (y <= x)"
   816   apply (simp add: order_less_le)
   817   apply (insert linorder_linear)
   818   apply (blast intro: order_antisym)
   819   done
   820 
   821 lemma linorder_not_le: "!!x::'a::linorder. (~ x <= y) = (y < x)"
   822   apply (simp add: order_less_le)
   823   apply (insert linorder_linear)
   824   apply (blast intro: order_antisym)
   825   done
   826 
   827 lemma linorder_neq_iff: "!!x::'a::linorder. (x ~= y) = (x<y | y<x)"
   828 by (cut_tac x = x and y = y in linorder_less_linear, auto)
   829 
   830 lemma linorder_neqE: "x ~= (y::'a::linorder) ==> (x < y ==> R) ==> (y < x ==> R) ==> R"
   831 by (simp add: linorder_neq_iff, blast)
   832 
   833 
   834 subsubsection "Min and max on (linear) orders"
   835 
   836 lemma min_same [simp]: "min (x::'a::order) x = x"
   837   by (simp add: min_def)
   838 
   839 lemma max_same [simp]: "max (x::'a::order) x = x"
   840   by (simp add: max_def)
   841 
   842 lemma le_max_iff_disj: "!!z::'a::linorder. (z <= max x y) = (z <= x | z <= y)"
   843   apply (simp add: max_def)
   844   apply (insert linorder_linear)
   845   apply (blast intro: order_trans)
   846   done
   847 
   848 lemma le_maxI1: "(x::'a::linorder) <= max x y"
   849   by (simp add: le_max_iff_disj)
   850 
   851 lemma le_maxI2: "(y::'a::linorder) <= max x y"
   852     -- {* CANNOT use with @{text "[intro!]"} because blast will give PROOF FAILED. *}
   853   by (simp add: le_max_iff_disj)
   854 
   855 lemma less_max_iff_disj: "!!z::'a::linorder. (z < max x y) = (z < x | z < y)"
   856   apply (simp add: max_def order_le_less)
   857   apply (insert linorder_less_linear)
   858   apply (blast intro: order_less_trans)
   859   done
   860 
   861 lemma max_le_iff_conj [simp]:
   862     "!!z::'a::linorder. (max x y <= z) = (x <= z & y <= z)"
   863   apply (simp add: max_def)
   864   apply (insert linorder_linear)
   865   apply (blast intro: order_trans)
   866   done
   867 
   868 lemma max_less_iff_conj [simp]:
   869     "!!z::'a::linorder. (max x y < z) = (x < z & y < z)"
   870   apply (simp add: order_le_less max_def)
   871   apply (insert linorder_less_linear)
   872   apply (blast intro: order_less_trans)
   873   done
   874 
   875 lemma le_min_iff_conj [simp]:
   876     "!!z::'a::linorder. (z <= min x y) = (z <= x & z <= y)"
   877     -- {* @{text "[iff]"} screws up a @{text blast} in MiniML *}
   878   apply (simp add: min_def)
   879   apply (insert linorder_linear)
   880   apply (blast intro: order_trans)
   881   done
   882 
   883 lemma min_less_iff_conj [simp]:
   884     "!!z::'a::linorder. (z < min x y) = (z < x & z < y)"
   885   apply (simp add: order_le_less min_def)
   886   apply (insert linorder_less_linear)
   887   apply (blast intro: order_less_trans)
   888   done
   889 
   890 lemma min_le_iff_disj: "!!z::'a::linorder. (min x y <= z) = (x <= z | y <= z)"
   891   apply (simp add: min_def)
   892   apply (insert linorder_linear)
   893   apply (blast intro: order_trans)
   894   done
   895 
   896 lemma min_less_iff_disj: "!!z::'a::linorder. (min x y < z) = (x < z | y < z)"
   897   apply (simp add: min_def order_le_less)
   898   apply (insert linorder_less_linear)
   899   apply (blast intro: order_less_trans)
   900   done
   901 
   902 lemma max_assoc: "!!x::'a::linorder. max (max x y) z = max x (max y z)"
   903 apply(simp add:max_def)
   904 apply(rule conjI)
   905 apply(blast intro:order_trans)
   906 apply(simp add:linorder_not_le)
   907 apply(blast dest: order_less_trans order_le_less_trans)
   908 done
   909 
   910 lemma max_commute: "!!x::'a::linorder. max x y = max y x"
   911 apply(simp add:max_def)
   912 apply(rule conjI)
   913 apply(blast intro:order_antisym)
   914 apply(simp add:linorder_not_le)
   915 apply(blast dest: order_less_trans)
   916 done
   917 
   918 lemmas max_ac = max_assoc max_commute
   919                 mk_left_commute[of max,OF max_assoc max_commute]
   920 
   921 lemma min_assoc: "!!x::'a::linorder. min (min x y) z = min x (min y z)"
   922 apply(simp add:min_def)
   923 apply(rule conjI)
   924 apply(blast intro:order_trans)
   925 apply(simp add:linorder_not_le)
   926 apply(blast dest: order_less_trans order_le_less_trans)
   927 done
   928 
   929 lemma min_commute: "!!x::'a::linorder. min x y = min y x"
   930 apply(simp add:min_def)
   931 apply(rule conjI)
   932 apply(blast intro:order_antisym)
   933 apply(simp add:linorder_not_le)
   934 apply(blast dest: order_less_trans)
   935 done
   936 
   937 lemmas min_ac = min_assoc min_commute
   938                 mk_left_commute[of min,OF min_assoc min_commute]
   939 
   940 lemma split_min:
   941     "P (min (i::'a::linorder) j) = ((i <= j --> P(i)) & (~ i <= j --> P(j)))"
   942   by (simp add: min_def)
   943 
   944 lemma split_max:
   945     "P (max (i::'a::linorder) j) = ((i <= j --> P(j)) & (~ i <= j --> P(i)))"
   946   by (simp add: max_def)
   947 
   948 
   949 subsubsection "Bounded quantifiers"
   950 
   951 syntax
   952   "_lessAll" :: "[idt, 'a, bool] => bool"   ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   953   "_lessEx"  :: "[idt, 'a, bool] => bool"   ("(3EX _<_./ _)"  [0, 0, 10] 10)
   954   "_leAll"   :: "[idt, 'a, bool] => bool"   ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   955   "_leEx"    :: "[idt, 'a, bool] => bool"   ("(3EX _<=_./ _)" [0, 0, 10] 10)
   956 
   957 syntax (xsymbols)
   958   "_lessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   959   "_lessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   960   "_leAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   961   "_leEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   962 
   963 syntax (HOL)
   964   "_lessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   965   "_lessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   966   "_leAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   967   "_leEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   968 
   969 translations
   970  "ALL x<y. P"   =>  "ALL x. x < y --> P"
   971  "EX x<y. P"    =>  "EX x. x < y  & P"
   972  "ALL x<=y. P"  =>  "ALL x. x <= y --> P"
   973  "EX x<=y. P"   =>  "EX x. x <= y & P"
   974 
   975 print_translation {*
   976 let
   977   fun all_tr' [Const ("_bound",_) $ Free (v,_), 
   978                Const("op -->",_) $ (Const ("op <",_) $ (Const ("_bound",_) $ Free (v',_)) $ n ) $ P] = 
   979   (if v=v' then Syntax.const "_lessAll" $ Syntax.mark_bound v' $ n $ P else raise Match)
   980 
   981   | all_tr' [Const ("_bound",_) $ Free (v,_), 
   982                Const("op -->",_) $ (Const ("op <=",_) $ (Const ("_bound",_) $ Free (v',_)) $ n ) $ P] = 
   983   (if v=v' then Syntax.const "_leAll" $ Syntax.mark_bound v' $ n $ P else raise Match);
   984 
   985   fun ex_tr' [Const ("_bound",_) $ Free (v,_), 
   986                Const("op &",_) $ (Const ("op <",_) $ (Const ("_bound",_) $ Free (v',_)) $ n ) $ P] = 
   987   (if v=v' then Syntax.const "_lessEx" $ Syntax.mark_bound v' $ n $ P else raise Match)
   988 
   989   | ex_tr' [Const ("_bound",_) $ Free (v,_), 
   990                Const("op &",_) $ (Const ("op <=",_) $ (Const ("_bound",_) $ Free (v',_)) $ n ) $ P] = 
   991   (if v=v' then Syntax.const "_leEx" $ Syntax.mark_bound v' $ n $ P else raise Match)
   992 in
   993 [("ALL ", all_tr'), ("EX ", ex_tr')]
   994 end
   995 *}
   996 
   997 end