author wenzelm
Fri Oct 09 20:26:03 2015 +0200 (2015-10-09)
changeset 61378 3e04c9ca001a
parent 61359 e985b52c3eb3
child 61384 9f5145281888
permissions -rw-r--r--
discontinued specific HTML syntax;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     5 section \<open>Pi and Function Sets\<close>
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    11 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    12   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    14 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    15   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    17 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    18   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    20 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "->" 60)
    21   where "A -> B \<equiv> Pi A (\<lambda>_. B)"
    23 notation (xsymbols)
    24   funcset  (infixr "\<rightarrow>" 60)
    26 syntax
    27   "_Pi"  :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PI _:_./ _)" 10)
    28   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    29 syntax (xsymbols)
    30   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    31   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    32 translations
    33   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    34   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    36 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    37   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    40 subsection \<open>Basic Properties of @{term Pi}\<close>
    42 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    43   by (simp add: Pi_def)
    45 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    46   by (simp add:Pi_def)
    48 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    49   by (simp add: Pi_def)
    51 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    52   by (simp add: Pi_def)
    54 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    55   unfolding Pi_def by auto
    57 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    58   by (auto simp: Pi_def)
    60 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    61   by (auto simp: Pi_def)
    63 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    64   by auto
    66 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    67   by (simp add: Pi_def)
    69 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    70   by auto
    72 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    73   by auto
    75 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    76   apply (simp add: Pi_def)
    77   apply auto
    78   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    79   picking an element from each non-empty @{term "B x"}\<close>
    80   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    81   apply auto
    82   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    83   apply auto
    84   done
    86 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    87   by (simp add: Pi_def)
    89 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    90   by auto
    92 lemma Pi_UN:
    93   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    94   assumes "finite I"
    95     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    96   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
    97 proof (intro set_eqI iffI)
    98   fix f
    99   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   100   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
   101     by auto
   102   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)"
   103     by auto
   104   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   105     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   106   have "f \<in> Pi I (A k)"
   107   proof (intro Pi_I)
   108     fix i
   109     assume "i \<in> I"
   110     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   111     show "f i \<in> A k i" by auto
   112   qed
   113   then show "f \<in> (\<Union>n. Pi I (A n))"
   114     by auto
   115 qed auto
   117 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   118   by (simp add: Pi_def)
   120 text \<open>Covariance of Pi-sets in their second argument\<close>
   121 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   122   by auto
   124 text \<open>Contravariance of Pi-sets in their first argument\<close>
   125 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   126   by auto
   128 lemma prod_final:
   129   assumes 1: "fst \<circ> f \<in> Pi A B"
   130     and 2: "snd \<circ> f \<in> Pi A C"
   131   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   132 proof (rule Pi_I)
   133   fix z
   134   assume z: "z \<in> A"
   135   have "f z = (fst (f z), snd (f z))"
   136     by simp
   137   also have "\<dots> \<in> B z \<times> C z"
   138     by (metis SigmaI PiE o_apply 1 2 z)
   139   finally show "f z \<in> B z \<times> C z" .
   140 qed
   142 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   143   by (auto simp: Pi_def)
   145 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   146   by (auto simp: Pi_def)
   148 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   149   by (auto simp: Pi_def)
   151 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   152   by (auto simp: Pi_def)
   154 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   155   apply auto
   156   apply (drule_tac x=x in Pi_mem)
   157   apply (simp_all split: split_if_asm)
   158   apply (drule_tac x=i in Pi_mem)
   159   apply (auto dest!: Pi_mem)
   160   done
   163 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
   165 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   166   by (simp add: Pi_def compose_def restrict_def)
   168 lemma compose_assoc:
   169   assumes "f \<in> A \<rightarrow> B"
   170     and "g \<in> B \<rightarrow> C"
   171     and "h \<in> C \<rightarrow> D"
   172   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   173   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   175 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   176   by (simp add: compose_def restrict_def)
   178 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   179   by (auto simp add: image_def compose_eq)
   182 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
   184 lemma restrict_cong: "I = J \<Longrightarrow> (\<And>i. i \<in> J =simp=> f i = g i) \<Longrightarrow> restrict f I = restrict g J"
   185   by (auto simp: restrict_def fun_eq_iff simp_implies_def)
   187 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   188   by (simp add: Pi_def restrict_def)
   190 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   191   by (simp add: Pi_def restrict_def)
   193 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   194   by (simp add: restrict_def)
   196 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   197   by simp
   199 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   200   by (simp add: fun_eq_iff Pi_def restrict_def)
   202 lemma restrict_UNIV: "restrict f UNIV = f"
   203   by (simp add: restrict_def)
   205 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   206   by (simp add: inj_on_def restrict_def)
   208 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   209   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   211 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   212   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   214 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   215   by (auto simp add: restrict_def)
   217 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   218   unfolding restrict_def by (simp add: fun_eq_iff)
   220 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   221   by (auto simp: restrict_def)
   223 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   224   by (auto simp: fun_eq_iff)
   226 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   227   by (auto simp: restrict_def Pi_def)
   230 subsection \<open>Bijections Between Sets\<close>
   232 text \<open>The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   233 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
   235 lemma bij_betwI:
   236   assumes "f \<in> A \<rightarrow> B"
   237     and "g \<in> B \<rightarrow> A"
   238     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   239     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   240   shows "bij_betw f A B"
   241   unfolding bij_betw_def
   242 proof
   243   show "inj_on f A"
   244     by (metis g_f inj_on_def)
   245   have "f ` A \<subseteq> B"
   246     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   247   moreover
   248   have "B \<subseteq> f ` A"
   249     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   250   ultimately show "f ` A = B"
   251     by blast
   252 qed
   254 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   255   by (auto simp add: bij_betw_def)
   257 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   258   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   260 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   261   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   262   apply (auto simp add: compose_def image_def)
   263   done
   265 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   266   by (simp add: bij_betw_def)
   269 subsection \<open>Extensionality\<close>
   271 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   272   unfolding extensional_def by auto
   274 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   275   by (simp add: extensional_def)
   277 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   278   by (simp add: restrict_def extensional_def)
   280 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   281   by (simp add: compose_def)
   283 lemma extensionalityI:
   284   assumes "f \<in> extensional A"
   285     and "g \<in> extensional A"
   286     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   287   shows "f = g"
   288   using assms by (force simp add: fun_eq_iff extensional_def)
   290 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   291   by (rule extensionalityI[OF restrict_extensional]) auto
   293 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   294   unfolding extensional_def by auto
   296 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   297   by (unfold inv_into_def) (fast intro: someI2)
   299 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   300   apply (simp add: bij_betw_def compose_def)
   301   apply (rule restrict_ext, auto)
   302   done
   304 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   305   apply (simp add: compose_def)
   306   apply (rule restrict_ext)
   307   apply (simp add: f_inv_into_f)
   308   done
   310 lemma extensional_insert[intro, simp]:
   311   assumes "a \<in> extensional (insert i I)"
   312   shows "a(i := b) \<in> extensional (insert i I)"
   313   using assms unfolding extensional_def by auto
   315 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   316   unfolding extensional_def by auto
   318 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   319   by (auto simp: extensional_def)
   321 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   322   unfolding restrict_def extensional_def by auto
   324 lemma extensional_insert_undefined[intro, simp]:
   325   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   326   unfolding extensional_def by auto
   328 lemma extensional_insert_cancel[intro, simp]:
   329   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   330   unfolding extensional_def by auto
   333 subsection \<open>Cardinality\<close>
   335 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   336   by (rule card_inj_on_le) auto
   338 lemma card_bij:
   339   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   340     and "g \<in> B \<rightarrow> A" "inj_on g B"
   341     and "finite A" "finite B"
   342   shows "card A = card B"
   343   using assms by (blast intro: card_inj order_antisym)
   346 subsection \<open>Extensional Function Spaces\<close>
   348 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   349   where "PiE S T = Pi S T \<inter> extensional S"
   351 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   353 syntax
   354   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PIE _:_./ _)" 10)
   355 syntax (xsymbols)
   356   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   357 translations "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   359 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^sub>E" 60)
   360   where "A ->\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   362 notation (xsymbols)
   363   extensional_funcset  (infixr "\<rightarrow>\<^sub>E" 60)
   365 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   366   by (simp add: PiE_def)
   368 lemma PiE_empty_domain[simp]: "PiE {} T = {\<lambda>x. undefined}"
   369   unfolding PiE_def by simp
   371 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   372   unfolding PiE_def by simp
   374 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   375   unfolding PiE_def by auto
   377 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   378 proof
   379   assume "Pi\<^sub>E I F = {}"
   380   show "\<exists>i\<in>I. F i = {}"
   381   proof (rule ccontr)
   382     assume "\<not> ?thesis"
   383     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   384       by auto
   385     from choice[OF this]
   386     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   387     then have "f \<in> Pi\<^sub>E I F"
   388       by (auto simp: extensional_def PiE_def)
   389     with \<open>Pi\<^sub>E I F = {}\<close> show False
   390       by auto
   391   qed
   392 qed (auto simp: PiE_def)
   394 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   395   unfolding PiE_def by auto (auto dest!: extensional_arb)
   397 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   398   unfolding PiE_def by auto
   400 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   401   unfolding PiE_def extensional_def by auto
   403 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   404   unfolding PiE_def extensional_def by auto
   406 lemma PiE_insert_eq: "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   407 proof -
   408   {
   409     fix f assume "f \<in> PiE (insert x S) T" "x \<notin> S"
   410     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   411       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   412   }
   413   moreover
   414   {
   415     fix f assume "f \<in> PiE (insert x S) T" "x \<in> S"
   416     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   417       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
   418   }
   419   ultimately show ?thesis
   420     using assms by (auto intro: PiE_fun_upd)
   421 qed
   423 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   424   by (auto simp: PiE_def)
   426 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   427   unfolding PiE_def by (auto simp: Pi_cong)
   429 lemma PiE_E [elim]:
   430   assumes "f \<in> PiE A B"
   431   obtains "x \<in> A" and "f x \<in> B x"
   432     | "x \<notin> A" and "f x = undefined"
   433   using assms by (auto simp: Pi_def PiE_def extensional_def)
   435 lemma PiE_I[intro!]:
   436   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   437   by (simp add: PiE_def extensional_def)
   439 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   440   by auto
   442 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   443   by (simp add: PiE_def Pi_iff)
   445 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   446   by (simp add: extensional_restrict PiE_def)
   448 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   449   by (auto simp: PiE_iff)
   451 lemma PiE_eq_subset:
   452   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   453     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   454     and "i \<in> I"
   455   shows "F i \<subseteq> F' i"
   456 proof
   457   fix x
   458   assume "x \<in> F i"
   459   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   460     by auto
   461   from choice[OF this] obtain f
   462     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   463   then have "f \<in> Pi\<^sub>E I F"
   464     by (auto simp: extensional_def PiE_def)
   465   then have "f \<in> Pi\<^sub>E I F'"
   466     using assms by simp
   467   then show "x \<in> F' i"
   468     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   469 qed
   471 lemma PiE_eq_iff_not_empty:
   472   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   473   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   474 proof (intro iffI ballI)
   475   fix i
   476   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   477   assume i: "i \<in> I"
   478   show "F i = F' i"
   479     using PiE_eq_subset[of I F F', OF ne eq i]
   480     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   481     by auto
   482 qed (auto simp: PiE_def)
   484 lemma PiE_eq_iff:
   485   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   486 proof (intro iffI disjCI)
   487   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   488   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   489   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   490     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   491   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   492     by auto
   493 next
   494   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   495   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   496     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   497 qed
   499 lemma extensional_funcset_fun_upd_restricts_rangeI:
   500   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   501   unfolding extensional_funcset_def extensional_def
   502   apply auto
   503   apply (case_tac "x = xa")
   504   apply auto
   505   done
   507 lemma extensional_funcset_fun_upd_extends_rangeI:
   508   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   509   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   510   using assms unfolding extensional_funcset_def extensional_def by auto
   513 subsubsection \<open>Injective Extensional Function Spaces\<close>
   515 lemma extensional_funcset_fun_upd_inj_onI:
   516   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   517     and "inj_on f S"
   518   shows "inj_on (f(x := a)) S"
   519   using assms
   520   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   522 lemma extensional_funcset_extend_domain_inj_on_eq:
   523   assumes "x \<notin> S"
   524   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   525     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   526   using assms
   527   apply (auto del: PiE_I PiE_E)
   528   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   529     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   530   apply (auto simp add: image_iff inj_on_def)
   531   apply (rule_tac x="xa x" in exI)
   532   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   533   apply (rule_tac x="xa(x := undefined)" in exI)
   534   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   535   apply (auto dest!: PiE_mem split: split_if_asm)
   536   done
   538 lemma extensional_funcset_extend_domain_inj_onI:
   539   assumes "x \<notin> S"
   540   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   541   using assms
   542   apply (auto intro!: inj_onI)
   543   apply (metis fun_upd_same)
   544   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   545   done
   548 subsubsection \<open>Cardinality\<close>
   550 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   551   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   553 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   554 proof (safe intro!: inj_onI ext)
   555   fix f y g z
   556   assume "x \<notin> S"
   557   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   558   assume "f(x := y) = g(x := z)"
   559   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   560     unfolding fun_eq_iff by auto
   561   from this[of x] show "y = z" by simp
   562   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   563     by (auto split: split_if_asm simp: PiE_def extensional_def)
   564 qed
   566 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   567 proof (induct rule: finite_induct)
   568   case empty
   569   then show ?case by auto
   570 next
   571   case (insert x S)
   572   then show ?case
   573     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   574 qed
   576 end