src/HOL/SEQ.thy
author hoelzl
Thu Jan 31 11:31:27 2013 +0100 (2013-01-31)
changeset 50999 3de230ed0547
parent 50937 d249ef928ae1
child 51328 d63ec23c9125
permissions -rw-r--r--
introduce order topology
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits RComplete
    14 begin
    15 
    16 subsection {* Monotone sequences and subsequences *}
    17 
    18 definition
    19   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
    20     --{*Definition of monotonicity.
    21         The use of disjunction here complicates proofs considerably.
    22         One alternative is to add a Boolean argument to indicate the direction.
    23         Another is to develop the notions of increasing and decreasing first.*}
    24   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    25 
    26 definition
    27   incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
    28     --{*Increasing sequence*}
    29   "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    30 
    31 definition
    32   decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
    33     --{*Decreasing sequence*}
    34   "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    35 
    36 definition
    37   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
    38     --{*Definition of subsequence*}
    39   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
    40 
    41 lemma incseq_mono: "mono f \<longleftrightarrow> incseq f"
    42   unfolding mono_def incseq_def by auto
    43 
    44 lemma incseq_SucI:
    45   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
    46   using lift_Suc_mono_le[of X]
    47   by (auto simp: incseq_def)
    48 
    49 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
    50   by (auto simp: incseq_def)
    51 
    52 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
    53   using incseqD[of A i "Suc i"] by auto
    54 
    55 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
    56   by (auto intro: incseq_SucI dest: incseq_SucD)
    57 
    58 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
    59   unfolding incseq_def by auto
    60 
    61 lemma decseq_SucI:
    62   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
    63   using order.lift_Suc_mono_le[OF dual_order, of X]
    64   by (auto simp: decseq_def)
    65 
    66 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
    67   by (auto simp: decseq_def)
    68 
    69 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
    70   using decseqD[of A i "Suc i"] by auto
    71 
    72 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
    73   by (auto intro: decseq_SucI dest: decseq_SucD)
    74 
    75 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
    76   unfolding decseq_def by auto
    77 
    78 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
    79   unfolding monoseq_def incseq_def decseq_def ..
    80 
    81 lemma monoseq_Suc:
    82   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
    83   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
    84 
    85 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
    86 by (simp add: monoseq_def)
    87 
    88 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
    89 by (simp add: monoseq_def)
    90 
    91 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
    92 by (simp add: monoseq_Suc)
    93 
    94 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
    95 by (simp add: monoseq_Suc)
    96 
    97 lemma monoseq_minus:
    98   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
    99   assumes "monoseq a"
   100   shows "monoseq (\<lambda> n. - a n)"
   101 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   102   case True
   103   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   104   thus ?thesis by (rule monoI2)
   105 next
   106   case False
   107   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   108   thus ?thesis by (rule monoI1)
   109 qed
   110 
   111 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   112 
   113 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   114 apply (simp add: subseq_def)
   115 apply (auto dest!: less_imp_Suc_add)
   116 apply (induct_tac k)
   117 apply (auto intro: less_trans)
   118 done
   119 
   120 text{* for any sequence, there is a monotonic subsequence *}
   121 lemma seq_monosub:
   122   fixes s :: "nat => 'a::linorder"
   123   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   124 proof cases
   125   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
   126   assume *: "\<forall>n. \<exists>p. ?P p n"
   127   def f \<equiv> "nat_rec (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
   128   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
   129   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
   130   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
   131   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
   132   then have "subseq f" unfolding subseq_Suc_iff by auto
   133   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
   134   proof (intro disjI2 allI)
   135     fix n show "s (f (Suc n)) \<le> s (f n)"
   136     proof (cases n)
   137       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
   138     next
   139       case (Suc m)
   140       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
   141       with P_Suc Suc show ?thesis by simp
   142     qed
   143   qed
   144   ultimately show ?thesis by auto
   145 next
   146   let "?P p m" = "m < p \<and> s m < s p"
   147   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
   148   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
   149   def f \<equiv> "nat_rec (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
   150   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
   151   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
   152   have P_0: "?P (f 0) (Suc N)"
   153     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
   154   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
   155       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
   156   note P' = this
   157   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
   158       by (induct i) (insert P_0 P', auto) }
   159   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
   160     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
   161   then show ?thesis by auto
   162 qed
   163 
   164 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   165 proof(induct n)
   166   case 0 thus ?case by simp
   167 next
   168   case (Suc n)
   169   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   170   have "n < f (Suc n)" by arith
   171   thus ?case by arith
   172 qed
   173 
   174 lemma eventually_subseq:
   175   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
   176   unfolding eventually_sequentially by (metis seq_suble le_trans)
   177 
   178 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
   179   unfolding filterlim_iff by (metis eventually_subseq)
   180 
   181 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
   182   unfolding subseq_def by simp
   183 
   184 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
   185   using assms by (auto simp: subseq_def)
   186 
   187 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   188   by (simp add: incseq_def monoseq_def)
   189 
   190 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   191   by (simp add: decseq_def monoseq_def)
   192 
   193 lemma decseq_eq_incseq:
   194   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
   195   by (simp add: decseq_def incseq_def)
   196 
   197 lemma INT_decseq_offset:
   198   assumes "decseq F"
   199   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
   200 proof safe
   201   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
   202   show "x \<in> F i"
   203   proof cases
   204     from x have "x \<in> F n" by auto
   205     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
   206       unfolding decseq_def by simp
   207     finally show ?thesis .
   208   qed (insert x, simp)
   209 qed auto
   210 
   211 subsection {* Defintions of limits *}
   212 
   213 abbreviation (in topological_space)
   214   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   215     ("((_)/ ----> (_))" [60, 60] 60) where
   216   "X ----> L \<equiv> (X ---> L) sequentially"
   217 
   218 definition
   219   lim :: "(nat \<Rightarrow> 'a::t2_space) \<Rightarrow> 'a" where
   220     --{*Standard definition of limit using choice operator*}
   221   "lim X = (THE L. X ----> L)"
   222 
   223 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   224   "convergent X = (\<exists>L. X ----> L)"
   225 
   226 definition
   227   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
   228     --{*Standard definition for bounded sequence*}
   229   "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
   230 
   231 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   232   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
   233 
   234 
   235 subsection {* Bounded Sequences *}
   236 
   237 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
   238 unfolding Bseq_def
   239 proof (intro exI conjI allI)
   240   show "0 < max K 1" by simp
   241 next
   242   fix n::nat
   243   have "norm (X n) \<le> K" by (rule K)
   244   thus "norm (X n) \<le> max K 1" by simp
   245 qed
   246 
   247 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   248 unfolding Bseq_def by auto
   249 
   250 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
   251 proof (rule BseqI')
   252   let ?A = "norm ` X ` {..N}"
   253   have 1: "finite ?A" by simp
   254   fix n::nat
   255   show "norm (X n) \<le> max K (Max ?A)"
   256   proof (cases rule: linorder_le_cases)
   257     assume "n \<ge> N"
   258     hence "norm (X n) \<le> K" using K by simp
   259     thus "norm (X n) \<le> max K (Max ?A)" by simp
   260   next
   261     assume "n \<le> N"
   262     hence "norm (X n) \<in> ?A" by simp
   263     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
   264     thus "norm (X n) \<le> max K (Max ?A)" by simp
   265   qed
   266 qed
   267 
   268 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   269 unfolding Bseq_def by auto
   270 
   271 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   272 apply (erule BseqE)
   273 apply (rule_tac N="k" and K="K" in BseqI2')
   274 apply clarify
   275 apply (drule_tac x="n - k" in spec, simp)
   276 done
   277 
   278 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   279 unfolding Bfun_def eventually_sequentially
   280 apply (rule iffI)
   281 apply (simp add: Bseq_def)
   282 apply (auto intro: BseqI2')
   283 done
   284 
   285 
   286 subsection {* Limits of Sequences *}
   287 
   288 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   289   by simp
   290 
   291 lemma LIMSEQ_def: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
   292 unfolding tendsto_iff eventually_sequentially ..
   293 
   294 lemma LIMSEQ_iff:
   295   fixes L :: "'a::real_normed_vector"
   296   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   297 unfolding LIMSEQ_def dist_norm ..
   298 
   299 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   300   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
   301 
   302 lemma metric_LIMSEQ_I:
   303   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   304 by (simp add: LIMSEQ_def)
   305 
   306 lemma metric_LIMSEQ_D:
   307   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   308 by (simp add: LIMSEQ_def)
   309 
   310 lemma LIMSEQ_I:
   311   fixes L :: "'a::real_normed_vector"
   312   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   313 by (simp add: LIMSEQ_iff)
   314 
   315 lemma LIMSEQ_D:
   316   fixes L :: "'a::real_normed_vector"
   317   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   318 by (simp add: LIMSEQ_iff)
   319 
   320 lemma LIMSEQ_const_iff:
   321   fixes k l :: "'a::t2_space"
   322   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   323   using trivial_limit_sequentially by (rule tendsto_const_iff)
   324 
   325 lemma LIMSEQ_ignore_initial_segment:
   326   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   327 apply (rule topological_tendstoI)
   328 apply (drule (2) topological_tendstoD)
   329 apply (simp only: eventually_sequentially)
   330 apply (erule exE, rename_tac N)
   331 apply (rule_tac x=N in exI)
   332 apply simp
   333 done
   334 
   335 lemma LIMSEQ_offset:
   336   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   337 apply (rule topological_tendstoI)
   338 apply (drule (2) topological_tendstoD)
   339 apply (simp only: eventually_sequentially)
   340 apply (erule exE, rename_tac N)
   341 apply (rule_tac x="N + k" in exI)
   342 apply clarify
   343 apply (drule_tac x="n - k" in spec)
   344 apply (simp add: le_diff_conv2)
   345 done
   346 
   347 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   348 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   349 
   350 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   351 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   352 
   353 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   354 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   355 
   356 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   357   unfolding tendsto_def eventually_sequentially
   358   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   359 
   360 lemma LIMSEQ_unique:
   361   fixes a b :: "'a::t2_space"
   362   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   363   using trivial_limit_sequentially by (rule tendsto_unique)
   364 
   365 lemma increasing_LIMSEQ:
   366   fixes f :: "nat \<Rightarrow> real"
   367   assumes inc: "\<And>n. f n \<le> f (Suc n)"
   368       and bdd: "\<And>n. f n \<le> l"
   369       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   370   shows "f ----> l"
   371 proof (rule increasing_tendsto)
   372   fix x assume "x < l"
   373   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
   374     by auto
   375   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
   376     by (auto simp: field_simps)
   377   with `e < l - x` `0 < e` have "x < f n" by simp
   378   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
   379     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
   380 qed (insert bdd, auto)
   381 
   382 lemma Bseq_inverse_lemma:
   383   fixes x :: "'a::real_normed_div_algebra"
   384   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   385 apply (subst nonzero_norm_inverse, clarsimp)
   386 apply (erule (1) le_imp_inverse_le)
   387 done
   388 
   389 lemma Bseq_inverse:
   390   fixes a :: "'a::real_normed_div_algebra"
   391   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   392 unfolding Bseq_conv_Bfun by (rule Bfun_inverse)
   393 
   394 lemma LIMSEQ_diff_approach_zero:
   395   fixes L :: "'a::real_normed_vector"
   396   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   397   by (drule (1) tendsto_add, simp)
   398 
   399 lemma LIMSEQ_diff_approach_zero2:
   400   fixes L :: "'a::real_normed_vector"
   401   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
   402   by (drule (1) tendsto_diff, simp)
   403 
   404 text{*An unbounded sequence's inverse tends to 0*}
   405 
   406 lemma LIMSEQ_inverse_zero:
   407   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   408   apply (rule filterlim_compose[OF tendsto_inverse_0])
   409   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
   410   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
   411   done
   412 
   413 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   414 
   415 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   416   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
   417             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
   418 
   419 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   420 infinity is now easily proved*}
   421 
   422 lemma LIMSEQ_inverse_real_of_nat_add:
   423      "(%n. r + inverse(real(Suc n))) ----> r"
   424   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
   425 
   426 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   427      "(%n. r + -inverse(real(Suc n))) ----> r"
   428   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
   429   by auto
   430 
   431 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   432      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   433   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
   434   by auto
   435 
   436 lemma LIMSEQ_le_const:
   437   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   438   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
   439 
   440 lemma LIMSEQ_le:
   441   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
   442   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
   443 
   444 lemma LIMSEQ_le_const2:
   445   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   446   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
   447 
   448 subsection {* Convergence *}
   449 
   450 lemma limI: "X ----> L ==> lim X = L"
   451 apply (simp add: lim_def)
   452 apply (blast intro: LIMSEQ_unique)
   453 done
   454 
   455 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   456 by (simp add: convergent_def)
   457 
   458 lemma convergentI: "(X ----> L) ==> convergent X"
   459 by (auto simp add: convergent_def)
   460 
   461 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   462 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   463 
   464 lemma convergent_const: "convergent (\<lambda>n. c)"
   465   by (rule convergentI, rule tendsto_const)
   466 
   467 lemma convergent_add:
   468   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
   469   assumes "convergent (\<lambda>n. X n)"
   470   assumes "convergent (\<lambda>n. Y n)"
   471   shows "convergent (\<lambda>n. X n + Y n)"
   472   using assms unfolding convergent_def by (fast intro: tendsto_add)
   473 
   474 lemma convergent_setsum:
   475   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
   476   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
   477   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
   478 proof (cases "finite A")
   479   case True from this and assms show ?thesis
   480     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
   481 qed (simp add: convergent_const)
   482 
   483 lemma (in bounded_linear) convergent:
   484   assumes "convergent (\<lambda>n. X n)"
   485   shows "convergent (\<lambda>n. f (X n))"
   486   using assms unfolding convergent_def by (fast intro: tendsto)
   487 
   488 lemma (in bounded_bilinear) convergent:
   489   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
   490   shows "convergent (\<lambda>n. X n ** Y n)"
   491   using assms unfolding convergent_def by (fast intro: tendsto)
   492 
   493 lemma convergent_minus_iff:
   494   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   495   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   496 apply (simp add: convergent_def)
   497 apply (auto dest: tendsto_minus)
   498 apply (drule tendsto_minus, auto)
   499 done
   500 
   501 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::real)) \<Longrightarrow> lim f \<le> x"
   502   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
   503 
   504 lemma monoseq_le:
   505   "monoseq a \<Longrightarrow> a ----> (x::real) \<Longrightarrow>
   506     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   507   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
   508 
   509 lemma LIMSEQ_subseq_LIMSEQ:
   510   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   511   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
   512 
   513 lemma convergent_subseq_convergent:
   514   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
   515   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
   516 
   517 
   518 subsection {* Bounded Monotonic Sequences *}
   519 
   520 text{*Bounded Sequence*}
   521 
   522 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   523 by (simp add: Bseq_def)
   524 
   525 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   526 by (auto simp add: Bseq_def)
   527 
   528 lemma lemma_NBseq_def:
   529   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   530 proof safe
   531   fix K :: real
   532   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   533   then have "K \<le> real (Suc n)" by auto
   534   moreover assume "\<forall>m. norm (X m) \<le> K"
   535   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   536     by (blast intro: order_trans)
   537   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   538 qed (force simp add: real_of_nat_Suc)
   539 
   540 text{* alternative definition for Bseq *}
   541 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   542 apply (simp add: Bseq_def)
   543 apply (simp (no_asm) add: lemma_NBseq_def)
   544 done
   545 
   546 lemma lemma_NBseq_def2:
   547      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   548 apply (subst lemma_NBseq_def, auto)
   549 apply (rule_tac x = "Suc N" in exI)
   550 apply (rule_tac [2] x = N in exI)
   551 apply (auto simp add: real_of_nat_Suc)
   552  prefer 2 apply (blast intro: order_less_imp_le)
   553 apply (drule_tac x = n in spec, simp)
   554 done
   555 
   556 (* yet another definition for Bseq *)
   557 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   558 by (simp add: Bseq_def lemma_NBseq_def2)
   559 
   560 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   561 
   562 text{*alternative formulation for boundedness*}
   563 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   564 apply (unfold Bseq_def, safe)
   565 apply (rule_tac [2] x = "k + norm x" in exI)
   566 apply (rule_tac x = K in exI, simp)
   567 apply (rule exI [where x = 0], auto)
   568 apply (erule order_less_le_trans, simp)
   569 apply (drule_tac x=n in spec, fold diff_minus)
   570 apply (drule order_trans [OF norm_triangle_ineq2])
   571 apply simp
   572 done
   573 
   574 text{*alternative formulation for boundedness*}
   575 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   576 apply safe
   577 apply (simp add: Bseq_def, safe)
   578 apply (rule_tac x = "K + norm (X N)" in exI)
   579 apply auto
   580 apply (erule order_less_le_trans, simp)
   581 apply (rule_tac x = N in exI, safe)
   582 apply (drule_tac x = n in spec)
   583 apply (rule order_trans [OF norm_triangle_ineq], simp)
   584 apply (auto simp add: Bseq_iff2)
   585 done
   586 
   587 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   588 apply (simp add: Bseq_def)
   589 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   590 apply (drule_tac x = n in spec, arith)
   591 done
   592 
   593 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   594 
   595 lemma Bseq_isUb:
   596   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   597 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   598 
   599 text{* Use completeness of reals (supremum property)
   600    to show that any bounded sequence has a least upper bound*}
   601 
   602 lemma Bseq_isLub:
   603   "!!(X::nat=>real). Bseq X ==>
   604    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   605 by (blast intro: reals_complete Bseq_isUb)
   606 
   607 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   608 
   609 (* TODO: delete *)
   610 (* FIXME: one use in NSA/HSEQ.thy *)
   611 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   612 unfolding tendsto_def eventually_sequentially
   613 apply (rule_tac x = "X m" in exI, safe)
   614 apply (rule_tac x = m in exI, safe)
   615 apply (drule spec, erule impE, auto)
   616 done
   617 
   618 text {* A monotone sequence converges to its least upper bound. *}
   619 
   620 lemma isLub_mono_imp_LIMSEQ:
   621   fixes X :: "nat \<Rightarrow> real"
   622   assumes u: "isLub UNIV {x. \<exists>n. X n = x} u" (* FIXME: use 'range X' *)
   623   assumes X: "\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n"
   624   shows "X ----> u"
   625 proof (rule LIMSEQ_I)
   626   have 1: "\<forall>n. X n \<le> u"
   627     using isLubD2 [OF u] by auto
   628   have "\<forall>y. (\<forall>n. X n \<le> y) \<longrightarrow> u \<le> y"
   629     using isLub_le_isUb [OF u] by (auto simp add: isUb_def setle_def)
   630   hence 2: "\<forall>y<u. \<exists>n. y < X n"
   631     by (metis not_le)
   632   fix r :: real assume "0 < r"
   633   hence "u - r < u" by simp
   634   hence "\<exists>m. u - r < X m" using 2 by simp
   635   then obtain m where "u - r < X m" ..
   636   with X have "\<forall>n\<ge>m. u - r < X n"
   637     by (fast intro: less_le_trans)
   638   hence "\<exists>m. \<forall>n\<ge>m. u - r < X n" ..
   639   thus "\<exists>m. \<forall>n\<ge>m. norm (X n - u) < r"
   640     using 1 by (simp add: diff_less_eq add_commute)
   641 qed
   642 
   643 text{*A standard proof of the theorem for monotone increasing sequence*}
   644 
   645 lemma Bseq_mono_convergent:
   646    "Bseq X \<Longrightarrow> \<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> convergent (X::nat=>real)"
   647   by (metis Bseq_isLub isLub_mono_imp_LIMSEQ convergentI)
   648 
   649 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   650   by (simp add: Bseq_def)
   651 
   652 text{*Main monotonicity theorem*}
   653 
   654 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
   655   by (metis monoseq_iff incseq_def decseq_eq_incseq convergent_minus_iff Bseq_minus_iff
   656             Bseq_mono_convergent)
   657 
   658 subsubsection{*Increasing and Decreasing Series*}
   659 
   660 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::real)"
   661   by (metis incseq_def LIMSEQ_le_const)
   662 
   663 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::real) \<le> X n"
   664   by (metis decseq_def LIMSEQ_le_const2)
   665 
   666 subsection {* Cauchy Sequences *}
   667 
   668 lemma metric_CauchyI:
   669   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
   670   by (simp add: Cauchy_def)
   671 
   672 lemma metric_CauchyD:
   673   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
   674   by (simp add: Cauchy_def)
   675 
   676 lemma Cauchy_iff:
   677   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   678   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
   679   unfolding Cauchy_def dist_norm ..
   680 
   681 lemma Cauchy_iff2:
   682   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
   683 apply (simp add: Cauchy_iff, auto)
   684 apply (drule reals_Archimedean, safe)
   685 apply (drule_tac x = n in spec, auto)
   686 apply (rule_tac x = M in exI, auto)
   687 apply (drule_tac x = m in spec, simp)
   688 apply (drule_tac x = na in spec, auto)
   689 done
   690 
   691 lemma CauchyI:
   692   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   693   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
   694 by (simp add: Cauchy_iff)
   695 
   696 lemma CauchyD:
   697   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   698   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
   699 by (simp add: Cauchy_iff)
   700 
   701 lemma Cauchy_subseq_Cauchy:
   702   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
   703 apply (auto simp add: Cauchy_def)
   704 apply (drule_tac x=e in spec, clarify)
   705 apply (rule_tac x=M in exI, clarify)
   706 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
   707 done
   708 
   709 subsubsection {* Cauchy Sequences are Bounded *}
   710 
   711 text{*A Cauchy sequence is bounded -- this is the standard
   712   proof mechanization rather than the nonstandard proof*}
   713 
   714 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
   715           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
   716 apply (clarify, drule spec, drule (1) mp)
   717 apply (simp only: norm_minus_commute)
   718 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
   719 apply simp
   720 done
   721 
   722 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
   723 apply (simp add: Cauchy_iff)
   724 apply (drule spec, drule mp, rule zero_less_one, safe)
   725 apply (drule_tac x="M" in spec, simp)
   726 apply (drule lemmaCauchy)
   727 apply (rule_tac k="M" in Bseq_offset)
   728 apply (simp add: Bseq_def)
   729 apply (rule_tac x="1 + norm (X M)" in exI)
   730 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
   731 apply (simp add: order_less_imp_le)
   732 done
   733 
   734 subsubsection {* Cauchy Sequences are Convergent *}
   735 
   736 class complete_space = metric_space +
   737   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
   738 
   739 class banach = real_normed_vector + complete_space
   740 
   741 theorem LIMSEQ_imp_Cauchy:
   742   assumes X: "X ----> a" shows "Cauchy X"
   743 proof (rule metric_CauchyI)
   744   fix e::real assume "0 < e"
   745   hence "0 < e/2" by simp
   746   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
   747   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
   748   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
   749   proof (intro exI allI impI)
   750     fix m assume "N \<le> m"
   751     hence m: "dist (X m) a < e/2" using N by fast
   752     fix n assume "N \<le> n"
   753     hence n: "dist (X n) a < e/2" using N by fast
   754     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
   755       by (rule dist_triangle2)
   756     also from m n have "\<dots> < e" by simp
   757     finally show "dist (X m) (X n) < e" .
   758   qed
   759 qed
   760 
   761 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
   762 unfolding convergent_def
   763 by (erule exE, erule LIMSEQ_imp_Cauchy)
   764 
   765 lemma Cauchy_convergent_iff:
   766   fixes X :: "nat \<Rightarrow> 'a::complete_space"
   767   shows "Cauchy X = convergent X"
   768 by (fast intro: Cauchy_convergent convergent_Cauchy)
   769 
   770 text {*
   771 Proof that Cauchy sequences converge based on the one from
   772 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
   773 *}
   774 
   775 text {*
   776   If sequence @{term "X"} is Cauchy, then its limit is the lub of
   777   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
   778 *}
   779 
   780 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
   781 by (simp add: isUbI setleI)
   782 
   783 lemma real_Cauchy_convergent:
   784   fixes X :: "nat \<Rightarrow> real"
   785   assumes X: "Cauchy X"
   786   shows "convergent X"
   787 proof -
   788   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
   789   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
   790 
   791   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
   792   have "isUb UNIV S x"
   793   proof (rule isUb_UNIV_I)
   794   fix y::real assume "y \<in> S"
   795   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
   796     by (simp add: S_def)
   797   then obtain M where "\<forall>n\<ge>M. y < X n" ..
   798   hence "y < X (max M N)" by simp
   799   also have "\<dots> < x" using N by simp
   800   finally show "y \<le> x"
   801     by (rule order_less_imp_le)
   802   qed }
   803   note bound_isUb = this 
   804 
   805   have "\<exists>u. isLub UNIV S u"
   806   proof (rule reals_complete)
   807   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
   808     using CauchyD [OF X zero_less_one] by auto
   809   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
   810   show "\<exists>x. x \<in> S"
   811   proof
   812     from N have "\<forall>n\<ge>N. X N - 1 < X n"
   813       by (simp add: abs_diff_less_iff)
   814     thus "X N - 1 \<in> S" by (rule mem_S)
   815   qed
   816   show "\<exists>u. isUb UNIV S u"
   817   proof
   818     from N have "\<forall>n\<ge>N. X n < X N + 1"
   819       by (simp add: abs_diff_less_iff)
   820     thus "isUb UNIV S (X N + 1)"
   821       by (rule bound_isUb)
   822   qed
   823   qed
   824   then obtain x where x: "isLub UNIV S x" ..
   825   have "X ----> x"
   826   proof (rule LIMSEQ_I)
   827   fix r::real assume "0 < r"
   828   hence r: "0 < r/2" by simp
   829   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
   830     using CauchyD [OF X r] by auto
   831   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
   832   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
   833     by (simp only: real_norm_def abs_diff_less_iff)
   834 
   835   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
   836   hence "X N - r/2 \<in> S" by (rule mem_S)
   837   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
   838 
   839   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
   840   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
   841   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
   842 
   843   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
   844   proof (intro exI allI impI)
   845     fix n assume n: "N \<le> n"
   846     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
   847     thus "norm (X n - x) < r" using 1 2
   848       by (simp add: abs_diff_less_iff)
   849   qed
   850   qed
   851   then show ?thesis unfolding convergent_def by auto
   852 qed
   853 
   854 instance real :: banach
   855   by intro_classes (rule real_Cauchy_convergent)
   856 
   857 
   858 subsection {* Power Sequences *}
   859 
   860 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
   861 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
   862   also fact that bounded and monotonic sequence converges.*}
   863 
   864 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
   865 apply (simp add: Bseq_def)
   866 apply (rule_tac x = 1 in exI)
   867 apply (simp add: power_abs)
   868 apply (auto dest: power_mono)
   869 done
   870 
   871 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
   872 apply (clarify intro!: mono_SucI2)
   873 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
   874 done
   875 
   876 lemma convergent_realpow:
   877   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
   878 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
   879 
   880 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
   881   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
   882 
   883 lemma LIMSEQ_realpow_zero:
   884   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
   885 proof cases
   886   assume "0 \<le> x" and "x \<noteq> 0"
   887   hence x0: "0 < x" by simp
   888   assume x1: "x < 1"
   889   from x0 x1 have "1 < inverse x"
   890     by (rule one_less_inverse)
   891   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
   892     by (rule LIMSEQ_inverse_realpow_zero)
   893   thus ?thesis by (simp add: power_inverse)
   894 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
   895 
   896 lemma LIMSEQ_power_zero:
   897   fixes x :: "'a::{real_normed_algebra_1}"
   898   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
   899 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
   900 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
   901 apply (simp add: power_abs norm_power_ineq)
   902 done
   903 
   904 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
   905   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
   906 
   907 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
   908 
   909 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
   910   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
   911 
   912 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
   913   by (rule LIMSEQ_power_zero) simp
   914 
   915 lemma tendsto_at_topI_sequentially:
   916   fixes f :: "real \<Rightarrow> real"
   917   assumes mono: "mono f"
   918   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
   919   shows "(f ---> y) at_top"
   920 proof (rule tendstoI)
   921   fix e :: real assume "0 < e"
   922   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
   923     by (auto simp: LIMSEQ_def dist_real_def)
   924   { fix x :: real
   925     from ex_le_of_nat[of x] guess n ..
   926     note monoD[OF mono this]
   927     also have "f (real_of_nat n) \<le> y"
   928       by (rule LIMSEQ_le_const[OF limseq])
   929          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
   930     finally have "f x \<le> y" . }
   931   note le = this
   932   have "eventually (\<lambda>x. real N \<le> x) at_top"
   933     by (rule eventually_ge_at_top)
   934   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
   935   proof eventually_elim
   936     fix x assume N': "real N \<le> x"
   937     with N[of N] le have "y - f (real N) < e" by auto
   938     moreover note monoD[OF mono N']
   939     ultimately show "dist (f x) y < e"
   940       using le[of x] by (auto simp: dist_real_def field_simps)
   941   qed
   942 qed
   943 
   944 end