src/HOL/Real/RealDef.thy
author huffman
Thu Jun 07 03:45:56 2007 +0200 (2007-06-07)
changeset 23288 3e45b5464d2b
parent 23287 063039db59dd
child 23289 0cf371d943b1
permissions -rw-r--r--
remove references to preal-specific theorems
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 instance real :: "{ord, zero, one, plus, times, minus, inverse}" ..
    24 
    25 definition
    26 
    27   (** these don't use the overloaded "real" function: users don't see them **)
    28 
    29   real_of_preal :: "preal => real" where
    30   "real_of_preal m = Abs_Real(realrel``{(m + 1, 1)})"
    31 
    32 consts
    33    (*overloaded constant for injecting other types into "real"*)
    34    real :: "'a => real"
    35 
    36 
    37 defs (overloaded)
    38 
    39   real_zero_def:
    40   "0 == Abs_Real(realrel``{(1, 1)})"
    41 
    42   real_one_def:
    43   "1 == Abs_Real(realrel``{(1 + 1, 1)})"
    44 
    45   real_minus_def:
    46   "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    47 
    48   real_add_def:
    49    "z + w ==
    50        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    51 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    52 
    53   real_diff_def:
    54    "r - (s::real) == r + - s"
    55 
    56   real_mult_def:
    57     "z * w ==
    58        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    59 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    60 
    61   real_inverse_def:
    62   "inverse (R::real) == (THE S. (R = 0 & S = 0) | S * R = 1)"
    63 
    64   real_divide_def:
    65   "R / (S::real) == R * inverse S"
    66 
    67   real_le_def:
    68    "z \<le> (w::real) == 
    69     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    70 
    71   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)"
    72 
    73   real_abs_def:  "abs (r::real) == (if r < 0 then - r else r)"
    74 
    75 
    76 subsection {* Equivalence relation over positive reals *}
    77 
    78 lemma preal_trans_lemma:
    79   assumes "x + y1 = x1 + y"
    80       and "x + y2 = x2 + y"
    81   shows "x1 + y2 = x2 + (y1::preal)"
    82 proof -
    83   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    84   also have "... = (x2 + y) + x1"  by (simp add: prems)
    85   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    86   also have "... = x2 + (x + y1)"  by (simp add: prems)
    87   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    88   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    89   thus ?thesis by (rule add_right_imp_eq)
    90 qed
    91 
    92 
    93 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    94 by (simp add: realrel_def)
    95 
    96 lemma equiv_realrel: "equiv UNIV realrel"
    97 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    98 apply (blast dest: preal_trans_lemma) 
    99 done
   100 
   101 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   102   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   103 lemmas equiv_realrel_iff = 
   104        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   105 
   106 declare equiv_realrel_iff [simp]
   107 
   108 
   109 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   110 by (simp add: Real_def realrel_def quotient_def, blast)
   111 
   112 declare Abs_Real_inject [simp]
   113 declare Abs_Real_inverse [simp]
   114 
   115 
   116 text{*Case analysis on the representation of a real number as an equivalence
   117       class of pairs of positive reals.*}
   118 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   119      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   120 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   121 apply (drule arg_cong [where f=Abs_Real])
   122 apply (auto simp add: Rep_Real_inverse)
   123 done
   124 
   125 
   126 subsection {* Addition and Subtraction *}
   127 
   128 lemma real_add_congruent2_lemma:
   129      "[|a + ba = aa + b; ab + bc = ac + bb|]
   130       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   131 apply (simp add: add_assoc)
   132 apply (rule add_left_commute [of ab, THEN ssubst])
   133 apply (simp add: add_assoc [symmetric])
   134 apply (simp add: add_ac)
   135 done
   136 
   137 lemma real_add:
   138      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   139       Abs_Real (realrel``{(x+u, y+v)})"
   140 proof -
   141   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   142         respects2 realrel"
   143     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   144   thus ?thesis
   145     by (simp add: real_add_def UN_UN_split_split_eq
   146                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   147 qed
   148 
   149 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   150 proof -
   151   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   152     by (simp add: congruent_def add_commute) 
   153   thus ?thesis
   154     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   155 qed
   156 
   157 instance real :: ab_group_add
   158 proof
   159   fix x y z :: real
   160   show "(x + y) + z = x + (y + z)"
   161     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   162   show "x + y = y + x"
   163     by (cases x, cases y, simp add: real_add add_commute)
   164   show "0 + x = x"
   165     by (cases x, simp add: real_add real_zero_def add_ac)
   166   show "- x + x = 0"
   167     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   168   show "x - y = x + - y"
   169     by (simp add: real_diff_def)
   170 qed
   171 
   172 
   173 subsection {* Multiplication *}
   174 
   175 lemma real_mult_congruent2_lemma:
   176      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   177           x * x1 + y * y1 + (x * y2 + y * x2) =
   178           x * x2 + y * y2 + (x * y1 + y * x1)"
   179 apply (simp add: add_left_commute add_assoc [symmetric])
   180 apply (simp add: add_assoc right_distrib [symmetric])
   181 apply (simp add: add_commute)
   182 done
   183 
   184 lemma real_mult_congruent2:
   185     "(%p1 p2.
   186         (%(x1,y1). (%(x2,y2). 
   187           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   188      respects2 realrel"
   189 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   190 apply (simp add: mult_commute add_commute)
   191 apply (auto simp add: real_mult_congruent2_lemma)
   192 done
   193 
   194 lemma real_mult:
   195       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   196        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   197 by (simp add: real_mult_def UN_UN_split_split_eq
   198          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   199 
   200 lemma real_mult_commute: "(z::real) * w = w * z"
   201 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   202 
   203 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   204 apply (cases z1, cases z2, cases z3)
   205 apply (simp add: real_mult right_distrib add_ac mult_ac)
   206 done
   207 
   208 lemma real_mult_1: "(1::real) * z = z"
   209 apply (cases z)
   210 apply (simp add: real_mult real_one_def right_distrib
   211                   mult_1_right mult_ac add_ac)
   212 done
   213 
   214 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   215 apply (cases z1, cases z2, cases w)
   216 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   217 done
   218 
   219 text{*one and zero are distinct*}
   220 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   221 proof -
   222   have "(1::preal) < 1 + 1"
   223     by (simp add: preal_self_less_add_left)
   224   thus ?thesis
   225     by (simp add: real_zero_def real_one_def)
   226 qed
   227 
   228 instance real :: comm_ring_1
   229 proof
   230   fix x y z :: real
   231   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   232   show "x * y = y * x" by (rule real_mult_commute)
   233   show "1 * x = x" by (rule real_mult_1)
   234   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   235   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   236 qed
   237 
   238 subsection {* Inverse and Division *}
   239 
   240 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   241 by (simp add: real_zero_def add_commute)
   242 
   243 text{*Instead of using an existential quantifier and constructing the inverse
   244 within the proof, we could define the inverse explicitly.*}
   245 
   246 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   247 apply (simp add: real_zero_def real_one_def, cases x)
   248 apply (cut_tac x = xa and y = y in linorder_less_linear)
   249 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   250 apply (rule_tac
   251         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   252        in exI)
   253 apply (rule_tac [2]
   254         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   255        in exI)
   256 apply (auto simp add: real_mult ring_distrib
   257               preal_mult_inverse_right add_ac mult_ac)
   258 done
   259 
   260 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   261 apply (simp add: real_inverse_def)
   262 apply (drule real_mult_inverse_left_ex, safe)
   263 apply (rule theI, assumption, rename_tac z)
   264 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   265 apply (simp add: mult_commute)
   266 apply (rule mult_assoc)
   267 done
   268 
   269 
   270 subsection{*The Real Numbers form a Field*}
   271 
   272 instance real :: field
   273 proof
   274   fix x y z :: real
   275   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   276   show "x / y = x * inverse y" by (simp add: real_divide_def)
   277 qed
   278 
   279 
   280 text{*Inverse of zero!  Useful to simplify certain equations*}
   281 
   282 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   283 by (simp add: real_inverse_def)
   284 
   285 instance real :: division_by_zero
   286 proof
   287   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   288 qed
   289 
   290 
   291 subsection{*The @{text "\<le>"} Ordering*}
   292 
   293 lemma real_le_refl: "w \<le> (w::real)"
   294 by (cases w, force simp add: real_le_def)
   295 
   296 text{*The arithmetic decision procedure is not set up for type preal.
   297   This lemma is currently unused, but it could simplify the proofs of the
   298   following two lemmas.*}
   299 lemma preal_eq_le_imp_le:
   300   assumes eq: "a+b = c+d" and le: "c \<le> a"
   301   shows "b \<le> (d::preal)"
   302 proof -
   303   have "c+d \<le> a+d" by (simp add: prems)
   304   hence "a+b \<le> a+d" by (simp add: prems)
   305   thus "b \<le> d" by simp
   306 qed
   307 
   308 lemma real_le_lemma:
   309   assumes l: "u1 + v2 \<le> u2 + v1"
   310       and "x1 + v1 = u1 + y1"
   311       and "x2 + v2 = u2 + y2"
   312   shows "x1 + y2 \<le> x2 + (y1::preal)"
   313 proof -
   314   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   315   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   316   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   317   finally show ?thesis by simp
   318 qed
   319 
   320 lemma real_le: 
   321      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   322       (x1 + y2 \<le> x2 + y1)"
   323 apply (simp add: real_le_def)
   324 apply (auto intro: real_le_lemma)
   325 done
   326 
   327 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   328 by (cases z, cases w, simp add: real_le)
   329 
   330 lemma real_trans_lemma:
   331   assumes "x + v \<le> u + y"
   332       and "u + v' \<le> u' + v"
   333       and "x2 + v2 = u2 + y2"
   334   shows "x + v' \<le> u' + (y::preal)"
   335 proof -
   336   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   337   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   338   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   339   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   340   finally show ?thesis by simp
   341 qed
   342 
   343 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   344 apply (cases i, cases j, cases k)
   345 apply (simp add: real_le)
   346 apply (blast intro: real_trans_lemma)
   347 done
   348 
   349 (* Axiom 'order_less_le' of class 'order': *)
   350 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   351 by (simp add: real_less_def)
   352 
   353 instance real :: order
   354 proof qed
   355  (assumption |
   356   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   357 
   358 (* Axiom 'linorder_linear' of class 'linorder': *)
   359 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   360 apply (cases z, cases w)
   361 apply (auto simp add: real_le real_zero_def add_ac)
   362 done
   363 
   364 
   365 instance real :: linorder
   366   by (intro_classes, rule real_le_linear)
   367 
   368 
   369 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   370 apply (cases x, cases y) 
   371 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   372                       add_ac)
   373 apply (simp_all add: add_assoc [symmetric])
   374 done
   375 
   376 lemma real_add_left_mono: 
   377   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   378 proof -
   379   have "z + x - (z + y) = (z + -z) + (x - y)"
   380     by (simp add: diff_minus add_ac) 
   381   with le show ?thesis 
   382     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   383 qed
   384 
   385 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   386 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   387 
   388 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   389 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   390 
   391 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   392 apply (cases x, cases y)
   393 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   394                  linorder_not_le [where 'a = preal] 
   395                   real_zero_def real_le real_mult)
   396   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   397 apply (auto dest!: less_add_left_Ex
   398      simp add: add_ac mult_ac
   399           right_distrib preal_self_less_add_left)
   400 done
   401 
   402 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   403 apply (rule real_sum_gt_zero_less)
   404 apply (drule real_less_sum_gt_zero [of x y])
   405 apply (drule real_mult_order, assumption)
   406 apply (simp add: right_distrib)
   407 done
   408 
   409 instance real :: distrib_lattice
   410   "inf x y \<equiv> min x y"
   411   "sup x y \<equiv> max x y"
   412   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   413 
   414 
   415 subsection{*The Reals Form an Ordered Field*}
   416 
   417 instance real :: ordered_field
   418 proof
   419   fix x y z :: real
   420   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   421   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   422   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   423 qed
   424 
   425 text{*The function @{term real_of_preal} requires many proofs, but it seems
   426 to be essential for proving completeness of the reals from that of the
   427 positive reals.*}
   428 
   429 lemma real_of_preal_add:
   430      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   431 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   432 
   433 lemma real_of_preal_mult:
   434      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   435 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   436 
   437 
   438 text{*Gleason prop 9-4.4 p 127*}
   439 lemma real_of_preal_trichotomy:
   440       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   441 apply (simp add: real_of_preal_def real_zero_def, cases x)
   442 apply (auto simp add: real_minus add_ac)
   443 apply (cut_tac x = x and y = y in linorder_less_linear)
   444 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   445 done
   446 
   447 lemma real_of_preal_leD:
   448       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   449 by (simp add: real_of_preal_def real_le)
   450 
   451 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   452 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   453 
   454 lemma real_of_preal_lessD:
   455       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   456 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   457 
   458 lemma real_of_preal_less_iff [simp]:
   459      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   460 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   461 
   462 lemma real_of_preal_le_iff:
   463      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   464 by (simp add: linorder_not_less [symmetric])
   465 
   466 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   467 apply (insert preal_self_less_add_left [of 1 m])
   468 apply (auto simp add: real_zero_def real_of_preal_def
   469                       real_less_def real_le_def add_ac)
   470 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   471 apply (simp add: add_ac)
   472 done
   473 
   474 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   475 by (simp add: real_of_preal_zero_less)
   476 
   477 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   478 proof -
   479   from real_of_preal_minus_less_zero
   480   show ?thesis by (blast dest: order_less_trans)
   481 qed
   482 
   483 
   484 subsection{*Theorems About the Ordering*}
   485 
   486 text{*obsolete but used a lot*}
   487 
   488 lemma real_not_refl2: "x < y ==> x \<noteq> (y::real)"
   489 by blast 
   490 
   491 lemma real_le_imp_less_or_eq: "!!(x::real). x \<le> y ==> x < y | x = y"
   492 by (simp add: order_le_less)
   493 
   494 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   495 apply (auto simp add: real_of_preal_zero_less)
   496 apply (cut_tac x = x in real_of_preal_trichotomy)
   497 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   498 done
   499 
   500 lemma real_gt_preal_preal_Ex:
   501      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   502 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   503              intro: real_gt_zero_preal_Ex [THEN iffD1])
   504 
   505 lemma real_ge_preal_preal_Ex:
   506      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   507 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   508 
   509 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   510 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   511             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   512             simp add: real_of_preal_zero_less)
   513 
   514 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   515 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   516 
   517 lemma real_le_square [simp]: "(0::real) \<le> x*x"
   518  by (rule Ring_and_Field.zero_le_square)
   519 
   520 
   521 subsection{*More Lemmas*}
   522 
   523 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   524 by auto
   525 
   526 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   527 by auto
   528 
   529 text{*The precondition could be weakened to @{term "0\<le>x"}*}
   530 lemma real_mult_less_mono:
   531      "[| u<v;  x<y;  (0::real) < v;  0 < x |] ==> u*x < v* y"
   532  by (simp add: Ring_and_Field.mult_strict_mono order_less_imp_le)
   533 
   534 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   535   by (force elim: order_less_asym
   536             simp add: Ring_and_Field.mult_less_cancel_right)
   537 
   538 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   539 apply (simp add: mult_le_cancel_right)
   540 apply (blast intro: elim: order_less_asym) 
   541 done
   542 
   543 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   544 by(simp add:mult_commute)
   545 
   546 lemma real_add_order: "[| 0 < x; 0 < y |] ==> (0::real) < x + y"
   547 by (rule add_pos_pos)
   548 
   549 lemma real_le_add_order: "[| 0 \<le> x; 0 \<le> y |] ==> (0::real) \<le> x + y"
   550 by (rule add_nonneg_nonneg)
   551 
   552 lemma real_inverse_unique: "x*y = (1::real) ==> y = inverse x"
   553 by (rule inverse_unique [symmetric])
   554 
   555 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   556 by (simp add: one_less_inverse_iff)
   557 
   558 
   559 subsection{*Embedding the Integers into the Reals*}
   560 
   561 defs (overloaded)
   562   real_of_nat_def: "real z == of_nat z"
   563   real_of_int_def: "real z == of_int z"
   564 
   565 lemma real_eq_of_nat: "real = of_nat"
   566   apply (rule ext)
   567   apply (unfold real_of_nat_def)
   568   apply (rule refl)
   569   done
   570 
   571 lemma real_eq_of_int: "real = of_int"
   572   apply (rule ext)
   573   apply (unfold real_of_int_def)
   574   apply (rule refl)
   575   done
   576 
   577 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   578 by (simp add: real_of_int_def) 
   579 
   580 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   581 by (simp add: real_of_int_def) 
   582 
   583 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   584 by (simp add: real_of_int_def) 
   585 
   586 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   587 by (simp add: real_of_int_def) 
   588 
   589 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   590 by (simp add: real_of_int_def) 
   591 
   592 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   593 by (simp add: real_of_int_def) 
   594 
   595 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   596   apply (subst real_eq_of_int)+
   597   apply (rule of_int_setsum)
   598 done
   599 
   600 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   601     (PROD x:A. real(f x))"
   602   apply (subst real_eq_of_int)+
   603   apply (rule of_int_setprod)
   604 done
   605 
   606 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   607 by (simp add: real_of_int_def) 
   608 
   609 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   610 by (simp add: real_of_int_def) 
   611 
   612 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   613 by (simp add: real_of_int_def) 
   614 
   615 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   616 by (simp add: real_of_int_def) 
   617 
   618 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   619 by (simp add: real_of_int_def) 
   620 
   621 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   622 by (simp add: real_of_int_def) 
   623 
   624 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   625 by (simp add: real_of_int_def)
   626 
   627 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   628 by (simp add: real_of_int_def)
   629 
   630 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   631 by (auto simp add: abs_if)
   632 
   633 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   634   apply (subgoal_tac "real n + 1 = real (n + 1)")
   635   apply (simp del: real_of_int_add)
   636   apply auto
   637 done
   638 
   639 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   640   apply (subgoal_tac "real m + 1 = real (m + 1)")
   641   apply (simp del: real_of_int_add)
   642   apply simp
   643 done
   644 
   645 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   646     real (x div d) + (real (x mod d)) / (real d)"
   647 proof -
   648   assume "d ~= 0"
   649   have "x = (x div d) * d + x mod d"
   650     by auto
   651   then have "real x = real (x div d) * real d + real(x mod d)"
   652     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   653   then have "real x / real d = ... / real d"
   654     by simp
   655   then show ?thesis
   656     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   657 qed
   658 
   659 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   660     real(n div d) = real n / real d"
   661   apply (frule real_of_int_div_aux [of d n])
   662   apply simp
   663   apply (simp add: zdvd_iff_zmod_eq_0)
   664 done
   665 
   666 lemma real_of_int_div2:
   667   "0 <= real (n::int) / real (x) - real (n div x)"
   668   apply (case_tac "x = 0")
   669   apply simp
   670   apply (case_tac "0 < x")
   671   apply (simp add: compare_rls)
   672   apply (subst real_of_int_div_aux)
   673   apply simp
   674   apply simp
   675   apply (subst zero_le_divide_iff)
   676   apply auto
   677   apply (simp add: compare_rls)
   678   apply (subst real_of_int_div_aux)
   679   apply simp
   680   apply simp
   681   apply (subst zero_le_divide_iff)
   682   apply auto
   683 done
   684 
   685 lemma real_of_int_div3:
   686   "real (n::int) / real (x) - real (n div x) <= 1"
   687   apply(case_tac "x = 0")
   688   apply simp
   689   apply (simp add: compare_rls)
   690   apply (subst real_of_int_div_aux)
   691   apply assumption
   692   apply simp
   693   apply (subst divide_le_eq)
   694   apply clarsimp
   695   apply (rule conjI)
   696   apply (rule impI)
   697   apply (rule order_less_imp_le)
   698   apply simp
   699   apply (rule impI)
   700   apply (rule order_less_imp_le)
   701   apply simp
   702 done
   703 
   704 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   705   by (insert real_of_int_div2 [of n x], simp)
   706 
   707 subsection{*Embedding the Naturals into the Reals*}
   708 
   709 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   710 by (simp add: real_of_nat_def)
   711 
   712 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   713 by (simp add: real_of_nat_def)
   714 
   715 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   716 by (simp add: real_of_nat_def)
   717 
   718 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   719 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   720 by (simp add: real_of_nat_def)
   721 
   722 lemma real_of_nat_less_iff [iff]: 
   723      "(real (n::nat) < real m) = (n < m)"
   724 by (simp add: real_of_nat_def)
   725 
   726 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   727 by (simp add: real_of_nat_def)
   728 
   729 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   730 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   731 
   732 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   733 by (simp add: real_of_nat_def del: of_nat_Suc)
   734 
   735 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   736 by (simp add: real_of_nat_def)
   737 
   738 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   739     (SUM x:A. real(f x))"
   740   apply (subst real_eq_of_nat)+
   741   apply (rule of_nat_setsum)
   742 done
   743 
   744 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   745     (PROD x:A. real(f x))"
   746   apply (subst real_eq_of_nat)+
   747   apply (rule of_nat_setprod)
   748 done
   749 
   750 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   751   apply (subst card_eq_setsum)
   752   apply (subst real_of_nat_setsum)
   753   apply simp
   754 done
   755 
   756 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   757 by (simp add: real_of_nat_def)
   758 
   759 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   760 by (simp add: real_of_nat_def)
   761 
   762 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   763 by (simp add: add: real_of_nat_def) 
   764 
   765 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   766 by (simp add: add: real_of_nat_def) 
   767 
   768 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   769 by (simp add: add: real_of_nat_def)
   770 
   771 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   772 by (simp add: add: real_of_nat_def)
   773 
   774 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   775 by (simp add: add: real_of_nat_def)
   776 
   777 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   778   apply (subgoal_tac "real n + 1 = real (Suc n)")
   779   apply simp
   780   apply (auto simp add: real_of_nat_Suc)
   781 done
   782 
   783 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   784   apply (subgoal_tac "real m + 1 = real (Suc m)")
   785   apply (simp add: less_Suc_eq_le)
   786   apply (simp add: real_of_nat_Suc)
   787 done
   788 
   789 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   790     real (x div d) + (real (x mod d)) / (real d)"
   791 proof -
   792   assume "0 < d"
   793   have "x = (x div d) * d + x mod d"
   794     by auto
   795   then have "real x = real (x div d) * real d + real(x mod d)"
   796     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   797   then have "real x / real d = \<dots> / real d"
   798     by simp
   799   then show ?thesis
   800     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   801 qed
   802 
   803 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   804     real(n div d) = real n / real d"
   805   apply (frule real_of_nat_div_aux [of d n])
   806   apply simp
   807   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   808   apply assumption
   809 done
   810 
   811 lemma real_of_nat_div2:
   812   "0 <= real (n::nat) / real (x) - real (n div x)"
   813   apply(case_tac "x = 0")
   814   apply simp
   815   apply (simp add: compare_rls)
   816   apply (subst real_of_nat_div_aux)
   817   apply assumption
   818   apply simp
   819   apply (subst zero_le_divide_iff)
   820   apply simp
   821 done
   822 
   823 lemma real_of_nat_div3:
   824   "real (n::nat) / real (x) - real (n div x) <= 1"
   825   apply(case_tac "x = 0")
   826   apply simp
   827   apply (simp add: compare_rls)
   828   apply (subst real_of_nat_div_aux)
   829   apply assumption
   830   apply simp
   831 done
   832 
   833 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   834   by (insert real_of_nat_div2 [of n x], simp)
   835 
   836 lemma real_of_int_real_of_nat: "real (int n) = real n"
   837 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   838 
   839 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   840 by (simp add: real_of_int_def real_of_nat_def)
   841 
   842 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   843   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   844   apply force
   845   apply (simp only: real_of_int_real_of_nat)
   846 done
   847 
   848 subsection{*Numerals and Arithmetic*}
   849 
   850 instance real :: number ..
   851 
   852 defs (overloaded)
   853   real_number_of_def: "(number_of w :: real) == of_int w"
   854     --{*the type constraint is essential!*}
   855 
   856 instance real :: number_ring
   857 by (intro_classes, simp add: real_number_of_def) 
   858 
   859 text{*Collapse applications of @{term real} to @{term number_of}*}
   860 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   861 by (simp add:  real_of_int_def of_int_number_of_eq)
   862 
   863 lemma real_of_nat_number_of [simp]:
   864      "real (number_of v :: nat) =  
   865         (if neg (number_of v :: int) then 0  
   866          else (number_of v :: real))"
   867 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   868  
   869 
   870 use "real_arith.ML"
   871 
   872 setup real_arith_setup
   873 
   874 
   875 lemma real_diff_mult_distrib:
   876   fixes a::real
   877   shows "a * (b - c) = a * b - a * c" 
   878 proof -
   879   have "a * (b - c) = a * (b + -c)" by simp
   880   also have "\<dots> = (b + -c) * a" by simp
   881   also have "\<dots> = b*a + (-c)*a" by (rule real_add_mult_distrib)
   882   also have "\<dots> = a*b - a*c" by simp
   883   finally show ?thesis .
   884 qed
   885 
   886 
   887 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   888 
   889 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   890 lemma real_0_le_divide_iff:
   891      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   892 by (simp add: real_divide_def zero_le_mult_iff, auto)
   893 
   894 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   895 by arith
   896 
   897 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   898 by auto
   899 
   900 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   901 by auto
   902 
   903 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   904 by auto
   905 
   906 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   907 by auto
   908 
   909 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   910 by auto
   911 
   912 
   913 (*
   914 FIXME: we should have this, as for type int, but many proofs would break.
   915 It replaces x+-y by x-y.
   916 declare real_diff_def [symmetric, simp]
   917 *)
   918 
   919 
   920 subsubsection{*Density of the Reals*}
   921 
   922 lemma real_lbound_gt_zero:
   923      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   924 apply (rule_tac x = " (min d1 d2) /2" in exI)
   925 apply (simp add: min_def)
   926 done
   927 
   928 
   929 text{*Similar results are proved in @{text Ring_and_Field}*}
   930 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   931   by auto
   932 
   933 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   934   by auto
   935 
   936 
   937 subsection{*Absolute Value Function for the Reals*}
   938 
   939 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   940 by (simp add: abs_if)
   941 
   942 lemma abs_interval_iff: "(abs x < r) = (-r < x & x < (r::real))"
   943 by (force simp add: Ring_and_Field.abs_less_iff)
   944 
   945 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   946 by (force simp add: OrderedGroup.abs_le_iff)
   947 
   948 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   949 by (simp add: abs_if)
   950 
   951 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   952 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   953 
   954 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   955 by simp
   956  
   957 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   958 by simp
   959 
   960 subsection{*Code generation using Isabelle's rats*}
   961 
   962 types_code
   963   real ("Rat.rat")
   964 attach (term_of) {*
   965 fun term_of_real x =
   966  let 
   967   val rT = HOLogic.realT
   968   val (p, q) = Rat.quotient_of_rat x
   969  in if q = 1 then HOLogic.mk_number rT p
   970     else Const("HOL.divide",[rT,rT] ---> rT) $
   971            (HOLogic.mk_number rT p) $ (HOLogic.mk_number rT q)
   972 end;
   973 *}
   974 attach (test) {*
   975 fun gen_real i =
   976 let val p = random_range 0 i; val q = random_range 0 i;
   977     val r = if q=0 then Rat.rat_of_int i else Rat.rat_of_quotient(p,q)
   978 in if one_of [true,false] then r else Rat.neg r end;
   979 *}
   980 
   981 consts_code
   982   "0 :: real" ("Rat.zero")
   983   "1 :: real" ("Rat.one")
   984   "uminus :: real \<Rightarrow> real" ("Rat.neg")
   985   "op + :: real \<Rightarrow> real \<Rightarrow> real" ("Rat.add")
   986   "op * :: real \<Rightarrow> real \<Rightarrow> real" ("Rat.mult")
   987   "inverse :: real \<Rightarrow> real" ("Rat.inv")
   988   "op \<le> :: real \<Rightarrow> real \<Rightarrow> bool" ("Rat.le")
   989   "op < :: real \<Rightarrow> real \<Rightarrow> bool" ("(Rat.ord (_, _) = LESS)")
   990   "op = :: real \<Rightarrow> real \<Rightarrow> bool" ("curry Rat.eq")
   991   "real :: int \<Rightarrow> real" ("Rat.rat'_of'_int")
   992   "real :: nat \<Rightarrow> real" ("(Rat.rat'_of'_int o {*int*})")
   993 
   994 
   995 lemma [code, code unfold]:
   996   "number_of k = real (number_of k :: int)"
   997   by simp
   998 
   999 end