src/HOL/Deriv.thy
author hoelzl
Thu Jan 31 11:31:27 2013 +0100 (2013-01-31)
changeset 50999 3de230ed0547
parent 50347 77e3effa50b6
child 51476 0c0efde246d1
permissions -rw-r--r--
introduce order topology
     1 (*  Title       : Deriv.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5     GMVT by Benjamin Porter, 2005
     6 *)
     7 
     8 header{* Differentiation *}
     9 
    10 theory Deriv
    11 imports Lim
    12 begin
    13 
    14 text{*Standard Definitions*}
    15 
    16 definition
    17   deriv :: "['a::real_normed_field \<Rightarrow> 'a, 'a, 'a] \<Rightarrow> bool"
    18     --{*Differentiation: D is derivative of function f at x*}
    19           ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60) where
    20   "DERIV f x :> D = ((%h. (f(x + h) - f x) / h) -- 0 --> D)"
    21 
    22 primrec
    23   Bolzano_bisect :: "(real \<times> real \<Rightarrow> bool) \<Rightarrow> real \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> real \<times> real" where
    24   "Bolzano_bisect P a b 0 = (a, b)"
    25   | "Bolzano_bisect P a b (Suc n) =
    26       (let (x, y) = Bolzano_bisect P a b n
    27        in if P (x, (x+y) / 2) then ((x+y)/2, y)
    28                               else (x, (x+y)/2))"
    29 
    30 
    31 subsection {* Derivatives *}
    32 
    33 lemma DERIV_iff: "(DERIV f x :> D) = ((%h. (f(x + h) - f(x))/h) -- 0 --> D)"
    34 by (simp add: deriv_def)
    35 
    36 lemma DERIV_D: "DERIV f x :> D ==> (%h. (f(x + h) - f(x))/h) -- 0 --> D"
    37 by (simp add: deriv_def)
    38 
    39 lemma DERIV_const [simp]: "DERIV (\<lambda>x. k) x :> 0"
    40   by (simp add: deriv_def tendsto_const)
    41 
    42 lemma DERIV_ident [simp]: "DERIV (\<lambda>x. x) x :> 1"
    43   by (simp add: deriv_def tendsto_const cong: LIM_cong)
    44 
    45 lemma DERIV_add:
    46   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + g x) x :> D + E"
    47   by (simp only: deriv_def add_diff_add add_divide_distrib tendsto_add)
    48 
    49 lemma DERIV_minus:
    50   "DERIV f x :> D \<Longrightarrow> DERIV (\<lambda>x. - f x) x :> - D"
    51   by (simp only: deriv_def minus_diff_minus divide_minus_left tendsto_minus)
    52 
    53 lemma DERIV_diff:
    54   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x - g x) x :> D - E"
    55 by (simp only: diff_minus DERIV_add DERIV_minus)
    56 
    57 lemma DERIV_add_minus:
    58   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + - g x) x :> D + - E"
    59 by (simp only: DERIV_add DERIV_minus)
    60 
    61 lemma DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
    62 proof (unfold isCont_iff)
    63   assume "DERIV f x :> D"
    64   hence "(\<lambda>h. (f(x+h) - f(x)) / h) -- 0 --> D"
    65     by (rule DERIV_D)
    66   hence "(\<lambda>h. (f(x+h) - f(x)) / h * h) -- 0 --> D * 0"
    67     by (intro tendsto_mult tendsto_ident_at)
    68   hence "(\<lambda>h. (f(x+h) - f(x)) * (h / h)) -- 0 --> 0"
    69     by simp
    70   hence "(\<lambda>h. f(x+h) - f(x)) -- 0 --> 0"
    71     by (simp cong: LIM_cong)
    72   thus "(\<lambda>h. f(x+h)) -- 0 --> f(x)"
    73     by (simp add: LIM_def dist_norm)
    74 qed
    75 
    76 lemma DERIV_mult_lemma:
    77   fixes a b c d :: "'a::real_field"
    78   shows "(a * b - c * d) / h = a * ((b - d) / h) + ((a - c) / h) * d"
    79   by (simp add: field_simps diff_divide_distrib)
    80 
    81 lemma DERIV_mult':
    82   assumes f: "DERIV f x :> D"
    83   assumes g: "DERIV g x :> E"
    84   shows "DERIV (\<lambda>x. f x * g x) x :> f x * E + D * g x"
    85 proof (unfold deriv_def)
    86   from f have "isCont f x"
    87     by (rule DERIV_isCont)
    88   hence "(\<lambda>h. f(x+h)) -- 0 --> f x"
    89     by (simp only: isCont_iff)
    90   hence "(\<lambda>h. f(x+h) * ((g(x+h) - g x) / h) +
    91               ((f(x+h) - f x) / h) * g x)
    92           -- 0 --> f x * E + D * g x"
    93     by (intro tendsto_intros DERIV_D f g)
    94   thus "(\<lambda>h. (f(x+h) * g(x+h) - f x * g x) / h)
    95          -- 0 --> f x * E + D * g x"
    96     by (simp only: DERIV_mult_lemma)
    97 qed
    98 
    99 lemma DERIV_mult:
   100     "DERIV f x :> Da \<Longrightarrow> DERIV g x :> Db \<Longrightarrow> DERIV (\<lambda>x. f x * g x) x :> Da * g x + Db * f x"
   101   by (drule (1) DERIV_mult', simp only: mult_commute add_commute)
   102 
   103 lemma DERIV_unique:
   104     "DERIV f x :> D \<Longrightarrow> DERIV f x :> E \<Longrightarrow> D = E"
   105   unfolding deriv_def by (rule LIM_unique) 
   106 
   107 text{*Differentiation of finite sum*}
   108 
   109 lemma DERIV_setsum:
   110   assumes "finite S"
   111   and "\<And> n. n \<in> S \<Longrightarrow> DERIV (%x. f x n) x :> (f' x n)"
   112   shows "DERIV (%x. setsum (f x) S) x :> setsum (f' x) S"
   113   using assms by induct (auto intro!: DERIV_add)
   114 
   115 lemma DERIV_sumr [rule_format (no_asm)]:
   116      "(\<forall>r. m \<le> r & r < (m + n) --> DERIV (%x. f r x) x :> (f' r x))
   117       --> DERIV (%x. \<Sum>n=m..<n::nat. f n x :: real) x :> (\<Sum>r=m..<n. f' r x)"
   118   by (auto intro: DERIV_setsum)
   119 
   120 text{*Alternative definition for differentiability*}
   121 
   122 lemma DERIV_LIM_iff:
   123   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a" shows
   124      "((%h. (f(a + h) - f(a)) / h) -- 0 --> D) =
   125       ((%x. (f(x)-f(a)) / (x-a)) -- a --> D)"
   126 apply (rule iffI)
   127 apply (drule_tac k="- a" in LIM_offset)
   128 apply (simp add: diff_minus)
   129 apply (drule_tac k="a" in LIM_offset)
   130 apply (simp add: add_commute)
   131 done
   132 
   133 lemma DERIV_iff2: "(DERIV f x :> D) = ((%z. (f(z) - f(x)) / (z-x)) -- x --> D)"
   134 by (simp add: deriv_def diff_minus [symmetric] DERIV_LIM_iff)
   135 
   136 lemma DERIV_inverse_lemma:
   137   "\<lbrakk>a \<noteq> 0; b \<noteq> (0::'a::real_normed_field)\<rbrakk>
   138    \<Longrightarrow> (inverse a - inverse b) / h
   139      = - (inverse a * ((a - b) / h) * inverse b)"
   140 by (simp add: inverse_diff_inverse)
   141 
   142 lemma DERIV_inverse':
   143   assumes der: "DERIV f x :> D"
   144   assumes neq: "f x \<noteq> 0"
   145   shows "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * D * inverse (f x))"
   146     (is "DERIV _ _ :> ?E")
   147 proof (unfold DERIV_iff2)
   148   from der have lim_f: "f -- x --> f x"
   149     by (rule DERIV_isCont [unfolded isCont_def])
   150 
   151   from neq have "0 < norm (f x)" by simp
   152   with LIM_D [OF lim_f] obtain s
   153     where s: "0 < s"
   154     and less_fx: "\<And>z. \<lbrakk>z \<noteq> x; norm (z - x) < s\<rbrakk>
   155                   \<Longrightarrow> norm (f z - f x) < norm (f x)"
   156     by fast
   157 
   158   show "(\<lambda>z. (inverse (f z) - inverse (f x)) / (z - x)) -- x --> ?E"
   159   proof (rule LIM_equal2 [OF s])
   160     fix z
   161     assume "z \<noteq> x" "norm (z - x) < s"
   162     hence "norm (f z - f x) < norm (f x)" by (rule less_fx)
   163     hence "f z \<noteq> 0" by auto
   164     thus "(inverse (f z) - inverse (f x)) / (z - x) =
   165           - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x))"
   166       using neq by (rule DERIV_inverse_lemma)
   167   next
   168     from der have "(\<lambda>z. (f z - f x) / (z - x)) -- x --> D"
   169       by (unfold DERIV_iff2)
   170     thus "(\<lambda>z. - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x)))
   171           -- x --> ?E"
   172       by (intro tendsto_intros lim_f neq)
   173   qed
   174 qed
   175 
   176 lemma DERIV_divide:
   177   "\<lbrakk>DERIV f x :> D; DERIV g x :> E; g x \<noteq> 0\<rbrakk>
   178    \<Longrightarrow> DERIV (\<lambda>x. f x / g x) x :> (D * g x - f x * E) / (g x * g x)"
   179 apply (subgoal_tac "f x * - (inverse (g x) * E * inverse (g x)) +
   180           D * inverse (g x) = (D * g x - f x * E) / (g x * g x)")
   181 apply (erule subst)
   182 apply (unfold divide_inverse)
   183 apply (erule DERIV_mult')
   184 apply (erule (1) DERIV_inverse')
   185 apply (simp add: ring_distribs nonzero_inverse_mult_distrib)
   186 done
   187 
   188 lemma DERIV_power_Suc:
   189   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field}"
   190   assumes f: "DERIV f x :> D"
   191   shows "DERIV (\<lambda>x. f x ^ Suc n) x :> (1 + of_nat n) * (D * f x ^ n)"
   192 proof (induct n)
   193 case 0
   194   show ?case by (simp add: f)
   195 case (Suc k)
   196   from DERIV_mult' [OF f Suc] show ?case
   197     apply (simp only: of_nat_Suc ring_distribs mult_1_left)
   198     apply (simp only: power_Suc algebra_simps)
   199     done
   200 qed
   201 
   202 lemma DERIV_power:
   203   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field}"
   204   assumes f: "DERIV f x :> D"
   205   shows "DERIV (\<lambda>x. f x ^ n) x :> of_nat n * (D * f x ^ (n - Suc 0))"
   206 by (cases "n", simp, simp add: DERIV_power_Suc f del: power_Suc)
   207 
   208 text {* Caratheodory formulation of derivative at a point *}
   209 
   210 lemma CARAT_DERIV:
   211      "(DERIV f x :> l) =
   212       (\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) & isCont g x & g x = l)"
   213       (is "?lhs = ?rhs")
   214 proof
   215   assume der: "DERIV f x :> l"
   216   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   217   proof (intro exI conjI)
   218     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   219     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   220     show "isCont ?g x" using der
   221       by (simp add: isCont_iff DERIV_iff diff_minus
   222                cong: LIM_equal [rule_format])
   223     show "?g x = l" by simp
   224   qed
   225 next
   226   assume "?rhs"
   227   then obtain g where
   228     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   229   thus "(DERIV f x :> l)"
   230      by (auto simp add: isCont_iff DERIV_iff cong: LIM_cong)
   231 qed
   232 
   233 lemma DERIV_chain':
   234   assumes f: "DERIV f x :> D"
   235   assumes g: "DERIV g (f x) :> E"
   236   shows "DERIV (\<lambda>x. g (f x)) x :> E * D"
   237 proof (unfold DERIV_iff2)
   238   obtain d where d: "\<forall>y. g y - g (f x) = d y * (y - f x)"
   239     and cont_d: "isCont d (f x)" and dfx: "d (f x) = E"
   240     using CARAT_DERIV [THEN iffD1, OF g] by fast
   241   from f have "f -- x --> f x"
   242     by (rule DERIV_isCont [unfolded isCont_def])
   243   with cont_d have "(\<lambda>z. d (f z)) -- x --> d (f x)"
   244     by (rule isCont_tendsto_compose)
   245   hence "(\<lambda>z. d (f z) * ((f z - f x) / (z - x)))
   246           -- x --> d (f x) * D"
   247     by (rule tendsto_mult [OF _ f [unfolded DERIV_iff2]])
   248   thus "(\<lambda>z. (g (f z) - g (f x)) / (z - x)) -- x --> E * D"
   249     by (simp add: d dfx)
   250 qed
   251 
   252 text {*
   253  Let's do the standard proof, though theorem
   254  @{text "LIM_mult2"} follows from a NS proof
   255 *}
   256 
   257 lemma DERIV_cmult:
   258       "DERIV f x :> D ==> DERIV (%x. c * f x) x :> c*D"
   259 by (drule DERIV_mult' [OF DERIV_const], simp)
   260 
   261 lemma DERIV_cdivide: "DERIV f x :> D ==> DERIV (%x. f x / c) x :> D / c"
   262   apply (subgoal_tac "DERIV (%x. (1 / c) * f x) x :> (1 / c) * D", force)
   263   apply (erule DERIV_cmult)
   264   done
   265 
   266 text {* Standard version *}
   267 lemma DERIV_chain: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (f o g) x :> Da * Db"
   268 by (drule (1) DERIV_chain', simp add: o_def mult_commute)
   269 
   270 lemma DERIV_chain2: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (%x. f (g x)) x :> Da * Db"
   271 by (auto dest: DERIV_chain simp add: o_def)
   272 
   273 text {* Derivative of linear multiplication *}
   274 lemma DERIV_cmult_Id [simp]: "DERIV (op * c) x :> c"
   275 by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   276 
   277 lemma DERIV_pow: "DERIV (%x. x ^ n) x :> real n * (x ^ (n - Suc 0))"
   278 apply (cut_tac DERIV_power [OF DERIV_ident])
   279 apply (simp add: real_of_nat_def)
   280 done
   281 
   282 text {* Power of @{text "-1"} *}
   283 
   284 lemma DERIV_inverse:
   285   fixes x :: "'a::{real_normed_field}"
   286   shows "x \<noteq> 0 ==> DERIV (%x. inverse(x)) x :> (-(inverse x ^ Suc (Suc 0)))"
   287 by (drule DERIV_inverse' [OF DERIV_ident]) simp
   288 
   289 text {* Derivative of inverse *}
   290 lemma DERIV_inverse_fun:
   291   fixes x :: "'a::{real_normed_field}"
   292   shows "[| DERIV f x :> d; f(x) \<noteq> 0 |]
   293       ==> DERIV (%x. inverse(f x)) x :> (- (d * inverse(f(x) ^ Suc (Suc 0))))"
   294 by (drule (1) DERIV_inverse') (simp add: mult_ac nonzero_inverse_mult_distrib)
   295 
   296 text {* Derivative of quotient *}
   297 lemma DERIV_quotient:
   298   fixes x :: "'a::{real_normed_field}"
   299   shows "[| DERIV f x :> d; DERIV g x :> e; g(x) \<noteq> 0 |]
   300        ==> DERIV (%y. f(y) / (g y)) x :> (d*g(x) - (e*f(x))) / (g(x) ^ Suc (Suc 0))"
   301 by (drule (2) DERIV_divide) (simp add: mult_commute)
   302 
   303 text {* @{text "DERIV_intros"} *}
   304 ML {*
   305 structure Deriv_Intros = Named_Thms
   306 (
   307   val name = @{binding DERIV_intros}
   308   val description = "DERIV introduction rules"
   309 )
   310 *}
   311 
   312 setup Deriv_Intros.setup
   313 
   314 lemma DERIV_cong: "\<lbrakk> DERIV f x :> X ; X = Y \<rbrakk> \<Longrightarrow> DERIV f x :> Y"
   315   by simp
   316 
   317 declare
   318   DERIV_const[THEN DERIV_cong, DERIV_intros]
   319   DERIV_ident[THEN DERIV_cong, DERIV_intros]
   320   DERIV_add[THEN DERIV_cong, DERIV_intros]
   321   DERIV_minus[THEN DERIV_cong, DERIV_intros]
   322   DERIV_mult[THEN DERIV_cong, DERIV_intros]
   323   DERIV_diff[THEN DERIV_cong, DERIV_intros]
   324   DERIV_inverse'[THEN DERIV_cong, DERIV_intros]
   325   DERIV_divide[THEN DERIV_cong, DERIV_intros]
   326   DERIV_power[where 'a=real, THEN DERIV_cong,
   327               unfolded real_of_nat_def[symmetric], DERIV_intros]
   328   DERIV_setsum[THEN DERIV_cong, DERIV_intros]
   329 
   330 
   331 subsection {* Differentiability predicate *}
   332 
   333 definition
   334   differentiable :: "['a::real_normed_field \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   335     (infixl "differentiable" 60) where
   336   "f differentiable x = (\<exists>D. DERIV f x :> D)"
   337 
   338 lemma differentiableE [elim?]:
   339   assumes "f differentiable x"
   340   obtains df where "DERIV f x :> df"
   341   using assms unfolding differentiable_def ..
   342 
   343 lemma differentiableD: "f differentiable x ==> \<exists>D. DERIV f x :> D"
   344 by (simp add: differentiable_def)
   345 
   346 lemma differentiableI: "DERIV f x :> D ==> f differentiable x"
   347 by (force simp add: differentiable_def)
   348 
   349 lemma differentiable_ident [simp]: "(\<lambda>x. x) differentiable x"
   350   by (rule DERIV_ident [THEN differentiableI])
   351 
   352 lemma differentiable_const [simp]: "(\<lambda>z. a) differentiable x"
   353   by (rule DERIV_const [THEN differentiableI])
   354 
   355 lemma differentiable_compose:
   356   assumes f: "f differentiable (g x)"
   357   assumes g: "g differentiable x"
   358   shows "(\<lambda>x. f (g x)) differentiable x"
   359 proof -
   360   from `f differentiable (g x)` obtain df where "DERIV f (g x) :> df" ..
   361   moreover
   362   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   363   ultimately
   364   have "DERIV (\<lambda>x. f (g x)) x :> df * dg" by (rule DERIV_chain2)
   365   thus ?thesis by (rule differentiableI)
   366 qed
   367 
   368 lemma differentiable_sum [simp]:
   369   assumes "f differentiable x"
   370   and "g differentiable x"
   371   shows "(\<lambda>x. f x + g x) differentiable x"
   372 proof -
   373   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   374   moreover
   375   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   376   ultimately
   377   have "DERIV (\<lambda>x. f x + g x) x :> df + dg" by (rule DERIV_add)
   378   thus ?thesis by (rule differentiableI)
   379 qed
   380 
   381 lemma differentiable_minus [simp]:
   382   assumes "f differentiable x"
   383   shows "(\<lambda>x. - f x) differentiable x"
   384 proof -
   385   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   386   hence "DERIV (\<lambda>x. - f x) x :> - df" by (rule DERIV_minus)
   387   thus ?thesis by (rule differentiableI)
   388 qed
   389 
   390 lemma differentiable_diff [simp]:
   391   assumes "f differentiable x"
   392   assumes "g differentiable x"
   393   shows "(\<lambda>x. f x - g x) differentiable x"
   394   unfolding diff_minus using assms by simp
   395 
   396 lemma differentiable_mult [simp]:
   397   assumes "f differentiable x"
   398   assumes "g differentiable x"
   399   shows "(\<lambda>x. f x * g x) differentiable x"
   400 proof -
   401   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   402   moreover
   403   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   404   ultimately
   405   have "DERIV (\<lambda>x. f x * g x) x :> df * g x + dg * f x" by (rule DERIV_mult)
   406   thus ?thesis by (rule differentiableI)
   407 qed
   408 
   409 lemma differentiable_inverse [simp]:
   410   assumes "f differentiable x" and "f x \<noteq> 0"
   411   shows "(\<lambda>x. inverse (f x)) differentiable x"
   412 proof -
   413   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   414   hence "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * df * inverse (f x))"
   415     using `f x \<noteq> 0` by (rule DERIV_inverse')
   416   thus ?thesis by (rule differentiableI)
   417 qed
   418 
   419 lemma differentiable_divide [simp]:
   420   assumes "f differentiable x"
   421   assumes "g differentiable x" and "g x \<noteq> 0"
   422   shows "(\<lambda>x. f x / g x) differentiable x"
   423   unfolding divide_inverse using assms by simp
   424 
   425 lemma differentiable_power [simp]:
   426   fixes f :: "'a::{real_normed_field} \<Rightarrow> 'a"
   427   assumes "f differentiable x"
   428   shows "(\<lambda>x. f x ^ n) differentiable x"
   429   apply (induct n)
   430   apply simp
   431   apply (simp add: assms)
   432   done
   433 
   434 
   435 subsection {* Nested Intervals and Bisection *}
   436 
   437 text{*Lemmas about nested intervals and proof by bisection (cf.Harrison).
   438      All considerably tidied by lcp.*}
   439 
   440 lemma lemma_f_mono_add [rule_format (no_asm)]: "(\<forall>n. (f::nat=>real) n \<le> f (Suc n)) --> f m \<le> f(m + no)"
   441 apply (induct "no")
   442 apply (auto intro: order_trans)
   443 done
   444 
   445 lemma f_inc_g_dec_Beq_f: "[| \<forall>n. f(n) \<le> f(Suc n);
   446          \<forall>n. g(Suc n) \<le> g(n);
   447          \<forall>n. f(n) \<le> g(n) |]
   448       ==> Bseq (f :: nat \<Rightarrow> real)"
   449 apply (rule_tac k = "f 0" and K = "g 0" in BseqI2, rule allI)
   450 apply (rule conjI)
   451 apply (induct_tac "n")
   452 apply (auto intro: order_trans)
   453 apply (rule_tac y = "g n" in order_trans)
   454 apply (induct_tac [2] "n")
   455 apply (auto intro: order_trans)
   456 done
   457 
   458 lemma f_inc_g_dec_Beq_g: "[| \<forall>n. f(n) \<le> f(Suc n);
   459          \<forall>n. g(Suc n) \<le> g(n);
   460          \<forall>n. f(n) \<le> g(n) |]
   461       ==> Bseq (g :: nat \<Rightarrow> real)"
   462 apply (subst Bseq_minus_iff [symmetric])
   463 apply (rule_tac g = "%x. - (f x)" in f_inc_g_dec_Beq_f)
   464 apply auto
   465 done
   466 
   467 lemma f_inc_imp_le_lim:
   468   fixes f :: "nat \<Rightarrow> real"
   469   shows "\<lbrakk>\<forall>n. f n \<le> f (Suc n); convergent f\<rbrakk> \<Longrightarrow> f n \<le> lim f"
   470   by (rule incseq_le, simp add: incseq_SucI, simp add: convergent_LIMSEQ_iff)
   471 
   472 lemma lim_uminus:
   473   fixes g :: "nat \<Rightarrow> 'a::real_normed_vector"
   474   shows "convergent g ==> lim (%x. - g x) = - (lim g)"
   475 apply (rule tendsto_minus [THEN limI])
   476 apply (simp add: convergent_LIMSEQ_iff)
   477 done
   478 
   479 lemma g_dec_imp_lim_le:
   480   fixes g :: "nat \<Rightarrow> real"
   481   shows "\<lbrakk>\<forall>n. g (Suc n) \<le> g(n); convergent g\<rbrakk> \<Longrightarrow> lim g \<le> g n"
   482   by (rule decseq_le, simp add: decseq_SucI, simp add: convergent_LIMSEQ_iff)
   483 
   484 lemma lemma_nest: "[| \<forall>n. f(n) \<le> f(Suc n);
   485          \<forall>n. g(Suc n) \<le> g(n);
   486          \<forall>n. f(n) \<le> g(n) |]
   487       ==> \<exists>l m :: real. l \<le> m &  ((\<forall>n. f(n) \<le> l) & f ----> l) &
   488                             ((\<forall>n. m \<le> g(n)) & g ----> m)"
   489 apply (subgoal_tac "monoseq f & monoseq g")
   490 prefer 2 apply (force simp add: LIMSEQ_iff monoseq_Suc)
   491 apply (subgoal_tac "Bseq f & Bseq g")
   492 prefer 2 apply (blast intro: f_inc_g_dec_Beq_f f_inc_g_dec_Beq_g)
   493 apply (auto dest!: Bseq_monoseq_convergent simp add: convergent_LIMSEQ_iff)
   494 apply (rule_tac x = "lim f" in exI)
   495 apply (rule_tac x = "lim g" in exI)
   496 apply (auto intro: LIMSEQ_le)
   497 apply (auto simp add: f_inc_imp_le_lim g_dec_imp_lim_le convergent_LIMSEQ_iff)
   498 done
   499 
   500 lemma lemma_nest_unique: "[| \<forall>n. f(n) \<le> f(Suc n);
   501          \<forall>n. g(Suc n) \<le> g(n);
   502          \<forall>n. f(n) \<le> g(n);
   503          (%n. f(n) - g(n)) ----> 0 |]
   504       ==> \<exists>l::real. ((\<forall>n. f(n) \<le> l) & f ----> l) &
   505                 ((\<forall>n. l \<le> g(n)) & g ----> l)"
   506 apply (drule lemma_nest, auto)
   507 apply (subgoal_tac "l = m")
   508 apply (drule_tac [2] f = f in tendsto_diff)
   509 apply (auto intro: LIMSEQ_unique)
   510 done
   511 
   512 text{*The universal quantifiers below are required for the declaration
   513   of @{text Bolzano_nest_unique} below.*}
   514 
   515 lemma Bolzano_bisect_le:
   516  "a \<le> b ==> \<forall>n. fst (Bolzano_bisect P a b n) \<le> snd (Bolzano_bisect P a b n)"
   517 apply (rule allI)
   518 apply (induct_tac "n")
   519 apply (auto simp add: Let_def split_def)
   520 done
   521 
   522 lemma Bolzano_bisect_fst_le_Suc: "a \<le> b ==>
   523    \<forall>n. fst(Bolzano_bisect P a b n) \<le> fst (Bolzano_bisect P a b (Suc n))"
   524 apply (rule allI)
   525 apply (induct_tac "n")
   526 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   527 done
   528 
   529 lemma Bolzano_bisect_Suc_le_snd: "a \<le> b ==>
   530    \<forall>n. snd(Bolzano_bisect P a b (Suc n)) \<le> snd (Bolzano_bisect P a b n)"
   531 apply (rule allI)
   532 apply (induct_tac "n")
   533 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   534 done
   535 
   536 lemma eq_divide_2_times_iff: "((x::real) = y / (2 * z)) = (2 * x = y/z)"
   537 apply (auto)
   538 apply (drule_tac f = "%u. (1/2) *u" in arg_cong)
   539 apply (simp)
   540 done
   541 
   542 lemma Bolzano_bisect_diff:
   543      "a \<le> b ==>
   544       snd(Bolzano_bisect P a b n) - fst(Bolzano_bisect P a b n) =
   545       (b-a) / (2 ^ n)"
   546 apply (induct "n")
   547 apply (auto simp add: eq_divide_2_times_iff add_divide_distrib Let_def split_def)
   548 done
   549 
   550 lemmas Bolzano_nest_unique =
   551     lemma_nest_unique
   552     [OF Bolzano_bisect_fst_le_Suc Bolzano_bisect_Suc_le_snd Bolzano_bisect_le]
   553 
   554 
   555 lemma not_P_Bolzano_bisect:
   556   assumes P:    "!!a b c. [| P(a,b); P(b,c); a \<le> b; b \<le> c|] ==> P(a,c)"
   557       and notP: "~ P(a,b)"
   558       and le:   "a \<le> b"
   559   shows "~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   560 proof (induct n)
   561   case 0 show ?case using notP by simp
   562  next
   563   case (Suc n)
   564   thus ?case
   565  by (auto simp del: surjective_pairing [symmetric]
   566              simp add: Let_def split_def Bolzano_bisect_le [OF le]
   567      P [of "fst (Bolzano_bisect P a b n)" _ "snd (Bolzano_bisect P a b n)"])
   568 qed
   569 
   570 (*Now we re-package P_prem as a formula*)
   571 lemma not_P_Bolzano_bisect':
   572      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   573          ~ P(a,b);  a \<le> b |] ==>
   574       \<forall>n. ~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   575 by (blast elim!: not_P_Bolzano_bisect [THEN [2] rev_notE])
   576 
   577 
   578 
   579 lemma lemma_BOLZANO:
   580      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   581          \<forall>x. \<exists>d::real. 0 < d &
   582                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b));
   583          a \<le> b |]
   584       ==> P(a,b)"
   585 apply (rule Bolzano_nest_unique [where P=P, THEN exE], assumption+)
   586 apply (rule tendsto_minus_cancel)
   587 apply (simp (no_asm_simp) add: Bolzano_bisect_diff LIMSEQ_divide_realpow_zero)
   588 apply (rule ccontr)
   589 apply (drule not_P_Bolzano_bisect', assumption+)
   590 apply (rename_tac "l")
   591 apply (drule_tac x = l in spec, clarify)
   592 apply (simp add: LIMSEQ_iff)
   593 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   594 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   595 apply (drule real_less_half_sum, auto)
   596 apply (drule_tac x = "fst (Bolzano_bisect P a b (no + noa))" in spec)
   597 apply (drule_tac x = "snd (Bolzano_bisect P a b (no + noa))" in spec)
   598 apply safe
   599 apply (simp_all (no_asm_simp))
   600 apply (rule_tac y = "abs (fst (Bolzano_bisect P a b (no + noa)) - l) + abs (snd (Bolzano_bisect P a b (no + noa)) - l)" in order_le_less_trans)
   601 apply (simp (no_asm_simp) add: abs_if)
   602 apply (rule real_sum_of_halves [THEN subst])
   603 apply (rule add_strict_mono)
   604 apply (simp_all add: diff_minus [symmetric])
   605 done
   606 
   607 
   608 lemma lemma_BOLZANO2: "((\<forall>a b c. (a \<le> b & b \<le> c & P(a,b) & P(b,c)) --> P(a,c)) &
   609        (\<forall>x. \<exists>d::real. 0 < d &
   610                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b))))
   611       --> (\<forall>a b. a \<le> b --> P(a,b))"
   612 apply clarify
   613 apply (blast intro: lemma_BOLZANO)
   614 done
   615 
   616 
   617 subsection {* Intermediate Value Theorem *}
   618 
   619 text {*Prove Contrapositive by Bisection*}
   620 
   621 lemma IVT: "[| f(a::real) \<le> (y::real); y \<le> f(b);
   622          a \<le> b;
   623          (\<forall>x. a \<le> x & x \<le> b --> isCont f x) |]
   624       ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   625 apply (rule contrapos_pp, assumption)
   626 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> ~ (f (u) \<le> y & y \<le> f (v))" in lemma_BOLZANO2)
   627 apply safe
   628 apply simp_all
   629 apply (simp add: isCont_iff LIM_eq)
   630 apply (rule ccontr)
   631 apply (subgoal_tac "a \<le> x & x \<le> b")
   632  prefer 2
   633  apply simp
   634  apply (drule_tac P = "%d. 0<d --> ?P d" and x = 1 in spec, arith)
   635 apply (drule_tac x = x in spec)+
   636 apply simp
   637 apply (drule_tac P = "%r. ?P r --> (\<exists>s>0. ?Q r s) " and x = "\<bar>y - f x\<bar>" in spec)
   638 apply safe
   639 apply simp
   640 apply (drule_tac x = s in spec, clarify)
   641 apply (cut_tac x = "f x" and y = y in linorder_less_linear, safe)
   642 apply (drule_tac x = "ba-x" in spec)
   643 apply (simp_all add: abs_if)
   644 apply (drule_tac x = "aa-x" in spec)
   645 apply (case_tac "x \<le> aa", simp_all)
   646 done
   647 
   648 lemma IVT2: "[| f(b::real) \<le> (y::real); y \<le> f(a);
   649          a \<le> b;
   650          (\<forall>x. a \<le> x & x \<le> b --> isCont f x)
   651       |] ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   652 apply (subgoal_tac "- f a \<le> -y & -y \<le> - f b", clarify)
   653 apply (drule IVT [where f = "%x. - f x"], assumption)
   654 apply simp_all
   655 done
   656 
   657 (*HOL style here: object-level formulations*)
   658 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
   659       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   660       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   661 apply (blast intro: IVT)
   662 done
   663 
   664 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
   665       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   666       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   667 apply (blast intro: IVT2)
   668 done
   669 
   670 
   671 subsection {* Boundedness of continuous functions *}
   672 
   673 text{*By bisection, function continuous on closed interval is bounded above*}
   674 
   675 lemma isCont_bounded:
   676      "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   677       ==> \<exists>M::real. \<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M"
   678 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> (\<exists>M. \<forall>x. u \<le> x & x \<le> v --> f x \<le> M)" in lemma_BOLZANO2)
   679 apply safe
   680 apply simp_all
   681 apply (rename_tac x xa ya M Ma)
   682 apply (metis linorder_not_less order_le_less order_trans)
   683 apply (case_tac "a \<le> x & x \<le> b")
   684  prefer 2
   685  apply (rule_tac x = 1 in exI, force)
   686 apply (simp add: LIM_eq isCont_iff)
   687 apply (drule_tac x = x in spec, auto)
   688 apply (erule_tac V = "\<forall>M. \<exists>x. a \<le> x & x \<le> b & ~ f x \<le> M" in thin_rl)
   689 apply (drule_tac x = 1 in spec, auto)
   690 apply (rule_tac x = s in exI, clarify)
   691 apply (rule_tac x = "\<bar>f x\<bar> + 1" in exI, clarify)
   692 apply (drule_tac x = "xa-x" in spec)
   693 apply (auto simp add: abs_ge_self)
   694 done
   695 
   696 text{*Refine the above to existence of least upper bound*}
   697 
   698 lemma lemma_reals_complete: "((\<exists>x. x \<in> S) & (\<exists>y. isUb UNIV S (y::real))) -->
   699       (\<exists>t. isLub UNIV S t)"
   700 by (blast intro: reals_complete)
   701 
   702 lemma isCont_has_Ub: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   703          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M) &
   704                    (\<forall>N. N < M --> (\<exists>x. a \<le> x & x \<le> b & N < f(x)))"
   705 apply (cut_tac S = "Collect (%y. \<exists>x. a \<le> x & x \<le> b & y = f x)"
   706         in lemma_reals_complete)
   707 apply auto
   708 apply (drule isCont_bounded, assumption)
   709 apply (auto simp add: isUb_def leastP_def isLub_def setge_def setle_def)
   710 apply (rule exI, auto)
   711 apply (auto dest!: spec simp add: linorder_not_less)
   712 done
   713 
   714 text{*Now show that it attains its upper bound*}
   715 
   716 lemma isCont_eq_Ub:
   717   assumes le: "a \<le> b"
   718       and con: "\<forall>x::real. a \<le> x & x \<le> b --> isCont f x"
   719   shows "\<exists>M::real. (\<forall>x. a \<le> x & x \<le> b --> f(x) \<le> M) &
   720              (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   721 proof -
   722   from isCont_has_Ub [OF le con]
   723   obtain M where M1: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
   724              and M2: "!!N. N<M ==> \<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x"  by blast
   725   show ?thesis
   726   proof (intro exI, intro conjI)
   727     show " \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M" by (rule M1)
   728     show "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M"
   729     proof (rule ccontr)
   730       assume "\<not> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
   731       with M1 have M3: "\<forall>x. a \<le> x & x \<le> b --> f x < M"
   732         by (fastforce simp add: linorder_not_le [symmetric])
   733       hence "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. inverse (M - f x)) x"
   734         by (auto simp add: con)
   735       from isCont_bounded [OF le this]
   736       obtain k where k: "!!x. a \<le> x & x \<le> b --> inverse (M - f x) \<le> k" by auto
   737       have Minv: "!!x. a \<le> x & x \<le> b --> 0 < inverse (M - f (x))"
   738         by (simp add: M3 algebra_simps)
   739       have "!!x. a \<le> x & x \<le> b --> inverse (M - f x) < k+1" using k
   740         by (auto intro: order_le_less_trans [of _ k])
   741       with Minv
   742       have "!!x. a \<le> x & x \<le> b --> inverse(k+1) < inverse(inverse(M - f x))"
   743         by (intro strip less_imp_inverse_less, simp_all)
   744       hence invlt: "!!x. a \<le> x & x \<le> b --> inverse(k+1) < M - f x"
   745         by simp
   746       have "M - inverse (k+1) < M" using k [of a] Minv [of a] le
   747         by (simp, arith)
   748       from M2 [OF this]
   749       obtain x where ax: "a \<le> x & x \<le> b & M - inverse(k+1) < f x" ..
   750       thus False using invlt [of x] by force
   751     qed
   752   qed
   753 qed
   754 
   755 
   756 text{*Same theorem for lower bound*}
   757 
   758 lemma isCont_eq_Lb: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   759          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> M \<le> f(x)) &
   760                    (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   761 apply (subgoal_tac "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. - (f x)) x")
   762 prefer 2 apply (blast intro: isCont_minus)
   763 apply (drule_tac f = "(%x. - (f x))" in isCont_eq_Ub)
   764 apply safe
   765 apply auto
   766 done
   767 
   768 
   769 text{*Another version.*}
   770 
   771 lemma isCont_Lb_Ub: "[|a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   772       ==> \<exists>L M::real. (\<forall>x::real. a \<le> x & x \<le> b --> L \<le> f(x) & f(x) \<le> M) &
   773           (\<forall>y. L \<le> y & y \<le> M --> (\<exists>x. a \<le> x & x \<le> b & (f(x) = y)))"
   774 apply (frule isCont_eq_Lb)
   775 apply (frule_tac [2] isCont_eq_Ub)
   776 apply (assumption+, safe)
   777 apply (rule_tac x = "f x" in exI)
   778 apply (rule_tac x = "f xa" in exI, simp, safe)
   779 apply (cut_tac x = x and y = xa in linorder_linear, safe)
   780 apply (cut_tac f = f and a = x and b = xa and y = y in IVT_objl)
   781 apply (cut_tac [2] f = f and a = xa and b = x and y = y in IVT2_objl, safe)
   782 apply (rule_tac [2] x = xb in exI)
   783 apply (rule_tac [4] x = xb in exI, simp_all)
   784 done
   785 
   786 
   787 subsection {* Local extrema *}
   788 
   789 text{*If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right*}
   790 
   791 lemma DERIV_pos_inc_right:
   792   fixes f :: "real => real"
   793   assumes der: "DERIV f x :> l"
   794       and l:   "0 < l"
   795   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   796 proof -
   797   from l der [THEN DERIV_D, THEN LIM_D [where r = "l"]]
   798   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l)"
   799     by (simp add: diff_minus)
   800   then obtain s
   801         where s:   "0 < s"
   802           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l"
   803     by auto
   804   thus ?thesis
   805   proof (intro exI conjI strip)
   806     show "0<s" using s .
   807     fix h::real
   808     assume "0 < h" "h < s"
   809     with all [of h] show "f x < f (x+h)"
   810     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   811     split add: split_if_asm)
   812       assume "~ (f (x+h) - f x) / h < l" and h: "0 < h"
   813       with l
   814       have "0 < (f (x+h) - f x) / h" by arith
   815       thus "f x < f (x+h)"
   816   by (simp add: pos_less_divide_eq h)
   817     qed
   818   qed
   819 qed
   820 
   821 lemma DERIV_neg_dec_left:
   822   fixes f :: "real => real"
   823   assumes der: "DERIV f x :> l"
   824       and l:   "l < 0"
   825   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
   826 proof -
   827   from l der [THEN DERIV_D, THEN LIM_D [where r = "-l"]]
   828   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l)"
   829     by (simp add: diff_minus)
   830   then obtain s
   831         where s:   "0 < s"
   832           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l"
   833     by auto
   834   thus ?thesis
   835   proof (intro exI conjI strip)
   836     show "0<s" using s .
   837     fix h::real
   838     assume "0 < h" "h < s"
   839     with all [of "-h"] show "f x < f (x-h)"
   840     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   841     split add: split_if_asm)
   842       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
   843       with l
   844       have "0 < (f (x-h) - f x) / h" by arith
   845       thus "f x < f (x-h)"
   846   by (simp add: pos_less_divide_eq h)
   847     qed
   848   qed
   849 qed
   850 
   851 
   852 lemma DERIV_pos_inc_left:
   853   fixes f :: "real => real"
   854   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x - h) < f(x)"
   855   apply (rule DERIV_neg_dec_left [of "%x. - f x" x "-l", simplified])
   856   apply (auto simp add: DERIV_minus)
   857   done
   858 
   859 lemma DERIV_neg_dec_right:
   860   fixes f :: "real => real"
   861   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x) > f(x + h)"
   862   apply (rule DERIV_pos_inc_right [of "%x. - f x" x "-l", simplified])
   863   apply (auto simp add: DERIV_minus)
   864   done
   865 
   866 lemma DERIV_local_max:
   867   fixes f :: "real => real"
   868   assumes der: "DERIV f x :> l"
   869       and d:   "0 < d"
   870       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
   871   shows "l = 0"
   872 proof (cases rule: linorder_cases [of l 0])
   873   case equal thus ?thesis .
   874 next
   875   case less
   876   from DERIV_neg_dec_left [OF der less]
   877   obtain d' where d': "0 < d'"
   878              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
   879   from real_lbound_gt_zero [OF d d']
   880   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   881   with lt le [THEN spec [where x="x-e"]]
   882   show ?thesis by (auto simp add: abs_if)
   883 next
   884   case greater
   885   from DERIV_pos_inc_right [OF der greater]
   886   obtain d' where d': "0 < d'"
   887              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
   888   from real_lbound_gt_zero [OF d d']
   889   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   890   with lt le [THEN spec [where x="x+e"]]
   891   show ?thesis by (auto simp add: abs_if)
   892 qed
   893 
   894 
   895 text{*Similar theorem for a local minimum*}
   896 lemma DERIV_local_min:
   897   fixes f :: "real => real"
   898   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
   899 by (drule DERIV_minus [THEN DERIV_local_max], auto)
   900 
   901 
   902 text{*In particular, if a function is locally flat*}
   903 lemma DERIV_local_const:
   904   fixes f :: "real => real"
   905   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
   906 by (auto dest!: DERIV_local_max)
   907 
   908 
   909 subsection {* Rolle's Theorem *}
   910 
   911 text{*Lemma about introducing open ball in open interval*}
   912 lemma lemma_interval_lt:
   913      "[| a < x;  x < b |]
   914       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
   915 
   916 apply (simp add: abs_less_iff)
   917 apply (insert linorder_linear [of "x-a" "b-x"], safe)
   918 apply (rule_tac x = "x-a" in exI)
   919 apply (rule_tac [2] x = "b-x" in exI, auto)
   920 done
   921 
   922 lemma lemma_interval: "[| a < x;  x < b |] ==>
   923         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
   924 apply (drule lemma_interval_lt, auto)
   925 apply force
   926 done
   927 
   928 text{*Rolle's Theorem.
   929    If @{term f} is defined and continuous on the closed interval
   930    @{text "[a,b]"} and differentiable on the open interval @{text "(a,b)"},
   931    and @{term "f(a) = f(b)"},
   932    then there exists @{text "x0 \<in> (a,b)"} such that @{term "f'(x0) = 0"}*}
   933 theorem Rolle:
   934   assumes lt: "a < b"
   935       and eq: "f(a) = f(b)"
   936       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
   937       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
   938   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
   939 proof -
   940   have le: "a \<le> b" using lt by simp
   941   from isCont_eq_Ub [OF le con]
   942   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
   943              and alex: "a \<le> x" and xleb: "x \<le> b"
   944     by blast
   945   from isCont_eq_Lb [OF le con]
   946   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
   947               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
   948     by blast
   949   show ?thesis
   950   proof cases
   951     assume axb: "a < x & x < b"
   952         --{*@{term f} attains its maximum within the interval*}
   953     hence ax: "a<x" and xb: "x<b" by arith + 
   954     from lemma_interval [OF ax xb]
   955     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   956       by blast
   957     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
   958       by blast
   959     from differentiableD [OF dif [OF axb]]
   960     obtain l where der: "DERIV f x :> l" ..
   961     have "l=0" by (rule DERIV_local_max [OF der d bound'])
   962         --{*the derivative at a local maximum is zero*}
   963     thus ?thesis using ax xb der by auto
   964   next
   965     assume notaxb: "~ (a < x & x < b)"
   966     hence xeqab: "x=a | x=b" using alex xleb by arith
   967     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
   968     show ?thesis
   969     proof cases
   970       assume ax'b: "a < x' & x' < b"
   971         --{*@{term f} attains its minimum within the interval*}
   972       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
   973       from lemma_interval [OF ax' x'b]
   974       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   975   by blast
   976       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
   977   by blast
   978       from differentiableD [OF dif [OF ax'b]]
   979       obtain l where der: "DERIV f x' :> l" ..
   980       have "l=0" by (rule DERIV_local_min [OF der d bound'])
   981         --{*the derivative at a local minimum is zero*}
   982       thus ?thesis using ax' x'b der by auto
   983     next
   984       assume notax'b: "~ (a < x' & x' < b)"
   985         --{*@{term f} is constant througout the interval*}
   986       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
   987       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
   988       from dense [OF lt]
   989       obtain r where ar: "a < r" and rb: "r < b" by blast
   990       from lemma_interval [OF ar rb]
   991       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   992   by blast
   993       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
   994       proof (clarify)
   995         fix z::real
   996         assume az: "a \<le> z" and zb: "z \<le> b"
   997         show "f z = f b"
   998         proof (rule order_antisym)
   999           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
  1000           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
  1001         qed
  1002       qed
  1003       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
  1004       proof (intro strip)
  1005         fix y::real
  1006         assume lt: "\<bar>r-y\<bar> < d"
  1007         hence "f y = f b" by (simp add: eq_fb bound)
  1008         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
  1009       qed
  1010       from differentiableD [OF dif [OF conjI [OF ar rb]]]
  1011       obtain l where der: "DERIV f r :> l" ..
  1012       have "l=0" by (rule DERIV_local_const [OF der d bound'])
  1013         --{*the derivative of a constant function is zero*}
  1014       thus ?thesis using ar rb der by auto
  1015     qed
  1016   qed
  1017 qed
  1018 
  1019 
  1020 subsection{*Mean Value Theorem*}
  1021 
  1022 lemma lemma_MVT:
  1023      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
  1024 proof cases
  1025   assume "a=b" thus ?thesis by simp
  1026 next
  1027   assume "a\<noteq>b"
  1028   hence ba: "b-a \<noteq> 0" by arith
  1029   show ?thesis
  1030     by (rule real_mult_left_cancel [OF ba, THEN iffD1],
  1031         simp add: right_diff_distrib,
  1032         simp add: left_diff_distrib)
  1033 qed
  1034 
  1035 theorem MVT:
  1036   assumes lt:  "a < b"
  1037       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1038       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
  1039   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1040                    (f(b) - f(a) = (b-a) * l)"
  1041 proof -
  1042   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1043   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x"
  1044     using con by (fast intro: isCont_intros)
  1045   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable x"
  1046   proof (clarify)
  1047     fix x::real
  1048     assume ax: "a < x" and xb: "x < b"
  1049     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1050     obtain l where der: "DERIV f x :> l" ..
  1051     show "?F differentiable x"
  1052       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1053           blast intro: DERIV_diff DERIV_cmult_Id der)
  1054   qed
  1055   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1056   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1057     by blast
  1058   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1059     by (rule DERIV_cmult_Id)
  1060   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1061                    :> 0 + (f b - f a) / (b - a)"
  1062     by (rule DERIV_add [OF der])
  1063   show ?thesis
  1064   proof (intro exI conjI)
  1065     show "a < z" using az .
  1066     show "z < b" using zb .
  1067     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1068     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1069   qed
  1070 qed
  1071 
  1072 lemma MVT2:
  1073      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1074       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1075 apply (drule MVT)
  1076 apply (blast intro: DERIV_isCont)
  1077 apply (force dest: order_less_imp_le simp add: differentiable_def)
  1078 apply (blast dest: DERIV_unique order_less_imp_le)
  1079 done
  1080 
  1081 
  1082 text{*A function is constant if its derivative is 0 over an interval.*}
  1083 
  1084 lemma DERIV_isconst_end:
  1085   fixes f :: "real => real"
  1086   shows "[| a < b;
  1087          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1088          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1089         ==> f b = f a"
  1090 apply (drule MVT, assumption)
  1091 apply (blast intro: differentiableI)
  1092 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1093 done
  1094 
  1095 lemma DERIV_isconst1:
  1096   fixes f :: "real => real"
  1097   shows "[| a < b;
  1098          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1099          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1100         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1101 apply safe
  1102 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1103 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1104 done
  1105 
  1106 lemma DERIV_isconst2:
  1107   fixes f :: "real => real"
  1108   shows "[| a < b;
  1109          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1110          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1111          a \<le> x; x \<le> b |]
  1112         ==> f x = f a"
  1113 apply (blast dest: DERIV_isconst1)
  1114 done
  1115 
  1116 lemma DERIV_isconst3: fixes a b x y :: real
  1117   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1118   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1119   shows "f x = f y"
  1120 proof (cases "x = y")
  1121   case False
  1122   let ?a = "min x y"
  1123   let ?b = "max x y"
  1124   
  1125   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1126   proof (rule allI, rule impI)
  1127     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1128     hence "a < z" and "z < b" using `x \<in> {a <..< b}` and `y \<in> {a <..< b}` by auto
  1129     hence "z \<in> {a<..<b}" by auto
  1130     thus "DERIV f z :> 0" by (rule derivable)
  1131   qed
  1132   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1133     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1134 
  1135   have "?a < ?b" using `x \<noteq> y` by auto
  1136   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1137   show ?thesis by auto
  1138 qed auto
  1139 
  1140 lemma DERIV_isconst_all:
  1141   fixes f :: "real => real"
  1142   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1143 apply (rule linorder_cases [of x y])
  1144 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1145 done
  1146 
  1147 lemma DERIV_const_ratio_const:
  1148   fixes f :: "real => real"
  1149   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1150 apply (rule linorder_cases [of a b], auto)
  1151 apply (drule_tac [!] f = f in MVT)
  1152 apply (auto dest: DERIV_isCont DERIV_unique simp add: differentiable_def)
  1153 apply (auto dest: DERIV_unique simp add: ring_distribs diff_minus)
  1154 done
  1155 
  1156 lemma DERIV_const_ratio_const2:
  1157   fixes f :: "real => real"
  1158   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1159 apply (rule_tac c1 = "b-a" in real_mult_right_cancel [THEN iffD1])
  1160 apply (auto dest!: DERIV_const_ratio_const simp add: mult_assoc)
  1161 done
  1162 
  1163 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1164 by (simp)
  1165 
  1166 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1167 by (simp)
  1168 
  1169 text{*Gallileo's "trick": average velocity = av. of end velocities*}
  1170 
  1171 lemma DERIV_const_average:
  1172   fixes v :: "real => real"
  1173   assumes neq: "a \<noteq> (b::real)"
  1174       and der: "\<forall>x. DERIV v x :> k"
  1175   shows "v ((a + b)/2) = (v a + v b)/2"
  1176 proof (cases rule: linorder_cases [of a b])
  1177   case equal with neq show ?thesis by simp
  1178 next
  1179   case less
  1180   have "(v b - v a) / (b - a) = k"
  1181     by (rule DERIV_const_ratio_const2 [OF neq der])
  1182   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1183   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1184     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1185   ultimately show ?thesis using neq by force
  1186 next
  1187   case greater
  1188   have "(v b - v a) / (b - a) = k"
  1189     by (rule DERIV_const_ratio_const2 [OF neq der])
  1190   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1191   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1192     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1193   ultimately show ?thesis using neq by (force simp add: add_commute)
  1194 qed
  1195 
  1196 (* A function with positive derivative is increasing. 
  1197    A simple proof using the MVT, by Jeremy Avigad. And variants.
  1198 *)
  1199 lemma DERIV_pos_imp_increasing:
  1200   fixes a::real and b::real and f::"real => real"
  1201   assumes "a < b" and "\<forall>x. a \<le> x & x \<le> b --> (EX y. DERIV f x :> y & y > 0)"
  1202   shows "f a < f b"
  1203 proof (rule ccontr)
  1204   assume f: "~ f a < f b"
  1205   have "EX l z. a < z & z < b & DERIV f z :> l
  1206       & f b - f a = (b - a) * l"
  1207     apply (rule MVT)
  1208       using assms
  1209       apply auto
  1210       apply (metis DERIV_isCont)
  1211      apply (metis differentiableI less_le)
  1212     done
  1213   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1214       and "f b - f a = (b - a) * l"
  1215     by auto
  1216   with assms f have "~(l > 0)"
  1217     by (metis linorder_not_le mult_le_0_iff diff_le_0_iff_le)
  1218   with assms z show False
  1219     by (metis DERIV_unique less_le)
  1220 qed
  1221 
  1222 lemma DERIV_nonneg_imp_nondecreasing:
  1223   fixes a::real and b::real and f::"real => real"
  1224   assumes "a \<le> b" and
  1225     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<ge> 0)"
  1226   shows "f a \<le> f b"
  1227 proof (rule ccontr, cases "a = b")
  1228   assume "~ f a \<le> f b" and "a = b"
  1229   then show False by auto
  1230 next
  1231   assume A: "~ f a \<le> f b"
  1232   assume B: "a ~= b"
  1233   with assms have "EX l z. a < z & z < b & DERIV f z :> l
  1234       & f b - f a = (b - a) * l"
  1235     apply -
  1236     apply (rule MVT)
  1237       apply auto
  1238       apply (metis DERIV_isCont)
  1239      apply (metis differentiableI less_le)
  1240     done
  1241   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1242       and C: "f b - f a = (b - a) * l"
  1243     by auto
  1244   with A have "a < b" "f b < f a" by auto
  1245   with C have "\<not> l \<ge> 0" by (auto simp add: not_le algebra_simps)
  1246     (metis A add_le_cancel_right assms(1) less_eq_real_def mult_right_mono add_left_mono linear order_refl)
  1247   with assms z show False
  1248     by (metis DERIV_unique order_less_imp_le)
  1249 qed
  1250 
  1251 lemma DERIV_neg_imp_decreasing:
  1252   fixes a::real and b::real and f::"real => real"
  1253   assumes "a < b" and
  1254     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y < 0)"
  1255   shows "f a > f b"
  1256 proof -
  1257   have "(%x. -f x) a < (%x. -f x) b"
  1258     apply (rule DERIV_pos_imp_increasing [of a b "%x. -f x"])
  1259     using assms
  1260     apply auto
  1261     apply (metis DERIV_minus neg_0_less_iff_less)
  1262     done
  1263   thus ?thesis
  1264     by simp
  1265 qed
  1266 
  1267 lemma DERIV_nonpos_imp_nonincreasing:
  1268   fixes a::real and b::real and f::"real => real"
  1269   assumes "a \<le> b" and
  1270     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<le> 0)"
  1271   shows "f a \<ge> f b"
  1272 proof -
  1273   have "(%x. -f x) a \<le> (%x. -f x) b"
  1274     apply (rule DERIV_nonneg_imp_nondecreasing [of a b "%x. -f x"])
  1275     using assms
  1276     apply auto
  1277     apply (metis DERIV_minus neg_0_le_iff_le)
  1278     done
  1279   thus ?thesis
  1280     by simp
  1281 qed
  1282 
  1283 subsection {* Continuous injective functions *}
  1284 
  1285 text{*Dull lemma: an continuous injection on an interval must have a
  1286 strict maximum at an end point, not in the middle.*}
  1287 
  1288 lemma lemma_isCont_inj:
  1289   fixes f :: "real \<Rightarrow> real"
  1290   assumes d: "0 < d"
  1291       and inj [rule_format]: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1292       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1293   shows "\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z"
  1294 proof (rule ccontr)
  1295   assume  "~ (\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z)"
  1296   hence all [rule_format]: "\<forall>z. \<bar>z - x\<bar> \<le> d --> f z \<le> f x" by auto
  1297   show False
  1298   proof (cases rule: linorder_le_cases [of "f(x-d)" "f(x+d)"])
  1299     case le
  1300     from d cont all [of "x+d"]
  1301     have flef: "f(x+d) \<le> f x"
  1302      and xlex: "x - d \<le> x"
  1303      and cont': "\<forall>z. x - d \<le> z \<and> z \<le> x \<longrightarrow> isCont f z"
  1304        by (auto simp add: abs_if)
  1305     from IVT [OF le flef xlex cont']
  1306     obtain x' where "x-d \<le> x'" "x' \<le> x" "f x' = f(x+d)" by blast
  1307     moreover
  1308     hence "g(f x') = g (f(x+d))" by simp
  1309     ultimately show False using d inj [of x'] inj [of "x+d"]
  1310       by (simp add: abs_le_iff)
  1311   next
  1312     case ge
  1313     from d cont all [of "x-d"]
  1314     have flef: "f(x-d) \<le> f x"
  1315      and xlex: "x \<le> x+d"
  1316      and cont': "\<forall>z. x \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z"
  1317        by (auto simp add: abs_if)
  1318     from IVT2 [OF ge flef xlex cont']
  1319     obtain x' where "x \<le> x'" "x' \<le> x+d" "f x' = f(x-d)" by blast
  1320     moreover
  1321     hence "g(f x') = g (f(x-d))" by simp
  1322     ultimately show False using d inj [of x'] inj [of "x-d"]
  1323       by (simp add: abs_le_iff)
  1324   qed
  1325 qed
  1326 
  1327 
  1328 text{*Similar version for lower bound.*}
  1329 
  1330 lemma lemma_isCont_inj2:
  1331   fixes f g :: "real \<Rightarrow> real"
  1332   shows "[|0 < d; \<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z;
  1333         \<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z |]
  1334       ==> \<exists>z. \<bar>z-x\<bar> \<le> d & f z < f x"
  1335 apply (insert lemma_isCont_inj
  1336           [where f = "%x. - f x" and g = "%y. g(-y)" and x = x and d = d])
  1337 apply (simp add: linorder_not_le)
  1338 done
  1339 
  1340 text{*Show there's an interval surrounding @{term "f(x)"} in
  1341 @{text "f[[x - d, x + d]]"} .*}
  1342 
  1343 lemma isCont_inj_range:
  1344   fixes f :: "real \<Rightarrow> real"
  1345   assumes d: "0 < d"
  1346       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1347       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1348   shows "\<exists>e>0. \<forall>y. \<bar>y - f x\<bar> \<le> e --> (\<exists>z. \<bar>z-x\<bar> \<le> d & f z = y)"
  1349 proof -
  1350   have "x-d \<le> x+d" "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z" using cont d
  1351     by (auto simp add: abs_le_iff)
  1352   from isCont_Lb_Ub [OF this]
  1353   obtain L M
  1354   where all1 [rule_format]: "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> L \<le> f z \<and> f z \<le> M"
  1355     and all2 [rule_format]:
  1356            "\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>z. x-d \<le> z \<and> z \<le> x+d \<and> f z = y)"
  1357     by auto
  1358   with d have "L \<le> f x & f x \<le> M" by simp
  1359   moreover have "L \<noteq> f x"
  1360   proof -
  1361     from lemma_isCont_inj2 [OF d inj cont]
  1362     obtain u where "\<bar>u - x\<bar> \<le> d" "f u < f x"  by auto
  1363     thus ?thesis using all1 [of u] by arith
  1364   qed
  1365   moreover have "f x \<noteq> M"
  1366   proof -
  1367     from lemma_isCont_inj [OF d inj cont]
  1368     obtain u where "\<bar>u - x\<bar> \<le> d" "f x < f u"  by auto
  1369     thus ?thesis using all1 [of u] by arith
  1370   qed
  1371   ultimately have "L < f x & f x < M" by arith
  1372   hence "0 < f x - L" "0 < M - f x" by arith+
  1373   from real_lbound_gt_zero [OF this]
  1374   obtain e where e: "0 < e" "e < f x - L" "e < M - f x" by auto
  1375   thus ?thesis
  1376   proof (intro exI conjI)
  1377     show "0<e" using e(1) .
  1378     show "\<forall>y. \<bar>y - f x\<bar> \<le> e \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y)"
  1379     proof (intro strip)
  1380       fix y::real
  1381       assume "\<bar>y - f x\<bar> \<le> e"
  1382       with e have "L \<le> y \<and> y \<le> M" by arith
  1383       from all2 [OF this]
  1384       obtain z where "x - d \<le> z" "z \<le> x + d" "f z = y" by blast
  1385       thus "\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y" 
  1386         by (force simp add: abs_le_iff)
  1387     qed
  1388   qed
  1389 qed
  1390 
  1391 
  1392 text{*Continuity of inverse function*}
  1393 
  1394 lemma isCont_inverse_function:
  1395   fixes f g :: "real \<Rightarrow> real"
  1396   assumes d: "0 < d"
  1397       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1398       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1399   shows "isCont g (f x)"
  1400 proof (simp add: isCont_iff LIM_eq)
  1401   show "\<forall>r. 0 < r \<longrightarrow>
  1402          (\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r)"
  1403   proof (intro strip)
  1404     fix r::real
  1405     assume r: "0<r"
  1406     from real_lbound_gt_zero [OF r d]
  1407     obtain e where e: "0 < e" and e_lt: "e < r \<and> e < d" by blast
  1408     with inj cont
  1409     have e_simps: "\<forall>z. \<bar>z-x\<bar> \<le> e --> g (f z) = z"
  1410                   "\<forall>z. \<bar>z-x\<bar> \<le> e --> isCont f z"   by auto
  1411     from isCont_inj_range [OF e this]
  1412     obtain e' where e': "0 < e'"
  1413         and all: "\<forall>y. \<bar>y - f x\<bar> \<le> e' \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> e \<and> f z = y)"
  1414           by blast
  1415     show "\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r"
  1416     proof (intro exI conjI)
  1417       show "0<e'" using e' .
  1418       show "\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < e' \<longrightarrow> \<bar>g (f x + z) - g (f x)\<bar> < r"
  1419       proof (intro strip)
  1420         fix z::real
  1421         assume z: "z \<noteq> 0 \<and> \<bar>z\<bar> < e'"
  1422         with e e_lt e_simps all [rule_format, of "f x + z"]
  1423         show "\<bar>g (f x + z) - g (f x)\<bar> < r" by force
  1424       qed
  1425     qed
  1426   qed
  1427 qed
  1428 
  1429 text {* Derivative of inverse function *}
  1430 
  1431 lemma DERIV_inverse_function:
  1432   fixes f g :: "real \<Rightarrow> real"
  1433   assumes der: "DERIV f (g x) :> D"
  1434   assumes neq: "D \<noteq> 0"
  1435   assumes a: "a < x" and b: "x < b"
  1436   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1437   assumes cont: "isCont g x"
  1438   shows "DERIV g x :> inverse D"
  1439 unfolding DERIV_iff2
  1440 proof (rule LIM_equal2)
  1441   show "0 < min (x - a) (b - x)"
  1442     using a b by arith 
  1443 next
  1444   fix y
  1445   assume "norm (y - x) < min (x - a) (b - x)"
  1446   hence "a < y" and "y < b" 
  1447     by (simp_all add: abs_less_iff)
  1448   thus "(g y - g x) / (y - x) =
  1449         inverse ((f (g y) - x) / (g y - g x))"
  1450     by (simp add: inj)
  1451 next
  1452   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) -- g x --> D"
  1453     by (rule der [unfolded DERIV_iff2])
  1454   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) -- g x --> D"
  1455     using inj a b by simp
  1456   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1457   proof (safe intro!: exI)
  1458     show "0 < min (x - a) (b - x)"
  1459       using a b by simp
  1460   next
  1461     fix y
  1462     assume "norm (y - x) < min (x - a) (b - x)"
  1463     hence y: "a < y" "y < b"
  1464       by (simp_all add: abs_less_iff)
  1465     assume "g y = g x"
  1466     hence "f (g y) = f (g x)" by simp
  1467     hence "y = x" using inj y a b by simp
  1468     also assume "y \<noteq> x"
  1469     finally show False by simp
  1470   qed
  1471   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) -- x --> D"
  1472     using cont 1 2 by (rule isCont_LIM_compose2)
  1473   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1474         -- x --> inverse D"
  1475     using neq by (rule tendsto_inverse)
  1476 qed
  1477 
  1478 
  1479 subsection {* Generalized Mean Value Theorem *}
  1480 
  1481 theorem GMVT:
  1482   fixes a b :: real
  1483   assumes alb: "a < b"
  1484     and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1485     and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable x"
  1486     and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1487     and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable x"
  1488   shows "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1489 proof -
  1490   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1491   from assms have "a < b" by simp
  1492   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1493     using fc gc by simp
  1494   moreover have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable x"
  1495     using fd gd by simp
  1496   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1497   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1498   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1499 
  1500   from cdef have cint: "a < c \<and> c < b" by auto
  1501   with gd have "g differentiable c" by simp
  1502   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1503   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1504 
  1505   from cdef have "a < c \<and> c < b" by auto
  1506   with fd have "f differentiable c" by simp
  1507   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1508   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1509 
  1510   from cdef have "DERIV ?h c :> l" by auto
  1511   moreover have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1512     using g'cdef f'cdef by (auto intro!: DERIV_intros)
  1513   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1514 
  1515   {
  1516     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1517     also with leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1518     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1519   }
  1520   moreover
  1521   {
  1522     have "?h b - ?h a =
  1523          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1524           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1525       by (simp add: algebra_simps)
  1526     hence "?h b - ?h a = 0" by auto
  1527   }
  1528   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1529   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1530   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1531   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: mult_ac)
  1532 
  1533   with g'cdef f'cdef cint show ?thesis by auto
  1534 qed
  1535 
  1536 
  1537 subsection {* Theorems about Limits *}
  1538 
  1539 (* need to rename second isCont_inverse *)
  1540 
  1541 lemma isCont_inv_fun:
  1542   fixes f g :: "real \<Rightarrow> real"
  1543   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1544          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1545       ==> isCont g (f x)"
  1546 by (rule isCont_inverse_function)
  1547 
  1548 lemma isCont_inv_fun_inv:
  1549   fixes f g :: "real \<Rightarrow> real"
  1550   shows "[| 0 < d;  
  1551          \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1552          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1553        ==> \<exists>e. 0 < e &  
  1554              (\<forall>y. 0 < \<bar>y - f(x)\<bar> & \<bar>y - f(x)\<bar> < e --> f(g(y)) = y)"
  1555 apply (drule isCont_inj_range)
  1556 prefer 2 apply (assumption, assumption, auto)
  1557 apply (rule_tac x = e in exI, auto)
  1558 apply (rotate_tac 2)
  1559 apply (drule_tac x = y in spec, auto)
  1560 done
  1561 
  1562 
  1563 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1564 lemma LIM_fun_gt_zero:
  1565      "[| f -- c --> (l::real); 0 < l |]  
  1566          ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> 0 < f x)"
  1567 apply (drule (1) LIM_D, clarify)
  1568 apply (rule_tac x = s in exI)
  1569 apply (simp add: abs_less_iff)
  1570 done
  1571 
  1572 lemma LIM_fun_less_zero:
  1573      "[| f -- c --> (l::real); l < 0 |]  
  1574       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x < 0)"
  1575 apply (drule LIM_D [where r="-l"], simp, clarify)
  1576 apply (rule_tac x = s in exI)
  1577 apply (simp add: abs_less_iff)
  1578 done
  1579 
  1580 lemma LIM_fun_not_zero:
  1581      "[| f -- c --> (l::real); l \<noteq> 0 |] 
  1582       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x \<noteq> 0)"
  1583 apply (rule linorder_cases [of l 0])
  1584 apply (drule (1) LIM_fun_less_zero, force)
  1585 apply simp
  1586 apply (drule (1) LIM_fun_gt_zero, force)
  1587 done
  1588 
  1589 lemma GMVT':
  1590   fixes f g :: "real \<Rightarrow> real"
  1591   assumes "a < b"
  1592   assumes isCont_f: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont f z"
  1593   assumes isCont_g: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont g z"
  1594   assumes DERIV_g: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV g z :> (g' z)"
  1595   assumes DERIV_f: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV f z :> (f' z)"
  1596   shows "\<exists>c. a < c \<and> c < b \<and> (f b - f a) * g' c = (g b - g a) * f' c"
  1597 proof -
  1598   have "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and>
  1599     a < c \<and> c < b \<and> (f b - f a) * g'c = (g b - g a) * f'c"
  1600     using assms by (intro GMVT) (force simp: differentiable_def)+
  1601   then obtain c where "a < c" "c < b" "(f b - f a) * g' c = (g b - g a) * f' c"
  1602     using DERIV_f DERIV_g by (force dest: DERIV_unique)
  1603   then show ?thesis
  1604     by auto
  1605 qed
  1606 
  1607 lemma DERIV_cong_ev: "x = y \<Longrightarrow> eventually (\<lambda>x. f x = g x) (nhds x) \<Longrightarrow> u = v \<Longrightarrow>
  1608     DERIV f x :> u \<longleftrightarrow> DERIV g y :> v"
  1609   unfolding DERIV_iff2
  1610 proof (rule filterlim_cong)
  1611   assume "eventually (\<lambda>x. f x = g x) (nhds x)"
  1612   moreover then have "f x = g x" by (auto simp: eventually_nhds)
  1613   moreover assume "x = y" "u = v"
  1614   ultimately show "eventually (\<lambda>xa. (f xa - f x) / (xa - x) = (g xa - g y) / (xa - y)) (at x)"
  1615     by (auto simp: eventually_within at_def elim: eventually_elim1)
  1616 qed simp_all
  1617 
  1618 lemma DERIV_shift:
  1619   "(DERIV f (x + z) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (x + z)) x :> y)"
  1620   by (simp add: DERIV_iff field_simps)
  1621 
  1622 lemma DERIV_mirror:
  1623   "(DERIV f (- x) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (- x::real) :: real) x :> - y)"
  1624   by (simp add: deriv_def filterlim_at_split filterlim_at_left_to_right
  1625                 tendsto_minus_cancel_left field_simps conj_commute)
  1626 
  1627 lemma lhopital_right_0:
  1628   fixes f0 g0 :: "real \<Rightarrow> real"
  1629   assumes f_0: "(f0 ---> 0) (at_right 0)"
  1630   assumes g_0: "(g0 ---> 0) (at_right 0)"
  1631   assumes ev:
  1632     "eventually (\<lambda>x. g0 x \<noteq> 0) (at_right 0)"
  1633     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1634     "eventually (\<lambda>x. DERIV f0 x :> f' x) (at_right 0)"
  1635     "eventually (\<lambda>x. DERIV g0 x :> g' x) (at_right 0)"
  1636   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) (at_right 0)"
  1637   shows "((\<lambda> x. f0 x / g0 x) ---> x) (at_right 0)"
  1638 proof -
  1639   def f \<equiv> "\<lambda>x. if x \<le> 0 then 0 else f0 x"
  1640   then have "f 0 = 0" by simp
  1641 
  1642   def g \<equiv> "\<lambda>x. if x \<le> 0 then 0 else g0 x"
  1643   then have "g 0 = 0" by simp
  1644 
  1645   have "eventually (\<lambda>x. g0 x \<noteq> 0 \<and> g' x \<noteq> 0 \<and>
  1646       DERIV f0 x :> (f' x) \<and> DERIV g0 x :> (g' x)) (at_right 0)"
  1647     using ev by eventually_elim auto
  1648   then obtain a where [arith]: "0 < a"
  1649     and g0_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g0 x \<noteq> 0"
  1650     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1651     and f0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV f0 x :> (f' x)"
  1652     and g0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV g0 x :> (g' x)"
  1653     unfolding eventually_within eventually_at by (auto simp: dist_real_def)
  1654 
  1655   have g_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g x \<noteq> 0"
  1656     using g0_neq_0 by (simp add: g_def)
  1657 
  1658   { fix x assume x: "0 < x" "x < a" then have "DERIV f x :> (f' x)"
  1659       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ f0[OF x]])
  1660          (auto simp: f_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1661   note f = this
  1662 
  1663   { fix x assume x: "0 < x" "x < a" then have "DERIV g x :> (g' x)"
  1664       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ g0[OF x]])
  1665          (auto simp: g_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1666   note g = this
  1667 
  1668   have "isCont f 0"
  1669     using tendsto_const[of "0::real" "at 0"] f_0
  1670     unfolding isCont_def f_def
  1671     by (intro filterlim_split_at_real)
  1672        (auto elim: eventually_elim1
  1673              simp add: filterlim_def le_filter_def eventually_within eventually_filtermap)
  1674     
  1675   have "isCont g 0"
  1676     using tendsto_const[of "0::real" "at 0"] g_0
  1677     unfolding isCont_def g_def
  1678     by (intro filterlim_split_at_real)
  1679        (auto elim: eventually_elim1
  1680              simp add: filterlim_def le_filter_def eventually_within eventually_filtermap)
  1681 
  1682   have "\<exists>\<zeta>. \<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)"
  1683   proof (rule bchoice, rule)
  1684     fix x assume "x \<in> {0 <..< a}"
  1685     then have x[arith]: "0 < x" "x < a" by auto
  1686     with g'_neq_0 g_neq_0 `g 0 = 0` have g': "\<And>x. 0 < x \<Longrightarrow> x < a  \<Longrightarrow> 0 \<noteq> g' x" "g 0 \<noteq> g x"
  1687       by auto
  1688     have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont f x"
  1689       using `isCont f 0` f by (auto intro: DERIV_isCont simp: le_less)
  1690     moreover have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont g x"
  1691       using `isCont g 0` g by (auto intro: DERIV_isCont simp: le_less)
  1692     ultimately have "\<exists>c. 0 < c \<and> c < x \<and> (f x - f 0) * g' c = (g x - g 0) * f' c"
  1693       using f g `x < a` by (intro GMVT') auto
  1694     then guess c ..
  1695     moreover
  1696     with g'(1)[of c] g'(2) have "(f x - f 0)  / (g x - g 0) = f' c / g' c"
  1697       by (simp add: field_simps)
  1698     ultimately show "\<exists>y. 0 < y \<and> y < x \<and> f x / g x = f' y / g' y"
  1699       using `f 0 = 0` `g 0 = 0` by (auto intro!: exI[of _ c])
  1700   qed
  1701   then guess \<zeta> ..
  1702   then have \<zeta>: "eventually (\<lambda>x. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)) (at_right 0)"
  1703     unfolding eventually_within eventually_at by (intro exI[of _ a]) (auto simp: dist_real_def)
  1704   moreover
  1705   from \<zeta> have "eventually (\<lambda>x. norm (\<zeta> x) \<le> x) (at_right 0)"
  1706     by eventually_elim auto
  1707   then have "((\<lambda>x. norm (\<zeta> x)) ---> 0) (at_right 0)"
  1708     by (rule_tac real_tendsto_sandwich[where f="\<lambda>x. 0" and h="\<lambda>x. x"])
  1709        (auto intro: tendsto_const tendsto_ident_at_within)
  1710   then have "(\<zeta> ---> 0) (at_right 0)"
  1711     by (rule tendsto_norm_zero_cancel)
  1712   with \<zeta> have "filterlim \<zeta> (at_right 0) (at_right 0)"
  1713     by (auto elim!: eventually_elim1 simp: filterlim_within filterlim_at)
  1714   from this lim have "((\<lambda>t. f' (\<zeta> t) / g' (\<zeta> t)) ---> x) (at_right 0)"
  1715     by (rule_tac filterlim_compose[of _ _ _ \<zeta>])
  1716   ultimately have "((\<lambda>t. f t / g t) ---> x) (at_right 0)" (is ?P)
  1717     by (rule_tac filterlim_cong[THEN iffD1, OF refl refl])
  1718        (auto elim: eventually_elim1)
  1719   also have "?P \<longleftrightarrow> ?thesis"
  1720     by (rule filterlim_cong) (auto simp: f_def g_def eventually_within)
  1721   finally show ?thesis .
  1722 qed
  1723 
  1724 lemma lhopital_right:
  1725   "((f::real \<Rightarrow> real) ---> 0) (at_right x) \<Longrightarrow> (g ---> 0) (at_right x) \<Longrightarrow>
  1726     eventually (\<lambda>x. g x \<noteq> 0) (at_right x) \<Longrightarrow>
  1727     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1728     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1729     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1730     ((\<lambda> x. (f' x / g' x)) ---> y) (at_right x) \<Longrightarrow>
  1731   ((\<lambda> x. f x / g x) ---> y) (at_right x)"
  1732   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1733   by (rule lhopital_right_0)
  1734 
  1735 lemma lhopital_left:
  1736   "((f::real \<Rightarrow> real) ---> 0) (at_left x) \<Longrightarrow> (g ---> 0) (at_left x) \<Longrightarrow>
  1737     eventually (\<lambda>x. g x \<noteq> 0) (at_left x) \<Longrightarrow>
  1738     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1739     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1740     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1741     ((\<lambda> x. (f' x / g' x)) ---> y) (at_left x) \<Longrightarrow>
  1742   ((\<lambda> x. f x / g x) ---> y) (at_left x)"
  1743   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1744   by (rule lhopital_right[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1745 
  1746 lemma lhopital:
  1747   "((f::real \<Rightarrow> real) ---> 0) (at x) \<Longrightarrow> (g ---> 0) (at x) \<Longrightarrow>
  1748     eventually (\<lambda>x. g x \<noteq> 0) (at x) \<Longrightarrow>
  1749     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1750     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1751     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1752     ((\<lambda> x. (f' x / g' x)) ---> y) (at x) \<Longrightarrow>
  1753   ((\<lambda> x. f x / g x) ---> y) (at x)"
  1754   unfolding eventually_at_split filterlim_at_split
  1755   by (auto intro!: lhopital_right[of f x g g' f'] lhopital_left[of f x g g' f'])
  1756 
  1757 lemma lhopital_right_0_at_top:
  1758   fixes f g :: "real \<Rightarrow> real"
  1759   assumes g_0: "LIM x at_right 0. g x :> at_top"
  1760   assumes ev:
  1761     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1762     "eventually (\<lambda>x. DERIV f x :> f' x) (at_right 0)"
  1763     "eventually (\<lambda>x. DERIV g x :> g' x) (at_right 0)"
  1764   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) (at_right 0)"
  1765   shows "((\<lambda> x. f x / g x) ---> x) (at_right 0)"
  1766   unfolding tendsto_iff
  1767 proof safe
  1768   fix e :: real assume "0 < e"
  1769 
  1770   with lim[unfolded tendsto_iff, rule_format, of "e / 4"]
  1771   have "eventually (\<lambda>t. dist (f' t / g' t) x < e / 4) (at_right 0)" by simp
  1772   from eventually_conj[OF eventually_conj[OF ev(1) ev(2)] eventually_conj[OF ev(3) this]]
  1773   obtain a where [arith]: "0 < a"
  1774     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1775     and f0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV f x :> (f' x)"
  1776     and g0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV g x :> (g' x)"
  1777     and Df: "\<And>t. 0 < t \<Longrightarrow> t < a \<Longrightarrow> dist (f' t / g' t) x < e / 4"
  1778     unfolding eventually_within_le by (auto simp: dist_real_def)
  1779 
  1780   from Df have
  1781     "eventually (\<lambda>t. t < a) (at_right 0)" "eventually (\<lambda>t::real. 0 < t) (at_right 0)"
  1782     unfolding eventually_within eventually_at by (auto intro!: exI[of _ a] simp: dist_real_def)
  1783 
  1784   moreover
  1785   have "eventually (\<lambda>t. 0 < g t) (at_right 0)" "eventually (\<lambda>t. g a < g t) (at_right 0)"
  1786     using g_0 by (auto elim: eventually_elim1 simp: filterlim_at_top_dense)
  1787 
  1788   moreover
  1789   have inv_g: "((\<lambda>x. inverse (g x)) ---> 0) (at_right 0)"
  1790     using tendsto_inverse_0 filterlim_mono[OF g_0 at_top_le_at_infinity order_refl]
  1791     by (rule filterlim_compose)
  1792   then have "((\<lambda>x. norm (1 - g a * inverse (g x))) ---> norm (1 - g a * 0)) (at_right 0)"
  1793     by (intro tendsto_intros)
  1794   then have "((\<lambda>x. norm (1 - g a / g x)) ---> 1) (at_right 0)"
  1795     by (simp add: inverse_eq_divide)
  1796   from this[unfolded tendsto_iff, rule_format, of 1]
  1797   have "eventually (\<lambda>x. norm (1 - g a / g x) < 2) (at_right 0)"
  1798     by (auto elim!: eventually_elim1 simp: dist_real_def)
  1799 
  1800   moreover
  1801   from inv_g have "((\<lambda>t. norm ((f a - x * g a) * inverse (g t))) ---> norm ((f a - x * g a) * 0)) (at_right 0)"
  1802     by (intro tendsto_intros)
  1803   then have "((\<lambda>t. norm (f a - x * g a) / norm (g t)) ---> 0) (at_right 0)"
  1804     by (simp add: inverse_eq_divide)
  1805   from this[unfolded tendsto_iff, rule_format, of "e / 2"] `0 < e`
  1806   have "eventually (\<lambda>t. norm (f a - x * g a) / norm (g t) < e / 2) (at_right 0)"
  1807     by (auto simp: dist_real_def)
  1808 
  1809   ultimately show "eventually (\<lambda>t. dist (f t / g t) x < e) (at_right 0)"
  1810   proof eventually_elim
  1811     fix t assume t[arith]: "0 < t" "t < a" "g a < g t" "0 < g t"
  1812     assume ineq: "norm (1 - g a / g t) < 2" "norm (f a - x * g a) / norm (g t) < e / 2"
  1813 
  1814     have "\<exists>y. t < y \<and> y < a \<and> (g a - g t) * f' y = (f a - f t) * g' y"
  1815       using f0 g0 t(1,2) by (intro GMVT') (force intro!: DERIV_isCont)+
  1816     then guess y ..
  1817     from this
  1818     have [arith]: "t < y" "y < a" and D_eq: "(f t - f a) / (g t - g a) = f' y / g' y"
  1819       using `g a < g t` g'_neq_0[of y] by (auto simp add: field_simps)
  1820 
  1821     have *: "f t / g t - x = ((f t - f a) / (g t - g a) - x) * (1 - g a / g t) + (f a - x * g a) / g t"
  1822       by (simp add: field_simps)
  1823     have "norm (f t / g t - x) \<le>
  1824         norm (((f t - f a) / (g t - g a) - x) * (1 - g a / g t)) + norm ((f a - x * g a) / g t)"
  1825       unfolding * by (rule norm_triangle_ineq)
  1826     also have "\<dots> = dist (f' y / g' y) x * norm (1 - g a / g t) + norm (f a - x * g a) / norm (g t)"
  1827       by (simp add: abs_mult D_eq dist_real_def)
  1828     also have "\<dots> < (e / 4) * 2 + e / 2"
  1829       using ineq Df[of y] `0 < e` by (intro add_le_less_mono mult_mono) auto
  1830     finally show "dist (f t / g t) x < e"
  1831       by (simp add: dist_real_def)
  1832   qed
  1833 qed
  1834 
  1835 lemma lhopital_right_at_top:
  1836   "LIM x at_right x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1837     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1838     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1839     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1840     ((\<lambda> x. (f' x / g' x)) ---> y) (at_right x) \<Longrightarrow>
  1841     ((\<lambda> x. f x / g x) ---> y) (at_right x)"
  1842   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1843   by (rule lhopital_right_0_at_top)
  1844 
  1845 lemma lhopital_left_at_top:
  1846   "LIM x at_left x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1847     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1848     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1849     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1850     ((\<lambda> x. (f' x / g' x)) ---> y) (at_left x) \<Longrightarrow>
  1851     ((\<lambda> x. f x / g x) ---> y) (at_left x)"
  1852   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1853   by (rule lhopital_right_at_top[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1854 
  1855 lemma lhopital_at_top:
  1856   "LIM x at x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1857     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1858     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1859     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1860     ((\<lambda> x. (f' x / g' x)) ---> y) (at x) \<Longrightarrow>
  1861     ((\<lambda> x. f x / g x) ---> y) (at x)"
  1862   unfolding eventually_at_split filterlim_at_split
  1863   by (auto intro!: lhopital_right_at_top[of g x g' f f'] lhopital_left_at_top[of g x g' f f'])
  1864 
  1865 lemma lhospital_at_top_at_top:
  1866   fixes f g :: "real \<Rightarrow> real"
  1867   assumes g_0: "LIM x at_top. g x :> at_top"
  1868   assumes g': "eventually (\<lambda>x. g' x \<noteq> 0) at_top"
  1869   assumes Df: "eventually (\<lambda>x. DERIV f x :> f' x) at_top"
  1870   assumes Dg: "eventually (\<lambda>x. DERIV g x :> g' x) at_top"
  1871   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) at_top"
  1872   shows "((\<lambda> x. f x / g x) ---> x) at_top"
  1873   unfolding filterlim_at_top_to_right
  1874 proof (rule lhopital_right_0_at_top)
  1875   let ?F = "\<lambda>x. f (inverse x)"
  1876   let ?G = "\<lambda>x. g (inverse x)"
  1877   let ?R = "at_right (0::real)"
  1878   let ?D = "\<lambda>f' x. f' (inverse x) * - (inverse x ^ Suc (Suc 0))"
  1879 
  1880   show "LIM x ?R. ?G x :> at_top"
  1881     using g_0 unfolding filterlim_at_top_to_right .
  1882 
  1883   show "eventually (\<lambda>x. DERIV ?G x  :> ?D g' x) ?R"
  1884     unfolding eventually_at_right_to_top
  1885     using Dg eventually_ge_at_top[where c="1::real"]
  1886     apply eventually_elim
  1887     apply (rule DERIV_cong)
  1888     apply (rule DERIV_chain'[where f=inverse])
  1889     apply (auto intro!:  DERIV_inverse)
  1890     done
  1891 
  1892   show "eventually (\<lambda>x. DERIV ?F x  :> ?D f' x) ?R"
  1893     unfolding eventually_at_right_to_top
  1894     using Df eventually_ge_at_top[where c="1::real"]
  1895     apply eventually_elim
  1896     apply (rule DERIV_cong)
  1897     apply (rule DERIV_chain'[where f=inverse])
  1898     apply (auto intro!:  DERIV_inverse)
  1899     done
  1900 
  1901   show "eventually (\<lambda>x. ?D g' x \<noteq> 0) ?R"
  1902     unfolding eventually_at_right_to_top
  1903     using g' eventually_ge_at_top[where c="1::real"]
  1904     by eventually_elim auto
  1905     
  1906   show "((\<lambda>x. ?D f' x / ?D g' x) ---> x) ?R"
  1907     unfolding filterlim_at_right_to_top
  1908     apply (intro filterlim_cong[THEN iffD2, OF refl refl _ lim])
  1909     using eventually_ge_at_top[where c="1::real"]
  1910     by eventually_elim simp
  1911 qed
  1912 
  1913 end