src/HOL/Power.thy
author wenzelm
Fri Oct 09 20:26:03 2015 +0200 (2015-10-09)
changeset 61378 3e04c9ca001a
parent 61076 bdc1e2f0a86a
child 61531 ab2e862263e7
permissions -rw-r--r--
discontinued specific HTML syntax;
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 context linordered_ring (* TODO: move *)
    13 begin
    14 
    15 lemma sum_squares_ge_zero:
    16   "0 \<le> x * x + y * y"
    17   by (intro add_nonneg_nonneg zero_le_square)
    18 
    19 lemma not_sum_squares_lt_zero:
    20   "\<not> x * x + y * y < 0"
    21   by (simp add: not_less sum_squares_ge_zero)
    22 
    23 end
    24 
    25 subsection \<open>Powers for Arbitrary Monoids\<close>
    26 
    27 class power = one + times
    28 begin
    29 
    30 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    31     power_0: "a ^ 0 = 1"
    32   | power_Suc: "a ^ Suc n = a * a ^ n"
    33 
    34 notation (latex output)
    35   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    36 
    37 text \<open>Special syntax for squares.\<close>
    38 
    39 abbreviation (xsymbols)
    40   power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999) where
    41   "x\<^sup>2 \<equiv> x ^ 2"
    42 
    43 notation (latex output)
    44   power2  ("(_\<^sup>2)" [1000] 999)
    45 
    46 end
    47 
    48 context monoid_mult
    49 begin
    50 
    51 subclass power .
    52 
    53 lemma power_one [simp]:
    54   "1 ^ n = 1"
    55   by (induct n) simp_all
    56 
    57 lemma power_one_right [simp]:
    58   "a ^ 1 = a"
    59   by simp
    60 
    61 lemma power_Suc0_right [simp]:
    62   "a ^ Suc 0 = a"
    63   by simp
    64 
    65 lemma power_commutes:
    66   "a ^ n * a = a * a ^ n"
    67   by (induct n) (simp_all add: mult.assoc)
    68 
    69 lemma power_Suc2:
    70   "a ^ Suc n = a ^ n * a"
    71   by (simp add: power_commutes)
    72 
    73 lemma power_add:
    74   "a ^ (m + n) = a ^ m * a ^ n"
    75   by (induct m) (simp_all add: algebra_simps)
    76 
    77 lemma power_mult:
    78   "a ^ (m * n) = (a ^ m) ^ n"
    79   by (induct n) (simp_all add: power_add)
    80 
    81 lemma power2_eq_square: "a\<^sup>2 = a * a"
    82   by (simp add: numeral_2_eq_2)
    83 
    84 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    85   by (simp add: numeral_3_eq_3 mult.assoc)
    86 
    87 lemma power_even_eq:
    88   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    89   by (subst mult.commute) (simp add: power_mult)
    90 
    91 lemma power_odd_eq:
    92   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    93   by (simp add: power_even_eq)
    94 
    95 lemma power_numeral_even:
    96   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    97   unfolding numeral_Bit0 power_add Let_def ..
    98 
    99 lemma power_numeral_odd:
   100   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
   101   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
   102   unfolding power_Suc power_add Let_def mult.assoc ..
   103 
   104 lemma funpow_times_power:
   105   "(times x ^^ f x) = times (x ^ f x)"
   106 proof (induct "f x" arbitrary: f)
   107   case 0 then show ?case by (simp add: fun_eq_iff)
   108 next
   109   case (Suc n)
   110   def g \<equiv> "\<lambda>x. f x - 1"
   111   with Suc have "n = g x" by simp
   112   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   113   moreover from Suc g_def have "f x = g x + 1" by simp
   114   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
   115 qed
   116 
   117 lemma power_commuting_commutes:
   118   assumes "x * y = y * x"
   119   shows "x ^ n * y = y * x ^n"
   120 proof (induct n)
   121   case (Suc n)
   122   have "x ^ Suc n * y = x ^ n * y * x"
   123     by (subst power_Suc2) (simp add: assms ac_simps)
   124   also have "\<dots> = y * x ^ Suc n"
   125     unfolding Suc power_Suc2
   126     by (simp add: ac_simps)
   127   finally show ?case .
   128 qed simp
   129 
   130 end
   131 
   132 context comm_monoid_mult
   133 begin
   134 
   135 lemma power_mult_distrib [field_simps]:
   136   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   137   by (induct n) (simp_all add: ac_simps)
   138 
   139 end
   140 
   141 text\<open>Extract constant factors from powers\<close>
   142 declare power_mult_distrib [where a = "numeral w" for w, simp]
   143 declare power_mult_distrib [where b = "numeral w" for w, simp]
   144 
   145 lemma power_add_numeral [simp]:
   146   fixes a :: "'a :: monoid_mult"
   147   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   148   by (simp add: power_add [symmetric])
   149 
   150 lemma power_add_numeral2 [simp]:
   151   fixes a :: "'a :: monoid_mult"
   152   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   153   by (simp add: mult.assoc [symmetric])
   154 
   155 lemma power_mult_numeral [simp]:
   156   fixes a :: "'a :: monoid_mult"
   157   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   158   by (simp only: numeral_mult power_mult)
   159 
   160 context semiring_numeral
   161 begin
   162 
   163 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   164   by (simp only: sqr_conv_mult numeral_mult)
   165 
   166 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   167   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   168     numeral_sqr numeral_mult power_add power_one_right)
   169 
   170 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   171   by (rule numeral_pow [symmetric])
   172 
   173 end
   174 
   175 context semiring_1
   176 begin
   177 
   178 lemma of_nat_power:
   179   "of_nat (m ^ n) = of_nat m ^ n"
   180   by (induct n) (simp_all add: of_nat_mult)
   181 
   182 lemma zero_power:
   183   "0 < n \<Longrightarrow> 0 ^ n = 0"
   184   by (cases n) simp_all
   185 
   186 lemma power_zero_numeral [simp]:
   187   "0 ^ numeral k = 0"
   188   by (simp add: numeral_eq_Suc)
   189 
   190 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   191   by (rule power_zero_numeral)
   192 
   193 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   194   by (rule power_one)
   195 
   196 lemma power_0_Suc [simp]:
   197   "0 ^ Suc n = 0"
   198   by simp
   199 
   200 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   201 lemma power_0_left:
   202   "0 ^ n = (if n = 0 then 1 else 0)"
   203   by (cases n) simp_all
   204 
   205 end
   206 
   207 context comm_semiring_1
   208 begin
   209 
   210 text \<open>The divides relation\<close>
   211 
   212 lemma le_imp_power_dvd:
   213   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   214 proof
   215   have "a ^ n = a ^ (m + (n - m))"
   216     using \<open>m \<le> n\<close> by simp
   217   also have "\<dots> = a ^ m * a ^ (n - m)"
   218     by (rule power_add)
   219   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   220 qed
   221 
   222 lemma power_le_dvd:
   223   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   224   by (rule dvd_trans [OF le_imp_power_dvd])
   225 
   226 lemma dvd_power_same:
   227   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   228   by (induct n) (auto simp add: mult_dvd_mono)
   229 
   230 lemma dvd_power_le:
   231   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   232   by (rule power_le_dvd [OF dvd_power_same])
   233 
   234 lemma dvd_power [simp]:
   235   assumes "n > (0::nat) \<or> x = 1"
   236   shows "x dvd (x ^ n)"
   237 using assms proof
   238   assume "0 < n"
   239   then have "x ^ n = x ^ Suc (n - 1)" by simp
   240   then show "x dvd (x ^ n)" by simp
   241 next
   242   assume "x = 1"
   243   then show "x dvd (x ^ n)" by simp
   244 qed
   245 
   246 end
   247 
   248 class semiring_1_no_zero_divisors = semiring_1 + semiring_no_zero_divisors
   249 begin
   250 
   251 subclass power .
   252 
   253 lemma power_eq_0_iff [simp]:
   254   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   255   by (induct n) auto
   256 
   257 lemma power_not_zero:
   258   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   259   by (induct n) auto
   260 
   261 lemma zero_eq_power2 [simp]:
   262   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   263   unfolding power2_eq_square by simp
   264 
   265 end
   266 
   267 context semidom
   268 begin
   269 
   270 subclass semiring_1_no_zero_divisors ..
   271 
   272 end
   273 
   274 context ring_1
   275 begin
   276 
   277 lemma power_minus:
   278   "(- a) ^ n = (- 1) ^ n * a ^ n"
   279 proof (induct n)
   280   case 0 show ?case by simp
   281 next
   282   case (Suc n) then show ?case
   283     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   284 qed
   285 
   286 lemma power_minus_Bit0:
   287   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   288   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   289     power_one_right mult_minus_left mult_minus_right minus_minus)
   290 
   291 lemma power_minus_Bit1:
   292   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   293   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   294 
   295 lemma power2_minus [simp]:
   296   "(- a)\<^sup>2 = a\<^sup>2"
   297   by (fact power_minus_Bit0)
   298 
   299 lemma power_minus1_even [simp]:
   300   "(- 1) ^ (2*n) = 1"
   301 proof (induct n)
   302   case 0 show ?case by simp
   303 next
   304   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   305 qed
   306 
   307 lemma power_minus1_odd:
   308   "(- 1) ^ Suc (2*n) = -1"
   309   by simp
   310 
   311 lemma power_minus_even [simp]:
   312   "(-a) ^ (2*n) = a ^ (2*n)"
   313   by (simp add: power_minus [of a])
   314 
   315 end
   316 
   317 context ring_1_no_zero_divisors
   318 begin
   319 
   320 subclass semiring_1_no_zero_divisors .. 
   321 
   322 lemma power2_eq_1_iff:
   323   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   324   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   325 
   326 end
   327 
   328 context idom
   329 begin
   330 
   331 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   332   unfolding power2_eq_square by (rule square_eq_iff)
   333 
   334 end
   335 
   336 context algebraic_semidom
   337 begin
   338 
   339 lemma div_power:
   340   assumes "b dvd a"
   341   shows "(a div b) ^ n = a ^ n div b ^ n"
   342   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   343 
   344 end
   345 
   346 context normalization_semidom
   347 begin
   348 
   349 lemma normalize_power:
   350   "normalize (a ^ n) = normalize a ^ n"
   351   by (induct n) (simp_all add: normalize_mult)
   352 
   353 lemma unit_factor_power:
   354   "unit_factor (a ^ n) = unit_factor a ^ n"
   355   by (induct n) (simp_all add: unit_factor_mult)
   356 
   357 end
   358 
   359 context division_ring
   360 begin
   361 
   362 text\<open>Perhaps these should be simprules.\<close>
   363 lemma power_inverse [field_simps, divide_simps]:
   364   "inverse a ^ n = inverse (a ^ n)"
   365 proof (cases "a = 0")
   366   case True then show ?thesis by (simp add: power_0_left)
   367 next
   368   case False then have "inverse (a ^ n) = inverse a ^ n"
   369     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   370   then show ?thesis by simp
   371 qed
   372 
   373 lemma power_one_over [field_simps, divide_simps]:
   374   "(1 / a) ^ n = 1 / a ^ n"
   375   using power_inverse [of a] by (simp add: divide_inverse)
   376 
   377 end  
   378 
   379 context field
   380 begin
   381 
   382 lemma power_diff:
   383   assumes nz: "a \<noteq> 0"
   384   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   385   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
   386 
   387 lemma power_divide [field_simps, divide_simps]:
   388   "(a / b) ^ n = a ^ n / b ^ n"
   389   by (induct n) simp_all
   390 
   391 declare power_divide [where b = "numeral w" for w, simp]
   392 
   393 end
   394 
   395 
   396 subsection \<open>Exponentiation on ordered types\<close>
   397 
   398 context linordered_semidom
   399 begin
   400 
   401 lemma zero_less_power [simp]:
   402   "0 < a \<Longrightarrow> 0 < a ^ n"
   403   by (induct n) simp_all
   404 
   405 lemma zero_le_power [simp]:
   406   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   407   by (induct n) simp_all
   408 
   409 lemma power_mono:
   410   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   411   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   412 
   413 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   414   using power_mono [of 1 a n] by simp
   415 
   416 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   417   using power_mono [of a 1 n] by simp
   418 
   419 lemma power_gt1_lemma:
   420   assumes gt1: "1 < a"
   421   shows "1 < a * a ^ n"
   422 proof -
   423   from gt1 have "0 \<le> a"
   424     by (fact order_trans [OF zero_le_one less_imp_le])
   425   have "1 * 1 < a * 1" using gt1 by simp
   426   also have "\<dots> \<le> a * a ^ n" using gt1
   427     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
   428         zero_le_one order_refl)
   429   finally show ?thesis by simp
   430 qed
   431 
   432 lemma power_gt1:
   433   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   434   by (simp add: power_gt1_lemma)
   435 
   436 lemma one_less_power [simp]:
   437   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   438   by (cases n) (simp_all add: power_gt1_lemma)
   439 
   440 lemma power_le_imp_le_exp:
   441   assumes gt1: "1 < a"
   442   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   443 proof (induct m arbitrary: n)
   444   case 0
   445   show ?case by simp
   446 next
   447   case (Suc m)
   448   show ?case
   449   proof (cases n)
   450     case 0
   451     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   452     with gt1 show ?thesis
   453       by (force simp only: power_gt1_lemma
   454           not_less [symmetric])
   455   next
   456     case (Suc n)
   457     with Suc.prems Suc.hyps show ?thesis
   458       by (force dest: mult_left_le_imp_le
   459           simp add: less_trans [OF zero_less_one gt1])
   460   qed
   461 qed
   462 
   463 text\<open>Surely we can strengthen this? It holds for @{text "0<a<1"} too.\<close>
   464 lemma power_inject_exp [simp]:
   465   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   466   by (force simp add: order_antisym power_le_imp_le_exp)
   467 
   468 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
   469 natural numbers.\<close>
   470 lemma power_less_imp_less_exp:
   471   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   472   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   473     power_le_imp_le_exp)
   474 
   475 lemma power_strict_mono [rule_format]:
   476   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   477   by (induct n)
   478    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   479 
   480 text\<open>Lemma for @{text power_strict_decreasing}\<close>
   481 lemma power_Suc_less:
   482   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   483   by (induct n)
   484     (auto simp add: mult_strict_left_mono)
   485 
   486 lemma power_strict_decreasing [rule_format]:
   487   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   488 proof (induct N)
   489   case 0 then show ?case by simp
   490 next
   491   case (Suc N) then show ?case 
   492   apply (auto simp add: power_Suc_less less_Suc_eq)
   493   apply (subgoal_tac "a * a^N < 1 * a^n")
   494   apply simp
   495   apply (rule mult_strict_mono) apply auto
   496   done
   497 qed
   498 
   499 text\<open>Proof resembles that of @{text power_strict_decreasing}\<close>
   500 lemma power_decreasing [rule_format]:
   501   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   502 proof (induct N)
   503   case 0 then show ?case by simp
   504 next
   505   case (Suc N) then show ?case 
   506   apply (auto simp add: le_Suc_eq)
   507   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   508   apply (rule mult_mono) apply auto
   509   done
   510 qed
   511 
   512 lemma power_Suc_less_one:
   513   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   514   using power_strict_decreasing [of 0 "Suc n" a] by simp
   515 
   516 text\<open>Proof again resembles that of @{text power_strict_decreasing}\<close>
   517 lemma power_increasing [rule_format]:
   518   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   519 proof (induct N)
   520   case 0 then show ?case by simp
   521 next
   522   case (Suc N) then show ?case 
   523   apply (auto simp add: le_Suc_eq)
   524   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   525   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   526   done
   527 qed
   528 
   529 text\<open>Lemma for @{text power_strict_increasing}\<close>
   530 lemma power_less_power_Suc:
   531   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   532   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   533 
   534 lemma power_strict_increasing [rule_format]:
   535   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   536 proof (induct N)
   537   case 0 then show ?case by simp
   538 next
   539   case (Suc N) then show ?case 
   540   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   541   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   542   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   543   done
   544 qed
   545 
   546 lemma power_increasing_iff [simp]:
   547   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   548   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   549 
   550 lemma power_strict_increasing_iff [simp]:
   551   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   552 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   553 
   554 lemma power_le_imp_le_base:
   555   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   556     and ynonneg: "0 \<le> b"
   557   shows "a \<le> b"
   558 proof (rule ccontr)
   559   assume "~ a \<le> b"
   560   then have "b < a" by (simp only: linorder_not_le)
   561   then have "b ^ Suc n < a ^ Suc n"
   562     by (simp only: assms power_strict_mono)
   563   from le and this show False
   564     by (simp add: linorder_not_less [symmetric])
   565 qed
   566 
   567 lemma power_less_imp_less_base:
   568   assumes less: "a ^ n < b ^ n"
   569   assumes nonneg: "0 \<le> b"
   570   shows "a < b"
   571 proof (rule contrapos_pp [OF less])
   572   assume "~ a < b"
   573   hence "b \<le> a" by (simp only: linorder_not_less)
   574   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   575   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   576 qed
   577 
   578 lemma power_inject_base:
   579   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   580 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   581 
   582 lemma power_eq_imp_eq_base:
   583   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   584   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   585 
   586 lemma power2_le_imp_le:
   587   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   588   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   589 
   590 lemma power2_less_imp_less:
   591   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   592   by (rule power_less_imp_less_base)
   593 
   594 lemma power2_eq_imp_eq:
   595   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   596   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   597 
   598 end
   599 
   600 context linordered_ring_strict
   601 begin
   602 
   603 lemma sum_squares_eq_zero_iff:
   604   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   605   by (simp add: add_nonneg_eq_0_iff)
   606 
   607 lemma sum_squares_le_zero_iff:
   608   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   609   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   610 
   611 lemma sum_squares_gt_zero_iff:
   612   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   613   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   614 
   615 end
   616 
   617 context linordered_idom
   618 begin
   619 
   620 lemma power_abs:
   621   "abs (a ^ n) = abs a ^ n"
   622   by (induct n) (auto simp add: abs_mult)
   623 
   624 lemma abs_power_minus [simp]:
   625   "abs ((-a) ^ n) = abs (a ^ n)"
   626   by (simp add: power_abs)
   627 
   628 lemma zero_less_power_abs_iff [simp]:
   629   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   630 proof (induct n)
   631   case 0 show ?case by simp
   632 next
   633   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   634 qed
   635 
   636 lemma zero_le_power_abs [simp]:
   637   "0 \<le> abs a ^ n"
   638   by (rule zero_le_power [OF abs_ge_zero])
   639 
   640 lemma zero_le_power2 [simp]:
   641   "0 \<le> a\<^sup>2"
   642   by (simp add: power2_eq_square)
   643 
   644 lemma zero_less_power2 [simp]:
   645   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   646   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   647 
   648 lemma power2_less_0 [simp]:
   649   "\<not> a\<^sup>2 < 0"
   650   by (force simp add: power2_eq_square mult_less_0_iff)
   651 
   652 lemma power2_less_eq_zero_iff [simp]:
   653   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   654   by (simp add: le_less)
   655 
   656 lemma abs_power2 [simp]:
   657   "abs (a\<^sup>2) = a\<^sup>2"
   658   by (simp add: power2_eq_square abs_mult abs_mult_self)
   659 
   660 lemma power2_abs [simp]:
   661   "(abs a)\<^sup>2 = a\<^sup>2"
   662   by (simp add: power2_eq_square abs_mult_self)
   663 
   664 lemma odd_power_less_zero:
   665   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   666 proof (induct n)
   667   case 0
   668   then show ?case by simp
   669 next
   670   case (Suc n)
   671   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   672     by (simp add: ac_simps power_add power2_eq_square)
   673   thus ?case
   674     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   675 qed
   676 
   677 lemma odd_0_le_power_imp_0_le:
   678   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   679   using odd_power_less_zero [of a n]
   680     by (force simp add: linorder_not_less [symmetric]) 
   681 
   682 lemma zero_le_even_power'[simp]:
   683   "0 \<le> a ^ (2*n)"
   684 proof (induct n)
   685   case 0
   686     show ?case by simp
   687 next
   688   case (Suc n)
   689     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)" 
   690       by (simp add: ac_simps power_add power2_eq_square)
   691     thus ?case
   692       by (simp add: Suc zero_le_mult_iff)
   693 qed
   694 
   695 lemma sum_power2_ge_zero:
   696   "0 \<le> x\<^sup>2 + y\<^sup>2"
   697   by (intro add_nonneg_nonneg zero_le_power2)
   698 
   699 lemma not_sum_power2_lt_zero:
   700   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   701   unfolding not_less by (rule sum_power2_ge_zero)
   702 
   703 lemma sum_power2_eq_zero_iff:
   704   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   705   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   706 
   707 lemma sum_power2_le_zero_iff:
   708   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   709   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   710 
   711 lemma sum_power2_gt_zero_iff:
   712   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   713   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   714 
   715 lemma abs_le_square_iff:
   716    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   717 proof
   718   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   719   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   720   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   721 next
   722   assume "x\<^sup>2 \<le> y\<^sup>2"
   723   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   724     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   725 qed
   726 
   727 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> abs(x) \<le> 1"
   728   using abs_le_square_iff [of x 1]
   729   by simp
   730 
   731 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> abs(x) = 1"
   732   by (auto simp add: abs_if power2_eq_1_iff)
   733   
   734 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> abs(x) < 1"
   735   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   736   by (auto simp add: le_less)
   737 
   738 end
   739 
   740 
   741 subsection \<open>Miscellaneous rules\<close>
   742 
   743 lemma (in linordered_semidom) self_le_power:
   744   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   745   using power_increasing [of 1 n a] power_one_right [of a] by auto
   746 
   747 lemma (in power) power_eq_if:
   748   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   749   unfolding One_nat_def by (cases m) simp_all
   750 
   751 lemma (in comm_semiring_1) power2_sum:
   752   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   753   by (simp add: algebra_simps power2_eq_square mult_2_right)
   754 
   755 lemma (in comm_ring_1) power2_diff:
   756   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   757   by (simp add: algebra_simps power2_eq_square mult_2_right)
   758 
   759 lemma (in comm_ring_1) power2_commute:
   760   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   761   by (simp add: algebra_simps power2_eq_square)
   762 
   763 
   764 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   765 
   766 lemmas zero_compare_simps =
   767     add_strict_increasing add_strict_increasing2 add_increasing
   768     zero_le_mult_iff zero_le_divide_iff 
   769     zero_less_mult_iff zero_less_divide_iff 
   770     mult_le_0_iff divide_le_0_iff 
   771     mult_less_0_iff divide_less_0_iff 
   772     zero_le_power2 power2_less_0
   773 
   774 
   775 subsection \<open>Exponentiation for the Natural Numbers\<close>
   776 
   777 lemma nat_one_le_power [simp]:
   778   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   779   by (rule one_le_power [of i n, unfolded One_nat_def])
   780 
   781 lemma nat_zero_less_power_iff [simp]:
   782   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   783   by (induct n) auto
   784 
   785 lemma nat_power_eq_Suc_0_iff [simp]: 
   786   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   787   by (induct m) auto
   788 
   789 lemma power_Suc_0 [simp]:
   790   "Suc 0 ^ n = Suc 0"
   791   by simp
   792 
   793 text\<open>Valid for the naturals, but what if @{text"0<i<1"}?
   794 Premises cannot be weakened: consider the case where @{term "i=0"},
   795 @{term "m=1"} and @{term "n=0"}.\<close>
   796 lemma nat_power_less_imp_less:
   797   assumes nonneg: "0 < (i::nat)"
   798   assumes less: "i ^ m < i ^ n"
   799   shows "m < n"
   800 proof (cases "i = 1")
   801   case True with less power_one [where 'a = nat] show ?thesis by simp
   802 next
   803   case False with nonneg have "1 < i" by auto
   804   from power_strict_increasing_iff [OF this] less show ?thesis ..
   805 qed
   806 
   807 lemma power_dvd_imp_le:
   808   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   809   apply (rule power_le_imp_le_exp, assumption)
   810   apply (erule dvd_imp_le, simp)
   811   done
   812 
   813 lemma power2_nat_le_eq_le:
   814   fixes m n :: nat
   815   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   816   by (auto intro: power2_le_imp_le power_mono)
   817 
   818 lemma power2_nat_le_imp_le:
   819   fixes m n :: nat
   820   assumes "m\<^sup>2 \<le> n"
   821   shows "m \<le> n"
   822 proof (cases m)
   823   case 0 then show ?thesis by simp
   824 next
   825   case (Suc k)
   826   show ?thesis
   827   proof (rule ccontr)
   828     assume "\<not> m \<le> n"
   829     then have "n < m" by simp
   830     with assms Suc show False
   831       by (simp add: power2_eq_square)
   832   qed
   833 qed
   834 
   835 subsubsection \<open>Cardinality of the Powerset\<close>
   836 
   837 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   838   unfolding UNIV_bool by simp
   839 
   840 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   841 proof (induct rule: finite_induct)
   842   case empty 
   843     show ?case by auto
   844 next
   845   case (insert x A)
   846   then have "inj_on (insert x) (Pow A)" 
   847     unfolding inj_on_def by (blast elim!: equalityE)
   848   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A" 
   849     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   850   then show ?case using insert
   851     apply (simp add: Pow_insert)
   852     apply (subst card_Un_disjoint, auto)
   853     done
   854 qed
   855 
   856 
   857 subsubsection \<open>Generalized sum over a set\<close>
   858 
   859 lemma setsum_zero_power [simp]:
   860   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   861   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   862 apply (cases "finite A")
   863   by (induction A rule: finite_induct) auto
   864 
   865 lemma setsum_zero_power' [simp]:
   866   fixes c :: "nat \<Rightarrow> 'a::field"
   867   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   868   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   869   by auto
   870 
   871 
   872 subsubsection \<open>Generalized product over a set\<close>
   873 
   874 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   875 apply (erule finite_induct)
   876 apply auto
   877 done
   878 
   879 lemma setprod_power_distrib:
   880   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   881   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   882 proof (cases "finite A") 
   883   case True then show ?thesis 
   884     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   885 next
   886   case False then show ?thesis 
   887     by simp
   888 qed
   889 
   890 lemma power_setsum:
   891   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
   892   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
   893 
   894 lemma setprod_gen_delta:
   895   assumes fS: "finite S"
   896   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   897 proof-
   898   let ?f = "(\<lambda>k. if k=a then b k else c)"
   899   {assume a: "a \<notin> S"
   900     hence "\<forall> k\<in> S. ?f k = c" by simp
   901     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   902   moreover 
   903   {assume a: "a \<in> S"
   904     let ?A = "S - {a}"
   905     let ?B = "{a}"
   906     have eq: "S = ?A \<union> ?B" using a by blast 
   907     have dj: "?A \<inter> ?B = {}" by simp
   908     from fS have fAB: "finite ?A" "finite ?B" by auto  
   909     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   910       apply (rule setprod.cong) by auto
   911     have cA: "card ?A = card S - 1" using fS a by auto
   912     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   913     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   914       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   915       by simp
   916     then have ?thesis using a cA
   917       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   918   ultimately show ?thesis by blast
   919 qed
   920 
   921 subsection \<open>Code generator tweak\<close>
   922 
   923 code_identifier
   924   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   925 
   926 end