src/HOL/Limits.thy
author hoelzl
Thu Jan 31 11:31:27 2013 +0100 (2013-01-31)
changeset 50999 3de230ed0547
parent 50880 b22ecedde1c7
child 51022 78de6c7e8a58
permissions -rw-r--r--
introduce order topology
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Filters *}
    12 
    13 text {*
    14   This definition also allows non-proper filters.
    15 *}
    16 
    17 locale is_filter =
    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    19   assumes True: "F (\<lambda>x. True)"
    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    22 
    23 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    24 proof
    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    26 qed
    27 
    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    29   using Rep_filter [of F] by simp
    30 
    31 lemma Abs_filter_inverse':
    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    33   using assms by (simp add: Abs_filter_inverse)
    34 
    35 
    36 subsection {* Eventually *}
    37 
    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    40 
    41 lemma eventually_Abs_filter:
    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    44 
    45 lemma filter_eq_iff:
    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    48 
    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    50   unfolding eventually_def
    51   by (rule is_filter.True [OF is_filter_Rep_filter])
    52 
    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    54 proof -
    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    56   thus "eventually P F" by simp
    57 qed
    58 
    59 lemma eventually_mono:
    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    61   unfolding eventually_def
    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
    63 
    64 lemma eventually_conj:
    65   assumes P: "eventually (\<lambda>x. P x) F"
    66   assumes Q: "eventually (\<lambda>x. Q x) F"
    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    68   using assms unfolding eventually_def
    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
    70 
    71 lemma eventually_Ball_finite:
    72   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
    73   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
    74 using assms by (induct set: finite, simp, simp add: eventually_conj)
    75 
    76 lemma eventually_all_finite:
    77   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
    78   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
    79   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
    80 using eventually_Ball_finite [of UNIV P] assms by simp
    81 
    82 lemma eventually_mp:
    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    84   assumes "eventually (\<lambda>x. P x) F"
    85   shows "eventually (\<lambda>x. Q x) F"
    86 proof (rule eventually_mono)
    87   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    88   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    89     using assms by (rule eventually_conj)
    90 qed
    91 
    92 lemma eventually_rev_mp:
    93   assumes "eventually (\<lambda>x. P x) F"
    94   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    95   shows "eventually (\<lambda>x. Q x) F"
    96 using assms(2) assms(1) by (rule eventually_mp)
    97 
    98 lemma eventually_conj_iff:
    99   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   100   by (auto intro: eventually_conj elim: eventually_rev_mp)
   101 
   102 lemma eventually_elim1:
   103   assumes "eventually (\<lambda>i. P i) F"
   104   assumes "\<And>i. P i \<Longrightarrow> Q i"
   105   shows "eventually (\<lambda>i. Q i) F"
   106   using assms by (auto elim!: eventually_rev_mp)
   107 
   108 lemma eventually_elim2:
   109   assumes "eventually (\<lambda>i. P i) F"
   110   assumes "eventually (\<lambda>i. Q i) F"
   111   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   112   shows "eventually (\<lambda>i. R i) F"
   113   using assms by (auto elim!: eventually_rev_mp)
   114 
   115 lemma eventually_subst:
   116   assumes "eventually (\<lambda>n. P n = Q n) F"
   117   shows "eventually P F = eventually Q F" (is "?L = ?R")
   118 proof -
   119   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   120       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   121     by (auto elim: eventually_elim1)
   122   then show ?thesis by (auto elim: eventually_elim2)
   123 qed
   124 
   125 ML {*
   126   fun eventually_elim_tac ctxt thms thm =
   127     let
   128       val thy = Proof_Context.theory_of ctxt
   129       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   130       val raw_elim_thm =
   131         (@{thm allI} RS @{thm always_eventually})
   132         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   133         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   134       val cases_prop = prop_of (raw_elim_thm RS thm)
   135       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   136     in
   137       CASES cases (rtac raw_elim_thm 1) thm
   138     end
   139 *}
   140 
   141 method_setup eventually_elim = {*
   142   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   143 *} "elimination of eventually quantifiers"
   144 
   145 
   146 subsection {* Finer-than relation *}
   147 
   148 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   149 filter @{term F'}. *}
   150 
   151 instantiation filter :: (type) complete_lattice
   152 begin
   153 
   154 definition le_filter_def:
   155   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   156 
   157 definition
   158   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   159 
   160 definition
   161   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   162 
   163 definition
   164   "bot = Abs_filter (\<lambda>P. True)"
   165 
   166 definition
   167   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   168 
   169 definition
   170   "inf F F' = Abs_filter
   171       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   172 
   173 definition
   174   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   175 
   176 definition
   177   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   178 
   179 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   180   unfolding top_filter_def
   181   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   182 
   183 lemma eventually_bot [simp]: "eventually P bot"
   184   unfolding bot_filter_def
   185   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   186 
   187 lemma eventually_sup:
   188   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   189   unfolding sup_filter_def
   190   by (rule eventually_Abs_filter, rule is_filter.intro)
   191      (auto elim!: eventually_rev_mp)
   192 
   193 lemma eventually_inf:
   194   "eventually P (inf F F') \<longleftrightarrow>
   195    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   196   unfolding inf_filter_def
   197   apply (rule eventually_Abs_filter, rule is_filter.intro)
   198   apply (fast intro: eventually_True)
   199   apply clarify
   200   apply (intro exI conjI)
   201   apply (erule (1) eventually_conj)
   202   apply (erule (1) eventually_conj)
   203   apply simp
   204   apply auto
   205   done
   206 
   207 lemma eventually_Sup:
   208   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   209   unfolding Sup_filter_def
   210   apply (rule eventually_Abs_filter, rule is_filter.intro)
   211   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   212   done
   213 
   214 instance proof
   215   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   216   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   217     by (rule less_filter_def) }
   218   { show "F \<le> F"
   219     unfolding le_filter_def by simp }
   220   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   221     unfolding le_filter_def by simp }
   222   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   223     unfolding le_filter_def filter_eq_iff by fast }
   224   { show "F \<le> top"
   225     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   226   { show "bot \<le> F"
   227     unfolding le_filter_def by simp }
   228   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   229     unfolding le_filter_def eventually_sup by simp_all }
   230   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   231     unfolding le_filter_def eventually_sup by simp }
   232   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   233     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   234   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   235     unfolding le_filter_def eventually_inf
   236     by (auto elim!: eventually_mono intro: eventually_conj) }
   237   { assume "F \<in> S" thus "F \<le> Sup S"
   238     unfolding le_filter_def eventually_Sup by simp }
   239   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   240     unfolding le_filter_def eventually_Sup by simp }
   241   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   242     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   243   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   244     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   245 qed
   246 
   247 end
   248 
   249 lemma filter_leD:
   250   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   251   unfolding le_filter_def by simp
   252 
   253 lemma filter_leI:
   254   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   255   unfolding le_filter_def by simp
   256 
   257 lemma eventually_False:
   258   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   259   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   260 
   261 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   262   where "trivial_limit F \<equiv> F = bot"
   263 
   264 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   265   by (rule eventually_False [symmetric])
   266 
   267 
   268 subsection {* Map function for filters *}
   269 
   270 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   271   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   272 
   273 lemma eventually_filtermap:
   274   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   275   unfolding filtermap_def
   276   apply (rule eventually_Abs_filter)
   277   apply (rule is_filter.intro)
   278   apply (auto elim!: eventually_rev_mp)
   279   done
   280 
   281 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   282   by (simp add: filter_eq_iff eventually_filtermap)
   283 
   284 lemma filtermap_filtermap:
   285   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   286   by (simp add: filter_eq_iff eventually_filtermap)
   287 
   288 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   289   unfolding le_filter_def eventually_filtermap by simp
   290 
   291 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   292   by (simp add: filter_eq_iff eventually_filtermap)
   293 
   294 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   295   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   296 
   297 subsection {* Order filters *}
   298 
   299 definition at_top :: "('a::order) filter"
   300   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   301 
   302 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   303   unfolding at_top_def
   304 proof (rule eventually_Abs_filter, rule is_filter.intro)
   305   fix P Q :: "'a \<Rightarrow> bool"
   306   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   307   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   308   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   309   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   310 qed auto
   311 
   312 lemma eventually_ge_at_top:
   313   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   314   unfolding eventually_at_top_linorder by auto
   315 
   316 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::dense_linorder. \<forall>n>N. P n)"
   317   unfolding eventually_at_top_linorder
   318 proof safe
   319   fix N assume "\<forall>n\<ge>N. P n" then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   320 next
   321   fix N assume "\<forall>n>N. P n"
   322   moreover from gt_ex[of N] guess y ..
   323   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   324 qed
   325 
   326 lemma eventually_gt_at_top:
   327   "eventually (\<lambda>x. (c::_::dense_linorder) < x) at_top"
   328   unfolding eventually_at_top_dense by auto
   329 
   330 definition at_bot :: "('a::order) filter"
   331   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   332 
   333 lemma eventually_at_bot_linorder:
   334   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   335   unfolding at_bot_def
   336 proof (rule eventually_Abs_filter, rule is_filter.intro)
   337   fix P Q :: "'a \<Rightarrow> bool"
   338   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   339   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   340   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   341   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   342 qed auto
   343 
   344 lemma eventually_le_at_bot:
   345   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   346   unfolding eventually_at_bot_linorder by auto
   347 
   348 lemma eventually_at_bot_dense:
   349   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   350   unfolding eventually_at_bot_linorder
   351 proof safe
   352   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   353 next
   354   fix N assume "\<forall>n<N. P n" 
   355   moreover from lt_ex[of N] guess y ..
   356   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   357 qed
   358 
   359 lemma eventually_gt_at_bot:
   360   "eventually (\<lambda>x. x < (c::_::dense_linorder)) at_bot"
   361   unfolding eventually_at_bot_dense by auto
   362 
   363 subsection {* Sequentially *}
   364 
   365 abbreviation sequentially :: "nat filter"
   366   where "sequentially == at_top"
   367 
   368 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   369   unfolding at_top_def by simp
   370 
   371 lemma eventually_sequentially:
   372   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   373   by (rule eventually_at_top_linorder)
   374 
   375 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   376   unfolding filter_eq_iff eventually_sequentially by auto
   377 
   378 lemmas trivial_limit_sequentially = sequentially_bot
   379 
   380 lemma eventually_False_sequentially [simp]:
   381   "\<not> eventually (\<lambda>n. False) sequentially"
   382   by (simp add: eventually_False)
   383 
   384 lemma le_sequentially:
   385   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   386   unfolding le_filter_def eventually_sequentially
   387   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   388 
   389 lemma eventually_sequentiallyI:
   390   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   391   shows "eventually P sequentially"
   392 using assms by (auto simp: eventually_sequentially)
   393 
   394 
   395 subsection {* Standard filters *}
   396 
   397 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
   398   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
   399 
   400 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   401   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   402 
   403 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
   404   where "at a = nhds a within - {a}"
   405 
   406 abbreviation at_right :: "'a\<Colon>{topological_space, order} \<Rightarrow> 'a filter" where
   407   "at_right x \<equiv> at x within {x <..}"
   408 
   409 abbreviation at_left :: "'a\<Colon>{topological_space, order} \<Rightarrow> 'a filter" where
   410   "at_left x \<equiv> at x within {..< x}"
   411 
   412 definition at_infinity :: "'a::real_normed_vector filter" where
   413   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
   414 
   415 lemma eventually_within:
   416   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
   417   unfolding within_def
   418   by (rule eventually_Abs_filter, rule is_filter.intro)
   419      (auto elim!: eventually_rev_mp)
   420 
   421 lemma within_UNIV [simp]: "F within UNIV = F"
   422   unfolding filter_eq_iff eventually_within by simp
   423 
   424 lemma within_empty [simp]: "F within {} = bot"
   425   unfolding filter_eq_iff eventually_within by simp
   426 
   427 lemma within_within_eq: "(F within S) within T = F within (S \<inter> T)"
   428   by (auto simp: filter_eq_iff eventually_within elim: eventually_elim1)
   429 
   430 lemma at_within_eq: "at x within T = nhds x within (T - {x})"
   431   unfolding at_def within_within_eq by (simp add: ac_simps Diff_eq)
   432 
   433 lemma within_le: "F within S \<le> F"
   434   unfolding le_filter_def eventually_within by (auto elim: eventually_elim1)
   435 
   436 lemma le_withinI: "F \<le> F' \<Longrightarrow> eventually (\<lambda>x. x \<in> S) F \<Longrightarrow> F \<le> F' within S"
   437   unfolding le_filter_def eventually_within by (auto elim: eventually_elim2)
   438 
   439 lemma le_within_iff: "eventually (\<lambda>x. x \<in> S) F \<Longrightarrow> F \<le> F' within S \<longleftrightarrow> F \<le> F'"
   440   by (blast intro: within_le le_withinI order_trans)
   441 
   442 lemma eventually_nhds:
   443   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   444 unfolding nhds_def
   445 proof (rule eventually_Abs_filter, rule is_filter.intro)
   446   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   447   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   448 next
   449   fix P Q
   450   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   451      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   452   then obtain S T where
   453     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   454     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   455   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   456     by (simp add: open_Int)
   457   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   458 qed auto
   459 
   460 lemma eventually_nhds_metric:
   461   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   462 unfolding eventually_nhds open_dist
   463 apply safe
   464 apply fast
   465 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   466 apply clarsimp
   467 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   468 apply (simp only: less_diff_eq)
   469 apply (erule le_less_trans [OF dist_triangle])
   470 done
   471 
   472 lemma eventually_nhds_order:
   473   "eventually P (nhds (a::'a::linorder_topology)) \<longleftrightarrow>
   474     (\<exists>S. open_interval S \<and> a \<in> S \<and> (\<forall>z\<in>S. P z))"
   475   (is "_ \<longleftrightarrow> ?rhs")
   476   unfolding eventually_nhds by (auto dest!: open_orderD dest: open_interval_imp_open)
   477 
   478 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   479   unfolding trivial_limit_def eventually_nhds by simp
   480 
   481 lemma eventually_at_topological:
   482   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   483 unfolding at_def eventually_within eventually_nhds by simp
   484 
   485 lemma eventually_at:
   486   fixes a :: "'a::metric_space"
   487   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   488 unfolding at_def eventually_within eventually_nhds_metric by auto
   489 
   490 lemma eventually_within_less: (* COPY FROM Topo/eventually_within *)
   491   "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   492   unfolding eventually_within eventually_at dist_nz by auto
   493 
   494 lemma eventually_within_le: (* COPY FROM Topo/eventually_within_le *)
   495   "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a <= d \<longrightarrow> P x)"
   496   unfolding eventually_within_less by auto (metis dense order_le_less_trans)
   497 
   498 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   499   unfolding trivial_limit_def eventually_at_topological
   500   by (safe, case_tac "S = {a}", simp, fast, fast)
   501 
   502 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   503   by (simp add: at_eq_bot_iff not_open_singleton)
   504 
   505 lemma trivial_limit_at_left_real [simp]: (* maybe generalize type *)
   506   "\<not> trivial_limit (at_left (x::real))"
   507   unfolding trivial_limit_def eventually_within_le
   508   apply clarsimp
   509   apply (rule_tac x="x - d/2" in bexI)
   510   apply (auto simp: dist_real_def)
   511   done
   512 
   513 lemma trivial_limit_at_right_real [simp]: (* maybe generalize type *)
   514   "\<not> trivial_limit (at_right (x::real))"
   515   unfolding trivial_limit_def eventually_within_le
   516   apply clarsimp
   517   apply (rule_tac x="x + d/2" in bexI)
   518   apply (auto simp: dist_real_def)
   519   done
   520 
   521 lemma eventually_at_infinity:
   522   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
   523 unfolding at_infinity_def
   524 proof (rule eventually_Abs_filter, rule is_filter.intro)
   525   fix P Q :: "'a \<Rightarrow> bool"
   526   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
   527   then obtain r s where
   528     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
   529   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
   530   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
   531 qed auto
   532 
   533 lemma at_infinity_eq_at_top_bot:
   534   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
   535   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
   536 proof (intro arg_cong[where f=Abs_filter] ext iffI)
   537   fix P :: "real \<Rightarrow> bool" assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
   538   then guess r ..
   539   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
   540   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
   541 next
   542   fix P :: "real \<Rightarrow> bool" assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
   543   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
   544   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
   545     by (intro exI[of _ "max p (-q)"])
   546        (auto simp: abs_real_def)
   547 qed
   548 
   549 lemma at_top_le_at_infinity:
   550   "at_top \<le> (at_infinity :: real filter)"
   551   unfolding at_infinity_eq_at_top_bot by simp
   552 
   553 lemma at_bot_le_at_infinity:
   554   "at_bot \<le> (at_infinity :: real filter)"
   555   unfolding at_infinity_eq_at_top_bot by simp
   556 
   557 subsection {* Boundedness *}
   558 
   559 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   560   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
   561 
   562 lemma BfunI:
   563   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
   564 unfolding Bfun_def
   565 proof (intro exI conjI allI)
   566   show "0 < max K 1" by simp
   567 next
   568   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
   569     using K by (rule eventually_elim1, simp)
   570 qed
   571 
   572 lemma BfunE:
   573   assumes "Bfun f F"
   574   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   575 using assms unfolding Bfun_def by fast
   576 
   577 
   578 subsection {* Convergence to Zero *}
   579 
   580 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   581   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   582 
   583 lemma ZfunI:
   584   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   585   unfolding Zfun_def by simp
   586 
   587 lemma ZfunD:
   588   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   589   unfolding Zfun_def by simp
   590 
   591 lemma Zfun_ssubst:
   592   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   593   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   594 
   595 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   596   unfolding Zfun_def by simp
   597 
   598 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   599   unfolding Zfun_def by simp
   600 
   601 lemma Zfun_imp_Zfun:
   602   assumes f: "Zfun f F"
   603   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   604   shows "Zfun (\<lambda>x. g x) F"
   605 proof (cases)
   606   assume K: "0 < K"
   607   show ?thesis
   608   proof (rule ZfunI)
   609     fix r::real assume "0 < r"
   610     hence "0 < r / K"
   611       using K by (rule divide_pos_pos)
   612     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   613       using ZfunD [OF f] by fast
   614     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   615     proof eventually_elim
   616       case (elim x)
   617       hence "norm (f x) * K < r"
   618         by (simp add: pos_less_divide_eq K)
   619       thus ?case
   620         by (simp add: order_le_less_trans [OF elim(1)])
   621     qed
   622   qed
   623 next
   624   assume "\<not> 0 < K"
   625   hence K: "K \<le> 0" by (simp only: not_less)
   626   show ?thesis
   627   proof (rule ZfunI)
   628     fix r :: real
   629     assume "0 < r"
   630     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   631     proof eventually_elim
   632       case (elim x)
   633       also have "norm (f x) * K \<le> norm (f x) * 0"
   634         using K norm_ge_zero by (rule mult_left_mono)
   635       finally show ?case
   636         using `0 < r` by simp
   637     qed
   638   qed
   639 qed
   640 
   641 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   642   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   643 
   644 lemma Zfun_add:
   645   assumes f: "Zfun f F" and g: "Zfun g F"
   646   shows "Zfun (\<lambda>x. f x + g x) F"
   647 proof (rule ZfunI)
   648   fix r::real assume "0 < r"
   649   hence r: "0 < r / 2" by simp
   650   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   651     using f r by (rule ZfunD)
   652   moreover
   653   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   654     using g r by (rule ZfunD)
   655   ultimately
   656   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   657   proof eventually_elim
   658     case (elim x)
   659     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   660       by (rule norm_triangle_ineq)
   661     also have "\<dots> < r/2 + r/2"
   662       using elim by (rule add_strict_mono)
   663     finally show ?case
   664       by simp
   665   qed
   666 qed
   667 
   668 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   669   unfolding Zfun_def by simp
   670 
   671 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   672   by (simp only: diff_minus Zfun_add Zfun_minus)
   673 
   674 lemma (in bounded_linear) Zfun:
   675   assumes g: "Zfun g F"
   676   shows "Zfun (\<lambda>x. f (g x)) F"
   677 proof -
   678   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   679     using bounded by fast
   680   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   681     by simp
   682   with g show ?thesis
   683     by (rule Zfun_imp_Zfun)
   684 qed
   685 
   686 lemma (in bounded_bilinear) Zfun:
   687   assumes f: "Zfun f F"
   688   assumes g: "Zfun g F"
   689   shows "Zfun (\<lambda>x. f x ** g x) F"
   690 proof (rule ZfunI)
   691   fix r::real assume r: "0 < r"
   692   obtain K where K: "0 < K"
   693     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   694     using pos_bounded by fast
   695   from K have K': "0 < inverse K"
   696     by (rule positive_imp_inverse_positive)
   697   have "eventually (\<lambda>x. norm (f x) < r) F"
   698     using f r by (rule ZfunD)
   699   moreover
   700   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   701     using g K' by (rule ZfunD)
   702   ultimately
   703   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   704   proof eventually_elim
   705     case (elim x)
   706     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   707       by (rule norm_le)
   708     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   709       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   710     also from K have "r * inverse K * K = r"
   711       by simp
   712     finally show ?case .
   713   qed
   714 qed
   715 
   716 lemma (in bounded_bilinear) Zfun_left:
   717   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   718   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   719 
   720 lemma (in bounded_bilinear) Zfun_right:
   721   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   722   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   723 
   724 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   725 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   726 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   727 
   728 
   729 subsection {* Limits *}
   730 
   731 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   732   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   733 
   734 syntax
   735   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   736 
   737 translations
   738   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   739 
   740 lemma filterlim_iff:
   741   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   742   unfolding filterlim_def le_filter_def eventually_filtermap ..
   743 
   744 lemma filterlim_compose:
   745   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   746   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   747 
   748 lemma filterlim_mono:
   749   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   750   unfolding filterlim_def by (metis filtermap_mono order_trans)
   751 
   752 lemma filterlim_ident: "LIM x F. x :> F"
   753   by (simp add: filterlim_def filtermap_ident)
   754 
   755 lemma filterlim_cong:
   756   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   757   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   758 
   759 lemma filterlim_within:
   760   "(LIM x F1. f x :> F2 within S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F1 \<and> (LIM x F1. f x :> F2))"
   761   unfolding filterlim_def
   762 proof safe
   763   assume "filtermap f F1 \<le> F2 within S" then show "eventually (\<lambda>x. f x \<in> S) F1"
   764     by (auto simp: le_filter_def eventually_filtermap eventually_within elim!: allE[of _ "\<lambda>x. x \<in> S"])
   765 qed (auto intro: within_le order_trans simp: le_within_iff eventually_filtermap)
   766 
   767 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   768   unfolding filterlim_def filtermap_filtermap ..
   769 
   770 lemma filterlim_sup:
   771   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   772   unfolding filterlim_def filtermap_sup by auto
   773 
   774 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   775   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   776 
   777 abbreviation (in topological_space)
   778   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   779   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   780 
   781 ML {*
   782 structure Tendsto_Intros = Named_Thms
   783 (
   784   val name = @{binding tendsto_intros}
   785   val description = "introduction rules for tendsto"
   786 )
   787 *}
   788 
   789 setup Tendsto_Intros.setup
   790 
   791 lemma tendsto_def: "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   792   unfolding filterlim_def
   793 proof safe
   794   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   795   then show "eventually (\<lambda>x. f x \<in> S) F"
   796     unfolding eventually_nhds eventually_filtermap le_filter_def
   797     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   798 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   799 
   800 lemma filterlim_at:
   801   "(LIM x F. f x :> at b) \<longleftrightarrow> (eventually (\<lambda>x. f x \<noteq> b) F \<and> (f ---> b) F)"
   802   by (simp add: at_def filterlim_within)
   803 
   804 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   805   unfolding tendsto_def le_filter_def by fast
   806 
   807 lemma topological_tendstoI:
   808   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
   809     \<Longrightarrow> (f ---> l) F"
   810   unfolding tendsto_def by auto
   811 
   812 lemma topological_tendstoD:
   813   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   814   unfolding tendsto_def by auto
   815 
   816 lemma tendstoI:
   817   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   818   shows "(f ---> l) F"
   819   apply (rule topological_tendstoI)
   820   apply (simp add: open_dist)
   821   apply (drule (1) bspec, clarify)
   822   apply (drule assms)
   823   apply (erule eventually_elim1, simp)
   824   done
   825 
   826 lemma tendstoD:
   827   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   828   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   829   apply (clarsimp simp add: open_dist)
   830   apply (rule_tac x="e - dist x l" in exI, clarsimp)
   831   apply (simp only: less_diff_eq)
   832   apply (erule le_less_trans [OF dist_triangle])
   833   apply simp
   834   apply simp
   835   done
   836 
   837 lemma tendsto_iff:
   838   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
   839   using tendstoI tendstoD by fast
   840 
   841 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   842   by (simp only: tendsto_iff Zfun_def dist_norm)
   843 
   844 lemma tendsto_bot [simp]: "(f ---> a) bot"
   845   unfolding tendsto_def by simp
   846 
   847 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   848   unfolding tendsto_def eventually_at_topological by auto
   849 
   850 lemma tendsto_ident_at_within [tendsto_intros]:
   851   "((\<lambda>x. x) ---> a) (at a within S)"
   852   unfolding tendsto_def eventually_within eventually_at_topological by auto
   853 
   854 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   855   by (simp add: tendsto_def)
   856 
   857 lemma tendsto_unique:
   858   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   859   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   860   shows "a = b"
   861 proof (rule ccontr)
   862   assume "a \<noteq> b"
   863   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   864     using hausdorff [OF `a \<noteq> b`] by fast
   865   have "eventually (\<lambda>x. f x \<in> U) F"
   866     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   867   moreover
   868   have "eventually (\<lambda>x. f x \<in> V) F"
   869     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   870   ultimately
   871   have "eventually (\<lambda>x. False) F"
   872   proof eventually_elim
   873     case (elim x)
   874     hence "f x \<in> U \<inter> V" by simp
   875     with `U \<inter> V = {}` show ?case by simp
   876   qed
   877   with `\<not> trivial_limit F` show "False"
   878     by (simp add: trivial_limit_def)
   879 qed
   880 
   881 lemma tendsto_const_iff:
   882   fixes a b :: "'a::t2_space"
   883   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
   884   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   885 
   886 lemma tendsto_at_iff_tendsto_nhds:
   887   "(g ---> g l) (at l) \<longleftrightarrow> (g ---> g l) (nhds l)"
   888   unfolding tendsto_def at_def eventually_within
   889   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
   890 
   891 lemma tendsto_compose:
   892   "(g ---> g l) (at l) \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
   893   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
   894 
   895 lemma tendsto_compose_eventually:
   896   "(g ---> m) (at l) \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
   897   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
   898 
   899 lemma metric_tendsto_imp_tendsto:
   900   assumes f: "(f ---> a) F"
   901   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
   902   shows "(g ---> b) F"
   903 proof (rule tendstoI)
   904   fix e :: real assume "0 < e"
   905   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
   906   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
   907     using le_less_trans by (rule eventually_elim2)
   908 qed
   909 
   910 lemma increasing_tendsto:
   911   fixes f :: "_ \<Rightarrow> 'a::linorder_topology"
   912   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   913       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   914   shows "(f ---> l) F"
   915 proof (rule topological_tendstoI)
   916   fix S assume "open S" "l \<in> S"
   917   then show "eventually (\<lambda>x. f x \<in> S) F"
   918   proof (induct rule: open_order_induct)
   919     case (greaterThanLessThan a b) with en bdd show ?case
   920       by (auto elim!: eventually_elim2)
   921   qed (insert en bdd, auto elim!: eventually_elim1)
   922 qed
   923 
   924 lemma decreasing_tendsto:
   925   fixes f :: "_ \<Rightarrow> 'a::linorder_topology"
   926   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   927       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   928   shows "(f ---> l) F"
   929 proof (rule topological_tendstoI)
   930   fix S assume "open S" "l \<in> S"
   931   then show "eventually (\<lambda>x. f x \<in> S) F"
   932   proof (induct rule: open_order_induct)
   933     case (greaterThanLessThan a b)
   934     with en have "eventually (\<lambda>n. f n < b) F" by auto
   935     with bdd show ?case
   936       by eventually_elim (insert greaterThanLessThan, auto)
   937   qed (insert en bdd, auto elim!: eventually_elim1)
   938 qed
   939 
   940 subsubsection {* Distance and norms *}
   941 
   942 lemma tendsto_dist [tendsto_intros]:
   943   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   944   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   945 proof (rule tendstoI)
   946   fix e :: real assume "0 < e"
   947   hence e2: "0 < e/2" by simp
   948   from tendstoD [OF f e2] tendstoD [OF g e2]
   949   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   950   proof (eventually_elim)
   951     case (elim x)
   952     then show "dist (dist (f x) (g x)) (dist l m) < e"
   953       unfolding dist_real_def
   954       using dist_triangle2 [of "f x" "g x" "l"]
   955       using dist_triangle2 [of "g x" "l" "m"]
   956       using dist_triangle3 [of "l" "m" "f x"]
   957       using dist_triangle [of "f x" "m" "g x"]
   958       by arith
   959   qed
   960 qed
   961 
   962 lemma norm_conv_dist: "norm x = dist x 0"
   963   unfolding dist_norm by simp
   964 
   965 lemma tendsto_norm [tendsto_intros]:
   966   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   967   unfolding norm_conv_dist by (intro tendsto_intros)
   968 
   969 lemma tendsto_norm_zero:
   970   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   971   by (drule tendsto_norm, simp)
   972 
   973 lemma tendsto_norm_zero_cancel:
   974   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   975   unfolding tendsto_iff dist_norm by simp
   976 
   977 lemma tendsto_norm_zero_iff:
   978   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   979   unfolding tendsto_iff dist_norm by simp
   980 
   981 lemma tendsto_rabs [tendsto_intros]:
   982   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   983   by (fold real_norm_def, rule tendsto_norm)
   984 
   985 lemma tendsto_rabs_zero:
   986   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   987   by (fold real_norm_def, rule tendsto_norm_zero)
   988 
   989 lemma tendsto_rabs_zero_cancel:
   990   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   991   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   992 
   993 lemma tendsto_rabs_zero_iff:
   994   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   995   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   996 
   997 subsubsection {* Addition and subtraction *}
   998 
   999 lemma tendsto_add [tendsto_intros]:
  1000   fixes a b :: "'a::real_normed_vector"
  1001   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
  1002   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
  1003 
  1004 lemma tendsto_add_zero:
  1005   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  1006   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
  1007   by (drule (1) tendsto_add, simp)
  1008 
  1009 lemma tendsto_minus [tendsto_intros]:
  1010   fixes a :: "'a::real_normed_vector"
  1011   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
  1012   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
  1013 
  1014 lemma tendsto_minus_cancel:
  1015   fixes a :: "'a::real_normed_vector"
  1016   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
  1017   by (drule tendsto_minus, simp)
  1018 
  1019 lemma tendsto_minus_cancel_left:
  1020     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
  1021   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
  1022   by auto
  1023 
  1024 lemma tendsto_diff [tendsto_intros]:
  1025   fixes a b :: "'a::real_normed_vector"
  1026   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
  1027   by (simp add: diff_minus tendsto_add tendsto_minus)
  1028 
  1029 lemma tendsto_setsum [tendsto_intros]:
  1030   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
  1031   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
  1032   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
  1033 proof (cases "finite S")
  1034   assume "finite S" thus ?thesis using assms
  1035     by (induct, simp add: tendsto_const, simp add: tendsto_add)
  1036 next
  1037   assume "\<not> finite S" thus ?thesis
  1038     by (simp add: tendsto_const)
  1039 qed
  1040 
  1041 lemma tendsto_sandwich:
  1042   fixes f g h :: "'a \<Rightarrow> 'b::linorder_topology"
  1043   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1044   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1045   shows "(g ---> c) net"
  1046 proof (rule topological_tendstoI)
  1047   fix S assume "open S" "c \<in> S"
  1048   from open_orderD[OF this] obtain T where "open_interval T" "c \<in> T" "T \<subseteq> S" by auto
  1049   with lim[THEN topological_tendstoD, of T]
  1050   have "eventually (\<lambda>x. f x \<in> T) net" "eventually (\<lambda>x. h x \<in> T) net"
  1051     by (auto dest: open_interval_imp_open)
  1052   with ev have "eventually (\<lambda>x. g x \<in> T) net"
  1053     by eventually_elim (insert `open_interval T`, auto dest: open_intervalD)
  1054   with `T \<subseteq> S` show "eventually (\<lambda>x. g x \<in> S) net"
  1055     by (auto elim: eventually_elim1)
  1056 qed
  1057 
  1058 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
  1059 
  1060 subsubsection {* Linear operators and multiplication *}
  1061 
  1062 lemma (in bounded_linear) tendsto:
  1063   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
  1064   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
  1065 
  1066 lemma (in bounded_linear) tendsto_zero:
  1067   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
  1068   by (drule tendsto, simp only: zero)
  1069 
  1070 lemma (in bounded_bilinear) tendsto:
  1071   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
  1072   by (simp only: tendsto_Zfun_iff prod_diff_prod
  1073                  Zfun_add Zfun Zfun_left Zfun_right)
  1074 
  1075 lemma (in bounded_bilinear) tendsto_zero:
  1076   assumes f: "(f ---> 0) F"
  1077   assumes g: "(g ---> 0) F"
  1078   shows "((\<lambda>x. f x ** g x) ---> 0) F"
  1079   using tendsto [OF f g] by (simp add: zero_left)
  1080 
  1081 lemma (in bounded_bilinear) tendsto_left_zero:
  1082   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
  1083   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
  1084 
  1085 lemma (in bounded_bilinear) tendsto_right_zero:
  1086   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
  1087   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
  1088 
  1089 lemmas tendsto_of_real [tendsto_intros] =
  1090   bounded_linear.tendsto [OF bounded_linear_of_real]
  1091 
  1092 lemmas tendsto_scaleR [tendsto_intros] =
  1093   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
  1094 
  1095 lemmas tendsto_mult [tendsto_intros] =
  1096   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
  1097 
  1098 lemmas tendsto_mult_zero =
  1099   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
  1100 
  1101 lemmas tendsto_mult_left_zero =
  1102   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
  1103 
  1104 lemmas tendsto_mult_right_zero =
  1105   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
  1106 
  1107 lemma tendsto_power [tendsto_intros]:
  1108   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
  1109   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
  1110   by (induct n) (simp_all add: tendsto_const tendsto_mult)
  1111 
  1112 lemma tendsto_setprod [tendsto_intros]:
  1113   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
  1114   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
  1115   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
  1116 proof (cases "finite S")
  1117   assume "finite S" thus ?thesis using assms
  1118     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
  1119 next
  1120   assume "\<not> finite S" thus ?thesis
  1121     by (simp add: tendsto_const)
  1122 qed
  1123 
  1124 lemma tendsto_le:
  1125   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1126   assumes F: "\<not> trivial_limit F"
  1127   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1128   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1129   shows "y \<le> x"
  1130 proof (rule ccontr)
  1131   assume "\<not> y \<le> x"
  1132   then have "x < y" by simp
  1133   from less_separate[OF this] obtain a b where xy: "x \<in> {..<a}" "y \<in> {b <..}" "{..<a} \<inter> {b<..} = {}"
  1134     by auto
  1135   then have less: "\<And>x y. x < a \<Longrightarrow> b < y \<Longrightarrow> x < y"
  1136     by auto
  1137   from x[THEN topological_tendstoD, of "{..<a}"] y[THEN topological_tendstoD, of "{b <..}"] xy
  1138   have "eventually (\<lambda>x. f x \<in> {..<a}) F" "eventually (\<lambda>x. g x \<in> {b <..}) F" by auto
  1139   with ev have "eventually (\<lambda>x. False) F"
  1140     by eventually_elim (auto dest!: less)
  1141   with F show False
  1142     by (simp add: eventually_False)
  1143 qed
  1144 
  1145 lemma tendsto_le_const:
  1146   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1147   assumes F: "\<not> trivial_limit F"
  1148   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>x. a \<le> f x) F"
  1149   shows "a \<le> x"
  1150   using F x tendsto_const a by (rule tendsto_le)
  1151 
  1152 subsubsection {* Inverse and division *}
  1153 
  1154 lemma (in bounded_bilinear) Zfun_prod_Bfun:
  1155   assumes f: "Zfun f F"
  1156   assumes g: "Bfun g F"
  1157   shows "Zfun (\<lambda>x. f x ** g x) F"
  1158 proof -
  1159   obtain K where K: "0 \<le> K"
  1160     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
  1161     using nonneg_bounded by fast
  1162   obtain B where B: "0 < B"
  1163     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
  1164     using g by (rule BfunE)
  1165   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
  1166   using norm_g proof eventually_elim
  1167     case (elim x)
  1168     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
  1169       by (rule norm_le)
  1170     also have "\<dots> \<le> norm (f x) * B * K"
  1171       by (intro mult_mono' order_refl norm_g norm_ge_zero
  1172                 mult_nonneg_nonneg K elim)
  1173     also have "\<dots> = norm (f x) * (B * K)"
  1174       by (rule mult_assoc)
  1175     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
  1176   qed
  1177   with f show ?thesis
  1178     by (rule Zfun_imp_Zfun)
  1179 qed
  1180 
  1181 lemma (in bounded_bilinear) flip:
  1182   "bounded_bilinear (\<lambda>x y. y ** x)"
  1183   apply default
  1184   apply (rule add_right)
  1185   apply (rule add_left)
  1186   apply (rule scaleR_right)
  1187   apply (rule scaleR_left)
  1188   apply (subst mult_commute)
  1189   using bounded by fast
  1190 
  1191 lemma (in bounded_bilinear) Bfun_prod_Zfun:
  1192   assumes f: "Bfun f F"
  1193   assumes g: "Zfun g F"
  1194   shows "Zfun (\<lambda>x. f x ** g x) F"
  1195   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
  1196 
  1197 lemma Bfun_inverse_lemma:
  1198   fixes x :: "'a::real_normed_div_algebra"
  1199   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1200   apply (subst nonzero_norm_inverse, clarsimp)
  1201   apply (erule (1) le_imp_inverse_le)
  1202   done
  1203 
  1204 lemma Bfun_inverse:
  1205   fixes a :: "'a::real_normed_div_algebra"
  1206   assumes f: "(f ---> a) F"
  1207   assumes a: "a \<noteq> 0"
  1208   shows "Bfun (\<lambda>x. inverse (f x)) F"
  1209 proof -
  1210   from a have "0 < norm a" by simp
  1211   hence "\<exists>r>0. r < norm a" by (rule dense)
  1212   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
  1213   have "eventually (\<lambda>x. dist (f x) a < r) F"
  1214     using tendstoD [OF f r1] by fast
  1215   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
  1216   proof eventually_elim
  1217     case (elim x)
  1218     hence 1: "norm (f x - a) < r"
  1219       by (simp add: dist_norm)
  1220     hence 2: "f x \<noteq> 0" using r2 by auto
  1221     hence "norm (inverse (f x)) = inverse (norm (f x))"
  1222       by (rule nonzero_norm_inverse)
  1223     also have "\<dots> \<le> inverse (norm a - r)"
  1224     proof (rule le_imp_inverse_le)
  1225       show "0 < norm a - r" using r2 by simp
  1226     next
  1227       have "norm a - norm (f x) \<le> norm (a - f x)"
  1228         by (rule norm_triangle_ineq2)
  1229       also have "\<dots> = norm (f x - a)"
  1230         by (rule norm_minus_commute)
  1231       also have "\<dots> < r" using 1 .
  1232       finally show "norm a - r \<le> norm (f x)" by simp
  1233     qed
  1234     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
  1235   qed
  1236   thus ?thesis by (rule BfunI)
  1237 qed
  1238 
  1239 lemma tendsto_inverse [tendsto_intros]:
  1240   fixes a :: "'a::real_normed_div_algebra"
  1241   assumes f: "(f ---> a) F"
  1242   assumes a: "a \<noteq> 0"
  1243   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
  1244 proof -
  1245   from a have "0 < norm a" by simp
  1246   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
  1247     by (rule tendstoD)
  1248   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
  1249     unfolding dist_norm by (auto elim!: eventually_elim1)
  1250   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
  1251     - (inverse (f x) * (f x - a) * inverse a)) F"
  1252     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
  1253   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
  1254     by (intro Zfun_minus Zfun_mult_left
  1255       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
  1256       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
  1257   ultimately show ?thesis
  1258     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
  1259 qed
  1260 
  1261 lemma tendsto_divide [tendsto_intros]:
  1262   fixes a b :: "'a::real_normed_field"
  1263   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
  1264     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
  1265   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1266 
  1267 lemma tendsto_sgn [tendsto_intros]:
  1268   fixes l :: "'a::real_normed_vector"
  1269   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
  1270   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1271 
  1272 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1273 
  1274 lemma filterlim_at_top:
  1275   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1276   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1277   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1278 
  1279 lemma filterlim_at_top_dense:
  1280   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1281   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1282   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1283             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1284 
  1285 lemma filterlim_at_top_ge:
  1286   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1287   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1288   unfolding filterlim_at_top
  1289 proof safe
  1290   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1291   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1292     by (auto elim!: eventually_elim1)
  1293 qed simp
  1294 
  1295 lemma filterlim_at_top_at_top:
  1296   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1297   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1298   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1299   assumes Q: "eventually Q at_top"
  1300   assumes P: "eventually P at_top"
  1301   shows "filterlim f at_top at_top"
  1302 proof -
  1303   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1304     unfolding eventually_at_top_linorder by auto
  1305   show ?thesis
  1306   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1307     fix z assume "x \<le> z"
  1308     with x have "P z" by auto
  1309     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1310       by (rule eventually_ge_at_top)
  1311     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1312       by eventually_elim (metis mono bij `P z`)
  1313   qed
  1314 qed
  1315 
  1316 lemma filterlim_at_top_gt:
  1317   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1318   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1319   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1320 
  1321 lemma filterlim_at_bot: 
  1322   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1323   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1324   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1325 
  1326 lemma filterlim_at_bot_le:
  1327   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1328   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1329   unfolding filterlim_at_bot
  1330 proof safe
  1331   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1332   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1333     by (auto elim!: eventually_elim1)
  1334 qed simp
  1335 
  1336 lemma filterlim_at_bot_lt:
  1337   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1338   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1339   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1340 
  1341 lemma filterlim_at_bot_at_right:
  1342   fixes f :: "real \<Rightarrow> 'b::linorder"
  1343   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1344   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1345   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1346   assumes P: "eventually P at_bot"
  1347   shows "filterlim f at_bot (at_right a)"
  1348 proof -
  1349   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1350     unfolding eventually_at_bot_linorder by auto
  1351   show ?thesis
  1352   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1353     fix z assume "z \<le> x"
  1354     with x have "P z" by auto
  1355     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1356       using bound[OF bij(2)[OF `P z`]]
  1357       by (auto simp add: eventually_within_less dist_real_def intro!:  exI[of _ "g z - a"])
  1358     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1359       by eventually_elim (metis bij `P z` mono)
  1360   qed
  1361 qed
  1362 
  1363 lemma filterlim_at_top_at_left:
  1364   fixes f :: "real \<Rightarrow> 'b::linorder"
  1365   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1366   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1367   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1368   assumes P: "eventually P at_top"
  1369   shows "filterlim f at_top (at_left a)"
  1370 proof -
  1371   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1372     unfolding eventually_at_top_linorder by auto
  1373   show ?thesis
  1374   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1375     fix z assume "x \<le> z"
  1376     with x have "P z" by auto
  1377     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1378       using bound[OF bij(2)[OF `P z`]]
  1379       by (auto simp add: eventually_within_less dist_real_def intro!:  exI[of _ "a - g z"])
  1380     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1381       by eventually_elim (metis bij `P z` mono)
  1382   qed
  1383 qed
  1384 
  1385 lemma filterlim_at_infinity:
  1386   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
  1387   assumes "0 \<le> c"
  1388   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1389   unfolding filterlim_iff eventually_at_infinity
  1390 proof safe
  1391   fix P :: "'a \<Rightarrow> bool" and b
  1392   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1393     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1394   have "max b (c + 1) > c" by auto
  1395   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1396     by auto
  1397   then show "eventually (\<lambda>x. P (f x)) F"
  1398   proof eventually_elim
  1399     fix x assume "max b (c + 1) \<le> norm (f x)"
  1400     with P show "P (f x)" by auto
  1401   qed
  1402 qed force
  1403 
  1404 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1405   unfolding filterlim_at_top
  1406   apply (intro allI)
  1407   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1408   apply (auto simp: natceiling_le_eq)
  1409   done
  1410 
  1411 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
  1412 
  1413 text {*
  1414 
  1415 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1416 @{term "at_right x"} and also @{term "at_right 0"}.
  1417 
  1418 *}
  1419 
  1420 lemma at_eq_sup_left_right: "at (x::real) = sup (at_left x) (at_right x)"
  1421   by (auto simp: eventually_within at_def filter_eq_iff eventually_sup 
  1422            elim: eventually_elim2 eventually_elim1)
  1423 
  1424 lemma filterlim_split_at_real:
  1425   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::real))"
  1426   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1427 
  1428 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::real)"
  1429   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
  1430   by (intro allI ex_cong) (auto simp: dist_real_def field_simps)
  1431 
  1432 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::real)"
  1433   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
  1434   apply (intro allI ex_cong)
  1435   apply (auto simp: dist_real_def field_simps)
  1436   apply (erule_tac x="-x" in allE)
  1437   apply simp
  1438   done
  1439 
  1440 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::real)"
  1441   unfolding at_def filtermap_nhds_shift[symmetric]
  1442   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
  1443 
  1444 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
  1445   unfolding filtermap_at_shift[symmetric]
  1446   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
  1447 
  1448 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
  1449   using filtermap_at_right_shift[of "-a" 0] by simp
  1450 
  1451 lemma filterlim_at_right_to_0:
  1452   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1453   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1454 
  1455 lemma eventually_at_right_to_0:
  1456   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1457   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1458 
  1459 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::real)"
  1460   unfolding at_def filtermap_nhds_minus[symmetric]
  1461   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
  1462 
  1463 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
  1464   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
  1465 
  1466 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
  1467   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
  1468 
  1469 lemma filterlim_at_left_to_right:
  1470   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1471   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1472 
  1473 lemma eventually_at_left_to_right:
  1474   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1475   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1476 
  1477 lemma filterlim_at_split:
  1478   "filterlim f F (at (x::real)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1479   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1480 
  1481 lemma eventually_at_split:
  1482   "eventually P (at (x::real)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
  1483   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
  1484 
  1485 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1486   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
  1487   by (metis le_minus_iff minus_minus)
  1488 
  1489 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1490   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1491 
  1492 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1493   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1494 
  1495 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1496   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1497 
  1498 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1499   unfolding filterlim_at_top eventually_at_bot_dense
  1500   by (metis leI minus_less_iff order_less_asym)
  1501 
  1502 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1503   unfolding filterlim_at_bot eventually_at_top_dense
  1504   by (metis leI less_minus_iff order_less_asym)
  1505 
  1506 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1507   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1508   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1509   by auto
  1510 
  1511 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1512   unfolding filterlim_uminus_at_top by simp
  1513 
  1514 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1515   unfolding filterlim_at_top_gt[where c=0] eventually_within at_def
  1516 proof safe
  1517   fix Z :: real assume [arith]: "0 < Z"
  1518   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1519     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1520   then show "eventually (\<lambda>x. x \<in> - {0} \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1521     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1522 qed
  1523 
  1524 lemma filterlim_inverse_at_top:
  1525   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1526   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1527      (simp add: filterlim_def eventually_filtermap le_within_iff at_def eventually_elim1)
  1528 
  1529 lemma filterlim_inverse_at_bot_neg:
  1530   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1531   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1532 
  1533 lemma filterlim_inverse_at_bot:
  1534   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1535   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1536   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1537 
  1538 lemma tendsto_inverse_0:
  1539   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1540   shows "(inverse ---> (0::'a)) at_infinity"
  1541   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1542 proof safe
  1543   fix r :: real assume "0 < r"
  1544   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1545   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1546     fix x :: 'a
  1547     from `0 < r` have "0 < inverse (r / 2)" by simp
  1548     also assume *: "inverse (r / 2) \<le> norm x"
  1549     finally show "norm (inverse x) < r"
  1550       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1551   qed
  1552 qed
  1553 
  1554 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1555 proof (rule antisym)
  1556   have "(inverse ---> (0::real)) at_top"
  1557     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1558   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1559     unfolding at_within_eq
  1560     by (intro le_withinI) (simp_all add: eventually_filtermap eventually_gt_at_top filterlim_def)
  1561 next
  1562   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1563     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1564   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1565     by (simp add: filtermap_ident filtermap_filtermap)
  1566 qed
  1567 
  1568 lemma eventually_at_right_to_top:
  1569   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1570   unfolding at_right_to_top eventually_filtermap ..
  1571 
  1572 lemma filterlim_at_right_to_top:
  1573   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1574   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1575 
  1576 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1577   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1578 
  1579 lemma eventually_at_top_to_right:
  1580   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1581   unfolding at_top_to_right eventually_filtermap ..
  1582 
  1583 lemma filterlim_at_top_to_right:
  1584   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1585   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1586 
  1587 lemma filterlim_inverse_at_infinity:
  1588   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1589   shows "filterlim inverse at_infinity (at (0::'a))"
  1590   unfolding filterlim_at_infinity[OF order_refl]
  1591 proof safe
  1592   fix r :: real assume "0 < r"
  1593   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1594     unfolding eventually_at norm_inverse
  1595     by (intro exI[of _ "inverse r"])
  1596        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1597 qed
  1598 
  1599 lemma filterlim_inverse_at_iff:
  1600   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1601   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1602   unfolding filterlim_def filtermap_filtermap[symmetric]
  1603 proof
  1604   assume "filtermap g F \<le> at_infinity"
  1605   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1606     by (rule filtermap_mono)
  1607   also have "\<dots> \<le> at 0"
  1608     using tendsto_inverse_0
  1609     by (auto intro!: le_withinI exI[of _ 1]
  1610              simp: eventually_filtermap eventually_at_infinity filterlim_def at_def)
  1611   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1612 next
  1613   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1614   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1615     by (rule filtermap_mono)
  1616   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1617     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1618 qed
  1619 
  1620 lemma tendsto_inverse_0_at_top:
  1621   "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1622  by (metis at_top_le_at_infinity filterlim_at filterlim_inverse_at_iff filterlim_mono order_refl)
  1623 
  1624 text {*
  1625 
  1626 We only show rules for multiplication and addition when the functions are either against a real
  1627 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1628 
  1629 *}
  1630 
  1631 lemma filterlim_tendsto_pos_mult_at_top: 
  1632   assumes f: "(f ---> c) F" and c: "0 < c"
  1633   assumes g: "LIM x F. g x :> at_top"
  1634   shows "LIM x F. (f x * g x :: real) :> at_top"
  1635   unfolding filterlim_at_top_gt[where c=0]
  1636 proof safe
  1637   fix Z :: real assume "0 < Z"
  1638   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1639     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1640              simp: dist_real_def abs_real_def split: split_if_asm)
  1641   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1642     unfolding filterlim_at_top by auto
  1643   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1644   proof eventually_elim
  1645     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1646     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1647       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1648     with `0 < c` show "Z \<le> f x * g x"
  1649        by simp
  1650   qed
  1651 qed
  1652 
  1653 lemma filterlim_at_top_mult_at_top: 
  1654   assumes f: "LIM x F. f x :> at_top"
  1655   assumes g: "LIM x F. g x :> at_top"
  1656   shows "LIM x F. (f x * g x :: real) :> at_top"
  1657   unfolding filterlim_at_top_gt[where c=0]
  1658 proof safe
  1659   fix Z :: real assume "0 < Z"
  1660   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1661     unfolding filterlim_at_top by auto
  1662   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1663     unfolding filterlim_at_top by auto
  1664   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1665   proof eventually_elim
  1666     fix x assume "1 \<le> f x" "Z \<le> g x"
  1667     with `0 < Z` have "1 * Z \<le> f x * g x"
  1668       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1669     then show "Z \<le> f x * g x"
  1670        by simp
  1671   qed
  1672 qed
  1673 
  1674 lemma filterlim_tendsto_pos_mult_at_bot:
  1675   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1676   shows "LIM x F. f x * g x :> at_bot"
  1677   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1678   unfolding filterlim_uminus_at_bot by simp
  1679 
  1680 lemma filterlim_tendsto_add_at_top: 
  1681   assumes f: "(f ---> c) F"
  1682   assumes g: "LIM x F. g x :> at_top"
  1683   shows "LIM x F. (f x + g x :: real) :> at_top"
  1684   unfolding filterlim_at_top_gt[where c=0]
  1685 proof safe
  1686   fix Z :: real assume "0 < Z"
  1687   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1688     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1689   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1690     unfolding filterlim_at_top by auto
  1691   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1692     by eventually_elim simp
  1693 qed
  1694 
  1695 lemma LIM_at_top_divide:
  1696   fixes f g :: "'a \<Rightarrow> real"
  1697   assumes f: "(f ---> a) F" "0 < a"
  1698   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1699   shows "LIM x F. f x / g x :> at_top"
  1700   unfolding divide_inverse
  1701   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1702 
  1703 lemma filterlim_at_top_add_at_top: 
  1704   assumes f: "LIM x F. f x :> at_top"
  1705   assumes g: "LIM x F. g x :> at_top"
  1706   shows "LIM x F. (f x + g x :: real) :> at_top"
  1707   unfolding filterlim_at_top_gt[where c=0]
  1708 proof safe
  1709   fix Z :: real assume "0 < Z"
  1710   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1711     unfolding filterlim_at_top by auto
  1712   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1713     unfolding filterlim_at_top by auto
  1714   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1715     by eventually_elim simp
  1716 qed
  1717 
  1718 lemma tendsto_divide_0:
  1719   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1720   assumes f: "(f ---> c) F"
  1721   assumes g: "LIM x F. g x :> at_infinity"
  1722   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1723   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1724 
  1725 lemma linear_plus_1_le_power:
  1726   fixes x :: real
  1727   assumes x: "0 \<le> x"
  1728   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1729 proof (induct n)
  1730   case (Suc n)
  1731   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1732     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1733   also have "\<dots> \<le> (x + 1)^Suc n"
  1734     using Suc x by (simp add: mult_left_mono)
  1735   finally show ?case .
  1736 qed simp
  1737 
  1738 lemma filterlim_realpow_sequentially_gt1:
  1739   fixes x :: "'a :: real_normed_div_algebra"
  1740   assumes x[arith]: "1 < norm x"
  1741   shows "LIM n sequentially. x ^ n :> at_infinity"
  1742 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1743   fix y :: real assume "0 < y"
  1744   have "0 < norm x - 1" by simp
  1745   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1746   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1747   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1748   also have "\<dots> = norm x ^ N" by simp
  1749   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1750     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1751   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1752     unfolding eventually_sequentially
  1753     by (auto simp: norm_power)
  1754 qed simp
  1755 
  1756 end
  1757