src/HOL/Rat.thy
author hoelzl
Thu Jan 31 11:31:27 2013 +0100 (2013-01-31)
changeset 50999 3de230ed0547
parent 50178 ad52ddd35c3a
child 51126 df86080de4cb
permissions -rw-r--r--
introduce order topology
     1 (*  Title:  HOL/Rat.thy
     2     Author: Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 header {* Rational numbers *}
     6 
     7 theory Rat
     8 imports GCD Archimedean_Field
     9 begin
    10 
    11 subsection {* Rational numbers as quotient *}
    12 
    13 subsubsection {* Construction of the type of rational numbers *}
    14 
    15 definition
    16   ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool" where
    17   "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    18 
    19 lemma ratrel_iff [simp]:
    20   "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    21   by (simp add: ratrel_def)
    22 
    23 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    24   by (auto intro!: one_neq_zero)
    25 
    26 lemma symp_ratrel: "symp ratrel"
    27   by (simp add: ratrel_def symp_def)
    28 
    29 lemma transp_ratrel: "transp ratrel"
    30 proof (rule transpI, unfold split_paired_all)
    31   fix a b a' b' a'' b'' :: int
    32   assume A: "ratrel (a, b) (a', b')"
    33   assume B: "ratrel (a', b') (a'', b'')"
    34   have "b' * (a * b'') = b'' * (a * b')" by simp
    35   also from A have "a * b' = a' * b" by auto
    36   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    37   also from B have "a' * b'' = a'' * b'" by auto
    38   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    39   finally have "b' * (a * b'') = b' * (a'' * b)" .
    40   moreover from B have "b' \<noteq> 0" by auto
    41   ultimately have "a * b'' = a'' * b" by simp
    42   with A B show "ratrel (a, b) (a'', b'')" by auto
    43 qed
    44 
    45 lemma part_equivp_ratrel: "part_equivp ratrel"
    46   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    47 
    48 quotient_type rat = "int \<times> int" / partial: "ratrel"
    49   morphisms Rep_Rat Abs_Rat
    50   by (rule part_equivp_ratrel)
    51 
    52 declare rat.forall_transfer [transfer_rule del]
    53 
    54 lemma forall_rat_transfer [transfer_rule]: (* TODO: generate automatically *)
    55   "(fun_rel (fun_rel cr_rat op =) op =)
    56     (transfer_bforall (\<lambda>x. snd x \<noteq> 0)) transfer_forall"
    57   using rat.forall_transfer by simp
    58 
    59 
    60 subsubsection {* Representation and basic operations *}
    61 
    62 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    63   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    64   by simp
    65 
    66 lemma eq_rat:
    67   shows "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    68   and "\<And>a. Fract a 0 = Fract 0 1"
    69   and "\<And>a c. Fract 0 a = Fract 0 c"
    70   by (transfer, simp)+
    71 
    72 lemma Rat_cases [case_names Fract, cases type: rat]:
    73   assumes "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    74   shows C
    75 proof -
    76   obtain a b :: int where "q = Fract a b" and "b \<noteq> 0"
    77     by transfer simp
    78   let ?a = "a div gcd a b"
    79   let ?b = "b div gcd a b"
    80   from `b \<noteq> 0` have "?b * gcd a b = b"
    81     by (simp add: dvd_div_mult_self)
    82   with `b \<noteq> 0` have "?b \<noteq> 0" by auto
    83   from `q = Fract a b` `b \<noteq> 0` `?b \<noteq> 0` have q: "q = Fract ?a ?b"
    84     by (simp add: eq_rat dvd_div_mult mult_commute [of a])
    85   from `b \<noteq> 0` have coprime: "coprime ?a ?b"
    86     by (auto intro: div_gcd_coprime_int)
    87   show C proof (cases "b > 0")
    88     case True
    89     note assms
    90     moreover note q
    91     moreover from True have "?b > 0" by (simp add: nonneg1_imp_zdiv_pos_iff)
    92     moreover note coprime
    93     ultimately show C .
    94   next
    95     case False
    96     note assms
    97     moreover have "q = Fract (- ?a) (- ?b)" unfolding q by transfer simp
    98     moreover from False `b \<noteq> 0` have "- ?b > 0" by (simp add: pos_imp_zdiv_neg_iff)
    99     moreover from coprime have "coprime (- ?a) (- ?b)" by simp
   100     ultimately show C .
   101   qed
   102 qed
   103 
   104 lemma Rat_induct [case_names Fract, induct type: rat]:
   105   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   106   shows "P q"
   107   using assms by (cases q) simp
   108 
   109 instantiation rat :: field_inverse_zero
   110 begin
   111 
   112 lift_definition zero_rat :: "rat" is "(0, 1)"
   113   by simp
   114 
   115 lift_definition one_rat :: "rat" is "(1, 1)"
   116   by simp
   117 
   118 lemma Zero_rat_def: "0 = Fract 0 1"
   119   by transfer simp
   120 
   121 lemma One_rat_def: "1 = Fract 1 1"
   122   by transfer simp
   123 
   124 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   125   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   126   by (clarsimp, simp add: distrib_right, simp add: mult_ac)
   127 
   128 lemma add_rat [simp]:
   129   assumes "b \<noteq> 0" and "d \<noteq> 0"
   130   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   131   using assms by transfer simp
   132 
   133 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   134   by simp
   135 
   136 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   137   by transfer simp
   138 
   139 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   140   by (cases "b = 0") (simp_all add: eq_rat)
   141 
   142 definition
   143   diff_rat_def: "q - r = q + - (r::rat)"
   144 
   145 lemma diff_rat [simp]:
   146   assumes "b \<noteq> 0" and "d \<noteq> 0"
   147   shows "Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   148   using assms by (simp add: diff_rat_def)
   149 
   150 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   151   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   152   by (simp add: mult_ac)
   153 
   154 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   155   by transfer simp
   156 
   157 lemma mult_rat_cancel:
   158   assumes "c \<noteq> 0"
   159   shows "Fract (c * a) (c * b) = Fract a b"
   160   using assms by transfer simp
   161 
   162 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   163   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   164   by (auto simp add: mult_commute)
   165 
   166 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   167   by transfer simp
   168 
   169 definition
   170   divide_rat_def: "q / r = q * inverse (r::rat)"
   171 
   172 lemma divide_rat [simp]: "Fract a b / Fract c d = Fract (a * d) (b * c)"
   173   by (simp add: divide_rat_def)
   174 
   175 instance proof
   176   fix q r s :: rat
   177   show "(q * r) * s = q * (r * s)"
   178     by transfer simp
   179   show "q * r = r * q"
   180     by transfer simp
   181   show "1 * q = q"
   182     by transfer simp
   183   show "(q + r) + s = q + (r + s)"
   184     by transfer (simp add: algebra_simps)
   185   show "q + r = r + q"
   186     by transfer simp
   187   show "0 + q = q"
   188     by transfer simp
   189   show "- q + q = 0"
   190     by transfer simp
   191   show "q - r = q + - r"
   192     by (fact diff_rat_def)
   193   show "(q + r) * s = q * s + r * s"
   194     by transfer (simp add: algebra_simps)
   195   show "(0::rat) \<noteq> 1"
   196     by transfer simp
   197   { assume "q \<noteq> 0" thus "inverse q * q = 1"
   198     by transfer simp }
   199   show "q / r = q * inverse r"
   200     by (fact divide_rat_def)
   201   show "inverse 0 = (0::rat)"
   202     by transfer simp
   203 qed
   204 
   205 end
   206 
   207 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   208   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   209 
   210 lemma of_int_rat: "of_int k = Fract k 1"
   211   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   212 
   213 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   214   by (rule of_nat_rat [symmetric])
   215 
   216 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   217   by (rule of_int_rat [symmetric])
   218 
   219 lemma rat_number_collapse:
   220   "Fract 0 k = 0"
   221   "Fract 1 1 = 1"
   222   "Fract (numeral w) 1 = numeral w"
   223   "Fract (neg_numeral w) 1 = neg_numeral w"
   224   "Fract k 0 = 0"
   225   using Fract_of_int_eq [of "numeral w"]
   226   using Fract_of_int_eq [of "neg_numeral w"]
   227   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   228 
   229 lemma rat_number_expand:
   230   "0 = Fract 0 1"
   231   "1 = Fract 1 1"
   232   "numeral k = Fract (numeral k) 1"
   233   "neg_numeral k = Fract (neg_numeral k) 1"
   234   by (simp_all add: rat_number_collapse)
   235 
   236 lemma Rat_cases_nonzero [case_names Fract 0]:
   237   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   238   assumes 0: "q = 0 \<Longrightarrow> C"
   239   shows C
   240 proof (cases "q = 0")
   241   case True then show C using 0 by auto
   242 next
   243   case False
   244   then obtain a b where "q = Fract a b" and "b > 0" and "coprime a b" by (cases q) auto
   245   moreover with False have "0 \<noteq> Fract a b" by simp
   246   with `b > 0` have "a \<noteq> 0" by (simp add: Zero_rat_def eq_rat)
   247   with Fract `q = Fract a b` `b > 0` `coprime a b` show C by blast
   248 qed
   249 
   250 subsubsection {* Function @{text normalize} *}
   251 
   252 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   253 proof (cases "b = 0")
   254   case True then show ?thesis by (simp add: eq_rat)
   255 next
   256   case False
   257   moreover have "b div gcd a b * gcd a b = b"
   258     by (rule dvd_div_mult_self) simp
   259   ultimately have "b div gcd a b \<noteq> 0" by auto
   260   with False show ?thesis by (simp add: eq_rat dvd_div_mult mult_commute [of a])
   261 qed
   262 
   263 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int" where
   264   "normalize p = (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   265     else if snd p = 0 then (0, 1)
   266     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   267 
   268 lemma normalize_crossproduct:
   269   assumes "q \<noteq> 0" "s \<noteq> 0"
   270   assumes "normalize (p, q) = normalize (r, s)"
   271   shows "p * s = r * q"
   272 proof -
   273   have aux: "p * gcd r s = sgn (q * s) * r * gcd p q \<Longrightarrow> q * gcd r s = sgn (q * s) * s * gcd p q \<Longrightarrow> p * s = q * r"
   274   proof -
   275     assume "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   276     then have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) = (q * gcd r s) * (sgn (q * s) * r * gcd p q)" by simp
   277     with assms show "p * s = q * r" by (auto simp add: mult_ac sgn_times sgn_0_0)
   278   qed
   279   from assms show ?thesis
   280     by (auto simp add: normalize_def Let_def dvd_div_div_eq_mult mult_commute sgn_times split: if_splits intro: aux)
   281 qed
   282 
   283 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   284   by (auto simp add: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   285     split:split_if_asm)
   286 
   287 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   288   by (auto simp add: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   289     split:split_if_asm)
   290 
   291 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   292   by (auto simp add: normalize_def Let_def dvd_div_neg div_gcd_coprime_int
   293     split:split_if_asm)
   294 
   295 lemma normalize_stable [simp]:
   296   "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   297   by (simp add: normalize_def)
   298 
   299 lemma normalize_denom_zero [simp]:
   300   "normalize (p, 0) = (0, 1)"
   301   by (simp add: normalize_def)
   302 
   303 lemma normalize_negative [simp]:
   304   "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   305   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   306 
   307 text{*
   308   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   309 *}
   310 
   311 definition quotient_of :: "rat \<Rightarrow> int \<times> int" where
   312   "quotient_of x = (THE pair. x = Fract (fst pair) (snd pair) &
   313                    snd pair > 0 & coprime (fst pair) (snd pair))"
   314 
   315 lemma quotient_of_unique:
   316   "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   317 proof (cases r)
   318   case (Fract a b)
   319   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and> snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))" by auto
   320   then show ?thesis proof (rule ex1I)
   321     fix p
   322     obtain c d :: int where p: "p = (c, d)" by (cases p)
   323     assume "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   324     with p have Fract': "r = Fract c d" "d > 0" "coprime c d" by simp_all
   325     have "c = a \<and> d = b"
   326     proof (cases "a = 0")
   327       case True with Fract Fract' show ?thesis by (simp add: eq_rat)
   328     next
   329       case False
   330       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0" by (auto simp add: eq_rat)
   331       then have "c * b > 0 \<longleftrightarrow> a * d > 0" by auto
   332       with `b > 0` `d > 0` have "a > 0 \<longleftrightarrow> c > 0" by (simp add: zero_less_mult_iff)
   333       with `a \<noteq> 0` `c \<noteq> 0` have sgn: "sgn a = sgn c" by (auto simp add: not_less)
   334       from `coprime a b` `coprime c d` have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   335         by (simp add: coprime_crossproduct_int)
   336       with `b > 0` `d > 0` have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b" by simp
   337       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b" by (simp add: abs_sgn)
   338       with sgn * show ?thesis by (auto simp add: sgn_0_0)
   339     qed
   340     with p show "p = (a, b)" by simp
   341   qed
   342 qed
   343 
   344 lemma quotient_of_Fract [code]:
   345   "quotient_of (Fract a b) = normalize (a, b)"
   346 proof -
   347   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   348     by (rule sym) (auto intro: normalize_eq)
   349   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos) 
   350     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   351   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   352     by (rule normalize_coprime) simp
   353   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   354   with quotient_of_unique have
   355     "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and> coprime (fst p) (snd p)) = normalize (a, b)"
   356     by (rule the1_equality)
   357   then show ?thesis by (simp add: quotient_of_def)
   358 qed
   359 
   360 lemma quotient_of_number [simp]:
   361   "quotient_of 0 = (0, 1)"
   362   "quotient_of 1 = (1, 1)"
   363   "quotient_of (numeral k) = (numeral k, 1)"
   364   "quotient_of (neg_numeral k) = (neg_numeral k, 1)"
   365   by (simp_all add: rat_number_expand quotient_of_Fract)
   366 
   367 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   368   by (simp add: quotient_of_Fract normalize_eq)
   369 
   370 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   371   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   372 
   373 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   374   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   375 
   376 lemma quotient_of_inject:
   377   assumes "quotient_of a = quotient_of b"
   378   shows "a = b"
   379 proof -
   380   obtain p q r s where a: "a = Fract p q"
   381     and b: "b = Fract r s"
   382     and "q > 0" and "s > 0" by (cases a, cases b)
   383   with assms show ?thesis by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   384 qed
   385 
   386 lemma quotient_of_inject_eq:
   387   "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   388   by (auto simp add: quotient_of_inject)
   389 
   390 
   391 subsubsection {* Various *}
   392 
   393 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   394   by (simp add: Fract_of_int_eq [symmetric])
   395 
   396 lemma Fract_add_one: "n \<noteq> 0 ==> Fract (m + n) n = Fract m n + 1"
   397   by (simp add: rat_number_expand)
   398 
   399 lemma quotient_of_div:
   400   assumes r: "quotient_of r = (n,d)"
   401   shows "r = of_int n / of_int d"
   402 proof -
   403   from theI'[OF quotient_of_unique[of r], unfolded r[unfolded quotient_of_def]]
   404   have "r = Fract n d" by simp
   405   thus ?thesis using Fract_of_int_quotient by simp
   406 qed
   407 
   408 subsubsection {* The ordered field of rational numbers *}
   409 
   410 lift_definition positive :: "rat \<Rightarrow> bool"
   411   is "\<lambda>x. 0 < fst x * snd x"
   412 proof (clarsimp)
   413   fix a b c d :: int
   414   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   415   hence "a * d * b * d = c * b * b * d"
   416     by simp
   417   hence "a * b * d\<twosuperior> = c * d * b\<twosuperior>"
   418     unfolding power2_eq_square by (simp add: mult_ac)
   419   hence "0 < a * b * d\<twosuperior> \<longleftrightarrow> 0 < c * d * b\<twosuperior>"
   420     by simp
   421   thus "0 < a * b \<longleftrightarrow> 0 < c * d"
   422     using `b \<noteq> 0` and `d \<noteq> 0`
   423     by (simp add: zero_less_mult_iff)
   424 qed
   425 
   426 lemma positive_zero: "\<not> positive 0"
   427   by transfer simp
   428 
   429 lemma positive_add:
   430   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   431 apply transfer
   432 apply (simp add: zero_less_mult_iff)
   433 apply (elim disjE, simp_all add: add_pos_pos add_neg_neg
   434   mult_pos_pos mult_pos_neg mult_neg_pos mult_neg_neg)
   435 done
   436 
   437 lemma positive_mult:
   438   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   439 by transfer (drule (1) mult_pos_pos, simp add: mult_ac)
   440 
   441 lemma positive_minus:
   442   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   443 by transfer (force simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   444 
   445 instantiation rat :: linordered_field_inverse_zero
   446 begin
   447 
   448 definition
   449   "x < y \<longleftrightarrow> positive (y - x)"
   450 
   451 definition
   452   "x \<le> (y::rat) \<longleftrightarrow> x < y \<or> x = y"
   453 
   454 definition
   455   "abs (a::rat) = (if a < 0 then - a else a)"
   456 
   457 definition
   458   "sgn (a::rat) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   459 
   460 instance proof
   461   fix a b c :: rat
   462   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   463     by (rule abs_rat_def)
   464   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   465     unfolding less_eq_rat_def less_rat_def
   466     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   467   show "a \<le> a"
   468     unfolding less_eq_rat_def by simp
   469   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   470     unfolding less_eq_rat_def less_rat_def
   471     by (auto, drule (1) positive_add, simp add: algebra_simps)
   472   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   473     unfolding less_eq_rat_def less_rat_def
   474     by (auto, drule (1) positive_add, simp add: positive_zero)
   475   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   476     unfolding less_eq_rat_def less_rat_def by (auto simp: diff_minus)
   477   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   478     by (rule sgn_rat_def)
   479   show "a \<le> b \<or> b \<le> a"
   480     unfolding less_eq_rat_def less_rat_def
   481     by (auto dest!: positive_minus)
   482   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   483     unfolding less_rat_def
   484     by (drule (1) positive_mult, simp add: algebra_simps)
   485 qed
   486 
   487 end
   488 
   489 instantiation rat :: distrib_lattice
   490 begin
   491 
   492 definition
   493   "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   494 
   495 definition
   496   "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   497 
   498 instance proof
   499 qed (auto simp add: inf_rat_def sup_rat_def min_max.sup_inf_distrib1)
   500 
   501 end
   502 
   503 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   504   by transfer simp
   505 
   506 lemma less_rat [simp]:
   507   assumes "b \<noteq> 0" and "d \<noteq> 0"
   508   shows "Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   509   using assms unfolding less_rat_def
   510   by (simp add: positive_rat algebra_simps)
   511 
   512 lemma le_rat [simp]:
   513   assumes "b \<noteq> 0" and "d \<noteq> 0"
   514   shows "Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   515   using assms unfolding le_less by (simp add: eq_rat)
   516 
   517 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   518   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   519 
   520 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   521   unfolding Fract_of_int_eq
   522   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   523     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   524 
   525 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   526   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   527   shows "P q"
   528 proof (cases q)
   529   have step': "\<And>a b. b < 0 \<Longrightarrow> P (Fract a b)"
   530   proof -
   531     fix a::int and b::int
   532     assume b: "b < 0"
   533     hence "0 < -b" by simp
   534     hence "P (Fract (-a) (-b))" by (rule step)
   535     thus "P (Fract a b)" by (simp add: order_less_imp_not_eq [OF b])
   536   qed
   537   case (Fract a b)
   538   thus "P q" by (force simp add: linorder_neq_iff step step')
   539 qed
   540 
   541 lemma zero_less_Fract_iff:
   542   "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   543   by (simp add: Zero_rat_def zero_less_mult_iff)
   544 
   545 lemma Fract_less_zero_iff:
   546   "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   547   by (simp add: Zero_rat_def mult_less_0_iff)
   548 
   549 lemma zero_le_Fract_iff:
   550   "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   551   by (simp add: Zero_rat_def zero_le_mult_iff)
   552 
   553 lemma Fract_le_zero_iff:
   554   "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   555   by (simp add: Zero_rat_def mult_le_0_iff)
   556 
   557 lemma one_less_Fract_iff:
   558   "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   559   by (simp add: One_rat_def mult_less_cancel_right_disj)
   560 
   561 lemma Fract_less_one_iff:
   562   "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   563   by (simp add: One_rat_def mult_less_cancel_right_disj)
   564 
   565 lemma one_le_Fract_iff:
   566   "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   567   by (simp add: One_rat_def mult_le_cancel_right)
   568 
   569 lemma Fract_le_one_iff:
   570   "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   571   by (simp add: One_rat_def mult_le_cancel_right)
   572 
   573 
   574 subsubsection {* Rationals are an Archimedean field *}
   575 
   576 lemma rat_floor_lemma:
   577   shows "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   578 proof -
   579   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   580     by (cases "b = 0", simp, simp add: of_int_rat)
   581   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   582     unfolding Fract_of_int_quotient
   583     by (rule linorder_cases [of b 0]) (simp add: divide_nonpos_neg, simp, simp add: divide_nonneg_pos)
   584   ultimately show ?thesis by simp
   585 qed
   586 
   587 instance rat :: archimedean_field
   588 proof
   589   fix r :: rat
   590   show "\<exists>z. r \<le> of_int z"
   591   proof (induct r)
   592     case (Fract a b)
   593     have "Fract a b \<le> of_int (a div b + 1)"
   594       using rat_floor_lemma [of a b] by simp
   595     then show "\<exists>z. Fract a b \<le> of_int z" ..
   596   qed
   597 qed
   598 
   599 instantiation rat :: floor_ceiling
   600 begin
   601 
   602 definition [code del]:
   603   "floor (x::rat) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   604 
   605 instance proof
   606   fix x :: rat
   607   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   608     unfolding floor_rat_def using floor_exists1 by (rule theI')
   609 qed
   610 
   611 end
   612 
   613 lemma floor_Fract: "floor (Fract a b) = a div b"
   614   using rat_floor_lemma [of a b]
   615   by (simp add: floor_unique)
   616 
   617 
   618 subsection {* Linear arithmetic setup *}
   619 
   620 declaration {*
   621   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   622     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   623   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   624     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   625   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   626       @{thm True_implies_equals},
   627       read_instantiate @{context} [(("a", 0), "(numeral ?v)")] @{thm distrib_left},
   628       read_instantiate @{context} [(("a", 0), "(neg_numeral ?v)")] @{thm distrib_left},
   629       @{thm divide_1}, @{thm divide_zero_left},
   630       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   631       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   632       @{thm of_int_minus}, @{thm of_int_diff},
   633       @{thm of_int_of_nat_eq}]
   634   #> Lin_Arith.add_simprocs Numeral_Simprocs.field_cancel_numeral_factors
   635   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat => rat"})
   636   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int => rat"}))
   637 *}
   638 
   639 
   640 subsection {* Embedding from Rationals to other Fields *}
   641 
   642 class field_char_0 = field + ring_char_0
   643 
   644 subclass (in linordered_field) field_char_0 ..
   645 
   646 context field_char_0
   647 begin
   648 
   649 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   650   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   651 apply (clarsimp simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   652 apply (simp only: of_int_mult [symmetric])
   653 done
   654 
   655 end
   656 
   657 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   658   by transfer simp
   659 
   660 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   661   by transfer simp
   662 
   663 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   664   by transfer simp
   665 
   666 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   667   by transfer (simp add: add_frac_eq)
   668 
   669 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   670   by transfer simp
   671 
   672 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   673 by (simp only: diff_minus of_rat_add of_rat_minus)
   674 
   675 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   676 apply transfer
   677 apply (simp add: divide_inverse nonzero_inverse_mult_distrib mult_ac)
   678 done
   679 
   680 lemma nonzero_of_rat_inverse:
   681   "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   682 apply (rule inverse_unique [symmetric])
   683 apply (simp add: of_rat_mult [symmetric])
   684 done
   685 
   686 lemma of_rat_inverse:
   687   "(of_rat (inverse a)::'a::{field_char_0, field_inverse_zero}) =
   688    inverse (of_rat a)"
   689 by (cases "a = 0", simp_all add: nonzero_of_rat_inverse)
   690 
   691 lemma nonzero_of_rat_divide:
   692   "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   693 by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   694 
   695 lemma of_rat_divide:
   696   "(of_rat (a / b)::'a::{field_char_0, field_inverse_zero})
   697    = of_rat a / of_rat b"
   698 by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   699 
   700 lemma of_rat_power:
   701   "(of_rat (a ^ n)::'a::field_char_0) = of_rat a ^ n"
   702 by (induct n) (simp_all add: of_rat_mult)
   703 
   704 lemma of_rat_eq_iff [simp]: "(of_rat a = of_rat b) = (a = b)"
   705 apply transfer
   706 apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   707 apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   708 done
   709 
   710 lemma of_rat_less:
   711   "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   712 proof (induct r, induct s)
   713   fix a b c d :: int
   714   assume not_zero: "b > 0" "d > 0"
   715   then have "b * d > 0" by (rule mult_pos_pos)
   716   have of_int_divide_less_eq:
   717     "(of_int a :: 'a) / of_int b < of_int c / of_int d
   718       \<longleftrightarrow> (of_int a :: 'a) * of_int d < of_int c * of_int b"
   719     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   720   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d)
   721     \<longleftrightarrow> Fract a b < Fract c d"
   722     using not_zero `b * d > 0`
   723     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   724 qed
   725 
   726 lemma of_rat_less_eq:
   727   "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   728   unfolding le_less by (auto simp add: of_rat_less)
   729 
   730 lemmas of_rat_eq_0_iff [simp] = of_rat_eq_iff [of _ 0, simplified]
   731 
   732 lemma of_rat_eq_id [simp]: "of_rat = id"
   733 proof
   734   fix a
   735   show "of_rat a = id a"
   736   by (induct a)
   737      (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   738 qed
   739 
   740 text{*Collapse nested embeddings*}
   741 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   742 by (induct n) (simp_all add: of_rat_add)
   743 
   744 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   745 by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   746 
   747 lemma of_rat_numeral_eq [simp]:
   748   "of_rat (numeral w) = numeral w"
   749 using of_rat_of_int_eq [of "numeral w"] by simp
   750 
   751 lemma of_rat_neg_numeral_eq [simp]:
   752   "of_rat (neg_numeral w) = neg_numeral w"
   753 using of_rat_of_int_eq [of "neg_numeral w"] by simp
   754 
   755 lemmas zero_rat = Zero_rat_def
   756 lemmas one_rat = One_rat_def
   757 
   758 abbreviation
   759   rat_of_nat :: "nat \<Rightarrow> rat"
   760 where
   761   "rat_of_nat \<equiv> of_nat"
   762 
   763 abbreviation
   764   rat_of_int :: "int \<Rightarrow> rat"
   765 where
   766   "rat_of_int \<equiv> of_int"
   767 
   768 subsection {* The Set of Rational Numbers *}
   769 
   770 context field_char_0
   771 begin
   772 
   773 definition
   774   Rats  :: "'a set" where
   775   "Rats = range of_rat"
   776 
   777 notation (xsymbols)
   778   Rats  ("\<rat>")
   779 
   780 end
   781 
   782 lemma Rats_of_rat [simp]: "of_rat r \<in> Rats"
   783 by (simp add: Rats_def)
   784 
   785 lemma Rats_of_int [simp]: "of_int z \<in> Rats"
   786 by (subst of_rat_of_int_eq [symmetric], rule Rats_of_rat)
   787 
   788 lemma Rats_of_nat [simp]: "of_nat n \<in> Rats"
   789 by (subst of_rat_of_nat_eq [symmetric], rule Rats_of_rat)
   790 
   791 lemma Rats_number_of [simp]: "numeral w \<in> Rats"
   792 by (subst of_rat_numeral_eq [symmetric], rule Rats_of_rat)
   793 
   794 lemma Rats_neg_number_of [simp]: "neg_numeral w \<in> Rats"
   795 by (subst of_rat_neg_numeral_eq [symmetric], rule Rats_of_rat)
   796 
   797 lemma Rats_0 [simp]: "0 \<in> Rats"
   798 apply (unfold Rats_def)
   799 apply (rule range_eqI)
   800 apply (rule of_rat_0 [symmetric])
   801 done
   802 
   803 lemma Rats_1 [simp]: "1 \<in> Rats"
   804 apply (unfold Rats_def)
   805 apply (rule range_eqI)
   806 apply (rule of_rat_1 [symmetric])
   807 done
   808 
   809 lemma Rats_add [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a + b \<in> Rats"
   810 apply (auto simp add: Rats_def)
   811 apply (rule range_eqI)
   812 apply (rule of_rat_add [symmetric])
   813 done
   814 
   815 lemma Rats_minus [simp]: "a \<in> Rats \<Longrightarrow> - a \<in> Rats"
   816 apply (auto simp add: Rats_def)
   817 apply (rule range_eqI)
   818 apply (rule of_rat_minus [symmetric])
   819 done
   820 
   821 lemma Rats_diff [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a - b \<in> Rats"
   822 apply (auto simp add: Rats_def)
   823 apply (rule range_eqI)
   824 apply (rule of_rat_diff [symmetric])
   825 done
   826 
   827 lemma Rats_mult [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a * b \<in> Rats"
   828 apply (auto simp add: Rats_def)
   829 apply (rule range_eqI)
   830 apply (rule of_rat_mult [symmetric])
   831 done
   832 
   833 lemma nonzero_Rats_inverse:
   834   fixes a :: "'a::field_char_0"
   835   shows "\<lbrakk>a \<in> Rats; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Rats"
   836 apply (auto simp add: Rats_def)
   837 apply (rule range_eqI)
   838 apply (erule nonzero_of_rat_inverse [symmetric])
   839 done
   840 
   841 lemma Rats_inverse [simp]:
   842   fixes a :: "'a::{field_char_0, field_inverse_zero}"
   843   shows "a \<in> Rats \<Longrightarrow> inverse a \<in> Rats"
   844 apply (auto simp add: Rats_def)
   845 apply (rule range_eqI)
   846 apply (rule of_rat_inverse [symmetric])
   847 done
   848 
   849 lemma nonzero_Rats_divide:
   850   fixes a b :: "'a::field_char_0"
   851   shows "\<lbrakk>a \<in> Rats; b \<in> Rats; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   852 apply (auto simp add: Rats_def)
   853 apply (rule range_eqI)
   854 apply (erule nonzero_of_rat_divide [symmetric])
   855 done
   856 
   857 lemma Rats_divide [simp]:
   858   fixes a b :: "'a::{field_char_0, field_inverse_zero}"
   859   shows "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   860 apply (auto simp add: Rats_def)
   861 apply (rule range_eqI)
   862 apply (rule of_rat_divide [symmetric])
   863 done
   864 
   865 lemma Rats_power [simp]:
   866   fixes a :: "'a::field_char_0"
   867   shows "a \<in> Rats \<Longrightarrow> a ^ n \<in> Rats"
   868 apply (auto simp add: Rats_def)
   869 apply (rule range_eqI)
   870 apply (rule of_rat_power [symmetric])
   871 done
   872 
   873 lemma Rats_cases [cases set: Rats]:
   874   assumes "q \<in> \<rat>"
   875   obtains (of_rat) r where "q = of_rat r"
   876 proof -
   877   from `q \<in> \<rat>` have "q \<in> range of_rat" unfolding Rats_def .
   878   then obtain r where "q = of_rat r" ..
   879   then show thesis ..
   880 qed
   881 
   882 lemma Rats_induct [case_names of_rat, induct set: Rats]:
   883   "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   884   by (rule Rats_cases) auto
   885 
   886 
   887 subsection {* Implementation of rational numbers as pairs of integers *}
   888 
   889 text {* Formal constructor *}
   890 
   891 definition Frct :: "int \<times> int \<Rightarrow> rat" where
   892   [simp]: "Frct p = Fract (fst p) (snd p)"
   893 
   894 lemma [code abstype]:
   895   "Frct (quotient_of q) = q"
   896   by (cases q) (auto intro: quotient_of_eq)
   897 
   898 
   899 text {* Numerals *}
   900 
   901 declare quotient_of_Fract [code abstract]
   902 
   903 definition of_int :: "int \<Rightarrow> rat"
   904 where
   905   [code_abbrev]: "of_int = Int.of_int"
   906 hide_const (open) of_int
   907 
   908 lemma quotient_of_int [code abstract]:
   909   "quotient_of (Rat.of_int a) = (a, 1)"
   910   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   911 
   912 lemma [code_unfold]:
   913   "numeral k = Rat.of_int (numeral k)"
   914   by (simp add: Rat.of_int_def)
   915 
   916 lemma [code_unfold]:
   917   "neg_numeral k = Rat.of_int (neg_numeral k)"
   918   by (simp add: Rat.of_int_def)
   919 
   920 lemma Frct_code_post [code_post]:
   921   "Frct (0, a) = 0"
   922   "Frct (a, 0) = 0"
   923   "Frct (1, 1) = 1"
   924   "Frct (numeral k, 1) = numeral k"
   925   "Frct (neg_numeral k, 1) = neg_numeral k"
   926   "Frct (1, numeral k) = 1 / numeral k"
   927   "Frct (1, neg_numeral k) = 1 / neg_numeral k"
   928   "Frct (numeral k, numeral l) = numeral k / numeral l"
   929   "Frct (numeral k, neg_numeral l) = numeral k / neg_numeral l"
   930   "Frct (neg_numeral k, numeral l) = neg_numeral k / numeral l"
   931   "Frct (neg_numeral k, neg_numeral l) = neg_numeral k / neg_numeral l"
   932   by (simp_all add: Fract_of_int_quotient)
   933 
   934 
   935 text {* Operations *}
   936 
   937 lemma rat_zero_code [code abstract]:
   938   "quotient_of 0 = (0, 1)"
   939   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   940 
   941 lemma rat_one_code [code abstract]:
   942   "quotient_of 1 = (1, 1)"
   943   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   944 
   945 lemma rat_plus_code [code abstract]:
   946   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   947      in normalize (a * d + b * c, c * d))"
   948   by (cases p, cases q) (simp add: quotient_of_Fract)
   949 
   950 lemma rat_uminus_code [code abstract]:
   951   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   952   by (cases p) (simp add: quotient_of_Fract)
   953 
   954 lemma rat_minus_code [code abstract]:
   955   "quotient_of (p - q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   956      in normalize (a * d - b * c, c * d))"
   957   by (cases p, cases q) (simp add: quotient_of_Fract)
   958 
   959 lemma rat_times_code [code abstract]:
   960   "quotient_of (p * q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   961      in normalize (a * b, c * d))"
   962   by (cases p, cases q) (simp add: quotient_of_Fract)
   963 
   964 lemma rat_inverse_code [code abstract]:
   965   "quotient_of (inverse p) = (let (a, b) = quotient_of p
   966     in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
   967 proof (cases p)
   968   case (Fract a b) then show ?thesis
   969     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd_int.commute)
   970 qed
   971 
   972 lemma rat_divide_code [code abstract]:
   973   "quotient_of (p / q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   974      in normalize (a * d, c * b))"
   975   by (cases p, cases q) (simp add: quotient_of_Fract)
   976 
   977 lemma rat_abs_code [code abstract]:
   978   "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
   979   by (cases p) (simp add: quotient_of_Fract)
   980 
   981 lemma rat_sgn_code [code abstract]:
   982   "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
   983 proof (cases p)
   984   case (Fract a b) then show ?thesis
   985   by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
   986 qed
   987 
   988 lemma rat_floor_code [code]:
   989   "floor p = (let (a, b) = quotient_of p in a div b)"
   990 by (cases p) (simp add: quotient_of_Fract floor_Fract)
   991 
   992 instantiation rat :: equal
   993 begin
   994 
   995 definition [code]:
   996   "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
   997 
   998 instance proof
   999 qed (simp add: equal_rat_def quotient_of_inject_eq)
  1000 
  1001 lemma rat_eq_refl [code nbe]:
  1002   "HOL.equal (r::rat) r \<longleftrightarrow> True"
  1003   by (rule equal_refl)
  1004 
  1005 end
  1006 
  1007 lemma rat_less_eq_code [code]:
  1008   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1009   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1010 
  1011 lemma rat_less_code [code]:
  1012   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1013   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1014 
  1015 lemma [code]:
  1016   "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1017   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1018 
  1019 
  1020 text {* Quickcheck *}
  1021 
  1022 definition (in term_syntax)
  1023   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> rat \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1024   [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1025 
  1026 notation fcomp (infixl "\<circ>>" 60)
  1027 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1028 
  1029 instantiation rat :: random
  1030 begin
  1031 
  1032 definition
  1033   "Quickcheck.random i = Quickcheck.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair (
  1034      let j = Code_Numeral.int_of (denom + 1)
  1035      in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1036 
  1037 instance ..
  1038 
  1039 end
  1040 
  1041 no_notation fcomp (infixl "\<circ>>" 60)
  1042 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1043 
  1044 instantiation rat :: exhaustive
  1045 begin
  1046 
  1047 definition
  1048   "exhaustive_rat f d = Quickcheck_Exhaustive.exhaustive (%l. Quickcheck_Exhaustive.exhaustive (%k. f (Fract k (Code_Numeral.int_of l + 1))) d) d"
  1049 
  1050 instance ..
  1051 
  1052 end
  1053 
  1054 instantiation rat :: full_exhaustive
  1055 begin
  1056 
  1057 definition
  1058   "full_exhaustive_rat f d = Quickcheck_Exhaustive.full_exhaustive (%(l, _). Quickcheck_Exhaustive.full_exhaustive (%k.
  1059      f (let j = Code_Numeral.int_of l + 1
  1060         in valterm_fract k (j, %_. Code_Evaluation.term_of j))) d) d"
  1061 
  1062 instance ..
  1063 
  1064 end
  1065 
  1066 instantiation rat :: partial_term_of
  1067 begin
  1068 
  1069 instance ..
  1070 
  1071 end
  1072 
  1073 lemma [code]:
  1074   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) == Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1075   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) ==
  1076      Code_Evaluation.App (Code_Evaluation.Const (STR ''Rat.Frct'')
  1077      (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1078         Typerep.Typerep (STR ''Rat.rat'') []])) (Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.Const (STR ''Product_Type.Pair'') (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]])) (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1079 by (rule partial_term_of_anything)+
  1080 
  1081 instantiation rat :: narrowing
  1082 begin
  1083 
  1084 definition
  1085   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.apply
  1086     (Quickcheck_Narrowing.cons (%nom denom. Fract nom denom)) narrowing) narrowing"
  1087 
  1088 instance ..
  1089 
  1090 end
  1091 
  1092 
  1093 subsection {* Setup for Nitpick *}
  1094 
  1095 declaration {*
  1096   Nitpick_HOL.register_frac_type @{type_name rat}
  1097    [(@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1098     (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1099     (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1100     (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1101     (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1102     (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1103     (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1104     (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1105     (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1106 *}
  1107 
  1108 lemmas [nitpick_unfold] = inverse_rat_inst.inverse_rat
  1109   one_rat_inst.one_rat ord_rat_inst.less_rat
  1110   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1111   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1112 
  1113 subsection{* Float syntax *}
  1114 
  1115 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1116 
  1117 ML_file "Tools/float_syntax.ML"
  1118 setup Float_Syntax.setup
  1119 
  1120 text{* Test: *}
  1121 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1122 by simp
  1123 
  1124 
  1125 hide_const (open) normalize positive
  1126 
  1127 lemmas [transfer_rule del] =
  1128   rat.All_transfer rat.Ex_transfer rat.rel_eq_transfer forall_rat_transfer
  1129   Fract.transfer zero_rat.transfer one_rat.transfer plus_rat.transfer
  1130   uminus_rat.transfer times_rat.transfer inverse_rat.transfer
  1131   positive.transfer of_rat.transfer
  1132 
  1133 text {* De-register @{text "rat"} as a quotient type: *}
  1134 
  1135 declare Quotient_rat[quot_del]
  1136 
  1137 end