src/HOL/Complex.thy
 author hoelzl Thu Jan 31 11:31:27 2013 +0100 (2013-01-31) changeset 50999 3de230ed0547 parent 49962 a8cc904a6820 child 51002 496013a6eb38 permissions -rw-r--r--
introduce order topology
     1 (*  Title:       HOL/Complex.thy

     2     Author:      Jacques D. Fleuriot

     3     Copyright:   2001 University of Edinburgh

     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4

     5 *)

     6

     7 header {* Complex Numbers: Rectangular and Polar Representations *}

     8

     9 theory Complex

    10 imports Transcendental

    11 begin

    12

    13 datatype complex = Complex real real

    14

    15 primrec Re :: "complex \<Rightarrow> real"

    16   where Re: "Re (Complex x y) = x"

    17

    18 primrec Im :: "complex \<Rightarrow> real"

    19   where Im: "Im (Complex x y) = y"

    20

    21 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"

    22   by (induct z) simp

    23

    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"

    25   by (induct x, induct y) simp

    26

    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"

    28   by (induct x, induct y) simp

    29

    30

    31 subsection {* Addition and Subtraction *}

    32

    33 instantiation complex :: ab_group_add

    34 begin

    35

    36 definition complex_zero_def:

    37   "0 = Complex 0 0"

    38

    39 definition complex_add_def:

    40   "x + y = Complex (Re x + Re y) (Im x + Im y)"

    41

    42 definition complex_minus_def:

    43   "- x = Complex (- Re x) (- Im x)"

    44

    45 definition complex_diff_def:

    46   "x - (y\<Colon>complex) = x + - y"

    47

    48 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"

    49   by (simp add: complex_zero_def)

    50

    51 lemma complex_Re_zero [simp]: "Re 0 = 0"

    52   by (simp add: complex_zero_def)

    53

    54 lemma complex_Im_zero [simp]: "Im 0 = 0"

    55   by (simp add: complex_zero_def)

    56

    57 lemma complex_add [simp]:

    58   "Complex a b + Complex c d = Complex (a + c) (b + d)"

    59   by (simp add: complex_add_def)

    60

    61 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"

    62   by (simp add: complex_add_def)

    63

    64 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"

    65   by (simp add: complex_add_def)

    66

    67 lemma complex_minus [simp]:

    68   "- (Complex a b) = Complex (- a) (- b)"

    69   by (simp add: complex_minus_def)

    70

    71 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"

    72   by (simp add: complex_minus_def)

    73

    74 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"

    75   by (simp add: complex_minus_def)

    76

    77 lemma complex_diff [simp]:

    78   "Complex a b - Complex c d = Complex (a - c) (b - d)"

    79   by (simp add: complex_diff_def)

    80

    81 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"

    82   by (simp add: complex_diff_def)

    83

    84 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"

    85   by (simp add: complex_diff_def)

    86

    87 instance

    88   by intro_classes (simp_all add: complex_add_def complex_diff_def)

    89

    90 end

    91

    92

    93 subsection {* Multiplication and Division *}

    94

    95 instantiation complex :: field_inverse_zero

    96 begin

    97

    98 definition complex_one_def:

    99   "1 = Complex 1 0"

   100

   101 definition complex_mult_def:

   102   "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"

   103

   104 definition complex_inverse_def:

   105   "inverse x =

   106     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"

   107

   108 definition complex_divide_def:

   109   "x / (y\<Colon>complex) = x * inverse y"

   110

   111 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"

   112   by (simp add: complex_one_def)

   113

   114 lemma complex_Re_one [simp]: "Re 1 = 1"

   115   by (simp add: complex_one_def)

   116

   117 lemma complex_Im_one [simp]: "Im 1 = 0"

   118   by (simp add: complex_one_def)

   119

   120 lemma complex_mult [simp]:

   121   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"

   122   by (simp add: complex_mult_def)

   123

   124 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"

   125   by (simp add: complex_mult_def)

   126

   127 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"

   128   by (simp add: complex_mult_def)

   129

   130 lemma complex_inverse [simp]:

   131   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"

   132   by (simp add: complex_inverse_def)

   133

   134 lemma complex_Re_inverse:

   135   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"

   136   by (simp add: complex_inverse_def)

   137

   138 lemma complex_Im_inverse:

   139   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"

   140   by (simp add: complex_inverse_def)

   141

   142 instance

   143   by intro_classes (simp_all add: complex_mult_def

   144     distrib_left distrib_right right_diff_distrib left_diff_distrib

   145     complex_inverse_def complex_divide_def

   146     power2_eq_square add_divide_distrib [symmetric]

   147     complex_eq_iff)

   148

   149 end

   150

   151

   152 subsection {* Numerals and Arithmetic *}

   153

   154 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"

   155   by (induct n) simp_all

   156

   157 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"

   158   by (induct n) simp_all

   159

   160 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"

   161   by (cases z rule: int_diff_cases) simp

   162

   163 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"

   164   by (cases z rule: int_diff_cases) simp

   165

   166 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"

   167   using complex_Re_of_int [of "numeral v"] by simp

   168

   169 lemma complex_Re_neg_numeral [simp]: "Re (neg_numeral v) = neg_numeral v"

   170   using complex_Re_of_int [of "neg_numeral v"] by simp

   171

   172 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"

   173   using complex_Im_of_int [of "numeral v"] by simp

   174

   175 lemma complex_Im_neg_numeral [simp]: "Im (neg_numeral v) = 0"

   176   using complex_Im_of_int [of "neg_numeral v"] by simp

   177

   178 lemma Complex_eq_numeral [simp]:

   179   "(Complex a b = numeral w) = (a = numeral w \<and> b = 0)"

   180   by (simp add: complex_eq_iff)

   181

   182 lemma Complex_eq_neg_numeral [simp]:

   183   "(Complex a b = neg_numeral w) = (a = neg_numeral w \<and> b = 0)"

   184   by (simp add: complex_eq_iff)

   185

   186

   187 subsection {* Scalar Multiplication *}

   188

   189 instantiation complex :: real_field

   190 begin

   191

   192 definition complex_scaleR_def:

   193   "scaleR r x = Complex (r * Re x) (r * Im x)"

   194

   195 lemma complex_scaleR [simp]:

   196   "scaleR r (Complex a b) = Complex (r * a) (r * b)"

   197   unfolding complex_scaleR_def by simp

   198

   199 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"

   200   unfolding complex_scaleR_def by simp

   201

   202 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"

   203   unfolding complex_scaleR_def by simp

   204

   205 instance

   206 proof

   207   fix a b :: real and x y :: complex

   208   show "scaleR a (x + y) = scaleR a x + scaleR a y"

   209     by (simp add: complex_eq_iff distrib_left)

   210   show "scaleR (a + b) x = scaleR a x + scaleR b x"

   211     by (simp add: complex_eq_iff distrib_right)

   212   show "scaleR a (scaleR b x) = scaleR (a * b) x"

   213     by (simp add: complex_eq_iff mult_assoc)

   214   show "scaleR 1 x = x"

   215     by (simp add: complex_eq_iff)

   216   show "scaleR a x * y = scaleR a (x * y)"

   217     by (simp add: complex_eq_iff algebra_simps)

   218   show "x * scaleR a y = scaleR a (x * y)"

   219     by (simp add: complex_eq_iff algebra_simps)

   220 qed

   221

   222 end

   223

   224

   225 subsection{* Properties of Embedding from Reals *}

   226

   227 abbreviation complex_of_real :: "real \<Rightarrow> complex"

   228   where "complex_of_real \<equiv> of_real"

   229

   230 lemma complex_of_real_def: "complex_of_real r = Complex r 0"

   231   by (simp add: of_real_def complex_scaleR_def)

   232

   233 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"

   234   by (simp add: complex_of_real_def)

   235

   236 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"

   237   by (simp add: complex_of_real_def)

   238

   239 lemma Complex_add_complex_of_real [simp]:

   240   shows "Complex x y + complex_of_real r = Complex (x+r) y"

   241   by (simp add: complex_of_real_def)

   242

   243 lemma complex_of_real_add_Complex [simp]:

   244   shows "complex_of_real r + Complex x y = Complex (r+x) y"

   245   by (simp add: complex_of_real_def)

   246

   247 lemma Complex_mult_complex_of_real:

   248   shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"

   249   by (simp add: complex_of_real_def)

   250

   251 lemma complex_of_real_mult_Complex:

   252   shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"

   253   by (simp add: complex_of_real_def)

   254

   255 lemma complex_eq_cancel_iff2 [simp]:

   256   shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"

   257   by (simp add: complex_of_real_def)

   258

   259 lemma complex_split_polar:

   260      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"

   261   by (simp add: complex_eq_iff polar_Ex)

   262

   263

   264 subsection {* Vector Norm *}

   265

   266 instantiation complex :: real_normed_field

   267 begin

   268

   269 definition complex_norm_def:

   270   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"

   271

   272 abbreviation cmod :: "complex \<Rightarrow> real"

   273   where "cmod \<equiv> norm"

   274

   275 definition complex_sgn_def:

   276   "sgn x = x /\<^sub>R cmod x"

   277

   278 definition dist_complex_def:

   279   "dist x y = cmod (x - y)"

   280

   281 definition open_complex_def:

   282   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   283

   284 lemmas cmod_def = complex_norm_def

   285

   286 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"

   287   by (simp add: complex_norm_def)

   288

   289 instance proof

   290   fix r :: real and x y :: complex and S :: "complex set"

   291   show "0 \<le> norm x"

   292     by (induct x) simp

   293   show "(norm x = 0) = (x = 0)"

   294     by (induct x) simp

   295   show "norm (x + y) \<le> norm x + norm y"

   296     by (induct x, induct y)

   297        (simp add: real_sqrt_sum_squares_triangle_ineq)

   298   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"

   299     by (induct x)

   300        (simp add: power_mult_distrib distrib_left [symmetric] real_sqrt_mult)

   301   show "norm (x * y) = norm x * norm y"

   302     by (induct x, induct y)

   303        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)

   304   show "sgn x = x /\<^sub>R cmod x"

   305     by (rule complex_sgn_def)

   306   show "dist x y = cmod (x - y)"

   307     by (rule dist_complex_def)

   308   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   309     by (rule open_complex_def)

   310 qed

   311

   312 end

   313

   314 lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"

   315   by simp

   316

   317 lemma cmod_complex_polar:

   318   "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"

   319   by (simp add: norm_mult)

   320

   321 lemma complex_Re_le_cmod: "Re x \<le> cmod x"

   322   unfolding complex_norm_def

   323   by (rule real_sqrt_sum_squares_ge1)

   324

   325 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"

   326   by (rule order_trans [OF _ norm_ge_zero], simp)

   327

   328 lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"

   329   by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)

   330

   331 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"

   332   by (cases x) simp

   333

   334 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"

   335   by (cases x) simp

   336

   337 text {* Properties of complex signum. *}

   338

   339 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"

   340   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)

   341

   342 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"

   343   by (simp add: complex_sgn_def divide_inverse)

   344

   345 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"

   346   by (simp add: complex_sgn_def divide_inverse)

   347

   348

   349 subsection {* Completeness of the Complexes *}

   350

   351 lemma bounded_linear_Re: "bounded_linear Re"

   352   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)

   353

   354 lemma bounded_linear_Im: "bounded_linear Im"

   355   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)

   356

   357 lemmas tendsto_Re [tendsto_intros] =

   358   bounded_linear.tendsto [OF bounded_linear_Re]

   359

   360 lemmas tendsto_Im [tendsto_intros] =

   361   bounded_linear.tendsto [OF bounded_linear_Im]

   362

   363 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]

   364 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]

   365 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]

   366 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]

   367

   368 lemma tendsto_Complex [tendsto_intros]:

   369   assumes "(f ---> a) F" and "(g ---> b) F"

   370   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"

   371 proof (rule tendstoI)

   372   fix r :: real assume "0 < r"

   373   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)

   374   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"

   375     using (f ---> a) F and 0 < r / sqrt 2 by (rule tendstoD)

   376   moreover

   377   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"

   378     using (g ---> b) F and 0 < r / sqrt 2 by (rule tendstoD)

   379   ultimately

   380   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"

   381     by (rule eventually_elim2)

   382        (simp add: dist_norm real_sqrt_sum_squares_less)

   383 qed

   384

   385 instance complex :: banach

   386 proof

   387   fix X :: "nat \<Rightarrow> complex"

   388   assume X: "Cauchy X"

   389   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"

   390     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)

   391   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"

   392     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)

   393   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"

   394     using tendsto_Complex [OF 1 2] by simp

   395   thus "convergent X"

   396     by (rule convergentI)

   397 qed

   398

   399

   400 subsection {* The Complex Number $i$ *}

   401

   402 definition "ii" :: complex  ("\<i>")

   403   where i_def: "ii \<equiv> Complex 0 1"

   404

   405 lemma complex_Re_i [simp]: "Re ii = 0"

   406   by (simp add: i_def)

   407

   408 lemma complex_Im_i [simp]: "Im ii = 1"

   409   by (simp add: i_def)

   410

   411 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"

   412   by (simp add: i_def)

   413

   414 lemma norm_ii [simp]: "norm ii = 1"

   415   by (simp add: i_def)

   416

   417 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"

   418   by (simp add: complex_eq_iff)

   419

   420 lemma complex_i_not_one [simp]: "ii \<noteq> 1"

   421   by (simp add: complex_eq_iff)

   422

   423 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"

   424   by (simp add: complex_eq_iff)

   425

   426 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> neg_numeral w"

   427   by (simp add: complex_eq_iff)

   428

   429 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"

   430   by (simp add: complex_eq_iff)

   431

   432 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"

   433   by (simp add: complex_eq_iff)

   434

   435 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"

   436   by (simp add: i_def complex_of_real_def)

   437

   438 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"

   439   by (simp add: i_def complex_of_real_def)

   440

   441 lemma i_squared [simp]: "ii * ii = -1"

   442   by (simp add: i_def)

   443

   444 lemma power2_i [simp]: "ii\<twosuperior> = -1"

   445   by (simp add: power2_eq_square)

   446

   447 lemma inverse_i [simp]: "inverse ii = - ii"

   448   by (rule inverse_unique, simp)

   449

   450 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"

   451   by (simp add: mult_assoc [symmetric])

   452

   453

   454 subsection {* Complex Conjugation *}

   455

   456 definition cnj :: "complex \<Rightarrow> complex" where

   457   "cnj z = Complex (Re z) (- Im z)"

   458

   459 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"

   460   by (simp add: cnj_def)

   461

   462 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"

   463   by (simp add: cnj_def)

   464

   465 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"

   466   by (simp add: cnj_def)

   467

   468 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"

   469   by (simp add: complex_eq_iff)

   470

   471 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"

   472   by (simp add: cnj_def)

   473

   474 lemma complex_cnj_zero [simp]: "cnj 0 = 0"

   475   by (simp add: complex_eq_iff)

   476

   477 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"

   478   by (simp add: complex_eq_iff)

   479

   480 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"

   481   by (simp add: complex_eq_iff)

   482

   483 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"

   484   by (simp add: complex_eq_iff)

   485

   486 lemma complex_cnj_minus: "cnj (- x) = - cnj x"

   487   by (simp add: complex_eq_iff)

   488

   489 lemma complex_cnj_one [simp]: "cnj 1 = 1"

   490   by (simp add: complex_eq_iff)

   491

   492 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"

   493   by (simp add: complex_eq_iff)

   494

   495 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"

   496   by (simp add: complex_inverse_def)

   497

   498 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"

   499   by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)

   500

   501 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"

   502   by (induct n, simp_all add: complex_cnj_mult)

   503

   504 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"

   505   by (simp add: complex_eq_iff)

   506

   507 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"

   508   by (simp add: complex_eq_iff)

   509

   510 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"

   511   by (simp add: complex_eq_iff)

   512

   513 lemma complex_cnj_neg_numeral [simp]: "cnj (neg_numeral w) = neg_numeral w"

   514   by (simp add: complex_eq_iff)

   515

   516 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"

   517   by (simp add: complex_eq_iff)

   518

   519 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"

   520   by (simp add: complex_norm_def)

   521

   522 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"

   523   by (simp add: complex_eq_iff)

   524

   525 lemma complex_cnj_i [simp]: "cnj ii = - ii"

   526   by (simp add: complex_eq_iff)

   527

   528 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"

   529   by (simp add: complex_eq_iff)

   530

   531 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"

   532   by (simp add: complex_eq_iff)

   533

   534 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"

   535   by (simp add: complex_eq_iff power2_eq_square)

   536

   537 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"

   538   by (simp add: norm_mult power2_eq_square)

   539

   540 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"

   541   by (simp add: cmod_def power2_eq_square)

   542

   543 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"

   544   by simp

   545

   546 lemma bounded_linear_cnj: "bounded_linear cnj"

   547   using complex_cnj_add complex_cnj_scaleR

   548   by (rule bounded_linear_intro [where K=1], simp)

   549

   550 lemmas tendsto_cnj [tendsto_intros] =

   551   bounded_linear.tendsto [OF bounded_linear_cnj]

   552

   553 lemmas isCont_cnj [simp] =

   554   bounded_linear.isCont [OF bounded_linear_cnj]

   555

   556

   557 subsection{*Finally! Polar Form for Complex Numbers*}

   558

   559 subsubsection {* $\cos \theta + i \sin \theta$ *}

   560

   561 definition cis :: "real \<Rightarrow> complex" where

   562   "cis a = Complex (cos a) (sin a)"

   563

   564 lemma Re_cis [simp]: "Re (cis a) = cos a"

   565   by (simp add: cis_def)

   566

   567 lemma Im_cis [simp]: "Im (cis a) = sin a"

   568   by (simp add: cis_def)

   569

   570 lemma cis_zero [simp]: "cis 0 = 1"

   571   by (simp add: cis_def)

   572

   573 lemma norm_cis [simp]: "norm (cis a) = 1"

   574   by (simp add: cis_def)

   575

   576 lemma sgn_cis [simp]: "sgn (cis a) = cis a"

   577   by (simp add: sgn_div_norm)

   578

   579 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"

   580   by (metis norm_cis norm_zero zero_neq_one)

   581

   582 lemma cis_mult: "cis a * cis b = cis (a + b)"

   583   by (simp add: cis_def cos_add sin_add)

   584

   585 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"

   586   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)

   587

   588 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"

   589   by (simp add: cis_def)

   590

   591 lemma cis_divide: "cis a / cis b = cis (a - b)"

   592   by (simp add: complex_divide_def cis_mult diff_minus)

   593

   594 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"

   595   by (auto simp add: DeMoivre)

   596

   597 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"

   598   by (auto simp add: DeMoivre)

   599

   600 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}

   601

   602 definition rcis :: "[real, real] \<Rightarrow> complex" where

   603   "rcis r a = complex_of_real r * cis a"

   604

   605 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"

   606   by (simp add: rcis_def)

   607

   608 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"

   609   by (simp add: rcis_def)

   610

   611 lemma rcis_Ex: "\<exists>r a. z = rcis r a"

   612   by (simp add: complex_eq_iff polar_Ex)

   613

   614 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"

   615   by (simp add: rcis_def norm_mult)

   616

   617 lemma cis_rcis_eq: "cis a = rcis 1 a"

   618   by (simp add: rcis_def)

   619

   620 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"

   621   by (simp add: rcis_def cis_mult)

   622

   623 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"

   624   by (simp add: rcis_def)

   625

   626 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"

   627   by (simp add: rcis_def)

   628

   629 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"

   630   by (simp add: rcis_def)

   631

   632 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"

   633   by (simp add: rcis_def power_mult_distrib DeMoivre)

   634

   635 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"

   636   by (simp add: divide_inverse rcis_def)

   637

   638 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"

   639   by (simp add: rcis_def cis_divide [symmetric])

   640

   641 subsubsection {* Complex exponential *}

   642

   643 abbreviation expi :: "complex \<Rightarrow> complex"

   644   where "expi \<equiv> exp"

   645

   646 lemma cis_conv_exp: "cis b = exp (Complex 0 b)"

   647 proof (rule complex_eqI)

   648   { fix n have "Complex 0 b ^ n =

   649     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"

   650       apply (induct n)

   651       apply (simp add: cos_coeff_def sin_coeff_def)

   652       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)

   653       done } note * = this

   654   show "Re (cis b) = Re (exp (Complex 0 b))"

   655     unfolding exp_def cis_def cos_def

   656     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],

   657       simp add: * mult_assoc [symmetric])

   658   show "Im (cis b) = Im (exp (Complex 0 b))"

   659     unfolding exp_def cis_def sin_def

   660     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],

   661       simp add: * mult_assoc [symmetric])

   662 qed

   663

   664 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"

   665   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp

   666

   667 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"

   668   unfolding expi_def by simp

   669

   670 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"

   671   unfolding expi_def by simp

   672

   673 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"

   674 apply (insert rcis_Ex [of z])

   675 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])

   676 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)

   677 done

   678

   679 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"

   680   by (simp add: expi_def cis_def)

   681

   682 subsubsection {* Complex argument *}

   683

   684 definition arg :: "complex \<Rightarrow> real" where

   685   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"

   686

   687 lemma arg_zero: "arg 0 = 0"

   688   by (simp add: arg_def)

   689

   690 lemma of_nat_less_of_int_iff: (* TODO: move *)

   691   "(of_nat n :: 'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"

   692   by (metis of_int_of_nat_eq of_int_less_iff)

   693

   694 lemma real_of_nat_less_numeral_iff [simp]: (* TODO: move *)

   695   "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"

   696   using of_nat_less_of_int_iff [of n "numeral w", where 'a=real]

   697   by (simp add: real_of_nat_def zless_nat_eq_int_zless [symmetric])

   698

   699 lemma arg_unique:

   700   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"

   701   shows "arg z = x"

   702 proof -

   703   from assms have "z \<noteq> 0" by auto

   704   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"

   705   proof

   706     fix a def d \<equiv> "a - x"

   707     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"

   708     from a assms have "- (2*pi) < d \<and> d < 2*pi"

   709       unfolding d_def by simp

   710     moreover from a assms have "cos a = cos x" and "sin a = sin x"

   711       by (simp_all add: complex_eq_iff)

   712     hence "cos d = 1" unfolding d_def cos_diff by simp

   713     moreover hence "sin d = 0" by (rule cos_one_sin_zero)

   714     ultimately have "d = 0"

   715       unfolding sin_zero_iff even_mult_two_ex

   716       by (safe, auto simp add: numeral_2_eq_2 less_Suc_eq)

   717     thus "a = x" unfolding d_def by simp

   718   qed (simp add: assms del: Re_sgn Im_sgn)

   719   with z \<noteq> 0 show "arg z = x"

   720     unfolding arg_def by simp

   721 qed

   722

   723 lemma arg_correct:

   724   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"

   725 proof (simp add: arg_def assms, rule someI_ex)

   726   obtain r a where z: "z = rcis r a" using rcis_Ex by fast

   727   with assms have "r \<noteq> 0" by auto

   728   def b \<equiv> "if 0 < r then a else a + pi"

   729   have b: "sgn z = cis b"

   730     unfolding z b_def rcis_def using r \<noteq> 0

   731     by (simp add: of_real_def sgn_scaleR sgn_if, simp add: cis_def)

   732   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"

   733     by (induct_tac n, simp_all add: distrib_left cis_mult [symmetric],

   734       simp add: cis_def)

   735   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"

   736     by (case_tac x rule: int_diff_cases,

   737       simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)

   738   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"

   739   have "sgn z = cis c"

   740     unfolding b c_def

   741     by (simp add: cis_divide [symmetric] cis_2pi_int)

   742   moreover have "- pi < c \<and> c \<le> pi"

   743     using ceiling_correct [of "(b - pi) / (2*pi)"]

   744     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)

   745   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast

   746 qed

   747

   748 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"

   749   by (cases "z = 0", simp_all add: arg_zero arg_correct)

   750

   751 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"

   752   by (simp add: arg_correct)

   753

   754 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"

   755   by (cases "z = 0", simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)

   756

   757 lemma cos_arg_i_mult_zero [simp]:

   758      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"

   759   using cis_arg [of "Complex 0 y"] by (simp add: complex_eq_iff)

   760

   761 text {* Legacy theorem names *}

   762

   763 lemmas expand_complex_eq = complex_eq_iff

   764 lemmas complex_Re_Im_cancel_iff = complex_eq_iff

   765 lemmas complex_equality = complex_eqI

   766

   767 end