src/HOL/Analysis/Infinite_Products.thy
author wenzelm
Mon Mar 25 17:21:26 2019 +0100 (3 months ago)
changeset 69981 3dced198b9ec
parent 69565 1daf07b65385
child 70113 c8deb8ba6d05
permissions -rw-r--r--
more strict AFP properties;
     1 (*File:      HOL/Analysis/Infinite_Product.thy
     2   Author:    Manuel Eberl & LC Paulson
     3 
     4   Basic results about convergence and absolute convergence of infinite products
     5   and their connection to summability.
     6 *)
     7 section \<open>Infinite Products\<close>
     8 theory Infinite_Products
     9   imports Topology_Euclidean_Space Complex_Transcendental
    10 begin
    11 
    12 subsection%unimportant \<open>Preliminaries\<close>
    13 
    14 lemma sum_le_prod:
    15   fixes f :: "'a \<Rightarrow> 'b :: linordered_semidom"
    16   assumes "\<And>x. x \<in> A \<Longrightarrow> f x \<ge> 0"
    17   shows   "sum f A \<le> (\<Prod>x\<in>A. 1 + f x)"
    18   using assms
    19 proof (induction A rule: infinite_finite_induct)
    20   case (insert x A)
    21   from insert.hyps have "sum f A + f x * (\<Prod>x\<in>A. 1) \<le> (\<Prod>x\<in>A. 1 + f x) + f x * (\<Prod>x\<in>A. 1 + f x)"
    22     by (intro add_mono insert mult_left_mono prod_mono) (auto intro: insert.prems)
    23   with insert.hyps show ?case by (simp add: algebra_simps)
    24 qed simp_all
    25 
    26 lemma prod_le_exp_sum:
    27   fixes f :: "'a \<Rightarrow> real"
    28   assumes "\<And>x. x \<in> A \<Longrightarrow> f x \<ge> 0"
    29   shows   "prod (\<lambda>x. 1 + f x) A \<le> exp (sum f A)"
    30   using assms
    31 proof (induction A rule: infinite_finite_induct)
    32   case (insert x A)
    33   have "(1 + f x) * (\<Prod>x\<in>A. 1 + f x) \<le> exp (f x) * exp (sum f A)"
    34     using insert.prems by (intro mult_mono insert prod_nonneg exp_ge_add_one_self) auto
    35   with insert.hyps show ?case by (simp add: algebra_simps exp_add)
    36 qed simp_all
    37 
    38 lemma lim_ln_1_plus_x_over_x_at_0: "(\<lambda>x::real. ln (1 + x) / x) \<midarrow>0\<rightarrow> 1"
    39 proof (rule lhopital)
    40   show "(\<lambda>x::real. ln (1 + x)) \<midarrow>0\<rightarrow> 0"
    41     by (rule tendsto_eq_intros refl | simp)+
    42   have "eventually (\<lambda>x::real. x \<in> {-1/2<..<1/2}) (nhds 0)"
    43     by (rule eventually_nhds_in_open) auto
    44   hence *: "eventually (\<lambda>x::real. x \<in> {-1/2<..<1/2}) (at 0)"
    45     by (rule filter_leD [rotated]) (simp_all add: at_within_def)   
    46   show "eventually (\<lambda>x::real. ((\<lambda>x. ln (1 + x)) has_field_derivative inverse (1 + x)) (at x)) (at 0)"
    47     using * by eventually_elim (auto intro!: derivative_eq_intros simp: field_simps)
    48   show "eventually (\<lambda>x::real. ((\<lambda>x. x) has_field_derivative 1) (at x)) (at 0)"
    49     using * by eventually_elim (auto intro!: derivative_eq_intros simp: field_simps)
    50   show "\<forall>\<^sub>F x in at 0. x \<noteq> 0" by (auto simp: at_within_def eventually_inf_principal)
    51   show "(\<lambda>x::real. inverse (1 + x) / 1) \<midarrow>0\<rightarrow> 1"
    52     by (rule tendsto_eq_intros refl | simp)+
    53 qed auto
    54 
    55 subsection\<open>Definitions and basic properties\<close>
    56 
    57 definition%important raw_has_prod :: "[nat \<Rightarrow> 'a::{t2_space, comm_semiring_1}, nat, 'a] \<Rightarrow> bool" 
    58   where "raw_has_prod f M p \<equiv> (\<lambda>n. \<Prod>i\<le>n. f (i+M)) \<longlonglongrightarrow> p \<and> p \<noteq> 0"
    59 
    60 text\<open>The nonzero and zero cases, as in \emph{Complex Analysis} by Joseph Bak and Donald J.Newman, page 241\<close>
    61 text%important \<open>%whitespace\<close>
    62 definition%important
    63   has_prod :: "(nat \<Rightarrow> 'a::{t2_space, comm_semiring_1}) \<Rightarrow> 'a \<Rightarrow> bool" (infixr "has'_prod" 80)
    64   where "f has_prod p \<equiv> raw_has_prod f 0 p \<or> (\<exists>i q. p = 0 \<and> f i = 0 \<and> raw_has_prod f (Suc i) q)"
    65 
    66 definition%important convergent_prod :: "(nat \<Rightarrow> 'a :: {t2_space,comm_semiring_1}) \<Rightarrow> bool" where
    67   "convergent_prod f \<equiv> \<exists>M p. raw_has_prod f M p"
    68 
    69 definition%important prodinf :: "(nat \<Rightarrow> 'a::{t2_space, comm_semiring_1}) \<Rightarrow> 'a"
    70     (binder "\<Prod>" 10)
    71   where "prodinf f = (THE p. f has_prod p)"
    72 
    73 lemmas prod_defs = raw_has_prod_def has_prod_def convergent_prod_def prodinf_def
    74 
    75 lemma has_prod_subst[trans]: "f = g \<Longrightarrow> g has_prod z \<Longrightarrow> f has_prod z"
    76   by simp
    77 
    78 lemma has_prod_cong: "(\<And>n. f n = g n) \<Longrightarrow> f has_prod c \<longleftrightarrow> g has_prod c"
    79   by presburger
    80 
    81 lemma raw_has_prod_nonzero [simp]: "\<not> raw_has_prod f M 0"
    82   by (simp add: raw_has_prod_def)
    83 
    84 lemma raw_has_prod_eq_0:
    85   fixes f :: "nat \<Rightarrow> 'a::{semidom,t2_space}"
    86   assumes p: "raw_has_prod f m p" and i: "f i = 0" "i \<ge> m"
    87   shows "p = 0"
    88 proof -
    89   have eq0: "(\<Prod>k\<le>n. f (k+m)) = 0" if "i - m \<le> n" for n
    90   proof -
    91     have "\<exists>k\<le>n. f (k + m) = 0"
    92       using i that by auto
    93     then show ?thesis
    94       by auto
    95   qed
    96   have "(\<lambda>n. \<Prod>i\<le>n. f (i + m)) \<longlonglongrightarrow> 0"
    97     by (rule LIMSEQ_offset [where k = "i-m"]) (simp add: eq0)
    98     with p show ?thesis
    99       unfolding raw_has_prod_def
   100     using LIMSEQ_unique by blast
   101 qed
   102 
   103 lemma raw_has_prod_Suc: 
   104   "raw_has_prod f (Suc M) a \<longleftrightarrow> raw_has_prod (\<lambda>n. f (Suc n)) M a"
   105   unfolding raw_has_prod_def by auto
   106 
   107 lemma has_prod_0_iff: "f has_prod 0 \<longleftrightarrow> (\<exists>i. f i = 0 \<and> (\<exists>p. raw_has_prod f (Suc i) p))"
   108   by (simp add: has_prod_def)
   109       
   110 lemma has_prod_unique2: 
   111   fixes f :: "nat \<Rightarrow> 'a::{semidom,t2_space}"
   112   assumes "f has_prod a" "f has_prod b" shows "a = b"
   113   using assms
   114   by (auto simp: has_prod_def raw_has_prod_eq_0) (meson raw_has_prod_def sequentially_bot tendsto_unique)
   115 
   116 lemma has_prod_unique:
   117   fixes f :: "nat \<Rightarrow> 'a :: {semidom,t2_space}"
   118   shows "f has_prod s \<Longrightarrow> s = prodinf f"
   119   by (simp add: has_prod_unique2 prodinf_def the_equality)
   120 
   121 lemma convergent_prod_altdef:
   122   fixes f :: "nat \<Rightarrow> 'a :: {t2_space,comm_semiring_1}"
   123   shows "convergent_prod f \<longleftrightarrow> (\<exists>M L. (\<forall>n\<ge>M. f n \<noteq> 0) \<and> (\<lambda>n. \<Prod>i\<le>n. f (i+M)) \<longlonglongrightarrow> L \<and> L \<noteq> 0)"
   124 proof
   125   assume "convergent_prod f"
   126   then obtain M L where *: "(\<lambda>n. \<Prod>i\<le>n. f (i+M)) \<longlonglongrightarrow> L" "L \<noteq> 0"
   127     by (auto simp: prod_defs)
   128   have "f i \<noteq> 0" if "i \<ge> M" for i
   129   proof
   130     assume "f i = 0"
   131     have **: "eventually (\<lambda>n. (\<Prod>i\<le>n. f (i+M)) = 0) sequentially"
   132       using eventually_ge_at_top[of "i - M"]
   133     proof eventually_elim
   134       case (elim n)
   135       with \<open>f i = 0\<close> and \<open>i \<ge> M\<close> show ?case
   136         by (auto intro!: bexI[of _ "i - M"] prod_zero)
   137     qed
   138     have "(\<lambda>n. (\<Prod>i\<le>n. f (i+M))) \<longlonglongrightarrow> 0"
   139       unfolding filterlim_iff
   140       by (auto dest!: eventually_nhds_x_imp_x intro!: eventually_mono[OF **])
   141     from tendsto_unique[OF _ this *(1)] and *(2)
   142       show False by simp
   143   qed
   144   with * show "(\<exists>M L. (\<forall>n\<ge>M. f n \<noteq> 0) \<and> (\<lambda>n. \<Prod>i\<le>n. f (i+M)) \<longlonglongrightarrow> L \<and> L \<noteq> 0)" 
   145     by blast
   146 qed (auto simp: prod_defs)
   147 
   148 
   149 subsection\<open>Absolutely convergent products\<close>
   150 
   151 definition%important abs_convergent_prod :: "(nat \<Rightarrow> _) \<Rightarrow> bool" where
   152   "abs_convergent_prod f \<longleftrightarrow> convergent_prod (\<lambda>i. 1 + norm (f i - 1))"
   153 
   154 lemma abs_convergent_prodI:
   155   assumes "convergent (\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1))"
   156   shows   "abs_convergent_prod f"
   157 proof -
   158   from assms obtain L where L: "(\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1)) \<longlonglongrightarrow> L"
   159     by (auto simp: convergent_def)
   160   have "L \<ge> 1"
   161   proof (rule tendsto_le)
   162     show "eventually (\<lambda>n. (\<Prod>i\<le>n. 1 + norm (f i - 1)) \<ge> 1) sequentially"
   163     proof (intro always_eventually allI)
   164       fix n
   165       have "(\<Prod>i\<le>n. 1 + norm (f i - 1)) \<ge> (\<Prod>i\<le>n. 1)"
   166         by (intro prod_mono) auto
   167       thus "(\<Prod>i\<le>n. 1 + norm (f i - 1)) \<ge> 1" by simp
   168     qed
   169   qed (use L in simp_all)
   170   hence "L \<noteq> 0" by auto
   171   with L show ?thesis unfolding abs_convergent_prod_def prod_defs
   172     by (intro exI[of _ "0::nat"] exI[of _ L]) auto
   173 qed
   174 
   175 lemma
   176   fixes f :: "nat \<Rightarrow> 'a :: {topological_semigroup_mult,t2_space,idom}"
   177   assumes "convergent_prod f"
   178   shows   convergent_prod_imp_convergent: "convergent (\<lambda>n. \<Prod>i\<le>n. f i)"
   179     and   convergent_prod_to_zero_iff:    "(\<lambda>n. \<Prod>i\<le>n. f i) \<longlonglongrightarrow> 0 \<longleftrightarrow> (\<exists>i. f i = 0)"
   180 proof -
   181   from assms obtain M L 
   182     where M: "\<And>n. n \<ge> M \<Longrightarrow> f n \<noteq> 0" and "(\<lambda>n. \<Prod>i\<le>n. f (i + M)) \<longlonglongrightarrow> L" and "L \<noteq> 0"
   183     by (auto simp: convergent_prod_altdef)
   184   note this(2)
   185   also have "(\<lambda>n. \<Prod>i\<le>n. f (i + M)) = (\<lambda>n. \<Prod>i=M..M+n. f i)"
   186     by (intro ext prod.reindex_bij_witness[of _ "\<lambda>n. n - M" "\<lambda>n. n + M"]) auto
   187   finally have "(\<lambda>n. (\<Prod>i<M. f i) * (\<Prod>i=M..M+n. f i)) \<longlonglongrightarrow> (\<Prod>i<M. f i) * L"
   188     by (intro tendsto_mult tendsto_const)
   189   also have "(\<lambda>n. (\<Prod>i<M. f i) * (\<Prod>i=M..M+n. f i)) = (\<lambda>n. (\<Prod>i\<in>{..<M}\<union>{M..M+n}. f i))"
   190     by (subst prod.union_disjoint) auto
   191   also have "(\<lambda>n. {..<M} \<union> {M..M+n}) = (\<lambda>n. {..n+M})" by auto
   192   finally have lim: "(\<lambda>n. prod f {..n}) \<longlonglongrightarrow> prod f {..<M} * L" 
   193     by (rule LIMSEQ_offset)
   194   thus "convergent (\<lambda>n. \<Prod>i\<le>n. f i)"
   195     by (auto simp: convergent_def)
   196 
   197   show "(\<lambda>n. \<Prod>i\<le>n. f i) \<longlonglongrightarrow> 0 \<longleftrightarrow> (\<exists>i. f i = 0)"
   198   proof
   199     assume "\<exists>i. f i = 0"
   200     then obtain i where "f i = 0" by auto
   201     moreover with M have "i < M" by (cases "i < M") auto
   202     ultimately have "(\<Prod>i<M. f i) = 0" by auto
   203     with lim show "(\<lambda>n. \<Prod>i\<le>n. f i) \<longlonglongrightarrow> 0" by simp
   204   next
   205     assume "(\<lambda>n. \<Prod>i\<le>n. f i) \<longlonglongrightarrow> 0"
   206     from tendsto_unique[OF _ this lim] and \<open>L \<noteq> 0\<close>
   207     show "\<exists>i. f i = 0" by auto
   208   qed
   209 qed
   210 
   211 lemma convergent_prod_iff_nz_lim:
   212   fixes f :: "nat \<Rightarrow> 'a :: {topological_semigroup_mult,t2_space,idom}"
   213   assumes "\<And>i. f i \<noteq> 0"
   214   shows "convergent_prod f \<longleftrightarrow> (\<exists>L. (\<lambda>n. \<Prod>i\<le>n. f i) \<longlonglongrightarrow> L \<and> L \<noteq> 0)"
   215     (is "?lhs \<longleftrightarrow> ?rhs")
   216 proof
   217   assume ?lhs then show ?rhs
   218     using assms convergentD convergent_prod_imp_convergent convergent_prod_to_zero_iff by blast
   219 next
   220   assume ?rhs then show ?lhs
   221     unfolding prod_defs
   222     by (rule_tac x=0 in exI) auto
   223 qed
   224 
   225 lemma%important convergent_prod_iff_convergent: 
   226   fixes f :: "nat \<Rightarrow> 'a :: {topological_semigroup_mult,t2_space,idom}"
   227   assumes "\<And>i. f i \<noteq> 0"
   228   shows "convergent_prod f \<longleftrightarrow> convergent (\<lambda>n. \<Prod>i\<le>n. f i) \<and> lim (\<lambda>n. \<Prod>i\<le>n. f i) \<noteq> 0"
   229   by (force simp: convergent_prod_iff_nz_lim assms convergent_def limI)
   230 
   231 lemma bounded_imp_convergent_prod:
   232   fixes a :: "nat \<Rightarrow> real"
   233   assumes 1: "\<And>n. a n \<ge> 1" and bounded: "\<And>n. (\<Prod>i\<le>n. a i) \<le> B"
   234   shows "convergent_prod a"
   235 proof -
   236   have "bdd_above (range(\<lambda>n. \<Prod>i\<le>n. a i))"
   237     by (meson bdd_aboveI2 bounded)
   238   moreover have "incseq (\<lambda>n. \<Prod>i\<le>n. a i)"
   239     unfolding mono_def by (metis 1 prod_mono2 atMost_subset_iff dual_order.trans finite_atMost zero_le_one)
   240   ultimately obtain p where p: "(\<lambda>n. \<Prod>i\<le>n. a i) \<longlonglongrightarrow> p"
   241     using LIMSEQ_incseq_SUP by blast
   242   then have "p \<noteq> 0"
   243     by (metis "1" not_one_le_zero prod_ge_1 LIMSEQ_le_const)
   244   with 1 p show ?thesis
   245     by (metis convergent_prod_iff_nz_lim not_one_le_zero)
   246 qed
   247 
   248 
   249 lemma abs_convergent_prod_altdef:
   250   fixes f :: "nat \<Rightarrow> 'a :: {one,real_normed_vector}"
   251   shows  "abs_convergent_prod f \<longleftrightarrow> convergent (\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1))"
   252 proof
   253   assume "abs_convergent_prod f"
   254   thus "convergent (\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1))"
   255     by (auto simp: abs_convergent_prod_def intro!: convergent_prod_imp_convergent)
   256 qed (auto intro: abs_convergent_prodI)
   257 
   258 lemma Weierstrass_prod_ineq:
   259   fixes f :: "'a \<Rightarrow> real" 
   260   assumes "\<And>x. x \<in> A \<Longrightarrow> f x \<in> {0..1}"
   261   shows   "1 - sum f A \<le> (\<Prod>x\<in>A. 1 - f x)"
   262   using assms
   263 proof (induction A rule: infinite_finite_induct)
   264   case (insert x A)
   265   from insert.hyps and insert.prems 
   266     have "1 - sum f A + f x * (\<Prod>x\<in>A. 1 - f x) \<le> (\<Prod>x\<in>A. 1 - f x) + f x * (\<Prod>x\<in>A. 1)"
   267     by (intro insert.IH add_mono mult_left_mono prod_mono) auto
   268   with insert.hyps show ?case by (simp add: algebra_simps)
   269 qed simp_all
   270 
   271 lemma norm_prod_minus1_le_prod_minus1:
   272   fixes f :: "nat \<Rightarrow> 'a :: {real_normed_div_algebra,comm_ring_1}"  
   273   shows "norm (prod (\<lambda>n. 1 + f n) A - 1) \<le> prod (\<lambda>n. 1 + norm (f n)) A - 1"
   274 proof (induction A rule: infinite_finite_induct)
   275   case (insert x A)
   276   from insert.hyps have 
   277     "norm ((\<Prod>n\<in>insert x A. 1 + f n) - 1) = 
   278        norm ((\<Prod>n\<in>A. 1 + f n) - 1 + f x * (\<Prod>n\<in>A. 1 + f n))"
   279     by (simp add: algebra_simps)
   280   also have "\<dots> \<le> norm ((\<Prod>n\<in>A. 1 + f n) - 1) + norm (f x * (\<Prod>n\<in>A. 1 + f n))"
   281     by (rule norm_triangle_ineq)
   282   also have "norm (f x * (\<Prod>n\<in>A. 1 + f n)) = norm (f x) * (\<Prod>x\<in>A. norm (1 + f x))"
   283     by (simp add: prod_norm norm_mult)
   284   also have "(\<Prod>x\<in>A. norm (1 + f x)) \<le> (\<Prod>x\<in>A. norm (1::'a) + norm (f x))"
   285     by (intro prod_mono norm_triangle_ineq ballI conjI) auto
   286   also have "norm (1::'a) = 1" by simp
   287   also note insert.IH
   288   also have "(\<Prod>n\<in>A. 1 + norm (f n)) - 1 + norm (f x) * (\<Prod>x\<in>A. 1 + norm (f x)) =
   289              (\<Prod>n\<in>insert x A. 1 + norm (f n)) - 1"
   290     using insert.hyps by (simp add: algebra_simps)
   291   finally show ?case by - (simp_all add: mult_left_mono)
   292 qed simp_all
   293 
   294 lemma convergent_prod_imp_ev_nonzero:
   295   fixes f :: "nat \<Rightarrow> 'a :: {t2_space,comm_semiring_1}"
   296   assumes "convergent_prod f"
   297   shows   "eventually (\<lambda>n. f n \<noteq> 0) sequentially"
   298   using assms by (auto simp: eventually_at_top_linorder convergent_prod_altdef)
   299 
   300 lemma convergent_prod_imp_LIMSEQ:
   301   fixes f :: "nat \<Rightarrow> 'a :: {real_normed_field}"
   302   assumes "convergent_prod f"
   303   shows   "f \<longlonglongrightarrow> 1"
   304 proof -
   305   from assms obtain M L where L: "(\<lambda>n. \<Prod>i\<le>n. f (i+M)) \<longlonglongrightarrow> L" "\<And>n. n \<ge> M \<Longrightarrow> f n \<noteq> 0" "L \<noteq> 0"
   306     by (auto simp: convergent_prod_altdef)
   307   hence L': "(\<lambda>n. \<Prod>i\<le>Suc n. f (i+M)) \<longlonglongrightarrow> L" by (subst filterlim_sequentially_Suc)
   308   have "(\<lambda>n. (\<Prod>i\<le>Suc n. f (i+M)) / (\<Prod>i\<le>n. f (i+M))) \<longlonglongrightarrow> L / L"
   309     using L L' by (intro tendsto_divide) simp_all
   310   also from L have "L / L = 1" by simp
   311   also have "(\<lambda>n. (\<Prod>i\<le>Suc n. f (i+M)) / (\<Prod>i\<le>n. f (i+M))) = (\<lambda>n. f (n + Suc M))"
   312     using assms L by (auto simp: fun_eq_iff atMost_Suc)
   313   finally show ?thesis by (rule LIMSEQ_offset)
   314 qed
   315 
   316 lemma abs_convergent_prod_imp_summable:
   317   fixes f :: "nat \<Rightarrow> 'a :: real_normed_div_algebra"
   318   assumes "abs_convergent_prod f"
   319   shows "summable (\<lambda>i. norm (f i - 1))"
   320 proof -
   321   from assms have "convergent (\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1))" 
   322     unfolding abs_convergent_prod_def by (rule convergent_prod_imp_convergent)
   323   then obtain L where L: "(\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1)) \<longlonglongrightarrow> L"
   324     unfolding convergent_def by blast
   325   have "convergent (\<lambda>n. \<Sum>i\<le>n. norm (f i - 1))"
   326   proof (rule Bseq_monoseq_convergent)
   327     have "eventually (\<lambda>n. (\<Prod>i\<le>n. 1 + norm (f i - 1)) < L + 1) sequentially"
   328       using L(1) by (rule order_tendstoD) simp_all
   329     hence "\<forall>\<^sub>F x in sequentially. norm (\<Sum>i\<le>x. norm (f i - 1)) \<le> L + 1"
   330     proof eventually_elim
   331       case (elim n)
   332       have "norm (\<Sum>i\<le>n. norm (f i - 1)) = (\<Sum>i\<le>n. norm (f i - 1))"
   333         unfolding real_norm_def by (intro abs_of_nonneg sum_nonneg) simp_all
   334       also have "\<dots> \<le> (\<Prod>i\<le>n. 1 + norm (f i - 1))" by (rule sum_le_prod) auto
   335       also have "\<dots> < L + 1" by (rule elim)
   336       finally show ?case by simp
   337     qed
   338     thus "Bseq (\<lambda>n. \<Sum>i\<le>n. norm (f i - 1))" by (rule BfunI)
   339   next
   340     show "monoseq (\<lambda>n. \<Sum>i\<le>n. norm (f i - 1))"
   341       by (rule mono_SucI1) auto
   342   qed
   343   thus "summable (\<lambda>i. norm (f i - 1))" by (simp add: summable_iff_convergent')
   344 qed
   345 
   346 lemma summable_imp_abs_convergent_prod:
   347   fixes f :: "nat \<Rightarrow> 'a :: real_normed_div_algebra"
   348   assumes "summable (\<lambda>i. norm (f i - 1))"
   349   shows   "abs_convergent_prod f"
   350 proof (intro abs_convergent_prodI Bseq_monoseq_convergent)
   351   show "monoseq (\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1))"
   352     by (intro mono_SucI1) 
   353        (auto simp: atMost_Suc algebra_simps intro!: mult_nonneg_nonneg prod_nonneg)
   354 next
   355   show "Bseq (\<lambda>n. \<Prod>i\<le>n. 1 + norm (f i - 1))"
   356   proof (rule Bseq_eventually_mono)
   357     show "eventually (\<lambda>n. norm (\<Prod>i\<le>n. 1 + norm (f i - 1)) \<le> 
   358             norm (exp (\<Sum>i\<le>n. norm (f i - 1)))) sequentially"
   359       by (intro always_eventually allI) (auto simp: abs_prod exp_sum intro!: prod_mono)
   360   next
   361     from assms have "(\<lambda>n. \<Sum>i\<le>n. norm (f i - 1)) \<longlonglongrightarrow> (\<Sum>i. norm (f i - 1))"
   362       using sums_def_le by blast
   363     hence "(\<lambda>n. exp (\<Sum>i\<le>n. norm (f i - 1))) \<longlonglongrightarrow> exp (\<Sum>i. norm (f i - 1))"
   364       by (rule tendsto_exp)
   365     hence "convergent (\<lambda>n. exp (\<Sum>i\<le>n. norm (f i - 1)))"
   366       by (rule convergentI)
   367     thus "Bseq (\<lambda>n. exp (\<Sum>i\<le>n. norm (f i - 1)))"
   368       by (rule convergent_imp_Bseq)
   369   qed
   370 qed
   371 
   372 theorem abs_convergent_prod_conv_summable:
   373   fixes f :: "nat \<Rightarrow> 'a :: real_normed_div_algebra"
   374   shows "abs_convergent_prod f \<longleftrightarrow> summable (\<lambda>i. norm (f i - 1))"
   375   by (blast intro: abs_convergent_prod_imp_summable summable_imp_abs_convergent_prod)
   376 
   377 lemma abs_convergent_prod_imp_LIMSEQ:
   378   fixes f :: "nat \<Rightarrow> 'a :: {comm_ring_1,real_normed_div_algebra}"
   379   assumes "abs_convergent_prod f"
   380   shows   "f \<longlonglongrightarrow> 1"
   381 proof -
   382   from assms have "summable (\<lambda>n. norm (f n - 1))"
   383     by (rule abs_convergent_prod_imp_summable)
   384   from summable_LIMSEQ_zero[OF this] have "(\<lambda>n. f n - 1) \<longlonglongrightarrow> 0"
   385     by (simp add: tendsto_norm_zero_iff)
   386   from tendsto_add[OF this tendsto_const[of 1]] show ?thesis by simp
   387 qed
   388 
   389 lemma abs_convergent_prod_imp_ev_nonzero:
   390   fixes f :: "nat \<Rightarrow> 'a :: {comm_ring_1,real_normed_div_algebra}"
   391   assumes "abs_convergent_prod f"
   392   shows   "eventually (\<lambda>n. f n \<noteq> 0) sequentially"
   393 proof -
   394   from assms have "f \<longlonglongrightarrow> 1" 
   395     by (rule abs_convergent_prod_imp_LIMSEQ)
   396   hence "eventually (\<lambda>n. dist (f n) 1 < 1) at_top"
   397     by (auto simp: tendsto_iff)
   398   thus ?thesis by eventually_elim auto
   399 qed
   400 
   401 subsection%unimportant \<open>Ignoring initial segments\<close>
   402 
   403 lemma convergent_prod_offset:
   404   assumes "convergent_prod (\<lambda>n. f (n + m))"  
   405   shows   "convergent_prod f"
   406 proof -
   407   from assms obtain M L where "(\<lambda>n. \<Prod>k\<le>n. f (k + (M + m))) \<longlonglongrightarrow> L" "L \<noteq> 0"
   408     by (auto simp: prod_defs add.assoc)
   409   thus "convergent_prod f" 
   410     unfolding prod_defs by blast
   411 qed
   412 
   413 lemma abs_convergent_prod_offset:
   414   assumes "abs_convergent_prod (\<lambda>n. f (n + m))"  
   415   shows   "abs_convergent_prod f"
   416   using assms unfolding abs_convergent_prod_def by (rule convergent_prod_offset)
   417 
   418 
   419 lemma raw_has_prod_ignore_initial_segment:
   420   fixes f :: "nat \<Rightarrow> 'a :: real_normed_field"
   421   assumes "raw_has_prod f M p" "N \<ge> M"
   422   obtains q where  "raw_has_prod f N q"
   423 proof -
   424   have p: "(\<lambda>n. \<Prod>k\<le>n. f (k + M)) \<longlonglongrightarrow> p" and "p \<noteq> 0" 
   425     using assms by (auto simp: raw_has_prod_def)
   426   then have nz: "\<And>n. n \<ge> M \<Longrightarrow> f n \<noteq> 0"
   427     using assms by (auto simp: raw_has_prod_eq_0)
   428   define C where "C = (\<Prod>k<N-M. f (k + M))"
   429   from nz have [simp]: "C \<noteq> 0" 
   430     by (auto simp: C_def)
   431 
   432   from p have "(\<lambda>i. \<Prod>k\<le>i + (N-M). f (k + M)) \<longlonglongrightarrow> p" 
   433     by (rule LIMSEQ_ignore_initial_segment)
   434   also have "(\<lambda>i. \<Prod>k\<le>i + (N-M). f (k + M)) = (\<lambda>n. C * (\<Prod>k\<le>n. f (k + N)))"
   435   proof (rule ext, goal_cases)
   436     case (1 n)
   437     have "{..n+(N-M)} = {..<(N-M)} \<union> {(N-M)..n+(N-M)}" by auto
   438     also have "(\<Prod>k\<in>\<dots>. f (k + M)) = C * (\<Prod>k=(N-M)..n+(N-M). f (k + M))"
   439       unfolding C_def by (rule prod.union_disjoint) auto
   440     also have "(\<Prod>k=(N-M)..n+(N-M). f (k + M)) = (\<Prod>k\<le>n. f (k + (N-M) + M))"
   441       by (intro ext prod.reindex_bij_witness[of _ "\<lambda>k. k + (N-M)" "\<lambda>k. k - (N-M)"]) auto
   442     finally show ?case
   443       using \<open>N \<ge> M\<close> by (simp add: add_ac)
   444   qed
   445   finally have "(\<lambda>n. C * (\<Prod>k\<le>n. f (k + N)) / C) \<longlonglongrightarrow> p / C"
   446     by (intro tendsto_divide tendsto_const) auto
   447   hence "(\<lambda>n. \<Prod>k\<le>n. f (k + N)) \<longlonglongrightarrow> p / C" by simp
   448   moreover from \<open>p \<noteq> 0\<close> have "p / C \<noteq> 0" by simp
   449   ultimately show ?thesis
   450     using raw_has_prod_def that by blast 
   451 qed
   452 
   453 corollary%unimportant convergent_prod_ignore_initial_segment:
   454   fixes f :: "nat \<Rightarrow> 'a :: real_normed_field"
   455   assumes "convergent_prod f"
   456   shows   "convergent_prod (\<lambda>n. f (n + m))"
   457   using assms
   458   unfolding convergent_prod_def 
   459   apply clarify
   460   apply (erule_tac N="M+m" in raw_has_prod_ignore_initial_segment)
   461   apply (auto simp add: raw_has_prod_def add_ac)
   462   done
   463 
   464 corollary%unimportant convergent_prod_ignore_nonzero_segment:
   465   fixes f :: "nat \<Rightarrow> 'a :: real_normed_field"
   466   assumes f: "convergent_prod f" and nz: "\<And>i. i \<ge> M \<Longrightarrow> f i \<noteq> 0"
   467   shows "\<exists>p. raw_has_prod f M p"
   468   using convergent_prod_ignore_initial_segment [OF f]
   469   by (metis convergent_LIMSEQ_iff convergent_prod_iff_convergent le_add_same_cancel2 nz prod_defs(1) zero_order(1))
   470 
   471 corollary%unimportant abs_convergent_prod_ignore_initial_segment:
   472   assumes "abs_convergent_prod f"
   473   shows   "abs_convergent_prod (\<lambda>n. f (n + m))"
   474   using assms unfolding abs_convergent_prod_def 
   475   by (rule convergent_prod_ignore_initial_segment)
   476 
   477 subsection\<open>More elementary properties\<close>
   478 
   479 theorem abs_convergent_prod_imp_convergent_prod:
   480   fixes f :: "nat \<Rightarrow> 'a :: {real_normed_div_algebra,complete_space,comm_ring_1}"
   481   assumes "abs_convergent_prod f"
   482   shows   "convergent_prod f"
   483 proof -
   484   from assms have "eventually (\<lambda>n. f n \<noteq> 0) sequentially"
   485     by (rule abs_convergent_prod_imp_ev_nonzero)
   486   then obtain N where N: "f n \<noteq> 0" if "n \<ge> N" for n 
   487     by (auto simp: eventually_at_top_linorder)
   488   let ?P = "\<lambda>n. \<Prod>i\<le>n. f (i + N)" and ?Q = "\<lambda>n. \<Prod>i\<le>n. 1 + norm (f (i + N) - 1)"
   489 
   490   have "Cauchy ?P"
   491   proof (rule CauchyI', goal_cases)
   492     case (1 \<epsilon>)
   493     from assms have "abs_convergent_prod (\<lambda>n. f (n + N))"
   494       by (rule abs_convergent_prod_ignore_initial_segment)
   495     hence "Cauchy ?Q"
   496       unfolding abs_convergent_prod_def
   497       by (intro convergent_Cauchy convergent_prod_imp_convergent)
   498     from CauchyD[OF this 1] obtain M where M: "norm (?Q m - ?Q n) < \<epsilon>" if "m \<ge> M" "n \<ge> M" for m n
   499       by blast
   500     show ?case
   501     proof (rule exI[of _ M], safe, goal_cases)
   502       case (1 m n)
   503       have "dist (?P m) (?P n) = norm (?P n - ?P m)"
   504         by (simp add: dist_norm norm_minus_commute)
   505       also from 1 have "{..n} = {..m} \<union> {m<..n}" by auto
   506       hence "norm (?P n - ?P m) = norm (?P m * (\<Prod>k\<in>{m<..n}. f (k + N)) - ?P m)"
   507         by (subst prod.union_disjoint [symmetric]) (auto simp: algebra_simps)
   508       also have "\<dots> = norm (?P m * ((\<Prod>k\<in>{m<..n}. f (k + N)) - 1))"
   509         by (simp add: algebra_simps)
   510       also have "\<dots> = (\<Prod>k\<le>m. norm (f (k + N))) * norm ((\<Prod>k\<in>{m<..n}. f (k + N)) - 1)"
   511         by (simp add: norm_mult prod_norm)
   512       also have "\<dots> \<le> ?Q m * ((\<Prod>k\<in>{m<..n}. 1 + norm (f (k + N) - 1)) - 1)"
   513         using norm_prod_minus1_le_prod_minus1[of "\<lambda>k. f (k + N) - 1" "{m<..n}"]
   514               norm_triangle_ineq[of 1 "f k - 1" for k]
   515         by (intro mult_mono prod_mono ballI conjI norm_prod_minus1_le_prod_minus1 prod_nonneg) auto
   516       also have "\<dots> = ?Q m * (\<Prod>k\<in>{m<..n}. 1 + norm (f (k + N) - 1)) - ?Q m"
   517         by (simp add: algebra_simps)
   518       also have "?Q m * (\<Prod>k\<in>{m<..n}. 1 + norm (f (k + N) - 1)) = 
   519                    (\<Prod>k\<in>{..m}\<union>{m<..n}. 1 + norm (f (k + N) - 1))"
   520         by (rule prod.union_disjoint [symmetric]) auto
   521       also from 1 have "{..m}\<union>{m<..n} = {..n}" by auto
   522       also have "?Q n - ?Q m \<le> norm (?Q n - ?Q m)" by simp
   523       also from 1 have "\<dots> < \<epsilon>" by (intro M) auto
   524       finally show ?case .
   525     qed
   526   qed
   527   hence conv: "convergent ?P" by (rule Cauchy_convergent)
   528   then obtain L where L: "?P \<longlonglongrightarrow> L"
   529     by (auto simp: convergent_def)
   530 
   531   have "L \<noteq> 0"
   532   proof
   533     assume [simp]: "L = 0"
   534     from tendsto_norm[OF L] have limit: "(\<lambda>n. \<Prod>k\<le>n. norm (f (k + N))) \<longlonglongrightarrow> 0" 
   535       by (simp add: prod_norm)
   536 
   537     from assms have "(\<lambda>n. f (n + N)) \<longlonglongrightarrow> 1"
   538       by (intro abs_convergent_prod_imp_LIMSEQ abs_convergent_prod_ignore_initial_segment)
   539     hence "eventually (\<lambda>n. norm (f (n + N) - 1) < 1) sequentially"
   540       by (auto simp: tendsto_iff dist_norm)
   541     then obtain M0 where M0: "norm (f (n + N) - 1) < 1" if "n \<ge> M0" for n
   542       by (auto simp: eventually_at_top_linorder)
   543 
   544     {
   545       fix M assume M: "M \<ge> M0"
   546       with M0 have M: "norm (f (n + N) - 1) < 1" if "n \<ge> M" for n using that by simp
   547 
   548       have "(\<lambda>n. \<Prod>k\<le>n. 1 - norm (f (k+M+N) - 1)) \<longlonglongrightarrow> 0"
   549       proof (rule tendsto_sandwich)
   550         show "eventually (\<lambda>n. (\<Prod>k\<le>n. 1 - norm (f (k+M+N) - 1)) \<ge> 0) sequentially"
   551           using M by (intro always_eventually prod_nonneg allI ballI) (auto intro: less_imp_le)
   552         have "norm (1::'a) - norm (f (i + M + N) - 1) \<le> norm (f (i + M + N))" for i
   553           using norm_triangle_ineq3[of "f (i + M + N)" 1] by simp
   554         thus "eventually (\<lambda>n. (\<Prod>k\<le>n. 1 - norm (f (k+M+N) - 1)) \<le> (\<Prod>k\<le>n. norm (f (k+M+N)))) at_top"
   555           using M by (intro always_eventually allI prod_mono ballI conjI) (auto intro: less_imp_le)
   556         
   557         define C where "C = (\<Prod>k<M. norm (f (k + N)))"
   558         from N have [simp]: "C \<noteq> 0" by (auto simp: C_def)
   559         from L have "(\<lambda>n. norm (\<Prod>k\<le>n+M. f (k + N))) \<longlonglongrightarrow> 0"
   560           by (intro LIMSEQ_ignore_initial_segment) (simp add: tendsto_norm_zero_iff)
   561         also have "(\<lambda>n. norm (\<Prod>k\<le>n+M. f (k + N))) = (\<lambda>n. C * (\<Prod>k\<le>n. norm (f (k + M + N))))"
   562         proof (rule ext, goal_cases)
   563           case (1 n)
   564           have "{..n+M} = {..<M} \<union> {M..n+M}" by auto
   565           also have "norm (\<Prod>k\<in>\<dots>. f (k + N)) = C * norm (\<Prod>k=M..n+M. f (k + N))"
   566             unfolding C_def by (subst prod.union_disjoint) (auto simp: norm_mult prod_norm)
   567           also have "(\<Prod>k=M..n+M. f (k + N)) = (\<Prod>k\<le>n. f (k + N + M))"
   568             by (intro prod.reindex_bij_witness[of _ "\<lambda>i. i + M" "\<lambda>i. i - M"]) auto
   569           finally show ?case by (simp add: add_ac prod_norm)
   570         qed
   571         finally have "(\<lambda>n. C * (\<Prod>k\<le>n. norm (f (k + M + N))) / C) \<longlonglongrightarrow> 0 / C"
   572           by (intro tendsto_divide tendsto_const) auto
   573         thus "(\<lambda>n. \<Prod>k\<le>n. norm (f (k + M + N))) \<longlonglongrightarrow> 0" by simp
   574       qed simp_all
   575 
   576       have "1 - (\<Sum>i. norm (f (i + M + N) - 1)) \<le> 0"
   577       proof (rule tendsto_le)
   578         show "eventually (\<lambda>n. 1 - (\<Sum>k\<le>n. norm (f (k+M+N) - 1)) \<le> 
   579                                 (\<Prod>k\<le>n. 1 - norm (f (k+M+N) - 1))) at_top"
   580           using M by (intro always_eventually allI Weierstrass_prod_ineq) (auto intro: less_imp_le)
   581         show "(\<lambda>n. \<Prod>k\<le>n. 1 - norm (f (k+M+N) - 1)) \<longlonglongrightarrow> 0" by fact
   582         show "(\<lambda>n. 1 - (\<Sum>k\<le>n. norm (f (k + M + N) - 1)))
   583                   \<longlonglongrightarrow> 1 - (\<Sum>i. norm (f (i + M + N) - 1))"
   584           by (intro tendsto_intros summable_LIMSEQ' summable_ignore_initial_segment 
   585                 abs_convergent_prod_imp_summable assms)
   586       qed simp_all
   587       hence "(\<Sum>i. norm (f (i + M + N) - 1)) \<ge> 1" by simp
   588       also have "\<dots> + (\<Sum>i<M. norm (f (i + N) - 1)) = (\<Sum>i. norm (f (i + N) - 1))"
   589         by (intro suminf_split_initial_segment [symmetric] summable_ignore_initial_segment
   590               abs_convergent_prod_imp_summable assms)
   591       finally have "1 + (\<Sum>i<M. norm (f (i + N) - 1)) \<le> (\<Sum>i. norm (f (i + N) - 1))" by simp
   592     } note * = this
   593 
   594     have "1 + (\<Sum>i. norm (f (i + N) - 1)) \<le> (\<Sum>i. norm (f (i + N) - 1))"
   595     proof (rule tendsto_le)
   596       show "(\<lambda>M. 1 + (\<Sum>i<M. norm (f (i + N) - 1))) \<longlonglongrightarrow> 1 + (\<Sum>i. norm (f (i + N) - 1))"
   597         by (intro tendsto_intros summable_LIMSEQ summable_ignore_initial_segment 
   598                 abs_convergent_prod_imp_summable assms)
   599       show "eventually (\<lambda>M. 1 + (\<Sum>i<M. norm (f (i + N) - 1)) \<le> (\<Sum>i. norm (f (i + N) - 1))) at_top"
   600         using eventually_ge_at_top[of M0] by eventually_elim (use * in auto)
   601     qed simp_all
   602     thus False by simp
   603   qed
   604   with L show ?thesis by (auto simp: prod_defs)
   605 qed
   606 
   607 lemma raw_has_prod_cases:
   608   fixes f :: "nat \<Rightarrow> 'a :: {idom,topological_semigroup_mult,t2_space}"
   609   assumes "raw_has_prod f M p"
   610   obtains i where "i<M" "f i = 0" | p where "raw_has_prod f 0 p"
   611 proof -
   612   have "(\<lambda>n. \<Prod>i\<le>n. f (i + M)) \<longlonglongrightarrow> p" "p \<noteq> 0"
   613     using assms unfolding raw_has_prod_def by blast+
   614   then have "(\<lambda>n. prod f {..<M} * (\<Prod>i\<le>n. f (i + M))) \<longlonglongrightarrow> prod f {..<M} * p"
   615     by (metis tendsto_mult_left)
   616   moreover have "prod f {..<M} * (\<Prod>i\<le>n. f (i + M)) = prod f {..n+M}" for n
   617   proof -
   618     have "{..n+M} = {..<M} \<union> {M..n+M}"
   619       by auto
   620     then have "prod f {..n+M} = prod f {..<M} * prod f {M..n+M}"
   621       by simp (subst prod.union_disjoint; force)
   622     also have "\<dots> = prod f {..<M} * (\<Prod>i\<le>n. f (i + M))"
   623       by (metis (mono_tags, lifting) add.left_neutral atMost_atLeast0 prod_shift_bounds_cl_nat_ivl)
   624     finally show ?thesis by metis
   625   qed
   626   ultimately have "(\<lambda>n. prod f {..n}) \<longlonglongrightarrow> prod f {..<M} * p"
   627     by (auto intro: LIMSEQ_offset [where k=M])
   628   then have "raw_has_prod f 0 (prod f {..<M} * p)" if "\<forall>i<M. f i \<noteq> 0"
   629     using \<open>p \<noteq> 0\<close> assms that by (auto simp: raw_has_prod_def)
   630   then show thesis
   631     using that by blast
   632 qed
   633 
   634 corollary convergent_prod_offset_0:
   635   fixes f :: "nat \<Rightarrow> 'a :: {idom,topological_semigroup_mult,t2_space}"
   636   assumes "convergent_prod f" "\<And>i. f i \<noteq> 0"
   637   shows "\<exists>p. raw_has_prod f 0 p"
   638   using assms convergent_prod_def raw_has_prod_cases by blast
   639 
   640 lemma prodinf_eq_lim:
   641   fixes f :: "nat \<Rightarrow> 'a :: {idom,topological_semigroup_mult,t2_space}"
   642   assumes "convergent_prod f" "\<And>i. f i \<noteq> 0"
   643   shows "prodinf f = lim (\<lambda>n. \<Prod>i\<le>n. f i)"
   644   using assms convergent_prod_offset_0 [OF assms]
   645   by (simp add: prod_defs lim_def) (metis (no_types) assms(1) convergent_prod_to_zero_iff)
   646 
   647 lemma has_prod_one[simp, intro]: "(\<lambda>n. 1) has_prod 1"
   648   unfolding prod_defs by auto
   649 
   650 lemma convergent_prod_one[simp, intro]: "convergent_prod (\<lambda>n. 1)"
   651   unfolding prod_defs by auto
   652 
   653 lemma prodinf_cong: "(\<And>n. f n = g n) \<Longrightarrow> prodinf f = prodinf g"
   654   by presburger
   655 
   656 lemma convergent_prod_cong:
   657   fixes f g :: "nat \<Rightarrow> 'a::{field,topological_semigroup_mult,t2_space}"
   658   assumes ev: "eventually (\<lambda>x. f x = g x) sequentially" and f: "\<And>i. f i \<noteq> 0" and g: "\<And>i. g i \<noteq> 0"
   659   shows "convergent_prod f = convergent_prod g"
   660 proof -
   661   from assms obtain N where N: "\<forall>n\<ge>N. f n = g n"
   662     by (auto simp: eventually_at_top_linorder)
   663   define C where "C = (\<Prod>k<N. f k / g k)"
   664   with g have "C \<noteq> 0"
   665     by (simp add: f)
   666   have *: "eventually (\<lambda>n. prod f {..n} = C * prod g {..n}) sequentially"
   667     using eventually_ge_at_top[of N]
   668   proof eventually_elim
   669     case (elim n)
   670     then have "{..n} = {..<N} \<union> {N..n}"
   671       by auto
   672     also have "prod f \<dots> = prod f {..<N} * prod f {N..n}"
   673       by (intro prod.union_disjoint) auto
   674     also from N have "prod f {N..n} = prod g {N..n}"
   675       by (intro prod.cong) simp_all
   676     also have "prod f {..<N} * prod g {N..n} = C * (prod g {..<N} * prod g {N..n})"
   677       unfolding C_def by (simp add: g prod_dividef)
   678     also have "prod g {..<N} * prod g {N..n} = prod g ({..<N} \<union> {N..n})"
   679       by (intro prod.union_disjoint [symmetric]) auto
   680     also from elim have "{..<N} \<union> {N..n} = {..n}"
   681       by auto                                                                    
   682     finally show "prod f {..n} = C * prod g {..n}" .
   683   qed
   684   then have cong: "convergent (\<lambda>n. prod f {..n}) = convergent (\<lambda>n. C * prod g {..n})"
   685     by (rule convergent_cong)
   686   show ?thesis
   687   proof
   688     assume cf: "convergent_prod f"
   689     then have "\<not> (\<lambda>n. prod g {..n}) \<longlonglongrightarrow> 0"
   690       using tendsto_mult_left * convergent_prod_to_zero_iff f filterlim_cong by fastforce
   691     then show "convergent_prod g"
   692       by (metis convergent_mult_const_iff \<open>C \<noteq> 0\<close> cong cf convergent_LIMSEQ_iff convergent_prod_iff_convergent convergent_prod_imp_convergent g)
   693   next
   694     assume cg: "convergent_prod g"
   695     have "\<exists>a. C * a \<noteq> 0 \<and> (\<lambda>n. prod g {..n}) \<longlonglongrightarrow> a"
   696       by (metis (no_types) \<open>C \<noteq> 0\<close> cg convergent_prod_iff_nz_lim divide_eq_0_iff g nonzero_mult_div_cancel_right)
   697     then show "convergent_prod f"
   698       using "*" tendsto_mult_left filterlim_cong
   699       by (fastforce simp add: convergent_prod_iff_nz_lim f)
   700   qed
   701 qed
   702 
   703 lemma has_prod_finite:
   704   fixes f :: "nat \<Rightarrow> 'a::{semidom,t2_space}"
   705   assumes [simp]: "finite N"
   706     and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 1"
   707   shows "f has_prod (\<Prod>n\<in>N. f n)"
   708 proof -
   709   have eq: "prod f {..n + Suc (Max N)} = prod f N" for n
   710   proof (rule prod.mono_neutral_right)
   711     show "N \<subseteq> {..n + Suc (Max N)}"
   712       by (auto simp: le_Suc_eq trans_le_add2)
   713     show "\<forall>i\<in>{..n + Suc (Max N)} - N. f i = 1"
   714       using f by blast
   715   qed auto
   716   show ?thesis
   717   proof (cases "\<forall>n\<in>N. f n \<noteq> 0")
   718     case True
   719     then have "prod f N \<noteq> 0"
   720       by simp
   721     moreover have "(\<lambda>n. prod f {..n}) \<longlonglongrightarrow> prod f N"
   722       by (rule LIMSEQ_offset[of _ "Suc (Max N)"]) (simp add: eq atLeast0LessThan del: add_Suc_right)
   723     ultimately show ?thesis
   724       by (simp add: raw_has_prod_def has_prod_def)
   725   next
   726     case False
   727     then obtain k where "k \<in> N" "f k = 0"
   728       by auto
   729     let ?Z = "{n \<in> N. f n = 0}"
   730     have maxge: "Max ?Z \<ge> n" if "f n = 0" for n
   731       using Max_ge [of ?Z] \<open>finite N\<close> \<open>f n = 0\<close>
   732       by (metis (mono_tags) Collect_mem_eq f finite_Collect_conjI mem_Collect_eq zero_neq_one)
   733     let ?q = "prod f {Suc (Max ?Z)..Max N}"
   734     have [simp]: "?q \<noteq> 0"
   735       using maxge Suc_n_not_le_n le_trans by force
   736     have eq: "(\<Prod>i\<le>n + Max N. f (Suc (i + Max ?Z))) = ?q" for n
   737     proof -
   738       have "(\<Prod>i\<le>n + Max N. f (Suc (i + Max ?Z))) = prod f {Suc (Max ?Z)..n + Max N + Suc (Max ?Z)}" 
   739       proof (rule prod.reindex_cong [where l = "\<lambda>i. i + Suc (Max ?Z)", THEN sym])
   740         show "{Suc (Max ?Z)..n + Max N + Suc (Max ?Z)} = (\<lambda>i. i + Suc (Max ?Z)) ` {..n + Max N}"
   741           using le_Suc_ex by fastforce
   742       qed (auto simp: inj_on_def)
   743       also have "\<dots> = ?q"
   744         by (rule prod.mono_neutral_right)
   745            (use Max.coboundedI [OF \<open>finite N\<close>] f in \<open>force+\<close>)
   746       finally show ?thesis .
   747     qed
   748     have q: "raw_has_prod f (Suc (Max ?Z)) ?q"
   749     proof (simp add: raw_has_prod_def)
   750       show "(\<lambda>n. \<Prod>i\<le>n. f (Suc (i + Max ?Z))) \<longlonglongrightarrow> ?q"
   751         by (rule LIMSEQ_offset[of _ "(Max N)"]) (simp add: eq)
   752     qed
   753     show ?thesis
   754       unfolding has_prod_def
   755     proof (intro disjI2 exI conjI)      
   756       show "prod f N = 0"
   757         using \<open>f k = 0\<close> \<open>k \<in> N\<close> \<open>finite N\<close> prod_zero by blast
   758       show "f (Max ?Z) = 0"
   759         using Max_in [of ?Z] \<open>finite N\<close> \<open>f k = 0\<close> \<open>k \<in> N\<close> by auto
   760     qed (use q in auto)
   761   qed
   762 qed
   763 
   764 corollary%unimportant has_prod_0:
   765   fixes f :: "nat \<Rightarrow> 'a::{semidom,t2_space}"
   766   assumes "\<And>n. f n = 1"
   767   shows "f has_prod 1"
   768   by (simp add: assms has_prod_cong)
   769 
   770 lemma prodinf_zero[simp]: "prodinf (\<lambda>n. 1::'a::real_normed_field) = 1"
   771   using has_prod_unique by force
   772 
   773 lemma convergent_prod_finite:
   774   fixes f :: "nat \<Rightarrow> 'a::{idom,t2_space}"
   775   assumes "finite N" "\<And>n. n \<notin> N \<Longrightarrow> f n = 1"
   776   shows "convergent_prod f"
   777 proof -
   778   have "\<exists>n p. raw_has_prod f n p"
   779     using assms has_prod_def has_prod_finite by blast
   780   then show ?thesis
   781     by (simp add: convergent_prod_def)
   782 qed
   783 
   784 lemma has_prod_If_finite_set:
   785   fixes f :: "nat \<Rightarrow> 'a::{idom,t2_space}"
   786   shows "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 1) has_prod (\<Prod>r\<in>A. f r)"
   787   using has_prod_finite[of A "(\<lambda>r. if r \<in> A then f r else 1)"]
   788   by simp
   789 
   790 lemma has_prod_If_finite:
   791   fixes f :: "nat \<Rightarrow> 'a::{idom,t2_space}"
   792   shows "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 1) has_prod (\<Prod>r | P r. f r)"
   793   using has_prod_If_finite_set[of "{r. P r}"] by simp
   794 
   795 lemma convergent_prod_If_finite_set[simp, intro]:
   796   fixes f :: "nat \<Rightarrow> 'a::{idom,t2_space}"
   797   shows "finite A \<Longrightarrow> convergent_prod (\<lambda>r. if r \<in> A then f r else 1)"
   798   by (simp add: convergent_prod_finite)
   799 
   800 lemma convergent_prod_If_finite[simp, intro]:
   801   fixes f :: "nat \<Rightarrow> 'a::{idom,t2_space}"
   802   shows "finite {r. P r} \<Longrightarrow> convergent_prod (\<lambda>r. if P r then f r else 1)"
   803   using convergent_prod_def has_prod_If_finite has_prod_def by fastforce
   804 
   805 lemma has_prod_single:
   806   fixes f :: "nat \<Rightarrow> 'a::{idom,t2_space}"
   807   shows "(\<lambda>r. if r = i then f r else 1) has_prod f i"
   808   using has_prod_If_finite[of "\<lambda>r. r = i"] by simp
   809 
   810 context
   811   fixes f :: "nat \<Rightarrow> 'a :: real_normed_field"
   812 begin
   813 
   814 lemma convergent_prod_imp_has_prod: 
   815   assumes "convergent_prod f"
   816   shows "\<exists>p. f has_prod p"
   817 proof -
   818   obtain M p where p: "raw_has_prod f M p"
   819     using assms convergent_prod_def by blast
   820   then have "p \<noteq> 0"
   821     using raw_has_prod_nonzero by blast
   822   with p have fnz: "f i \<noteq> 0" if "i \<ge> M" for i
   823     using raw_has_prod_eq_0 that by blast
   824   define C where "C = (\<Prod>n<M. f n)"
   825   show ?thesis
   826   proof (cases "\<forall>n\<le>M. f n \<noteq> 0")
   827     case True
   828     then have "C \<noteq> 0"
   829       by (simp add: C_def)
   830     then show ?thesis
   831       by (meson True assms convergent_prod_offset_0 fnz has_prod_def nat_le_linear)
   832   next
   833     case False
   834     let ?N = "GREATEST n. f n = 0"
   835     have 0: "f ?N = 0"
   836       using fnz False
   837       by (metis (mono_tags, lifting) GreatestI_ex_nat nat_le_linear)
   838     have "f i \<noteq> 0" if "i > ?N" for i
   839       by (metis (mono_tags, lifting) Greatest_le_nat fnz leD linear that)
   840     then have "\<exists>p. raw_has_prod f (Suc ?N) p"
   841       using assms by (auto simp: intro!: convergent_prod_ignore_nonzero_segment)
   842     then show ?thesis
   843       unfolding has_prod_def using 0 by blast
   844   qed
   845 qed
   846 
   847 lemma convergent_prod_has_prod [intro]:
   848   shows "convergent_prod f \<Longrightarrow> f has_prod (prodinf f)"
   849   unfolding prodinf_def
   850   by (metis convergent_prod_imp_has_prod has_prod_unique theI')
   851 
   852 lemma convergent_prod_LIMSEQ:
   853   shows "convergent_prod f \<Longrightarrow> (\<lambda>n. \<Prod>i\<le>n. f i) \<longlonglongrightarrow> prodinf f"
   854   by (metis convergent_LIMSEQ_iff convergent_prod_has_prod convergent_prod_imp_convergent 
   855       convergent_prod_to_zero_iff raw_has_prod_eq_0 has_prod_def prodinf_eq_lim zero_le)
   856 
   857 theorem has_prod_iff: "f has_prod x \<longleftrightarrow> convergent_prod f \<and> prodinf f = x"
   858 proof
   859   assume "f has_prod x"
   860   then show "convergent_prod f \<and> prodinf f = x"
   861     apply safe
   862     using convergent_prod_def has_prod_def apply blast
   863     using has_prod_unique by blast
   864 qed auto
   865 
   866 lemma convergent_prod_has_prod_iff: "convergent_prod f \<longleftrightarrow> f has_prod prodinf f"
   867   by (auto simp: has_prod_iff convergent_prod_has_prod)
   868 
   869 lemma prodinf_finite:
   870   assumes N: "finite N"
   871     and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 1"
   872   shows "prodinf f = (\<Prod>n\<in>N. f n)"
   873   using has_prod_finite[OF assms, THEN has_prod_unique] by simp
   874 
   875 end
   876 
   877 subsection%unimportant \<open>Infinite products on ordered topological monoids\<close>
   878 
   879 lemma LIMSEQ_prod_0: 
   880   fixes f :: "nat \<Rightarrow> 'a::{semidom,topological_space}"
   881   assumes "f i = 0"
   882   shows "(\<lambda>n. prod f {..n}) \<longlonglongrightarrow> 0"
   883 proof (subst tendsto_cong)
   884   show "\<forall>\<^sub>F n in sequentially. prod f {..n} = 0"
   885   proof
   886     show "prod f {..n} = 0" if "n \<ge> i" for n
   887       using that assms by auto
   888   qed
   889 qed auto
   890 
   891 lemma LIMSEQ_prod_nonneg: 
   892   fixes f :: "nat \<Rightarrow> 'a::{linordered_semidom,linorder_topology}"
   893   assumes 0: "\<And>n. 0 \<le> f n" and a: "(\<lambda>n. prod f {..n}) \<longlonglongrightarrow> a"
   894   shows "a \<ge> 0"
   895   by (simp add: "0" prod_nonneg LIMSEQ_le_const [OF a])
   896 
   897 
   898 context
   899   fixes f :: "nat \<Rightarrow> 'a::{linordered_semidom,linorder_topology}"
   900 begin
   901 
   902 lemma has_prod_le:
   903   assumes f: "f has_prod a" and g: "g has_prod b" and le: "\<And>n. 0 \<le> f n \<and> f n \<le> g n"
   904   shows "a \<le> b"
   905 proof (cases "a=0 \<or> b=0")
   906   case True
   907   then show ?thesis
   908   proof
   909     assume [simp]: "a=0"
   910     have "b \<ge> 0"
   911     proof (rule LIMSEQ_prod_nonneg)
   912       show "(\<lambda>n. prod g {..n}) \<longlonglongrightarrow> b"
   913         using g by (auto simp: has_prod_def raw_has_prod_def LIMSEQ_prod_0)
   914     qed (use le order_trans in auto)
   915     then show ?thesis
   916       by auto
   917   next
   918     assume [simp]: "b=0"
   919     then obtain i where "g i = 0"    
   920       using g by (auto simp: prod_defs)
   921     then have "f i = 0"
   922       using antisym le by force
   923     then have "a=0"
   924       using f by (auto simp: prod_defs LIMSEQ_prod_0 LIMSEQ_unique)
   925     then show ?thesis
   926       by auto
   927   qed
   928 next
   929   case False
   930   then show ?thesis
   931     using assms
   932     unfolding has_prod_def raw_has_prod_def
   933     by (force simp: LIMSEQ_prod_0 intro!: LIMSEQ_le prod_mono)
   934 qed
   935 
   936 lemma prodinf_le: 
   937   assumes f: "f has_prod a" and g: "g has_prod b" and le: "\<And>n. 0 \<le> f n \<and> f n \<le> g n"
   938   shows "prodinf f \<le> prodinf g"
   939   using has_prod_le [OF assms] has_prod_unique f g  by blast
   940 
   941 end
   942 
   943 
   944 lemma prod_le_prodinf: 
   945   fixes f :: "nat \<Rightarrow> 'a::{linordered_idom,linorder_topology}"
   946   assumes "f has_prod a" "\<And>i. 0 \<le> f i" "\<And>i. i\<ge>n \<Longrightarrow> 1 \<le> f i"
   947   shows "prod f {..<n} \<le> prodinf f"
   948   by(rule has_prod_le[OF has_prod_If_finite_set]) (use assms has_prod_unique in auto)
   949 
   950 lemma prodinf_nonneg:
   951   fixes f :: "nat \<Rightarrow> 'a::{linordered_idom,linorder_topology}"
   952   assumes "f has_prod a" "\<And>i. 1 \<le> f i" 
   953   shows "1 \<le> prodinf f"
   954   using prod_le_prodinf[of f a 0] assms
   955   by (metis order_trans prod_ge_1 zero_le_one)
   956 
   957 lemma prodinf_le_const:
   958   fixes f :: "nat \<Rightarrow> real"
   959   assumes "convergent_prod f" "\<And>n. prod f {..<n} \<le> x" 
   960   shows "prodinf f \<le> x"
   961   by (metis lessThan_Suc_atMost assms convergent_prod_LIMSEQ LIMSEQ_le_const2)
   962 
   963 lemma prodinf_eq_one_iff: 
   964   fixes f :: "nat \<Rightarrow> real"
   965   assumes f: "convergent_prod f" and ge1: "\<And>n. 1 \<le> f n"
   966   shows "prodinf f = 1 \<longleftrightarrow> (\<forall>n. f n = 1)"
   967 proof
   968   assume "prodinf f = 1" 
   969   then have "(\<lambda>n. \<Prod>i<n. f i) \<longlonglongrightarrow> 1"
   970     using convergent_prod_LIMSEQ[of f] assms by (simp add: LIMSEQ_lessThan_iff_atMost)
   971   then have "\<And>i. (\<Prod>n\<in>{i}. f n) \<le> 1"
   972   proof (rule LIMSEQ_le_const)
   973     have "1 \<le> prod f n" for n
   974       by (simp add: ge1 prod_ge_1)
   975     have "prod f {..<n} = 1" for n
   976       by (metis \<open>\<And>n. 1 \<le> prod f n\<close> \<open>prodinf f = 1\<close> antisym f convergent_prod_has_prod ge1 order_trans prod_le_prodinf zero_le_one)
   977     then have "(\<Prod>n\<in>{i}. f n) \<le> prod f {..<n}" if "n \<ge> Suc i" for i n
   978       by (metis mult.left_neutral order_refl prod.cong prod.neutral_const prod_lessThan_Suc)
   979     then show "\<exists>N. \<forall>n\<ge>N. (\<Prod>n\<in>{i}. f n) \<le> prod f {..<n}" for i
   980       by blast      
   981   qed
   982   with ge1 show "\<forall>n. f n = 1"
   983     by (auto intro!: antisym)
   984 qed (metis prodinf_zero fun_eq_iff)
   985 
   986 lemma prodinf_pos_iff:
   987   fixes f :: "nat \<Rightarrow> real"
   988   assumes "convergent_prod f" "\<And>n. 1 \<le> f n"
   989   shows "1 < prodinf f \<longleftrightarrow> (\<exists>i. 1 < f i)"
   990   using prod_le_prodinf[of f 1] prodinf_eq_one_iff
   991   by (metis convergent_prod_has_prod assms less_le prodinf_nonneg)
   992 
   993 lemma less_1_prodinf2:
   994   fixes f :: "nat \<Rightarrow> real"
   995   assumes "convergent_prod f" "\<And>n. 1 \<le> f n" "1 < f i"
   996   shows "1 < prodinf f"
   997 proof -
   998   have "1 < (\<Prod>n<Suc i. f n)"
   999     using assms  by (intro less_1_prod2[where i=i]) auto
  1000   also have "\<dots> \<le> prodinf f"
  1001     by (intro prod_le_prodinf) (use assms order_trans zero_le_one in \<open>blast+\<close>)
  1002   finally show ?thesis .
  1003 qed
  1004 
  1005 lemma less_1_prodinf:
  1006   fixes f :: "nat \<Rightarrow> real"
  1007   shows "\<lbrakk>convergent_prod f; \<And>n. 1 < f n\<rbrakk> \<Longrightarrow> 1 < prodinf f"
  1008   by (intro less_1_prodinf2[where i=1]) (auto intro: less_imp_le)
  1009 
  1010 lemma prodinf_nonzero:
  1011   fixes f :: "nat \<Rightarrow> 'a :: {idom,topological_semigroup_mult,t2_space}"
  1012   assumes "convergent_prod f" "\<And>i. f i \<noteq> 0"
  1013   shows "prodinf f \<noteq> 0"
  1014   by (metis assms convergent_prod_offset_0 has_prod_unique raw_has_prod_def has_prod_def)
  1015 
  1016 lemma less_0_prodinf:
  1017   fixes f :: "nat \<Rightarrow> real"
  1018   assumes f: "convergent_prod f" and 0: "\<And>i. f i > 0"
  1019   shows "0 < prodinf f"
  1020 proof -
  1021   have "prodinf f \<noteq> 0"
  1022     by (metis assms less_irrefl prodinf_nonzero)
  1023   moreover have "0 < (\<Prod>n<i. f n)" for i
  1024     by (simp add: 0 prod_pos)
  1025   then have "prodinf f \<ge> 0"
  1026     using convergent_prod_LIMSEQ [OF f] LIMSEQ_prod_nonneg 0 less_le by blast
  1027   ultimately show ?thesis
  1028     by auto
  1029 qed
  1030 
  1031 lemma prod_less_prodinf2:
  1032   fixes f :: "nat \<Rightarrow> real"
  1033   assumes f: "convergent_prod f" and 1: "\<And>m. m\<ge>n \<Longrightarrow> 1 \<le> f m" and 0: "\<And>m. 0 < f m" and i: "n \<le> i" "1 < f i"
  1034   shows "prod f {..<n} < prodinf f"
  1035 proof -
  1036   have "prod f {..<n} \<le> prod f {..<i}"
  1037     by (rule prod_mono2) (use assms less_le in auto)
  1038   then have "prod f {..<n} < f i * prod f {..<i}"
  1039     using mult_less_le_imp_less[of 1 "f i" "prod f {..<n}" "prod f {..<i}"] assms
  1040     by (simp add: prod_pos)
  1041   moreover have "prod f {..<Suc i} \<le> prodinf f"
  1042     using prod_le_prodinf[of f _ "Suc i"]
  1043     by (meson "0" "1" Suc_leD convergent_prod_has_prod f \<open>n \<le> i\<close> le_trans less_eq_real_def)
  1044   ultimately show ?thesis
  1045     by (metis le_less_trans mult.commute not_le prod_lessThan_Suc)
  1046 qed
  1047 
  1048 lemma prod_less_prodinf:
  1049   fixes f :: "nat \<Rightarrow> real"
  1050   assumes f: "convergent_prod f" and 1: "\<And>m. m\<ge>n \<Longrightarrow> 1 < f m" and 0: "\<And>m. 0 < f m" 
  1051   shows "prod f {..<n} < prodinf f"
  1052   by (meson "0" "1" f le_less prod_less_prodinf2)
  1053 
  1054 lemma raw_has_prodI_bounded:
  1055   fixes f :: "nat \<Rightarrow> real"
  1056   assumes pos: "\<And>n. 1 \<le> f n"
  1057     and le: "\<And>n. (\<Prod>i<n. f i) \<le> x"
  1058   shows "\<exists>p. raw_has_prod f 0 p"
  1059   unfolding raw_has_prod_def add_0_right
  1060 proof (rule exI LIMSEQ_incseq_SUP conjI)+
  1061   show "bdd_above (range (\<lambda>n. prod f {..n}))"
  1062     by (metis bdd_aboveI2 le lessThan_Suc_atMost)
  1063   then have "(SUP i. prod f {..i}) > 0"
  1064     by (metis UNIV_I cSUP_upper less_le_trans pos prod_pos zero_less_one)
  1065   then show "(SUP i. prod f {..i}) \<noteq> 0"
  1066     by auto
  1067   show "incseq (\<lambda>n. prod f {..n})"
  1068     using pos order_trans [OF zero_le_one] by (auto simp: mono_def intro!: prod_mono2)
  1069 qed
  1070 
  1071 lemma convergent_prodI_nonneg_bounded:
  1072   fixes f :: "nat \<Rightarrow> real"
  1073   assumes "\<And>n. 1 \<le> f n" "\<And>n. (\<Prod>i<n. f i) \<le> x"
  1074   shows "convergent_prod f"
  1075   using convergent_prod_def raw_has_prodI_bounded [OF assms] by blast
  1076 
  1077 
  1078 subsection%unimportant \<open>Infinite products on topological spaces\<close>
  1079 
  1080 context
  1081   fixes f g :: "nat \<Rightarrow> 'a::{t2_space,topological_semigroup_mult,idom}"
  1082 begin
  1083 
  1084 lemma raw_has_prod_mult: "\<lbrakk>raw_has_prod f M a; raw_has_prod g M b\<rbrakk> \<Longrightarrow> raw_has_prod (\<lambda>n. f n * g n) M (a * b)"
  1085   by (force simp add: prod.distrib tendsto_mult raw_has_prod_def)
  1086 
  1087 lemma has_prod_mult_nz: "\<lbrakk>f has_prod a; g has_prod b; a \<noteq> 0; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. f n * g n) has_prod (a * b)"
  1088   by (simp add: raw_has_prod_mult has_prod_def)
  1089 
  1090 end
  1091 
  1092 
  1093 context
  1094   fixes f g :: "nat \<Rightarrow> 'a::real_normed_field"
  1095 begin
  1096 
  1097 lemma has_prod_mult:
  1098   assumes f: "f has_prod a" and g: "g has_prod b"
  1099   shows "(\<lambda>n. f n * g n) has_prod (a * b)"
  1100   using f [unfolded has_prod_def]
  1101 proof (elim disjE exE conjE)
  1102   assume f0: "raw_has_prod f 0 a"
  1103   show ?thesis
  1104     using g [unfolded has_prod_def]
  1105   proof (elim disjE exE conjE)
  1106     assume g0: "raw_has_prod g 0 b"
  1107     with f0 show ?thesis
  1108       by (force simp add: has_prod_def prod.distrib tendsto_mult raw_has_prod_def)
  1109   next
  1110     fix j q
  1111     assume "b = 0" and "g j = 0" and q: "raw_has_prod g (Suc j) q"
  1112     obtain p where p: "raw_has_prod f (Suc j) p"
  1113       using f0 raw_has_prod_ignore_initial_segment by blast
  1114     then have "Ex (raw_has_prod (\<lambda>n. f n * g n) (Suc j))"
  1115       using q raw_has_prod_mult by blast
  1116     then show ?thesis
  1117       using \<open>b = 0\<close> \<open>g j = 0\<close> has_prod_0_iff by fastforce
  1118   qed
  1119 next
  1120   fix i p
  1121   assume "a = 0" and "f i = 0" and p: "raw_has_prod f (Suc i) p"
  1122   show ?thesis
  1123     using g [unfolded has_prod_def]
  1124   proof (elim disjE exE conjE)
  1125     assume g0: "raw_has_prod g 0 b"
  1126     obtain q where q: "raw_has_prod g (Suc i) q"
  1127       using g0 raw_has_prod_ignore_initial_segment by blast
  1128     then have "Ex (raw_has_prod (\<lambda>n. f n * g n) (Suc i))"
  1129       using raw_has_prod_mult p by blast
  1130     then show ?thesis
  1131       using \<open>a = 0\<close> \<open>f i = 0\<close> has_prod_0_iff by fastforce
  1132   next
  1133     fix j q
  1134     assume "b = 0" and "g j = 0" and q: "raw_has_prod g (Suc j) q"
  1135     obtain p' where p': "raw_has_prod f (Suc (max i j)) p'"
  1136       by (metis raw_has_prod_ignore_initial_segment max_Suc_Suc max_def p)
  1137     moreover
  1138     obtain q' where q': "raw_has_prod g (Suc (max i j)) q'"
  1139       by (metis raw_has_prod_ignore_initial_segment max.cobounded2 max_Suc_Suc q)
  1140     ultimately show ?thesis
  1141       using \<open>b = 0\<close> by (simp add: has_prod_def) (metis \<open>f i = 0\<close> \<open>g j = 0\<close> raw_has_prod_mult max_def)
  1142   qed
  1143 qed
  1144 
  1145 lemma convergent_prod_mult:
  1146   assumes f: "convergent_prod f" and g: "convergent_prod g"
  1147   shows "convergent_prod (\<lambda>n. f n * g n)"
  1148   unfolding convergent_prod_def
  1149 proof -
  1150   obtain M p N q where p: "raw_has_prod f M p" and q: "raw_has_prod g N q"
  1151     using convergent_prod_def f g by blast+
  1152   then obtain p' q' where p': "raw_has_prod f (max M N) p'" and q': "raw_has_prod g (max M N) q'"
  1153     by (meson raw_has_prod_ignore_initial_segment max.cobounded1 max.cobounded2)
  1154   then show "\<exists>M p. raw_has_prod (\<lambda>n. f n * g n) M p"
  1155     using raw_has_prod_mult by blast
  1156 qed
  1157 
  1158 lemma prodinf_mult: "convergent_prod f \<Longrightarrow> convergent_prod g \<Longrightarrow> prodinf f * prodinf g = (\<Prod>n. f n * g n)"
  1159   by (intro has_prod_unique has_prod_mult convergent_prod_has_prod)
  1160 
  1161 end
  1162 
  1163 context
  1164   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::real_normed_field"
  1165     and I :: "'i set"
  1166 begin
  1167 
  1168 lemma has_prod_prod: "(\<And>i. i \<in> I \<Longrightarrow> (f i) has_prod (x i)) \<Longrightarrow> (\<lambda>n. \<Prod>i\<in>I. f i n) has_prod (\<Prod>i\<in>I. x i)"
  1169   by (induct I rule: infinite_finite_induct) (auto intro!: has_prod_mult)
  1170 
  1171 lemma prodinf_prod: "(\<And>i. i \<in> I \<Longrightarrow> convergent_prod (f i)) \<Longrightarrow> (\<Prod>n. \<Prod>i\<in>I. f i n) = (\<Prod>i\<in>I. \<Prod>n. f i n)"
  1172   using has_prod_unique[OF has_prod_prod, OF convergent_prod_has_prod] by simp
  1173 
  1174 lemma convergent_prod_prod: "(\<And>i. i \<in> I \<Longrightarrow> convergent_prod (f i)) \<Longrightarrow> convergent_prod (\<lambda>n. \<Prod>i\<in>I. f i n)"
  1175   using convergent_prod_has_prod_iff has_prod_prod prodinf_prod by force
  1176 
  1177 end
  1178 
  1179 subsection%unimportant \<open>Infinite summability on real normed fields\<close>
  1180 
  1181 context
  1182   fixes f :: "nat \<Rightarrow> 'a::real_normed_field"
  1183 begin
  1184 
  1185 lemma raw_has_prod_Suc_iff: "raw_has_prod f M (a * f M) \<longleftrightarrow> raw_has_prod (\<lambda>n. f (Suc n)) M a \<and> f M \<noteq> 0"
  1186 proof -
  1187   have "raw_has_prod f M (a * f M) \<longleftrightarrow> (\<lambda>i. \<Prod>j\<le>Suc i. f (j+M)) \<longlonglongrightarrow> a * f M \<and> a * f M \<noteq> 0"
  1188     by (subst LIMSEQ_Suc_iff) (simp add: raw_has_prod_def)
  1189   also have "\<dots> \<longleftrightarrow> (\<lambda>i. (\<Prod>j\<le>i. f (Suc j + M)) * f M) \<longlonglongrightarrow> a * f M \<and> a * f M \<noteq> 0"
  1190     by (simp add: ac_simps atMost_Suc_eq_insert_0 image_Suc_atMost prod_atLeast1_atMost_eq lessThan_Suc_atMost)
  1191   also have "\<dots> \<longleftrightarrow> raw_has_prod (\<lambda>n. f (Suc n)) M a \<and> f M \<noteq> 0"
  1192   proof safe
  1193     assume tends: "(\<lambda>i. (\<Prod>j\<le>i. f (Suc j + M)) * f M) \<longlonglongrightarrow> a * f M" and 0: "a * f M \<noteq> 0"
  1194     with tendsto_divide[OF tends tendsto_const, of "f M"]    
  1195     show "raw_has_prod (\<lambda>n. f (Suc n)) M a"
  1196       by (simp add: raw_has_prod_def)
  1197   qed (auto intro: tendsto_mult_right simp:  raw_has_prod_def)
  1198   finally show ?thesis .
  1199 qed
  1200 
  1201 lemma has_prod_Suc_iff:
  1202   assumes "f 0 \<noteq> 0" shows "(\<lambda>n. f (Suc n)) has_prod a \<longleftrightarrow> f has_prod (a * f 0)"
  1203 proof (cases "a = 0")
  1204   case True
  1205   then show ?thesis
  1206   proof (simp add: has_prod_def, safe)
  1207     fix i x
  1208     assume "f (Suc i) = 0" and "raw_has_prod (\<lambda>n. f (Suc n)) (Suc i) x"
  1209     then obtain y where "raw_has_prod f (Suc (Suc i)) y"
  1210       by (metis (no_types) raw_has_prod_eq_0 Suc_n_not_le_n raw_has_prod_Suc_iff raw_has_prod_ignore_initial_segment raw_has_prod_nonzero linear)
  1211     then show "\<exists>i. f i = 0 \<and> Ex (raw_has_prod f (Suc i))"
  1212       using \<open>f (Suc i) = 0\<close> by blast
  1213   next
  1214     fix i x
  1215     assume "f i = 0" and x: "raw_has_prod f (Suc i) x"
  1216     then obtain j where j: "i = Suc j"
  1217       by (metis assms not0_implies_Suc)
  1218     moreover have "\<exists> y. raw_has_prod (\<lambda>n. f (Suc n)) i y"
  1219       using x by (auto simp: raw_has_prod_def)
  1220     then show "\<exists>i. f (Suc i) = 0 \<and> Ex (raw_has_prod (\<lambda>n. f (Suc n)) (Suc i))"
  1221       using \<open>f i = 0\<close> j by blast
  1222   qed
  1223 next
  1224   case False
  1225   then show ?thesis
  1226     by (auto simp: has_prod_def raw_has_prod_Suc_iff assms)
  1227 qed
  1228 
  1229 lemma convergent_prod_Suc_iff:
  1230   shows "convergent_prod (\<lambda>n. f (Suc n)) = convergent_prod f"
  1231 proof
  1232   assume "convergent_prod f"
  1233   then obtain M L where M_nz:"\<forall>n\<ge>M. f n \<noteq> 0" and 
  1234         M_L:"(\<lambda>n. \<Prod>i\<le>n. f (i + M)) \<longlonglongrightarrow> L" and "L \<noteq> 0" 
  1235     unfolding convergent_prod_altdef by auto
  1236   have "(\<lambda>n. \<Prod>i\<le>n. f (Suc (i + M))) \<longlonglongrightarrow> L / f M"
  1237   proof -
  1238     have "(\<lambda>n. \<Prod>i\<in>{0..Suc n}. f (i + M)) \<longlonglongrightarrow> L"
  1239       using M_L 
  1240       apply (subst (asm) LIMSEQ_Suc_iff[symmetric]) 
  1241       using atLeast0AtMost by auto
  1242     then have "(\<lambda>n. f M * (\<Prod>i\<in>{0..n}. f (Suc (i + M)))) \<longlonglongrightarrow> L"
  1243       apply (subst (asm) prod.atLeast0_atMost_Suc_shift)
  1244       by simp
  1245     then have "(\<lambda>n. (\<Prod>i\<in>{0..n}. f (Suc (i + M)))) \<longlonglongrightarrow> L/f M"
  1246       apply (drule_tac tendsto_divide)
  1247       using M_nz[rule_format,of M,simplified] by auto
  1248     then show ?thesis unfolding atLeast0AtMost .
  1249   qed
  1250   then show "convergent_prod (\<lambda>n. f (Suc n))" unfolding convergent_prod_altdef
  1251     apply (rule_tac exI[where x=M])
  1252     apply (rule_tac exI[where x="L/f M"])
  1253     using M_nz \<open>L\<noteq>0\<close> by auto
  1254 next
  1255   assume "convergent_prod (\<lambda>n. f (Suc n))"
  1256   then obtain M where "\<exists>L. (\<forall>n\<ge>M. f (Suc n) \<noteq> 0) \<and> (\<lambda>n. \<Prod>i\<le>n. f (Suc (i + M))) \<longlonglongrightarrow> L \<and> L \<noteq> 0"
  1257     unfolding convergent_prod_altdef by auto
  1258   then show "convergent_prod f" unfolding convergent_prod_altdef
  1259     apply (rule_tac exI[where x="Suc M"])
  1260     using Suc_le_D by auto
  1261 qed
  1262 
  1263 lemma raw_has_prod_inverse: 
  1264   assumes "raw_has_prod f M a" shows "raw_has_prod (\<lambda>n. inverse (f n)) M (inverse a)"
  1265   using assms unfolding raw_has_prod_def by (auto dest: tendsto_inverse simp: prod_inversef [symmetric])
  1266 
  1267 lemma has_prod_inverse: 
  1268   assumes "f has_prod a" shows "(\<lambda>n. inverse (f n)) has_prod (inverse a)"
  1269 using assms raw_has_prod_inverse unfolding has_prod_def by auto 
  1270 
  1271 lemma convergent_prod_inverse:
  1272   assumes "convergent_prod f" 
  1273   shows "convergent_prod (\<lambda>n. inverse (f n))"
  1274   using assms unfolding convergent_prod_def  by (blast intro: raw_has_prod_inverse elim: )
  1275 
  1276 end
  1277 
  1278 context 
  1279   fixes f :: "nat \<Rightarrow> 'a::real_normed_field"
  1280 begin
  1281 
  1282 lemma raw_has_prod_Suc_iff': "raw_has_prod f M a \<longleftrightarrow> raw_has_prod (\<lambda>n. f (Suc n)) M (a / f M) \<and> f M \<noteq> 0"
  1283   by (metis raw_has_prod_eq_0 add.commute add.left_neutral raw_has_prod_Suc_iff raw_has_prod_nonzero le_add1 nonzero_mult_div_cancel_right times_divide_eq_left)
  1284 
  1285 lemma has_prod_divide: "f has_prod a \<Longrightarrow> g has_prod b \<Longrightarrow> (\<lambda>n. f n / g n) has_prod (a / b)"
  1286   unfolding divide_inverse by (intro has_prod_inverse has_prod_mult)
  1287 
  1288 lemma convergent_prod_divide:
  1289   assumes f: "convergent_prod f" and g: "convergent_prod g"
  1290   shows "convergent_prod (\<lambda>n. f n / g n)"
  1291   using f g has_prod_divide has_prod_iff by blast
  1292 
  1293 lemma prodinf_divide: "convergent_prod f \<Longrightarrow> convergent_prod g \<Longrightarrow> prodinf f / prodinf g = (\<Prod>n. f n / g n)"
  1294   by (intro has_prod_unique has_prod_divide convergent_prod_has_prod)
  1295 
  1296 lemma prodinf_inverse: "convergent_prod f \<Longrightarrow> (\<Prod>n. inverse (f n)) = inverse (\<Prod>n. f n)"
  1297   by (intro has_prod_unique [symmetric] has_prod_inverse convergent_prod_has_prod)
  1298 
  1299 lemma has_prod_Suc_imp: 
  1300   assumes "(\<lambda>n. f (Suc n)) has_prod a"
  1301   shows "f has_prod (a * f 0)"
  1302 proof -
  1303   have "f has_prod (a * f 0)" when "raw_has_prod (\<lambda>n. f (Suc n)) 0 a" 
  1304     apply (cases "f 0=0")
  1305     using that unfolding has_prod_def raw_has_prod_Suc 
  1306     by (auto simp add: raw_has_prod_Suc_iff)
  1307   moreover have "f has_prod (a * f 0)" when 
  1308     "(\<exists>i q. a = 0 \<and> f (Suc i) = 0 \<and> raw_has_prod (\<lambda>n. f (Suc n)) (Suc i) q)" 
  1309   proof -
  1310     from that 
  1311     obtain i q where "a = 0" "f (Suc i) = 0" "raw_has_prod (\<lambda>n. f (Suc n)) (Suc i) q"
  1312       by auto
  1313     then show ?thesis unfolding has_prod_def 
  1314       by (auto intro!:exI[where x="Suc i"] simp:raw_has_prod_Suc)
  1315   qed
  1316   ultimately show "f has_prod (a * f 0)" using assms unfolding has_prod_def by auto
  1317 qed
  1318 
  1319 lemma has_prod_iff_shift: 
  1320   assumes "\<And>i. i < n \<Longrightarrow> f i \<noteq> 0"
  1321   shows "(\<lambda>i. f (i + n)) has_prod a \<longleftrightarrow> f has_prod (a * (\<Prod>i<n. f i))"
  1322   using assms
  1323 proof (induct n arbitrary: a)
  1324   case 0
  1325   then show ?case by simp
  1326 next
  1327   case (Suc n)
  1328   then have "(\<lambda>i. f (Suc i + n)) has_prod a \<longleftrightarrow> (\<lambda>i. f (i + n)) has_prod (a * f n)"
  1329     by (subst has_prod_Suc_iff) auto
  1330   with Suc show ?case
  1331     by (simp add: ac_simps)
  1332 qed
  1333 
  1334 corollary%unimportant has_prod_iff_shift':
  1335   assumes "\<And>i. i < n \<Longrightarrow> f i \<noteq> 0"
  1336   shows "(\<lambda>i. f (i + n)) has_prod (a / (\<Prod>i<n. f i)) \<longleftrightarrow> f has_prod a"
  1337   by (simp add: assms has_prod_iff_shift)
  1338 
  1339 lemma has_prod_one_iff_shift:
  1340   assumes "\<And>i. i < n \<Longrightarrow> f i = 1"
  1341   shows "(\<lambda>i. f (i+n)) has_prod a \<longleftrightarrow> (\<lambda>i. f i) has_prod a"
  1342   by (simp add: assms has_prod_iff_shift)
  1343 
  1344 lemma convergent_prod_iff_shift:
  1345   shows "convergent_prod (\<lambda>i. f (i + n)) \<longleftrightarrow> convergent_prod f"
  1346   apply safe
  1347   using convergent_prod_offset apply blast
  1348   using convergent_prod_ignore_initial_segment convergent_prod_def by blast
  1349 
  1350 lemma has_prod_split_initial_segment:
  1351   assumes "f has_prod a" "\<And>i. i < n \<Longrightarrow> f i \<noteq> 0"
  1352   shows "(\<lambda>i. f (i + n)) has_prod (a / (\<Prod>i<n. f i))"
  1353   using assms has_prod_iff_shift' by blast
  1354 
  1355 lemma prodinf_divide_initial_segment:
  1356   assumes "convergent_prod f" "\<And>i. i < n \<Longrightarrow> f i \<noteq> 0"
  1357   shows "(\<Prod>i. f (i + n)) = (\<Prod>i. f i) / (\<Prod>i<n. f i)"
  1358   by (rule has_prod_unique[symmetric]) (auto simp: assms has_prod_iff_shift)
  1359 
  1360 lemma prodinf_split_initial_segment:
  1361   assumes "convergent_prod f" "\<And>i. i < n \<Longrightarrow> f i \<noteq> 0"
  1362   shows "prodinf f = (\<Prod>i. f (i + n)) * (\<Prod>i<n. f i)"
  1363   by (auto simp add: assms prodinf_divide_initial_segment)
  1364 
  1365 lemma prodinf_split_head:
  1366   assumes "convergent_prod f" "f 0 \<noteq> 0"
  1367   shows "(\<Prod>n. f (Suc n)) = prodinf f / f 0"
  1368   using prodinf_split_initial_segment[of 1] assms by simp
  1369 
  1370 end
  1371 
  1372 context 
  1373   fixes f :: "nat \<Rightarrow> 'a::real_normed_field"
  1374 begin
  1375 
  1376 lemma convergent_prod_inverse_iff: "convergent_prod (\<lambda>n. inverse (f n)) \<longleftrightarrow> convergent_prod f"
  1377   by (auto dest: convergent_prod_inverse)
  1378 
  1379 lemma convergent_prod_const_iff:
  1380   fixes c :: "'a :: {real_normed_field}"
  1381   shows "convergent_prod (\<lambda>_. c) \<longleftrightarrow> c = 1"
  1382 proof
  1383   assume "convergent_prod (\<lambda>_. c)"
  1384   then show "c = 1"
  1385     using convergent_prod_imp_LIMSEQ LIMSEQ_unique by blast 
  1386 next
  1387   assume "c = 1"
  1388   then show "convergent_prod (\<lambda>_. c)"
  1389     by auto
  1390 qed
  1391 
  1392 lemma has_prod_power: "f has_prod a \<Longrightarrow> (\<lambda>i. f i ^ n) has_prod (a ^ n)"
  1393   by (induction n) (auto simp: has_prod_mult)
  1394 
  1395 lemma convergent_prod_power: "convergent_prod f \<Longrightarrow> convergent_prod (\<lambda>i. f i ^ n)"
  1396   by (induction n) (auto simp: convergent_prod_mult)
  1397 
  1398 lemma prodinf_power: "convergent_prod f \<Longrightarrow> prodinf (\<lambda>i. f i ^ n) = prodinf f ^ n"
  1399   by (metis has_prod_unique convergent_prod_imp_has_prod has_prod_power)
  1400 
  1401 end
  1402 
  1403 
  1404 subsection\<open>Exponentials and logarithms\<close>
  1405 
  1406 context 
  1407   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}"
  1408 begin
  1409 
  1410 lemma sums_imp_has_prod_exp: 
  1411   assumes "f sums s"
  1412   shows "raw_has_prod (\<lambda>i. exp (f i)) 0 (exp s)"
  1413   using assms continuous_on_exp [of UNIV "\<lambda>x::'a. x"]
  1414   using continuous_on_tendsto_compose [of UNIV exp "(\<lambda>n. sum f {..n})" s]
  1415   by (simp add: prod_defs sums_def_le exp_sum)
  1416 
  1417 lemma convergent_prod_exp: 
  1418   assumes "summable f"
  1419   shows "convergent_prod (\<lambda>i. exp (f i))"
  1420   using sums_imp_has_prod_exp assms unfolding summable_def convergent_prod_def  by blast
  1421 
  1422 lemma prodinf_exp: 
  1423   assumes "summable f"
  1424   shows "prodinf (\<lambda>i. exp (f i)) = exp (suminf f)"
  1425 proof -
  1426   have "f sums suminf f"
  1427     using assms by blast
  1428   then have "(\<lambda>i. exp (f i)) has_prod exp (suminf f)"
  1429     by (simp add: has_prod_def sums_imp_has_prod_exp)
  1430   then show ?thesis
  1431     by (rule has_prod_unique [symmetric])
  1432 qed
  1433 
  1434 end
  1435 
  1436 theorem convergent_prod_iff_summable_real:
  1437   fixes a :: "nat \<Rightarrow> real"
  1438   assumes "\<And>n. a n > 0"
  1439   shows "convergent_prod (\<lambda>k. 1 + a k) \<longleftrightarrow> summable a" (is "?lhs = ?rhs")
  1440 proof
  1441   assume ?lhs
  1442   then obtain p where "raw_has_prod (\<lambda>k. 1 + a k) 0 p"
  1443     by (metis assms add_less_same_cancel2 convergent_prod_offset_0 not_one_less_zero)
  1444   then have to_p: "(\<lambda>n. \<Prod>k\<le>n. 1 + a k) \<longlonglongrightarrow> p"
  1445     by (auto simp: raw_has_prod_def)
  1446   moreover have le: "(\<Sum>k\<le>n. a k) \<le> (\<Prod>k\<le>n. 1 + a k)" for n
  1447     by (rule sum_le_prod) (use assms less_le in force)
  1448   have "(\<Prod>k\<le>n. 1 + a k) \<le> p" for n
  1449   proof (rule incseq_le [OF _ to_p])
  1450     show "incseq (\<lambda>n. \<Prod>k\<le>n. 1 + a k)"
  1451       using assms by (auto simp: mono_def order.strict_implies_order intro!: prod_mono2)
  1452   qed
  1453   with le have "(\<Sum>k\<le>n. a k) \<le> p" for n
  1454     by (metis order_trans)
  1455   with assms bounded_imp_summable show ?rhs
  1456     by (metis not_less order.asym)
  1457 next
  1458   assume R: ?rhs
  1459   have "(\<Prod>k\<le>n. 1 + a k) \<le> exp (suminf a)" for n
  1460   proof -
  1461     have "(\<Prod>k\<le>n. 1 + a k) \<le> exp (\<Sum>k\<le>n. a k)" for n
  1462       by (rule prod_le_exp_sum) (use assms less_le in force)
  1463     moreover have "exp (\<Sum>k\<le>n. a k) \<le> exp (suminf a)" for n
  1464       unfolding exp_le_cancel_iff
  1465       by (meson sum_le_suminf R assms finite_atMost less_eq_real_def)
  1466     ultimately show ?thesis
  1467       by (meson order_trans)
  1468   qed
  1469   then obtain L where L: "(\<lambda>n. \<Prod>k\<le>n. 1 + a k) \<longlonglongrightarrow> L"
  1470     by (metis assms bounded_imp_convergent_prod convergent_prod_iff_nz_lim le_add_same_cancel1 le_add_same_cancel2 less_le not_le zero_le_one)
  1471   moreover have "L \<noteq> 0"
  1472   proof
  1473     assume "L = 0"
  1474     with L have "(\<lambda>n. \<Prod>k\<le>n. 1 + a k) \<longlonglongrightarrow> 0"
  1475       by simp
  1476     moreover have "(\<Prod>k\<le>n. 1 + a k) > 1" for n
  1477       by (simp add: assms less_1_prod)
  1478     ultimately show False
  1479       by (meson Lim_bounded2 not_one_le_zero less_imp_le)
  1480   qed
  1481   ultimately show ?lhs
  1482     using assms convergent_prod_iff_nz_lim
  1483     by (metis add_less_same_cancel1 less_le not_le zero_less_one)
  1484 qed
  1485 
  1486 lemma exp_suminf_prodinf_real:
  1487   fixes f :: "nat \<Rightarrow> real"
  1488   assumes ge0:"\<And>n. f n \<ge> 0" and ac: "abs_convergent_prod (\<lambda>n. exp (f n))"
  1489   shows "prodinf (\<lambda>i. exp (f i)) = exp (suminf f)"
  1490 proof -
  1491   have "summable f"
  1492     using ac unfolding abs_convergent_prod_conv_summable
  1493   proof (elim summable_comparison_test')
  1494     fix n
  1495     have "\<bar>f n\<bar> = f n"
  1496       by (simp add: ge0)
  1497     also have "\<dots> \<le> exp (f n) - 1"
  1498       by (metis diff_diff_add exp_ge_add_one_self ge_iff_diff_ge_0)
  1499     finally show "norm (f n) \<le> norm (exp (f n) - 1)"
  1500       by simp
  1501   qed
  1502   then show ?thesis
  1503     by (simp add: prodinf_exp)
  1504 qed
  1505 
  1506 lemma has_prod_imp_sums_ln_real: 
  1507   fixes f :: "nat \<Rightarrow> real"
  1508   assumes "raw_has_prod f 0 p" and 0: "\<And>x. f x > 0"
  1509   shows "(\<lambda>i. ln (f i)) sums (ln p)"
  1510 proof -
  1511   have "p > 0"
  1512     using assms unfolding prod_defs by (metis LIMSEQ_prod_nonneg less_eq_real_def)
  1513   then show ?thesis
  1514   using assms continuous_on_ln [of "{0<..}" "\<lambda>x. x"]
  1515   using continuous_on_tendsto_compose [of "{0<..}" ln "(\<lambda>n. prod f {..n})" p]
  1516   by (auto simp: prod_defs sums_def_le ln_prod order_tendstoD)
  1517 qed
  1518 
  1519 lemma summable_ln_real: 
  1520   fixes f :: "nat \<Rightarrow> real"
  1521   assumes f: "convergent_prod f" and 0: "\<And>x. f x > 0"
  1522   shows "summable (\<lambda>i. ln (f i))"
  1523 proof -
  1524   obtain M p where "raw_has_prod f M p"
  1525     using f convergent_prod_def by blast
  1526   then consider i where "i<M" "f i = 0" | p where "raw_has_prod f 0 p"
  1527     using raw_has_prod_cases by blast
  1528   then show ?thesis
  1529   proof cases
  1530     case 1
  1531     with 0 show ?thesis
  1532       by (metis less_irrefl)
  1533   next
  1534     case 2
  1535     then show ?thesis
  1536       using "0" has_prod_imp_sums_ln_real summable_def by blast
  1537   qed
  1538 qed
  1539 
  1540 lemma suminf_ln_real: 
  1541   fixes f :: "nat \<Rightarrow> real"
  1542   assumes f: "convergent_prod f" and 0: "\<And>x. f x > 0"
  1543   shows "suminf (\<lambda>i. ln (f i)) = ln (prodinf f)"
  1544 proof -
  1545   have "f has_prod prodinf f"
  1546     by (simp add: f has_prod_iff)
  1547   then have "raw_has_prod f 0 (prodinf f)"
  1548     by (metis "0" has_prod_def less_irrefl)
  1549   then have "(\<lambda>i. ln (f i)) sums ln (prodinf f)"
  1550     using "0" has_prod_imp_sums_ln_real by blast
  1551   then show ?thesis
  1552     by (rule sums_unique [symmetric])
  1553 qed
  1554 
  1555 lemma prodinf_exp_real: 
  1556   fixes f :: "nat \<Rightarrow> real"
  1557   assumes f: "convergent_prod f" and 0: "\<And>x. f x > 0"
  1558   shows "prodinf f = exp (suminf (\<lambda>i. ln (f i)))"
  1559   by (simp add: "0" f less_0_prodinf suminf_ln_real)
  1560 
  1561 
  1562 theorem Ln_prodinf_complex:
  1563   fixes z :: "nat \<Rightarrow> complex"
  1564   assumes z: "\<And>j. z j \<noteq> 0" and \<xi>: "\<xi> \<noteq> 0"
  1565   shows "((\<lambda>n. \<Prod>j\<le>n. z j) \<longlonglongrightarrow> \<xi>) \<longleftrightarrow> (\<exists>k. (\<lambda>n. (\<Sum>j\<le>n. Ln (z j))) \<longlonglongrightarrow> Ln \<xi> + of_int k * (of_real(2*pi) * \<i>))" (is "?lhs = ?rhs")
  1566 proof
  1567   assume L: ?lhs
  1568   have pnz: "(\<Prod>j\<le>n. z j) \<noteq> 0" for n
  1569     using z by auto
  1570   define \<Theta> where "\<Theta> \<equiv> Arg \<xi> + 2*pi"
  1571   then have "\<Theta> > pi"
  1572     using Arg_def mpi_less_Im_Ln by fastforce
  1573   have \<xi>_eq: "\<xi> = cmod \<xi> * exp (\<i> * \<Theta>)"
  1574     using Arg_def Arg_eq \<xi> unfolding \<Theta>_def by (simp add: algebra_simps exp_add)
  1575   define \<theta> where "\<theta> \<equiv> \<lambda>n. THE t. is_Arg (\<Prod>j\<le>n. z j) t \<and> t \<in> {\<Theta>-pi<..\<Theta>+pi}"
  1576   have uniq: "\<exists>!s. is_Arg (\<Prod>j\<le>n. z j) s \<and> s \<in> {\<Theta>-pi<..\<Theta>+pi}" for n
  1577     using Argument_exists_unique [OF pnz] by metis
  1578   have \<theta>: "is_Arg (\<Prod>j\<le>n. z j) (\<theta> n)" and \<theta>_interval: "\<theta> n \<in> {\<Theta>-pi<..\<Theta>+pi}" for n
  1579     unfolding \<theta>_def
  1580     using theI' [OF uniq] by metis+
  1581   have \<theta>_pos: "\<And>j. \<theta> j > 0"
  1582     using \<theta>_interval \<open>\<Theta> > pi\<close> by simp (meson diff_gt_0_iff_gt less_trans)
  1583   have "(\<Prod>j\<le>n. z j) = cmod (\<Prod>j\<le>n. z j) * exp (\<i> * \<theta> n)" for n
  1584     using \<theta> by (auto simp: is_Arg_def)
  1585   then have eq: "(\<lambda>n. \<Prod>j\<le>n. z j) = (\<lambda>n. cmod (\<Prod>j\<le>n. z j) * exp (\<i> * \<theta> n))"
  1586     by simp
  1587   then have "(\<lambda>n. (cmod (\<Prod>j\<le>n. z j)) * exp (\<i> * (\<theta> n))) \<longlonglongrightarrow> \<xi>"
  1588     using L by force
  1589   then obtain k where k: "(\<lambda>j. \<theta> j - of_int (k j) * (2 * pi)) \<longlonglongrightarrow> \<Theta>"
  1590     using L by (subst (asm) \<xi>_eq) (auto simp add: eq z \<xi> polar_convergence)
  1591   moreover have "\<forall>\<^sub>F n in sequentially. k n = 0"
  1592   proof -
  1593     have *: "kj = 0" if "dist (vj - real_of_int kj * 2) V < 1" "vj \<in> {V - 1<..V + 1}" for kj vj V
  1594       using that  by (auto simp: dist_norm)
  1595     have "\<forall>\<^sub>F j in sequentially. dist (\<theta> j - of_int (k j) * (2 * pi)) \<Theta> < pi"
  1596       using tendstoD [OF k] pi_gt_zero by blast
  1597     then show ?thesis
  1598     proof (rule eventually_mono)
  1599       fix j
  1600       assume d: "dist (\<theta> j - real_of_int (k j) * (2 * pi)) \<Theta> < pi"
  1601       show "k j = 0"
  1602         by (rule * [of "\<theta> j/pi" _ "\<Theta>/pi"])
  1603            (use \<theta>_interval [of j] d in \<open>simp_all add: divide_simps dist_norm\<close>)
  1604     qed
  1605   qed
  1606   ultimately have \<theta>to\<Theta>: "\<theta> \<longlonglongrightarrow> \<Theta>"
  1607     apply (simp only: tendsto_def)
  1608     apply (erule all_forward imp_forward asm_rl)+
  1609     apply (drule (1) eventually_conj)
  1610     apply (auto elim: eventually_mono)
  1611     done
  1612   then have to0: "(\<lambda>n. \<bar>\<theta> (Suc n) - \<theta> n\<bar>) \<longlonglongrightarrow> 0"
  1613     by (metis (full_types) diff_self filterlim_sequentially_Suc tendsto_diff tendsto_rabs_zero)
  1614   have "\<exists>k. Im (\<Sum>j\<le>n. Ln (z j)) - of_int k * (2*pi) = \<theta> n" for n
  1615   proof (rule is_Arg_exp_diff_2pi)
  1616     show "is_Arg (exp (\<Sum>j\<le>n. Ln (z j))) (\<theta> n)"
  1617       using pnz \<theta> by (simp add: is_Arg_def exp_sum prod_norm)
  1618   qed
  1619   then have "\<exists>k. (\<Sum>j\<le>n. Im (Ln (z j))) = \<theta> n + of_int k * (2*pi)" for n
  1620     by (simp add: algebra_simps)
  1621   then obtain k where k: "\<And>n. (\<Sum>j\<le>n. Im (Ln (z j))) = \<theta> n + of_int (k n) * (2*pi)"
  1622     by metis
  1623   obtain K where "\<forall>\<^sub>F n in sequentially. k n = K"
  1624   proof -
  1625     have k_le: "(2*pi) * \<bar>k (Suc n) - k n\<bar> \<le> \<bar>\<theta> (Suc n) - \<theta> n\<bar> + \<bar>Im (Ln (z (Suc n)))\<bar>" for n
  1626     proof -
  1627       have "(\<Sum>j\<le>Suc n. Im (Ln (z j))) - (\<Sum>j\<le>n. Im (Ln (z j))) = Im (Ln (z (Suc n)))"
  1628         by simp
  1629       then show ?thesis
  1630         using k [of "Suc n"] k [of n] by (auto simp: abs_if algebra_simps)
  1631     qed
  1632     have "z \<longlonglongrightarrow> 1"
  1633       using L \<xi> convergent_prod_iff_nz_lim z by (blast intro: convergent_prod_imp_LIMSEQ)
  1634     with z have "(\<lambda>n. Ln (z n)) \<longlonglongrightarrow> Ln 1"
  1635       using isCont_tendsto_compose [OF continuous_at_Ln] nonpos_Reals_one_I by blast
  1636     then have "(\<lambda>n. Ln (z n)) \<longlonglongrightarrow> 0"
  1637       by simp
  1638     then have "(\<lambda>n. \<bar>Im (Ln (z (Suc n)))\<bar>) \<longlonglongrightarrow> 0"
  1639       by (metis LIMSEQ_unique \<open>z \<longlonglongrightarrow> 1\<close> continuous_at_Ln filterlim_sequentially_Suc isCont_tendsto_compose nonpos_Reals_one_I tendsto_Im tendsto_rabs_zero_iff zero_complex.simps(2))
  1640     then have "\<forall>\<^sub>F n in sequentially. \<bar>Im (Ln (z (Suc n)))\<bar> < 1"
  1641       by (simp add: order_tendsto_iff)
  1642     moreover have "\<forall>\<^sub>F n in sequentially. \<bar>\<theta> (Suc n) - \<theta> n\<bar> < 1"
  1643       using to0 by (simp add: order_tendsto_iff)
  1644     ultimately have "\<forall>\<^sub>F n in sequentially. (2*pi) * \<bar>k (Suc n) - k n\<bar> < 1 + 1" 
  1645     proof (rule eventually_elim2) 
  1646       fix n 
  1647       assume "\<bar>Im (Ln (z (Suc n)))\<bar> < 1" and "\<bar>\<theta> (Suc n) - \<theta> n\<bar> < 1"
  1648       with k_le [of n] show "2 * pi * real_of_int \<bar>k (Suc n) - k n\<bar> < 1 + 1"
  1649         by linarith
  1650     qed
  1651     then have "\<forall>\<^sub>F n in sequentially. real_of_int\<bar>k (Suc n) - k n\<bar> < 1" 
  1652     proof (rule eventually_mono)
  1653       fix n :: "nat"
  1654       assume "2 * pi * \<bar>k (Suc n) - k n\<bar> < 1 + 1"
  1655       then have "\<bar>k (Suc n) - k n\<bar> < 2 / (2*pi)"
  1656         by (simp add: field_simps)
  1657       also have "... < 1"
  1658         using pi_ge_two by auto
  1659       finally show "real_of_int \<bar>k (Suc n) - k n\<bar> < 1" .
  1660     qed
  1661   then obtain N where N: "\<And>n. n\<ge>N \<Longrightarrow> \<bar>k (Suc n) - k n\<bar> = 0"
  1662     using eventually_sequentially less_irrefl of_int_abs by fastforce
  1663   have "k (N+i) = k N" for i
  1664   proof (induction i)
  1665     case (Suc i)
  1666     with N [of "N+i"] show ?case
  1667       by auto
  1668   qed simp
  1669   then have "\<And>n. n\<ge>N \<Longrightarrow> k n = k N"
  1670     using le_Suc_ex by auto
  1671   then show ?thesis
  1672     by (force simp add: eventually_sequentially intro: that)
  1673   qed
  1674   with \<theta>to\<Theta> have "(\<lambda>n. (\<Sum>j\<le>n. Im (Ln (z j)))) \<longlonglongrightarrow> \<Theta> + of_int K * (2*pi)"
  1675     by (simp add: k tendsto_add tendsto_mult Lim_eventually)
  1676   moreover have "(\<lambda>n. (\<Sum>k\<le>n. Re (Ln (z k)))) \<longlonglongrightarrow> Re (Ln \<xi>)"
  1677     using assms continuous_imp_tendsto [OF isCont_ln tendsto_norm [OF L]]
  1678     by (simp add: o_def flip: prod_norm ln_prod)
  1679   ultimately show ?rhs
  1680     by (rule_tac x="K+1" in exI) (auto simp: tendsto_complex_iff \<Theta>_def Arg_def assms algebra_simps)
  1681 next
  1682   assume ?rhs
  1683   then obtain r where r: "(\<lambda>n. (\<Sum>k\<le>n. Ln (z k))) \<longlonglongrightarrow> Ln \<xi> + of_int r * (of_real(2*pi) * \<i>)" ..
  1684   have "(\<lambda>n. exp (\<Sum>k\<le>n. Ln (z k))) \<longlonglongrightarrow> \<xi>"
  1685     using assms continuous_imp_tendsto [OF isCont_exp r] exp_integer_2pi [of r]
  1686     by (simp add: o_def exp_add algebra_simps)
  1687   moreover have "exp (\<Sum>k\<le>n. Ln (z k)) = (\<Prod>k\<le>n. z k)" for n
  1688     by (simp add: exp_sum add_eq_0_iff assms)
  1689   ultimately show ?lhs
  1690     by auto
  1691 qed
  1692 
  1693 text\<open>Prop 17.2 of Bak and Newman, Complex Analysis, p.242\<close>
  1694 proposition convergent_prod_iff_summable_complex:
  1695   fixes z :: "nat \<Rightarrow> complex"
  1696   assumes "\<And>k. z k \<noteq> 0"
  1697   shows "convergent_prod (\<lambda>k. z k) \<longleftrightarrow> summable (\<lambda>k. Ln (z k))" (is "?lhs = ?rhs")
  1698 proof
  1699   assume ?lhs
  1700   then obtain p where p: "(\<lambda>n. \<Prod>k\<le>n. z k) \<longlonglongrightarrow> p" and "p \<noteq> 0"
  1701     using convergent_prod_LIMSEQ prodinf_nonzero add_eq_0_iff assms by fastforce
  1702   then show ?rhs
  1703     using Ln_prodinf_complex assms
  1704     by (auto simp: prodinf_nonzero summable_def sums_def_le)
  1705 next
  1706   assume R: ?rhs
  1707   have "(\<Prod>k\<le>n. z k) = exp (\<Sum>k\<le>n. Ln (z k))" for n
  1708     by (simp add: exp_sum add_eq_0_iff assms)
  1709   then have "(\<lambda>n. \<Prod>k\<le>n. z k) \<longlonglongrightarrow> exp (suminf (\<lambda>k. Ln (z k)))"
  1710     using continuous_imp_tendsto [OF isCont_exp summable_LIMSEQ' [OF R]] by (simp add: o_def)
  1711   then show ?lhs
  1712     by (subst convergent_prod_iff_convergent) (auto simp: convergent_def tendsto_Lim assms add_eq_0_iff)
  1713 qed
  1714 
  1715 text\<open>Prop 17.3 of Bak and Newman, Complex Analysis\<close>
  1716 proposition summable_imp_convergent_prod_complex:
  1717   fixes z :: "nat \<Rightarrow> complex"
  1718   assumes z: "summable (\<lambda>k. norm (z k))" and non0: "\<And>k. z k \<noteq> -1"
  1719   shows "convergent_prod (\<lambda>k. 1 + z k)" 
  1720 proof -
  1721   note if_cong [cong] power_Suc [simp del]
  1722   obtain N where N: "\<And>k. k\<ge>N \<Longrightarrow> norm (z k) < 1/2"
  1723     using summable_LIMSEQ_zero [OF z]
  1724     by (metis diff_zero dist_norm half_gt_zero_iff less_numeral_extra(1) lim_sequentially tendsto_norm_zero_iff)
  1725   have "norm (Ln (1 + z k)) \<le> 2 * norm (z k)" if "k \<ge> N" for k
  1726   proof (cases "z k = 0")
  1727     case False
  1728     let ?f = "\<lambda>i. cmod ((- 1) ^ i * z k ^ i / of_nat (Suc i))"
  1729     have normf: "norm (?f n) \<le> (1 / 2) ^ n" for n
  1730     proof -
  1731       have "norm (?f n) = cmod (z k) ^ n / cmod (1 + of_nat n)"
  1732         by (auto simp: norm_divide norm_mult norm_power)
  1733       also have "\<dots> \<le> cmod (z k) ^ n"
  1734         by (auto simp: divide_simps mult_le_cancel_left1 in_Reals_norm)
  1735       also have "\<dots> \<le> (1 / 2) ^ n"
  1736         using N [OF that] by (simp add: power_mono)
  1737       finally show "norm (?f n) \<le> (1 / 2) ^ n" .
  1738     qed
  1739     have summablef: "summable ?f"
  1740       by (intro normf summable_comparison_test' [OF summable_geometric [of "1/2"]]) auto
  1741     have "(\<lambda>n. (- 1) ^ Suc n / of_nat n * z k ^ n) sums Ln (1 + z k)"
  1742       using Ln_series [of "z k"] N that by fastforce
  1743     then have *: "(\<lambda>i. z k * (((- 1) ^ i * z k ^ i) / (Suc i))) sums Ln (1 + z k)"
  1744       using sums_split_initial_segment [where n= 1]  by (force simp: power_Suc mult_ac)
  1745     then have "norm (Ln (1 + z k)) = norm (suminf (\<lambda>i. z k * (((- 1) ^ i * z k ^ i) / (Suc i))))"
  1746       using sums_unique by force
  1747     also have "\<dots> = norm (z k * suminf (\<lambda>i. ((- 1) ^ i * z k ^ i) / (Suc i)))"
  1748       apply (subst suminf_mult)
  1749       using * False
  1750       by (auto simp: sums_summable intro: summable_mult_D [of "z k"])
  1751     also have "\<dots> = norm (z k) * norm (suminf (\<lambda>i. ((- 1) ^ i * z k ^ i) / (Suc i)))"
  1752       by (simp add: norm_mult)
  1753     also have "\<dots> \<le> norm (z k) * suminf (\<lambda>i. norm (((- 1) ^ i * z k ^ i) / (Suc i)))"
  1754       by (intro mult_left_mono summable_norm summablef) auto
  1755     also have "\<dots> \<le> norm (z k) * suminf (\<lambda>i. (1/2) ^ i)"
  1756       by (intro mult_left_mono suminf_le) (use summable_geometric [of "1/2"] summablef normf in auto)
  1757     also have "\<dots> \<le> norm (z k) * 2"
  1758       using suminf_geometric [of "1/2::real"] by simp
  1759     finally show ?thesis
  1760       by (simp add: mult_ac)
  1761   qed simp
  1762   then have "summable (\<lambda>k. Ln (1 + z k))"
  1763     by (metis summable_comparison_test summable_mult z)
  1764   with non0 show ?thesis
  1765     by (simp add: add_eq_0_iff convergent_prod_iff_summable_complex)
  1766 qed
  1767 
  1768 lemma summable_Ln_complex:
  1769   fixes z :: "nat \<Rightarrow> complex"
  1770   assumes "convergent_prod z" "\<And>k. z k \<noteq> 0"
  1771   shows "summable (\<lambda>k. Ln (z k))"
  1772   using convergent_prod_def assms convergent_prod_iff_summable_complex by blast
  1773 
  1774 
  1775 subsection%unimportant \<open>Embeddings from the reals into some complete real normed field\<close>
  1776 
  1777 lemma tendsto_eq_of_real_lim:
  1778   assumes "(\<lambda>n. of_real (f n) :: 'a::{complete_space,real_normed_field}) \<longlonglongrightarrow> q"
  1779   shows "q = of_real (lim f)"
  1780 proof -
  1781   have "convergent (\<lambda>n. of_real (f n) :: 'a)"
  1782     using assms convergent_def by blast 
  1783   then have "convergent f"
  1784     unfolding convergent_def
  1785     by (simp add: convergent_eq_Cauchy Cauchy_def)
  1786   then show ?thesis
  1787     by (metis LIMSEQ_unique assms convergentD sequentially_bot tendsto_Lim tendsto_of_real)
  1788 qed
  1789 
  1790 lemma tendsto_eq_of_real:
  1791   assumes "(\<lambda>n. of_real (f n) :: 'a::{complete_space,real_normed_field}) \<longlonglongrightarrow> q"
  1792   obtains r where "q = of_real r"
  1793   using tendsto_eq_of_real_lim assms by blast
  1794 
  1795 lemma has_prod_of_real_iff:
  1796   "(\<lambda>n. of_real (f n) :: 'a::{complete_space,real_normed_field}) has_prod of_real c \<longleftrightarrow> f has_prod c"
  1797   (is "?lhs = ?rhs")
  1798 proof
  1799   assume ?lhs
  1800   then show ?rhs
  1801     apply (auto simp: prod_defs LIMSEQ_prod_0 tendsto_of_real_iff simp flip: of_real_prod)
  1802     using tendsto_eq_of_real
  1803     by (metis of_real_0 tendsto_of_real_iff)
  1804 next
  1805   assume ?rhs
  1806   with tendsto_of_real_iff show ?lhs
  1807     by (fastforce simp: prod_defs simp flip: of_real_prod)
  1808 qed
  1809 
  1810 end