src/HOL/Fun.thy
author wenzelm
Fri Oct 09 20:26:03 2015 +0200 (2015-10-09)
changeset 61378 3e04c9ca001a
parent 61204 3e491e34a62e
child 61520 8f85bb443d33
permissions -rw-r--r--
discontinued specific HTML syntax;
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   1994, 2012
     5 *)
     6 
     7 section \<open>Notions about functions\<close>
     8 
     9 theory Fun
    10 imports Set
    11 keywords "functor" :: thy_goal
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 text\<open>Uniqueness, so NOT the axiom of choice.\<close>
    19 lemma uniq_choice: "\<forall>x. \<exists>!y. Q x y \<Longrightarrow> \<exists>f. \<forall>x. Q x (f x)"
    20   by (force intro: theI')
    21 
    22 lemma b_uniq_choice: "\<forall>x\<in>S. \<exists>!y. Q x y \<Longrightarrow> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    23   by (force intro: theI')
    24 
    25 subsection \<open>The Identity Function @{text id}\<close>
    26 
    27 definition id :: "'a \<Rightarrow> 'a" where
    28   "id = (\<lambda>x. x)"
    29 
    30 lemma id_apply [simp]: "id x = x"
    31   by (simp add: id_def)
    32 
    33 lemma image_id [simp]: "image id = id"
    34   by (simp add: id_def fun_eq_iff)
    35 
    36 lemma vimage_id [simp]: "vimage id = id"
    37   by (simp add: id_def fun_eq_iff)
    38 
    39 code_printing
    40   constant id \<rightharpoonup> (Haskell) "id"
    41 
    42 
    43 subsection \<open>The Composition Operator @{text "f \<circ> g"}\<close>
    44 
    45 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    46   "f o g = (\<lambda>x. f (g x))"
    47 
    48 notation (xsymbols)
    49   comp  (infixl "\<circ>" 55)
    50 
    51 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    52   by (simp add: comp_def)
    53 
    54 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    55   by (simp add: fun_eq_iff)
    56 
    57 lemma id_comp [simp]: "id o g = g"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_id [simp]: "f o id = f"
    61   by (simp add: fun_eq_iff)
    62 
    63 lemma comp_eq_dest:
    64   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    65   by (simp add: fun_eq_iff)
    66 
    67 lemma comp_eq_elim:
    68   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    69   by (simp add: fun_eq_iff)
    70 
    71 lemma comp_eq_dest_lhs: "a o b = c \<Longrightarrow> a (b v) = c v"
    72   by clarsimp
    73 
    74 lemma comp_eq_id_dest: "a o b = id o c \<Longrightarrow> a (b v) = c v"
    75   by clarsimp
    76 
    77 lemma image_comp:
    78   "f ` (g ` r) = (f o g) ` r"
    79   by auto
    80 
    81 lemma vimage_comp:
    82   "f -` (g -` x) = (g \<circ> f) -` x"
    83   by auto
    84 
    85 lemma image_eq_imp_comp: "f ` A = g ` B \<Longrightarrow> (h o f) ` A = (h o g) ` B"
    86   by (auto simp: comp_def elim!: equalityE)
    87 
    88 lemma image_bind: "f ` (Set.bind A g) = Set.bind A (op ` f \<circ> g)"
    89 by(auto simp add: Set.bind_def)
    90 
    91 lemma bind_image: "Set.bind (f ` A) g = Set.bind A (g \<circ> f)"
    92 by(auto simp add: Set.bind_def)
    93 
    94 lemma (in group_add) minus_comp_minus [simp]:
    95   "uminus \<circ> uminus = id"
    96   by (simp add: fun_eq_iff)
    97 
    98 lemma (in boolean_algebra) minus_comp_minus [simp]:
    99   "uminus \<circ> uminus = id"
   100   by (simp add: fun_eq_iff)
   101 
   102 code_printing
   103   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
   104 
   105 
   106 subsection \<open>The Forward Composition Operator @{text fcomp}\<close>
   107 
   108 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
   109   "f \<circ>> g = (\<lambda>x. g (f x))"
   110 
   111 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   112   by (simp add: fcomp_def)
   113 
   114 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   115   by (simp add: fcomp_def)
   116 
   117 lemma id_fcomp [simp]: "id \<circ>> g = g"
   118   by (simp add: fcomp_def)
   119 
   120 lemma fcomp_id [simp]: "f \<circ>> id = f"
   121   by (simp add: fcomp_def)
   122 
   123 code_printing
   124   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   125 
   126 no_notation fcomp (infixl "\<circ>>" 60)
   127 
   128 
   129 subsection \<open>Mapping functions\<close>
   130 
   131 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   132   "map_fun f g h = g \<circ> h \<circ> f"
   133 
   134 lemma map_fun_apply [simp]:
   135   "map_fun f g h x = g (h (f x))"
   136   by (simp add: map_fun_def)
   137 
   138 
   139 subsection \<open>Injectivity and Bijectivity\<close>
   140 
   141 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   142   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   143 
   144 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   145   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   146 
   147 text\<open>A common special case: functions injective, surjective or bijective over
   148 the entire domain type.\<close>
   149 
   150 abbreviation
   151   "inj f \<equiv> inj_on f UNIV"
   152 
   153 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   154   "surj f \<equiv> (range f = UNIV)"
   155 
   156 abbreviation
   157   "bij f \<equiv> bij_betw f UNIV UNIV"
   158 
   159 text\<open>The negated case:\<close>
   160 translations
   161 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   162 
   163 lemma injI:
   164   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   165   shows "inj f"
   166   using assms unfolding inj_on_def by auto
   167 
   168 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   169   by (unfold inj_on_def, blast)
   170 
   171 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   172 by (simp add: inj_on_def)
   173 
   174 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   175 by (force simp add: inj_on_def)
   176 
   177 lemma inj_on_cong:
   178   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   179 unfolding inj_on_def by auto
   180 
   181 lemma inj_on_strict_subset:
   182   "inj_on f B \<Longrightarrow> A \<subset> B \<Longrightarrow> f ` A \<subset> f ` B"
   183   unfolding inj_on_def by blast
   184 
   185 lemma inj_comp:
   186   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   187   by (simp add: inj_on_def)
   188 
   189 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   190   by (simp add: inj_on_def fun_eq_iff)
   191 
   192 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   193 by (simp add: inj_on_eq_iff)
   194 
   195 lemma inj_on_id[simp]: "inj_on id A"
   196   by (simp add: inj_on_def)
   197 
   198 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   199 by (simp add: inj_on_def)
   200 
   201 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   202 unfolding inj_on_def by blast
   203 
   204 lemma surj_id: "surj id"
   205 by simp
   206 
   207 lemma bij_id[simp]: "bij id"
   208 by (simp add: bij_betw_def)
   209 
   210 lemma inj_onI:
   211     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   212 by (simp add: inj_on_def)
   213 
   214 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   215 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   216 
   217 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   218 by (unfold inj_on_def, blast)
   219 
   220 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   221   by (fact inj_on_eq_iff)
   222 
   223 lemma comp_inj_on:
   224      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   225 by (simp add: comp_def inj_on_def)
   226 
   227 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   228   by (simp add: inj_on_def) blast
   229 
   230 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   231   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   232 apply(unfold inj_on_def)
   233 apply blast
   234 done
   235 
   236 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   237 by (unfold inj_on_def, blast)
   238 
   239 lemma inj_singleton: "inj (%s. {s})"
   240 by (simp add: inj_on_def)
   241 
   242 lemma inj_on_empty[iff]: "inj_on f {}"
   243 by(simp add: inj_on_def)
   244 
   245 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   246 by (unfold inj_on_def, blast)
   247 
   248 lemma inj_on_Un:
   249  "inj_on f (A Un B) =
   250   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   251 apply(unfold inj_on_def)
   252 apply (blast intro:sym)
   253 done
   254 
   255 lemma inj_on_insert[iff]:
   256   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   257 apply(unfold inj_on_def)
   258 apply (blast intro:sym)
   259 done
   260 
   261 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   262 apply(unfold inj_on_def)
   263 apply (blast)
   264 done
   265 
   266 lemma comp_inj_on_iff:
   267   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   268 by(auto simp add: comp_inj_on inj_on_def)
   269 
   270 lemma inj_on_imageI2:
   271   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   272 by(auto simp add: comp_inj_on inj_on_def)
   273 
   274 lemma inj_img_insertE:
   275   assumes "inj_on f A"
   276   assumes "x \<notin> B" and "insert x B = f ` A"
   277   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   278     and "x = f x'" and "B = f ` A'"
   279 proof -
   280   from assms have "x \<in> f ` A" by auto
   281   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   282   then have "A = insert x' (A - {x'})" by auto
   283   with assms * have "B = f ` (A - {x'})"
   284     by (auto dest: inj_on_contraD)
   285   have "x' \<notin> A - {x'}" by simp
   286   from \<open>x' \<notin> A - {x'}\<close> \<open>A = insert x' (A - {x'})\<close> \<open>x = f x'\<close> \<open>B = image f (A - {x'})\<close>
   287   show ?thesis ..
   288 qed
   289 
   290 lemma linorder_injI:
   291   assumes hyp: "\<And>x y. x < (y::'a::linorder) \<Longrightarrow> f x \<noteq> f y"
   292   shows "inj f"
   293   -- \<open>Courtesy of Stephan Merz\<close>
   294 proof (rule inj_onI)
   295   fix x y
   296   assume f_eq: "f x = f y"
   297   show "x = y" by (rule linorder_cases) (auto dest: hyp simp: f_eq)
   298 qed
   299 
   300 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   301   by auto
   302 
   303 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   304   using *[symmetric] by auto
   305 
   306 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   307   by (simp add: surj_def)
   308 
   309 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   310   by (simp add: surj_def, blast)
   311 
   312 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   313 apply (simp add: comp_def surj_def, clarify)
   314 apply (drule_tac x = y in spec, clarify)
   315 apply (drule_tac x = x in spec, blast)
   316 done
   317 
   318 lemma bij_betw_imageI:
   319   "\<lbrakk> inj_on f A; f ` A = B \<rbrakk> \<Longrightarrow> bij_betw f A B"
   320 unfolding bij_betw_def by clarify
   321 
   322 lemma bij_betw_imp_surj_on: "bij_betw f A B \<Longrightarrow> f ` A = B"
   323   unfolding bij_betw_def by clarify
   324 
   325 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   326   unfolding bij_betw_def by auto
   327 
   328 lemma bij_betw_empty1:
   329   assumes "bij_betw f {} A"
   330   shows "A = {}"
   331 using assms unfolding bij_betw_def by blast
   332 
   333 lemma bij_betw_empty2:
   334   assumes "bij_betw f A {}"
   335   shows "A = {}"
   336 using assms unfolding bij_betw_def by blast
   337 
   338 lemma inj_on_imp_bij_betw:
   339   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   340 unfolding bij_betw_def by simp
   341 
   342 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   343   unfolding bij_betw_def ..
   344 
   345 lemma bijI: "[| inj f; surj f |] ==> bij f"
   346 by (simp add: bij_def)
   347 
   348 lemma bij_is_inj: "bij f ==> inj f"
   349 by (simp add: bij_def)
   350 
   351 lemma bij_is_surj: "bij f ==> surj f"
   352 by (simp add: bij_def)
   353 
   354 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   355 by (simp add: bij_betw_def)
   356 
   357 lemma bij_betw_trans:
   358   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   359 by(auto simp add:bij_betw_def comp_inj_on)
   360 
   361 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   362   by (rule bij_betw_trans)
   363 
   364 lemma bij_betw_comp_iff:
   365   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   366 by(auto simp add: bij_betw_def inj_on_def)
   367 
   368 lemma bij_betw_comp_iff2:
   369   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   370   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   371 using assms
   372 proof(auto simp add: bij_betw_comp_iff)
   373   assume *: "bij_betw (f' \<circ> f) A A''"
   374   thus "bij_betw f A A'"
   375   using IM
   376   proof(auto simp add: bij_betw_def)
   377     assume "inj_on (f' \<circ> f) A"
   378     thus "inj_on f A" using inj_on_imageI2 by blast
   379   next
   380     fix a' assume **: "a' \<in> A'"
   381     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   382     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   383     unfolding bij_betw_def by force
   384     hence "f a \<in> A'" using IM by auto
   385     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   386     thus "a' \<in> f ` A" using 1 by auto
   387   qed
   388 qed
   389 
   390 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   391 proof -
   392   have i: "inj_on f A" and s: "f ` A = B"
   393     using assms by(auto simp:bij_betw_def)
   394   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   395   { fix a b assume P: "?P b a"
   396     hence ex1: "\<exists>a. ?P b a" using s by blast
   397     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   398     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   399   } note g = this
   400   have "inj_on ?g B"
   401   proof(rule inj_onI)
   402     fix x y assume "x:B" "y:B" "?g x = ?g y"
   403     from s \<open>x:B\<close> obtain a1 where a1: "?P x a1" by blast
   404     from s \<open>y:B\<close> obtain a2 where a2: "?P y a2" by blast
   405     from g[OF a1] a1 g[OF a2] a2 \<open>?g x = ?g y\<close> show "x=y" by simp
   406   qed
   407   moreover have "?g ` B = A"
   408   proof(auto simp: image_def)
   409     fix b assume "b:B"
   410     with s obtain a where P: "?P b a" by blast
   411     thus "?g b \<in> A" using g[OF P] by auto
   412   next
   413     fix a assume "a:A"
   414     then obtain b where P: "?P b a" using s by blast
   415     then have "b:B" using s by blast
   416     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   417   qed
   418   ultimately show ?thesis by(auto simp:bij_betw_def)
   419 qed
   420 
   421 lemma bij_betw_cong:
   422   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   423 unfolding bij_betw_def inj_on_def by force
   424 
   425 lemma bij_betw_id[intro, simp]:
   426   "bij_betw id A A"
   427 unfolding bij_betw_def id_def by auto
   428 
   429 lemma bij_betw_id_iff:
   430   "bij_betw id A B \<longleftrightarrow> A = B"
   431 by(auto simp add: bij_betw_def)
   432 
   433 lemma bij_betw_combine:
   434   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   435   shows "bij_betw f (A \<union> C) (B \<union> D)"
   436   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   437 
   438 lemma bij_betw_subset:
   439   assumes BIJ: "bij_betw f A A'" and
   440           SUB: "B \<le> A" and IM: "f ` B = B'"
   441   shows "bij_betw f B B'"
   442 using assms
   443 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   444 
   445 lemma bij_pointE:
   446   assumes "bij f"
   447   obtains x where "y = f x" and "\<And>x'. y = f x' \<Longrightarrow> x' = x"
   448 proof -
   449   from assms have "inj f" by (rule bij_is_inj)
   450   moreover from assms have "surj f" by (rule bij_is_surj)
   451   then have "y \<in> range f" by simp
   452   ultimately have "\<exists>!x. y = f x" by (simp add: range_ex1_eq)
   453   with that show thesis by blast
   454 qed
   455 
   456 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   457 by simp
   458 
   459 lemma surj_vimage_empty:
   460   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   461   using surj_image_vimage_eq[OF \<open>surj f\<close>, of A]
   462   by (intro iffI) fastforce+
   463 
   464 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   465 by (simp add: inj_on_def, blast)
   466 
   467 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   468 by (blast intro: sym)
   469 
   470 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   471 by (unfold inj_on_def, blast)
   472 
   473 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   474 apply (unfold bij_def)
   475 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   476 done
   477 
   478 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   479 by(fastforce simp add: inj_on_def)
   480 
   481 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   482 by(erule inj_on_image_eq_iff) simp_all
   483 
   484 lemma inj_on_image_Int:
   485    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   486   by (simp add: inj_on_def, blast)
   487 
   488 lemma inj_on_image_set_diff:
   489    "[| inj_on f C;  A-B \<subseteq> C;  B \<subseteq> C |] ==> f`(A-B) = f`A - f`B"
   490   by (simp add: inj_on_def, blast)
   491 
   492 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   493   by (simp add: inj_on_def, blast)
   494 
   495 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   496 by (simp add: inj_on_def, blast)
   497 
   498 lemma inj_on_image_mem_iff: "\<lbrakk>inj_on f B; a \<in> B; A \<subseteq> B\<rbrakk> \<Longrightarrow> f a \<in> f`A \<longleftrightarrow> a \<in> A"
   499   by (auto simp: inj_on_def)
   500 
   501 lemma inj_image_mem_iff: "inj f \<Longrightarrow> f a \<in> f`A \<longleftrightarrow> a \<in> A"
   502   by (blast dest: injD)
   503 
   504 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   505   by (blast dest: injD)
   506 
   507 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   508   by (blast dest: injD)
   509 
   510 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   511 by auto
   512 
   513 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   514 by (auto simp add: inj_on_def)
   515 
   516 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   517 apply (simp add: bij_def)
   518 apply (rule equalityI)
   519 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   520 done
   521 
   522 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   523   -- \<open>The inverse image of a singleton under an injective function
   524          is included in a singleton.\<close>
   525   apply (auto simp add: inj_on_def)
   526   apply (blast intro: the_equality [symmetric])
   527   done
   528 
   529 lemma inj_on_vimage_singleton:
   530   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   531   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   532 
   533 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   534   by (auto intro!: inj_onI)
   535 
   536 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   537   by (auto intro!: inj_onI dest: strict_mono_eq)
   538 
   539 lemma bij_betw_byWitness:
   540 assumes LEFT: "\<forall>a \<in> A. f'(f a) = a" and
   541         RIGHT: "\<forall>a' \<in> A'. f(f' a') = a'" and
   542         IM1: "f ` A \<le> A'" and IM2: "f' ` A' \<le> A"
   543 shows "bij_betw f A A'"
   544 using assms
   545 proof(unfold bij_betw_def inj_on_def, safe)
   546   fix a b assume *: "a \<in> A" "b \<in> A" and **: "f a = f b"
   547   have "a = f'(f a) \<and> b = f'(f b)" using * LEFT by simp
   548   with ** show "a = b" by simp
   549 next
   550   fix a' assume *: "a' \<in> A'"
   551   hence "f' a' \<in> A" using IM2 by blast
   552   moreover
   553   have "a' = f(f' a')" using * RIGHT by simp
   554   ultimately show "a' \<in> f ` A" by blast
   555 qed
   556 
   557 corollary notIn_Un_bij_betw:
   558 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'" and
   559        BIJ: "bij_betw f A A'"
   560 shows "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   561 proof-
   562   have "bij_betw f {b} {f b}"
   563   unfolding bij_betw_def inj_on_def by simp
   564   with assms show ?thesis
   565   using bij_betw_combine[of f A A' "{b}" "{f b}"] by blast
   566 qed
   567 
   568 lemma notIn_Un_bij_betw3:
   569 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'"
   570 shows "bij_betw f A A' = bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   571 proof
   572   assume "bij_betw f A A'"
   573   thus "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   574   using assms notIn_Un_bij_betw[of b A f A'] by blast
   575 next
   576   assume *: "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   577   have "f ` A = A'"
   578   proof(auto)
   579     fix a assume **: "a \<in> A"
   580     hence "f a \<in> A' \<union> {f b}" using * unfolding bij_betw_def by blast
   581     moreover
   582     {assume "f a = f b"
   583      hence "a = b" using * ** unfolding bij_betw_def inj_on_def by blast
   584      with NIN ** have False by blast
   585     }
   586     ultimately show "f a \<in> A'" by blast
   587   next
   588     fix a' assume **: "a' \<in> A'"
   589     hence "a' \<in> f`(A \<union> {b})"
   590     using * by (auto simp add: bij_betw_def)
   591     then obtain a where 1: "a \<in> A \<union> {b} \<and> f a = a'" by blast
   592     moreover
   593     {assume "a = b" with 1 ** NIN' have False by blast
   594     }
   595     ultimately have "a \<in> A" by blast
   596     with 1 show "a' \<in> f ` A" by blast
   597   qed
   598   thus "bij_betw f A A'" using * bij_betw_subset[of f "A \<union> {b}" _ A] by blast
   599 qed
   600 
   601 
   602 subsection\<open>Function Updating\<close>
   603 
   604 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   605   "fun_upd f a b == % x. if x=a then b else f x"
   606 
   607 nonterminal updbinds and updbind
   608 
   609 syntax
   610   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   611   ""         :: "updbind => updbinds"             ("_")
   612   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   613   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   614 
   615 translations
   616   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   617   "f(x:=y)" == "CONST fun_upd f x y"
   618 
   619 (* Hint: to define the sum of two functions (or maps), use case_sum.
   620          A nice infix syntax could be defined by
   621 notation
   622   case_sum  (infixr "'(+')"80)
   623 *)
   624 
   625 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   626 apply (simp add: fun_upd_def, safe)
   627 apply (erule subst)
   628 apply (rule_tac [2] ext, auto)
   629 done
   630 
   631 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   632   by (simp only: fun_upd_idem_iff)
   633 
   634 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   635   by (simp only: fun_upd_idem)
   636 
   637 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   638 by (simp add: fun_upd_def)
   639 
   640 (* fun_upd_apply supersedes these two,   but they are useful
   641    if fun_upd_apply is intentionally removed from the simpset *)
   642 lemma fun_upd_same: "(f(x:=y)) x = y"
   643 by simp
   644 
   645 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   646 by simp
   647 
   648 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   649 by (simp add: fun_eq_iff)
   650 
   651 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   652 by (rule ext, auto)
   653 
   654 lemma inj_on_fun_updI:
   655   "inj_on f A \<Longrightarrow> y \<notin> f ` A \<Longrightarrow> inj_on (f(x := y)) A"
   656   by (fastforce simp: inj_on_def)
   657 
   658 lemma fun_upd_image:
   659      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   660 by auto
   661 
   662 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   663   by auto
   664 
   665 
   666 subsection \<open>@{text override_on}\<close>
   667 
   668 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   669   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   670 
   671 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   672 by(simp add:override_on_def)
   673 
   674 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   675 by(simp add:override_on_def)
   676 
   677 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   678 by(simp add:override_on_def)
   679 
   680 
   681 subsection \<open>@{text swap}\<close>
   682 
   683 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   684 where
   685   "swap a b f = f (a := f b, b:= f a)"
   686 
   687 lemma swap_apply [simp]:
   688   "swap a b f a = f b"
   689   "swap a b f b = f a"
   690   "c \<noteq> a \<Longrightarrow> c \<noteq> b \<Longrightarrow> swap a b f c = f c"
   691   by (simp_all add: swap_def)
   692 
   693 lemma swap_self [simp]:
   694   "swap a a f = f"
   695   by (simp add: swap_def)
   696 
   697 lemma swap_commute:
   698   "swap a b f = swap b a f"
   699   by (simp add: fun_upd_def swap_def fun_eq_iff)
   700 
   701 lemma swap_nilpotent [simp]:
   702   "swap a b (swap a b f) = f"
   703   by (rule ext, simp add: fun_upd_def swap_def)
   704 
   705 lemma swap_comp_involutory [simp]:
   706   "swap a b \<circ> swap a b = id"
   707   by (rule ext) simp
   708 
   709 lemma swap_triple:
   710   assumes "a \<noteq> c" and "b \<noteq> c"
   711   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   712   using assms by (simp add: fun_eq_iff swap_def)
   713 
   714 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   715   by (rule ext, simp add: fun_upd_def swap_def)
   716 
   717 lemma swap_image_eq [simp]:
   718   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   719 proof -
   720   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   721     using assms by (auto simp: image_iff swap_def)
   722   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   723   with subset[of f] show ?thesis by auto
   724 qed
   725 
   726 lemma inj_on_imp_inj_on_swap:
   727   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   728   by (simp add: inj_on_def swap_def, blast)
   729 
   730 lemma inj_on_swap_iff [simp]:
   731   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   732 proof
   733   assume "inj_on (swap a b f) A"
   734   with A have "inj_on (swap a b (swap a b f)) A"
   735     by (iprover intro: inj_on_imp_inj_on_swap)
   736   thus "inj_on f A" by simp
   737 next
   738   assume "inj_on f A"
   739   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   740 qed
   741 
   742 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   743   by simp
   744 
   745 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   746   by simp
   747 
   748 lemma bij_betw_swap_iff [simp]:
   749   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   750   by (auto simp: bij_betw_def)
   751 
   752 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   753   by simp
   754 
   755 hide_const (open) swap
   756 
   757 
   758 subsection \<open>Inversion of injective functions\<close>
   759 
   760 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   761   "the_inv_into A f == %x. THE y. y : A & f y = x"
   762 
   763 lemma the_inv_into_f_f:
   764   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   765 apply (simp add: the_inv_into_def inj_on_def)
   766 apply blast
   767 done
   768 
   769 lemma f_the_inv_into_f:
   770   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   771 apply (simp add: the_inv_into_def)
   772 apply (rule the1I2)
   773  apply(blast dest: inj_onD)
   774 apply blast
   775 done
   776 
   777 lemma the_inv_into_into:
   778   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   779 apply (simp add: the_inv_into_def)
   780 apply (rule the1I2)
   781  apply(blast dest: inj_onD)
   782 apply blast
   783 done
   784 
   785 lemma the_inv_into_onto[simp]:
   786   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   787 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   788 
   789 lemma the_inv_into_f_eq:
   790   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   791   apply (erule subst)
   792   apply (erule the_inv_into_f_f, assumption)
   793   done
   794 
   795 lemma the_inv_into_comp:
   796   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   797   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   798 apply (rule the_inv_into_f_eq)
   799   apply (fast intro: comp_inj_on)
   800  apply (simp add: f_the_inv_into_f the_inv_into_into)
   801 apply (simp add: the_inv_into_into)
   802 done
   803 
   804 lemma inj_on_the_inv_into:
   805   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   806 by (auto intro: inj_onI simp: the_inv_into_f_f)
   807 
   808 lemma bij_betw_the_inv_into:
   809   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   810 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   811 
   812 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   813   "the_inv f \<equiv> the_inv_into UNIV f"
   814 
   815 lemma the_inv_f_f:
   816   assumes "inj f"
   817   shows "the_inv f (f x) = x" using assms UNIV_I
   818   by (rule the_inv_into_f_f)
   819 
   820 
   821 subsection \<open>Cantor's Paradox\<close>
   822 
   823 lemma Cantors_paradox:
   824   "\<not>(\<exists>f. f ` A = Pow A)"
   825 proof clarify
   826   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   827   let ?X = "{a \<in> A. a \<notin> f a}"
   828   have "?X \<in> Pow A" unfolding Pow_def by auto
   829   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   830   thus False by best
   831 qed
   832 
   833 subsection \<open>Setup\<close>
   834 
   835 subsubsection \<open>Proof tools\<close>
   836 
   837 text \<open>simplifies terms of the form
   838   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...)\<close>
   839 
   840 simproc_setup fun_upd2 ("f(v := w, x := y)") = \<open>fn _ =>
   841 let
   842   fun gen_fun_upd NONE T _ _ = NONE
   843     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   844   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   845   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   846     let
   847       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   848             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   849         | find t = NONE
   850     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   851 
   852   val ss = simpset_of @{context}
   853 
   854   fun proc ctxt ct =
   855     let
   856       val t = Thm.term_of ct
   857     in
   858       case find_double t of
   859         (T, NONE) => NONE
   860       | (T, SOME rhs) =>
   861           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   862             (fn _ =>
   863               resolve_tac ctxt [eq_reflection] 1 THEN
   864               resolve_tac ctxt @{thms ext} 1 THEN
   865               simp_tac (put_simpset ss ctxt) 1))
   866     end
   867 in proc end
   868 \<close>
   869 
   870 
   871 subsubsection \<open>Functorial structure of types\<close>
   872 
   873 ML_file "Tools/functor.ML"
   874 
   875 functor map_fun: map_fun
   876   by (simp_all add: fun_eq_iff)
   877 
   878 functor vimage
   879   by (simp_all add: fun_eq_iff vimage_comp)
   880 
   881 text \<open>Legacy theorem names\<close>
   882 
   883 lemmas o_def = comp_def
   884 lemmas o_apply = comp_apply
   885 lemmas o_assoc = comp_assoc [symmetric]
   886 lemmas id_o = id_comp
   887 lemmas o_id = comp_id
   888 lemmas o_eq_dest = comp_eq_dest
   889 lemmas o_eq_elim = comp_eq_elim
   890 lemmas o_eq_dest_lhs = comp_eq_dest_lhs
   891 lemmas o_eq_id_dest = comp_eq_id_dest
   892 
   893 end
   894