src/HOL/Analysis/Equivalence_Lebesgue_Henstock_Integration.thy
author wenzelm
Mon Mar 25 17:21:26 2019 +0100 (2 months ago)
changeset 69981 3dced198b9ec
parent 69922 4a9167f377b0
child 70271 f7630118814c
permissions -rw-r--r--
more strict AFP properties;
     1 (*  Title:      HOL/Analysis/Equivalence_Lebesgue_Henstock_Integration.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Robert Himmelmann, TU München
     4     Huge cleanup by LCP
     5 *)
     6 
     7 theory Equivalence_Lebesgue_Henstock_Integration
     8   imports Lebesgue_Measure Henstock_Kurzweil_Integration Complete_Measure Set_Integral
     9 begin
    10 
    11 lemma le_left_mono: "x \<le> y \<Longrightarrow> y \<le> a \<longrightarrow> x \<le> (a::'a::preorder)"
    12   by (auto intro: order_trans)
    13 
    14 lemma ball_trans:
    15   assumes "y \<in> ball z q" "r + q \<le> s" shows "ball y r \<subseteq> ball z s"
    16 proof safe
    17   fix x assume x: "x \<in> ball y r"
    18   have "dist z x \<le> dist z y + dist y x"
    19     by (rule dist_triangle)
    20   also have "\<dots> < s"
    21     using assms x by auto
    22   finally show "x \<in> ball z s"
    23     by simp
    24 qed
    25 
    26 lemma has_integral_implies_lebesgue_measurable_cbox:
    27   fixes f :: "'a :: euclidean_space \<Rightarrow> real"
    28   assumes f: "(f has_integral I) (cbox x y)"
    29   shows "f \<in> lebesgue_on (cbox x y) \<rightarrow>\<^sub>M borel"
    30 proof (rule cld_measure.borel_measurable_cld)
    31   let ?L = "lebesgue_on (cbox x y)"
    32   let ?\<mu> = "emeasure ?L"
    33   let ?\<mu>' = "outer_measure_of ?L"
    34   interpret L: finite_measure ?L
    35   proof
    36     show "?\<mu> (space ?L) \<noteq> \<infinity>"
    37       by (simp add: emeasure_restrict_space space_restrict_space emeasure_lborel_cbox_eq)
    38   qed
    39 
    40   show "cld_measure ?L"
    41   proof
    42     fix B A assume "B \<subseteq> A" "A \<in> null_sets ?L"
    43     then show "B \<in> sets ?L"
    44       using null_sets_completion_subset[OF \<open>B \<subseteq> A\<close>, of lborel]
    45       by (auto simp add: null_sets_restrict_space sets_restrict_space_iff intro: )
    46   next
    47     fix A assume "A \<subseteq> space ?L" "\<And>B. B \<in> sets ?L \<Longrightarrow> ?\<mu> B < \<infinity> \<Longrightarrow> A \<inter> B \<in> sets ?L"
    48     from this(1) this(2)[of "space ?L"] show "A \<in> sets ?L"
    49       by (auto simp: Int_absorb2 less_top[symmetric])
    50   qed auto
    51   then interpret cld_measure ?L
    52     .
    53 
    54   have content_eq_L: "A \<in> sets borel \<Longrightarrow> A \<subseteq> cbox x y \<Longrightarrow> content A = measure ?L A" for A
    55     by (subst measure_restrict_space) (auto simp: measure_def)
    56 
    57   fix E and a b :: real assume "E \<in> sets ?L" "a < b" "0 < ?\<mu> E" "?\<mu> E < \<infinity>"
    58   then obtain M :: real where "?\<mu> E = M" "0 < M"
    59     by (cases "?\<mu> E") auto
    60   define e where "e = M / (4 + 2 / (b - a))"
    61   from \<open>a < b\<close> \<open>0<M\<close> have "0 < e"
    62     by (auto intro!: divide_pos_pos simp: field_simps e_def)
    63 
    64   have "e < M / (3 + 2 / (b - a))"
    65     using \<open>a < b\<close> \<open>0 < M\<close>
    66     unfolding e_def by (intro divide_strict_left_mono add_strict_right_mono mult_pos_pos) (auto simp: field_simps)
    67   then have "2 * e < (b - a) * (M - e * 3)"
    68     using \<open>0<M\<close> \<open>0 < e\<close> \<open>a < b\<close> by (simp add: field_simps)
    69 
    70   have e_less_M: "e < M / 1"
    71     unfolding e_def using \<open>a < b\<close> \<open>0<M\<close> by (intro divide_strict_left_mono) (auto simp: field_simps)
    72 
    73   obtain d
    74     where "gauge d"
    75       and integral_f: "\<forall>p. p tagged_division_of cbox x y \<and> d fine p \<longrightarrow>
    76         norm ((\<Sum>(x,k) \<in> p. content k *\<^sub>R f x) - I) < e"
    77     using \<open>0<e\<close> f unfolding has_integral by auto
    78 
    79   define C where "C X m = X \<inter> {x. ball x (1/Suc m) \<subseteq> d x}" for X m
    80   have "incseq (C X)" for X
    81     unfolding C_def [abs_def]
    82     by (intro monoI Collect_mono conj_mono imp_refl le_left_mono subset_ball divide_left_mono Int_mono) auto
    83 
    84   { fix X assume "X \<subseteq> space ?L" and eq: "?\<mu>' X = ?\<mu> E"
    85     have "(SUP m. outer_measure_of ?L (C X m)) = outer_measure_of ?L (\<Union>m. C X m)"
    86       using \<open>X \<subseteq> space ?L\<close> by (intro SUP_outer_measure_of_incseq \<open>incseq (C X)\<close>) (auto simp: C_def)
    87     also have "(\<Union>m. C X m) = X"
    88     proof -
    89       { fix x
    90         obtain e where "0 < e" "ball x e \<subseteq> d x"
    91           using gaugeD[OF \<open>gauge d\<close>, of x] unfolding open_contains_ball by auto
    92         moreover
    93         obtain n where "1 / (1 + real n) < e"
    94           using reals_Archimedean[OF \<open>0<e\<close>] by (auto simp: inverse_eq_divide)
    95         then have "ball x (1 / (1 + real n)) \<subseteq> ball x e"
    96           by (intro subset_ball) auto
    97         ultimately have "\<exists>n. ball x (1 / (1 + real n)) \<subseteq> d x"
    98           by blast }
    99       then show ?thesis
   100         by (auto simp: C_def)
   101     qed
   102     finally have "(SUP m. outer_measure_of ?L (C X m)) = ?\<mu> E"
   103       using eq by auto
   104     also have "\<dots> > M - e"
   105       using \<open>0 < M\<close> \<open>?\<mu> E = M\<close> \<open>0<e\<close> by (auto intro!: ennreal_lessI)
   106     finally have "\<exists>m. M - e < outer_measure_of ?L (C X m)"
   107       unfolding less_SUP_iff by auto }
   108   note C = this
   109 
   110   let ?E = "{x\<in>E. f x \<le> a}" and ?F = "{x\<in>E. b \<le> f x}"
   111 
   112   have "\<not> (?\<mu>' ?E = ?\<mu> E \<and> ?\<mu>' ?F = ?\<mu> E)"
   113   proof
   114     assume eq: "?\<mu>' ?E = ?\<mu> E \<and> ?\<mu>' ?F = ?\<mu> E"
   115     with C[of ?E] C[of ?F] \<open>E \<in> sets ?L\<close>[THEN sets.sets_into_space] obtain ma mb
   116       where "M - e < outer_measure_of ?L (C ?E ma)" "M - e < outer_measure_of ?L (C ?F mb)"
   117       by auto
   118     moreover define m where "m = max ma mb"
   119     ultimately have M_minus_e: "M - e < outer_measure_of ?L (C ?E m)" "M - e < outer_measure_of ?L (C ?F m)"
   120       using
   121         incseqD[OF \<open>incseq (C ?E)\<close>, of ma m, THEN outer_measure_of_mono]
   122         incseqD[OF \<open>incseq (C ?F)\<close>, of mb m, THEN outer_measure_of_mono]
   123       by (auto intro: less_le_trans)
   124     define d' where "d' x = d x \<inter> ball x (1 / (3 * Suc m))" for x
   125     have "gauge d'"
   126       unfolding d'_def by (intro gauge_Int \<open>gauge d\<close> gauge_ball) auto
   127     then obtain p where p: "p tagged_division_of cbox x y" "d' fine p"
   128       by (rule fine_division_exists)
   129     then have "d fine p"
   130       unfolding d'_def[abs_def] fine_def by auto
   131 
   132     define s where "s = {(x::'a, k). k \<inter> (C ?E m) \<noteq> {} \<and> k \<inter> (C ?F m) \<noteq> {}}"
   133     define T where "T E k = (SOME x. x \<in> k \<inter> C E m)" for E k
   134     let ?A = "(\<lambda>(x, k). (T ?E k, k)) ` (p \<inter> s) \<union> (p - s)"
   135     let ?B = "(\<lambda>(x, k). (T ?F k, k)) ` (p \<inter> s) \<union> (p - s)"
   136 
   137     { fix X assume X_eq: "X = ?E \<or> X = ?F"
   138       let ?T = "(\<lambda>(x, k). (T X k, k))"
   139       let ?p = "?T ` (p \<inter> s) \<union> (p - s)"
   140 
   141       have in_s: "(x, k) \<in> s \<Longrightarrow> T X k \<in> k \<inter> C X m" for x k
   142         using someI_ex[of "\<lambda>x. x \<in> k \<inter> C X m"] X_eq unfolding ex_in_conv by (auto simp: T_def s_def)
   143 
   144       { fix x k assume "(x, k) \<in> p" "(x, k) \<in> s"
   145         have k: "k \<subseteq> ball x (1 / (3 * Suc m))"
   146           using \<open>d' fine p\<close>[THEN fineD, OF \<open>(x, k) \<in> p\<close>] by (auto simp: d'_def)
   147         then have "x \<in> ball (T X k) (1 / (3 * Suc m))"
   148           using in_s[OF \<open>(x, k) \<in> s\<close>] by (auto simp: C_def subset_eq dist_commute)
   149         then have "ball x (1 / (3 * Suc m)) \<subseteq> ball (T X k) (1 / Suc m)"
   150           by (rule ball_trans) (auto simp: divide_simps)
   151         with k in_s[OF \<open>(x, k) \<in> s\<close>] have "k \<subseteq> d (T X k)"
   152           by (auto simp: C_def) }
   153       then have "d fine ?p"
   154         using \<open>d fine p\<close> by (auto intro!: fineI)
   155       moreover
   156       have "?p tagged_division_of cbox x y"
   157       proof (rule tagged_division_ofI)
   158         show "finite ?p"
   159           using p(1) by auto
   160       next
   161         fix z k assume *: "(z, k) \<in> ?p"
   162         then consider "(z, k) \<in> p" "(z, k) \<notin> s"
   163           | x' where "(x', k) \<in> p" "(x', k) \<in> s" "z = T X k"
   164           by (auto simp: T_def)
   165         then have "z \<in> k \<and> k \<subseteq> cbox x y \<and> (\<exists>a b. k = cbox a b)"
   166           using p(1) by cases (auto dest: in_s)
   167         then show "z \<in> k" "k \<subseteq> cbox x y" "\<exists>a b. k = cbox a b"
   168           by auto
   169       next
   170         fix z k z' k' assume "(z, k) \<in> ?p" "(z', k') \<in> ?p" "(z, k) \<noteq> (z', k')"
   171         with tagged_division_ofD(5)[OF p(1), of _ k _ k']
   172         show "interior k \<inter> interior k' = {}"
   173           by (auto simp: T_def dest: in_s)
   174       next
   175         have "{k. \<exists>x. (x, k) \<in> ?p} = {k. \<exists>x. (x, k) \<in> p}"
   176           by (auto simp: T_def image_iff Bex_def)
   177         then show "\<Union>{k. \<exists>x. (x, k) \<in> ?p} = cbox x y"
   178           using p(1) by auto
   179       qed
   180       ultimately have I: "norm ((\<Sum>(x,k) \<in> ?p. content k *\<^sub>R f x) - I) < e"
   181         using integral_f by auto
   182 
   183       have "(\<Sum>(x,k) \<in> ?p. content k *\<^sub>R f x) =
   184         (\<Sum>(x,k) \<in> ?T ` (p \<inter> s). content k *\<^sub>R f x) + (\<Sum>(x,k) \<in> p - s. content k *\<^sub>R f x)"
   185         using p(1)[THEN tagged_division_ofD(1)]
   186         by (safe intro!: sum.union_inter_neutral) (auto simp: s_def T_def)
   187       also have "(\<Sum>(x,k) \<in> ?T ` (p \<inter> s). content k *\<^sub>R f x) = (\<Sum>(x,k) \<in> p \<inter> s. content k *\<^sub>R f (T X k))"
   188       proof (subst sum.reindex_nontrivial, safe)
   189         fix x1 x2 k assume 1: "(x1, k) \<in> p" "(x1, k) \<in> s" and 2: "(x2, k) \<in> p" "(x2, k) \<in> s"
   190           and eq: "content k *\<^sub>R f (T X k) \<noteq> 0"
   191         with tagged_division_ofD(5)[OF p(1), of x1 k x2 k] tagged_division_ofD(4)[OF p(1), of x1 k]
   192         show "x1 = x2"
   193           by (auto simp: content_eq_0_interior)
   194       qed (use p in \<open>auto intro!: sum.cong\<close>)
   195       finally have eq: "(\<Sum>(x,k) \<in> ?p. content k *\<^sub>R f x) =
   196         (\<Sum>(x,k) \<in> p \<inter> s. content k *\<^sub>R f (T X k)) + (\<Sum>(x,k) \<in> p - s. content k *\<^sub>R f x)" .
   197 
   198       have in_T: "(x, k) \<in> s \<Longrightarrow> T X k \<in> X" for x k
   199         using in_s[of x k] by (auto simp: C_def)
   200 
   201       note I eq in_T }
   202     note parts = this
   203 
   204     have p_in_L: "(x, k) \<in> p \<Longrightarrow> k \<in> sets ?L" for x k
   205       using tagged_division_ofD(3, 4)[OF p(1), of x k] by (auto simp: sets_restrict_space)
   206 
   207     have [simp]: "finite p"
   208       using tagged_division_ofD(1)[OF p(1)] .
   209 
   210     have "(M - 3*e) * (b - a) \<le> (\<Sum>(x,k) \<in> p \<inter> s. content k) * (b - a)"
   211     proof (intro mult_right_mono)
   212       have fin: "?\<mu> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C X m = {}}) < \<infinity>" for X
   213         using \<open>?\<mu> E < \<infinity>\<close> by (rule le_less_trans[rotated]) (auto intro!: emeasure_mono \<open>E \<in> sets ?L\<close>)
   214       have sets: "(E \<inter> \<Union>{k\<in>snd`p. k \<inter> C X m = {}}) \<in> sets ?L" for X
   215         using tagged_division_ofD(1)[OF p(1)] by (intro sets.Diff \<open>E \<in> sets ?L\<close> sets.finite_Union sets.Int) (auto intro: p_in_L)
   216       { fix X assume "X \<subseteq> E" "M - e < ?\<mu>' (C X m)"
   217         have "M - e \<le> ?\<mu>' (C X m)"
   218           by (rule less_imp_le) fact
   219         also have "\<dots> \<le> ?\<mu>' (E - (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C X m = {}}))"
   220         proof (intro outer_measure_of_mono subsetI)
   221           fix v assume "v \<in> C X m"
   222           then have "v \<in> cbox x y" "v \<in> E"
   223             using \<open>E \<subseteq> space ?L\<close> \<open>X \<subseteq> E\<close> by (auto simp: space_restrict_space C_def)
   224           then obtain z k where "(z, k) \<in> p" "v \<in> k"
   225             using tagged_division_ofD(6)[OF p(1), symmetric] by auto
   226           then show "v \<in> E - E \<inter> (\<Union>{k\<in>snd`p. k \<inter> C X m = {}})"
   227             using \<open>v \<in> C X m\<close> \<open>v \<in> E\<close> by auto
   228         qed
   229         also have "\<dots> = ?\<mu> E - ?\<mu> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C X m = {}})"
   230           using \<open>E \<in> sets ?L\<close> fin[of X] sets[of X] by (auto intro!: emeasure_Diff)
   231         finally have "?\<mu> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C X m = {}}) \<le> e"
   232           using \<open>0 < e\<close> e_less_M apply (cases "?\<mu> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C X m = {}})")
   233           by (auto simp add: \<open>?\<mu> E = M\<close> ennreal_minus ennreal_le_iff2)
   234         note this }
   235       note upper_bound = this
   236 
   237       have "?\<mu> (E \<inter> \<Union>(snd`(p - s))) =
   238         ?\<mu> ((E \<inter> \<Union>{k\<in>snd`p. k \<inter> C ?E m = {}}) \<union> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C ?F m = {}}))"
   239         by (intro arg_cong[where f="?\<mu>"]) (auto simp: s_def image_def Bex_def)
   240       also have "\<dots> \<le> ?\<mu> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C ?E m = {}}) + ?\<mu> (E \<inter> \<Union>{k\<in>snd`p. k \<inter> C ?F m = {}})"
   241         using sets[of ?E] sets[of ?F] M_minus_e by (intro emeasure_subadditive) auto
   242       also have "\<dots> \<le> e + ennreal e"
   243         using upper_bound[of ?E] upper_bound[of ?F] M_minus_e by (intro add_mono) auto
   244       finally have "?\<mu> E - 2*e \<le> ?\<mu> (E - (E \<inter> \<Union>(snd`(p - s))))"
   245         using \<open>0 < e\<close> \<open>E \<in> sets ?L\<close> tagged_division_ofD(1)[OF p(1)]
   246         by (subst emeasure_Diff)
   247            (auto simp: top_unique simp flip: ennreal_plus
   248                  intro!: sets.Int sets.finite_UN ennreal_mono_minus intro: p_in_L)
   249       also have "\<dots> \<le> ?\<mu> (\<Union>x\<in>p \<inter> s. snd x)"
   250       proof (safe intro!: emeasure_mono subsetI)
   251         fix v assume "v \<in> E" and not: "v \<notin> (\<Union>x\<in>p \<inter> s. snd x)"
   252         then have "v \<in> cbox x y"
   253           using \<open>E \<subseteq> space ?L\<close> by (auto simp: space_restrict_space)
   254         then obtain z k where "(z, k) \<in> p" "v \<in> k"
   255           using tagged_division_ofD(6)[OF p(1), symmetric] by auto
   256         with not show "v \<in> \<Union>(snd ` (p - s))"
   257           by (auto intro!: bexI[of _ "(z, k)"] elim: ballE[of _ _ "(z, k)"])
   258       qed (auto intro!: sets.Int sets.finite_UN ennreal_mono_minus intro: p_in_L)
   259       also have "\<dots> = measure ?L (\<Union>x\<in>p \<inter> s. snd x)"
   260         by (auto intro!: emeasure_eq_ennreal_measure)
   261       finally have "M - 2 * e \<le> measure ?L (\<Union>x\<in>p \<inter> s. snd x)"
   262         unfolding \<open>?\<mu> E = M\<close> using \<open>0 < e\<close> by (simp add: ennreal_minus)
   263       also have "measure ?L (\<Union>x\<in>p \<inter> s. snd x) = content (\<Union>x\<in>p \<inter> s. snd x)"
   264         using tagged_division_ofD(1,3,4) [OF p(1)]
   265         by (intro content_eq_L[symmetric])
   266            (fastforce intro!: sets.finite_UN UN_least del: subsetI)+
   267       also have "content (\<Union>x\<in>p \<inter> s. snd x) \<le> (\<Sum>k\<in>p \<inter> s. content (snd k))"
   268         using p(1) by (auto simp: emeasure_lborel_cbox_eq intro!: measure_subadditive_finite
   269                             dest!: p(1)[THEN tagged_division_ofD(4)])
   270       finally show "M - 3 * e \<le> (\<Sum>(x, y)\<in>p \<inter> s. content y)"
   271         using \<open>0 < e\<close> by (simp add: split_beta)
   272     qed (use \<open>a < b\<close> in auto)
   273     also have "\<dots> = (\<Sum>(x,k) \<in> p \<inter> s. content k * (b - a))"
   274       by (simp add: sum_distrib_right split_beta')
   275     also have "\<dots> \<le> (\<Sum>(x,k) \<in> p \<inter> s. content k * (f (T ?F k) - f (T ?E k)))"
   276       using parts(3) by (auto intro!: sum_mono mult_left_mono diff_mono)
   277     also have "\<dots> = (\<Sum>(x,k) \<in> p \<inter> s. content k * f (T ?F k)) - (\<Sum>(x,k) \<in> p \<inter> s. content k * f (T ?E k))"
   278       by (auto intro!: sum.cong simp: field_simps sum_subtractf[symmetric])
   279     also have "\<dots> = (\<Sum>(x,k) \<in> ?B. content k *\<^sub>R f x) - (\<Sum>(x,k) \<in> ?A. content k *\<^sub>R f x)"
   280       by (subst (1 2) parts) auto
   281     also have "\<dots> \<le> norm ((\<Sum>(x,k) \<in> ?B. content k *\<^sub>R f x) - (\<Sum>(x,k) \<in> ?A. content k *\<^sub>R f x))"
   282       by auto
   283     also have "\<dots> \<le> e + e"
   284       using parts(1)[of ?E] parts(1)[of ?F] by (intro norm_diff_triangle_le[of _ I]) auto
   285     finally show False
   286       using \<open>2 * e < (b - a) * (M - e * 3)\<close> by (auto simp: field_simps)
   287   qed
   288   moreover have "?\<mu>' ?E \<le> ?\<mu> E" "?\<mu>' ?F \<le> ?\<mu> E"
   289     unfolding outer_measure_of_eq[OF \<open>E \<in> sets ?L\<close>, symmetric] by (auto intro!: outer_measure_of_mono)
   290   ultimately show "min (?\<mu>' ?E) (?\<mu>' ?F) < ?\<mu> E"
   291     unfolding min_less_iff_disj by (auto simp: less_le)
   292 qed
   293 
   294 lemma has_integral_implies_lebesgue_measurable_real:
   295   fixes f :: "'a :: euclidean_space \<Rightarrow> real"
   296   assumes f: "(f has_integral I) \<Omega>"
   297   shows "(\<lambda>x. f x * indicator \<Omega> x) \<in> lebesgue \<rightarrow>\<^sub>M borel"
   298 proof -
   299   define B :: "nat \<Rightarrow> 'a set" where "B n = cbox (- real n *\<^sub>R One) (real n *\<^sub>R One)" for n
   300   show "(\<lambda>x. f x * indicator \<Omega> x) \<in> lebesgue \<rightarrow>\<^sub>M borel"
   301   proof (rule measurable_piecewise_restrict)
   302     have "(\<Union>n. box (- real n *\<^sub>R One) (real n *\<^sub>R One)) \<subseteq> \<Union>(B ` UNIV)"
   303       unfolding B_def by (intro UN_mono box_subset_cbox order_refl)
   304     then show "countable (range B)" "space lebesgue \<subseteq> \<Union>(B ` UNIV)"
   305       by (auto simp: B_def UN_box_eq_UNIV)
   306   next
   307     fix \<Omega>' assume "\<Omega>' \<in> range B"
   308     then obtain n where \<Omega>': "\<Omega>' = B n" by auto
   309     then show "\<Omega>' \<inter> space lebesgue \<in> sets lebesgue"
   310       by (auto simp: B_def)
   311 
   312     have "f integrable_on \<Omega>"
   313       using f by auto
   314     then have "(\<lambda>x. f x * indicator \<Omega> x) integrable_on \<Omega>"
   315       by (auto simp: integrable_on_def cong: has_integral_cong)
   316     then have "(\<lambda>x. f x * indicator \<Omega> x) integrable_on (\<Omega> \<union> B n)"
   317       by (rule integrable_on_superset) auto
   318     then have "(\<lambda>x. f x * indicator \<Omega> x) integrable_on B n"
   319       unfolding B_def by (rule integrable_on_subcbox) auto
   320     then show "(\<lambda>x. f x * indicator \<Omega> x) \<in> lebesgue_on \<Omega>' \<rightarrow>\<^sub>M borel"
   321       unfolding B_def \<Omega>' by (auto intro: has_integral_implies_lebesgue_measurable_cbox simp: integrable_on_def)
   322   qed
   323 qed
   324 
   325 lemma has_integral_implies_lebesgue_measurable:
   326   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
   327   assumes f: "(f has_integral I) \<Omega>"
   328   shows "(\<lambda>x. indicator \<Omega> x *\<^sub>R f x) \<in> lebesgue \<rightarrow>\<^sub>M borel"
   329 proof (intro borel_measurable_euclidean_space[where 'c='b, THEN iffD2] ballI)
   330   fix i :: "'b" assume "i \<in> Basis"
   331   have "(\<lambda>x. (f x \<bullet> i) * indicator \<Omega> x) \<in> borel_measurable (completion lborel)"
   332     using has_integral_linear[OF f bounded_linear_inner_left, of i]
   333     by (intro has_integral_implies_lebesgue_measurable_real) (auto simp: comp_def)
   334   then show "(\<lambda>x. indicator \<Omega> x *\<^sub>R f x \<bullet> i) \<in> borel_measurable (completion lborel)"
   335     by (simp add: ac_simps)
   336 qed
   337 
   338 subsection \<open>Equivalence Lebesgue integral on \<^const>\<open>lborel\<close> and HK-integral\<close>
   339 
   340 lemma has_integral_measure_lborel:
   341   fixes A :: "'a::euclidean_space set"
   342   assumes A[measurable]: "A \<in> sets borel" and finite: "emeasure lborel A < \<infinity>"
   343   shows "((\<lambda>x. 1) has_integral measure lborel A) A"
   344 proof -
   345   { fix l u :: 'a
   346     have "((\<lambda>x. 1) has_integral measure lborel (box l u)) (box l u)"
   347     proof cases
   348       assume "\<forall>b\<in>Basis. l \<bullet> b \<le> u \<bullet> b"
   349       then show ?thesis
   350         apply simp
   351         apply (subst has_integral_restrict[symmetric, OF box_subset_cbox])
   352         apply (subst has_integral_spike_interior_eq[where g="\<lambda>_. 1"])
   353         using has_integral_const[of "1::real" l u]
   354         apply (simp_all add: inner_diff_left[symmetric] content_cbox_cases)
   355         done
   356     next
   357       assume "\<not> (\<forall>b\<in>Basis. l \<bullet> b \<le> u \<bullet> b)"
   358       then have "box l u = {}"
   359         unfolding box_eq_empty by (auto simp: not_le intro: less_imp_le)
   360       then show ?thesis
   361         by simp
   362     qed }
   363   note has_integral_box = this
   364 
   365   { fix a b :: 'a let ?M = "\<lambda>A. measure lborel (A \<inter> box a b)"
   366     have "Int_stable  (range (\<lambda>(a, b). box a b))"
   367       by (auto simp: Int_stable_def box_Int_box)
   368     moreover have "(range (\<lambda>(a, b). box a b)) \<subseteq> Pow UNIV"
   369       by auto
   370     moreover have "A \<in> sigma_sets UNIV (range (\<lambda>(a, b). box a b))"
   371        using A unfolding borel_eq_box by simp
   372     ultimately have "((\<lambda>x. 1) has_integral ?M A) (A \<inter> box a b)"
   373     proof (induction rule: sigma_sets_induct_disjoint)
   374       case (basic A) then show ?case
   375         by (auto simp: box_Int_box has_integral_box)
   376     next
   377       case empty then show ?case
   378         by simp
   379     next
   380       case (compl A)
   381       then have [measurable]: "A \<in> sets borel"
   382         by (simp add: borel_eq_box)
   383 
   384       have "((\<lambda>x. 1) has_integral ?M (box a b)) (box a b)"
   385         by (simp add: has_integral_box)
   386       moreover have "((\<lambda>x. if x \<in> A \<inter> box a b then 1 else 0) has_integral ?M A) (box a b)"
   387         by (subst has_integral_restrict) (auto intro: compl)
   388       ultimately have "((\<lambda>x. 1 - (if x \<in> A \<inter> box a b then 1 else 0)) has_integral ?M (box a b) - ?M A) (box a b)"
   389         by (rule has_integral_diff)
   390       then have "((\<lambda>x. (if x \<in> (UNIV - A) \<inter> box a b then 1 else 0)) has_integral ?M (box a b) - ?M A) (box a b)"
   391         by (rule has_integral_cong[THEN iffD1, rotated 1]) auto
   392       then have "((\<lambda>x. 1) has_integral ?M (box a b) - ?M A) ((UNIV - A) \<inter> box a b)"
   393         by (subst (asm) has_integral_restrict) auto
   394       also have "?M (box a b) - ?M A = ?M (UNIV - A)"
   395         by (subst measure_Diff[symmetric]) (auto simp: emeasure_lborel_box_eq Diff_Int_distrib2)
   396       finally show ?case .
   397     next
   398       case (union F)
   399       then have [measurable]: "\<And>i. F i \<in> sets borel"
   400         by (simp add: borel_eq_box subset_eq)
   401       have "((\<lambda>x. if x \<in> \<Union>(F ` UNIV) \<inter> box a b then 1 else 0) has_integral ?M (\<Union>i. F i)) (box a b)"
   402       proof (rule has_integral_monotone_convergence_increasing)
   403         let ?f = "\<lambda>k x. \<Sum>i<k. if x \<in> F i \<inter> box a b then 1 else 0 :: real"
   404         show "\<And>k. (?f k has_integral (\<Sum>i<k. ?M (F i))) (box a b)"
   405           using union.IH by (auto intro!: has_integral_sum simp del: Int_iff)
   406         show "\<And>k x. ?f k x \<le> ?f (Suc k) x"
   407           by (intro sum_mono2) auto
   408         from union(1) have *: "\<And>x i j. x \<in> F i \<Longrightarrow> x \<in> F j \<longleftrightarrow> j = i"
   409           by (auto simp add: disjoint_family_on_def)
   410         show "\<And>x. (\<lambda>k. ?f k x) \<longlonglongrightarrow> (if x \<in> \<Union>(F ` UNIV) \<inter> box a b then 1 else 0)"
   411           apply (auto simp: * sum.If_cases Iio_Int_singleton)
   412           apply (rule_tac k="Suc xa" in LIMSEQ_offset)
   413           apply simp
   414           done
   415         have *: "emeasure lborel ((\<Union>x. F x) \<inter> box a b) \<le> emeasure lborel (box a b)"
   416           by (intro emeasure_mono) auto
   417 
   418         with union(1) show "(\<lambda>k. \<Sum>i<k. ?M (F i)) \<longlonglongrightarrow> ?M (\<Union>i. F i)"
   419           unfolding sums_def[symmetric] UN_extend_simps
   420           by (intro measure_UNION) (auto simp: disjoint_family_on_def emeasure_lborel_box_eq top_unique)
   421       qed
   422       then show ?case
   423         by (subst (asm) has_integral_restrict) auto
   424     qed }
   425   note * = this
   426 
   427   show ?thesis
   428   proof (rule has_integral_monotone_convergence_increasing)
   429     let ?B = "\<lambda>n::nat. box (- real n *\<^sub>R One) (real n *\<^sub>R One) :: 'a set"
   430     let ?f = "\<lambda>n::nat. \<lambda>x. if x \<in> A \<inter> ?B n then 1 else 0 :: real"
   431     let ?M = "\<lambda>n. measure lborel (A \<inter> ?B n)"
   432 
   433     show "\<And>n::nat. (?f n has_integral ?M n) A"
   434       using * by (subst has_integral_restrict) simp_all
   435     show "\<And>k x. ?f k x \<le> ?f (Suc k) x"
   436       by (auto simp: box_def)
   437     { fix x assume "x \<in> A"
   438       moreover have "(\<lambda>k. indicator (A \<inter> ?B k) x :: real) \<longlonglongrightarrow> indicator (\<Union>k::nat. A \<inter> ?B k) x"
   439         by (intro LIMSEQ_indicator_incseq) (auto simp: incseq_def box_def)
   440       ultimately show "(\<lambda>k. if x \<in> A \<inter> ?B k then 1 else 0::real) \<longlonglongrightarrow> 1"
   441         by (simp add: indicator_def UN_box_eq_UNIV) }
   442 
   443     have "(\<lambda>n. emeasure lborel (A \<inter> ?B n)) \<longlonglongrightarrow> emeasure lborel (\<Union>n::nat. A \<inter> ?B n)"
   444       by (intro Lim_emeasure_incseq) (auto simp: incseq_def box_def)
   445     also have "(\<lambda>n. emeasure lborel (A \<inter> ?B n)) = (\<lambda>n. measure lborel (A \<inter> ?B n))"
   446     proof (intro ext emeasure_eq_ennreal_measure)
   447       fix n have "emeasure lborel (A \<inter> ?B n) \<le> emeasure lborel (?B n)"
   448         by (intro emeasure_mono) auto
   449       then show "emeasure lborel (A \<inter> ?B n) \<noteq> top"
   450         by (auto simp: top_unique)
   451     qed
   452     finally show "(\<lambda>n. measure lborel (A \<inter> ?B n)) \<longlonglongrightarrow> measure lborel A"
   453       using emeasure_eq_ennreal_measure[of lborel A] finite
   454       by (simp add: UN_box_eq_UNIV less_top)
   455   qed
   456 qed
   457 
   458 lemma nn_integral_has_integral:
   459   fixes f::"'a::euclidean_space \<Rightarrow> real"
   460   assumes f: "f \<in> borel_measurable borel" "\<And>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>lborel) = ennreal r" "0 \<le> r"
   461   shows "(f has_integral r) UNIV"
   462 using f proof (induct f arbitrary: r rule: borel_measurable_induct_real)
   463   case (set A)
   464   then have "((\<lambda>x. 1) has_integral measure lborel A) A"
   465     by (intro has_integral_measure_lborel) (auto simp: ennreal_indicator)
   466   with set show ?case
   467     by (simp add: ennreal_indicator measure_def) (simp add: indicator_def)
   468 next
   469   case (mult g c)
   470   then have "ennreal c * (\<integral>\<^sup>+ x. g x \<partial>lborel) = ennreal r"
   471     by (subst nn_integral_cmult[symmetric]) (auto simp: ennreal_mult)
   472   with \<open>0 \<le> r\<close> \<open>0 \<le> c\<close>
   473   obtain r' where "(c = 0 \<and> r = 0) \<or> (0 \<le> r' \<and> (\<integral>\<^sup>+ x. ennreal (g x) \<partial>lborel) = ennreal r' \<and> r = c * r')"
   474     by (cases "\<integral>\<^sup>+ x. ennreal (g x) \<partial>lborel" rule: ennreal_cases)
   475        (auto split: if_split_asm simp: ennreal_mult_top ennreal_mult[symmetric])
   476   with mult show ?case
   477     by (auto intro!: has_integral_cmult_real)
   478 next
   479   case (add g h)
   480   then have "(\<integral>\<^sup>+ x. h x + g x \<partial>lborel) = (\<integral>\<^sup>+ x. h x \<partial>lborel) + (\<integral>\<^sup>+ x. g x \<partial>lborel)"
   481     by (simp add: nn_integral_add)
   482   with add obtain a b where "0 \<le> a" "0 \<le> b" "(\<integral>\<^sup>+ x. h x \<partial>lborel) = ennreal a" "(\<integral>\<^sup>+ x. g x \<partial>lborel) = ennreal b" "r = a + b"
   483     by (cases "\<integral>\<^sup>+ x. h x \<partial>lborel" "\<integral>\<^sup>+ x. g x \<partial>lborel" rule: ennreal2_cases)
   484        (auto simp: add_top nn_integral_add top_add simp flip: ennreal_plus)
   485   with add show ?case
   486     by (auto intro!: has_integral_add)
   487 next
   488   case (seq U)
   489   note seq(1)[measurable] and f[measurable]
   490 
   491   { fix i x
   492     have "U i x \<le> f x"
   493       using seq(5)
   494       apply (rule LIMSEQ_le_const)
   495       using seq(4)
   496       apply (auto intro!: exI[of _ i] simp: incseq_def le_fun_def)
   497       done }
   498   note U_le_f = this
   499 
   500   { fix i
   501     have "(\<integral>\<^sup>+x. U i x \<partial>lborel) \<le> (\<integral>\<^sup>+x. f x \<partial>lborel)"
   502       using seq(2) f(2) U_le_f by (intro nn_integral_mono) simp
   503     then obtain p where "(\<integral>\<^sup>+x. U i x \<partial>lborel) = ennreal p" "p \<le> r" "0 \<le> p"
   504       using seq(6) \<open>0\<le>r\<close> by (cases "\<integral>\<^sup>+x. U i x \<partial>lborel" rule: ennreal_cases) (auto simp: top_unique)
   505     moreover note seq
   506     ultimately have "\<exists>p. (\<integral>\<^sup>+x. U i x \<partial>lborel) = ennreal p \<and> 0 \<le> p \<and> p \<le> r \<and> (U i has_integral p) UNIV"
   507       by auto }
   508   then obtain p where p: "\<And>i. (\<integral>\<^sup>+x. ennreal (U i x) \<partial>lborel) = ennreal (p i)"
   509     and bnd: "\<And>i. p i \<le> r" "\<And>i. 0 \<le> p i"
   510     and U_int: "\<And>i.(U i has_integral (p i)) UNIV" by metis
   511 
   512   have int_eq: "\<And>i. integral UNIV (U i) = p i" using U_int by (rule integral_unique)
   513 
   514   have *: "f integrable_on UNIV \<and> (\<lambda>k. integral UNIV (U k)) \<longlonglongrightarrow> integral UNIV f"
   515   proof (rule monotone_convergence_increasing)
   516     show "\<And>k. U k integrable_on UNIV" using U_int by auto
   517     show "\<And>k x. x\<in>UNIV \<Longrightarrow> U k x \<le> U (Suc k) x" using \<open>incseq U\<close> by (auto simp: incseq_def le_fun_def)
   518     then show "bounded (range (\<lambda>k. integral UNIV (U k)))"
   519       using bnd int_eq by (auto simp: bounded_real intro!: exI[of _ r])
   520     show "\<And>x. x\<in>UNIV \<Longrightarrow> (\<lambda>k. U k x) \<longlonglongrightarrow> f x"
   521       using seq by auto
   522   qed
   523   moreover have "(\<lambda>i. (\<integral>\<^sup>+x. U i x \<partial>lborel)) \<longlonglongrightarrow> (\<integral>\<^sup>+x. f x \<partial>lborel)"
   524     using seq f(2) U_le_f by (intro nn_integral_dominated_convergence[where w=f]) auto
   525   ultimately have "integral UNIV f = r"
   526     by (auto simp add: bnd int_eq p seq intro: LIMSEQ_unique)
   527   with * show ?case
   528     by (simp add: has_integral_integral)
   529 qed
   530 
   531 lemma nn_integral_lborel_eq_integral:
   532   fixes f::"'a::euclidean_space \<Rightarrow> real"
   533   assumes f: "f \<in> borel_measurable borel" "\<And>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>lborel) < \<infinity>"
   534   shows "(\<integral>\<^sup>+x. f x \<partial>lborel) = integral UNIV f"
   535 proof -
   536   from f(3) obtain r where r: "(\<integral>\<^sup>+x. f x \<partial>lborel) = ennreal r" "0 \<le> r"
   537     by (cases "\<integral>\<^sup>+x. f x \<partial>lborel" rule: ennreal_cases) auto
   538   then show ?thesis
   539     using nn_integral_has_integral[OF f(1,2) r] by (simp add: integral_unique)
   540 qed
   541 
   542 lemma nn_integral_integrable_on:
   543   fixes f::"'a::euclidean_space \<Rightarrow> real"
   544   assumes f: "f \<in> borel_measurable borel" "\<And>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>lborel) < \<infinity>"
   545   shows "f integrable_on UNIV"
   546 proof -
   547   from f(3) obtain r where r: "(\<integral>\<^sup>+x. f x \<partial>lborel) = ennreal r" "0 \<le> r"
   548     by (cases "\<integral>\<^sup>+x. f x \<partial>lborel" rule: ennreal_cases) auto
   549   then show ?thesis
   550     by (intro has_integral_integrable[where i=r] nn_integral_has_integral[where r=r] f)
   551 qed
   552 
   553 lemma nn_integral_has_integral_lborel:
   554   fixes f :: "'a::euclidean_space \<Rightarrow> real"
   555   assumes f_borel: "f \<in> borel_measurable borel" and nonneg: "\<And>x. 0 \<le> f x"
   556   assumes I: "(f has_integral I) UNIV"
   557   shows "integral\<^sup>N lborel f = I"
   558 proof -
   559   from f_borel have "(\<lambda>x. ennreal (f x)) \<in> borel_measurable lborel" by auto
   560   from borel_measurable_implies_simple_function_sequence'[OF this] 
   561   obtain F where F: "\<And>i. simple_function lborel (F i)" "incseq F" 
   562                  "\<And>i x. F i x < top" "\<And>x. (SUP i. F i x) = ennreal (f x)"
   563     by blast
   564   then have [measurable]: "\<And>i. F i \<in> borel_measurable lborel"
   565     by (metis borel_measurable_simple_function)
   566   let ?B = "\<lambda>i::nat. box (- (real i *\<^sub>R One)) (real i *\<^sub>R One) :: 'a set"
   567 
   568   have "0 \<le> I"
   569     using I by (rule has_integral_nonneg) (simp add: nonneg)
   570 
   571   have F_le_f: "enn2real (F i x) \<le> f x" for i x
   572     using F(3,4)[where x=x] nonneg SUP_upper[of i UNIV "\<lambda>i. F i x"]
   573     by (cases "F i x" rule: ennreal_cases) auto
   574   let ?F = "\<lambda>i x. F i x * indicator (?B i) x"
   575   have "(\<integral>\<^sup>+ x. ennreal (f x) \<partial>lborel) = (SUP i. integral\<^sup>N lborel (\<lambda>x. ?F i x))"
   576   proof (subst nn_integral_monotone_convergence_SUP[symmetric])
   577     { fix x
   578       obtain j where j: "x \<in> ?B j"
   579         using UN_box_eq_UNIV by auto
   580 
   581       have "ennreal (f x) = (SUP i. F i x)"
   582         using F(4)[of x] nonneg[of x] by (simp add: max_def)
   583       also have "\<dots> = (SUP i. ?F i x)"
   584       proof (rule SUP_eq)
   585         fix i show "\<exists>j\<in>UNIV. F i x \<le> ?F j x"
   586           using j F(2)
   587           by (intro bexI[of _ "max i j"])
   588              (auto split: split_max split_indicator simp: incseq_def le_fun_def box_def)
   589       qed (auto intro!: F split: split_indicator)
   590       finally have "ennreal (f x) =  (SUP i. ?F i x)" . }
   591     then show "(\<integral>\<^sup>+ x. ennreal (f x) \<partial>lborel) = (\<integral>\<^sup>+ x. (SUP i. ?F i x) \<partial>lborel)"
   592       by simp
   593   qed (insert F, auto simp: incseq_def le_fun_def box_def split: split_indicator)
   594   also have "\<dots> \<le> ennreal I"
   595   proof (rule SUP_least)
   596     fix i :: nat
   597     have finite_F: "(\<integral>\<^sup>+ x. ennreal (enn2real (F i x) * indicator (?B i) x) \<partial>lborel) < \<infinity>"
   598     proof (rule nn_integral_bound_simple_function)
   599       have "emeasure lborel {x \<in> space lborel. ennreal (enn2real (F i x) * indicator (?B i) x) \<noteq> 0} \<le>
   600         emeasure lborel (?B i)"
   601         by (intro emeasure_mono)  (auto split: split_indicator)
   602       then show "emeasure lborel {x \<in> space lborel. ennreal (enn2real (F i x) * indicator (?B i) x) \<noteq> 0} < \<infinity>"
   603         by (auto simp: less_top[symmetric] top_unique)
   604     qed (auto split: split_indicator
   605               intro!: F simple_function_compose1[where g="enn2real"] simple_function_ennreal)
   606 
   607     have int_F: "(\<lambda>x. enn2real (F i x) * indicator (?B i) x) integrable_on UNIV"
   608       using F(4) finite_F
   609       by (intro nn_integral_integrable_on) (auto split: split_indicator simp: enn2real_nonneg)
   610 
   611     have "(\<integral>\<^sup>+ x. F i x * indicator (?B i) x \<partial>lborel) =
   612       (\<integral>\<^sup>+ x. ennreal (enn2real (F i x) * indicator (?B i) x) \<partial>lborel)"
   613       using F(3,4)
   614       by (intro nn_integral_cong) (auto simp: image_iff eq_commute split: split_indicator)
   615     also have "\<dots> = ennreal (integral UNIV (\<lambda>x. enn2real (F i x) * indicator (?B i) x))"
   616       using F
   617       by (intro nn_integral_lborel_eq_integral[OF _ _ finite_F])
   618          (auto split: split_indicator intro: enn2real_nonneg)
   619     also have "\<dots> \<le> ennreal I"
   620       by (auto intro!: has_integral_le[OF integrable_integral[OF int_F] I] nonneg F_le_f
   621                simp: \<open>0 \<le> I\<close> split: split_indicator )
   622     finally show "(\<integral>\<^sup>+ x. F i x * indicator (?B i) x \<partial>lborel) \<le> ennreal I" .
   623   qed
   624   finally have "(\<integral>\<^sup>+ x. ennreal (f x) \<partial>lborel) < \<infinity>"
   625     by (auto simp: less_top[symmetric] top_unique)
   626   from nn_integral_lborel_eq_integral[OF assms(1,2) this] I show ?thesis
   627     by (simp add: integral_unique)
   628 qed
   629 
   630 lemma has_integral_iff_emeasure_lborel:
   631   fixes A :: "'a::euclidean_space set"
   632   assumes A[measurable]: "A \<in> sets borel" and [simp]: "0 \<le> r"
   633   shows "((\<lambda>x. 1) has_integral r) A \<longleftrightarrow> emeasure lborel A = ennreal r"
   634 proof (cases "emeasure lborel A = \<infinity>")
   635   case emeasure_A: True
   636   have "\<not> (\<lambda>x. 1::real) integrable_on A"
   637   proof
   638     assume int: "(\<lambda>x. 1::real) integrable_on A"
   639     then have "(indicator A::'a \<Rightarrow> real) integrable_on UNIV"
   640       unfolding indicator_def[abs_def] integrable_restrict_UNIV .
   641     then obtain r where "((indicator A::'a\<Rightarrow>real) has_integral r) UNIV"
   642       by auto
   643     from nn_integral_has_integral_lborel[OF _ _ this] emeasure_A show False
   644       by (simp add: ennreal_indicator)
   645   qed
   646   with emeasure_A show ?thesis
   647     by auto
   648 next
   649   case False
   650   then have "((\<lambda>x. 1) has_integral measure lborel A) A"
   651     by (simp add: has_integral_measure_lborel less_top)
   652   with False show ?thesis
   653     by (auto simp: emeasure_eq_ennreal_measure has_integral_unique)
   654 qed
   655 
   656 lemma ennreal_max_0: "ennreal (max 0 x) = ennreal x"
   657   by (auto simp: max_def ennreal_neg)
   658 
   659 lemma has_integral_integral_real:
   660   fixes f::"'a::euclidean_space \<Rightarrow> real"
   661   assumes f: "integrable lborel f"
   662   shows "(f has_integral (integral\<^sup>L lborel f)) UNIV"
   663 proof -
   664   from integrableE[OF f] obtain r q
   665     where "0 \<le> r" "0 \<le> q"
   666       and r: "(\<integral>\<^sup>+ x. ennreal (max 0 (f x)) \<partial>lborel) = ennreal r"
   667       and q: "(\<integral>\<^sup>+ x. ennreal (max 0 (- f x)) \<partial>lborel) = ennreal q"
   668       and f: "f \<in> borel_measurable lborel" and eq: "integral\<^sup>L lborel f = r - q"
   669     unfolding ennreal_max_0 by auto
   670   then have "((\<lambda>x. max 0 (f x)) has_integral r) UNIV" "((\<lambda>x. max 0 (- f x)) has_integral q) UNIV"
   671     using nn_integral_has_integral[OF _ _ r] nn_integral_has_integral[OF _ _ q] by auto
   672   note has_integral_diff[OF this]
   673   moreover have "(\<lambda>x. max 0 (f x) - max 0 (- f x)) = f"
   674     by auto
   675   ultimately show ?thesis
   676     by (simp add: eq)
   677 qed
   678 
   679 lemma has_integral_AE:
   680   assumes ae: "AE x in lborel. x \<in> \<Omega> \<longrightarrow> f x = g x"
   681   shows "(f has_integral x) \<Omega> = (g has_integral x) \<Omega>"
   682 proof -
   683   from ae obtain N
   684     where N: "N \<in> sets borel" "emeasure lborel N = 0" "{x. \<not> (x \<in> \<Omega> \<longrightarrow> f x = g x)} \<subseteq> N"
   685     by (auto elim!: AE_E)
   686   then have not_N: "AE x in lborel. x \<notin> N"
   687     by (simp add: AE_iff_measurable)
   688   show ?thesis
   689   proof (rule has_integral_spike_eq[symmetric])
   690     show "\<And>x. x\<in>\<Omega> - N \<Longrightarrow> f x = g x" using N(3) by auto
   691     show "negligible N"
   692       unfolding negligible_def
   693     proof (intro allI)
   694       fix a b :: "'a"
   695       let ?F = "\<lambda>x::'a. if x \<in> cbox a b then indicator N x else 0 :: real"
   696       have "integrable lborel ?F = integrable lborel (\<lambda>x::'a. 0::real)"
   697         using not_N N(1) by (intro integrable_cong_AE) auto
   698       moreover have "(LINT x|lborel. ?F x) = (LINT x::'a|lborel. 0::real)"
   699         using not_N N(1) by (intro integral_cong_AE) auto
   700       ultimately have "(?F has_integral 0) UNIV"
   701         using has_integral_integral_real[of ?F] by simp
   702       then show "(indicator N has_integral (0::real)) (cbox a b)"
   703         unfolding has_integral_restrict_UNIV .
   704     qed
   705   qed
   706 qed
   707 
   708 lemma nn_integral_has_integral_lebesgue:
   709   fixes f :: "'a::euclidean_space \<Rightarrow> real"
   710   assumes nonneg: "\<And>x. 0 \<le> f x" and I: "(f has_integral I) \<Omega>"
   711   shows "integral\<^sup>N lborel (\<lambda>x. indicator \<Omega> x * f x) = I"
   712 proof -
   713   from I have "(\<lambda>x. indicator \<Omega> x *\<^sub>R f x) \<in> lebesgue \<rightarrow>\<^sub>M borel"
   714     by (rule has_integral_implies_lebesgue_measurable)
   715   then obtain f' :: "'a \<Rightarrow> real"
   716     where [measurable]: "f' \<in> borel \<rightarrow>\<^sub>M borel" and eq: "AE x in lborel. indicator \<Omega> x * f x = f' x"
   717     by (auto dest: completion_ex_borel_measurable_real)
   718 
   719   from I have "((\<lambda>x. abs (indicator \<Omega> x * f x)) has_integral I) UNIV"
   720     using nonneg by (simp add: indicator_def if_distrib[of "\<lambda>x. x * f y" for y] cong: if_cong)
   721   also have "((\<lambda>x. abs (indicator \<Omega> x * f x)) has_integral I) UNIV \<longleftrightarrow> ((\<lambda>x. abs (f' x)) has_integral I) UNIV"
   722     using eq by (intro has_integral_AE) auto
   723   finally have "integral\<^sup>N lborel (\<lambda>x. abs (f' x)) = I"
   724     by (rule nn_integral_has_integral_lborel[rotated 2]) auto
   725   also have "integral\<^sup>N lborel (\<lambda>x. abs (f' x)) = integral\<^sup>N lborel (\<lambda>x. abs (indicator \<Omega> x * f x))"
   726     using eq by (intro nn_integral_cong_AE) auto
   727   finally show ?thesis
   728     using nonneg by auto
   729 qed
   730 
   731 lemma has_integral_iff_nn_integral_lebesgue:
   732   assumes f: "\<And>x. 0 \<le> f x"
   733   shows "(f has_integral r) UNIV \<longleftrightarrow> (f \<in> lebesgue \<rightarrow>\<^sub>M borel \<and> integral\<^sup>N lebesgue f = r \<and> 0 \<le> r)" (is "?I = ?N")
   734 proof
   735   assume ?I
   736   have "0 \<le> r"
   737     using has_integral_nonneg[OF \<open>?I\<close>] f by auto
   738   then show ?N
   739     using nn_integral_has_integral_lebesgue[OF f \<open>?I\<close>]
   740       has_integral_implies_lebesgue_measurable[OF \<open>?I\<close>]
   741     by (auto simp: nn_integral_completion)
   742 next
   743   assume ?N
   744   then obtain f' where f': "f' \<in> borel \<rightarrow>\<^sub>M borel" "AE x in lborel. f x = f' x"
   745     by (auto dest: completion_ex_borel_measurable_real)
   746   moreover have "(\<integral>\<^sup>+ x. ennreal \<bar>f' x\<bar> \<partial>lborel) = (\<integral>\<^sup>+ x. ennreal \<bar>f x\<bar> \<partial>lborel)"
   747     using f' by (intro nn_integral_cong_AE) auto
   748   moreover have "((\<lambda>x. \<bar>f' x\<bar>) has_integral r) UNIV \<longleftrightarrow> ((\<lambda>x. \<bar>f x\<bar>) has_integral r) UNIV"
   749     using f' by (intro has_integral_AE) auto
   750   moreover note nn_integral_has_integral[of "\<lambda>x. \<bar>f' x\<bar>" r] \<open>?N\<close>
   751   ultimately show ?I
   752     using f by (auto simp: nn_integral_completion)
   753 qed
   754 
   755 context
   756   fixes f::"'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   757 begin
   758 
   759 lemma has_integral_integral_lborel:
   760   assumes f: "integrable lborel f"
   761   shows "(f has_integral (integral\<^sup>L lborel f)) UNIV"
   762 proof -
   763   have "((\<lambda>x. \<Sum>b\<in>Basis. (f x \<bullet> b) *\<^sub>R b) has_integral (\<Sum>b\<in>Basis. integral\<^sup>L lborel (\<lambda>x. f x \<bullet> b) *\<^sub>R b)) UNIV"
   764     using f by (intro has_integral_sum finite_Basis ballI has_integral_scaleR_left has_integral_integral_real) auto
   765   also have eq_f: "(\<lambda>x. \<Sum>b\<in>Basis. (f x \<bullet> b) *\<^sub>R b) = f"
   766     by (simp add: fun_eq_iff euclidean_representation)
   767   also have "(\<Sum>b\<in>Basis. integral\<^sup>L lborel (\<lambda>x. f x \<bullet> b) *\<^sub>R b) = integral\<^sup>L lborel f"
   768     using f by (subst (2) eq_f[symmetric]) simp
   769   finally show ?thesis .
   770 qed
   771 
   772 lemma integrable_on_lborel: "integrable lborel f \<Longrightarrow> f integrable_on UNIV"
   773   using has_integral_integral_lborel by auto
   774 
   775 lemma integral_lborel: "integrable lborel f \<Longrightarrow> integral UNIV f = (\<integral>x. f x \<partial>lborel)"
   776   using has_integral_integral_lborel by auto
   777 
   778 end
   779 
   780 context
   781 begin
   782 
   783 private lemma has_integral_integral_lebesgue_real:
   784   fixes f :: "'a::euclidean_space \<Rightarrow> real"
   785   assumes f: "integrable lebesgue f"
   786   shows "(f has_integral (integral\<^sup>L lebesgue f)) UNIV"
   787 proof -
   788   obtain f' where f': "f' \<in> borel \<rightarrow>\<^sub>M borel" "AE x in lborel. f x = f' x"
   789     using completion_ex_borel_measurable_real[OF borel_measurable_integrable[OF f]] by auto
   790   moreover have "(\<integral>\<^sup>+ x. ennreal (norm (f x)) \<partial>lborel) = (\<integral>\<^sup>+ x. ennreal (norm (f' x)) \<partial>lborel)"
   791     using f' by (intro nn_integral_cong_AE) auto
   792   ultimately have "integrable lborel f'"
   793     using f by (auto simp: integrable_iff_bounded nn_integral_completion cong: nn_integral_cong_AE)
   794   note has_integral_integral_real[OF this]
   795   moreover have "integral\<^sup>L lebesgue f = integral\<^sup>L lebesgue f'"
   796     using f' f by (intro integral_cong_AE) (auto intro: AE_completion measurable_completion)
   797   moreover have "integral\<^sup>L lebesgue f' = integral\<^sup>L lborel f'"
   798     using f' by (simp add: integral_completion)
   799   moreover have "(f' has_integral integral\<^sup>L lborel f') UNIV \<longleftrightarrow> (f has_integral integral\<^sup>L lborel f') UNIV"
   800     using f' by (intro has_integral_AE) auto
   801   ultimately show ?thesis
   802     by auto
   803 qed
   804 
   805 lemma has_integral_integral_lebesgue:
   806   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   807   assumes f: "integrable lebesgue f"
   808   shows "(f has_integral (integral\<^sup>L lebesgue f)) UNIV"
   809 proof -
   810   have "((\<lambda>x. \<Sum>b\<in>Basis. (f x \<bullet> b) *\<^sub>R b) has_integral (\<Sum>b\<in>Basis. integral\<^sup>L lebesgue (\<lambda>x. f x \<bullet> b) *\<^sub>R b)) UNIV"
   811     using f by (intro has_integral_sum finite_Basis ballI has_integral_scaleR_left has_integral_integral_lebesgue_real) auto
   812   also have eq_f: "(\<lambda>x. \<Sum>b\<in>Basis. (f x \<bullet> b) *\<^sub>R b) = f"
   813     by (simp add: fun_eq_iff euclidean_representation)
   814   also have "(\<Sum>b\<in>Basis. integral\<^sup>L lebesgue (\<lambda>x. f x \<bullet> b) *\<^sub>R b) = integral\<^sup>L lebesgue f"
   815     using f by (subst (2) eq_f[symmetric]) simp
   816   finally show ?thesis .
   817 qed
   818 
   819 lemma integrable_on_lebesgue:
   820   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   821   shows "integrable lebesgue f \<Longrightarrow> f integrable_on UNIV"
   822   using has_integral_integral_lebesgue by auto
   823 
   824 lemma integral_lebesgue:
   825   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   826   shows "integrable lebesgue f \<Longrightarrow> integral UNIV f = (\<integral>x. f x \<partial>lebesgue)"
   827   using has_integral_integral_lebesgue by auto
   828 
   829 end
   830 
   831 subsection \<open>Absolute integrability (this is the same as Lebesgue integrability)\<close>
   832 
   833 translations
   834 "LBINT x. f" == "CONST lebesgue_integral CONST lborel (\<lambda>x. f)"
   835 
   836 translations
   837 "LBINT x:A. f" == "CONST set_lebesgue_integral CONST lborel A (\<lambda>x. f)"
   838 
   839 lemma set_integral_reflect:
   840   fixes S and f :: "real \<Rightarrow> 'a :: {banach, second_countable_topology}"
   841   shows "(LBINT x : S. f x) = (LBINT x : {x. - x \<in> S}. f (- x))"
   842   unfolding set_lebesgue_integral_def
   843   by (subst lborel_integral_real_affine[where c="-1" and t=0])
   844      (auto intro!: Bochner_Integration.integral_cong split: split_indicator)
   845 
   846 lemma borel_integrable_atLeastAtMost':
   847   fixes f :: "real \<Rightarrow> 'a::{banach, second_countable_topology}"
   848   assumes f: "continuous_on {a..b} f"
   849   shows "set_integrable lborel {a..b} f" 
   850   unfolding set_integrable_def
   851   by (intro borel_integrable_compact compact_Icc f)
   852 
   853 lemma integral_FTC_atLeastAtMost:
   854   fixes f :: "real \<Rightarrow> 'a :: euclidean_space"
   855   assumes "a \<le> b"
   856     and F: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_vector_derivative f x) (at x within {a .. b})"
   857     and f: "continuous_on {a .. b} f"
   858   shows "integral\<^sup>L lborel (\<lambda>x. indicator {a .. b} x *\<^sub>R f x) = F b - F a"
   859 proof -
   860   let ?f = "\<lambda>x. indicator {a .. b} x *\<^sub>R f x"
   861   have "(?f has_integral (\<integral>x. ?f x \<partial>lborel)) UNIV"
   862     using borel_integrable_atLeastAtMost'[OF f]
   863     unfolding set_integrable_def by (rule has_integral_integral_lborel)
   864   moreover
   865   have "(f has_integral F b - F a) {a .. b}"
   866     by (intro fundamental_theorem_of_calculus ballI assms) auto
   867   then have "(?f has_integral F b - F a) {a .. b}"
   868     by (subst has_integral_cong[where g=f]) auto
   869   then have "(?f has_integral F b - F a) UNIV"
   870     by (intro has_integral_on_superset[where T=UNIV and S="{a..b}"]) auto
   871   ultimately show "integral\<^sup>L lborel ?f = F b - F a"
   872     by (rule has_integral_unique)
   873 qed
   874 
   875 lemma set_borel_integral_eq_integral:
   876   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   877   assumes "set_integrable lborel S f"
   878   shows "f integrable_on S" "LINT x : S | lborel. f x = integral S f"
   879 proof -
   880   let ?f = "\<lambda>x. indicator S x *\<^sub>R f x"
   881   have "(?f has_integral LINT x : S | lborel. f x) UNIV"
   882     using assms has_integral_integral_lborel 
   883     unfolding set_integrable_def set_lebesgue_integral_def by blast
   884   hence 1: "(f has_integral (set_lebesgue_integral lborel S f)) S"
   885     apply (subst has_integral_restrict_UNIV [symmetric])
   886     apply (rule has_integral_eq)
   887     by auto
   888   thus "f integrable_on S"
   889     by (auto simp add: integrable_on_def)
   890   with 1 have "(f has_integral (integral S f)) S"
   891     by (intro integrable_integral, auto simp add: integrable_on_def)
   892   thus "LINT x : S | lborel. f x = integral S f"
   893     by (intro has_integral_unique [OF 1])
   894 qed
   895 
   896 lemma has_integral_set_lebesgue:
   897   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   898   assumes f: "set_integrable lebesgue S f"
   899   shows "(f has_integral (LINT x:S|lebesgue. f x)) S"
   900   using has_integral_integral_lebesgue f 
   901   by (fastforce simp add: set_integrable_def set_lebesgue_integral_def indicator_def if_distrib[of "\<lambda>x. x *\<^sub>R f _"] cong: if_cong)
   902 
   903 lemma set_lebesgue_integral_eq_integral:
   904   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   905   assumes f: "set_integrable lebesgue S f"
   906   shows "f integrable_on S" "LINT x:S | lebesgue. f x = integral S f"
   907   using has_integral_set_lebesgue[OF f] by (auto simp: integral_unique integrable_on_def)
   908 
   909 lemma lmeasurable_iff_has_integral:
   910   "S \<in> lmeasurable \<longleftrightarrow> ((indicator S) has_integral measure lebesgue S) UNIV"
   911   by (subst has_integral_iff_nn_integral_lebesgue)
   912      (auto simp: ennreal_indicator emeasure_eq_measure2 borel_measurable_indicator_iff intro!: fmeasurableI)
   913 
   914 abbreviation
   915   absolutely_integrable_on :: "('a::euclidean_space \<Rightarrow> 'b::{banach, second_countable_topology}) \<Rightarrow> 'a set \<Rightarrow> bool"
   916   (infixr "absolutely'_integrable'_on" 46)
   917   where "f absolutely_integrable_on s \<equiv> set_integrable lebesgue s f"
   918 
   919 
   920 lemma absolutely_integrable_zero [simp]: "(\<lambda>x. 0) absolutely_integrable_on S"
   921     by (simp add: set_integrable_def)
   922 
   923 lemma absolutely_integrable_on_def:
   924   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   925   shows "f absolutely_integrable_on S \<longleftrightarrow> f integrable_on S \<and> (\<lambda>x. norm (f x)) integrable_on S"
   926 proof safe
   927   assume f: "f absolutely_integrable_on S"
   928   then have nf: "integrable lebesgue (\<lambda>x. norm (indicator S x *\<^sub>R f x))"
   929     using integrable_norm set_integrable_def by blast
   930   show "f integrable_on S"
   931     by (rule set_lebesgue_integral_eq_integral[OF f])
   932   have "(\<lambda>x. norm (indicator S x *\<^sub>R f x)) = (\<lambda>x. if x \<in> S then norm (f x) else 0)"
   933     by auto
   934   with integrable_on_lebesgue[OF nf] show "(\<lambda>x. norm (f x)) integrable_on S"
   935     by (simp add: integrable_restrict_UNIV)
   936 next
   937   assume f: "f integrable_on S" and nf: "(\<lambda>x. norm (f x)) integrable_on S"
   938   show "f absolutely_integrable_on S"
   939     unfolding set_integrable_def
   940   proof (rule integrableI_bounded)
   941     show "(\<lambda>x. indicator S x *\<^sub>R f x) \<in> borel_measurable lebesgue"
   942       using f has_integral_implies_lebesgue_measurable[of f _ S] by (auto simp: integrable_on_def)
   943     show "(\<integral>\<^sup>+ x. ennreal (norm (indicator S x *\<^sub>R f x)) \<partial>lebesgue) < \<infinity>"
   944       using nf nn_integral_has_integral_lebesgue[of "\<lambda>x. norm (f x)" _ S]
   945       by (auto simp: integrable_on_def nn_integral_completion)
   946   qed
   947 qed
   948 
   949 lemma integrable_on_lebesgue_on:
   950   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   951   assumes f: "integrable (lebesgue_on S) f" and S: "S \<in> sets lebesgue"
   952   shows "f integrable_on S"
   953 proof -
   954   have "integrable lebesgue (\<lambda>x. indicator S x *\<^sub>R f x)"
   955     using S f inf_top.comm_neutral integrable_restrict_space by blast
   956   then show ?thesis
   957     using absolutely_integrable_on_def set_integrable_def by blast
   958 qed
   959 
   960 lemma absolutely_integrable_on_null [intro]:
   961   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   962   shows "content (cbox a b) = 0 \<Longrightarrow> f absolutely_integrable_on (cbox a b)"
   963   by (auto simp: absolutely_integrable_on_def)
   964 
   965 lemma absolutely_integrable_on_open_interval:
   966   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
   967   shows "f absolutely_integrable_on box a b \<longleftrightarrow>
   968          f absolutely_integrable_on cbox a b"
   969   by (auto simp: integrable_on_open_interval absolutely_integrable_on_def)
   970 
   971 lemma absolutely_integrable_restrict_UNIV:
   972   "(\<lambda>x. if x \<in> S then f x else 0) absolutely_integrable_on UNIV \<longleftrightarrow> f absolutely_integrable_on S"
   973     unfolding set_integrable_def
   974   by (intro arg_cong2[where f=integrable]) auto
   975 
   976 lemma absolutely_integrable_onI:
   977   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
   978   shows "f integrable_on S \<Longrightarrow> (\<lambda>x. norm (f x)) integrable_on S \<Longrightarrow> f absolutely_integrable_on S"
   979   unfolding absolutely_integrable_on_def by auto
   980 
   981 lemma nonnegative_absolutely_integrable_1:
   982   fixes f :: "'a :: euclidean_space \<Rightarrow> real"
   983   assumes f: "f integrable_on A" and "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x"
   984   shows "f absolutely_integrable_on A"
   985   by (rule absolutely_integrable_onI [OF f]) (use assms in \<open>simp add: integrable_eq\<close>)
   986 
   987 lemma absolutely_integrable_on_iff_nonneg:
   988   fixes f :: "'a :: euclidean_space \<Rightarrow> real"
   989   assumes "\<And>x. x \<in> S \<Longrightarrow> 0 \<le> f x" shows "f absolutely_integrable_on S \<longleftrightarrow> f integrable_on S"
   990 proof -
   991   { assume "f integrable_on S"
   992     then have "(\<lambda>x. if x \<in> S then f x else 0) integrable_on UNIV"
   993       by (simp add: integrable_restrict_UNIV)
   994     then have "(\<lambda>x. if x \<in> S then f x else 0) absolutely_integrable_on UNIV"
   995       using \<open>f integrable_on S\<close> absolutely_integrable_restrict_UNIV assms nonnegative_absolutely_integrable_1 by blast
   996     then have "f absolutely_integrable_on S"
   997       using absolutely_integrable_restrict_UNIV by blast
   998   }
   999   then show ?thesis        
  1000     unfolding absolutely_integrable_on_def by auto
  1001 qed
  1002 
  1003 lemma absolutely_integrable_on_scaleR_iff:
  1004   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1005   shows
  1006    "(\<lambda>x. c *\<^sub>R f x) absolutely_integrable_on S \<longleftrightarrow>
  1007       c = 0 \<or> f absolutely_integrable_on S"
  1008 proof (cases "c=0")
  1009   case False
  1010   then show ?thesis
  1011   unfolding absolutely_integrable_on_def 
  1012   by (simp add: norm_mult)
  1013 qed auto
  1014 
  1015 lemma absolutely_integrable_spike:
  1016   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1017   assumes "f absolutely_integrable_on T" and S: "negligible S" "\<And>x. x \<in> T - S \<Longrightarrow> g x = f x"
  1018   shows "g absolutely_integrable_on T"
  1019   using assms integrable_spike
  1020   unfolding absolutely_integrable_on_def by metis
  1021 
  1022 lemma absolutely_integrable_negligible:
  1023   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1024   assumes "negligible S"
  1025   shows "f absolutely_integrable_on S"
  1026   using assms by (simp add: absolutely_integrable_on_def integrable_negligible)
  1027 
  1028 lemma absolutely_integrable_spike_eq:
  1029   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1030   assumes "negligible S" "\<And>x. x \<in> T - S \<Longrightarrow> g x = f x"
  1031   shows "(f absolutely_integrable_on T \<longleftrightarrow> g absolutely_integrable_on T)"
  1032   using assms by (blast intro: absolutely_integrable_spike sym)
  1033 
  1034 lemma absolutely_integrable_spike_set_eq:
  1035   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1036   assumes "negligible {x \<in> S - T. f x \<noteq> 0}" "negligible {x \<in> T - S. f x \<noteq> 0}"
  1037   shows "(f absolutely_integrable_on S \<longleftrightarrow> f absolutely_integrable_on T)"
  1038 proof -
  1039   have "(\<lambda>x. if x \<in> S then f x else 0) absolutely_integrable_on UNIV \<longleftrightarrow>
  1040         (\<lambda>x. if x \<in> T then f x else 0) absolutely_integrable_on UNIV"
  1041   proof (rule absolutely_integrable_spike_eq)
  1042     show "negligible ({x \<in> S - T. f x \<noteq> 0} \<union> {x \<in> T - S. f x \<noteq> 0})"
  1043       by (rule negligible_Un [OF assms])
  1044   qed auto
  1045   with absolutely_integrable_restrict_UNIV show ?thesis
  1046     by blast
  1047 qed
  1048 
  1049 lemma absolutely_integrable_spike_set:
  1050   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1051   assumes f: "f absolutely_integrable_on S" and neg: "negligible {x \<in> S - T. f x \<noteq> 0}" "negligible {x \<in> T - S. f x \<noteq> 0}"
  1052   shows "f absolutely_integrable_on T"
  1053   using absolutely_integrable_spike_set_eq f neg by blast
  1054 
  1055 lemma lmeasurable_iff_integrable_on: "S \<in> lmeasurable \<longleftrightarrow> (\<lambda>x. 1::real) integrable_on S"
  1056   by (subst absolutely_integrable_on_iff_nonneg[symmetric])
  1057      (simp_all add: lmeasurable_iff_integrable set_integrable_def)
  1058 
  1059 lemma lmeasure_integral_UNIV: "S \<in> lmeasurable \<Longrightarrow> measure lebesgue S = integral UNIV (indicator S)"
  1060   by (simp add: lmeasurable_iff_has_integral integral_unique)
  1061 
  1062 lemma lmeasure_integral: "S \<in> lmeasurable \<Longrightarrow> measure lebesgue S = integral S (\<lambda>x. 1::real)"
  1063   by (fastforce simp add: lmeasure_integral_UNIV indicator_def[abs_def] lmeasurable_iff_integrable_on)
  1064 
  1065 lemma integrable_on_const: "S \<in> lmeasurable \<Longrightarrow> (\<lambda>x. c) integrable_on S"
  1066   unfolding lmeasurable_iff_integrable
  1067   by (metis (mono_tags, lifting) integrable_eq integrable_on_scaleR_left lmeasurable_iff_integrable lmeasurable_iff_integrable_on scaleR_one)
  1068 
  1069 lemma integral_indicator:
  1070   assumes "(S \<inter> T) \<in> lmeasurable"
  1071   shows "integral T (indicator S) = measure lebesgue (S \<inter> T)"
  1072 proof -
  1073   have "integral UNIV (indicator (S \<inter> T)) = integral UNIV (\<lambda>a. if a \<in> S \<inter> T then 1::real else 0)"
  1074     by (meson indicator_def)
  1075   moreover
  1076   have "(indicator (S \<inter> T) has_integral measure lebesgue (S \<inter> T)) UNIV"
  1077     using assms by (simp add: lmeasurable_iff_has_integral)
  1078   ultimately have "integral UNIV (\<lambda>x. if x \<in> S \<inter> T then 1 else 0) = measure lebesgue (S \<inter> T)"
  1079     by (metis (no_types) integral_unique)
  1080   then show ?thesis
  1081     using integral_restrict_Int [of UNIV "S \<inter> T" "\<lambda>x. 1::real"]
  1082     apply (simp add: integral_restrict_Int [symmetric])
  1083     by (meson indicator_def)
  1084 qed
  1085 
  1086 lemma measurable_integrable:
  1087   fixes S :: "'a::euclidean_space set"
  1088   shows "S \<in> lmeasurable \<longleftrightarrow> (indicat_real S) integrable_on UNIV"
  1089   by (auto simp: lmeasurable_iff_integrable absolutely_integrable_on_iff_nonneg [symmetric] set_integrable_def)
  1090 
  1091 lemma integrable_on_indicator:
  1092   fixes S :: "'a::euclidean_space set"
  1093   shows "indicat_real S integrable_on T \<longleftrightarrow> (S \<inter> T) \<in> lmeasurable"
  1094   unfolding measurable_integrable
  1095   unfolding integrable_restrict_UNIV [of T, symmetric]
  1096   by (fastforce simp add: indicator_def elim: integrable_eq)
  1097 
  1098 lemma
  1099   assumes \<D>: "\<D> division_of S"
  1100   shows lmeasurable_division: "S \<in> lmeasurable" (is ?l)
  1101     and content_division: "(\<Sum>k\<in>\<D>. measure lebesgue k) = measure lebesgue S" (is ?m)
  1102 proof -
  1103   { fix d1 d2 assume *: "d1 \<in> \<D>" "d2 \<in> \<D>" "d1 \<noteq> d2"
  1104     then obtain a b c d where "d1 = cbox a b" "d2 = cbox c d"
  1105       using division_ofD(4)[OF \<D>] by blast
  1106     with division_ofD(5)[OF \<D> *]
  1107     have "d1 \<in> sets lborel" "d2 \<in> sets lborel" "d1 \<inter> d2 \<subseteq> (cbox a b - box a b) \<union> (cbox c d - box c d)"
  1108       by auto
  1109     moreover have "(cbox a b - box a b) \<union> (cbox c d - box c d) \<in> null_sets lborel"
  1110       by (intro null_sets.Un null_sets_cbox_Diff_box)
  1111     ultimately have "d1 \<inter> d2 \<in> null_sets lborel"
  1112       by (blast intro: null_sets_subset) }
  1113   then show ?l ?m
  1114     unfolding division_ofD(6)[OF \<D>, symmetric]
  1115     using division_ofD(1,4)[OF \<D>]
  1116     by (auto intro!: measure_Union_AE[symmetric] simp: completion.AE_iff_null_sets Int_def[symmetric] pairwise_def null_sets_def)
  1117 qed
  1118 
  1119 lemma has_measure_limit:
  1120   assumes "S \<in> lmeasurable" "e > 0"
  1121   obtains B where "B > 0"
  1122     "\<And>a b. ball 0 B \<subseteq> cbox a b \<Longrightarrow> \<bar>measure lebesgue (S \<inter> cbox a b) - measure lebesgue S\<bar> < e"
  1123   using assms unfolding lmeasurable_iff_has_integral has_integral_alt'
  1124   by (force simp: integral_indicator integrable_on_indicator)
  1125 
  1126 lemma lmeasurable_iff_indicator_has_integral:
  1127   fixes S :: "'a::euclidean_space set"
  1128   shows "S \<in> lmeasurable \<and> m = measure lebesgue S \<longleftrightarrow> (indicat_real S has_integral m) UNIV"
  1129   by (metis has_integral_iff lmeasurable_iff_has_integral measurable_integrable)
  1130 
  1131 lemma has_measure_limit_iff:
  1132   fixes f :: "'n::euclidean_space \<Rightarrow> 'a::banach"
  1133   shows "S \<in> lmeasurable \<and> m = measure lebesgue S \<longleftrightarrow>
  1134           (\<forall>e>0. \<exists>B>0. \<forall>a b. ball 0 B \<subseteq> cbox a b \<longrightarrow>
  1135             (S \<inter> cbox a b) \<in> lmeasurable \<and> \<bar>measure lebesgue (S \<inter> cbox a b) - m\<bar> < e)" (is "?lhs = ?rhs")
  1136 proof
  1137   assume ?lhs then show ?rhs
  1138     by (meson has_measure_limit fmeasurable.Int lmeasurable_cbox)
  1139 next
  1140   assume RHS [rule_format]: ?rhs
  1141   show ?lhs
  1142     apply (simp add: lmeasurable_iff_indicator_has_integral has_integral' [where i=m])
  1143     using RHS
  1144     by (metis (full_types) integral_indicator integrable_integral integrable_on_indicator)
  1145 qed
  1146 
  1147 subsection\<open>Applications to Negligibility\<close>
  1148 
  1149 lemma negligible_iff_null_sets: "negligible S \<longleftrightarrow> S \<in> null_sets lebesgue"
  1150 proof
  1151   assume "negligible S"
  1152   then have "(indicator S has_integral (0::real)) UNIV"
  1153     by (auto simp: negligible)
  1154   then show "S \<in> null_sets lebesgue"
  1155     by (subst (asm) has_integral_iff_nn_integral_lebesgue)
  1156         (auto simp: borel_measurable_indicator_iff nn_integral_0_iff_AE AE_iff_null_sets indicator_eq_0_iff)
  1157 next
  1158   assume S: "S \<in> null_sets lebesgue"
  1159   show "negligible S"
  1160     unfolding negligible_def
  1161   proof (safe intro!: has_integral_iff_nn_integral_lebesgue[THEN iffD2]
  1162                       has_integral_restrict_UNIV[where s="cbox _ _", THEN iffD1])
  1163     fix a b
  1164     show "(\<lambda>x. if x \<in> cbox a b then indicator S x else 0) \<in> lebesgue \<rightarrow>\<^sub>M borel"
  1165       using S by (auto intro!: measurable_If)
  1166     then show "(\<integral>\<^sup>+ x. ennreal (if x \<in> cbox a b then indicator S x else 0) \<partial>lebesgue) = ennreal 0"
  1167       using S[THEN AE_not_in] by (auto intro!: nn_integral_0_iff_AE[THEN iffD2])
  1168   qed auto
  1169 qed
  1170 
  1171 lemma starlike_negligible:
  1172   assumes "closed S"
  1173       and eq1: "\<And>c x. (a + c *\<^sub>R x) \<in> S \<Longrightarrow> 0 \<le> c \<Longrightarrow> a + x \<in> S \<Longrightarrow> c = 1"
  1174     shows "negligible S"
  1175 proof -
  1176   have "negligible ((+) (-a) ` S)"
  1177   proof (subst negligible_on_intervals, intro allI)
  1178     fix u v
  1179     show "negligible ((+) (- a) ` S \<inter> cbox u v)"
  1180       using \<open>closed S\<close> eq1 by (auto simp add: negligible_iff_null_sets field_simps
  1181         intro!: closed_translation_subtract starlike_negligible_compact cong: image_cong_simp)
  1182   qed
  1183   then show ?thesis
  1184     by (rule negligible_translation_rev)
  1185 qed
  1186 
  1187 lemma starlike_negligible_strong:
  1188   assumes "closed S"
  1189       and star: "\<And>c x. \<lbrakk>0 \<le> c; c < 1; a+x \<in> S\<rbrakk> \<Longrightarrow> a + c *\<^sub>R x \<notin> S"
  1190     shows "negligible S"
  1191 proof -
  1192   show ?thesis
  1193   proof (rule starlike_negligible [OF \<open>closed S\<close>, of a])
  1194     fix c x
  1195     assume cx: "a + c *\<^sub>R x \<in> S" "0 \<le> c" "a + x \<in> S"
  1196     with star have "\<not> (c < 1)" by auto
  1197     moreover have "\<not> (c > 1)"
  1198       using star [of "1/c" "c *\<^sub>R x"] cx by force
  1199     ultimately show "c = 1" by arith
  1200   qed
  1201 qed
  1202 
  1203 lemma negligible_hyperplane:
  1204   assumes "a \<noteq> 0 \<or> b \<noteq> 0" shows "negligible {x. a \<bullet> x = b}"
  1205 proof -
  1206   obtain x where x: "a \<bullet> x \<noteq> b"
  1207     using assms
  1208     apply auto
  1209      apply (metis inner_eq_zero_iff inner_zero_right)
  1210     using inner_zero_right by fastforce
  1211   show ?thesis
  1212     apply (rule starlike_negligible [OF closed_hyperplane, of x])
  1213     using x apply (auto simp: algebra_simps)
  1214     done
  1215 qed
  1216 
  1217 lemma negligible_lowdim:
  1218   fixes S :: "'N :: euclidean_space set"
  1219   assumes "dim S < DIM('N)"
  1220     shows "negligible S"
  1221 proof -
  1222   obtain a where "a \<noteq> 0" and a: "span S \<subseteq> {x. a \<bullet> x = 0}"
  1223     using lowdim_subset_hyperplane [OF assms] by blast
  1224   have "negligible (span S)"
  1225     using \<open>a \<noteq> 0\<close> a negligible_hyperplane by (blast intro: negligible_subset)
  1226   then show ?thesis
  1227     using span_base by (blast intro: negligible_subset)
  1228 qed
  1229 
  1230 proposition negligible_convex_frontier:
  1231   fixes S :: "'N :: euclidean_space set"
  1232   assumes "convex S"
  1233     shows "negligible(frontier S)"
  1234 proof -
  1235   have nf: "negligible(frontier S)" if "convex S" "0 \<in> S" for S :: "'N set"
  1236   proof -
  1237     obtain B where "B \<subseteq> S" and indB: "independent B"
  1238                and spanB: "S \<subseteq> span B" and cardB: "card B = dim S"
  1239       by (metis basis_exists)
  1240     consider "dim S < DIM('N)" | "dim S = DIM('N)"
  1241       using dim_subset_UNIV le_eq_less_or_eq by auto
  1242     then show ?thesis
  1243     proof cases
  1244       case 1
  1245       show ?thesis
  1246         by (rule negligible_subset [of "closure S"])
  1247            (simp_all add: frontier_def negligible_lowdim 1)
  1248     next
  1249       case 2
  1250       obtain a where a: "a \<in> interior S"
  1251         apply (rule interior_simplex_nonempty [OF indB])
  1252           apply (simp add: indB independent_finite)
  1253          apply (simp add: cardB 2)
  1254         apply (metis \<open>B \<subseteq> S\<close> \<open>0 \<in> S\<close> \<open>convex S\<close> insert_absorb insert_subset interior_mono subset_hull)
  1255         done
  1256       show ?thesis
  1257       proof (rule starlike_negligible_strong [where a=a])
  1258         fix c::real and x
  1259         have eq: "a + c *\<^sub>R x = (a + x) - (1 - c) *\<^sub>R ((a + x) - a)"
  1260           by (simp add: algebra_simps)
  1261         assume "0 \<le> c" "c < 1" "a + x \<in> frontier S"
  1262         then show "a + c *\<^sub>R x \<notin> frontier S"
  1263           apply (clarsimp simp: frontier_def)
  1264           apply (subst eq)
  1265           apply (rule mem_interior_closure_convex_shrink [OF \<open>convex S\<close> a, of _ "1-c"], auto)
  1266           done
  1267       qed auto
  1268     qed
  1269   qed
  1270   show ?thesis
  1271   proof (cases "S = {}")
  1272     case True then show ?thesis by auto
  1273   next
  1274     case False
  1275     then obtain a where "a \<in> S" by auto
  1276     show ?thesis
  1277       using nf [of "(\<lambda>x. -a + x) ` S"]
  1278       by (metis \<open>a \<in> S\<close> add.left_inverse assms convex_translation_eq frontier_translation
  1279                 image_eqI negligible_translation_rev)
  1280   qed
  1281 qed
  1282 
  1283 corollary negligible_sphere: "negligible (sphere a e)"
  1284   using frontier_cball negligible_convex_frontier convex_cball
  1285   by (blast intro: negligible_subset)
  1286 
  1287 lemma non_negligible_UNIV [simp]: "\<not> negligible UNIV"
  1288   unfolding negligible_iff_null_sets by (auto simp: null_sets_def)
  1289 
  1290 lemma negligible_interval:
  1291   "negligible (cbox a b) \<longleftrightarrow> box a b = {}" "negligible (box a b) \<longleftrightarrow> box a b = {}"
  1292    by (auto simp: negligible_iff_null_sets null_sets_def prod_nonneg inner_diff_left box_eq_empty
  1293                   not_le emeasure_lborel_cbox_eq emeasure_lborel_box_eq
  1294             intro: eq_refl antisym less_imp_le)
  1295 
  1296 proposition open_not_negligible:
  1297   assumes "open S" "S \<noteq> {}"
  1298   shows "\<not> negligible S"
  1299 proof
  1300   assume neg: "negligible S"
  1301   obtain a where "a \<in> S"
  1302     using \<open>S \<noteq> {}\<close> by blast
  1303   then obtain e where "e > 0" "cball a e \<subseteq> S"
  1304     using \<open>open S\<close> open_contains_cball_eq by blast
  1305   let ?p = "a - (e / DIM('a)) *\<^sub>R One" let ?q = "a + (e / DIM('a)) *\<^sub>R One"
  1306   have "cbox ?p ?q \<subseteq> cball a e"
  1307   proof (clarsimp simp: mem_box dist_norm)
  1308     fix x
  1309     assume "\<forall>i\<in>Basis. ?p \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> ?q \<bullet> i"
  1310     then have ax: "\<bar>(a - x) \<bullet> i\<bar> \<le> e / real DIM('a)" if "i \<in> Basis" for i
  1311       using that by (auto simp: algebra_simps)
  1312     have "norm (a - x) \<le> (\<Sum>i\<in>Basis. \<bar>(a - x) \<bullet> i\<bar>)"
  1313       by (rule norm_le_l1)
  1314     also have "\<dots> \<le> DIM('a) * (e / real DIM('a))"
  1315       by (intro sum_bounded_above ax)
  1316     also have "\<dots> = e"
  1317       by simp
  1318     finally show "norm (a - x) \<le> e" .
  1319   qed
  1320   then have "negligible (cbox ?p ?q)"
  1321     by (meson \<open>cball a e \<subseteq> S\<close> neg negligible_subset)
  1322   with \<open>e > 0\<close> show False
  1323     by (simp add: negligible_interval box_eq_empty algebra_simps divide_simps mult_le_0_iff)
  1324 qed
  1325 
  1326 lemma negligible_convex_interior:
  1327    "convex S \<Longrightarrow> (negligible S \<longleftrightarrow> interior S = {})"
  1328   apply safe
  1329   apply (metis interior_subset negligible_subset open_interior open_not_negligible)
  1330    apply (metis Diff_empty closure_subset frontier_def negligible_convex_frontier negligible_subset)
  1331   done
  1332 
  1333 lemma measure_eq_0_null_sets: "S \<in> null_sets M \<Longrightarrow> measure M S = 0"
  1334   by (auto simp: measure_def null_sets_def)
  1335 
  1336 lemma negligible_imp_measure0: "negligible S \<Longrightarrow> measure lebesgue S = 0"
  1337   by (simp add: measure_eq_0_null_sets negligible_iff_null_sets)
  1338 
  1339 lemma negligible_iff_emeasure0: "S \<in> sets lebesgue \<Longrightarrow> (negligible S \<longleftrightarrow> emeasure lebesgue S = 0)"
  1340   by (auto simp: measure_eq_0_null_sets negligible_iff_null_sets)
  1341 
  1342 lemma negligible_iff_measure0: "S \<in> lmeasurable \<Longrightarrow> (negligible S \<longleftrightarrow> measure lebesgue S = 0)"
  1343   apply (auto simp: measure_eq_0_null_sets negligible_iff_null_sets)
  1344   by (metis completion.null_sets_outer subsetI)
  1345 
  1346 lemma negligible_imp_sets: "negligible S \<Longrightarrow> S \<in> sets lebesgue"
  1347   by (simp add: negligible_iff_null_sets null_setsD2)
  1348 
  1349 lemma negligible_imp_measurable: "negligible S \<Longrightarrow> S \<in> lmeasurable"
  1350   by (simp add: fmeasurableI_null_sets negligible_iff_null_sets)
  1351 
  1352 lemma negligible_iff_measure: "negligible S \<longleftrightarrow> S \<in> lmeasurable \<and> measure lebesgue S = 0"
  1353   by (fastforce simp: negligible_iff_measure0 negligible_imp_measurable dest: negligible_imp_measure0)
  1354 
  1355 lemma negligible_outer:
  1356   "negligible S \<longleftrightarrow> (\<forall>e>0. \<exists>T. S \<subseteq> T \<and> T \<in> lmeasurable \<and> measure lebesgue T < e)" (is "_ = ?rhs")
  1357 proof
  1358   assume "negligible S" then show ?rhs
  1359     by (metis negligible_iff_measure order_refl)
  1360 next
  1361   assume ?rhs then show "negligible S"
  1362   by (meson completion.null_sets_outer negligible_iff_null_sets)
  1363 qed
  1364 
  1365 lemma negligible_outer_le:
  1366      "negligible S \<longleftrightarrow> (\<forall>e>0. \<exists>T. S \<subseteq> T \<and> T \<in> lmeasurable \<and> measure lebesgue T \<le> e)" (is "_ = ?rhs")
  1367 proof
  1368   assume "negligible S" then show ?rhs
  1369     by (metis dual_order.strict_implies_order negligible_imp_measurable negligible_imp_measure0 order_refl)
  1370 next
  1371   assume ?rhs then show "negligible S"
  1372     by (metis le_less_trans negligible_outer field_lbound_gt_zero)
  1373 qed
  1374 
  1375 lemma negligible_UNIV: "negligible S \<longleftrightarrow> (indicat_real S has_integral 0) UNIV" (is "_=?rhs")
  1376 proof
  1377   assume ?rhs
  1378   then show "negligible S"
  1379     apply (auto simp: negligible_def has_integral_iff integrable_on_indicator)
  1380     by (metis negligible integral_unique lmeasure_integral_UNIV negligible_iff_measure0)
  1381 qed (simp add: negligible)
  1382 
  1383 lemma sets_negligible_symdiff:
  1384    "\<lbrakk>S \<in> sets lebesgue; negligible((S - T) \<union> (T - S))\<rbrakk> \<Longrightarrow> T \<in> sets lebesgue"
  1385   by (metis Diff_Diff_Int Int_Diff_Un inf_commute negligible_Un_eq negligible_imp_sets sets.Diff sets.Un)
  1386 
  1387 lemma lmeasurable_negligible_symdiff:
  1388    "\<lbrakk>S \<in> lmeasurable; negligible((S - T) \<union> (T - S))\<rbrakk> \<Longrightarrow> T \<in> lmeasurable"
  1389   using integrable_spike_set_eq lmeasurable_iff_integrable_on by blast
  1390 
  1391 
  1392 lemma measure_Un3_negligible:
  1393   assumes meas: "S \<in> lmeasurable" "T \<in> lmeasurable" "U \<in> lmeasurable"
  1394   and neg: "negligible(S \<inter> T)" "negligible(S \<inter> U)" "negligible(T \<inter> U)" and V: "S \<union> T \<union> U = V"
  1395 shows "measure lebesgue V = measure lebesgue S + measure lebesgue T + measure lebesgue U"
  1396 proof -
  1397   have [simp]: "measure lebesgue (S \<inter> T) = 0"
  1398     using neg(1) negligible_imp_measure0 by blast
  1399   have [simp]: "measure lebesgue (S \<inter> U \<union> T \<inter> U) = 0"
  1400     using neg(2) neg(3) negligible_Un negligible_imp_measure0 by blast
  1401   have "measure lebesgue V = measure lebesgue (S \<union> T \<union> U)"
  1402     using V by simp
  1403   also have "\<dots> = measure lebesgue S + measure lebesgue T + measure lebesgue U"
  1404     by (simp add: measure_Un3 meas fmeasurable.Un Int_Un_distrib2)
  1405   finally show ?thesis .
  1406 qed
  1407 
  1408 lemma measure_translate_add:
  1409   assumes meas: "S \<in> lmeasurable" "T \<in> lmeasurable"
  1410     and U: "S \<union> ((+)a ` T) = U" and neg: "negligible(S \<inter> ((+)a ` T))"
  1411   shows "measure lebesgue S + measure lebesgue T = measure lebesgue U"
  1412 proof -
  1413   have [simp]: "measure lebesgue (S \<inter> (+) a ` T) = 0"
  1414     using neg negligible_imp_measure0 by blast
  1415   have "measure lebesgue (S \<union> ((+)a ` T)) = measure lebesgue S + measure lebesgue T"
  1416     by (simp add: measure_Un3 meas measurable_translation measure_translation fmeasurable.Un)
  1417   then show ?thesis
  1418     using U by auto
  1419 qed
  1420 
  1421 lemma measure_negligible_symdiff:
  1422   assumes S: "S \<in> lmeasurable"
  1423     and neg: "negligible (S - T \<union> (T - S))"
  1424   shows "measure lebesgue T = measure lebesgue S"
  1425 proof -
  1426   have "measure lebesgue (S - T) = 0"
  1427     using neg negligible_Un_eq negligible_imp_measure0 by blast
  1428   then show ?thesis
  1429     by (metis S Un_commute add.right_neutral lmeasurable_negligible_symdiff measure_Un2 neg negligible_Un_eq negligible_imp_measure0)
  1430 qed
  1431 
  1432 lemma measure_closure:
  1433   assumes "bounded S" and neg: "negligible (frontier S)"
  1434   shows "measure lebesgue (closure S) = measure lebesgue S"
  1435 proof -
  1436   have "measure lebesgue (frontier S) = 0"
  1437     by (metis neg negligible_imp_measure0)
  1438   then show ?thesis
  1439     by (metis assms lmeasurable_iff_integrable_on eq_iff_diff_eq_0 has_integral_interior integrable_on_def integral_unique lmeasurable_interior lmeasure_integral measure_frontier)
  1440 qed
  1441 
  1442 lemma measure_interior:
  1443    "\<lbrakk>bounded S; negligible(frontier S)\<rbrakk> \<Longrightarrow> measure lebesgue (interior S) = measure lebesgue S"
  1444   using measure_closure measure_frontier negligible_imp_measure0 by fastforce
  1445 
  1446 lemma measurable_Jordan:
  1447   assumes "bounded S" and neg: "negligible (frontier S)"
  1448   shows "S \<in> lmeasurable"
  1449 proof -
  1450   have "closure S \<in> lmeasurable"
  1451     by (metis lmeasurable_closure \<open>bounded S\<close>)
  1452   moreover have "interior S \<in> lmeasurable"
  1453     by (simp add: lmeasurable_interior \<open>bounded S\<close>)
  1454   moreover have "interior S \<subseteq> S"
  1455     by (simp add: interior_subset)
  1456   ultimately show ?thesis
  1457     using assms by (metis (full_types) closure_subset completion.complete_sets_sandwich_fmeasurable measure_closure measure_interior)
  1458 qed
  1459 
  1460 lemma measurable_convex: "\<lbrakk>convex S; bounded S\<rbrakk> \<Longrightarrow> S \<in> lmeasurable"
  1461   by (simp add: measurable_Jordan negligible_convex_frontier)
  1462 
  1463 subsection\<open>Negligibility of image under non-injective linear map\<close>
  1464 
  1465 lemma negligible_Union_nat:
  1466   assumes "\<And>n::nat. negligible(S n)"
  1467   shows "negligible(\<Union>n. S n)"
  1468 proof -
  1469   have "negligible (\<Union>m\<le>k. S m)" for k
  1470     using assms by blast
  1471   then have 0:  "integral UNIV (indicat_real (\<Union>m\<le>k. S m)) = 0"
  1472     and 1: "(indicat_real (\<Union>m\<le>k. S m)) integrable_on UNIV" for k
  1473     by (auto simp: negligible has_integral_iff)
  1474   have 2: "\<And>k x. indicat_real (\<Union>m\<le>k. S m) x \<le> (indicat_real (\<Union>m\<le>Suc k. S m) x)"
  1475     by (simp add: indicator_def)
  1476   have 3: "\<And>x. (\<lambda>k. indicat_real (\<Union>m\<le>k. S m) x) \<longlonglongrightarrow> (indicat_real (\<Union>n. S n) x)"
  1477     by (force simp: indicator_def eventually_sequentially intro: Lim_eventually)
  1478   have 4: "bounded (range (\<lambda>k. integral UNIV (indicat_real (\<Union>m\<le>k. S m))))"
  1479     by (simp add: 0)
  1480   have *: "indicat_real (\<Union>n. S n) integrable_on UNIV \<and>
  1481         (\<lambda>k. integral UNIV (indicat_real (\<Union>m\<le>k. S m))) \<longlonglongrightarrow> (integral UNIV (indicat_real (\<Union>n. S n)))"
  1482     by (intro monotone_convergence_increasing 1 2 3 4)
  1483   then have "integral UNIV (indicat_real (\<Union>n. S n)) = (0::real)"
  1484     using LIMSEQ_unique by (auto simp: 0)
  1485   then show ?thesis
  1486     using * by (simp add: negligible_UNIV has_integral_iff)
  1487 qed
  1488 
  1489 
  1490 lemma negligible_linear_singular_image:
  1491   fixes f :: "'n::euclidean_space \<Rightarrow> 'n"
  1492   assumes "linear f" "\<not> inj f"
  1493   shows "negligible (f ` S)"
  1494 proof -
  1495   obtain a where "a \<noteq> 0" "\<And>S. f ` S \<subseteq> {x. a \<bullet> x = 0}"
  1496     using assms linear_singular_image_hyperplane by blast
  1497   then show "negligible (f ` S)"
  1498     by (metis negligible_hyperplane negligible_subset)
  1499 qed
  1500 
  1501 lemma measure_negligible_finite_Union:
  1502   assumes "finite \<F>"
  1503     and meas: "\<And>S. S \<in> \<F> \<Longrightarrow> S \<in> lmeasurable"
  1504     and djointish: "pairwise (\<lambda>S T. negligible (S \<inter> T)) \<F>"
  1505   shows "measure lebesgue (\<Union>\<F>) = (\<Sum>S\<in>\<F>. measure lebesgue S)"
  1506   using assms
  1507 proof (induction)
  1508   case empty
  1509   then show ?case
  1510     by auto
  1511 next
  1512   case (insert S \<F>)
  1513   then have "S \<in> lmeasurable" "\<Union>\<F> \<in> lmeasurable" "pairwise (\<lambda>S T. negligible (S \<inter> T)) \<F>"
  1514     by (simp_all add: fmeasurable.finite_Union insert.hyps(1) insert.prems(1) pairwise_insert subsetI)
  1515   then show ?case
  1516   proof (simp add: measure_Un3 insert)
  1517     have *: "\<And>T. T \<in> (\<inter>) S ` \<F> \<Longrightarrow> negligible T"
  1518       using insert by (force simp: pairwise_def)
  1519     have "negligible(S \<inter> \<Union>\<F>)"
  1520       unfolding Int_Union
  1521       by (rule negligible_Union) (simp_all add: * insert.hyps(1))
  1522     then show "measure lebesgue (S \<inter> \<Union>\<F>) = 0"
  1523       using negligible_imp_measure0 by blast
  1524   qed
  1525 qed
  1526 
  1527 lemma measure_negligible_finite_Union_image:
  1528   assumes "finite S"
  1529     and meas: "\<And>x. x \<in> S \<Longrightarrow> f x \<in> lmeasurable"
  1530     and djointish: "pairwise (\<lambda>x y. negligible (f x \<inter> f y)) S"
  1531   shows "measure lebesgue (\<Union>(f ` S)) = (\<Sum>x\<in>S. measure lebesgue (f x))"
  1532 proof -
  1533   have "measure lebesgue (\<Union>(f ` S)) = sum (measure lebesgue) (f ` S)"
  1534     using assms by (auto simp: pairwise_mono pairwise_image intro: measure_negligible_finite_Union)
  1535   also have "\<dots> = sum (measure lebesgue \<circ> f) S"
  1536     using djointish [unfolded pairwise_def] by (metis inf.idem negligible_imp_measure0 sum.reindex_nontrivial [OF \<open>finite S\<close>])
  1537   also have "\<dots> = (\<Sum>x\<in>S. measure lebesgue (f x))"
  1538     by simp
  1539   finally show ?thesis .
  1540 qed
  1541 
  1542 subsection \<open>Negligibility of a Lipschitz image of a negligible set\<close>
  1543 
  1544 text\<open>The bound will be eliminated by a sort of onion argument\<close>
  1545 lemma locally_Lipschitz_negl_bounded:
  1546   fixes f :: "'M::euclidean_space \<Rightarrow> 'N::euclidean_space"
  1547   assumes MleN: "DIM('M) \<le> DIM('N)" "0 < B" "bounded S" "negligible S"
  1548       and lips: "\<And>x. x \<in> S
  1549                       \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and>
  1550                               (\<forall>y \<in> S \<inter> T. norm(f y - f x) \<le> B * norm(y - x))"
  1551   shows "negligible (f ` S)"
  1552   unfolding negligible_iff_null_sets
  1553 proof (clarsimp simp: completion.null_sets_outer)
  1554   fix e::real
  1555   assume "0 < e"
  1556   have "S \<in> lmeasurable"
  1557     using \<open>negligible S\<close> by (simp add: negligible_iff_null_sets fmeasurableI_null_sets)
  1558   then have "S \<in> sets lebesgue"
  1559     by blast
  1560   have e22: "0 < e/2 / (2 * B * real DIM('M)) ^ DIM('N)"
  1561     using \<open>0 < e\<close> \<open>0 < B\<close> by (simp add: divide_simps)
  1562   obtain T where "open T" "S \<subseteq> T" "(T - S) \<in> lmeasurable" 
  1563                  "measure lebesgue (T - S) < e/2 / (2 * B * DIM('M)) ^ DIM('N)"
  1564     by (rule lmeasurable_outer_open [OF \<open>S \<in> sets lebesgue\<close> e22])
  1565   then have T: "measure lebesgue T \<le> e/2 / (2 * B * DIM('M)) ^ DIM('N)"
  1566     using \<open>negligible S\<close> by (simp add: measure_Diff_null_set negligible_iff_null_sets)
  1567   have "\<exists>r. 0 < r \<and> r \<le> 1/2 \<and>
  1568             (x \<in> S \<longrightarrow> (\<forall>y. norm(y - x) < r
  1569                        \<longrightarrow> y \<in> T \<and> (y \<in> S \<longrightarrow> norm(f y - f x) \<le> B * norm(y - x))))"
  1570         for x
  1571   proof (cases "x \<in> S")
  1572     case True
  1573     obtain U where "open U" "x \<in> U" and U: "\<And>y. y \<in> S \<inter> U \<Longrightarrow> norm(f y - f x) \<le> B * norm(y - x)"
  1574       using lips [OF \<open>x \<in> S\<close>] by auto
  1575     have "x \<in> T \<inter> U"
  1576       using \<open>S \<subseteq> T\<close> \<open>x \<in> U\<close> \<open>x \<in> S\<close> by auto
  1577     then obtain \<epsilon> where "0 < \<epsilon>" "ball x \<epsilon> \<subseteq> T \<inter> U"
  1578       by (metis \<open>open T\<close> \<open>open U\<close> openE open_Int)
  1579     then show ?thesis
  1580       apply (rule_tac x="min (1/2) \<epsilon>" in exI)
  1581       apply (simp del: divide_const_simps)
  1582       apply (intro allI impI conjI)
  1583        apply (metis dist_commute dist_norm mem_ball subsetCE)
  1584       by (metis Int_iff subsetCE U dist_norm mem_ball norm_minus_commute)
  1585   next
  1586     case False
  1587     then show ?thesis
  1588       by (rule_tac x="1/4" in exI) auto
  1589   qed
  1590   then obtain R where R12: "\<And>x. 0 < R x \<and> R x \<le> 1/2"
  1591                 and RT: "\<And>x y. \<lbrakk>x \<in> S; norm(y - x) < R x\<rbrakk> \<Longrightarrow> y \<in> T"
  1592                 and RB: "\<And>x y. \<lbrakk>x \<in> S; y \<in> S; norm(y - x) < R x\<rbrakk> \<Longrightarrow> norm(f y - f x) \<le> B * norm(y - x)"
  1593     by metis+
  1594   then have gaugeR: "gauge (\<lambda>x. ball x (R x))"
  1595     by (simp add: gauge_def)
  1596   obtain c where c: "S \<subseteq> cbox (-c *\<^sub>R One) (c *\<^sub>R One)" "box (-c *\<^sub>R One:: 'M) (c *\<^sub>R One) \<noteq> {}"
  1597   proof -
  1598     obtain B where B: "\<And>x. x \<in> S \<Longrightarrow> norm x \<le> B"
  1599       using \<open>bounded S\<close> bounded_iff by blast
  1600     show ?thesis
  1601       apply (rule_tac c = "abs B + 1" in that)
  1602       using norm_bound_Basis_le Basis_le_norm
  1603        apply (fastforce simp: box_eq_empty mem_box dest!: B intro: order_trans)+
  1604       done
  1605   qed
  1606   obtain \<D> where "countable \<D>"
  1607      and Dsub: "\<Union>\<D> \<subseteq> cbox (-c *\<^sub>R One) (c *\<^sub>R One)"
  1608      and cbox: "\<And>K. K \<in> \<D> \<Longrightarrow> interior K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  1609      and pw:   "pairwise (\<lambda>A B. interior A \<inter> interior B = {}) \<D>"
  1610      and Ksub: "\<And>K. K \<in> \<D> \<Longrightarrow> \<exists>x \<in> S \<inter> K. K \<subseteq> (\<lambda>x. ball x (R x)) x"
  1611      and exN:  "\<And>u v. cbox u v \<in> \<D> \<Longrightarrow> \<exists>n. \<forall>i \<in> Basis. v \<bullet> i - u \<bullet> i = (2*c) / 2^n"
  1612      and "S \<subseteq> \<Union>\<D>"
  1613     using covering_lemma [OF c gaugeR]  by force
  1614   have "\<exists>u v z. K = cbox u v \<and> box u v \<noteq> {} \<and> z \<in> S \<and> z \<in> cbox u v \<and>
  1615                 cbox u v \<subseteq> ball z (R z)" if "K \<in> \<D>" for K
  1616   proof -
  1617     obtain u v where "K = cbox u v"
  1618       using \<open>K \<in> \<D>\<close> cbox by blast
  1619     with that show ?thesis
  1620       apply (rule_tac x=u in exI)
  1621       apply (rule_tac x=v in exI)
  1622       apply (metis Int_iff interior_cbox cbox Ksub)
  1623       done
  1624   qed
  1625   then obtain uf vf zf
  1626     where uvz: "\<And>K. K \<in> \<D> \<Longrightarrow>
  1627                 K = cbox (uf K) (vf K) \<and> box (uf K) (vf K) \<noteq> {} \<and> zf K \<in> S \<and>
  1628                 zf K \<in> cbox (uf K) (vf K) \<and> cbox (uf K) (vf K) \<subseteq> ball (zf K) (R (zf K))"
  1629     by metis
  1630   define prj1 where "prj1 \<equiv> \<lambda>x::'M. x \<bullet> (SOME i. i \<in> Basis)"
  1631   define fbx where "fbx \<equiv> \<lambda>D. cbox (f(zf D) - (B * DIM('M) * (prj1(vf D - uf D))) *\<^sub>R One::'N)
  1632                                     (f(zf D) + (B * DIM('M) * prj1(vf D - uf D)) *\<^sub>R One)"
  1633   have vu_pos: "0 < prj1 (vf X - uf X)" if "X \<in> \<D>" for X
  1634     using uvz [OF that] by (simp add: prj1_def box_ne_empty SOME_Basis inner_diff_left)
  1635   have prj1_idem: "prj1 (vf X - uf X) = (vf X - uf X) \<bullet> i" if  "X \<in> \<D>" "i \<in> Basis" for X i
  1636   proof -
  1637     have "cbox (uf X) (vf X) \<in> \<D>"
  1638       using uvz \<open>X \<in> \<D>\<close> by auto
  1639     with exN obtain n where "\<And>i. i \<in> Basis \<Longrightarrow> vf X \<bullet> i - uf X \<bullet> i = (2*c) / 2^n"
  1640       by blast
  1641     then show ?thesis
  1642       by (simp add: \<open>i \<in> Basis\<close> SOME_Basis inner_diff prj1_def)
  1643   qed
  1644   have countbl: "countable (fbx ` \<D>)"
  1645     using \<open>countable \<D>\<close> by blast
  1646   have "(\<Sum>k\<in>fbx`\<D>'. measure lebesgue k) \<le> e/2" if "\<D>' \<subseteq> \<D>" "finite \<D>'" for \<D>'
  1647   proof -
  1648     have BM_ge0: "0 \<le> B * (DIM('M) * prj1 (vf X - uf X))" if "X \<in> \<D>'" for X
  1649       using \<open>0 < B\<close> \<open>\<D>' \<subseteq> \<D>\<close> that vu_pos by fastforce
  1650     have "{} \<notin> \<D>'"
  1651       using cbox \<open>\<D>' \<subseteq> \<D>\<close> interior_empty by blast
  1652     have "(\<Sum>k\<in>fbx`\<D>'. measure lebesgue k) \<le> sum (measure lebesgue o fbx) \<D>'"
  1653       by (rule sum_image_le [OF \<open>finite \<D>'\<close>]) (force simp: fbx_def)
  1654     also have "\<dots> \<le> (\<Sum>X\<in>\<D>'. (2 * B * DIM('M)) ^ DIM('N) * measure lebesgue X)"
  1655     proof (rule sum_mono)
  1656       fix X assume "X \<in> \<D>'"
  1657       then have "X \<in> \<D>" using \<open>\<D>' \<subseteq> \<D>\<close> by blast
  1658       then have ufvf: "cbox (uf X) (vf X) = X"
  1659         using uvz by blast
  1660       have "prj1 (vf X - uf X) ^ DIM('M) = (\<Prod>i::'M \<in> Basis. prj1 (vf X - uf X))"
  1661         by (rule prod_constant [symmetric])
  1662       also have "\<dots> = (\<Prod>i\<in>Basis. vf X \<bullet> i - uf X \<bullet> i)"
  1663         apply (rule prod.cong [OF refl])
  1664         by (simp add: \<open>X \<in> \<D>\<close> inner_diff_left prj1_idem)
  1665       finally have prj1_eq: "prj1 (vf X - uf X) ^ DIM('M) = (\<Prod>i\<in>Basis. vf X \<bullet> i - uf X \<bullet> i)" .
  1666       have "uf X \<in> cbox (uf X) (vf X)" "vf X \<in> cbox (uf X) (vf X)"
  1667         using uvz [OF \<open>X \<in> \<D>\<close>] by (force simp: mem_box)+
  1668       moreover have "cbox (uf X) (vf X) \<subseteq> ball (zf X) (1/2)"
  1669         by (meson R12 order_trans subset_ball uvz [OF \<open>X \<in> \<D>\<close>])
  1670       ultimately have "uf X \<in> ball (zf X) (1/2)"  "vf X \<in> ball (zf X) (1/2)"
  1671         by auto
  1672       then have "dist (vf X) (uf X) \<le> 1"
  1673         unfolding mem_ball
  1674         by (metis dist_commute dist_triangle_half_l dual_order.order_iff_strict)
  1675       then have 1: "prj1 (vf X - uf X) \<le> 1"
  1676         unfolding prj1_def dist_norm using Basis_le_norm SOME_Basis order_trans by fastforce
  1677       have 0: "0 \<le> prj1 (vf X - uf X)"
  1678         using \<open>X \<in> \<D>\<close> prj1_def vu_pos by fastforce
  1679       have "(measure lebesgue \<circ> fbx) X \<le> (2 * B * DIM('M)) ^ DIM('N) * content (cbox (uf X) (vf X))"
  1680         apply (simp add: fbx_def content_cbox_cases algebra_simps BM_ge0 \<open>X \<in> \<D>'\<close> prod_constant)
  1681         apply (simp add: power_mult_distrib \<open>0 < B\<close> prj1_eq [symmetric])
  1682         using MleN 0 1 uvz \<open>X \<in> \<D>\<close>
  1683         apply (fastforce simp add: box_ne_empty power_decreasing)
  1684         done
  1685       also have "\<dots> = (2 * B * DIM('M)) ^ DIM('N) * measure lebesgue X"
  1686         by (subst (3) ufvf[symmetric]) simp
  1687       finally show "(measure lebesgue \<circ> fbx) X \<le> (2 * B * DIM('M)) ^ DIM('N) * measure lebesgue X" .
  1688     qed
  1689     also have "\<dots> = (2 * B * DIM('M)) ^ DIM('N) * sum (measure lebesgue) \<D>'"
  1690       by (simp add: sum_distrib_left)
  1691     also have "\<dots> \<le> e/2"
  1692     proof -
  1693       have div: "\<D>' division_of \<Union>\<D>'"
  1694         apply (auto simp: \<open>finite \<D>'\<close> \<open>{} \<notin> \<D>'\<close> division_of_def)
  1695         using cbox that apply blast
  1696         using pairwise_subset [OF pw \<open>\<D>' \<subseteq> \<D>\<close>] unfolding pairwise_def apply force+
  1697         done
  1698       have le_meaT: "measure lebesgue (\<Union>\<D>') \<le> measure lebesgue T"
  1699       proof (rule measure_mono_fmeasurable)
  1700         show "(\<Union>\<D>') \<in> sets lebesgue"
  1701           using div lmeasurable_division by auto
  1702         have "\<Union>\<D>' \<subseteq> \<Union>\<D>"
  1703           using \<open>\<D>' \<subseteq> \<D>\<close> by blast
  1704         also have "... \<subseteq> T"
  1705         proof (clarify)
  1706           fix x D
  1707           assume "x \<in> D" "D \<in> \<D>"
  1708           show "x \<in> T"
  1709             using Ksub [OF \<open>D \<in> \<D>\<close>]
  1710             by (metis \<open>x \<in> D\<close> Int_iff dist_norm mem_ball norm_minus_commute subsetD RT)
  1711         qed
  1712         finally show "\<Union>\<D>' \<subseteq> T" .
  1713         show "T \<in> lmeasurable"
  1714           using \<open>S \<in> lmeasurable\<close> \<open>S \<subseteq> T\<close> \<open>T - S \<in> lmeasurable\<close> fmeasurable_Diff_D by blast
  1715       qed 
  1716       have "sum (measure lebesgue) \<D>' = sum content \<D>'"
  1717         using  \<open>\<D>' \<subseteq> \<D>\<close> cbox by (force intro: sum.cong)
  1718       then have "(2 * B * DIM('M)) ^ DIM('N) * sum (measure lebesgue) \<D>' =
  1719                  (2 * B * real DIM('M)) ^ DIM('N) * measure lebesgue (\<Union>\<D>')"
  1720         using content_division [OF div] by auto
  1721       also have "\<dots> \<le> (2 * B * real DIM('M)) ^ DIM('N) * measure lebesgue T"
  1722         apply (rule mult_left_mono [OF le_meaT])
  1723         using \<open>0 < B\<close>
  1724         apply (simp add: algebra_simps)
  1725         done
  1726       also have "\<dots> \<le> e/2"
  1727         using T \<open>0 < B\<close> by (simp add: field_simps)
  1728       finally show ?thesis .
  1729     qed
  1730     finally show ?thesis .
  1731   qed
  1732   then have e2: "sum (measure lebesgue) \<G> \<le> e/2" if "\<G> \<subseteq> fbx ` \<D>" "finite \<G>" for \<G>
  1733     by (metis finite_subset_image that)
  1734   show "\<exists>W\<in>lmeasurable. f ` S \<subseteq> W \<and> measure lebesgue W < e"
  1735   proof (intro bexI conjI)
  1736     have "\<exists>X\<in>\<D>. f y \<in> fbx X" if "y \<in> S" for y
  1737     proof -
  1738       obtain X where "y \<in> X" "X \<in> \<D>"
  1739         using \<open>S \<subseteq> \<Union>\<D>\<close> \<open>y \<in> S\<close> by auto
  1740       then have y: "y \<in> ball(zf X) (R(zf X))"
  1741         using uvz by fastforce
  1742       have conj_le_eq: "z - b \<le> y \<and> y \<le> z + b \<longleftrightarrow> abs(y - z) \<le> b" for z y b::real
  1743         by auto
  1744       have yin: "y \<in> cbox (uf X) (vf X)" and zin: "(zf X) \<in> cbox (uf X) (vf X)"
  1745         using uvz \<open>X \<in> \<D>\<close> \<open>y \<in> X\<close> by auto
  1746       have "norm (y - zf X) \<le> (\<Sum>i\<in>Basis. \<bar>(y - zf X) \<bullet> i\<bar>)"
  1747         by (rule norm_le_l1)
  1748       also have "\<dots> \<le> real DIM('M) * prj1 (vf X - uf X)"
  1749       proof (rule sum_bounded_above)
  1750         fix j::'M assume j: "j \<in> Basis"
  1751         show "\<bar>(y - zf X) \<bullet> j\<bar> \<le> prj1 (vf X - uf X)"
  1752           using yin zin j
  1753           by (fastforce simp add: mem_box prj1_idem [OF \<open>X \<in> \<D>\<close> j] inner_diff_left)
  1754       qed
  1755       finally have nole: "norm (y - zf X) \<le> DIM('M) * prj1 (vf X - uf X)"
  1756         by simp
  1757       have fle: "\<bar>f y \<bullet> i - f(zf X) \<bullet> i\<bar> \<le> B * DIM('M) * prj1 (vf X - uf X)" if "i \<in> Basis" for i
  1758       proof -
  1759         have "\<bar>f y \<bullet> i - f (zf X) \<bullet> i\<bar> = \<bar>(f y - f (zf X)) \<bullet> i\<bar>"
  1760           by (simp add: algebra_simps)
  1761         also have "\<dots> \<le> norm (f y - f (zf X))"
  1762           by (simp add: Basis_le_norm that)
  1763         also have "\<dots> \<le> B * norm(y - zf X)"
  1764           by (metis uvz RB \<open>X \<in> \<D>\<close> dist_commute dist_norm mem_ball \<open>y \<in> S\<close> y)
  1765         also have "\<dots> \<le> B * real DIM('M) * prj1 (vf X - uf X)"
  1766           using \<open>0 < B\<close> by (simp add: nole)
  1767         finally show ?thesis .
  1768       qed
  1769       show ?thesis
  1770         by (rule_tac x=X in bexI)
  1771            (auto simp: fbx_def prj1_idem mem_box conj_le_eq inner_add inner_diff fle \<open>X \<in> \<D>\<close>)
  1772     qed
  1773     then show "f ` S \<subseteq> (\<Union>D\<in>\<D>. fbx D)" by auto
  1774   next
  1775     have 1: "\<And>D. D \<in> \<D> \<Longrightarrow> fbx D \<in> lmeasurable"
  1776       by (auto simp: fbx_def)
  1777     have 2: "I' \<subseteq> \<D> \<Longrightarrow> finite I' \<Longrightarrow> measure lebesgue (\<Union>D\<in>I'. fbx D) \<le> e/2" for I'
  1778       by (rule order_trans[OF measure_Union_le e2]) (auto simp: fbx_def)
  1779     show "(\<Union>D\<in>\<D>. fbx D) \<in> lmeasurable"
  1780       by (intro fmeasurable_UN_bound[OF \<open>countable \<D>\<close> 1 2])
  1781     have "measure lebesgue (\<Union>D\<in>\<D>. fbx D) \<le> e/2"
  1782       by (intro measure_UN_bound[OF \<open>countable \<D>\<close> 1 2])
  1783     then show "measure lebesgue (\<Union>D\<in>\<D>. fbx D) < e"
  1784       using \<open>0 < e\<close> by linarith
  1785   qed
  1786 qed
  1787 
  1788 proposition negligible_locally_Lipschitz_image:
  1789   fixes f :: "'M::euclidean_space \<Rightarrow> 'N::euclidean_space"
  1790   assumes MleN: "DIM('M) \<le> DIM('N)" "negligible S"
  1791       and lips: "\<And>x. x \<in> S
  1792                       \<Longrightarrow> \<exists>T B. open T \<and> x \<in> T \<and>
  1793                               (\<forall>y \<in> S \<inter> T. norm(f y - f x) \<le> B * norm(y - x))"
  1794     shows "negligible (f ` S)"
  1795 proof -
  1796   let ?S = "\<lambda>n. ({x \<in> S. norm x \<le> n \<and>
  1797                           (\<exists>T. open T \<and> x \<in> T \<and>
  1798                                (\<forall>y\<in>S \<inter> T. norm (f y - f x) \<le> (real n + 1) * norm (y - x)))})"
  1799   have negfn: "f ` ?S n \<in> null_sets lebesgue" for n::nat
  1800     unfolding negligible_iff_null_sets[symmetric]
  1801     apply (rule_tac B = "real n + 1" in locally_Lipschitz_negl_bounded)
  1802     by (auto simp: MleN bounded_iff intro: negligible_subset [OF \<open>negligible S\<close>])
  1803   have "S = (\<Union>n. ?S n)"
  1804   proof (intro set_eqI iffI)
  1805     fix x assume "x \<in> S"
  1806     with lips obtain T B where T: "open T" "x \<in> T"
  1807                            and B: "\<And>y. y \<in> S \<inter> T \<Longrightarrow> norm(f y - f x) \<le> B * norm(y - x)"
  1808       by metis+
  1809     have no: "norm (f y - f x) \<le> (nat \<lceil>max B (norm x)\<rceil> + 1) * norm (y - x)" if "y \<in> S \<inter> T" for y
  1810     proof -
  1811       have "B * norm(y - x) \<le> (nat \<lceil>max B (norm x)\<rceil> + 1) * norm (y - x)"
  1812         by (meson max.cobounded1 mult_right_mono nat_ceiling_le_eq nat_le_iff_add norm_ge_zero order_trans)
  1813       then show ?thesis
  1814         using B order_trans that by blast
  1815     qed
  1816     have "x \<in> ?S (nat (ceiling (max B (norm x))))"
  1817       apply (simp add: \<open>x \<in> S \<close>, rule)
  1818       using real_nat_ceiling_ge max.bounded_iff apply blast
  1819       using T no
  1820       apply (force simp: algebra_simps)
  1821       done
  1822     then show "x \<in> (\<Union>n. ?S n)" by force
  1823   qed auto
  1824   then show ?thesis
  1825     by (rule ssubst) (auto simp: image_Union negligible_iff_null_sets intro: negfn)
  1826 qed
  1827 
  1828 corollary negligible_differentiable_image_negligible:
  1829   fixes f :: "'M::euclidean_space \<Rightarrow> 'N::euclidean_space"
  1830   assumes MleN: "DIM('M) \<le> DIM('N)" "negligible S"
  1831       and diff_f: "f differentiable_on S"
  1832     shows "negligible (f ` S)"
  1833 proof -
  1834   have "\<exists>T B. open T \<and> x \<in> T \<and> (\<forall>y \<in> S \<inter> T. norm(f y - f x) \<le> B * norm(y - x))"
  1835         if "x \<in> S" for x
  1836   proof -
  1837     obtain f' where "linear f'"
  1838       and f': "\<And>e. e>0 \<Longrightarrow>
  1839                   \<exists>d>0. \<forall>y\<in>S. norm (y - x) < d \<longrightarrow>
  1840                               norm (f y - f x - f' (y - x)) \<le> e * norm (y - x)"
  1841       using diff_f \<open>x \<in> S\<close>
  1842       by (auto simp: linear_linear differentiable_on_def differentiable_def has_derivative_within_alt)
  1843     obtain B where "B > 0" and B: "\<forall>x. norm (f' x) \<le> B * norm x"
  1844       using linear_bounded_pos \<open>linear f'\<close> by blast
  1845     obtain d where "d>0"
  1846               and d: "\<And>y. \<lbrakk>y \<in> S; norm (y - x) < d\<rbrakk> \<Longrightarrow>
  1847                           norm (f y - f x - f' (y - x)) \<le> norm (y - x)"
  1848       using f' [of 1] by (force simp:)
  1849     have *: "norm (f y - f x) \<le> (B + 1) * norm (y - x)"
  1850               if "y \<in> S" "norm (y - x) < d" for y
  1851     proof -
  1852       have "norm (f y - f x) -B *  norm (y - x) \<le> norm (f y - f x) - norm (f' (y - x))"
  1853         by (simp add: B)
  1854       also have "\<dots> \<le> norm (f y - f x - f' (y - x))"
  1855         by (rule norm_triangle_ineq2)
  1856       also have "... \<le> norm (y - x)"
  1857         by (rule d [OF that])
  1858       finally show ?thesis
  1859         by (simp add: algebra_simps)
  1860     qed
  1861     show ?thesis
  1862       apply (rule_tac x="ball x d" in exI)
  1863       apply (rule_tac x="B+1" in exI)
  1864       using \<open>d>0\<close>
  1865       apply (auto simp: dist_norm norm_minus_commute intro!: *)
  1866       done
  1867   qed
  1868   with negligible_locally_Lipschitz_image assms show ?thesis by metis
  1869 qed
  1870 
  1871 corollary negligible_differentiable_image_lowdim:
  1872   fixes f :: "'M::euclidean_space \<Rightarrow> 'N::euclidean_space"
  1873   assumes MlessN: "DIM('M) < DIM('N)" and diff_f: "f differentiable_on S"
  1874     shows "negligible (f ` S)"
  1875 proof -
  1876   have "x \<le> DIM('M) \<Longrightarrow> x \<le> DIM('N)" for x
  1877     using MlessN by linarith
  1878   obtain lift :: "'M * real \<Rightarrow> 'N" and drop :: "'N \<Rightarrow> 'M * real" and j :: 'N
  1879     where "linear lift" "linear drop" and dropl [simp]: "\<And>z. drop (lift z) = z"
  1880       and "j \<in> Basis" and j: "\<And>x. lift(x,0) \<bullet> j = 0"
  1881     using lowerdim_embeddings [OF MlessN] by metis
  1882   have "negligible {x. x\<bullet>j = 0}"
  1883     by (metis \<open>j \<in> Basis\<close> negligible_standard_hyperplane)
  1884   then have neg0S: "negligible ((\<lambda>x. lift (x, 0)) ` S)"
  1885     apply (rule negligible_subset)
  1886     by (simp add: image_subsetI j)
  1887   have diff_f': "f \<circ> fst \<circ> drop differentiable_on (\<lambda>x. lift (x, 0)) ` S"
  1888     using diff_f
  1889     apply (clarsimp simp add: differentiable_on_def)
  1890     apply (intro differentiable_chain_within linear_imp_differentiable [OF \<open>linear drop\<close>]
  1891              linear_imp_differentiable [OF fst_linear])
  1892     apply (force simp: image_comp o_def)
  1893     done
  1894   have "f = (f o fst o drop o (\<lambda>x. lift (x, 0)))"
  1895     by (simp add: o_def)
  1896   then show ?thesis
  1897     apply (rule ssubst)
  1898     apply (subst image_comp [symmetric])
  1899     apply (metis negligible_differentiable_image_negligible order_refl diff_f' neg0S)
  1900     done
  1901 qed
  1902 
  1903 subsection\<open>Measurability of countable unions and intersections of various kinds.\<close>
  1904 
  1905 lemma
  1906   assumes S: "\<And>n. S n \<in> lmeasurable"
  1907     and leB: "\<And>n. measure lebesgue (S n) \<le> B"
  1908     and nest: "\<And>n. S n \<subseteq> S(Suc n)"
  1909   shows measurable_nested_Union: "(\<Union>n. S n) \<in> lmeasurable"
  1910   and measure_nested_Union:  "(\<lambda>n. measure lebesgue (S n)) \<longlonglongrightarrow> measure lebesgue (\<Union>n. S n)" (is ?Lim)
  1911 proof -
  1912   have 1: "\<And>n. (indicat_real (S n)) integrable_on UNIV"
  1913     using S measurable_integrable by blast
  1914   have 2: "\<And>n x::'a. indicat_real (S n) x \<le> (indicat_real (S (Suc n)) x)"
  1915     by (simp add: indicator_leI nest rev_subsetD)
  1916   have 3: "\<And>x. (\<lambda>n. indicat_real (S n) x) \<longlonglongrightarrow> (indicat_real (\<Union>(S ` UNIV)) x)"
  1917     apply (rule Lim_eventually)
  1918     apply (simp add: indicator_def)
  1919     by (metis eventually_sequentiallyI lift_Suc_mono_le nest subsetCE)
  1920   have 4: "bounded (range (\<lambda>n. integral UNIV (indicat_real (S n))))"
  1921     using leB by (auto simp: lmeasure_integral_UNIV [symmetric] S bounded_iff)
  1922   have "(\<Union>n. S n) \<in> lmeasurable \<and> ?Lim"
  1923     apply (simp add: lmeasure_integral_UNIV S cong: conj_cong)
  1924     apply (simp add: measurable_integrable)
  1925     apply (rule monotone_convergence_increasing [OF 1 2 3 4])
  1926     done
  1927   then show "(\<Union>n. S n) \<in> lmeasurable" "?Lim"
  1928     by auto
  1929 qed
  1930 
  1931 lemma
  1932   assumes S: "\<And>n. S n \<in> lmeasurable"
  1933     and djointish: "pairwise (\<lambda>m n. negligible (S m \<inter> S n)) UNIV"
  1934     and leB: "\<And>n. (\<Sum>k\<le>n. measure lebesgue (S k)) \<le> B"
  1935   shows measurable_countable_negligible_Union: "(\<Union>n. S n) \<in> lmeasurable"
  1936   and   measure_countable_negligible_Union:    "(\<lambda>n. (measure lebesgue (S n))) sums measure lebesgue (\<Union>n. S n)" (is ?Sums)
  1937 proof -
  1938   have 1: "\<Union> (S ` {..n}) \<in> lmeasurable" for n
  1939     using S by blast
  1940   have 2: "measure lebesgue (\<Union> (S ` {..n})) \<le> B" for n
  1941   proof -
  1942     have "measure lebesgue (\<Union> (S ` {..n})) \<le> (\<Sum>k\<le>n. measure lebesgue (S k))"
  1943       by (simp add: S fmeasurableD measure_UNION_le)
  1944     with leB show ?thesis
  1945       using order_trans by blast
  1946   qed
  1947   have 3: "\<And>n. \<Union> (S ` {..n}) \<subseteq> \<Union> (S ` {..Suc n})"
  1948     by (simp add: SUP_subset_mono)
  1949   have eqS: "(\<Union>n. S n) = (\<Union>n. \<Union> (S ` {..n}))"
  1950     using atLeastAtMost_iff by blast
  1951   also have "(\<Union>n. \<Union> (S ` {..n})) \<in> lmeasurable"
  1952     by (intro measurable_nested_Union [OF 1 2] 3)
  1953   finally show "(\<Union>n. S n) \<in> lmeasurable" .
  1954   have eqm: "(\<Sum>i\<le>n. measure lebesgue (S i)) = measure lebesgue (\<Union> (S ` {..n}))" for n
  1955     using assms by (simp add: measure_negligible_finite_Union_image pairwise_mono)
  1956   have "(\<lambda>n. (measure lebesgue (S n))) sums measure lebesgue (\<Union>n. \<Union> (S ` {..n}))"
  1957     by (simp add: sums_def' eqm atLeast0AtMost) (intro measure_nested_Union [OF 1 2] 3)
  1958   then show ?Sums
  1959     by (simp add: eqS)
  1960 qed
  1961 
  1962 lemma negligible_countable_Union [intro]:
  1963   assumes "countable \<F>" and meas: "\<And>S. S \<in> \<F> \<Longrightarrow> negligible S"
  1964   shows "negligible (\<Union>\<F>)"
  1965 proof (cases "\<F> = {}")
  1966   case False
  1967   then show ?thesis
  1968     by (metis from_nat_into range_from_nat_into assms negligible_Union_nat)
  1969 qed simp
  1970 
  1971 lemma
  1972   assumes S: "\<And>n. (S n) \<in> lmeasurable"
  1973     and djointish: "pairwise (\<lambda>m n. negligible (S m \<inter> S n)) UNIV"
  1974     and bo: "bounded (\<Union>n. S n)"
  1975   shows measurable_countable_negligible_Union_bounded: "(\<Union>n. S n) \<in> lmeasurable"
  1976   and   measure_countable_negligible_Union_bounded:    "(\<lambda>n. (measure lebesgue (S n))) sums measure lebesgue (\<Union>n. S n)" (is ?Sums)
  1977 proof -
  1978   obtain a b where ab: "(\<Union>n. S n) \<subseteq> cbox a b"
  1979     using bo bounded_subset_cbox_symmetric by metis
  1980   then have B: "(\<Sum>k\<le>n. measure lebesgue (S k)) \<le> measure lebesgue (cbox a b)" for n
  1981   proof -
  1982     have "(\<Sum>k\<le>n. measure lebesgue (S k)) = measure lebesgue (\<Union> (S ` {..n}))"
  1983       using measure_negligible_finite_Union_image [OF _ _ pairwise_subset] djointish
  1984       by (metis S finite_atMost subset_UNIV)
  1985     also have "\<dots> \<le> measure lebesgue (cbox a b)"
  1986       apply (rule measure_mono_fmeasurable)
  1987       using ab S by force+
  1988     finally show ?thesis .
  1989   qed
  1990   show "(\<Union>n. S n) \<in> lmeasurable"
  1991     by (rule measurable_countable_negligible_Union [OF S djointish B])
  1992   show ?Sums
  1993     by (rule measure_countable_negligible_Union [OF S djointish B])
  1994 qed
  1995 
  1996 lemma measure_countable_Union_approachable:
  1997   assumes "countable \<D>" "e > 0" and measD: "\<And>d. d \<in> \<D> \<Longrightarrow> d \<in> lmeasurable"
  1998       and B: "\<And>D'. \<lbrakk>D' \<subseteq> \<D>; finite D'\<rbrakk> \<Longrightarrow> measure lebesgue (\<Union>D') \<le> B"
  1999     obtains D' where "D' \<subseteq> \<D>" "finite D'" "measure lebesgue (\<Union>\<D>) - e < measure lebesgue (\<Union>D')"
  2000 proof (cases "\<D> = {}")
  2001   case True
  2002   then show ?thesis
  2003     by (simp add: \<open>e > 0\<close> that)
  2004 next
  2005   case False
  2006   let ?S = "\<lambda>n. \<Union>k \<le> n. from_nat_into \<D> k"
  2007   have "(\<lambda>n. measure lebesgue (?S n)) \<longlonglongrightarrow> measure lebesgue (\<Union>n. ?S n)"
  2008   proof (rule measure_nested_Union)
  2009     show "?S n \<in> lmeasurable" for n
  2010       by (simp add: False fmeasurable.finite_UN from_nat_into measD)
  2011     show "measure lebesgue (?S n) \<le> B" for n
  2012       by (metis (mono_tags, lifting) B False finite_atMost finite_imageI from_nat_into image_iff subsetI)
  2013     show "?S n \<subseteq> ?S (Suc n)" for n
  2014       by force
  2015   qed
  2016   then obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> dist (measure lebesgue (?S n)) (measure lebesgue (\<Union>n. ?S n)) < e"
  2017     using metric_LIMSEQ_D \<open>e > 0\<close> by blast
  2018   show ?thesis
  2019   proof
  2020     show "from_nat_into \<D> ` {..N} \<subseteq> \<D>"
  2021       by (auto simp: False from_nat_into)
  2022     have eq: "(\<Union>n. \<Union>k\<le>n. from_nat_into \<D> k) = (\<Union>\<D>)"
  2023       using \<open>countable \<D>\<close> False
  2024       by (auto intro: from_nat_into dest: from_nat_into_surj [OF \<open>countable \<D>\<close>])
  2025     show "measure lebesgue (\<Union>\<D>) - e < measure lebesgue (\<Union> (from_nat_into \<D> ` {..N}))"
  2026       using N [OF order_refl]
  2027       by (auto simp: eq algebra_simps dist_norm)
  2028   qed auto
  2029 qed
  2030 
  2031 
  2032 subsection\<open>Negligibility is a local property\<close>
  2033 
  2034 lemma locally_negligible_alt:
  2035     "negligible S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>U. openin (top_of_set S) U \<and> x \<in> U \<and> negligible U)"
  2036      (is "_ = ?rhs")
  2037 proof
  2038   assume "negligible S"
  2039   then show ?rhs
  2040     using openin_subtopology_self by blast
  2041 next
  2042   assume ?rhs
  2043   then obtain U where ope: "\<And>x. x \<in> S \<Longrightarrow> openin (top_of_set S) (U x)"
  2044     and cov: "\<And>x. x \<in> S \<Longrightarrow> x \<in> U x"
  2045     and neg: "\<And>x. x \<in> S \<Longrightarrow> negligible (U x)"
  2046     by metis
  2047   obtain \<F> where "\<F> \<subseteq> U ` S" "countable \<F>" and eq: "\<Union>\<F> = \<Union>(U ` S)"
  2048     using ope by (force intro: Lindelof_openin [of "U ` S" S])
  2049   then have "negligible (\<Union>\<F>)"
  2050     by (metis imageE neg negligible_countable_Union subset_eq)
  2051   with eq have "negligible (\<Union>(U ` S))"
  2052     by metis
  2053   moreover have "S \<subseteq> \<Union>(U ` S)"
  2054     using cov by blast
  2055   ultimately show "negligible S"
  2056     using negligible_subset by blast
  2057 qed
  2058 
  2059 lemma locally_negligible:
  2060      "locally negligible S \<longleftrightarrow> negligible S"
  2061   unfolding locally_def
  2062   apply safe
  2063    apply (meson negligible_subset openin_subtopology_self locally_negligible_alt)
  2064   by (meson negligible_subset openin_imp_subset order_refl)
  2065 
  2066 
  2067 subsection\<open>Integral bounds\<close>
  2068 
  2069 lemma set_integral_norm_bound:
  2070   fixes f :: "_ \<Rightarrow> 'a :: {banach, second_countable_topology}"
  2071   shows "set_integrable M k f \<Longrightarrow> norm (LINT x:k|M. f x) \<le> LINT x:k|M. norm (f x)"
  2072   using integral_norm_bound[of M "\<lambda>x. indicator k x *\<^sub>R f x"] by (simp add: set_lebesgue_integral_def)
  2073 
  2074 lemma set_integral_finite_UN_AE:
  2075   fixes f :: "_ \<Rightarrow> _ :: {banach, second_countable_topology}"
  2076   assumes "finite I"
  2077     and ae: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> AE x in M. (x \<in> A i \<and> x \<in> A j) \<longrightarrow> i = j"
  2078     and [measurable]: "\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets M"
  2079     and f: "\<And>i. i \<in> I \<Longrightarrow> set_integrable M (A i) f"
  2080   shows "LINT x:(\<Union>i\<in>I. A i)|M. f x = (\<Sum>i\<in>I. LINT x:A i|M. f x)"
  2081   using \<open>finite I\<close> order_refl[of I]
  2082 proof (induction I rule: finite_subset_induct')
  2083   case (insert i I')
  2084   have "AE x in M. (\<forall>j\<in>I'. x \<in> A i \<longrightarrow> x \<notin> A j)"
  2085   proof (intro AE_ball_countable[THEN iffD2] ballI)
  2086     fix j assume "j \<in> I'"
  2087     with \<open>I' \<subseteq> I\<close> \<open>i \<notin> I'\<close> have "i \<noteq> j" "j \<in> I"
  2088       by auto
  2089     then show "AE x in M. x \<in> A i \<longrightarrow> x \<notin> A j"
  2090       using ae[of i j] \<open>i \<in> I\<close> by auto
  2091   qed (use \<open>finite I'\<close> in \<open>rule countable_finite\<close>)
  2092   then have "AE x\<in>A i in M. \<forall>xa\<in>I'. x \<notin> A xa "
  2093     by auto
  2094   with insert.hyps insert.IH[symmetric]
  2095   show ?case
  2096     by (auto intro!: set_integral_Un_AE sets.finite_UN f set_integrable_UN)
  2097 qed (simp add: set_lebesgue_integral_def)
  2098 
  2099 lemma set_integrable_norm:
  2100   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  2101   assumes f: "set_integrable M k f" shows "set_integrable M k (\<lambda>x. norm (f x))"
  2102   using integrable_norm f by (force simp add: set_integrable_def)
  2103  
  2104 lemma absolutely_integrable_bounded_variation:
  2105   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  2106   assumes f: "f absolutely_integrable_on UNIV"
  2107   obtains B where "\<forall>d. d division_of (\<Union>d) \<longrightarrow> sum (\<lambda>k. norm (integral k f)) d \<le> B"
  2108 proof (rule that[of "integral UNIV (\<lambda>x. norm (f x))"]; safe)
  2109   fix d :: "'a set set" assume d: "d division_of \<Union>d"
  2110   have *: "k \<in> d \<Longrightarrow> f absolutely_integrable_on k" for k
  2111     using f[THEN set_integrable_subset, of k] division_ofD(2,4)[OF d, of k] by auto
  2112   note d' = division_ofD[OF d]
  2113   have "(\<Sum>k\<in>d. norm (integral k f)) = (\<Sum>k\<in>d. norm (LINT x:k|lebesgue. f x))"
  2114     by (intro sum.cong refl arg_cong[where f=norm] set_lebesgue_integral_eq_integral(2)[symmetric] *)
  2115   also have "\<dots> \<le> (\<Sum>k\<in>d. LINT x:k|lebesgue. norm (f x))"
  2116     by (intro sum_mono set_integral_norm_bound *)
  2117   also have "\<dots> = (\<Sum>k\<in>d. integral k (\<lambda>x. norm (f x)))"
  2118     by (intro sum.cong refl set_lebesgue_integral_eq_integral(2) set_integrable_norm *)
  2119   also have "\<dots> \<le> integral (\<Union>d) (\<lambda>x. norm (f x))"
  2120     using integrable_on_subdivision[OF d] assms f unfolding absolutely_integrable_on_def
  2121     by (subst integral_combine_division_topdown[OF _ d]) auto
  2122   also have "\<dots> \<le> integral UNIV (\<lambda>x. norm (f x))"
  2123     using integrable_on_subdivision[OF d] assms unfolding absolutely_integrable_on_def
  2124     by (intro integral_subset_le) auto
  2125   finally show "(\<Sum>k\<in>d. norm (integral k f)) \<le> integral UNIV (\<lambda>x. norm (f x))" .
  2126 qed
  2127 
  2128 lemma absdiff_norm_less:
  2129   assumes "sum (\<lambda>x. norm (f x - g x)) s < e"
  2130     and "finite s"
  2131   shows "\<bar>sum (\<lambda>x. norm(f x)) s - sum (\<lambda>x. norm(g x)) s\<bar> < e"
  2132   unfolding sum_subtractf[symmetric]
  2133   apply (rule le_less_trans[OF sum_abs])
  2134   apply (rule le_less_trans[OF _ assms(1)])
  2135   apply (rule sum_mono)
  2136   apply (rule norm_triangle_ineq3)
  2137   done
  2138 
  2139 proposition bounded_variation_absolutely_integrable_interval:
  2140   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  2141   assumes f: "f integrable_on cbox a b"
  2142     and *: "\<And>d. d division_of (cbox a b) \<Longrightarrow> sum (\<lambda>K. norm(integral K f)) d \<le> B"
  2143   shows "f absolutely_integrable_on cbox a b"
  2144 proof -
  2145   let ?f = "\<lambda>d. \<Sum>K\<in>d. norm (integral K f)" and ?D = "{d. d division_of (cbox a b)}"
  2146   have D_1: "?D \<noteq> {}"
  2147     by (rule elementary_interval[of a b]) auto
  2148   have D_2: "bdd_above (?f`?D)"
  2149     by (metis * mem_Collect_eq bdd_aboveI2)
  2150   note D = D_1 D_2
  2151   let ?S = "SUP x\<in>?D. ?f x"
  2152   have *: "\<exists>\<gamma>. gauge \<gamma> \<and>
  2153              (\<forall>p. p tagged_division_of cbox a b \<and>
  2154                   \<gamma> fine p \<longrightarrow>
  2155                   norm ((\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x)) - ?S) < e)"
  2156     if e: "e > 0" for e
  2157   proof -
  2158     have "?S - e/2 < ?S" using \<open>e > 0\<close> by simp
  2159     then obtain d where d: "d division_of (cbox a b)" "?S - e/2 < (\<Sum>k\<in>d. norm (integral k f))"
  2160       unfolding less_cSUP_iff[OF D] by auto
  2161     note d' = division_ofD[OF this(1)]
  2162 
  2163     have "\<exists>e>0. \<forall>i\<in>d. x \<notin> i \<longrightarrow> ball x e \<inter> i = {}" for x
  2164     proof -
  2165       have "\<exists>d'>0. \<forall>x'\<in>\<Union>{i \<in> d. x \<notin> i}. d' \<le> dist x x'"
  2166       proof (rule separate_point_closed)
  2167         show "closed (\<Union>{i \<in> d. x \<notin> i})"
  2168           using d' by force
  2169         show "x \<notin> \<Union>{i \<in> d. x \<notin> i}"
  2170           by auto
  2171       qed 
  2172       then show ?thesis
  2173         by force
  2174     qed
  2175     then obtain k where k: "\<And>x. 0 < k x" "\<And>i x. \<lbrakk>i \<in> d; x \<notin> i\<rbrakk> \<Longrightarrow> ball x (k x) \<inter> i = {}"
  2176       by metis
  2177     have "e/2 > 0"
  2178       using e by auto
  2179     with Henstock_lemma[OF f] 
  2180     obtain \<gamma> where g: "gauge \<gamma>"
  2181       "\<And>p. \<lbrakk>p tagged_partial_division_of cbox a b; \<gamma> fine p\<rbrakk> 
  2182                 \<Longrightarrow> (\<Sum>(x,k) \<in> p. norm (content k *\<^sub>R f x - integral k f)) < e/2"
  2183       by (metis (no_types, lifting))      
  2184     let ?g = "\<lambda>x. \<gamma> x \<inter> ball x (k x)"
  2185     show ?thesis 
  2186     proof (intro exI conjI allI impI)
  2187       show "gauge ?g"
  2188         using g(1) k(1) by (auto simp: gauge_def)
  2189     next
  2190       fix p
  2191       assume "p tagged_division_of (cbox a b) \<and> ?g fine p"
  2192       then have p: "p tagged_division_of cbox a b" "\<gamma> fine p" "(\<lambda>x. ball x (k x)) fine p"
  2193         by (auto simp: fine_Int)
  2194       note p' = tagged_division_ofD[OF p(1)]
  2195       define p' where "p' = {(x,k) | x k. \<exists>i l. x \<in> i \<and> i \<in> d \<and> (x,l) \<in> p \<and> k = i \<inter> l}"
  2196       have gp': "\<gamma> fine p'"
  2197         using p(2) by (auto simp: p'_def fine_def)
  2198       have p'': "p' tagged_division_of (cbox a b)"
  2199       proof (rule tagged_division_ofI)
  2200         show "finite p'"
  2201         proof (rule finite_subset)
  2202           show "p' \<subseteq> (\<lambda>(k, x, l). (x, k \<inter> l)) ` (d \<times> p)"
  2203             by (force simp: p'_def image_iff)
  2204           show "finite ((\<lambda>(k, x, l). (x, k \<inter> l)) ` (d \<times> p))"
  2205             by (simp add: d'(1) p'(1))
  2206         qed
  2207       next
  2208         fix x K
  2209         assume "(x, K) \<in> p'"
  2210         then have "\<exists>i l. x \<in> i \<and> i \<in> d \<and> (x, l) \<in> p \<and> K = i \<inter> l"
  2211           unfolding p'_def by auto
  2212         then obtain i l where il: "x \<in> i" "i \<in> d" "(x, l) \<in> p" "K = i \<inter> l" by blast
  2213         show "x \<in> K" and "K \<subseteq> cbox a b"
  2214           using p'(2-3)[OF il(3)] il by auto
  2215         show "\<exists>a b. K = cbox a b"
  2216           unfolding il using p'(4)[OF il(3)] d'(4)[OF il(2)] by (meson Int_interval)
  2217       next
  2218         fix x1 K1
  2219         assume "(x1, K1) \<in> p'"
  2220         then have "\<exists>i l. x1 \<in> i \<and> i \<in> d \<and> (x1, l) \<in> p \<and> K1 = i \<inter> l"
  2221           unfolding p'_def by auto
  2222         then obtain i1 l1 where il1: "x1 \<in> i1" "i1 \<in> d" "(x1, l1) \<in> p" "K1 = i1 \<inter> l1" by blast
  2223         fix x2 K2
  2224         assume "(x2,K2) \<in> p'"
  2225         then have "\<exists>i l. x2 \<in> i \<and> i \<in> d \<and> (x2, l) \<in> p \<and> K2 = i \<inter> l"
  2226           unfolding p'_def by auto
  2227         then obtain i2 l2 where il2: "x2 \<in> i2" "i2 \<in> d" "(x2, l2) \<in> p" "K2 = i2 \<inter> l2" by blast
  2228         assume "(x1, K1) \<noteq> (x2, K2)"
  2229         then have "interior i1 \<inter> interior i2 = {} \<or> interior l1 \<inter> interior l2 = {}"
  2230           using d'(5)[OF il1(2) il2(2)] p'(5)[OF il1(3) il2(3)]  by (auto simp: il1 il2)
  2231         then show "interior K1 \<inter> interior K2 = {}"
  2232           unfolding il1 il2 by auto
  2233       next
  2234         have *: "\<forall>(x, X) \<in> p'. X \<subseteq> cbox a b"
  2235           unfolding p'_def using d' by blast
  2236         have "y \<in> \<Union>{K. \<exists>x. (x, K) \<in> p'}" if y: "y \<in> cbox a b" for y
  2237         proof -
  2238           obtain x l where xl: "(x, l) \<in> p" "y \<in> l" 
  2239             using y unfolding p'(6)[symmetric] by auto
  2240           obtain i where i: "i \<in> d" "y \<in> i" 
  2241             using y unfolding d'(6)[symmetric] by auto
  2242           have "x \<in> i"
  2243             using fineD[OF p(3) xl(1)] using k(2) i xl by auto
  2244           then show ?thesis
  2245             unfolding p'_def by (rule_tac X="i \<inter> l" in UnionI) (use i xl in auto)
  2246         qed
  2247         show "\<Union>{K. \<exists>x. (x, K) \<in> p'} = cbox a b"
  2248         proof
  2249           show "\<Union>{k. \<exists>x. (x, k) \<in> p'} \<subseteq> cbox a b"
  2250             using * by auto
  2251         next
  2252           show "cbox a b \<subseteq> \<Union>{k. \<exists>x. (x, k) \<in> p'}"
  2253           proof 
  2254             fix y
  2255             assume y: "y \<in> cbox a b"
  2256             obtain x L where xl: "(x, L) \<in> p" "y \<in> L" 
  2257               using y unfolding p'(6)[symmetric] by auto
  2258             obtain I where i: "I \<in> d" "y \<in> I" 
  2259               using y unfolding d'(6)[symmetric] by auto
  2260             have "x \<in> I"
  2261               using fineD[OF p(3) xl(1)] using k(2) i xl by auto
  2262             then show "y \<in> \<Union>{k. \<exists>x. (x, k) \<in> p'}"
  2263               apply (rule_tac X="I \<inter> L" in UnionI)
  2264               using i xl by (auto simp: p'_def)
  2265           qed
  2266         qed
  2267       qed
  2268 
  2269       then have sum_less_e2: "(\<Sum>(x,K) \<in> p'. norm (content K *\<^sub>R f x - integral K f)) < e/2"
  2270         using g(2) gp' tagged_division_of_def by blast
  2271 
  2272       have "(x, I \<inter> L) \<in> p'" if x: "(x, L) \<in> p" "I \<in> d" and y: "y \<in> I" "y \<in> L"
  2273         for x I L y
  2274       proof -
  2275         have "x \<in> I"
  2276           using fineD[OF p(3) that(1)] k(2)[OF \<open>I \<in> d\<close>] y by auto
  2277         with x have "(\<exists>i l. x \<in> i \<and> i \<in> d \<and> (x, l) \<in> p \<and> I \<inter> L = i \<inter> l)"
  2278           by blast
  2279         then have "(x, I \<inter> L) \<in> p'"
  2280           by (simp add: p'_def)
  2281         with y show ?thesis by auto
  2282       qed
  2283       moreover have "\<exists>y i l. (x, K) = (y, i \<inter> l) \<and> (y, l) \<in> p \<and> i \<in> d \<and> i \<inter> l \<noteq> {}"
  2284         if xK: "(x,K) \<in> p'" for x K
  2285       proof -
  2286         obtain i l where il: "x \<in> i" "i \<in> d" "(x, l) \<in> p" "K = i \<inter> l" 
  2287           using xK unfolding p'_def by auto
  2288         then show ?thesis
  2289           using p'(2) by fastforce
  2290       qed
  2291       ultimately have p'alt: "p' = {(x, I \<inter> L) | x I L. (x,L) \<in> p \<and> I \<in> d \<and> I \<inter> L \<noteq> {}}"
  2292         by auto
  2293       have sum_p': "(\<Sum>(x,K) \<in> p'. norm (integral K f)) = (\<Sum>k\<in>snd ` p'. norm (integral k f))"
  2294         apply (subst sum.over_tagged_division_lemma[OF p'',of "\<lambda>k. norm (integral k f)"])
  2295          apply (auto intro: integral_null simp: content_eq_0_interior)
  2296         done
  2297       have snd_p_div: "snd ` p division_of cbox a b"
  2298         by (rule division_of_tagged_division[OF p(1)])
  2299       note snd_p = division_ofD[OF snd_p_div]
  2300       have fin_d_sndp: "finite (d \<times> snd ` p)"
  2301         by (simp add: d'(1) snd_p(1))
  2302 
  2303       have *: "\<And>sni sni' sf sf'. \<lbrakk>\<bar>sf' - sni'\<bar> < e/2; ?S - e/2 < sni; sni' \<le> ?S;
  2304                        sni \<le> sni'; sf' = sf\<rbrakk> \<Longrightarrow> \<bar>sf - ?S\<bar> < e"
  2305         by arith
  2306       show "norm ((\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x)) - ?S) < e"
  2307         unfolding real_norm_def
  2308       proof (rule *)
  2309         show "\<bar>(\<Sum>(x,K)\<in>p'. norm (content K *\<^sub>R f x)) - (\<Sum>(x,k)\<in>p'. norm (integral k f))\<bar> < e/2"
  2310           using p'' sum_less_e2 unfolding split_def by (force intro!: absdiff_norm_less)
  2311         show "(\<Sum>(x,k) \<in> p'. norm (integral k f)) \<le>?S"
  2312           by (auto simp: sum_p' division_of_tagged_division[OF p''] D intro!: cSUP_upper)
  2313         show "(\<Sum>k\<in>d. norm (integral k f)) \<le> (\<Sum>(x,k) \<in> p'. norm (integral k f))"
  2314         proof -
  2315           have *: "{k \<inter> l | k l. k \<in> d \<and> l \<in> snd ` p} = (\<lambda>(k,l). k \<inter> l) ` (d \<times> snd ` p)"
  2316             by auto
  2317           have "(\<Sum>K\<in>d. norm (integral K f)) \<le> (\<Sum>i\<in>d. \<Sum>l\<in>snd ` p. norm (integral (i \<inter> l) f))"
  2318           proof (rule sum_mono)
  2319             fix K assume k: "K \<in> d"
  2320             from d'(4)[OF this] obtain u v where uv: "K = cbox u v" by metis
  2321             define d' where "d' = {cbox u v \<inter> l |l. l \<in> snd ` p \<and>  cbox u v \<inter> l \<noteq> {}}"
  2322             have uvab: "cbox u v \<subseteq> cbox a b"
  2323               using d(1) k uv by blast
  2324             have "d' division_of cbox u v"
  2325               unfolding d'_def by (rule division_inter_1 [OF snd_p_div uvab])
  2326             moreover then have "norm (\<Sum>i\<in>d'. integral i f) \<le> (\<Sum>k\<in>d'. norm (integral k f))"
  2327               by (simp add: sum_norm_le)
  2328             ultimately have "norm (integral K f) \<le> sum (\<lambda>k. norm (integral k f)) d'"
  2329               apply (subst integral_combine_division_topdown[of _ _ d'])
  2330                 apply (auto simp: uv intro: integrable_on_subcbox[OF assms(1) uvab])
  2331               done
  2332             also have "\<dots> = (\<Sum>I\<in>{K \<inter> L |L. L \<in> snd ` p}. norm (integral I f))"
  2333             proof -
  2334               have *: "norm (integral I f) = 0"
  2335                 if "I \<in> {cbox u v \<inter> l |l. l \<in> snd ` p}"
  2336                   "I \<notin> {cbox u v \<inter> l |l. l \<in> snd ` p \<and> cbox u v \<inter> l \<noteq> {}}" for I
  2337                 using that by auto
  2338               show ?thesis
  2339                 apply (rule sum.mono_neutral_left)
  2340                   apply (simp add: snd_p(1))
  2341                 unfolding d'_def uv using * by auto 
  2342             qed
  2343             also have "\<dots> = (\<Sum>l\<in>snd ` p. norm (integral (K \<inter> l) f))"
  2344             proof -
  2345               have *: "norm (integral (K \<inter> l) f) = 0"
  2346                 if "l \<in> snd ` p" "y \<in> snd ` p" "l \<noteq> y" "K \<inter> l = K \<inter> y" for l y
  2347               proof -
  2348                 have "interior (K \<inter> l) \<subseteq> interior (l \<inter> y)"
  2349                   by (metis Int_lower2 interior_mono le_inf_iff that(4))
  2350                 then have "interior (K \<inter> l) = {}"
  2351                   by (simp add: snd_p(5) that) 
  2352                 moreover from d'(4)[OF k] snd_p(4)[OF that(1)] 
  2353                 obtain u1 v1 u2 v2
  2354                   where uv: "K = cbox u1 u2" "l = cbox v1 v2" by metis
  2355                 ultimately show ?thesis
  2356                   using that integral_null
  2357                   unfolding uv Int_interval content_eq_0_interior
  2358                   by (metis (mono_tags, lifting) norm_eq_zero)
  2359               qed
  2360               show ?thesis
  2361                 unfolding Setcompr_eq_image
  2362                 apply (rule sum.reindex_nontrivial [unfolded o_def])
  2363                  apply (rule finite_imageI)
  2364                  apply (rule p')
  2365                 using * by auto
  2366             qed
  2367             finally show "norm (integral K f) \<le> (\<Sum>l\<in>snd ` p. norm (integral (K \<inter> l) f))" .
  2368           qed
  2369           also have "\<dots> = (\<Sum>(i,l) \<in> d \<times> snd ` p. norm (integral (i\<inter>l) f))"
  2370             by (simp add: sum.cartesian_product)
  2371           also have "\<dots> = (\<Sum>x \<in> d \<times> snd ` p. norm (integral (case_prod (\<inter>) x) f))"
  2372             by (force simp: split_def intro!: sum.cong)
  2373           also have "\<dots> = (\<Sum>k\<in>{i \<inter> l |i l. i \<in> d \<and> l \<in> snd ` p}. norm (integral k f))"
  2374           proof -
  2375             have eq0: " (integral (l1 \<inter> k1) f) = 0"
  2376               if "l1 \<inter> k1 = l2 \<inter> k2" "(l1, k1) \<noteq> (l2, k2)"
  2377                 "l1 \<in> d" "(j1,k1) \<in> p" "l2 \<in> d" "(j2,k2) \<in> p"
  2378               for l1 l2 k1 k2 j1 j2
  2379             proof -
  2380               obtain u1 v1 u2 v2 where uv: "l1 = cbox u1 u2" "k1 = cbox v1 v2"
  2381                 using \<open>(j1, k1) \<in> p\<close> \<open>l1 \<in> d\<close> d'(4) p'(4) by blast
  2382               have "l1 \<noteq> l2 \<or> k1 \<noteq> k2"
  2383                 using that by auto
  2384               then have "interior k1 \<inter> interior k2 = {} \<or> interior l1 \<inter> interior l2 = {}"
  2385                 by (meson d'(5) old.prod.inject p'(5) that(3) that(4) that(5) that(6))
  2386               moreover have "interior (l1 \<inter> k1) = interior (l2 \<inter> k2)"
  2387                 by (simp add: that(1))
  2388               ultimately have "interior(l1 \<inter> k1) = {}"
  2389                 by auto
  2390               then show ?thesis
  2391                 unfolding uv Int_interval content_eq_0_interior[symmetric] by auto
  2392             qed
  2393             show ?thesis
  2394               unfolding *
  2395               apply (rule sum.reindex_nontrivial [OF fin_d_sndp, symmetric, unfolded o_def])
  2396               apply clarsimp
  2397               by (metis eq0 fst_conv snd_conv)
  2398           qed
  2399           also have "\<dots> = (\<Sum>(x,k) \<in> p'. norm (integral k f))"
  2400           proof -
  2401             have 0: "integral (ia \<inter> snd (a, b)) f = 0"
  2402               if "ia \<inter> snd (a, b) \<notin> snd ` p'" "ia \<in> d" "(a, b) \<in> p" for ia a b
  2403             proof -
  2404               have "ia \<inter> b = {}"
  2405                 using that unfolding p'alt image_iff Bex_def not_ex
  2406                 apply (erule_tac x="(a, ia \<inter> b)" in allE)
  2407                 apply auto
  2408                 done
  2409               then show ?thesis by auto
  2410             qed
  2411             have 1: "\<exists>i l. snd (a, b) = i \<inter> l \<and> i \<in> d \<and> l \<in> snd ` p" if "(a, b) \<in> p'" for a b
  2412               using that 
  2413               apply (clarsimp simp: p'_def image_iff)
  2414               by (metis (no_types, hide_lams) snd_conv)
  2415             show ?thesis
  2416               unfolding sum_p'
  2417               apply (rule sum.mono_neutral_right)
  2418                 apply (metis * finite_imageI[OF fin_d_sndp])
  2419               using 0 1 by auto
  2420           qed
  2421           finally show ?thesis .
  2422         qed
  2423         show "(\<Sum>(x,k) \<in> p'. norm (content k *\<^sub>R f x)) = (\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x))"
  2424         proof -
  2425           let ?S = "{(x, i \<inter> l) |x i l. (x, l) \<in> p \<and> i \<in> d}"
  2426           have *: "?S = (\<lambda>(xl,i). (fst xl, snd xl \<inter> i)) ` (p \<times> d)"
  2427             by force
  2428           have fin_pd: "finite (p \<times> d)"
  2429             using finite_cartesian_product[OF p'(1) d'(1)] by metis
  2430           have "(\<Sum>(x,k) \<in> p'. norm (content k *\<^sub>R f x)) = (\<Sum>(x,k) \<in> ?S. \<bar>content k\<bar> * norm (f x))"
  2431             unfolding norm_scaleR
  2432             apply (rule sum.mono_neutral_left)
  2433               apply (subst *)
  2434               apply (rule finite_imageI [OF fin_pd])
  2435             unfolding p'alt apply auto
  2436             by fastforce
  2437           also have "\<dots> = (\<Sum>((x,l),i)\<in>p \<times> d. \<bar>content (l \<inter> i)\<bar> * norm (f x))"
  2438           proof -
  2439             have "\<bar>content (l1 \<inter> k1)\<bar> * norm (f x1) = 0"
  2440               if "(x1, l1) \<in> p" "(x2, l2) \<in> p" "k1 \<in> d" "k2 \<in> d"
  2441                 "x1 = x2" "l1 \<inter> k1 = l2 \<inter> k2" "x1 \<noteq> x2 \<or> l1 \<noteq> l2 \<or> k1 \<noteq> k2"
  2442               for x1 l1 k1 x2 l2 k2
  2443             proof -
  2444               obtain u1 v1 u2 v2 where uv: "k1 = cbox u1 u2" "l1 = cbox v1 v2"
  2445                 by (meson \<open>(x1, l1) \<in> p\<close> \<open>k1 \<in> d\<close> d(1) division_ofD(4) p'(4))
  2446               have "l1 \<noteq> l2 \<or> k1 \<noteq> k2"
  2447                 using that by auto
  2448               then have "interior k1 \<inter> interior k2 = {} \<or> interior l1 \<inter> interior l2 = {}"
  2449                 apply (rule disjE)
  2450                 using that p'(5) d'(5) by auto
  2451               moreover have "interior (l1 \<inter> k1) = interior (l2 \<inter> k2)"
  2452                 unfolding that ..
  2453               ultimately have "interior (l1 \<inter> k1) = {}"
  2454                 by auto
  2455               then show "\<bar>content (l1 \<inter> k1)\<bar> * norm (f x1) = 0"
  2456                 unfolding uv Int_interval content_eq_0_interior[symmetric] by auto
  2457             qed 
  2458             then show ?thesis
  2459               unfolding *
  2460               apply (subst sum.reindex_nontrivial [OF fin_pd])
  2461               unfolding split_paired_all o_def split_def prod.inject
  2462                apply force+
  2463               done
  2464           qed
  2465           also have "\<dots> = (\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x))"
  2466           proof -
  2467             have sumeq: "(\<Sum>i\<in>d. content (l \<inter> i) * norm (f x)) = content l * norm (f x)"
  2468               if "(x, l) \<in> p" for x l
  2469             proof -
  2470               note xl = p'(2-4)[OF that]
  2471               then obtain u v where uv: "l = cbox u v" by blast
  2472               have "(\<Sum>i\<in>d. \<bar>content (l \<inter> i)\<bar>) = (\<Sum>k\<in>d. content (k \<inter> cbox u v))"
  2473                 by (simp add: Int_commute uv)
  2474               also have "\<dots> = sum content {k \<inter> cbox u v| k. k \<in> d}"
  2475               proof -
  2476                 have eq0: "content (k \<inter> cbox u v) = 0"
  2477                   if "k \<in> d" "y \<in> d" "k \<noteq> y" and eq: "k \<inter> cbox u v = y \<inter> cbox u v" for k y
  2478                 proof -
  2479                   from d'(4)[OF that(1)] d'(4)[OF that(2)]
  2480                   obtain \<alpha> \<beta> where \<alpha>: "k \<inter> cbox u v = cbox \<alpha> \<beta>"
  2481                     by (meson Int_interval)
  2482                   have "{} = interior ((k \<inter> y) \<inter> cbox u v)"
  2483                     by (simp add: d'(5) that)
  2484                   also have "\<dots> = interior (y \<inter> (k \<inter> cbox u v))"
  2485                     by auto
  2486                   also have "\<dots> = interior (k \<inter> cbox u v)"
  2487                     unfolding eq by auto
  2488                   finally show ?thesis
  2489                     unfolding \<alpha> content_eq_0_interior ..
  2490                 qed
  2491                 then show ?thesis
  2492                   unfolding Setcompr_eq_image
  2493                   apply (rule sum.reindex_nontrivial [OF \<open>finite d\<close>, unfolded o_def, symmetric])
  2494                   by auto
  2495               qed
  2496               also have "\<dots> = sum content {cbox u v \<inter> k |k. k \<in> d \<and> cbox u v \<inter> k \<noteq> {}}"
  2497                 apply (rule sum.mono_neutral_right)
  2498                 unfolding Setcompr_eq_image
  2499                   apply (rule finite_imageI [OF \<open>finite d\<close>])
  2500                  apply (fastforce simp: inf.commute)+
  2501                 done
  2502               finally show "(\<Sum>i\<in>d. content (l \<inter> i) * norm (f x)) = content l * norm (f x)"
  2503                 unfolding sum_distrib_right[symmetric] real_scaleR_def
  2504                 apply (subst(asm) additive_content_division[OF division_inter_1[OF d(1)]])
  2505                 using xl(2)[unfolded uv] unfolding uv apply auto
  2506                 done
  2507             qed
  2508             show ?thesis
  2509               by (subst sum_Sigma_product[symmetric]) (auto intro!: sumeq sum.cong p' d')
  2510           qed
  2511           finally show ?thesis .
  2512         qed
  2513       qed (rule d)
  2514     qed 
  2515   qed
  2516   then show ?thesis
  2517     using absolutely_integrable_onI [OF f has_integral_integrable] has_integral[of _ ?S]
  2518     by blast
  2519 qed
  2520 
  2521 
  2522 lemma bounded_variation_absolutely_integrable:
  2523   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  2524   assumes "f integrable_on UNIV"
  2525     and "\<forall>d. d division_of (\<Union>d) \<longrightarrow> sum (\<lambda>k. norm (integral k f)) d \<le> B"
  2526   shows "f absolutely_integrable_on UNIV"
  2527 proof (rule absolutely_integrable_onI, fact)
  2528   let ?f = "\<lambda>d. \<Sum>k\<in>d. norm (integral k f)" and ?D = "{d. d division_of  (\<Union>d)}"
  2529   have D_1: "?D \<noteq> {}"
  2530     by (rule elementary_interval) auto
  2531   have D_2: "bdd_above (?f`?D)"
  2532     by (intro bdd_aboveI2[where M=B] assms(2)[rule_format]) simp
  2533   note D = D_1 D_2
  2534   let ?S = "SUP d\<in>?D. ?f d"
  2535   have "\<And>a b. f integrable_on cbox a b"
  2536     using assms(1) integrable_on_subcbox by blast
  2537   then have f_int: "\<And>a b. f absolutely_integrable_on cbox a b"
  2538     apply (rule bounded_variation_absolutely_integrable_interval[where B=B])
  2539     using assms(2) apply blast
  2540     done
  2541   have "((\<lambda>x. norm (f x)) has_integral ?S) UNIV"
  2542     apply (subst has_integral_alt')
  2543     apply safe
  2544   proof goal_cases
  2545     case (1 a b)
  2546     show ?case
  2547       using f_int[of a b] unfolding absolutely_integrable_on_def by auto
  2548   next
  2549     case prems: (2 e)
  2550     have "\<exists>y\<in>sum (\<lambda>k. norm (integral k f)) ` {d. d division_of \<Union>d}. \<not> y \<le> ?S - e"
  2551     proof (rule ccontr)
  2552       assume "\<not> ?thesis"
  2553       then have "?S \<le> ?S - e"
  2554         by (intro cSUP_least[OF D(1)]) auto
  2555       then show False
  2556         using prems by auto
  2557     qed
  2558     then obtain d K where ddiv: "d division_of \<Union>d" and "K = (\<Sum>k\<in>d. norm (integral k f))"
  2559       "Sup (sum (\<lambda>k. norm (integral k f)) ` {d. d division_of \<Union> d}) - e < K"
  2560       by (auto simp add: image_iff not_le)
  2561     then have d: "Sup (sum (\<lambda>k. norm (integral k f)) ` {d. d division_of \<Union> d}) - e 
  2562                   < (\<Sum>k\<in>d. norm (integral k f))"
  2563       by auto
  2564     note d'=division_ofD[OF ddiv]
  2565     have "bounded (\<Union>d)"
  2566       by (rule elementary_bounded,fact)
  2567     from this[unfolded bounded_pos] obtain K where
  2568        K: "0 < K" "\<forall>x\<in>\<Union>d. norm x \<le> K" by auto
  2569     show ?case
  2570     proof (intro conjI impI allI exI)
  2571       fix a b :: 'n
  2572       assume ab: "ball 0 (K + 1) \<subseteq> cbox a b"
  2573       have *: "\<And>s s1. \<lbrakk>?S - e < s1; s1 \<le> s; s < ?S + e\<rbrakk> \<Longrightarrow> \<bar>s - ?S\<bar> < e"
  2574         by arith
  2575       show "norm (integral (cbox a b) (\<lambda>x. if x \<in> UNIV then norm (f x) else 0) - ?S) < e"
  2576         unfolding real_norm_def
  2577       proof (rule * [OF d])
  2578         have "(\<Sum>k\<in>d. norm (integral k f)) \<le> sum (\<lambda>k. integral k (\<lambda>x. norm (f x))) d"
  2579         proof (intro sum_mono)
  2580           fix k assume "k \<in> d"
  2581           with d'(4) f_int show "norm (integral k f) \<le> integral k (\<lambda>x. norm (f x))"
  2582             by (force simp: absolutely_integrable_on_def integral_norm_bound_integral)
  2583         qed
  2584         also have "\<dots> = integral (\<Union>d) (\<lambda>x. norm (f x))"
  2585           apply (rule integral_combine_division_bottomup[OF ddiv, symmetric])
  2586           using absolutely_integrable_on_def d'(4) f_int by blast
  2587         also have "\<dots> \<le> integral (cbox a b) (\<lambda>x. if x \<in> UNIV then norm (f x) else 0)"
  2588         proof -
  2589           have "\<Union>d \<subseteq> cbox a b"
  2590             using K(2) ab by fastforce
  2591           then show ?thesis
  2592             using integrable_on_subdivision[OF ddiv] f_int[of a b] unfolding absolutely_integrable_on_def
  2593             by (auto intro!: integral_subset_le)
  2594         qed
  2595         finally show "(\<Sum>k\<in>d. norm (integral k f))
  2596                       \<le> integral (cbox a b) (\<lambda>x. if x \<in> UNIV then norm (f x) else 0)" .
  2597       next
  2598         have "e/2>0"
  2599           using \<open>e > 0\<close> by auto
  2600         moreover
  2601         have f: "f integrable_on cbox a b" "(\<lambda>x. norm (f x)) integrable_on cbox a b"
  2602           using f_int by (auto simp: absolutely_integrable_on_def)
  2603         ultimately obtain d1 where "gauge d1"
  2604            and d1: "\<And>p. \<lbrakk>p tagged_division_of (cbox a b); d1 fine p\<rbrakk> \<Longrightarrow>
  2605             norm ((\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x)) - integral (cbox a b) (\<lambda>x. norm (f x))) < e/2"
  2606           unfolding has_integral_integral has_integral by meson
  2607         obtain d2 where "gauge d2" 
  2608           and d2: "\<And>p. \<lbrakk>p tagged_partial_division_of (cbox a b); d2 fine p\<rbrakk> \<Longrightarrow>
  2609             (\<Sum>(x,k) \<in> p. norm (content k *\<^sub>R f x - integral k f)) < e/2"
  2610           by (blast intro: Henstock_lemma [OF f(1) \<open>e/2>0\<close>])
  2611         obtain p where
  2612           p: "p tagged_division_of (cbox a b)" "d1 fine p" "d2 fine p"
  2613           by (rule fine_division_exists [OF gauge_Int [OF \<open>gauge d1\<close> \<open>gauge d2\<close>], of a b])
  2614             (auto simp add: fine_Int)
  2615         have *: "\<And>sf sf' si di. \<lbrakk>sf' = sf; si \<le> ?S; \<bar>sf - si\<bar> < e/2;
  2616                       \<bar>sf' - di\<bar> < e/2\<rbrakk> \<Longrightarrow> di < ?S + e"
  2617           by arith
  2618         have "integral (cbox a b) (\<lambda>x. norm (f x)) < ?S + e"
  2619         proof (rule *)
  2620           show "\<bar>(\<Sum>(x,k)\<in>p. norm (content k *\<^sub>R f x)) - (\<Sum>(x,k)\<in>p. norm (integral k f))\<bar> < e/2"
  2621             unfolding split_def
  2622             apply (rule absdiff_norm_less)
  2623             using d2[of p] p(1,3) apply (auto simp: tagged_division_of_def split_def)
  2624             done
  2625           show "\<bar>(\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x)) - integral (cbox a b) (\<lambda>x. norm(f x))\<bar> < e/2"
  2626             using d1[OF p(1,2)] by (simp only: real_norm_def)
  2627           show "(\<Sum>(x,k) \<in> p. content k *\<^sub>R norm (f x)) = (\<Sum>(x,k) \<in> p. norm (content k *\<^sub>R f x))"
  2628             by (auto simp: split_paired_all sum.cong [OF refl])
  2629           show "(\<Sum>(x,k) \<in> p. norm (integral k f)) \<le> ?S"
  2630             using partial_division_of_tagged_division[of p "cbox a b"] p(1)
  2631             apply (subst sum.over_tagged_division_lemma[OF p(1)])
  2632             apply (auto simp: content_eq_0_interior tagged_partial_division_of_def intro!: cSUP_upper2 D)
  2633             done
  2634         qed
  2635         then show "integral (cbox a b) (\<lambda>x. if x \<in> UNIV then norm (f x) else 0) < ?S + e"
  2636           by simp
  2637       qed
  2638     qed (insert K, auto)
  2639   qed
  2640   then show "(\<lambda>x. norm (f x)) integrable_on UNIV"
  2641     by blast
  2642 qed
  2643 
  2644 
  2645 subsection\<open>Outer and inner approximation of measurable sets by well-behaved sets.\<close>
  2646 
  2647 proposition measurable_outer_intervals_bounded:
  2648   assumes "S \<in> lmeasurable" "S \<subseteq> cbox a b" "e > 0"
  2649   obtains \<D>
  2650   where "countable \<D>"
  2651         "\<And>K. K \<in> \<D> \<Longrightarrow> K \<subseteq> cbox a b \<and> K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  2652         "pairwise (\<lambda>A B. interior A \<inter> interior B = {}) \<D>"
  2653         "\<And>u v. cbox u v \<in> \<D> \<Longrightarrow> \<exists>n. \<forall>i \<in> Basis. v \<bullet> i - u \<bullet> i = (b \<bullet> i - a \<bullet> i)/2^n"
  2654         "\<And>K. \<lbrakk>K \<in> \<D>; box a b \<noteq> {}\<rbrakk> \<Longrightarrow> interior K \<noteq> {}"
  2655         "S \<subseteq> \<Union>\<D>" "\<Union>\<D> \<in> lmeasurable" "measure lebesgue (\<Union>\<D>) \<le> measure lebesgue S + e"
  2656 proof (cases "box a b = {}")
  2657   case True
  2658   show ?thesis
  2659   proof (cases "cbox a b = {}")
  2660     case True
  2661     with assms have [simp]: "S = {}"
  2662       by auto
  2663     show ?thesis
  2664     proof
  2665       show "countable {}"
  2666         by simp
  2667     qed (use \<open>e > 0\<close> in auto)
  2668   next
  2669     case False
  2670     show ?thesis
  2671     proof
  2672       show "countable {cbox a b}"
  2673         by simp
  2674       show "\<And>u v. cbox u v \<in> {cbox a b} \<Longrightarrow> \<exists>n. \<forall>i\<in>Basis. v \<bullet> i - u \<bullet> i = (b \<bullet> i - a \<bullet> i)/2 ^ n"
  2675         using False by (force simp: eq_cbox intro: exI [where x=0])
  2676       show "measure lebesgue (\<Union>{cbox a b}) \<le> measure lebesgue S + e"
  2677         using assms by (simp add: sum_content.box_empty_imp [OF True])
  2678     qed (use assms \<open>cbox a b \<noteq> {}\<close> in auto)
  2679   qed
  2680 next
  2681   case False
  2682   let ?\<mu> = "measure lebesgue"
  2683   have "S \<inter> cbox a b \<in> lmeasurable"
  2684     using \<open>S \<in> lmeasurable\<close> by blast
  2685   then have indS_int: "(indicator S has_integral (?\<mu> S)) (cbox a b)"
  2686     by (metis integral_indicator \<open>S \<subseteq> cbox a b\<close> has_integral_integrable_integral inf.orderE integrable_on_indicator)
  2687   with \<open>e > 0\<close> obtain \<gamma> where "gauge \<gamma>" and \<gamma>:
  2688     "\<And>\<D>. \<lbrakk>\<D> tagged_division_of (cbox a b); \<gamma> fine \<D>\<rbrakk> \<Longrightarrow> norm ((\<Sum>(x,K)\<in>\<D>. content(K) *\<^sub>R indicator S x) - ?\<mu> S) < e"
  2689     by (force simp: has_integral)
  2690   have inteq: "integral (cbox a b) (indicat_real S) = integral UNIV (indicator S)"
  2691     using assms by (metis has_integral_iff indS_int lmeasure_integral_UNIV)
  2692   obtain \<D> where \<D>: "countable \<D>"  "\<Union>\<D> \<subseteq> cbox a b"
  2693             and cbox: "\<And>K. K \<in> \<D> \<Longrightarrow> interior K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  2694             and djointish: "pairwise (\<lambda>A B. interior A \<inter> interior B = {}) \<D>"
  2695             and covered: "\<And>K. K \<in> \<D> \<Longrightarrow> \<exists>x \<in> S \<inter> K. K \<subseteq> \<gamma> x"
  2696             and close: "\<And>u v. cbox u v \<in> \<D> \<Longrightarrow> \<exists>n. \<forall>i \<in> Basis. v\<bullet>i - u\<bullet>i = (b\<bullet>i - a\<bullet>i)/2^n"
  2697             and covers: "S \<subseteq> \<Union>\<D>"
  2698     using covering_lemma [of S a b \<gamma>] \<open>gauge \<gamma>\<close> \<open>box a b \<noteq> {}\<close> assms by force
  2699   show ?thesis
  2700   proof
  2701     show "\<And>K. K \<in> \<D> \<Longrightarrow> K \<subseteq> cbox a b \<and> K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  2702       by (meson Sup_le_iff \<D>(2) cbox interior_empty)
  2703     have negl_int: "negligible(K \<inter> L)" if "K \<in> \<D>" "L \<in> \<D>" "K \<noteq> L" for K L
  2704     proof -
  2705       have "interior K \<inter> interior L = {}"
  2706         using djointish pairwiseD that by fastforce
  2707       moreover obtain u v x y where "K = cbox u v" "L = cbox x y"
  2708         using cbox \<open>K \<in> \<D>\<close> \<open>L \<in> \<D>\<close> by blast
  2709       ultimately show ?thesis
  2710         by (simp add: Int_interval box_Int_box negligible_interval(1))
  2711     qed
  2712     have fincase: "\<Union>\<F> \<in> lmeasurable \<and> ?\<mu> (\<Union>\<F>) \<le> ?\<mu> S + e" if "finite \<F>" "\<F> \<subseteq> \<D>" for \<F>
  2713     proof -
  2714       obtain t where t: "\<And>K. K \<in> \<F> \<Longrightarrow> t K \<in> S \<inter> K \<and> K \<subseteq> \<gamma>(t K)"
  2715         using covered \<open>\<F> \<subseteq> \<D>\<close> subsetD by metis
  2716       have "\<forall>K \<in> \<F>. \<forall>L \<in> \<F>. K \<noteq> L \<longrightarrow> interior K \<inter> interior L = {}"
  2717         using that djointish by (simp add: pairwise_def) (metis subsetD)
  2718       with cbox that \<D> have \<F>div: "\<F> division_of (\<Union>\<F>)"
  2719         by (fastforce simp: division_of_def dest: cbox)
  2720       then have 1: "\<Union>\<F> \<in> lmeasurable"
  2721         by blast
  2722       have norme: "\<And>p. \<lbrakk>p tagged_division_of cbox a b; \<gamma> fine p\<rbrakk>
  2723           \<Longrightarrow> norm ((\<Sum>(x,K)\<in>p. content K * indicator S x) - integral (cbox a b) (indicator S)) < e"
  2724         by (auto simp: lmeasure_integral_UNIV assms inteq dest: \<gamma>)
  2725       have "\<forall>x K y L. (x,K) \<in> (\<lambda>K. (t K,K)) ` \<F> \<and> (y,L) \<in> (\<lambda>K. (t K,K)) ` \<F> \<and> (x,K) \<noteq> (y,L) \<longrightarrow>             interior K \<inter> interior L = {}"
  2726         using that djointish  by (clarsimp simp: pairwise_def) (metis subsetD)
  2727       with that \<D> have tagged: "(\<lambda>K. (t K, K)) ` \<F> tagged_partial_division_of cbox a b"
  2728         by (auto simp: tagged_partial_division_of_def dest: t cbox)
  2729       have fine: "\<gamma> fine (\<lambda>K. (t K, K)) ` \<F>"
  2730         using t by (auto simp: fine_def)
  2731       have *: "y \<le> ?\<mu> S \<Longrightarrow> \<bar>x - y\<bar> \<le> e \<Longrightarrow> x \<le> ?\<mu> S + e" for x y
  2732         by arith
  2733       have "?\<mu> (\<Union>\<F>) \<le> ?\<mu> S + e"
  2734       proof (rule *)
  2735         have "(\<Sum>K\<in>\<F>. ?\<mu> (K \<inter> S)) = ?\<mu> (\<Union>C\<in>\<F>. C \<inter> S)"
  2736           apply (rule measure_negligible_finite_Union_image [OF \<open>finite \<F>\<close>, symmetric])
  2737           using \<F>div \<open>S \<in> lmeasurable\<close> apply blast
  2738           unfolding pairwise_def
  2739           by (metis inf.commute inf_sup_aci(3) negligible_Int subsetCE negl_int \<open>\<F> \<subseteq> \<D>\<close>)
  2740         also have "\<dots> = ?\<mu> (\<Union>\<F> \<inter> S)"
  2741           by simp
  2742         also have "\<dots> \<le> ?\<mu> S"
  2743           by (simp add: "1" \<open>S \<in> lmeasurable\<close> fmeasurableD measure_mono_fmeasurable sets.Int)
  2744         finally show "(\<Sum>K\<in>\<F>. ?\<mu> (K \<inter> S)) \<le> ?\<mu> S" .
  2745       next
  2746         have "?\<mu> (\<Union>\<F>) = sum ?\<mu> \<F>"
  2747           by (metis \<F>div content_division)
  2748         also have "\<dots> = (\<Sum>K\<in>\<F>. content K)"
  2749           using \<F>div by (force intro: sum.cong)
  2750         also have "\<dots> = (\<Sum>x\<in>\<F>. content x * indicator S (t x))"
  2751           using t by auto
  2752         finally have eq1: "?\<mu> (\<Union>\<F>) = (\<Sum>x\<in>\<F>. content x * indicator S (t x))" .
  2753         have eq2: "(\<Sum>K\<in>\<F>. ?\<mu> (K \<inter> S)) = (\<Sum>K\<in>\<F>. integral K (indicator S))"
  2754           apply (rule sum.cong [OF refl])
  2755           by (metis integral_indicator \<F>div \<open>S \<in> lmeasurable\<close> division_ofD(4) fmeasurable.Int inf.commute lmeasurable_cbox)
  2756         have "\<bar>\<Sum>(x,K)\<in>(\<lambda>K. (t K, K)) ` \<F>. content K * indicator S x - integral K (indicator S)\<bar> \<le> e"
  2757           using Henstock_lemma_part1 [of "indicator S::'a\<Rightarrow>real", OF _ \<open>e > 0\<close> \<open>gauge \<gamma>\<close> _ tagged fine]
  2758             indS_int norme by auto
  2759         then show "\<bar>?\<mu> (\<Union>\<F>) - (\<Sum>K\<in>\<F>. ?\<mu> (K \<inter> S))\<bar> \<le> e"
  2760           by (simp add: eq1 eq2 comm_monoid_add_class.sum.reindex inj_on_def sum_subtractf)
  2761       qed
  2762       with 1 show ?thesis by blast
  2763     qed
  2764     have "\<Union>\<D> \<in> lmeasurable \<and> ?\<mu> (\<Union>\<D>) \<le> ?\<mu> S + e"
  2765     proof (cases "finite \<D>")
  2766       case True
  2767       with fincase show ?thesis
  2768         by blast
  2769     next
  2770       case False
  2771       let ?T = "from_nat_into \<D>"
  2772       have T: "bij_betw ?T UNIV \<D>"
  2773         by (simp add: False \<D>(1) bij_betw_from_nat_into)
  2774       have TM: "\<And>n. ?T n \<in> lmeasurable"
  2775         by (metis False cbox finite.emptyI from_nat_into lmeasurable_cbox)
  2776       have TN: "\<And>m n. m \<noteq> n \<Longrightarrow> negligible (?T m \<inter> ?T n)"
  2777         by (simp add: False \<D>(1) from_nat_into infinite_imp_nonempty negl_int)
  2778       have TB: "(\<Sum>k\<le>n. ?\<mu> (?T k)) \<le> ?\<mu> S + e" for n
  2779       proof -
  2780         have "(\<Sum>k\<le>n. ?\<mu> (?T k)) = ?\<mu> (\<Union> (?T ` {..n}))"
  2781           by (simp add: pairwise_def TM TN measure_negligible_finite_Union_image)
  2782         also have "?\<mu> (\<Union> (?T ` {..n})) \<le> ?\<mu> S + e"
  2783           using fincase [of "?T ` {..n}"] T by (auto simp: bij_betw_def)
  2784         finally show ?thesis .
  2785       qed
  2786       have "\<Union>\<D> \<in> lmeasurable"
  2787         by (metis lmeasurable_compact T \<D>(2) bij_betw_def cbox compact_cbox countable_Un_Int(1) fmeasurableD fmeasurableI2 rangeI)
  2788       moreover
  2789       have "?\<mu> (\<Union>x. from_nat_into \<D> x) \<le> ?\<mu> S + e"
  2790       proof (rule measure_countable_Union_le [OF TM])
  2791         show "?\<mu> (\<Union>x\<le>n. from_nat_into \<D> x) \<le> ?\<mu> S + e" for n
  2792           by (metis (mono_tags, lifting) False fincase finite.emptyI finite_atMost finite_imageI from_nat_into imageE subsetI)
  2793       qed
  2794       ultimately show ?thesis by (metis T bij_betw_def)
  2795     qed
  2796     then show "\<Union>\<D> \<in> lmeasurable" "measure lebesgue (\<Union>\<D>) \<le> ?\<mu> S + e" by blast+
  2797   qed (use \<D> cbox djointish close covers in auto)
  2798 qed
  2799 
  2800 
  2801 subsection\<open>Transformation of measure by linear maps\<close>
  2802 
  2803 lemma measurable_linear_image_interval:
  2804    "linear f \<Longrightarrow> f ` (cbox a b) \<in> lmeasurable"
  2805   by (metis bounded_linear_image linear_linear bounded_cbox closure_bounded_linear_image closure_cbox compact_closure lmeasurable_compact)
  2806 
  2807 proposition measure_linear_sufficient:
  2808   fixes f :: "'n::euclidean_space \<Rightarrow> 'n"
  2809   assumes "linear f" and S: "S \<in> lmeasurable"
  2810     and im: "\<And>a b. measure lebesgue (f ` (cbox a b)) = m * measure lebesgue (cbox a b)"
  2811   shows "f ` S \<in> lmeasurable \<and> m * measure lebesgue S = measure lebesgue (f ` S)"
  2812   using le_less_linear [of 0 m]
  2813 proof
  2814   assume "m < 0"
  2815   then show ?thesis
  2816     using im [of 0 One] by auto
  2817 next
  2818   assume "m \<ge> 0"
  2819   let ?\<mu> = "measure lebesgue"
  2820   show ?thesis
  2821   proof (cases "inj f")
  2822     case False
  2823     then have "?\<mu> (f ` S) = 0"
  2824       using \<open>linear f\<close> negligible_imp_measure0 negligible_linear_singular_image by blast
  2825     then have "m * ?\<mu> (cbox 0 (One)) = 0"
  2826       by (metis False \<open>linear f\<close> cbox_borel content_unit im measure_completion negligible_imp_measure0 negligible_linear_singular_image sets_lborel)
  2827     then show ?thesis
  2828       using \<open>linear f\<close> negligible_linear_singular_image negligible_imp_measure0 False
  2829       by (auto simp: lmeasurable_iff_has_integral negligible_UNIV)
  2830   next
  2831     case True
  2832     then obtain h where "linear h" and hf: "\<And>x. h (f x) = x" and fh: "\<And>x. f (h x) = x"
  2833       using \<open>linear f\<close> linear_injective_isomorphism by blast
  2834     have fBS: "(f ` S) \<in> lmeasurable \<and> m * ?\<mu> S = ?\<mu> (f ` S)"
  2835       if "bounded S" "S \<in> lmeasurable" for S
  2836     proof -
  2837       obtain a b where "S \<subseteq> cbox a b"
  2838         using \<open>bounded S\<close> bounded_subset_cbox_symmetric by metis
  2839       have fUD: "(f ` \<Union>\<D>) \<in> lmeasurable \<and> ?\<mu> (f ` \<Union>\<D>) = (m * ?\<mu> (\<Union>\<D>))"
  2840         if "countable \<D>"
  2841           and cbox: "\<And>K. K \<in> \<D> \<Longrightarrow> K \<subseteq> cbox a b \<and> K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  2842           and intint: "pairwise (\<lambda>A B. interior A \<inter> interior B = {}) \<D>"
  2843         for \<D>
  2844       proof -
  2845         have conv: "\<And>K. K \<in> \<D> \<Longrightarrow> convex K"
  2846           using cbox convex_box(1) by blast
  2847         have neg: "negligible (g ` K \<inter> g ` L)" if "linear g" "K \<in> \<D>" "L \<in> \<D>" "K \<noteq> L"
  2848           for K L and g :: "'n\<Rightarrow>'n"
  2849         proof (cases "inj g")
  2850           case True
  2851           have "negligible (frontier(g ` K \<inter> g ` L) \<union> interior(g ` K \<inter> g ` L))"
  2852           proof (rule negligible_Un)
  2853             show "negligible (frontier (g ` K \<inter> g ` L))"
  2854               by (simp add: negligible_convex_frontier convex_Int conv convex_linear_image that)
  2855           next
  2856             have "\<forall>p N. pairwise p N = (\<forall>Na. (Na::'n set) \<in> N \<longrightarrow> (\<forall>Nb. Nb \<in> N \<and> Na \<noteq> Nb \<longrightarrow> p Na Nb))"
  2857               by (metis pairwise_def)
  2858             then have "interior K \<inter> interior L = {}"
  2859               using intint that(2) that(3) that(4) by presburger
  2860             then show "negligible (interior (g ` K \<inter> g ` L))"
  2861               by (metis True empty_imp_negligible image_Int image_empty interior_Int interior_injective_linear_image that(1))
  2862           qed
  2863           moreover have "g ` K \<inter> g ` L \<subseteq> frontier (g ` K \<inter> g ` L) \<union> interior (g ` K \<inter> g ` L)"
  2864             apply (auto simp: frontier_def)
  2865             using closure_subset contra_subsetD by fastforce+
  2866           ultimately show ?thesis
  2867             by (rule negligible_subset)
  2868         next
  2869           case False
  2870           then show ?thesis
  2871             by (simp add: negligible_Int negligible_linear_singular_image \<open>linear g\<close>)
  2872         qed
  2873         have negf: "negligible ((f ` K) \<inter> (f ` L))"
  2874         and negid: "negligible (K \<inter> L)" if "K \<in> \<D>" "L \<in> \<D>" "K \<noteq> L" for K L
  2875           using neg [OF \<open>linear f\<close>] neg [OF linear_id] that by auto
  2876         show ?thesis
  2877         proof (cases "finite \<D>")
  2878           case True
  2879           then have "?\<mu> (\<Union>x\<in>\<D>. f ` x) = (\<Sum>x\<in>\<D>. ?\<mu> (f ` x))"
  2880             using \<open>linear f\<close> cbox measurable_linear_image_interval negf
  2881             by (blast intro: measure_negligible_finite_Union_image [unfolded pairwise_def])
  2882           also have "\<dots> = (\<Sum>k\<in>\<D>. m * ?\<mu> k)"
  2883             by (metis (no_types, lifting) cbox im sum.cong)
  2884           also have "\<dots> = m * ?\<mu> (\<Union>\<D>)"
  2885             unfolding sum_distrib_left [symmetric]
  2886             by (metis True cbox lmeasurable_cbox measure_negligible_finite_Union [unfolded pairwise_def] negid)
  2887           finally show ?thesis
  2888             by (metis True \<open>linear f\<close> cbox image_Union fmeasurable.finite_UN measurable_linear_image_interval)
  2889         next
  2890           case False
  2891           with \<open>countable \<D>\<close> obtain X :: "nat \<Rightarrow> 'n set" where S: "bij_betw X UNIV \<D>"
  2892             using bij_betw_from_nat_into by blast
  2893           then have eq: "(\<Union>\<D>) = (\<Union>n. X n)" "(f ` \<Union>\<D>) = (\<Union>n. f ` X n)"
  2894             by (auto simp: bij_betw_def)
  2895           have meas: "\<And>K. K \<in> \<D> \<Longrightarrow> K \<in> lmeasurable"
  2896             using cbox by blast
  2897           with S have 1: "\<And>n. X n \<in> lmeasurable"
  2898             by (auto simp: bij_betw_def)
  2899           have 2: "pairwise (\<lambda>m n. negligible (X m \<inter> X n)) UNIV"
  2900             using S unfolding bij_betw_def pairwise_def by (metis injD negid range_eqI)
  2901           have "bounded (\<Union>\<D>)"
  2902             by (meson Sup_least bounded_cbox bounded_subset cbox)
  2903           then have 3: "bounded (\<Union>n. X n)"
  2904             using S unfolding bij_betw_def by blast
  2905           have "(\<Union>n. X n) \<in> lmeasurable"
  2906             by (rule measurable_countable_negligible_Union_bounded [OF 1 2 3])
  2907           with S have f1: "\<And>n. f ` (X n) \<in> lmeasurable"
  2908             unfolding bij_betw_def by (metis assms(1) cbox measurable_linear_image_interval rangeI)
  2909           have f2: "pairwise (\<lambda>m n. negligible (f ` (X m) \<inter> f ` (X n))) UNIV"
  2910             using S unfolding bij_betw_def pairwise_def by (metis injD negf rangeI)
  2911           have "bounded (\<Union>\<D>)"
  2912             by (meson Sup_least bounded_cbox bounded_subset cbox)
  2913           then have f3: "bounded (\<Union>n. f ` X n)"
  2914             using S unfolding bij_betw_def
  2915             by (metis bounded_linear_image linear_linear assms(1) image_Union range_composition)
  2916           have "(\<lambda>n. ?\<mu> (X n)) sums ?\<mu> (\<Union>n. X n)"
  2917             by (rule measure_countable_negligible_Union_bounded [OF 1 2 3])
  2918           have meq: "?\<mu> (\<Union>n. f ` X n) = m * ?\<mu> (\<Union>(X ` UNIV))"
  2919           proof (rule sums_unique2 [OF measure_countable_negligible_Union_bounded [OF f1 f2 f3]])
  2920             have m: "\<And>n. ?\<mu> (f ` X n) = (m * ?\<mu> (X n))"
  2921               using S unfolding bij_betw_def by (metis cbox im rangeI)
  2922             show "(\<lambda>n. ?\<mu> (f ` X n)) sums (m * ?\<mu> (\<Union>(X ` UNIV)))"
  2923               unfolding m
  2924               using measure_countable_negligible_Union_bounded [OF 1 2 3] sums_mult by blast
  2925           qed
  2926           show ?thesis
  2927             using measurable_countable_negligible_Union_bounded [OF f1 f2 f3] meq
  2928             by (auto simp: eq [symmetric])
  2929         qed
  2930       qed
  2931       show ?thesis
  2932         unfolding completion.fmeasurable_measure_inner_outer_le
  2933       proof (intro conjI allI impI)
  2934         fix e :: real
  2935         assume "e > 0"
  2936         have 1: "cbox a b - S \<in> lmeasurable"
  2937           by (simp add: fmeasurable.Diff that)
  2938         have 2: "0 < e / (1 + \<bar>m\<bar>)"
  2939           using \<open>e > 0\<close> by (simp add: divide_simps abs_add_one_gt_zero)
  2940         obtain \<D>
  2941           where "countable \<D>"
  2942             and cbox: "\<And>K. K \<in> \<D> \<Longrightarrow> K \<subseteq> cbox a b \<and> K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  2943             and intdisj: "pairwise (\<lambda>A B. interior A \<inter> interior B = {}) \<D>"
  2944             and DD: "cbox a b - S \<subseteq> \<Union>\<D>" "\<Union>\<D> \<in> lmeasurable"
  2945             and le: "?\<mu> (\<Union>\<D>) \<le> ?\<mu> (cbox a b - S) + e/(1 + \<bar>m\<bar>)"
  2946           by (rule measurable_outer_intervals_bounded [of "cbox a b - S" a b "e/(1 + \<bar>m\<bar>)"]; use 1 2 pairwise_def in force)
  2947         have meq: "?\<mu> (cbox a b - S) = ?\<mu> (cbox a b) - ?\<mu> S"
  2948           by (simp add: measurable_measure_Diff \<open>S \<subseteq> cbox a b\<close> fmeasurableD that(2))
  2949         show "\<exists>T \<in> lmeasurable. T \<subseteq> f ` S \<and> m * ?\<mu> S - e \<le> ?\<mu> T"
  2950         proof (intro bexI conjI)
  2951           show "f ` (cbox a b) - f ` (\<Union>\<D>) \<subseteq> f ` S"
  2952             using \<open>cbox a b - S \<subseteq> \<Union>\<D>\<close> by force
  2953           have "m * ?\<mu> S - e \<le> m * (?\<mu> S - e / (1 + \<bar>m\<bar>))"
  2954             using \<open>m \<ge> 0\<close> \<open>e > 0\<close> by (simp add: field_simps)
  2955           also have "\<dots> \<le> ?\<mu> (f ` cbox a b) - ?\<mu> (f ` (\<Union>\<D>))"
  2956             using le \<open>m \<ge> 0\<close> \<open>e > 0\<close>
  2957             apply (simp add: im fUD [OF \<open>countable \<D>\<close> cbox intdisj] right_diff_distrib [symmetric])
  2958             apply (rule mult_left_mono; simp add: algebra_simps meq)
  2959             done
  2960           also have "\<dots> = ?\<mu> (f ` cbox a b - f ` \<Union>\<D>)"
  2961             apply (rule measurable_measure_Diff [symmetric])
  2962             apply (simp add: assms(1) measurable_linear_image_interval)
  2963             apply (simp add: \<open>countable \<D>\<close> cbox fUD fmeasurableD intdisj)
  2964              apply (simp add: Sup_le_iff cbox image_mono)
  2965             done
  2966           finally show "m * ?\<mu> S - e \<le> ?\<mu> (f ` cbox a b - f ` \<Union>\<D>)" .
  2967           show "f ` cbox a b - f ` \<Union>\<D> \<in> lmeasurable"
  2968             by (simp add: fUD \<open>countable \<D>\<close> \<open>linear f\<close> cbox fmeasurable.Diff intdisj measurable_linear_image_interval)
  2969         qed
  2970       next
  2971         fix e :: real
  2972         assume "e > 0"
  2973         have em: "0 < e / (1 + \<bar>m\<bar>)"
  2974           using \<open>e > 0\<close> by (simp add: divide_simps abs_add_one_gt_zero)
  2975         obtain \<D>
  2976           where "countable \<D>"
  2977             and cbox: "\<And>K. K \<in> \<D> \<Longrightarrow> K \<subseteq> cbox a b \<and> K \<noteq> {} \<and> (\<exists>c d. K = cbox c d)"
  2978             and intdisj: "pairwise (\<lambda>A B. interior A \<inter> interior B = {}) \<D>"
  2979             and DD: "S \<subseteq> \<Union>\<D>" "\<Union>\<D> \<in> lmeasurable"
  2980             and le: "?\<mu> (\<Union>\<D>) \<le> ?\<mu> S + e/(1 + \<bar>m\<bar>)"
  2981           by (rule measurable_outer_intervals_bounded [of S a b "e/(1 + \<bar>m\<bar>)"]; use \<open>S \<in> lmeasurable\<close> \<open>S \<subseteq> cbox a b\<close> em in force)
  2982         show "\<exists>U \<in> lmeasurable. f ` S \<subseteq> U \<and> ?\<mu> U \<le> m * ?\<mu> S + e"
  2983         proof (intro bexI conjI)
  2984           show "f ` S \<subseteq> f ` (\<Union>\<D>)"
  2985             by (simp add: DD(1) image_mono)
  2986           have "?\<mu> (f ` \<Union>\<D>) \<le> m * (?\<mu> S + e / (1 + \<bar>m\<bar>))"
  2987             using \<open>m \<ge> 0\<close> le mult_left_mono
  2988             by (auto simp: fUD \<open>countable \<D>\<close> \<open>linear f\<close> cbox fmeasurable.Diff intdisj measurable_linear_image_interval)
  2989           also have "\<dots> \<le> m * ?\<mu> S + e"
  2990             using \<open>m \<ge> 0\<close> \<open>e > 0\<close> by (simp add: fUD [OF \<open>countable \<D>\<close> cbox intdisj] field_simps)
  2991           finally show "?\<mu> (f ` \<Union>\<D>) \<le> m * ?\<mu> S + e" .
  2992           show "f ` \<Union>\<D> \<in> lmeasurable"
  2993             by (simp add: \<open>countable \<D>\<close> cbox fUD intdisj)
  2994         qed
  2995       qed
  2996     qed
  2997     show ?thesis
  2998       unfolding has_measure_limit_iff
  2999     proof (intro allI impI)
  3000       fix e :: real
  3001       assume "e > 0"
  3002       obtain B where "B > 0" and B:
  3003         "\<And>a b. ball 0 B \<subseteq> cbox a b \<Longrightarrow> \<bar>?\<mu> (S \<inter> cbox a b) - ?\<mu> S\<bar> < e / (1 + \<bar>m\<bar>)"
  3004         using has_measure_limit [OF S] \<open>e > 0\<close> by (metis abs_add_one_gt_zero zero_less_divide_iff)
  3005       obtain c d::'n where cd: "ball 0 B \<subseteq> cbox c d"
  3006         by (metis bounded_subset_cbox_symmetric bounded_ball)
  3007       with B have less: "\<bar>?\<mu> (S \<inter> cbox c d) - ?\<mu> S\<bar> < e / (1 + \<bar>m\<bar>)" .
  3008       obtain D where "D > 0" and D: "cbox c d \<subseteq> ball 0 D"
  3009         by (metis bounded_cbox bounded_subset_ballD)
  3010       obtain C where "C > 0" and C: "\<And>x. norm (f x) \<le> C * norm x"
  3011         using linear_bounded_pos \<open>linear f\<close> by blast
  3012       have "f ` S \<inter> cbox a b \<in> lmeasurable \<and>
  3013             \<bar>?\<mu> (f ` S \<inter> cbox a b) - m * ?\<mu> S\<bar> < e"
  3014         if "ball 0 (D*C) \<subseteq> cbox a b" for a b
  3015       proof -
  3016         have "bounded (S \<inter> h ` cbox a b)"
  3017           by (simp add: bounded_linear_image linear_linear \<open>linear h\<close> bounded_Int)
  3018         moreover have Shab: "S \<inter> h ` cbox a b \<in> lmeasurable"
  3019           by (simp add: S \<open>linear h\<close> fmeasurable.Int measurable_linear_image_interval)
  3020         moreover have fim: "f ` (S \<inter> h ` (cbox a b)) = (f ` S) \<inter> cbox a b"
  3021           by (auto simp: hf rev_image_eqI fh)
  3022         ultimately have 1: "(f ` S) \<inter> cbox a b \<in> lmeasurable"
  3023               and 2: "m * ?\<mu> (S \<inter> h ` cbox a b) = ?\<mu> ((f ` S) \<inter> cbox a b)"
  3024           using fBS [of "S \<inter> (h ` (cbox a b))"] by auto
  3025         have *: "\<lbrakk>\<bar>z - m\<bar> < e; z \<le> w; w \<le> m\<rbrakk> \<Longrightarrow> \<bar>w - m\<bar> \<le> e"
  3026           for w z m and e::real by auto
  3027         have meas_adiff: "\<bar>?\<mu> (S \<inter> h ` cbox a b) - ?\<mu> S\<bar> \<le> e / (1 + \<bar>m\<bar>)"
  3028         proof (rule * [OF less])
  3029           show "?\<mu> (S \<inter> cbox c d) \<le> ?\<mu> (S \<inter> h ` cbox a b)"
  3030           proof (rule measure_mono_fmeasurable [OF _ _ Shab])
  3031             have "f ` ball 0 D \<subseteq> ball 0 (C * D)"
  3032               using C \<open>C > 0\<close>
  3033               apply (clarsimp simp: algebra_simps)
  3034               by (meson le_less_trans linordered_comm_semiring_strict_class.comm_mult_strict_left_mono)
  3035             then have "f ` ball 0 D \<subseteq> cbox a b"
  3036               by (metis mult.commute order_trans that)
  3037             have "ball 0 D \<subseteq> h ` cbox a b"
  3038               by (metis \<open>f ` ball 0 D \<subseteq> cbox a b\<close> hf image_subset_iff subsetI)
  3039             then show "S \<inter> cbox c d \<subseteq> S \<inter> h ` cbox a b"
  3040               using D by blast
  3041           next
  3042             show "S \<inter> cbox c d \<in> sets lebesgue"
  3043               using S fmeasurable_cbox by blast
  3044           qed
  3045         next
  3046           show "?\<mu> (S \<inter> h ` cbox a b) \<le> ?\<mu> S"
  3047             by (simp add: S Shab fmeasurableD measure_mono_fmeasurable)
  3048         qed
  3049         have "\<bar>?\<mu> (f ` S \<inter> cbox a b) - m * ?\<mu> S\<bar> \<le> m * e / (1 + \<bar>m\<bar>)"
  3050         proof -
  3051           have mm: "\<bar>m\<bar> = m"
  3052             by (simp add: \<open>0 \<le> m\<close>)
  3053           then have "\<bar>?\<mu> S - ?\<mu> (S \<inter> h ` cbox a b)\<bar> * m \<le> e / (1 + m) * m"
  3054             by (metis (no_types) \<open>0 \<le> m\<close> meas_adiff abs_minus_commute mult_right_mono)
  3055           moreover have "\<forall>r. \<bar>r * m\<bar> = m * \<bar>r\<bar>"
  3056             by (metis \<open>0 \<le> m\<close> abs_mult_pos mult.commute)
  3057           ultimately show ?thesis
  3058             apply (simp add: 2 [symmetric])
  3059             by (metis (no_types) abs_minus_commute mult.commute right_diff_distrib' mm)
  3060         qed
  3061         also have "\<dots> < e"
  3062           using \<open>e > 0\<close> by (auto simp: divide_simps)
  3063         finally have "\<bar>?\<mu> (f ` S \<inter> cbox a b) - m * ?\<mu> S\<bar> < e" .
  3064         with 1 show ?thesis by auto
  3065       qed
  3066       then show "\<exists>B>0. \<forall>a b. ball 0 B \<subseteq> cbox a b \<longrightarrow>
  3067                          f ` S \<inter> cbox a b \<in> lmeasurable \<and>
  3068                          \<bar>?\<mu> (f ` S \<inter> cbox a b) - m * ?\<mu> S\<bar> < e"
  3069         using \<open>C>0\<close> \<open>D>0\<close> by (metis mult_zero_left real_mult_less_iff1)
  3070     qed
  3071   qed
  3072 qed
  3073 
  3074 
  3075 subsection\<open>Lemmas about absolute integrability\<close>
  3076 
  3077 text\<open>FIXME Redundant!\<close>
  3078 lemma absolutely_integrable_add[intro]:
  3079   fixes f g :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3080   shows "f absolutely_integrable_on s \<Longrightarrow> g absolutely_integrable_on s \<Longrightarrow> (\<lambda>x. f x + g x) absolutely_integrable_on s"
  3081   by (rule set_integral_add)
  3082 
  3083 text\<open>FIXME Redundant!\<close>
  3084 lemma absolutely_integrable_diff[intro]:
  3085   fixes f g :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3086   shows "f absolutely_integrable_on s \<Longrightarrow> g absolutely_integrable_on s \<Longrightarrow> (\<lambda>x. f x - g x) absolutely_integrable_on s"
  3087   by (rule set_integral_diff)
  3088 
  3089 lemma absolutely_integrable_linear:
  3090   fixes f :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space"
  3091     and h :: "'n::euclidean_space \<Rightarrow> 'p::euclidean_space"
  3092   shows "f absolutely_integrable_on s \<Longrightarrow> bounded_linear h \<Longrightarrow> (h \<circ> f) absolutely_integrable_on s"
  3093   using integrable_bounded_linear[of h lebesgue "\<lambda>x. indicator s x *\<^sub>R f x"]
  3094   by (simp add: linear_simps[of h] set_integrable_def)
  3095 
  3096 lemma absolutely_integrable_sum:
  3097   fixes f :: "'a \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3098   assumes "finite T" and "\<And>a. a \<in> T \<Longrightarrow> (f a) absolutely_integrable_on S"
  3099   shows "(\<lambda>x. sum (\<lambda>a. f a x) T) absolutely_integrable_on S"
  3100   using assms by induction auto
  3101 
  3102 lemma absolutely_integrable_integrable_bound:
  3103   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3104   assumes le: "\<And>x. x\<in>S \<Longrightarrow> norm (f x) \<le> g x" and f: "f integrable_on S" and g: "g integrable_on S"
  3105   shows "f absolutely_integrable_on S"
  3106     unfolding set_integrable_def
  3107 proof (rule Bochner_Integration.integrable_bound)
  3108   have "g absolutely_integrable_on S"
  3109     unfolding absolutely_integrable_on_def
  3110   proof
  3111     show "(\<lambda>x. norm (g x)) integrable_on S"
  3112       using le norm_ge_zero[of "f _"]
  3113       by (intro integrable_spike_finite[OF _ _ g, of "{}"])
  3114          (auto intro!: abs_of_nonneg intro: order_trans simp del: norm_ge_zero)
  3115   qed fact
  3116   then show "integrable lebesgue (\<lambda>x. indicat_real S x *\<^sub>R g x)"
  3117     by (simp add: set_integrable_def)
  3118   show "(\<lambda>x. indicat_real S x *\<^sub>R f x) \<in> borel_measurable lebesgue"
  3119     using f by (auto intro: has_integral_implies_lebesgue_measurable simp: integrable_on_def)
  3120 qed (use le in \<open>force intro!: always_eventually split: split_indicator\<close>)
  3121 
  3122 lemma absolutely_integrable_continuous:
  3123   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  3124   shows "continuous_on (cbox a b) f \<Longrightarrow> f absolutely_integrable_on cbox a b"
  3125   using absolutely_integrable_integrable_bound
  3126   by (simp add: absolutely_integrable_on_def continuous_on_norm integrable_continuous)
  3127 
  3128 
  3129 subsection \<open>Componentwise\<close>
  3130 
  3131 proposition absolutely_integrable_componentwise_iff:
  3132   shows "f absolutely_integrable_on A \<longleftrightarrow> (\<forall>b\<in>Basis. (\<lambda>x. f x \<bullet> b) absolutely_integrable_on A)"
  3133 proof -
  3134   have *: "(\<lambda>x. norm (f x)) integrable_on A \<longleftrightarrow> (\<forall>b\<in>Basis. (\<lambda>x. norm (f x \<bullet> b)) integrable_on A)"
  3135           if "f integrable_on A"
  3136   proof -
  3137     have 1: "\<And>i. \<lbrakk>(\<lambda>x. norm (f x)) integrable_on A; i \<in> Basis\<rbrakk>
  3138                  \<Longrightarrow> (\<lambda>x. f x \<bullet> i) absolutely_integrable_on A"
  3139       apply (rule absolutely_integrable_integrable_bound [where g = "\<lambda>x. norm(f x)"])
  3140       using Basis_le_norm integrable_component that apply fastforce+
  3141       done
  3142     have 2: "\<forall>i\<in>Basis. (\<lambda>x. \<bar>f x \<bullet> i\<bar>) integrable_on A \<Longrightarrow> f absolutely_integrable_on A"
  3143       apply (rule absolutely_integrable_integrable_bound [where g = "\<lambda>x. \<Sum>i\<in>Basis. norm (f x \<bullet> i)"])
  3144       using norm_le_l1 that apply (force intro: integrable_sum)+
  3145       done
  3146     show ?thesis
  3147       apply auto
  3148        apply (metis (full_types) absolutely_integrable_on_def set_integrable_abs 1)
  3149       apply (metis (full_types) absolutely_integrable_on_def 2)
  3150       done
  3151   qed
  3152   show ?thesis
  3153     unfolding absolutely_integrable_on_def
  3154     by (simp add:  integrable_componentwise_iff [symmetric] ball_conj_distrib * cong: conj_cong)
  3155 qed
  3156 
  3157 lemma absolutely_integrable_componentwise:
  3158   shows "(\<And>b. b \<in> Basis \<Longrightarrow> (\<lambda>x. f x \<bullet> b) absolutely_integrable_on A) \<Longrightarrow> f absolutely_integrable_on A"
  3159   using absolutely_integrable_componentwise_iff by blast
  3160 
  3161 lemma absolutely_integrable_component:
  3162   "f absolutely_integrable_on A \<Longrightarrow> (\<lambda>x. f x \<bullet> (b :: 'b :: euclidean_space)) absolutely_integrable_on A"
  3163   by (drule absolutely_integrable_linear[OF _ bounded_linear_inner_left[of b]]) (simp add: o_def)
  3164 
  3165 
  3166 lemma absolutely_integrable_scaleR_left:
  3167   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3168     assumes "f absolutely_integrable_on S"
  3169   shows "(\<lambda>x. c *\<^sub>R f x) absolutely_integrable_on S"
  3170 proof -
  3171   have "(\<lambda>x. c *\<^sub>R x) o f absolutely_integrable_on S"
  3172     apply (rule absolutely_integrable_linear [OF assms])
  3173     by (simp add: bounded_linear_scaleR_right)
  3174   then show ?thesis
  3175     using assms by blast
  3176 qed
  3177 
  3178 lemma absolutely_integrable_scaleR_right:
  3179   assumes "f absolutely_integrable_on S"
  3180   shows "(\<lambda>x. f x *\<^sub>R c) absolutely_integrable_on S"
  3181   using assms by blast
  3182 
  3183 lemma absolutely_integrable_norm:
  3184   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
  3185   assumes "f absolutely_integrable_on S"
  3186   shows "(norm o f) absolutely_integrable_on S"
  3187   using assms by (simp add: absolutely_integrable_on_def o_def)
  3188 
  3189 lemma absolutely_integrable_abs:
  3190   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
  3191   assumes "f absolutely_integrable_on S"
  3192   shows "(\<lambda>x. \<Sum>i\<in>Basis. \<bar>f x \<bullet> i\<bar> *\<^sub>R i) absolutely_integrable_on S"
  3193         (is "?g absolutely_integrable_on S")
  3194 proof -
  3195   have eq: "?g =
  3196         (\<lambda>x. \<Sum>i\<in>Basis. ((\<lambda>y. \<Sum>j\<in>Basis. if j = i then y *\<^sub>R j else 0) \<circ>
  3197                (\<lambda>x. norm(\<Sum>j\<in>Basis. if j = i then (x \<bullet> i) *\<^sub>R j else 0)) \<circ> f) x)"
  3198     by (simp add: sum.delta)
  3199   have *: "(\<lambda>y. \<Sum>j\<in>Basis. if j = i then y *\<^sub>R j else 0) \<circ>
  3200            (\<lambda>x. norm (\<Sum>j\<in>Basis. if j = i then (x \<bullet> i) *\<^sub>R j else 0)) \<circ> f 
  3201            absolutely_integrable_on S" 
  3202         if "i \<in> Basis" for i
  3203   proof -
  3204     have "bounded_linear (\<lambda>y. \<Sum>j\<in>Basis. if j = i then y *\<^sub>R j else 0)"
  3205       by (simp add: linear_linear algebra_simps linearI)
  3206     moreover have "(\<lambda>x. norm (\<Sum>j\<in>Basis. if j = i then (x \<bullet> i) *\<^sub>R j else 0)) \<circ> f 
  3207                    absolutely_integrable_on S"
  3208       unfolding o_def
  3209       apply (rule absolutely_integrable_norm [unfolded o_def])
  3210       using assms \<open>i \<in> Basis\<close>
  3211       apply (auto simp: algebra_simps dest: absolutely_integrable_component[where b=i])
  3212       done
  3213     ultimately show ?thesis
  3214       by (subst comp_assoc) (blast intro: absolutely_integrable_linear)
  3215   qed
  3216   show ?thesis
  3217     apply (rule ssubst [OF eq])
  3218     apply (rule absolutely_integrable_sum)
  3219      apply (force simp: intro!: *)+
  3220     done
  3221 qed
  3222 
  3223 lemma abs_absolutely_integrableI_1:
  3224   fixes f :: "'a :: euclidean_space \<Rightarrow> real"
  3225   assumes f: "f integrable_on A" and "(\<lambda>x. \<bar>f x\<bar>) integrable_on A"
  3226   shows "f absolutely_integrable_on A"
  3227   by (rule absolutely_integrable_integrable_bound [OF _ assms]) auto
  3228 
  3229   
  3230 lemma abs_absolutely_integrableI:
  3231   assumes f: "f integrable_on S" and fcomp: "(\<lambda>x. \<Sum>i\<in>Basis. \<bar>f x \<bullet> i\<bar> *\<^sub>R i) integrable_on S"
  3232   shows "f absolutely_integrable_on S"
  3233 proof -
  3234   have "(\<lambda>x. (f x \<bullet> i) *\<^sub>R i) absolutely_integrable_on S" if "i \<in> Basis" for i
  3235   proof -
  3236     have "(\<lambda>x. \<bar>f x \<bullet> i\<bar>) integrable_on S" 
  3237       using assms integrable_component [OF fcomp, where y=i] that by simp
  3238     then have "(\<lambda>x. f x \<bullet> i) absolutely_integrable_on S"
  3239       using abs_absolutely_integrableI_1 f integrable_component by blast
  3240     then show ?thesis
  3241       by (rule absolutely_integrable_scaleR_right)
  3242   qed
  3243   then have "(\<lambda>x. \<Sum>i\<in>Basis. (f x \<bullet> i) *\<^sub>R i) absolutely_integrable_on S"
  3244     by (simp add: absolutely_integrable_sum)
  3245   then show ?thesis
  3246     by (simp add: euclidean_representation)
  3247 qed
  3248 
  3249     
  3250 lemma absolutely_integrable_abs_iff:
  3251    "f absolutely_integrable_on S \<longleftrightarrow>
  3252     f integrable_on S \<and> (\<lambda>x. \<Sum>i\<in>Basis. \<bar>f x \<bullet> i\<bar> *\<^sub>R i) integrable_on S"
  3253     (is "?lhs = ?rhs")
  3254 proof
  3255   assume ?lhs then show ?rhs
  3256     using absolutely_integrable_abs absolutely_integrable_on_def by blast
  3257 next
  3258   assume ?rhs 
  3259   moreover
  3260   have "(\<lambda>x. if x \<in> S then \<Sum>i\<in>Basis. \<bar>f x \<bullet> i\<bar> *\<^sub>R i else 0) = (\<lambda>x. \<Sum>i\<in>Basis. \<bar>(if x \<in> S then f x else 0) \<bullet> i\<bar> *\<^sub>R i)"
  3261     by force
  3262   ultimately show ?lhs
  3263     by (simp only: absolutely_integrable_restrict_UNIV [of S, symmetric] integrable_restrict_UNIV [of S, symmetric] abs_absolutely_integrableI)
  3264 qed
  3265 
  3266 lemma absolutely_integrable_max:
  3267   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3268   assumes "f absolutely_integrable_on S" "g absolutely_integrable_on S"
  3269    shows "(\<lambda>x. \<Sum>i\<in>Basis. max (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i)
  3270             absolutely_integrable_on S"
  3271 proof -
  3272   have "(\<lambda>x. \<Sum>i\<in>Basis. max (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i) = 
  3273         (\<lambda>x. (1/2) *\<^sub>R (f x + g x + (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i)))"
  3274   proof (rule ext)
  3275     fix x
  3276     have "(\<Sum>i\<in>Basis. max (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i) = (\<Sum>i\<in>Basis. ((f x \<bullet> i + g x \<bullet> i + \<bar>f x \<bullet> i - g x \<bullet> i\<bar>) / 2) *\<^sub>R i)"
  3277       by (force intro: sum.cong)
  3278     also have "... = (1 / 2) *\<^sub>R (\<Sum>i\<in>Basis. (f x \<bullet> i + g x \<bullet> i + \<bar>f x \<bullet> i - g x \<bullet> i\<bar>) *\<^sub>R i)"
  3279       by (simp add: scaleR_right.sum)
  3280     also have "... = (1 / 2) *\<^sub>R (f x + g x + (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i))"
  3281       by (simp add: sum.distrib algebra_simps euclidean_representation)
  3282     finally
  3283     show "(\<Sum>i\<in>Basis. max (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i) =
  3284          (1 / 2) *\<^sub>R (f x + g x + (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i))" .
  3285   qed
  3286   moreover have "(\<lambda>x. (1 / 2) *\<^sub>R (f x + g x + (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i))) 
  3287                  absolutely_integrable_on S"
  3288     apply (intro absolutely_integrable_add absolutely_integrable_scaleR_left assms)
  3289     using absolutely_integrable_abs [OF absolutely_integrable_diff [OF assms]]
  3290     apply (simp add: algebra_simps)
  3291     done
  3292   ultimately show ?thesis by metis
  3293 qed
  3294   
  3295 corollary absolutely_integrable_max_1:
  3296   fixes f :: "'n::euclidean_space \<Rightarrow> real"
  3297   assumes "f absolutely_integrable_on S" "g absolutely_integrable_on S"
  3298    shows "(\<lambda>x. max (f x) (g x)) absolutely_integrable_on S"
  3299   using absolutely_integrable_max [OF assms] by simp
  3300 
  3301 lemma absolutely_integrable_min:
  3302   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3303   assumes "f absolutely_integrable_on S" "g absolutely_integrable_on S"
  3304    shows "(\<lambda>x. \<Sum>i\<in>Basis. min (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i)
  3305             absolutely_integrable_on S"
  3306 proof -
  3307   have "(\<lambda>x. \<Sum>i\<in>Basis. min (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i) = 
  3308         (\<lambda>x. (1/2) *\<^sub>R (f x + g x - (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i)))"
  3309   proof (rule ext)
  3310     fix x
  3311     have "(\<Sum>i\<in>Basis. min (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i) = (\<Sum>i\<in>Basis. ((f x \<bullet> i + g x \<bullet> i - \<bar>f x \<bullet> i - g x \<bullet> i\<bar>) / 2) *\<^sub>R i)"
  3312       by (force intro: sum.cong)
  3313     also have "... = (1 / 2) *\<^sub>R (\<Sum>i\<in>Basis. (f x \<bullet> i + g x \<bullet> i - \<bar>f x \<bullet> i - g x \<bullet> i\<bar>) *\<^sub>R i)"
  3314       by (simp add: scaleR_right.sum)
  3315     also have "... = (1 / 2) *\<^sub>R (f x + g x - (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i))"
  3316       by (simp add: sum.distrib sum_subtractf algebra_simps euclidean_representation)
  3317     finally
  3318     show "(\<Sum>i\<in>Basis. min (f x \<bullet> i) (g x \<bullet> i) *\<^sub>R i) =
  3319          (1 / 2) *\<^sub>R (f x + g x - (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i))" .
  3320   qed
  3321   moreover have "(\<lambda>x. (1 / 2) *\<^sub>R (f x + g x - (\<Sum>i\<in>Basis. \<bar>f x \<bullet> i - g x \<bullet> i\<bar> *\<^sub>R i))) 
  3322                  absolutely_integrable_on S"
  3323     apply (intro absolutely_integrable_add absolutely_integrable_diff absolutely_integrable_scaleR_left assms)
  3324     using absolutely_integrable_abs [OF absolutely_integrable_diff [OF assms]]
  3325     apply (simp add: algebra_simps)
  3326     done
  3327   ultimately show ?thesis by metis
  3328 qed
  3329   
  3330 corollary absolutely_integrable_min_1:
  3331   fixes f :: "'n::euclidean_space \<Rightarrow> real"
  3332   assumes "f absolutely_integrable_on S" "g absolutely_integrable_on S"
  3333    shows "(\<lambda>x. min (f x) (g x)) absolutely_integrable_on S"
  3334   using absolutely_integrable_min [OF assms] by simp
  3335 
  3336 lemma nonnegative_absolutely_integrable:
  3337   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
  3338   assumes "f integrable_on A" and comp: "\<And>x b. \<lbrakk>x \<in> A; b \<in> Basis\<rbrakk> \<Longrightarrow> 0 \<le> f x \<bullet> b"
  3339   shows "f absolutely_integrable_on A"
  3340 proof -
  3341   have "(\<lambda>x. (f x \<bullet> i) *\<^sub>R i) absolutely_integrable_on A" if "i \<in> Basis" for i
  3342   proof -
  3343     have "(\<lambda>x. f x \<bullet> i) integrable_on A" 
  3344       by (simp add: assms(1) integrable_component)
  3345     then have "(\<lambda>x. f x \<bullet> i) absolutely_integrable_on A"
  3346       by (metis that comp nonnegative_absolutely_integrable_1)
  3347     then show ?thesis
  3348       by (rule absolutely_integrable_scaleR_right)
  3349   qed
  3350   then have "(\<lambda>x. \<Sum>i\<in>Basis. (f x \<bullet> i) *\<^sub>R i) absolutely_integrable_on A"
  3351     by (simp add: absolutely_integrable_sum)
  3352   then show ?thesis
  3353     by (simp add: euclidean_representation)
  3354 qed
  3355   
  3356 lemma absolutely_integrable_component_ubound:
  3357   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
  3358   assumes f: "f integrable_on A" and g: "g absolutely_integrable_on A"
  3359       and comp: "\<And>x b. \<lbrakk>x \<in> A; b \<in> Basis\<rbrakk> \<Longrightarrow> f x \<bullet> b \<le> g x \<bullet> b"
  3360   shows "f absolutely_integrable_on A"
  3361 proof -
  3362   have "(\<lambda>x. g x - (g x - f x)) absolutely_integrable_on A"
  3363     apply (rule absolutely_integrable_diff [OF g nonnegative_absolutely_integrable])
  3364     using Henstock_Kurzweil_Integration.integrable_diff absolutely_integrable_on_def f g apply blast
  3365     by (simp add: comp inner_diff_left)
  3366   then show ?thesis
  3367     by simp
  3368 qed
  3369 
  3370 lemma absolutely_integrable_component_lbound:
  3371   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
  3372   assumes f: "f absolutely_integrable_on A" and g: "g integrable_on A"
  3373       and comp: "\<And>x b. \<lbrakk>x \<in> A; b \<in> Basis\<rbrakk> \<Longrightarrow> f x \<bullet> b \<le> g x \<bullet> b"
  3374   shows "g absolutely_integrable_on A"
  3375 proof -
  3376   have "(\<lambda>x. f x + (g x - f x)) absolutely_integrable_on A"
  3377     apply (rule absolutely_integrable_add [OF f nonnegative_absolutely_integrable])
  3378     using Henstock_Kurzweil_Integration.integrable_diff absolutely_integrable_on_def f g apply blast
  3379     by (simp add: comp inner_diff_left)
  3380   then show ?thesis
  3381     by simp
  3382 qed
  3383 
  3384 lemma integrable_on_1_iff:
  3385   fixes f :: "'a::euclidean_space \<Rightarrow> real^1"
  3386   shows "f integrable_on S \<longleftrightarrow> (\<lambda>x. f x $ 1) integrable_on S"
  3387   by (auto simp: integrable_componentwise_iff [of f] Basis_vec_def cart_eq_inner_axis)
  3388 
  3389 lemma integral_on_1_eq:
  3390   fixes f :: "'a::euclidean_space \<Rightarrow> real^1"
  3391   shows "integral S f = vec (integral S (\<lambda>x. f x $ 1))"
  3392 by (cases "f integrable_on S") (simp_all add: integrable_on_1_iff vec_eq_iff not_integrable_integral)
  3393 
  3394 lemma absolutely_integrable_on_1_iff:
  3395   fixes f :: "'a::euclidean_space \<Rightarrow> real^1"
  3396   shows "f absolutely_integrable_on S \<longleftrightarrow> (\<lambda>x. f x $ 1) absolutely_integrable_on S"
  3397   unfolding absolutely_integrable_on_def
  3398   by (auto simp: integrable_on_1_iff norm_real)
  3399 
  3400 lemma absolutely_integrable_absolutely_integrable_lbound:
  3401   fixes f :: "'m::euclidean_space \<Rightarrow> real"
  3402   assumes f: "f integrable_on S" and g: "g absolutely_integrable_on S"
  3403     and *: "\<And>x. x \<in> S \<Longrightarrow> g x \<le> f x"
  3404   shows "f absolutely_integrable_on S"
  3405   by (rule absolutely_integrable_component_lbound [OF g f]) (simp add: *)
  3406 
  3407 lemma absolutely_integrable_absolutely_integrable_ubound:
  3408   fixes f :: "'m::euclidean_space \<Rightarrow> real"
  3409   assumes fg: "f integrable_on S" "g absolutely_integrable_on S"
  3410     and *: "\<And>x. x \<in> S \<Longrightarrow> f x \<le> g x"
  3411   shows "f absolutely_integrable_on S"
  3412   by (rule absolutely_integrable_component_ubound [OF fg]) (simp add: *)
  3413 
  3414 lemma has_integral_vec1_I_cbox:
  3415   fixes f :: "real^1 \<Rightarrow> 'a::real_normed_vector"
  3416   assumes "(f has_integral y) (cbox a b)"
  3417   shows "((f \<circ> vec) has_integral y) {a$1..b$1}"
  3418 proof -
  3419   have "((\<lambda>x. f(vec x)) has_integral (1 / 1) *\<^sub>R y) ((\<lambda>x. x $ 1) ` cbox a b)"
  3420   proof (rule has_integral_twiddle)
  3421     show "\<exists>w z::real^1. vec ` cbox u v = cbox w z"
  3422          "content (vec ` cbox u v :: (real^1) set) = 1 * content (cbox u v)" for u v
  3423       unfolding vec_cbox_1_eq
  3424       by (auto simp: content_cbox_if_cart interval_eq_empty_cart)
  3425     show "\<exists>w z. (\<lambda>x. x $ 1) ` cbox u v = cbox w z" for u v :: "real^1"
  3426       using vec_nth_cbox_1_eq by blast
  3427   qed (auto simp: continuous_vec assms)
  3428   then show ?thesis
  3429     by (simp add: o_def)
  3430 qed
  3431 
  3432 lemma has_integral_vec1_I:
  3433   fixes f :: "real^1 \<Rightarrow> 'a::real_normed_vector"
  3434   assumes "(f has_integral y) S"
  3435   shows "(f \<circ> vec has_integral y) ((\<lambda>x. x $ 1) ` S)"
  3436 proof -
  3437   have *: "\<exists>z. ((\<lambda>x. if x \<in> (\<lambda>x. x $ 1) ` S then (f \<circ> vec) x else 0) has_integral z) {a..b} \<and> norm (z - y) < e"
  3438     if int: "\<And>a b. ball 0 B \<subseteq> cbox a b \<Longrightarrow>
  3439                     (\<exists>z. ((\<lambda>x. if x \<in> S then f x else 0) has_integral z) (cbox a b) \<and> norm (z - y) < e)"
  3440       and B: "ball 0 B \<subseteq> {a..b}" for e B a b
  3441   proof -
  3442     have [simp]: "(\<exists>y\<in>S. x = y $ 1) \<longleftrightarrow> vec x \<in> S" for x
  3443       by force
  3444     have B': "ball (0::real^1) B \<subseteq> cbox (vec a) (vec b)"
  3445       using B by (simp add: Basis_vec_def cart_eq_inner_axis [symmetric] mem_box norm_real subset_iff)
  3446     show ?thesis
  3447       using int [OF B'] by (auto simp: image_iff o_def cong: if_cong dest!: has_integral_vec1_I_cbox)
  3448   qed
  3449   show ?thesis
  3450     using assms 
  3451     apply (subst has_integral_alt)
  3452     apply (subst (asm) has_integral_alt)
  3453     apply (simp add: has_integral_vec1_I_cbox split: if_split_asm)
  3454     apply (metis vector_one_nth)
  3455     apply (erule all_forward imp_forward asm_rl ex_forward conj_forward)+
  3456     apply (blast intro!: *)
  3457     done
  3458 qed
  3459 
  3460 lemma has_integral_vec1_nth_cbox:
  3461   fixes f :: "real \<Rightarrow> 'a::real_normed_vector"
  3462   assumes "(f has_integral y) {a..b}"
  3463   shows "((\<lambda>x::real^1. f(x$1)) has_integral y) (cbox (vec a) (vec b))"
  3464 proof -
  3465   have "((\<lambda>x::real^1. f(x$1)) has_integral (1 / 1) *\<^sub>R y) (vec ` cbox a b)"
  3466   proof (rule has_integral_twiddle)
  3467     show "\<exists>w z::real. (\<lambda>x. x $ 1) ` cbox u v = cbox w z"
  3468          "content ((\<lambda>x. x $ 1) ` cbox u v) = 1 * content (cbox u v)" for u v::"real^1"
  3469       unfolding vec_cbox_1_eq by (auto simp: content_cbox_if_cart interval_eq_empty_cart)
  3470     show "\<exists>w z::real^1. vec ` cbox u v = cbox w z" for u v :: "real"
  3471       using vec_cbox_1_eq by auto
  3472   qed (auto simp: continuous_vec assms)
  3473   then show ?thesis
  3474     using vec_cbox_1_eq by auto
  3475 qed
  3476 
  3477 lemma has_integral_vec1_D_cbox:
  3478   fixes f :: "real^1 \<Rightarrow> 'a::real_normed_vector"
  3479   assumes "((f \<circ> vec) has_integral y) {a$1..b$1}"
  3480   shows "(f has_integral y) (cbox a b)"
  3481   by (metis (mono_tags, lifting) assms comp_apply has_integral_eq has_integral_vec1_nth_cbox vector_one_nth)
  3482 
  3483 lemma has_integral_vec1_D:
  3484   fixes f :: "real^1 \<Rightarrow> 'a::real_normed_vector"
  3485   assumes "((f \<circ> vec) has_integral y) ((\<lambda>x. x $ 1) ` S)"
  3486   shows "(f has_integral y) S"
  3487 proof -
  3488   have *: "\<exists>z. ((\<lambda>x. if x \<in> S then f x else 0) has_integral z) (cbox a b) \<and> norm (z - y) < e"
  3489     if int: "\<And>a b. ball 0 B \<subseteq> {a..b} \<Longrightarrow>
  3490                              (\<exists>z. ((\<lambda>x. if x \<in> (\<lambda>x. x $ 1) ` S then (f \<circ> vec) x else 0) has_integral z) {a..b} \<and> norm (z - y) < e)"
  3491       and B: "ball 0 B \<subseteq> cbox a b" for e B and a b::"real^1"
  3492   proof -
  3493     have B': "ball 0 B \<subseteq> {a$1..b$1}"
  3494       using B
  3495       apply (simp add: subset_iff Basis_vec_def cart_eq_inner_axis [symmetric] mem_box)
  3496       apply (metis (full_types) norm_real vec_component)
  3497       done
  3498     have eq: "(\<lambda>x. if vec x \<in> S then f (vec x) else 0) = (\<lambda>x. if x \<in> S then f x else 0) \<circ> vec"
  3499       by force
  3500     have [simp]: "(\<exists>y\<in>S. x = y $ 1) \<longleftrightarrow> vec x \<in> S" for x
  3501       by force
  3502     show ?thesis
  3503       using int [OF B'] by (auto simp: image_iff eq cong: if_cong dest!: has_integral_vec1_D_cbox)
  3504 qed
  3505   show ?thesis
  3506     using assms
  3507     apply (subst has_integral_alt)
  3508     apply (subst (asm) has_integral_alt)
  3509     apply (simp add: has_integral_vec1_D_cbox eq_cbox split: if_split_asm, blast)
  3510     apply (intro conjI impI)
  3511      apply (metis vector_one_nth)
  3512     apply (erule thin_rl)
  3513     apply (erule all_forward imp_forward asm_rl ex_forward conj_forward)+
  3514     using * apply blast
  3515     done
  3516 qed
  3517 
  3518 
  3519 lemma integral_vec1_eq:
  3520   fixes f :: "real^1 \<Rightarrow> 'a::real_normed_vector"
  3521   shows "integral S f = integral ((\<lambda>x. x $ 1) ` S) (f \<circ> vec)"
  3522   using has_integral_vec1_I [of f] has_integral_vec1_D [of f]
  3523   by (metis has_integral_iff not_integrable_integral)
  3524 
  3525 lemma absolutely_integrable_drop:
  3526   fixes f :: "real^1 \<Rightarrow> 'b::euclidean_space"
  3527   shows "f absolutely_integrable_on S \<longleftrightarrow> (f \<circ> vec) absolutely_integrable_on (\<lambda>x. x $ 1) ` S"
  3528   unfolding absolutely_integrable_on_def integrable_on_def
  3529 proof safe
  3530   fix y r
  3531   assume "(f has_integral y) S" "((\<lambda>x. norm (f x)) has_integral r) S"
  3532   then show "\<exists>y. (f \<circ> vec has_integral y) ((\<lambda>x. x $ 1) ` S)"
  3533             "\<exists>y. ((\<lambda>x. norm ((f \<circ> vec) x)) has_integral y) ((\<lambda>x. x $ 1) ` S)"
  3534     by (force simp: o_def dest!: has_integral_vec1_I)+
  3535 next
  3536   fix y :: "'b" and r :: "real"
  3537   assume "(f \<circ> vec has_integral y) ((\<lambda>x. x $ 1) ` S)"
  3538          "((\<lambda>x. norm ((f \<circ> vec) x)) has_integral r) ((\<lambda>x. x $ 1) ` S)"
  3539   then show "\<exists>y. (f has_integral y) S"  "\<exists>y. ((\<lambda>x. norm (f x)) has_integral y) S"
  3540     by (force simp: o_def intro: has_integral_vec1_D)+
  3541 qed
  3542 
  3543 subsection \<open>Dominated convergence\<close>
  3544 
  3545 lemma dominated_convergence:
  3546   fixes f :: "nat \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3547   assumes f: "\<And>k. (f k) integrable_on S" and h: "h integrable_on S"
  3548     and le: "\<And>k x. x \<in> S \<Longrightarrow> norm (f k x) \<le> h x"
  3549     and conv: "\<forall>x \<in> S. (\<lambda>k. f k x) \<longlonglongrightarrow> g x"
  3550   shows "g integrable_on S" "(\<lambda>k. integral S (f k)) \<longlonglongrightarrow> integral S g"
  3551 proof -
  3552   have 3: "h absolutely_integrable_on S"
  3553     unfolding absolutely_integrable_on_def
  3554   proof
  3555     show "(\<lambda>x. norm (h x)) integrable_on S"
  3556     proof (intro integrable_spike_finite[OF _ _ h, of "{}"] ballI)
  3557       fix x assume "x \<in> S - {}" then show "norm (h x) = h x"
  3558         by (metis Diff_empty abs_of_nonneg bot_set_def le norm_ge_zero order_trans real_norm_def)
  3559     qed auto
  3560   qed fact
  3561   have 2: "set_borel_measurable lebesgue S (f k)" for k
  3562     unfolding set_borel_measurable_def
  3563     using f by (auto intro: has_integral_implies_lebesgue_measurable simp: integrable_on_def)
  3564   then have 1: "set_borel_measurable lebesgue S g"
  3565     unfolding set_borel_measurable_def
  3566     by (rule borel_measurable_LIMSEQ_metric) (use conv in \<open>auto split: split_indicator\<close>)
  3567   have 4: "AE x in lebesgue. (\<lambda>i. indicator S x *\<^sub>R f i x) \<longlonglongrightarrow> indicator S x *\<^sub>R g x"
  3568     "AE x in lebesgue. norm (indicator S x *\<^sub>R f k x) \<le> indicator S x *\<^sub>R h x" for k
  3569     using conv le by (auto intro!: always_eventually split: split_indicator)
  3570   have g: "g absolutely_integrable_on S"
  3571     using 1 2 3 4 unfolding set_borel_measurable_def set_integrable_def    
  3572     by (rule integrable_dominated_convergence)
  3573   then show "g integrable_on S"
  3574     by (auto simp: absolutely_integrable_on_def)
  3575   have "(\<lambda>k. (LINT x:S|lebesgue. f k x)) \<longlonglongrightarrow> (LINT x:S|lebesgue. g x)"
  3576     unfolding set_borel_measurable_def set_lebesgue_integral_def
  3577     using 1 2 3 4 unfolding set_borel_measurable_def set_lebesgue_integral_def set_integrable_def
  3578     by (rule integral_dominated_convergence)
  3579   then show "(\<lambda>k. integral S (f k)) \<longlonglongrightarrow> integral S g"
  3580     using g absolutely_integrable_integrable_bound[OF le f h]
  3581     by (subst (asm) (1 2) set_lebesgue_integral_eq_integral) auto
  3582 qed
  3583 
  3584 lemma has_integral_dominated_convergence:
  3585   fixes f :: "nat \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3586   assumes "\<And>k. (f k has_integral y k) S" "h integrable_on S"
  3587     "\<And>k. \<forall>x\<in>S. norm (f k x) \<le> h x" "\<forall>x\<in>S. (\<lambda>k. f k x) \<longlonglongrightarrow> g x"
  3588     and x: "y \<longlonglongrightarrow> x"
  3589   shows "(g has_integral x) S"
  3590 proof -
  3591   have int_f: "\<And>k. (f k) integrable_on S"
  3592     using assms by (auto simp: integrable_on_def)
  3593   have "(g has_integral (integral S g)) S"
  3594     by (metis assms(2-4) dominated_convergence(1) has_integral_integral int_f)
  3595   moreover have "integral S g = x"
  3596   proof (rule LIMSEQ_unique)
  3597     show "(\<lambda>i. integral S (f i)) \<longlonglongrightarrow> x"
  3598       using integral_unique[OF assms(1)] x by simp
  3599     show "(\<lambda>i. integral S (f i)) \<longlonglongrightarrow> integral S g"
  3600       by (metis assms(2) assms(3) assms(4) dominated_convergence(2) int_f)
  3601   qed
  3602   ultimately show ?thesis
  3603     by simp
  3604 qed
  3605 
  3606 lemma dominated_convergence_integrable_1:
  3607   fixes f :: "nat \<Rightarrow> 'n::euclidean_space \<Rightarrow> real"
  3608   assumes f: "\<And>k. f k absolutely_integrable_on S"
  3609     and h: "h integrable_on S"
  3610     and normg: "\<And>x. x \<in> S \<Longrightarrow> norm(g x) \<le> (h x)"
  3611     and lim: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>k. f k x) \<longlonglongrightarrow> g x"
  3612  shows "g integrable_on S"
  3613 proof -
  3614   have habs: "h absolutely_integrable_on S"
  3615     using h normg nonnegative_absolutely_integrable_1 norm_ge_zero order_trans by blast
  3616   let ?f = "\<lambda>n x. (min (max (- h x) (f n x)) (h x))"
  3617   have h0: "h x \<ge> 0" if "x \<in> S" for x
  3618     using normg that by force
  3619   have leh: "norm (?f k x) \<le> h x" if "x \<in> S" for k x
  3620     using h0 that by force
  3621   have limf: "(\<lambda>k. ?f k x) \<longlonglongrightarrow> g x" if "x \<in> S" for x
  3622   proof -
  3623     have "\<And>e y. \<bar>f y x - g x\<bar> < e \<Longrightarrow> \<bar>min (max (- h x) (f y x)) (h x) - g x\<bar> < e"
  3624       using h0 [OF that] normg [OF that] by simp
  3625     then show ?thesis
  3626       using lim [OF that] by (auto simp add: tendsto_iff dist_norm elim!: eventually_mono)
  3627   qed
  3628   show ?thesis
  3629   proof (rule dominated_convergence [of ?f S h g])
  3630     have "(\<lambda>x. - h x) absolutely_integrable_on S"
  3631       using habs unfolding set_integrable_def by auto
  3632     then show "?f k integrable_on S" for k
  3633       by (intro set_lebesgue_integral_eq_integral absolutely_integrable_min_1 absolutely_integrable_max_1 f habs)
  3634   qed (use assms leh limf in auto)
  3635 qed
  3636 
  3637 lemma dominated_convergence_integrable:
  3638   fixes f :: "nat \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3639   assumes f: "\<And>k. f k absolutely_integrable_on S"
  3640     and h: "h integrable_on S"
  3641     and normg: "\<And>x. x \<in> S \<Longrightarrow> norm(g x) \<le> (h x)"
  3642     and lim: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>k. f k x) \<longlonglongrightarrow> g x"
  3643   shows "g integrable_on S"
  3644   using f
  3645   unfolding integrable_componentwise_iff [of g] absolutely_integrable_componentwise_iff [where f = "f k" for k]
  3646 proof clarify
  3647   fix b :: "'m"
  3648   assume fb [rule_format]: "\<And>k. \<forall>b\<in>Basis. (\<lambda>x. f k x \<bullet> b) absolutely_integrable_on S" and b: "b \<in> Basis"
  3649   show "(\<lambda>x. g x \<bullet> b) integrable_on S"
  3650   proof (rule dominated_convergence_integrable_1 [OF fb h])
  3651     fix x 
  3652     assume "x \<in> S"
  3653     show "norm (g x \<bullet> b) \<le> h x"
  3654       using norm_nth_le \<open>x \<in> S\<close> b normg order.trans by blast
  3655     show "(\<lambda>k. f k x \<bullet> b) \<longlonglongrightarrow> g x \<bullet> b"
  3656       using \<open>x \<in> S\<close> b lim tendsto_componentwise_iff by fastforce
  3657   qed (use b in auto)
  3658 qed
  3659 
  3660 lemma dominated_convergence_absolutely_integrable:
  3661   fixes f :: "nat \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  3662   assumes f: "\<And>k. f k absolutely_integrable_on S"
  3663     and h: "h integrable_on S"
  3664     and normg: "\<And>x. x \<in> S \<Longrightarrow> norm(g x) \<le> (h x)"
  3665     and lim: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>k. f k x) \<longlonglongrightarrow> g x"
  3666   shows "g absolutely_integrable_on S"
  3667 proof -
  3668   have "g integrable_on S"
  3669     by (rule dominated_convergence_integrable [OF assms])
  3670   with assms show ?thesis
  3671     by (blast intro:  absolutely_integrable_integrable_bound [where g=h])
  3672 qed
  3673 
  3674 
  3675 proposition integral_countable_UN:
  3676   fixes f :: "real^'m \<Rightarrow> real^'n"
  3677   assumes f: "f absolutely_integrable_on (\<Union>(range s))"
  3678     and s: "\<And>m. s m \<in> sets lebesgue"
  3679   shows "\<And>n. f absolutely_integrable_on (\<Union>m\<le>n. s m)"
  3680     and "(\<lambda>n. integral (\<Union>m\<le>n. s m) f) \<longlonglongrightarrow> integral (\<Union>(s ` UNIV)) f" (is "?F \<longlonglongrightarrow> ?I")
  3681 proof -
  3682   show fU: "f absolutely_integrable_on (\<Union>m\<le>n. s m)" for n
  3683     using assms by (blast intro: set_integrable_subset [OF f])
  3684   have fint: "f integrable_on (\<Union> (range s))"
  3685     using absolutely_integrable_on_def f by blast
  3686   let ?h = "\<lambda>x. if x \<in> \<Union>(s ` UNIV) then norm(f x) else 0"
  3687   have "(\<lambda>n. integral UNIV (\<lambda>x. if x \<in> (\<Union>m\<le>n. s m) then f x else 0))
  3688         \<longlonglongrightarrow> integral UNIV (\<lambda>x. if x \<in> \<Union>(s ` UNIV) then f x else 0)"
  3689   proof (rule dominated_convergence)
  3690     show "(\<lambda>x. if x \<in> (\<Union>m\<le>n. s m) then f x else 0) integrable_on UNIV" for n
  3691       unfolding integrable_restrict_UNIV
  3692       using fU absolutely_integrable_on_def by blast
  3693     show "(\<lambda>x. if x \<in> \<Union>(s ` UNIV) then norm(f x) else 0) integrable_on UNIV"
  3694       by (metis (no_types) absolutely_integrable_on_def f integrable_restrict_UNIV)
  3695     show "\<forall>x\<in>UNIV.
  3696          (\<lambda>n. if x \<in> (\<Union>m\<le>n. s m) then f x else 0)
  3697          \<longlonglongrightarrow> (if x \<in> \<Union>(s ` UNIV) then f x else 0)"
  3698       by (force intro: Lim_eventually eventually_sequentiallyI)
  3699   qed auto
  3700   then show "?F \<longlonglongrightarrow> ?I"
  3701     by (simp only: integral_restrict_UNIV)
  3702 qed
  3703 
  3704 
  3705 subsection \<open>Fundamental Theorem of Calculus for the Lebesgue integral\<close>
  3706 
  3707 text \<open>
  3708 
  3709 For the positive integral we replace continuity with Borel-measurability.
  3710 
  3711 \<close>
  3712 
  3713 lemma                                                                                          
  3714   fixes f :: "real \<Rightarrow> real"
  3715   assumes [measurable]: "f \<in> borel_measurable borel"
  3716   assumes f: "\<And>x. x \<in> {a..b} \<Longrightarrow> DERIV F x :> f x" "\<And>x. x \<in> {a..b} \<Longrightarrow> 0 \<le> f x" and "a \<le> b"
  3717   shows nn_integral_FTC_Icc: "(\<integral>\<^sup>+x. ennreal (f x) * indicator {a .. b} x \<partial>lborel) = F b - F a" (is ?nn)
  3718     and has_bochner_integral_FTC_Icc_nonneg:
  3719       "has_bochner_integral lborel (\<lambda>x. f x * indicator {a .. b} x) (F b - F a)" (is ?has)
  3720     and integral_FTC_Icc_nonneg: "(\<integral>x. f x * indicator {a .. b} x \<partial>lborel) = F b - F a" (is ?eq)
  3721     and integrable_FTC_Icc_nonneg: "integrable lborel (\<lambda>x. f x * indicator {a .. b} x)" (is ?int)
  3722 proof -
  3723   have *: "(\<lambda>x. f x * indicator {a..b} x) \<in> borel_measurable borel" "\<And>x. 0 \<le> f x * indicator {a..b} x"
  3724     using f(2) by (auto split: split_indicator)
  3725 
  3726   have F_mono: "a \<le> x \<Longrightarrow> x \<le> y \<Longrightarrow> y \<le> b\<Longrightarrow> F x \<le> F y" for x y
  3727     using f by (intro DERIV_nonneg_imp_nondecreasing[of x y F]) (auto intro: order_trans)
  3728 
  3729   have "(f has_integral F b - F a) {a..b}"
  3730     by (intro fundamental_theorem_of_calculus)
  3731        (auto simp: has_field_derivative_iff_has_vector_derivative[symmetric]
  3732              intro: has_field_derivative_subset[OF f(1)] \<open>a \<le> b\<close>)
  3733   then have i: "((\<lambda>x. f x * indicator {a .. b} x) has_integral F b - F a) UNIV"
  3734     unfolding indicator_def if_distrib[where f="\<lambda>x. a * x" for a]
  3735     by (simp cong del: if_weak_cong del: atLeastAtMost_iff)
  3736   then have nn: "(\<integral>\<^sup>+x. f x * indicator {a .. b} x \<partial>lborel) = F b - F a"
  3737     by (rule nn_integral_has_integral_lborel[OF *])
  3738   then show ?has
  3739     by (rule has_bochner_integral_nn_integral[rotated 3]) (simp_all add: * F_mono \<open>a \<le> b\<close>)
  3740   then show ?eq ?int
  3741     unfolding has_bochner_integral_iff by auto
  3742   show ?nn
  3743     by (subst nn[symmetric])
  3744        (auto intro!: nn_integral_cong simp add: ennreal_mult f split: split_indicator)
  3745 qed
  3746 
  3747 lemma
  3748   fixes f :: "real \<Rightarrow> 'a :: euclidean_space"
  3749   assumes "a \<le> b"
  3750   assumes "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_vector_derivative f x) (at x within {a .. b})"
  3751   assumes cont: "continuous_on {a .. b} f"
  3752   shows has_bochner_integral_FTC_Icc:
  3753       "has_bochner_integral lborel (\<lambda>x. indicator {a .. b} x *\<^sub>R f x) (F b - F a)" (is ?has)
  3754     and integral_FTC_Icc: "(\<integral>x. indicator {a .. b} x *\<^sub>R f x \<partial>lborel) = F b - F a" (is ?eq)
  3755 proof -
  3756   let ?f = "\<lambda>x. indicator {a .. b} x *\<^sub>R f x"
  3757   have int: "integrable lborel ?f"
  3758     using borel_integrable_compact[OF _ cont] by auto
  3759   have "(f has_integral F b - F a) {a..b}"
  3760     using assms(1,2) by (intro fundamental_theorem_of_calculus) auto
  3761   moreover
  3762   have "(f has_integral integral\<^sup>L lborel ?f) {a..b}"
  3763     using has_integral_integral_lborel[OF int]
  3764     unfolding indicator_def if_distrib[where f="\<lambda>x. x *\<^sub>R a" for a]
  3765     by (simp cong del: if_weak_cong del: atLeastAtMost_iff)
  3766   ultimately show ?eq
  3767     by (auto dest: has_integral_unique)
  3768   then show ?has
  3769     using int by (auto simp: has_bochner_integral_iff)
  3770 qed
  3771 
  3772 lemma
  3773   fixes f :: "real \<Rightarrow> real"
  3774   assumes "a \<le> b"
  3775   assumes deriv: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> DERIV F x :> f x"
  3776   assumes cont: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  3777   shows has_bochner_integral_FTC_Icc_real:
  3778       "has_bochner_integral lborel (\<lambda>x. f x * indicator {a .. b} x) (F b - F a)" (is ?has)
  3779     and integral_FTC_Icc_real: "(\<integral>x. f x * indicator {a .. b} x \<partial>lborel) = F b - F a" (is ?eq)
  3780 proof -
  3781   have 1: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_vector_derivative f x) (at x within {a .. b})"
  3782     unfolding has_field_derivative_iff_has_vector_derivative[symmetric]
  3783     using deriv by (auto intro: DERIV_subset)
  3784   have 2: "continuous_on {a .. b} f"
  3785     using cont by (intro continuous_at_imp_continuous_on) auto
  3786   show ?has ?eq
  3787     using has_bochner_integral_FTC_Icc[OF \<open>a \<le> b\<close> 1 2] integral_FTC_Icc[OF \<open>a \<le> b\<close> 1 2]
  3788     by (auto simp: mult.commute)
  3789 qed
  3790 
  3791 lemma nn_integral_FTC_atLeast:
  3792   fixes f :: "real \<Rightarrow> real"
  3793   assumes f_borel: "f \<in> borel_measurable borel"
  3794   assumes f: "\<And>x. a \<le> x \<Longrightarrow> DERIV F x :> f x"
  3795   assumes nonneg: "\<And>x. a \<le> x \<Longrightarrow> 0 \<le> f x"
  3796   assumes lim: "(F \<longlongrightarrow> T) at_top"
  3797   shows "(\<integral>\<^sup>+x. ennreal (f x) * indicator {a ..} x \<partial>lborel) = T - F a"
  3798 proof -
  3799   let ?f = "\<lambda>(i::nat) (x::real). ennreal (f x) * indicator {a..a + real i} x"
  3800   let ?fR = "\<lambda>x. ennreal (f x) * indicator {a ..} x"
  3801 
  3802   have F_mono: "a \<le> x \<Longrightarrow> x \<le> y \<Longrightarrow> F x \<le> F y" for x y
  3803     using f nonneg by (intro DERIV_nonneg_imp_nondecreasing[of x y F]) (auto intro: order_trans)
  3804   then have F_le_T: "a \<le> x \<Longrightarrow> F x \<le> T" for x
  3805     by (intro tendsto_lowerbound[OF lim])
  3806        (auto simp: eventually_at_top_linorder)
  3807 
  3808   have "(SUP i. ?f i x) = ?fR x" for x
  3809   proof (rule LIMSEQ_unique[OF LIMSEQ_SUP])
  3810     obtain n where "x - a < real n"
  3811       using reals_Archimedean2[of "x - a"] ..
  3812     then have "eventually (\<lambda>n. ?f n x = ?fR x) sequentially"
  3813       by (auto intro!: eventually_sequentiallyI[where c=n] split: split_indicator)
  3814     then show "(\<lambda>n. ?f n x) \<longlonglongrightarrow> ?fR x"
  3815       by (rule Lim_eventually)
  3816   qed (auto simp: nonneg incseq_def le_fun_def split: split_indicator)
  3817   then have "integral\<^sup>N lborel ?fR = (\<integral>\<^sup>+ x. (SUP i. ?f i x) \<partial>lborel)"
  3818     by simp
  3819   also have "\<dots> = (SUP i. (\<integral>\<^sup>+ x. ?f i x \<partial>lborel))"
  3820   proof (rule nn_integral_monotone_convergence_SUP)
  3821     show "incseq ?f"
  3822       using nonneg by (auto simp: incseq_def le_fun_def split: split_indicator)
  3823     show "\<And>i. (?f i) \<in> borel_measurable lborel"
  3824       using f_borel by auto
  3825   qed
  3826   also have "\<dots> = (SUP i. ennreal (F (a + real i) - F a))"
  3827     by (subst nn_integral_FTC_Icc[OF f_borel f nonneg]) auto
  3828   also have "\<dots> = T - F a"
  3829   proof (rule LIMSEQ_unique[OF LIMSEQ_SUP])
  3830     have "(\<lambda>x. F (a + real x)) \<longlonglongrightarrow> T"
  3831       apply (rule filterlim_compose[OF lim filterlim_tendsto_add_at_top])
  3832       apply (rule LIMSEQ_const_iff[THEN iffD2, OF refl])
  3833       apply (rule filterlim_real_sequentially)
  3834       done
  3835     then show "(\<lambda>n. ennreal (F (a + real n) - F a)) \<longlonglongrightarrow> ennreal (T - F a)"
  3836       by (simp add: F_mono F_le_T tendsto_diff)
  3837   qed (auto simp: incseq_def intro!: ennreal_le_iff[THEN iffD2] F_mono)
  3838   finally show ?thesis .
  3839 qed
  3840 
  3841 lemma integral_power:
  3842   "a \<le> b \<Longrightarrow> (\<integral>x. x^k * indicator {a..b} x \<partial>lborel) = (b^Suc k - a^Suc k) / Suc k"
  3843 proof (subst integral_FTC_Icc_real)
  3844   fix x show "DERIV (\<lambda>x. x^Suc k / Suc k) x :> x^k"
  3845     by (intro derivative_eq_intros) auto
  3846 qed (auto simp: field_simps simp del: of_nat_Suc)
  3847 
  3848 subsection \<open>Integration by parts\<close>
  3849 
  3850 lemma integral_by_parts_integrable:
  3851   fixes f g F G::"real \<Rightarrow> real"
  3852   assumes "a \<le> b"
  3853   assumes cont_f[intro]: "!!x. a \<le>x \<Longrightarrow> x\<le>b \<Longrightarrow> isCont f x"
  3854   assumes cont_g[intro]: "!!x. a \<le>x \<Longrightarrow> x\<le>b \<Longrightarrow> isCont g x"
  3855   assumes [intro]: "!!x. DERIV F x :> f x"
  3856   assumes [intro]: "!!x. DERIV G x :> g x"
  3857   shows  "integrable lborel (\<lambda>x.((F x) * (g x) + (f x) * (G x)) * indicator {a .. b} x)"
  3858   by (auto intro!: borel_integrable_atLeastAtMost continuous_intros) (auto intro!: DERIV_isCont)
  3859 
  3860 lemma integral_by_parts:
  3861   fixes f g F G::"real \<Rightarrow> real"
  3862   assumes [arith]: "a \<le> b"
  3863   assumes cont_f[intro]: "!!x. a \<le>x \<Longrightarrow> x\<le>b \<Longrightarrow> isCont f x"
  3864   assumes cont_g[intro]: "!!x. a \<le>x \<Longrightarrow> x\<le>b \<Longrightarrow> isCont g x"
  3865   assumes [intro]: "!!x. DERIV F x :> f x"
  3866   assumes [intro]: "!!x. DERIV G x :> g x"
  3867   shows "(\<integral>x. (F x * g x) * indicator {a .. b} x \<partial>lborel)
  3868             =  F b * G b - F a * G a - \<integral>x. (f x * G x) * indicator {a .. b} x \<partial>lborel"
  3869 proof-
  3870   have 0: "(\<integral>x. (F x * g x + f x * G x) * indicator {a .. b} x \<partial>lborel) = F b * G b - F a * G a"
  3871     by (rule integral_FTC_Icc_real, auto intro!: derivative_eq_intros continuous_intros)
  3872       (auto intro!: DERIV_isCont)
  3873 
  3874   have "(\<integral>x. (F x * g x + f x * G x) * indicator {a .. b} x \<partial>lborel) =
  3875     (\<integral>x. (F x * g x) * indicator {a .. b} x \<partial>lborel) + \<integral>x. (f x * G x) * indicator {a .. b} x \<partial>lborel"
  3876     apply (subst Bochner_Integration.integral_add[symmetric])
  3877     apply (auto intro!: borel_integrable_atLeastAtMost continuous_intros)
  3878     by (auto intro!: DERIV_isCont Bochner_Integration.integral_cong split: split_indicator)
  3879 
  3880   thus ?thesis using 0 by auto
  3881 qed
  3882 
  3883 lemma integral_by_parts':
  3884   fixes f g F G::"real \<Rightarrow> real"
  3885   assumes "a \<le> b"
  3886   assumes "!!x. a \<le>x \<Longrightarrow> x\<le>b \<Longrightarrow> isCont f x"
  3887   assumes "!!x. a \<le>x \<Longrightarrow> x\<le>b \<Longrightarrow> isCont g x"
  3888   assumes "!!x. DERIV F x :> f x"
  3889   assumes "!!x. DERIV G x :> g x"
  3890   shows "(\<integral>x. indicator {a .. b} x *\<^sub>R (F x * g x) \<partial>lborel)
  3891             =  F b * G b - F a * G a - \<integral>x. indicator {a .. b} x *\<^sub>R (f x * G x) \<partial>lborel"
  3892   using integral_by_parts[OF assms] by (simp add: ac_simps)
  3893 
  3894 lemma has_bochner_integral_even_function:
  3895   fixes f :: "real \<Rightarrow> 'a :: {banach, second_countable_topology}"
  3896   assumes f: "has_bochner_integral lborel (\<lambda>x. indicator {0..} x *\<^sub>R f x) x"
  3897   assumes even: "\<And>x. f (- x) = f x"
  3898   shows "has_bochner_integral lborel f (2 *\<^sub>R x)"
  3899 proof -
  3900   have indicator: "\<And>x::real. indicator {..0} (- x) = indicator {0..} x"
  3901     by (auto split: split_indicator)
  3902   have "has_bochner_integral lborel (\<lambda>x. indicator {.. 0} x *\<^sub>R f x) x"
  3903     by (subst lborel_has_bochner_integral_real_affine_iff[where c="-1" and t=0])
  3904        (auto simp: indicator even f)
  3905   with f have "has_bochner_integral lborel (\<lambda>x. indicator {0..} x *\<^sub>R f x + indicator {.. 0} x *\<^sub>R f x) (x + x)"
  3906     by (rule has_bochner_integral_add)
  3907   then have "has_bochner_integral lborel f (x + x)"
  3908     by (rule has_bochner_integral_discrete_difference[where X="{0}", THEN iffD1, rotated 4])
  3909        (auto split: split_indicator)
  3910   then show ?thesis
  3911     by (simp add: scaleR_2)
  3912 qed
  3913 
  3914 lemma has_bochner_integral_odd_function:
  3915   fixes f :: "real \<Rightarrow> 'a :: {banach, second_countable_topology}"
  3916   assumes f: "has_bochner_integral lborel (\<lambda>x. indicator {0..} x *\<^sub>R f x) x"
  3917   assumes odd: "\<And>x. f (- x) = - f x"
  3918   shows "has_bochner_integral lborel f 0"
  3919 proof -
  3920   have indicator: "\<And>x::real. indicator {..0} (- x) = indicator {0..} x"
  3921     by (auto split: split_indicator)
  3922   have "has_bochner_integral lborel (\<lambda>x. - indicator {.. 0} x *\<^sub>R f x) x"
  3923     by (subst lborel_has_bochner_integral_real_affine_iff[where c="-1" and t=0])
  3924        (auto simp: indicator odd f)
  3925   from has_bochner_integral_minus[OF this]
  3926   have "has_bochner_integral lborel (\<lambda>x. indicator {.. 0} x *\<^sub>R f x) (- x)"
  3927     by simp
  3928   with f have "has_bochner_integral lborel (\<lambda>x. indicator {0..} x *\<^sub>R f x + indicator {.. 0} x *\<^sub>R f x) (x + - x)"
  3929     by (rule has_bochner_integral_add)
  3930   then have "has_bochner_integral lborel f (x + - x)"
  3931     by (rule has_bochner_integral_discrete_difference[where X="{0}", THEN iffD1, rotated 4])
  3932        (auto split: split_indicator)
  3933   then show ?thesis
  3934     by simp
  3935 qed
  3936 
  3937 lemma has_integral_0_closure_imp_0:
  3938   fixes f :: "'a::euclidean_space \<Rightarrow> real"
  3939   assumes f: "continuous_on (closure S) f"
  3940     and nonneg_interior: "\<And>x. x \<in> S \<Longrightarrow> 0 \<le> f x"
  3941     and pos: "0 < emeasure lborel S"
  3942     and finite: "emeasure lborel S < \<infinity>"
  3943     and regular: "emeasure lborel (closure S) = emeasure lborel S"
  3944     and opn: "open S"
  3945   assumes int: "(f has_integral 0) (closure S)"
  3946   assumes x: "x \<in> closure S"
  3947   shows "f x = 0"
  3948 proof -
  3949   have zero: "emeasure lborel (frontier S) = 0"
  3950     using finite closure_subset regular
  3951     unfolding frontier_def
  3952     by (subst emeasure_Diff) (auto simp: frontier_def interior_open \<open>open S\<close> )
  3953   have nonneg: "0 \<le> f x" if "x \<in> closure S" for x
  3954     using continuous_ge_on_closure[OF f that nonneg_interior] by simp
  3955   have "0 = integral (closure S) f"
  3956     by (blast intro: int sym)
  3957   also
  3958   note intl = has_integral_integrable[OF int]
  3959   have af: "f absolutely_integrable_on (closure S)"
  3960     using nonneg
  3961     by (intro absolutely_integrable_onI intl integrable_eq[OF intl]) simp
  3962   then have "integral (closure S) f = set_lebesgue_integral lebesgue (closure S) f"
  3963     by (intro set_lebesgue_integral_eq_integral(2)[symmetric])
  3964   also have "\<dots> = 0 \<longleftrightarrow> (AE x in lebesgue. indicator (closure S) x *\<^sub>R f x = 0)"
  3965     unfolding set_lebesgue_integral_def
  3966   proof (rule integral_nonneg_eq_0_iff_AE)
  3967     show "integrable lebesgue (\<lambda>x. indicat_real (closure S) x *\<^sub>R f x)"
  3968       by (metis af set_integrable_def)
  3969   qed (use nonneg in \<open>auto simp: indicator_def\<close>)
  3970   also have "\<dots> \<longleftrightarrow> (AE x in lebesgue. x \<in> {x. x \<in> closure S \<longrightarrow> f x = 0})"
  3971     by (auto simp: indicator_def)
  3972   finally have "(AE x in lebesgue. x \<in> {x. x \<in> closure S \<longrightarrow> f x = 0})" by simp
  3973   moreover have "(AE x in lebesgue. x \<in> - frontier S)"
  3974     using zero
  3975     by (auto simp: eventually_ae_filter null_sets_def intro!: exI[where x="frontier S"])
  3976   ultimately have ae: "AE x \<in> S in lebesgue. x \<in> {x \<in> closure S. f x = 0}" (is ?th)
  3977     by eventually_elim (use closure_subset in \<open>auto simp: \<close>)
  3978   have "closed {0::real}" by simp
  3979   with continuous_on_closed_vimage[OF closed_closure, of S f] f
  3980   have "closed (f -` {0} \<inter> closure S)" by blast
  3981   then have "closed {x \<in> closure S. f x = 0}" by (auto simp: vimage_def Int_def conj_commute)
  3982   with \<open>open S\<close> have "x \<in> {x \<in> closure S. f x = 0}" if "x \<in> S" for x using ae that
  3983     by (rule mem_closed_if_AE_lebesgue_open)
  3984   then have "f x = 0" if "x \<in> S" for x using that by auto
  3985   from continuous_constant_on_closure[OF f this \<open>x \<in> closure S\<close>]
  3986   show "f x = 0" .
  3987 qed
  3988 
  3989 lemma has_integral_0_cbox_imp_0:
  3990   fixes f :: "'a::euclidean_space \<Rightarrow> real"
  3991   assumes f: "continuous_on (cbox a b) f"
  3992     and nonneg_interior: "\<And>x. x \<in> box a b \<Longrightarrow> 0 \<le> f x"
  3993   assumes int: "(f has_integral 0) (cbox a b)"
  3994   assumes ne: "box a b \<noteq> {}"
  3995   assumes x: "x \<in> cbox a b"
  3996   shows "f x = 0"
  3997 proof -
  3998   have "0 < emeasure lborel (box a b)"
  3999     using ne x unfolding emeasure_lborel_box_eq
  4000     by (force intro!: prod_pos simp: mem_box algebra_simps)
  4001   then show ?thesis using assms
  4002     by (intro has_integral_0_closure_imp_0[of "box a b" f x])
  4003       (auto simp: emeasure_lborel_box_eq emeasure_lborel_cbox_eq algebra_simps mem_box)
  4004 qed
  4005 
  4006 subsection\<open>Various common equivalent forms of function measurability\<close>
  4007 
  4008 lemma indicator_sum_eq:
  4009   fixes m::real and f :: "'a \<Rightarrow> real"
  4010   assumes "\<bar>m\<bar> \<le> 2 ^ (2*n)" "m/2^n \<le> f x" "f x < (m+1)/2^n" "m \<in> \<int>"
  4011   shows   "(\<Sum>k::real | k \<in> \<int> \<and> \<bar>k\<bar> \<le> 2 ^ (2*n).
  4012             k/2^n * indicator {y. k/2^n \<le> f y \<and> f y < (k+1)/2^n} x)  = m/2^n"
  4013           (is "sum ?f ?S = _")
  4014 proof -
  4015   have "sum ?f ?S = sum (\<lambda>k. k/2^n * indicator {y. k/2^n \<le> f y \<and> f y < (k+1)/2^n} x) {m}"
  4016   proof (rule comm_monoid_add_class.sum.mono_neutral_right)
  4017     show "finite ?S"
  4018       by (rule finite_abs_int_segment)
  4019     show "{m} \<subseteq> {k \<in> \<int>. \<bar>k\<bar> \<le> 2 ^ (2*n)}"
  4020       using assms by auto
  4021     show "\<forall>i\<in>{k \<in> \<int>. \<bar>k\<bar> \<le> 2 ^ (2*n)} - {m}. ?f i = 0"
  4022       using assms by (auto simp: indicator_def Ints_def abs_le_iff divide_simps)
  4023   qed
  4024   also have "\<dots> = m/2^n"
  4025     using assms by (auto simp: indicator_def not_less)
  4026   finally show ?thesis .
  4027 qed
  4028 
  4029 lemma measurable_on_sf_limit_lemma1:
  4030   fixes f :: "'a::euclidean_space \<Rightarrow> real"
  4031   assumes "\<And>a b. {x \<in> S. a \<le> f x \<and> f x < b} \<in> sets (lebesgue_on S)"
  4032   obtains g where "\<And>n. g n \<in> borel_measurable (lebesgue_on S)"
  4033                   "\<And>n. finite(range (g n))"
  4034                   "\<And>x. (\<lambda>n. g n x) \<longlonglongrightarrow> f x"
  4035 proof
  4036   show "(\<lambda>x. sum (\<lambda>k::real. k/2^n * indicator {y. k/2^n \<le> f y \<and> f y < (k+1)/2^n} x)
  4037                  {k \<in> \<int>. \<bar>k\<bar> \<le> 2 ^ (2*n)}) \<in> borel_measurable (lebesgue_on S)"
  4038         (is "?g \<in> _")  for n
  4039   proof -
  4040     have "\<And>k. \<lbrakk>k \<in> \<int>; \<bar>k\<bar> \<le> 2 ^ (2*n)\<rbrakk>
  4041          \<Longrightarrow> Measurable.pred (lebesgue_on S) (\<lambda>x. k / (2^n) \<le> f x \<and> f x < (k+1) / (2^n))"
  4042       using assms by (force simp: pred_def space_restrict_space)
  4043     then show ?thesis
  4044       by (simp add: field_class.field_divide_inverse)
  4045   qed
  4046   show "finite (range (?g n))" for n
  4047   proof -
  4048     have "range (?g n) \<subseteq> (\<lambda>k. k/2^n) ` {k \<in> \<int>. \<bar>k\<bar> \<le> 2 ^ (2*n)}"
  4049     proof clarify
  4050       fix x
  4051       show "?g n x  \<in> (\<lambda>k. k/2^n) ` {k \<in> \<int>. \<bar>k\<bar> \<le> 2 ^ (2*n)}"
  4052       proof (cases "\<exists>k::real. k \<in> \<int> \<and> \<bar>k\<bar> \<le> 2 ^ (2*n) \<and> k/2^n \<le> (f x) \<and> (f x) < (k+1)/2^n")
  4053         case True
  4054         then show ?thesis
  4055           apply clarify
  4056           by (subst indicator_sum_eq) auto
  4057       next
  4058         case False
  4059         then have "?g n x = 0" by auto
  4060         then show ?thesis by force
  4061       qed
  4062     qed
  4063     moreover have "finite ((\<lambda>k::real. (k/2^n)) ` {k \<in> \<int>. \<bar>k\<bar> \<le> 2 ^ (2*n)})"
  4064       by (simp add: finite_abs_int_segment)
  4065     ultimately show ?thesis
  4066       using finite_subset by blast
  4067   qed
  4068   show "(\<lambda>n. ?g n x) \<longlonglongrightarrow> f x" for x
  4069   proof (rule LIMSEQ_I)
  4070     fix e::real
  4071     assume "e > 0"
  4072     obtain N1 where N1: "\<bar>f x\<bar> < 2 ^ N1"
  4073       using real_arch_pow by fastforce
  4074     obtain N2 where N2: "(1/2) ^ N2 < e"
  4075       using real_arch_pow_inv \<open>e > 0\<close> by force
  4076     have "norm (?g n x - f x) < e" if n: "n \<ge> max N1 N2" for n
  4077     proof -
  4078       define m where "m \<equiv> floor(2^n * (f x))"
  4079       have "1 \<le> \<bar>2^n\<bar> * e"
  4080         using n N2 \<open>e > 0\<close> less_eq_real_def less_le_trans by (fastforce simp add: divide_simps)
  4081       then have *: "\<lbrakk>x \<le> y; y < x + 1\<rbrakk> \<Longrightarrow> abs(x - y) < \<bar>2^n\<bar> * e" for x y::real
  4082         by linarith
  4083       have "\<bar>2^n\<bar> * \<bar>m/2^n - f x\<bar> = \<bar>2^n * (m/2^n - f x)\<bar>"
  4084         by (simp add: abs_mult)
  4085       also have "\<dots> = \<bar>real_of_int \<lfloor>2^n * f x\<rfloor> - f x * 2^n\<bar>"
  4086         by (simp add: algebra_simps m_def)
  4087       also have "\<dots> < \<bar>2^n\<bar> * e"
  4088         by (rule *; simp add: mult.commute)
  4089       finally have "\<bar>2^n\<bar> * \<bar>m/2^n - f x\<bar> < \<bar>2^n\<bar> * e" .
  4090       then have me: "\<bar>m/2^n - f x\<bar> < e"
  4091         by simp
  4092       have "\<bar>real_of_int m\<bar> \<le> 2 ^ (2*n)"
  4093       proof (cases "f x < 0")
  4094         case True
  4095         then have "-\<lfloor>f x\<rfloor> \<le> \<lfloor>(2::real) ^ N1\<rfloor>"
  4096           using N1 le_floor_iff minus_le_iff by fastforce
  4097         with n True have "\<bar>real_of_int\<lfloor>f x\<rfloor>\<bar> \<le> 2 ^ N1"
  4098           by linarith
  4099         also have "\<dots> \<le> 2^n"
  4100           using n by (simp add: m_def)
  4101         finally have "\<bar>real_of_int \<lfloor>f x\<rfloor>\<bar> * 2^n \<le> 2^n * 2^n"
  4102           by simp
  4103         moreover
  4104         have "\<bar>real_of_int \<lfloor>2^n * f x\<rfloor>\<bar> \<le> \<bar>real_of_int \<lfloor>f x\<rfloor>\<bar> * 2^n"
  4105         proof -
  4106           have "\<bar>real_of_int \<lfloor>2^n * f x\<rfloor>\<bar> = - (real_of_int \<lfloor>2^n * f x\<rfloor>)"
  4107             using True by (simp add: abs_if mult_less_0_iff)
  4108           also have "\<dots> \<le> - (real_of_int (\<lfloor>(2::real) ^ n\<rfloor> * \<lfloor>f x\<rfloor>))"
  4109             using le_mult_floor_Ints [of "(2::real)^n"] by simp
  4110           also have "\<dots> \<le> \<bar>real_of_int \<lfloor>f x\<rfloor>\<bar> * 2^n"
  4111             using True
  4112             by simp
  4113           finally show ?thesis .
  4114         qed
  4115         ultimately show ?thesis
  4116           by (metis (no_types, hide_lams) m_def order_trans power2_eq_square power_even_eq)
  4117       next
  4118         case False
  4119         with n N1 have "f x \<le> 2^n"
  4120           by (simp add: not_less) (meson less_eq_real_def one_le_numeral order_trans power_increasing)
  4121         moreover have "0 \<le> m"
  4122           using False m_def by force
  4123         ultimately show ?thesis
  4124           by (metis abs_of_nonneg floor_mono le_floor_iff m_def of_int_0_le_iff power2_eq_square power_mult real_mult_le_cancel_iff1 zero_less_numeral mult.commute zero_less_power)
  4125       qed
  4126       then have "?g n x = m/2^n"
  4127         by (rule indicator_sum_eq) (auto simp: m_def mult.commute divide_simps)
  4128       then have "norm (?g n x - f x) = norm (m/2^n - f x)"
  4129         by simp
  4130       also have "\<dots> < e"
  4131         by (simp add: me)
  4132       finally show ?thesis .
  4133     qed
  4134     then show "\<exists>no. \<forall>n\<ge>no. norm (?g n x - f x) < e"
  4135       by blast
  4136   qed
  4137 qed
  4138 
  4139 
  4140 lemma borel_measurable_vimage_halfspace_component_lt:
  4141      "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4142       (\<forall>a i. i \<in> Basis \<longrightarrow> {x \<in> S. f x \<bullet> i < a} \<in> sets (lebesgue_on S))"
  4143   apply (rule trans [OF borel_measurable_iff_halfspace_less])
  4144   apply (fastforce simp add: space_restrict_space)
  4145   done
  4146 
  4147 lemma borel_measurable_simple_function_limit:
  4148   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4149   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4150          (\<exists>g. (\<forall>n. (g n) \<in> borel_measurable (lebesgue_on S)) \<and>
  4151               (\<forall>n. finite (range (g n))) \<and> (\<forall>x. (\<lambda>n. g n x) \<longlonglongrightarrow> f x))"
  4152 proof -
  4153   have "\<exists>g. (\<forall>n. (g n) \<in> borel_measurable (lebesgue_on S)) \<and>
  4154             (\<forall>n. finite (range (g n))) \<and> (\<forall>x. (\<lambda>n. g n x) \<longlonglongrightarrow> f x)"
  4155        if f: "\<And>a i. i \<in> Basis \<Longrightarrow> {x \<in> S. f x \<bullet> i < a} \<in> sets (lebesgue_on S)"
  4156   proof -
  4157     have "\<exists>g. (\<forall>n. (g n) \<in> borel_measurable (lebesgue_on S)) \<and>
  4158                   (\<forall>n. finite(image (g n) UNIV)) \<and>
  4159                   (\<forall>x. ((\<lambda>n. g n x) \<longlonglongrightarrow> f x \<bullet> i))" if "i \<in> Basis" for i
  4160     proof (rule measurable_on_sf_limit_lemma1 [of S "\<lambda>x. f x \<bullet> i"])
  4161       show "{x \<in> S. a \<le> f x \<bullet> i \<and> f x \<bullet> i < b} \<in> sets (lebesgue_on S)" for a b
  4162       proof -
  4163         have "{x \<in> S. a \<le> f x \<bullet> i \<and> f x \<bullet> i < b} = {x \<in> S. f x \<bullet> i < b} - {x \<in> S. a > f x \<bullet> i}"
  4164           by auto
  4165         also have "\<dots> \<in> sets (lebesgue_on S)"
  4166           using f that by blast
  4167         finally show ?thesis .
  4168       qed
  4169     qed blast
  4170     then obtain g where g:
  4171           "\<And>i n. i \<in> Basis \<Longrightarrow> g i n \<in> borel_measurable (lebesgue_on S)"
  4172           "\<And>i n. i \<in> Basis \<Longrightarrow> finite(range (g i n))"
  4173           "\<And>i x. i \<in> Basis \<Longrightarrow> ((\<lambda>n. g i n x) \<longlonglongrightarrow> f x \<bullet> i)"
  4174       by metis
  4175     show ?thesis
  4176     proof (intro conjI allI exI)
  4177       show "(\<lambda>x. \<Sum>i\<in>Basis. g i n x *\<^sub>R i) \<in> borel_measurable (lebesgue_on S)" for n
  4178         by (intro borel_measurable_sum borel_measurable_scaleR) (auto intro: g)
  4179       show "finite (range (\<lambda>x. \<Sum>i\<in>Basis. g i n x *\<^sub>R i))" for n
  4180       proof -
  4181         have "range (\<lambda>x. \<Sum>i\<in>Basis. g i n x *\<^sub>R i) \<subseteq> (\<lambda>h. \<Sum>i\<in>Basis. h i *\<^sub>R i) ` PiE Basis (\<lambda>i. range (g i n))"
  4182         proof clarify
  4183           fix x
  4184           show "(\<Sum>i\<in>Basis. g i n x *\<^sub>R i) \<in> (\<lambda>h. \<Sum>i\<in>Basis. h i *\<^sub>R i) ` (\<Pi>\<^sub>E i\<in>Basis. range (g i n))"
  4185             by (rule_tac x="\<lambda>i\<in>Basis. g i n x" in image_eqI) auto
  4186         qed
  4187         moreover have "finite(PiE Basis (\<lambda>i. range (g i n)))"
  4188           by (simp add: g finite_PiE)
  4189         ultimately show ?thesis
  4190           by (metis (mono_tags, lifting) finite_surj)
  4191       qed
  4192       show "(\<lambda>n. \<Sum>i\<in>Basis. g i n x *\<^sub>R i) \<longlonglongrightarrow> f x" for x
  4193       proof -
  4194         have "(\<lambda>n. \<Sum>i\<in>Basis. g i n x *\<^sub>R i) \<longlonglongrightarrow> (\<Sum>i\<in>Basis. (f x \<bullet> i) *\<^sub>R i)"
  4195           by (auto intro!: tendsto_sum tendsto_scaleR g)
  4196         moreover have "(\<Sum>i\<in>Basis. (f x \<bullet> i) *\<^sub>R i) = f x"
  4197           using euclidean_representation by blast
  4198         ultimately show ?thesis
  4199           by metis
  4200       qed
  4201     qed
  4202   qed
  4203   moreover have "f \<in> borel_measurable (lebesgue_on S)"
  4204               if meas_g: "\<And>n. g n \<in> borel_measurable (lebesgue_on S)"
  4205                  and fin: "\<And>n. finite (range (g n))"
  4206                  and to_f: "\<And>x. (\<lambda>n. g n x) \<longlonglongrightarrow> f x" for  g
  4207     by (rule borel_measurable_LIMSEQ_metric [OF meas_g to_f])
  4208   ultimately show ?thesis
  4209     using borel_measurable_vimage_halfspace_component_lt by blast
  4210 qed
  4211 
  4212 lemma borel_measurable_vimage_halfspace_component_ge:
  4213   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4214   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4215          (\<forall>a i. i \<in> Basis \<longrightarrow> {x \<in> S. f x \<bullet> i \<ge> a} \<in> sets (lebesgue_on S))"
  4216   apply (rule trans [OF borel_measurable_iff_halfspace_ge])
  4217   apply (fastforce simp add: space_restrict_space)
  4218   done
  4219 
  4220 lemma borel_measurable_vimage_halfspace_component_gt:
  4221   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4222   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4223          (\<forall>a i. i \<in> Basis \<longrightarrow> {x \<in> S. f x \<bullet> i > a} \<in> sets (lebesgue_on S))"
  4224   apply (rule trans [OF borel_measurable_iff_halfspace_greater])
  4225   apply (fastforce simp add: space_restrict_space)
  4226   done
  4227 
  4228 lemma borel_measurable_vimage_halfspace_component_le:
  4229   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4230   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4231          (\<forall>a i. i \<in> Basis \<longrightarrow> {x \<in> S. f x \<bullet> i \<le> a} \<in> sets (lebesgue_on S))"
  4232   apply (rule trans [OF borel_measurable_iff_halfspace_le])
  4233   apply (fastforce simp add: space_restrict_space)
  4234   done
  4235 
  4236 lemma
  4237   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4238   shows borel_measurable_vimage_open_interval:
  4239          "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4240          (\<forall>a b. {x \<in> S. f x \<in> box a b} \<in> sets (lebesgue_on S))" (is ?thesis1)
  4241    and borel_measurable_vimage_open:
  4242          "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4243          (\<forall>T. open T \<longrightarrow> {x \<in> S. f x \<in> T} \<in> sets (lebesgue_on S))" (is ?thesis2)
  4244 proof -
  4245   have "{x \<in> S. f x \<in> box a b} \<in> sets (lebesgue_on S)" if "f \<in> borel_measurable (lebesgue_on S)" for a b
  4246   proof -
  4247     have "S = S \<inter> space lebesgue"
  4248       by simp
  4249     then have "S \<inter> (f -` box a b) \<in> sets (lebesgue_on S)"
  4250       by (metis (no_types) box_borel in_borel_measurable_borel inf_sup_aci(1) space_restrict_space that)
  4251     then show ?thesis
  4252       by (simp add: Collect_conj_eq vimage_def)
  4253   qed
  4254   moreover
  4255   have "{x \<in> S. f x \<in> T} \<in> sets (lebesgue_on S)"
  4256        if T: "\<And>a b. {x \<in> S. f x \<in> box a b} \<in> sets (lebesgue_on S)" "open T" for T
  4257   proof -
  4258     obtain \<D> where "countable \<D>" and \<D>: "\<And>X. X \<in> \<D> \<Longrightarrow> \<exists>a b. X = box a b" "\<Union>\<D> = T"
  4259       using open_countable_Union_open_box that \<open>open T\<close> by metis
  4260     then have eq: "{x \<in> S. f x \<in> T} = (\<Union>U \<in> \<D>. {x \<in> S. f x \<in> U})"
  4261       by blast
  4262     have "{x \<in> S. f x \<in> U} \<in> sets (lebesgue_on S)" if "U \<in> \<D>" for U
  4263       using that T \<D> by blast
  4264     then show ?thesis
  4265       by (auto simp: eq intro: Sigma_Algebra.sets.countable_UN' [OF \<open>countable \<D>\<close>])
  4266   qed
  4267   moreover
  4268   have eq: "{x \<in> S. f x \<bullet> i < a} = {x \<in> S. f x \<in> {y. y \<bullet> i < a}}" for i a
  4269     by auto
  4270   have "f \<in> borel_measurable (lebesgue_on S)"
  4271     if "\<And>T. open T \<Longrightarrow> {x \<in> S. f x \<in> T} \<in> sets (lebesgue_on S)"
  4272     by (metis (no_types) eq borel_measurable_vimage_halfspace_component_lt open_halfspace_component_lt that)
  4273   ultimately show "?thesis1" "?thesis2"
  4274     by blast+
  4275 qed
  4276 
  4277 
  4278 lemma borel_measurable_vimage_closed:
  4279   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4280   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4281          (\<forall>T. closed T \<longrightarrow> {x \<in> S. f x \<in> T} \<in> sets (lebesgue_on S))"
  4282         (is "?lhs = ?rhs")
  4283 proof -
  4284   have eq: "{x \<in> S. f x \<in> T} = S - {x \<in> S. f x \<in> (- T)}" for T
  4285     by auto
  4286   show ?thesis
  4287     apply (simp add: borel_measurable_vimage_open, safe)
  4288      apply (simp_all (no_asm) add: eq)
  4289      apply (intro sets.Diff sets_lebesgue_on_refl, force simp: closed_open)
  4290     apply (intro sets.Diff sets_lebesgue_on_refl, force simp: open_closed)
  4291     done
  4292 qed
  4293 
  4294 lemma borel_measurable_vimage_closed_interval:
  4295   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4296   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4297          (\<forall>a b. {x \<in> S. f x \<in> cbox a b} \<in> sets (lebesgue_on S))"
  4298         (is "?lhs = ?rhs")
  4299 proof
  4300   assume ?lhs then show ?rhs
  4301     using borel_measurable_vimage_closed by blast
  4302 next
  4303   assume RHS: ?rhs
  4304   have "{x \<in> S. f x \<in> T} \<in> sets (lebesgue_on S)" if "open T" for T
  4305   proof -
  4306     obtain \<D> where "countable \<D>" and \<D>: "\<D> \<subseteq> Pow T" "\<And>X. X \<in> \<D> \<Longrightarrow> \<exists>a b. X = cbox a b" "\<Union>\<D> = T"
  4307       using open_countable_Union_open_cbox that \<open>open T\<close> by metis
  4308     then have eq: "{x \<in> S. f x \<in> T} = (\<Union>U \<in> \<D>. {x \<in> S. f x \<in> U})"
  4309       by blast
  4310     have "{x \<in> S. f x \<in> U} \<in> sets (lebesgue_on S)" if "U \<in> \<D>" for U
  4311       using that \<D> by (metis RHS)
  4312     then show ?thesis
  4313       by (auto simp: eq intro: Sigma_Algebra.sets.countable_UN' [OF \<open>countable \<D>\<close>])
  4314   qed
  4315   then show ?lhs
  4316     by (simp add: borel_measurable_vimage_open)
  4317 qed
  4318 
  4319 lemma borel_measurable_UNIV_eq: "borel_measurable (lebesgue_on UNIV) = borel_measurable lebesgue"
  4320   by auto
  4321 
  4322 lemma borel_measurable_vimage_borel:
  4323   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4324   shows "f \<in> borel_measurable (lebesgue_on S) \<longleftrightarrow>
  4325          (\<forall>T. T \<in> sets borel \<longrightarrow> {x \<in> S. f x \<in> T} \<in> sets (lebesgue_on S))"
  4326         (is "?lhs = ?rhs")
  4327 proof
  4328   assume f: ?lhs
  4329   then show ?rhs
  4330     using measurable_sets [OF f]
  4331       by (simp add: Collect_conj_eq inf_sup_aci(1) space_restrict_space vimage_def)
  4332 qed (simp add: borel_measurable_vimage_open_interval)
  4333 
  4334 lemma lebesgue_measurable_vimage_borel:
  4335   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4336   assumes "f \<in> borel_measurable lebesgue" "T \<in> sets borel"
  4337   shows "{x. f x \<in> T} \<in> sets lebesgue"
  4338   using assms borel_measurable_vimage_borel [of f UNIV] by auto
  4339 
  4340 lemma borel_measurable_If_I:
  4341   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4342   assumes f: "f \<in> borel_measurable (lebesgue_on S)" and S: "S \<in> sets lebesgue"
  4343   shows "(\<lambda>x. if x \<in> S then f x else 0) \<in> borel_measurable lebesgue"
  4344 proof -
  4345   have eq: "{x. x \<notin> S} \<union> {x. f x \<in> Y} = {x. x \<notin> S} \<union> {x. f x \<in> Y} \<inter> S" for Y
  4346     by blast
  4347   show ?thesis
  4348   using f S
  4349   apply (simp add: vimage_def in_borel_measurable_borel Ball_def)
  4350   apply (elim all_forward imp_forward asm_rl)
  4351   apply (simp only: Collect_conj_eq Collect_disj_eq imp_conv_disj eq)
  4352   apply (auto simp: Compl_eq [symmetric] Compl_in_sets_lebesgue sets_restrict_space_iff)
  4353   done
  4354 qed
  4355 
  4356 lemma borel_measurable_If_D:
  4357   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4358   assumes "(\<lambda>x. if x \<in> S then f x else 0) \<in> borel_measurable lebesgue"
  4359   shows "f \<in> borel_measurable (lebesgue_on S)"
  4360   using assms
  4361   apply (simp add: in_borel_measurable_borel Ball_def)
  4362   apply (elim all_forward imp_forward asm_rl)
  4363   apply (force simp: space_restrict_space sets_restrict_space image_iff intro: rev_bexI)
  4364   done
  4365 
  4366 lemma borel_measurable_UNIV:
  4367   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4368   assumes "S \<in> sets lebesgue"
  4369   shows "(\<lambda>x. if x \<in> S then f x else 0) \<in> borel_measurable lebesgue \<longleftrightarrow> f \<in> borel_measurable (lebesgue_on S)"
  4370   using assms borel_measurable_If_D borel_measurable_If_I by blast
  4371 
  4372 lemma borel_measurable_lebesgue_preimage_borel:
  4373   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4374   shows "f \<in> borel_measurable lebesgue \<longleftrightarrow>
  4375          (\<forall>T. T \<in> sets borel \<longrightarrow> {x. f x \<in> T} \<in> sets lebesgue)"
  4376   apply (intro iffI allI impI lebesgue_measurable_vimage_borel)
  4377     apply (auto simp: in_borel_measurable_borel vimage_def)
  4378   done
  4379 
  4380 subsection\<open>More results on integrability\<close>
  4381 
  4382 lemma integrable_on_all_intervals_UNIV:
  4383   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::banach"
  4384   assumes intf: "\<And>a b. f integrable_on cbox a b"
  4385     and normf: "\<And>x. norm(f x) \<le> g x" and g: "g integrable_on UNIV"
  4386   shows "f integrable_on UNIV"
  4387 proof -
  4388 have intg: "(\<forall>a b. g integrable_on cbox a b)"
  4389     and gle_e: "\<forall>e>0. \<exists>B>0. \<forall>a b c d.
  4390                     ball 0 B \<subseteq> cbox a b \<and> cbox a b \<subseteq> cbox c d \<longrightarrow>
  4391                     \<bar>integral (cbox a b) g - integral (cbox c d) g\<bar>
  4392                     < e"
  4393     using g
  4394     by (auto simp: integrable_alt_subset [of _ UNIV] intf)
  4395   have le: "norm (integral (cbox a b) f - integral (cbox c d) f) \<le> \<bar>integral (cbox a b) g - integral (cbox c d) g\<bar>"
  4396     if "cbox a b \<subseteq> cbox c d" for a b c d
  4397   proof -
  4398     have "norm (integral (cbox a b) f - integral (cbox c d) f) = norm (integral (cbox c d - cbox a b) f)"
  4399       using intf that by (simp add: norm_minus_commute integral_setdiff)
  4400     also have "\<dots> \<le> integral (cbox c d - cbox a b) g"
  4401     proof (rule integral_norm_bound_integral [OF _ _ normf])
  4402       show "f integrable_on cbox c d - cbox a b" "g integrable_on cbox c d - cbox a b"
  4403         by (meson integrable_integral integrable_setdiff intf intg negligible_setdiff that)+
  4404     qed
  4405     also have "\<dots> = integral (cbox c d) g - integral (cbox a b) g"
  4406       using intg that by (simp add: integral_setdiff)
  4407     also have "\<dots> \<le> \<bar>integral (cbox a b) g - integral (cbox c d) g\<bar>"
  4408       by simp
  4409     finally show ?thesis .
  4410   qed
  4411   show ?thesis
  4412     using gle_e
  4413     apply (simp add: integrable_alt_subset [of _ UNIV] intf)
  4414     apply (erule imp_forward all_forward ex_forward asm_rl)+
  4415     by (meson not_less order_trans le)
  4416 qed
  4417 
  4418 lemma integrable_on_all_intervals_integrable_bound:
  4419   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::banach"
  4420   assumes intf: "\<And>a b. (\<lambda>x. if x \<in> S then f x else 0) integrable_on cbox a b"
  4421     and normf: "\<And>x. x \<in> S \<Longrightarrow> norm(f x) \<le> g x" and g: "g integrable_on S"
  4422   shows "f integrable_on S"
  4423   using integrable_on_all_intervals_UNIV [OF intf, of "(\<lambda>x. if x \<in> S then g x else 0)"]
  4424   by (simp add: g integrable_restrict_UNIV normf)
  4425 
  4426 lemma measurable_bounded_lemma:
  4427   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4428   assumes f: "f \<in> borel_measurable lebesgue" and g: "g integrable_on cbox a b"
  4429     and normf: "\<And>x. x \<in> cbox a b \<Longrightarrow> norm(f x) \<le> g x"
  4430   shows "f integrable_on cbox a b"
  4431 proof -
  4432   have "g absolutely_integrable_on cbox a b"
  4433     by (metis (full_types) add_increasing g le_add_same_cancel1 nonnegative_absolutely_integrable_1 norm_ge_zero normf)
  4434   then have "integrable (lebesgue_on (cbox a b)) g"
  4435     by (simp add: integrable_restrict_space set_integrable_def)
  4436   then have "integrable (lebesgue_on (cbox a b)) f"
  4437   proof (rule Bochner_Integration.integrable_bound)
  4438     show "AE x in lebesgue_on (cbox a b). norm (f x) \<le> norm (g x)"
  4439       by (rule AE_I2) (auto intro: normf order_trans)
  4440   qed (simp add: f measurable_restrict_space1)
  4441   then show ?thesis
  4442     by (simp add: integrable_on_lebesgue_on)
  4443 qed
  4444 
  4445 proposition measurable_bounded_by_integrable_imp_integrable:
  4446   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4447   assumes f: "f \<in> borel_measurable (lebesgue_on S)" and g: "g integrable_on S"
  4448     and normf: "\<And>x. x \<in> S \<Longrightarrow> norm(f x) \<le> g x" and S: "S \<in> sets lebesgue"
  4449   shows "f integrable_on S"
  4450 proof (rule integrable_on_all_intervals_integrable_bound [OF _ normf g])
  4451   show "(\<lambda>x. if x \<in> S then f x else 0) integrable_on cbox a b" for a b
  4452   proof (rule measurable_bounded_lemma)
  4453     show "(\<lambda>x. if x \<in> S then f x else 0) \<in> borel_measurable lebesgue"
  4454       by (simp add: S borel_measurable_UNIV f)
  4455     show "(\<lambda>x. if x \<in> S then g x else 0) integrable_on cbox a b"
  4456       by (simp add: g integrable_altD(1))
  4457     show "norm (if x \<in> S then f x else 0) \<le> (if x \<in> S then g x else 0)" for x
  4458       using normf by simp
  4459   qed
  4460 qed
  4461 
  4462 subsection\<open> Relation between Borel measurability and integrability.\<close>
  4463 
  4464 lemma integrable_imp_measurable_weak:
  4465   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4466   assumes "S \<in> sets lebesgue" "f integrable_on S"
  4467   shows "f \<in> borel_measurable (lebesgue_on S)"
  4468   by (metis (mono_tags, lifting) assms has_integral_implies_lebesgue_measurable borel_measurable_restrict_space_iff integrable_on_def sets.Int_space_eq2)
  4469 
  4470 lemma integrable_imp_measurable:
  4471   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4472   assumes "f integrable_on S"
  4473   shows "f \<in> borel_measurable (lebesgue_on S)"
  4474 proof -
  4475   have "(UNIV::'a set) \<in> sets lborel"
  4476     by simp
  4477   then show ?thesis
  4478     using assms borel_measurable_If_D borel_measurable_UNIV_eq integrable_imp_measurable_weak integrable_restrict_UNIV by blast
  4479 qed
  4480 
  4481 proposition negligible_differentiable_vimage:
  4482   fixes f :: "'a \<Rightarrow> 'a::euclidean_space"
  4483   assumes "negligible T"
  4484     and f': "\<And>x. x \<in> S \<Longrightarrow> inj(f' x)"
  4485     and derf: "\<And>x. x \<in> S \<Longrightarrow> (f has_derivative f' x) (at x within S)"
  4486   shows "negligible {x \<in> S. f x \<in> T}"
  4487 proof -
  4488   define U where
  4489     "U \<equiv> \<lambda>n::nat. {x \<in> S. \<forall>y. y \<in> S \<and> norm(y - x) < 1/n
  4490                      \<longrightarrow> norm(y - x) \<le> n * norm(f y - f x)}"
  4491   have "negligible {x \<in> U n. f x \<in> T}" if "n > 0" for n
  4492   proof (subst locally_negligible_alt, clarify)
  4493     fix a
  4494     assume a: "a \<in> U n" and fa: "f a \<in> T"
  4495     define V where "V \<equiv> {x. x \<in> U n \<and> f x \<in> T} \<inter> ball a (1 / n / 2)"
  4496     show "\<exists>V. openin (top_of_set {x \<in> U n. f x \<in> T}) V \<and> a \<in> V \<and> negligible V"
  4497     proof (intro exI conjI)
  4498       have noxy: "norm(x - y) \<le> n * norm(f x - f y)" if "x \<in> V" "y \<in> V" for x y
  4499         using that unfolding U_def V_def mem_Collect_eq Int_iff mem_ball dist_norm
  4500         by (meson norm_triangle_half_r)
  4501       then have "inj_on f V"
  4502         by (force simp: inj_on_def)
  4503       then obtain g where g: "\<And>x. x \<in> V \<Longrightarrow> g(f x) = x"
  4504         by (metis inv_into_f_f)
  4505       have "\<exists>T' B. open T' \<and> f x \<in> T' \<and>
  4506                    (\<forall>y\<in>f ` V \<inter> T \<inter> T'. norm (g y - g (f x)) \<le> B * norm (y - f x))"
  4507         if "f x \<in> T" "x \<in> V" for x
  4508         apply (rule_tac x = "ball (f x) 1" in exI)
  4509         using that noxy by (force simp: g)
  4510       then have "negligible (g ` (f ` V \<inter> T))"
  4511         by (force simp: \<open>negligible T\<close> negligible_Int intro!: negligible_locally_Lipschitz_image)
  4512       moreover have "V \<subseteq> g ` (f ` V \<inter> T)"
  4513         by (force simp: g image_iff V_def)
  4514       ultimately show "negligible V"
  4515         by (rule negligible_subset)
  4516     qed (use a fa V_def that in auto)
  4517   qed
  4518   with negligible_countable_Union have "negligible (\<Union>n \<in> {0<..}. {x. x \<in> U n \<and> f x \<in> T})"
  4519     by auto
  4520   moreover have "{x \<in> S. f x \<in> T} \<subseteq> (\<Union>n \<in> {0<..}. {x. x \<in> U n \<and> f x \<in> T})"
  4521   proof clarsimp
  4522     fix x
  4523     assume "x \<in> S" and "f x \<in> T"
  4524     then obtain inj: "inj(f' x)" and der: "(f has_derivative f' x) (at x within S)"
  4525       using assms by metis
  4526     moreover have "linear(f' x)"
  4527       and eps: "\<And>\<epsilon>. \<epsilon> > 0 \<Longrightarrow> \<exists>\<delta>>0. \<forall>y\<in>S. norm (y - x) < \<delta> \<longrightarrow>
  4528                       norm (f y - f x - f' x (y - x)) \<le> \<epsilon> * norm (y - x)"
  4529       using der by (auto simp: has_derivative_within_alt linear_linear)
  4530     ultimately obtain g where "linear g" and g: "g \<circ> f' x = id"
  4531       using linear_injective_left_inverse by metis
  4532     then obtain B where "B > 0" and B: "\<And>z. B * norm z \<le> norm(f' x z)"
  4533       using linear_invertible_bounded_below_pos \<open>linear (f' x)\<close> by blast
  4534     then obtain i where "i \<noteq> 0" and i: "1 / real i < B"
  4535       by (metis (full_types) inverse_eq_divide real_arch_invD)
  4536     then obtain \<delta> where "\<delta> > 0"
  4537          and \<delta>: "\<And>y. \<lbrakk>y\<in>S; norm (y - x) < \<delta>\<rbrakk> \<Longrightarrow>
  4538                   norm (f y - f x - f' x (y - x)) \<le> (B - 1 / real i) * norm (y - x)"
  4539       using eps [of "B - 1/i"] by auto
  4540     then obtain j where "j \<noteq> 0" and j: "inverse (real j) < \<delta>"
  4541       using real_arch_inverse by blast
  4542     have "norm (y - x)/(max i j) \<le> norm (f y - f x)"
  4543       if "y \<in> S" and less: "norm (y - x) < 1 / (max i j)" for y
  4544     proof -
  4545       have "1 / real (max i j) < \<delta>"
  4546         using j \<open>j \<noteq> 0\<close> \<open>0 < \<delta>\<close>
  4547         by (auto simp: divide_simps max_mult_distrib_left of_nat_max)
  4548     then have "norm (y - x) < \<delta>"
  4549       using less by linarith
  4550     with \<delta> \<open>y \<in> S\<close> have le: "norm (f y - f x - f' x (y - x)) \<le> B * norm (y - x) - norm (y - x)/i"
  4551       by (auto simp: algebra_simps)
  4552     have *: "\<lbrakk>norm(f - f' - y) \<le> b - c; b \<le> norm y; d \<le> c\<rbrakk> \<Longrightarrow> d \<le> norm(f - f')"
  4553       for b c d and y f f'::'a
  4554       using norm_triangle_ineq3 [of "f - f'" y] by simp
  4555     show ?thesis
  4556       apply (rule * [OF le B])
  4557       using \<open>i \<noteq> 0\<close> \<open>j \<noteq> 0\<close> by (simp add: divide_simps max_mult_distrib_left of_nat_max less_max_iff_disj)
  4558   qed
  4559   with \<open>x \<in> S\<close> \<open>i \<noteq> 0\<close> \<open>j \<noteq> 0\<close> show "\<exists>n\<in>{0<..}. x \<in> U n"
  4560     by (rule_tac x="max i j" in bexI) (auto simp: field_simps U_def less_max_iff_disj)
  4561 qed
  4562   ultimately show ?thesis
  4563     by (rule negligible_subset)
  4564 qed
  4565 
  4566 lemma absolutely_integrable_Un:
  4567   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  4568   assumes S: "f absolutely_integrable_on S" and T: "f absolutely_integrable_on T"
  4569   shows "f absolutely_integrable_on (S \<union> T)"
  4570 proof -
  4571   have [simp]: "{x. (if x \<in> A then f x else 0) \<noteq> 0} = {x \<in> A. f x \<noteq> 0}" for A
  4572     by auto
  4573   let ?ST = "{x \<in> S. f x \<noteq> 0} \<inter> {x \<in> T. f x \<noteq> 0}"
  4574   have "?ST \<in> sets lebesgue"
  4575   proof (rule Sigma_Algebra.sets.Int)
  4576     have "f integrable_on S"
  4577       using S absolutely_integrable_on_def by blast
  4578     then have "(\<lambda>x. if x \<in> S then f x else 0) integrable_on UNIV"
  4579       by (simp add: integrable_restrict_UNIV)
  4580     then have borel: "(\<lambda>x. if x \<in> S then f x else 0) \<in> borel_measurable (lebesgue_on UNIV)"
  4581       using integrable_imp_measurable borel_measurable_UNIV_eq by blast
  4582     then show "{x \<in> S. f x \<noteq> 0} \<in> sets lebesgue"
  4583       unfolding borel_measurable_vimage_open
  4584       by (rule allE [where x = "-{0}"]) auto
  4585   next
  4586     have "f integrable_on T"
  4587       using T absolutely_integrable_on_def by blast
  4588     then have "(\<lambda>x. if x \<in> T then f x else 0) integrable_on UNIV"
  4589       by (simp add: integrable_restrict_UNIV)
  4590     then have borel: "(\<lambda>x. if x \<in> T then f x else 0) \<in> borel_measurable (lebesgue_on UNIV)"
  4591       using integrable_imp_measurable borel_measurable_UNIV_eq by blast
  4592     then show "{x \<in> T. f x \<noteq> 0} \<in> sets lebesgue"
  4593       unfolding borel_measurable_vimage_open
  4594       by (rule allE [where x = "-{0}"]) auto
  4595   qed
  4596   then have "f absolutely_integrable_on ?ST"
  4597     by (rule set_integrable_subset [OF S]) auto
  4598   then have Int: "(\<lambda>x. if x \<in> ?ST then f x else 0) absolutely_integrable_on UNIV"
  4599     using absolutely_integrable_restrict_UNIV by blast
  4600   have "(\<lambda>x. if x \<in> S then f x else 0) absolutely_integrable_on UNIV"
  4601        "(\<lambda>x. if x \<in> T then f x else 0) absolutely_integrable_on UNIV"
  4602     using S T absolutely_integrable_restrict_UNIV by blast+
  4603   then have "(\<lambda>x. (if x \<in> S then f x else 0) + (if x \<in> T then f x else 0)) absolutely_integrable_on UNIV"
  4604     by (rule absolutely_integrable_add)
  4605   then have "(\<lambda>x. ((if x \<in> S then f x else 0) + (if x \<in> T then f x else 0)) - (if x \<in> ?ST then f x else 0)) absolutely_integrable_on UNIV"
  4606     using Int by (rule absolutely_integrable_diff)
  4607   then have "(\<lambda>x. if x \<in> S \<union> T then f x else 0) absolutely_integrable_on UNIV"
  4608     by (rule absolutely_integrable_spike) (auto intro: empty_imp_negligible)
  4609   then show ?thesis
  4610     unfolding absolutely_integrable_restrict_UNIV .
  4611 qed
  4612 
  4613 lemma uniform_limit_set_lebesgue_integral_at_top:
  4614   fixes f :: "'a \<Rightarrow> real \<Rightarrow> 'b::{banach, second_countable_topology}"
  4615     and g :: "real \<Rightarrow> real"
  4616   assumes bound: "\<And>x y. x \<in> A \<Longrightarrow> y \<ge> a \<Longrightarrow> norm (f x y) \<le> g y"
  4617   assumes integrable: "set_integrable M {a..} g"
  4618   assumes measurable: "\<And>x. x \<in> A \<Longrightarrow> set_borel_measurable M {a..} (f x)"
  4619   assumes "sets borel \<subseteq> sets M"
  4620   shows   "uniform_limit A (\<lambda>b x. LINT y:{a..b}|M. f x y) (\<lambda>x. LINT y:{a..}|M. f x y) at_top"
  4621 proof (cases "A = {}")
  4622   case False
  4623   then obtain x where x: "x \<in> A" by auto
  4624   have g_nonneg: "g y \<ge> 0" if "y \<ge> a" for y
  4625   proof -
  4626     have "0 \<le> norm (f x y)" by simp
  4627     also have "\<dots> \<le> g y" using bound[OF x that] by simp
  4628     finally show ?thesis .
  4629   qed
  4630 
  4631   have integrable': "set_integrable M {a..} (\<lambda>y. f x y)" if "x \<in> A" for x
  4632     unfolding set_integrable_def
  4633   proof (rule Bochner_Integration.integrable_bound)
  4634     show "integrable M (\<lambda>x. indicator {a..} x * g x)"
  4635       using integrable by (simp add: set_integrable_def)
  4636     show "(\<lambda>y. indicat_real {a..} y *\<^sub>R f x y) \<in> borel_measurable M" using measurable[OF that]
  4637       by (simp add: set_borel_measurable_def)
  4638     show "AE y in M. norm (indicat_real {a..} y *\<^sub>R f x y) \<le> norm (indicat_real {a..} y * g y)"
  4639       using bound[OF that] by (intro AE_I2) (auto simp: indicator_def g_nonneg)
  4640   qed
  4641 
  4642   show ?thesis
  4643   proof (rule uniform_limitI)
  4644     fix e :: real assume e: "e > 0"
  4645     have sets [intro]: "A \<in> sets M" if "A \<in> sets borel" for A
  4646       using that assms by blast
  4647   
  4648     have "((\<lambda>b. LINT y:{a..b}|M. g y) \<longlongrightarrow> (LINT y:{a..}|M. g y)) at_top"
  4649       by (intro tendsto_set_lebesgue_integral_at_top assms sets) auto
  4650     with e obtain b0 :: real where b0: "\<forall>b\<ge>b0. \<bar>(LINT y:{a..}|M. g y) - (LINT y:{a..b}|M. g y)\<bar> < e"
  4651       by (auto simp: tendsto_iff eventually_at_top_linorder dist_real_def abs_minus_commute)
  4652     define b where "b = max a b0"
  4653     have "a \<le> b" by (simp add: b_def)
  4654     from b0 have "\<bar>(LINT y:{a..}|M. g y) - (LINT y:{a..b}|M. g y)\<bar> < e"
  4655       by (auto simp: b_def)
  4656     also have "{a..} = {a..b} \<union> {b<..}" by (auto simp: b_def)
  4657     also have "\<bar>(LINT y:\<dots>|M. g y) - (LINT y:{a..b}|M. g y)\<bar> = \<bar>(LINT y:{b<..}|M. g y)\<bar>"
  4658       using \<open>a \<le> b\<close> by (subst set_integral_Un) (auto intro!: set_integrable_subset[OF integrable])
  4659     also have "(LINT y:{b<..}|M. g y) \<ge> 0"
  4660       using g_nonneg \<open>a \<le> b\<close> unfolding set_lebesgue_integral_def
  4661       by (intro Bochner_Integration.integral_nonneg) (auto simp: indicator_def)
  4662     hence "\<bar>(LINT y:{b<..}|M. g y)\<bar> = (LINT y:{b<..}|M. g y)" by simp
  4663     finally have less: "(LINT y:{b<..}|M. g y) < e" .
  4664 
  4665     have "eventually (\<lambda>b. b \<ge> b0) at_top" by (rule eventually_ge_at_top)
  4666     moreover have "eventually (\<lambda>b. b \<ge> a) at_top" by (rule eventually_ge_at_top)
  4667     ultimately show "eventually (\<lambda>b. \<forall>x\<in>A. 
  4668                        dist (LINT y:{a..b}|M. f x y) (LINT y:{a..}|M. f x y) < e) at_top"
  4669     proof eventually_elim
  4670       case (elim b)
  4671       show ?case
  4672       proof
  4673         fix x assume x: "x \<in> A"
  4674         have "dist (LINT y:{a..b}|M. f x y) (LINT y:{a..}|M. f x y) =
  4675                 norm ((LINT y:{a..}|M. f x y) - (LINT y:{a..b}|M. f x y))"
  4676           by (simp add: dist_norm norm_minus_commute)
  4677         also have "{a..} = {a..b} \<union> {b<..}" using elim by auto
  4678         also have "(LINT y:\<dots>|M. f x y) - (LINT y:{a..b}|M. f x y) = (LINT y:{b<..}|M. f x y)"
  4679           using elim x
  4680           by (subst set_integral_Un) (auto intro!: set_integrable_subset[OF integrable'])
  4681         also have "norm \<dots> \<le> (LINT y:{b<..}|M. norm (f x y))" using elim x
  4682           by (intro set_integral_norm_bound set_integrable_subset[OF integrable']) auto
  4683         also have "\<dots> \<le> (LINT y:{b<..}|M. g y)" using elim x bound g_nonneg
  4684           by (intro set_integral_mono set_integrable_norm set_integrable_subset[OF integrable']
  4685                     set_integrable_subset[OF integrable]) auto
  4686         also have "(LINT y:{b<..}|M. g y) \<ge> 0"
  4687           using g_nonneg \<open>a \<le> b\<close> unfolding set_lebesgue_integral_def
  4688           by (intro Bochner_Integration.integral_nonneg) (auto simp: indicator_def)
  4689         hence "(LINT y:{b<..}|M. g y) = \<bar>(LINT y:{b<..}|M. g y)\<bar>" by simp
  4690         also have "\<dots> = \<bar>(LINT y:{a..b} \<union> {b<..}|M. g y) - (LINT y:{a..b}|M. g y)\<bar>"
  4691           using elim by (subst set_integral_Un) (auto intro!: set_integrable_subset[OF integrable])
  4692         also have "{a..b} \<union> {b<..} = {a..}" using elim by auto
  4693         also have "\<bar>(LINT y:{a..}|M. g y) - (LINT y:{a..b}|M. g y)\<bar> < e"
  4694           using b0 elim by blast
  4695         finally show "dist (LINT y:{a..b}|M. f x y) (LINT y:{a..}|M. f x y) < e" .
  4696       qed
  4697     qed
  4698   qed
  4699 qed auto
  4700 
  4701 
  4702 
  4703 subsubsection\<open>Differentiability of inverse function (most basic form)\<close>
  4704 
  4705 proposition has_derivative_inverse_within:
  4706   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
  4707   assumes der_f: "(f has_derivative f') (at a within S)"
  4708     and cont_g: "continuous (at (f a) within f ` S) g"
  4709     and "a \<in> S" "linear g'" and id: "g' \<circ> f' = id"
  4710     and gf: "\<And>x. x \<in> S \<Longrightarrow> g(f x) = x"
  4711   shows "(g has_derivative g') (at (f a) within f ` S)"
  4712 proof -
  4713   have [simp]: "g' (f' x) = x" for x
  4714     by (simp add: local.id pointfree_idE)
  4715   have "bounded_linear f'"
  4716     and f': "\<And>e. e>0 \<Longrightarrow> \<exists>d>0. \<forall>y\<in>S. norm (y - a) < d \<longrightarrow>
  4717                         norm (f y - f a - f' (y - a)) \<le> e * norm (y - a)"
  4718     using der_f by (auto simp: has_derivative_within_alt)
  4719   obtain C where "C > 0" and C: "\<And>x. norm (g' x) \<le> C * norm x"
  4720     using linear_bounded_pos [OF \<open>linear g'\<close>] by metis
  4721   obtain B k where "B > 0" "k > 0"
  4722     and Bk: "\<And>x. \<lbrakk>x \<in> S; norm(f x - f a) < k\<rbrakk> \<Longrightarrow> norm(x - a) \<le> B * norm(f x - f a)"
  4723   proof -
  4724     obtain B where "B > 0" and B: "\<And>x. B * norm x \<le> norm (f' x)"
  4725       using linear_inj_bounded_below_pos [of f'] \<open>linear g'\<close> id der_f has_derivative_linear
  4726         linear_invertible_bounded_below_pos by blast
  4727     then obtain d where "d>0"
  4728       and d: "\<And>y. \<lbrakk>y \<in> S; norm (y - a) < d\<rbrakk> \<Longrightarrow>
  4729                     norm (f y - f a - f' (y - a)) \<le> B / 2 * norm (y - a)"
  4730       using f' [of "B/2"] by auto
  4731     then obtain e where "e > 0"
  4732       and e: "\<And>x. \<lbrakk>x \<in> S; norm (f x - f a) < e\<rbrakk> \<Longrightarrow> norm (g (f x) - g (f a)) < d"
  4733       using cont_g by (auto simp: continuous_within_eps_delta dist_norm)
  4734     show thesis
  4735     proof
  4736       show "2/B > 0"
  4737         using \<open>B > 0\<close> by simp
  4738       show "norm (x - a) \<le> 2 / B * norm (f x - f a)"
  4739         if "x \<in> S" "norm (f x - f a) < e" for x
  4740       proof -
  4741         have xa: "norm (x - a) < d"
  4742           using e [OF that] gf by (simp add: \<open>a \<in> S\<close> that)
  4743         have *: "\<lbrakk>norm(y - f') \<le> B / 2 * norm x; B * norm x \<le> norm f'\<rbrakk>
  4744                  \<Longrightarrow> norm y \<ge> B / 2 * norm x" for y f'::'b and x::'a
  4745           using norm_triangle_ineq3 [of y f'] by linarith
  4746         show ?thesis
  4747           using * [OF d [OF \<open>x \<in> S\<close> xa] B] \<open>B > 0\<close> by (simp add: field_simps)
  4748       qed
  4749     qed (use \<open>e > 0\<close> in auto)
  4750   qed
  4751   show ?thesis
  4752     unfolding has_derivative_within_alt
  4753   proof (intro conjI impI allI)
  4754     show "bounded_linear g'"
  4755       using \<open>linear g'\<close> by (simp add: linear_linear)
  4756   next
  4757     fix e :: "real"
  4758     assume "e > 0"
  4759     then obtain d where "d>0"
  4760       and d: "\<And>y. \<lbrakk>y \<in> S; norm (y - a) < d\<rbrakk> \<Longrightarrow>
  4761                     norm (f y - f a - f' (y - a)) \<le> e / (B * C) * norm (y - a)"
  4762       using f' [of "e / (B * C)"] \<open>B > 0\<close> \<open>C > 0\<close> by auto
  4763     have "norm (x - a - g' (f x - f a)) \<le> e * norm (f x - f a)"
  4764       if "x \<in> S" and lt_k: "norm (f x - f a) < k" and lt_dB: "norm (f x - f a) < d/B" for x
  4765     proof -
  4766       have "norm (x - a) \<le> B * norm(f x - f a)"
  4767         using Bk lt_k \<open>x \<in> S\<close> by blast
  4768       also have "\<dots> < d"
  4769         by (metis \<open>0 < B\<close> lt_dB mult.commute pos_less_divide_eq)
  4770       finally have lt_d: "norm (x - a) < d" .
  4771       have "norm (x - a - g' (f x - f a)) \<le> norm(g'(f x - f a - (f' (x - a))))"
  4772         by (simp add: linear_diff [OF \<open>linear g'\<close>] norm_minus_commute)
  4773       also have "\<dots> \<le> C * norm (f x - f a - f' (x - a))"
  4774         using C by blast
  4775       also have "\<dots> \<le> e * norm (f x - f a)"
  4776       proof -
  4777         have "norm (f x - f a - f' (x - a)) \<le> e / (B * C) * norm (x - a)"
  4778           using d [OF \<open>x \<in> S\<close> lt_d] .
  4779         also have "\<dots> \<le> (norm (f x - f a) * e) / C"
  4780           using \<open>B > 0\<close> \<open>C > 0\<close> \<open>e > 0\<close> by (simp add: field_simps Bk lt_k \<open>x \<in> S\<close>)
  4781         finally show ?thesis
  4782           using \<open>C > 0\<close> by (simp add: field_simps)
  4783       qed
  4784     finally show ?thesis .
  4785     qed
  4786     then show "\<exists>d>0. \<forall>y\<in>f ` S.
  4787                norm (y - f a) < d \<longrightarrow>
  4788                norm (g y - g (f a) - g' (y - f a)) \<le> e * norm (y - f a)"
  4789       apply (rule_tac x="min k (d / B)" in exI)
  4790       using \<open>k > 0\<close> \<open>B > 0\<close> \<open>d > 0\<close> \<open>a \<in> S\<close> by (auto simp: gf)
  4791   qed
  4792 qed
  4793 
  4794 end