src/HOL/Deriv.thy
author paulson
Mon Sep 21 19:52:13 2015 +0100 (2015-09-21)
changeset 61204 3e491e34a62e
parent 60758 d8d85a8172b5
child 61552 980dd46a03fb
permissions -rw-r--r--
new lemmas and movement of lemmas into place
     1 (*  Title       : Deriv.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Author      : Brian Huffman
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     GMVT by Benjamin Porter, 2005
     7 *)
     8 
     9 section\<open>Differentiation\<close>
    10 
    11 theory Deriv
    12 imports Limits
    13 begin
    14 
    15 subsection \<open>Frechet derivative\<close>
    16 
    17 definition
    18   has_derivative :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow>  bool"
    19   (infix "(has'_derivative)" 50)
    20 where
    21   "(f has_derivative f') F \<longleftrightarrow>
    22     (bounded_linear f' \<and>
    23      ((\<lambda>y. ((f y - f (Lim F (\<lambda>x. x))) - f' (y - Lim F (\<lambda>x. x))) /\<^sub>R norm (y - Lim F (\<lambda>x. x))) ---> 0) F)"
    24 
    25 text \<open>
    26   Usually the filter @{term F} is @{term "at x within s"}.  @{term "(f has_derivative D)
    27   (at x within s)"} means: @{term D} is the derivative of function @{term f} at point @{term x}
    28   within the set @{term s}. Where @{term s} is used to express left or right sided derivatives. In
    29   most cases @{term s} is either a variable or @{term UNIV}.
    30 \<close>
    31 
    32 lemma has_derivative_eq_rhs: "(f has_derivative f') F \<Longrightarrow> f' = g' \<Longrightarrow> (f has_derivative g') F"
    33   by simp
    34 
    35 definition 
    36   has_field_derivative :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a filter \<Rightarrow> bool"
    37   (infix "(has'_field'_derivative)" 50)
    38 where
    39   "(f has_field_derivative D) F \<longleftrightarrow> (f has_derivative op * D) F"
    40 
    41 lemma DERIV_cong: "(f has_field_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_field_derivative Y) F"
    42   by simp
    43 
    44 definition
    45   has_vector_derivative :: "(real \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'b \<Rightarrow> real filter \<Rightarrow> bool"
    46   (infix "has'_vector'_derivative" 50)
    47 where
    48   "(f has_vector_derivative f') net \<longleftrightarrow> (f has_derivative (\<lambda>x. x *\<^sub>R f')) net"
    49 
    50 lemma has_vector_derivative_eq_rhs: "(f has_vector_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_vector_derivative Y) F"
    51   by simp
    52 
    53 named_theorems derivative_intros "structural introduction rules for derivatives"
    54 setup \<open>
    55   let
    56     val eq_thms = @{thms has_derivative_eq_rhs DERIV_cong has_vector_derivative_eq_rhs}
    57     fun eq_rule thm = get_first (try (fn eq_thm => eq_thm OF [thm])) eq_thms
    58   in
    59     Global_Theory.add_thms_dynamic
    60       (@{binding derivative_eq_intros},
    61         fn context =>
    62           Named_Theorems.get (Context.proof_of context) @{named_theorems derivative_intros}
    63           |> map_filter eq_rule)
    64   end;
    65 \<close>
    66 
    67 text \<open>
    68   The following syntax is only used as a legacy syntax.
    69 \<close>
    70 abbreviation (input)
    71   FDERIV :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a \<Rightarrow>  ('a \<Rightarrow> 'b) \<Rightarrow> bool"
    72   ("(FDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
    73 where
    74   "FDERIV f x :> f' \<equiv> (f has_derivative f') (at x)"
    75 
    76 lemma has_derivative_bounded_linear: "(f has_derivative f') F \<Longrightarrow> bounded_linear f'"
    77   by (simp add: has_derivative_def)
    78 
    79 lemma has_derivative_linear: "(f has_derivative f') F \<Longrightarrow> linear f'"
    80   using bounded_linear.linear[OF has_derivative_bounded_linear] .
    81 
    82 lemma has_derivative_ident[derivative_intros, simp]: "((\<lambda>x. x) has_derivative (\<lambda>x. x)) F"
    83   by (simp add: has_derivative_def)
    84 
    85 lemma has_derivative_const[derivative_intros, simp]: "((\<lambda>x. c) has_derivative (\<lambda>x. 0)) F"
    86   by (simp add: has_derivative_def)
    87 
    88 lemma (in bounded_linear) bounded_linear: "bounded_linear f" ..
    89 
    90 lemma (in bounded_linear) has_derivative:
    91   "(g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f (g x)) has_derivative (\<lambda>x. f (g' x))) F"
    92   using assms unfolding has_derivative_def
    93   apply safe
    94   apply (erule bounded_linear_compose [OF bounded_linear])
    95   apply (drule tendsto)
    96   apply (simp add: scaleR diff add zero)
    97   done
    98 
    99 lemmas has_derivative_scaleR_right [derivative_intros] =
   100   bounded_linear.has_derivative [OF bounded_linear_scaleR_right]
   101 
   102 lemmas has_derivative_scaleR_left [derivative_intros] =
   103   bounded_linear.has_derivative [OF bounded_linear_scaleR_left]
   104 
   105 lemmas has_derivative_mult_right [derivative_intros] =
   106   bounded_linear.has_derivative [OF bounded_linear_mult_right]
   107 
   108 lemmas has_derivative_mult_left [derivative_intros] =
   109   bounded_linear.has_derivative [OF bounded_linear_mult_left]
   110 
   111 lemma has_derivative_add[simp, derivative_intros]:
   112   assumes f: "(f has_derivative f') F" and g: "(g has_derivative g') F"
   113   shows "((\<lambda>x. f x + g x) has_derivative (\<lambda>x. f' x + g' x)) F"
   114   unfolding has_derivative_def
   115 proof safe
   116   let ?x = "Lim F (\<lambda>x. x)"
   117   let ?D = "\<lambda>f f' y. ((f y - f ?x) - f' (y - ?x)) /\<^sub>R norm (y - ?x)"
   118   have "((\<lambda>x. ?D f f' x + ?D g g' x) ---> (0 + 0)) F"
   119     using f g by (intro tendsto_add) (auto simp: has_derivative_def)
   120   then show "(?D (\<lambda>x. f x + g x) (\<lambda>x. f' x + g' x) ---> 0) F"
   121     by (simp add: field_simps scaleR_add_right scaleR_diff_right)
   122 qed (blast intro: bounded_linear_add f g has_derivative_bounded_linear)
   123 
   124 lemma has_derivative_setsum[simp, derivative_intros]:
   125   assumes f: "\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) F"
   126   shows "((\<lambda>x. \<Sum>i\<in>I. f i x) has_derivative (\<lambda>x. \<Sum>i\<in>I. f' i x)) F"
   127 proof cases
   128   assume "finite I" from this f show ?thesis
   129     by induct (simp_all add: f)
   130 qed simp
   131 
   132 lemma has_derivative_minus[simp, derivative_intros]: "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. - f x) has_derivative (\<lambda>x. - f' x)) F"
   133   using has_derivative_scaleR_right[of f f' F "-1"] by simp
   134 
   135 lemma has_derivative_diff[simp, derivative_intros]:
   136   "(f has_derivative f') F \<Longrightarrow> (g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f x - g x) has_derivative (\<lambda>x. f' x - g' x)) F"
   137   by (simp only: diff_conv_add_uminus has_derivative_add has_derivative_minus)
   138 
   139 lemma has_derivative_at_within:
   140   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   141     (bounded_linear f' \<and> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) ---> 0) (at x within s))"
   142   by (cases "at x within s = bot") (simp_all add: has_derivative_def Lim_ident_at)
   143 
   144 lemma has_derivative_iff_norm:
   145   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   146     (bounded_linear f' \<and> ((\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x)) ---> 0) (at x within s))"
   147   using tendsto_norm_zero_iff[of _ "at x within s", where 'b="'b", symmetric]
   148   by (simp add: has_derivative_at_within divide_inverse ac_simps)
   149 
   150 lemma has_derivative_at:
   151   "(f has_derivative D) (at x) \<longleftrightarrow> (bounded_linear D \<and> (\<lambda>h. norm (f (x + h) - f x - D h) / norm h) -- 0 --> 0)"
   152   unfolding has_derivative_iff_norm LIM_offset_zero_iff[of _ _ x] by simp
   153 
   154 lemma field_has_derivative_at:
   155   fixes x :: "'a::real_normed_field"
   156   shows "(f has_derivative op * D) (at x) \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) -- 0 --> D"
   157   apply (unfold has_derivative_at)
   158   apply (simp add: bounded_linear_mult_right)
   159   apply (simp cong: LIM_cong add: nonzero_norm_divide [symmetric])
   160   apply (subst diff_divide_distrib)
   161   apply (subst times_divide_eq_left [symmetric])
   162   apply (simp cong: LIM_cong)
   163   apply (simp add: tendsto_norm_zero_iff LIM_zero_iff)
   164   done
   165 
   166 lemma has_derivativeI:
   167   "bounded_linear f' \<Longrightarrow> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) ---> 0) (at x within s) \<Longrightarrow>
   168   (f has_derivative f') (at x within s)"
   169   by (simp add: has_derivative_at_within)
   170 
   171 lemma has_derivativeI_sandwich:
   172   assumes e: "0 < e" and bounded: "bounded_linear f'"
   173     and sandwich: "(\<And>y. y \<in> s \<Longrightarrow> y \<noteq> x \<Longrightarrow> dist y x < e \<Longrightarrow> norm ((f y - f x) - f' (y - x)) / norm (y - x) \<le> H y)"
   174     and "(H ---> 0) (at x within s)"
   175   shows "(f has_derivative f') (at x within s)"
   176   unfolding has_derivative_iff_norm
   177 proof safe
   178   show "((\<lambda>y. norm (f y - f x - f' (y - x)) / norm (y - x)) ---> 0) (at x within s)"
   179   proof (rule tendsto_sandwich[where f="\<lambda>x. 0"])
   180     show "(H ---> 0) (at x within s)" by fact
   181     show "eventually (\<lambda>n. norm (f n - f x - f' (n - x)) / norm (n - x) \<le> H n) (at x within s)"
   182       unfolding eventually_at using e sandwich by auto
   183   qed (auto simp: le_divide_eq)
   184 qed fact
   185 
   186 lemma has_derivative_subset: "(f has_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> (f has_derivative f') (at x within t)"
   187   by (auto simp add: has_derivative_iff_norm intro: tendsto_within_subset)
   188 
   189 lemmas has_derivative_within_subset = has_derivative_subset 
   190 
   191 
   192 subsection \<open>Continuity\<close>
   193 
   194 lemma has_derivative_continuous:
   195   assumes f: "(f has_derivative f') (at x within s)"
   196   shows "continuous (at x within s) f"
   197 proof -
   198   from f interpret F: bounded_linear f' by (rule has_derivative_bounded_linear)
   199   note F.tendsto[tendsto_intros]
   200   let ?L = "\<lambda>f. (f ---> 0) (at x within s)"
   201   have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x))"
   202     using f unfolding has_derivative_iff_norm by blast
   203   then have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x) * norm (y - x))" (is ?m)
   204     by (rule tendsto_mult_zero) (auto intro!: tendsto_eq_intros)
   205   also have "?m \<longleftrightarrow> ?L (\<lambda>y. norm ((f y - f x) - f' (y - x)))"
   206     by (intro filterlim_cong) (simp_all add: eventually_at_filter)
   207   finally have "?L (\<lambda>y. (f y - f x) - f' (y - x))"
   208     by (rule tendsto_norm_zero_cancel)
   209   then have "?L (\<lambda>y. ((f y - f x) - f' (y - x)) + f' (y - x))"
   210     by (rule tendsto_eq_intros) (auto intro!: tendsto_eq_intros simp: F.zero)
   211   then have "?L (\<lambda>y. f y - f x)"
   212     by simp
   213   from tendsto_add[OF this tendsto_const, of "f x"] show ?thesis
   214     by (simp add: continuous_within)
   215 qed
   216 
   217 subsection \<open>Composition\<close>
   218 
   219 lemma tendsto_at_iff_tendsto_nhds_within: "f x = y \<Longrightarrow> (f ---> y) (at x within s) \<longleftrightarrow> (f ---> y) (inf (nhds x) (principal s))"
   220   unfolding tendsto_def eventually_inf_principal eventually_at_filter
   221   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
   222 
   223 lemma has_derivative_in_compose:
   224   assumes f: "(f has_derivative f') (at x within s)"
   225   assumes g: "(g has_derivative g') (at (f x) within (f`s))"
   226   shows "((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   227 proof -
   228   from f interpret F: bounded_linear f' by (rule has_derivative_bounded_linear)
   229   from g interpret G: bounded_linear g' by (rule has_derivative_bounded_linear)
   230   from F.bounded obtain kF where kF: "\<And>x. norm (f' x) \<le> norm x * kF" by fast
   231   from G.bounded obtain kG where kG: "\<And>x. norm (g' x) \<le> norm x * kG" by fast
   232   note G.tendsto[tendsto_intros]
   233 
   234   let ?L = "\<lambda>f. (f ---> 0) (at x within s)"
   235   let ?D = "\<lambda>f f' x y. (f y - f x) - f' (y - x)"
   236   let ?N = "\<lambda>f f' x y. norm (?D f f' x y) / norm (y - x)"
   237   let ?gf = "\<lambda>x. g (f x)" and ?gf' = "\<lambda>x. g' (f' x)"
   238   def Nf \<equiv> "?N f f' x"
   239   def Ng \<equiv> "\<lambda>y. ?N g g' (f x) (f y)"
   240 
   241   show ?thesis
   242   proof (rule has_derivativeI_sandwich[of 1])
   243     show "bounded_linear (\<lambda>x. g' (f' x))"
   244       using f g by (blast intro: bounded_linear_compose has_derivative_bounded_linear)
   245   next
   246     fix y::'a assume neq: "y \<noteq> x"
   247     have "?N ?gf ?gf' x y = norm (g' (?D f f' x y) + ?D g g' (f x) (f y)) / norm (y - x)"
   248       by (simp add: G.diff G.add field_simps)
   249     also have "\<dots> \<le> norm (g' (?D f f' x y)) / norm (y - x) + Ng y * (norm (f y - f x) / norm (y - x))"
   250       by (simp add: add_divide_distrib[symmetric] divide_right_mono norm_triangle_ineq G.zero Ng_def)
   251     also have "\<dots> \<le> Nf y * kG + Ng y * (Nf y + kF)"
   252     proof (intro add_mono mult_left_mono)
   253       have "norm (f y - f x) = norm (?D f f' x y + f' (y - x))"
   254         by simp
   255       also have "\<dots> \<le> norm (?D f f' x y) + norm (f' (y - x))"
   256         by (rule norm_triangle_ineq)
   257       also have "\<dots> \<le> norm (?D f f' x y) + norm (y - x) * kF"
   258         using kF by (intro add_mono) simp
   259       finally show "norm (f y - f x) / norm (y - x) \<le> Nf y + kF"
   260         by (simp add: neq Nf_def field_simps)
   261     qed (insert kG, simp_all add: Ng_def Nf_def neq zero_le_divide_iff field_simps)
   262     finally show "?N ?gf ?gf' x y \<le> Nf y * kG + Ng y * (Nf y + kF)" .
   263   next
   264     have [tendsto_intros]: "?L Nf"
   265       using f unfolding has_derivative_iff_norm Nf_def ..
   266     from f have "(f ---> f x) (at x within s)"
   267       by (blast intro: has_derivative_continuous continuous_within[THEN iffD1])
   268     then have f': "LIM x at x within s. f x :> inf (nhds (f x)) (principal (f`s))"
   269       unfolding filterlim_def
   270       by (simp add: eventually_filtermap eventually_at_filter le_principal)
   271 
   272     have "((?N g  g' (f x)) ---> 0) (at (f x) within f`s)"
   273       using g unfolding has_derivative_iff_norm ..
   274     then have g': "((?N g  g' (f x)) ---> 0) (inf (nhds (f x)) (principal (f`s)))"
   275       by (rule tendsto_at_iff_tendsto_nhds_within[THEN iffD1, rotated]) simp
   276 
   277     have [tendsto_intros]: "?L Ng"
   278       unfolding Ng_def by (rule filterlim_compose[OF g' f'])
   279     show "((\<lambda>y. Nf y * kG + Ng y * (Nf y + kF)) ---> 0) (at x within s)"
   280       by (intro tendsto_eq_intros) auto
   281   qed simp
   282 qed
   283 
   284 lemma has_derivative_compose:
   285   "(f has_derivative f') (at x within s) \<Longrightarrow> (g has_derivative g') (at (f x)) \<Longrightarrow>
   286   ((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   287   by (blast intro: has_derivative_in_compose has_derivative_subset)
   288 
   289 lemma (in bounded_bilinear) FDERIV:
   290   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)"
   291   shows "((\<lambda>x. f x ** g x) has_derivative (\<lambda>h. f x ** g' h + f' h ** g x)) (at x within s)"
   292 proof -
   293   from bounded_linear.bounded [OF has_derivative_bounded_linear [OF f]]
   294   obtain KF where norm_F: "\<And>x. norm (f' x) \<le> norm x * KF" by fast
   295 
   296   from pos_bounded obtain K where K: "0 < K" and norm_prod:
   297     "\<And>a b. norm (a ** b) \<le> norm a * norm b * K" by fast
   298   let ?D = "\<lambda>f f' y. f y - f x - f' (y - x)"
   299   let ?N = "\<lambda>f f' y. norm (?D f f' y) / norm (y - x)"
   300   def Ng =="?N g g'" and Nf =="?N f f'"
   301 
   302   let ?fun1 = "\<lambda>y. norm (f y ** g y - f x ** g x - (f x ** g' (y - x) + f' (y - x) ** g x)) / norm (y - x)"
   303   let ?fun2 = "\<lambda>y. norm (f x) * Ng y * K + Nf y * norm (g y) * K + KF * norm (g y - g x) * K"
   304   let ?F = "at x within s"
   305 
   306   show ?thesis
   307   proof (rule has_derivativeI_sandwich[of 1])
   308     show "bounded_linear (\<lambda>h. f x ** g' h + f' h ** g x)"
   309       by (intro bounded_linear_add
   310         bounded_linear_compose [OF bounded_linear_right] bounded_linear_compose [OF bounded_linear_left]
   311         has_derivative_bounded_linear [OF g] has_derivative_bounded_linear [OF f])
   312   next
   313     from g have "(g ---> g x) ?F"
   314       by (intro continuous_within[THEN iffD1] has_derivative_continuous)
   315     moreover from f g have "(Nf ---> 0) ?F" "(Ng ---> 0) ?F"
   316       by (simp_all add: has_derivative_iff_norm Ng_def Nf_def)
   317     ultimately have "(?fun2 ---> norm (f x) * 0 * K + 0 * norm (g x) * K + KF * norm (0::'b) * K) ?F"
   318       by (intro tendsto_intros) (simp_all add: LIM_zero_iff)
   319     then show "(?fun2 ---> 0) ?F"
   320       by simp
   321   next
   322     fix y::'d assume "y \<noteq> x"
   323     have "?fun1 y = norm (f x ** ?D g g' y + ?D f f' y ** g y + f' (y - x) ** (g y - g x)) / norm (y - x)"
   324       by (simp add: diff_left diff_right add_left add_right field_simps)
   325     also have "\<dots> \<le> (norm (f x) * norm (?D g g' y) * K + norm (?D f f' y) * norm (g y) * K +
   326         norm (y - x) * KF * norm (g y - g x) * K) / norm (y - x)"
   327       by (intro divide_right_mono mult_mono'
   328                 order_trans [OF norm_triangle_ineq add_mono]
   329                 order_trans [OF norm_prod mult_right_mono]
   330                 mult_nonneg_nonneg order_refl norm_ge_zero norm_F
   331                 K [THEN order_less_imp_le])
   332     also have "\<dots> = ?fun2 y"
   333       by (simp add: add_divide_distrib Ng_def Nf_def)
   334     finally show "?fun1 y \<le> ?fun2 y" .
   335   qed simp
   336 qed
   337 
   338 lemmas has_derivative_mult[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_mult]
   339 lemmas has_derivative_scaleR[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_scaleR]
   340 
   341 lemma has_derivative_setprod[simp, derivative_intros]:
   342   fixes f :: "'i \<Rightarrow> 'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   343   assumes f: "\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) (at x within s)"
   344   shows "((\<lambda>x. \<Prod>i\<in>I. f i x) has_derivative (\<lambda>y. \<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x))) (at x within s)"
   345 proof cases
   346   assume "finite I" from this f show ?thesis
   347   proof induct
   348     case (insert i I)
   349     let ?P = "\<lambda>y. f i x * (\<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x)) + (f' i y) * (\<Prod>i\<in>I. f i x)"
   350     have "((\<lambda>x. f i x * (\<Prod>i\<in>I. f i x)) has_derivative ?P) (at x within s)"
   351       using insert by (intro has_derivative_mult) auto
   352     also have "?P = (\<lambda>y. \<Sum>i'\<in>insert i I. f' i' y * (\<Prod>j\<in>insert i I - {i'}. f j x))"
   353       using insert(1,2) by (auto simp add: setsum_right_distrib insert_Diff_if intro!: ext setsum.cong)
   354     finally show ?case
   355       using insert by simp
   356   qed simp  
   357 qed simp
   358 
   359 lemma has_derivative_power[simp, derivative_intros]:
   360   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   361   assumes f: "(f has_derivative f') (at x within s)"
   362   shows "((\<lambda>x. f x^n) has_derivative (\<lambda>y. of_nat n * f' y * f x^(n - 1))) (at x within s)"
   363   using has_derivative_setprod[OF f, of "{..< n}"] by (simp add: setprod_constant ac_simps)
   364 
   365 lemma has_derivative_inverse':
   366   fixes x :: "'a::real_normed_div_algebra"
   367   assumes x: "x \<noteq> 0"
   368   shows "(inverse has_derivative (\<lambda>h. - (inverse x * h * inverse x))) (at x within s)"
   369         (is "(?inv has_derivative ?f) _")
   370 proof (rule has_derivativeI_sandwich)
   371   show "bounded_linear (\<lambda>h. - (?inv x * h * ?inv x))"
   372     apply (rule bounded_linear_minus)
   373     apply (rule bounded_linear_mult_const)
   374     apply (rule bounded_linear_const_mult)
   375     apply (rule bounded_linear_ident)
   376     done
   377 next
   378   show "0 < norm x" using x by simp
   379 next
   380   show "((\<lambda>y. norm (?inv y - ?inv x) * norm (?inv x)) ---> 0) (at x within s)"
   381     apply (rule tendsto_mult_left_zero)
   382     apply (rule tendsto_norm_zero)
   383     apply (rule LIM_zero)
   384     apply (rule tendsto_inverse)
   385     apply (rule tendsto_ident_at)
   386     apply (rule x)
   387     done
   388 next
   389   fix y::'a assume h: "y \<noteq> x" "dist y x < norm x"
   390   then have "y \<noteq> 0"
   391     by (auto simp: norm_conv_dist dist_commute)
   392   have "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) = norm ((?inv y - ?inv x) * (y - x) * ?inv x) / norm (y - x)"
   393     apply (subst inverse_diff_inverse [OF \<open>y \<noteq> 0\<close> x])
   394     apply (subst minus_diff_minus)
   395     apply (subst norm_minus_cancel)
   396     apply (simp add: left_diff_distrib)
   397     done
   398   also have "\<dots> \<le> norm (?inv y - ?inv x) * norm (y - x) * norm (?inv x) / norm (y - x)"
   399     apply (rule divide_right_mono [OF _ norm_ge_zero])
   400     apply (rule order_trans [OF norm_mult_ineq])
   401     apply (rule mult_right_mono [OF _ norm_ge_zero])
   402     apply (rule norm_mult_ineq)
   403     done
   404   also have "\<dots> = norm (?inv y - ?inv x) * norm (?inv x)"
   405     by simp
   406   finally show "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) \<le>
   407       norm (?inv y - ?inv x) * norm (?inv x)" .
   408 qed
   409 
   410 lemma has_derivative_inverse[simp, derivative_intros]:
   411   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   412   assumes x:  "f x \<noteq> 0" and f: "(f has_derivative f') (at x within s)"
   413   shows "((\<lambda>x. inverse (f x)) has_derivative (\<lambda>h. - (inverse (f x) * f' h * inverse (f x)))) (at x within s)"
   414   using has_derivative_compose[OF f has_derivative_inverse', OF x] .
   415 
   416 lemma has_derivative_divide[simp, derivative_intros]:
   417   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   418   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)" 
   419   assumes x: "g x \<noteq> 0"
   420   shows "((\<lambda>x. f x / g x) has_derivative
   421                 (\<lambda>h. - f x * (inverse (g x) * g' h * inverse (g x)) + f' h / g x)) (at x within s)"
   422   using has_derivative_mult[OF f has_derivative_inverse[OF x g]]
   423   by (simp add: field_simps)
   424 
   425 text\<open>Conventional form requires mult-AC laws. Types real and complex only.\<close>
   426 
   427 lemma has_derivative_divide'[derivative_intros]: 
   428   fixes f :: "_ \<Rightarrow> 'a::real_normed_field"
   429   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)" and x: "g x \<noteq> 0"
   430   shows "((\<lambda>x. f x / g x) has_derivative (\<lambda>h. (f' h * g x - f x * g' h) / (g x * g x))) (at x within s)"
   431 proof -
   432   { fix h
   433     have "f' h / g x - f x * (inverse (g x) * g' h * inverse (g x)) =
   434           (f' h * g x - f x * g' h) / (g x * g x)"
   435       by (simp add: field_simps x)
   436    }
   437   then show ?thesis
   438     using has_derivative_divide [OF f g] x
   439     by simp
   440 qed
   441 
   442 subsection \<open>Uniqueness\<close>
   443 
   444 text \<open>
   445 
   446 This can not generally shown for @{const has_derivative}, as we need to approach the point from
   447 all directions. There is a proof in @{text Multivariate_Analysis} for @{text euclidean_space}.
   448 
   449 \<close>
   450 
   451 lemma has_derivative_zero_unique:
   452   assumes "((\<lambda>x. 0) has_derivative F) (at x)" shows "F = (\<lambda>h. 0)"
   453 proof -
   454   interpret F: bounded_linear F
   455     using assms by (rule has_derivative_bounded_linear)
   456   let ?r = "\<lambda>h. norm (F h) / norm h"
   457   have *: "?r -- 0 --> 0"
   458     using assms unfolding has_derivative_at by simp
   459   show "F = (\<lambda>h. 0)"
   460   proof
   461     fix h show "F h = 0"
   462     proof (rule ccontr)
   463       assume **: "F h \<noteq> 0"
   464       hence h: "h \<noteq> 0" by (clarsimp simp add: F.zero)
   465       with ** have "0 < ?r h" by simp
   466       from LIM_D [OF * this] obtain s where s: "0 < s"
   467         and r: "\<And>x. x \<noteq> 0 \<Longrightarrow> norm x < s \<Longrightarrow> ?r x < ?r h" by auto
   468       from dense [OF s] obtain t where t: "0 < t \<and> t < s" ..
   469       let ?x = "scaleR (t / norm h) h"
   470       have "?x \<noteq> 0" and "norm ?x < s" using t h by simp_all
   471       hence "?r ?x < ?r h" by (rule r)
   472       thus "False" using t h by (simp add: F.scaleR)
   473     qed
   474   qed
   475 qed
   476 
   477 lemma has_derivative_unique:
   478   assumes "(f has_derivative F) (at x)" and "(f has_derivative F') (at x)" shows "F = F'"
   479 proof -
   480   have "((\<lambda>x. 0) has_derivative (\<lambda>h. F h - F' h)) (at x)"
   481     using has_derivative_diff [OF assms] by simp
   482   hence "(\<lambda>h. F h - F' h) = (\<lambda>h. 0)"
   483     by (rule has_derivative_zero_unique)
   484   thus "F = F'"
   485     unfolding fun_eq_iff right_minus_eq .
   486 qed
   487 
   488 subsection \<open>Differentiability predicate\<close>
   489 
   490 definition
   491   differentiable :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   492   (infix "differentiable" 50)
   493 where
   494   "f differentiable F \<longleftrightarrow> (\<exists>D. (f has_derivative D) F)"
   495 
   496 lemma differentiable_subset: "f differentiable (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f differentiable (at x within t)"
   497   unfolding differentiable_def by (blast intro: has_derivative_subset)
   498 
   499 lemmas differentiable_within_subset = differentiable_subset
   500 
   501 lemma differentiable_ident [simp, derivative_intros]: "(\<lambda>x. x) differentiable F"
   502   unfolding differentiable_def by (blast intro: has_derivative_ident)
   503 
   504 lemma differentiable_const [simp, derivative_intros]: "(\<lambda>z. a) differentiable F"
   505   unfolding differentiable_def by (blast intro: has_derivative_const)
   506 
   507 lemma differentiable_in_compose:
   508   "f differentiable (at (g x) within (g`s)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f (g x)) differentiable (at x within s)"
   509   unfolding differentiable_def by (blast intro: has_derivative_in_compose)
   510 
   511 lemma differentiable_compose:
   512   "f differentiable (at (g x)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f (g x)) differentiable (at x within s)"
   513   by (blast intro: differentiable_in_compose differentiable_subset)
   514 
   515 lemma differentiable_sum [simp, derivative_intros]:
   516   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x + g x) differentiable F"
   517   unfolding differentiable_def by (blast intro: has_derivative_add)
   518 
   519 lemma differentiable_minus [simp, derivative_intros]:
   520   "f differentiable F \<Longrightarrow> (\<lambda>x. - f x) differentiable F"
   521   unfolding differentiable_def by (blast intro: has_derivative_minus)
   522 
   523 lemma differentiable_diff [simp, derivative_intros]:
   524   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x - g x) differentiable F"
   525   unfolding differentiable_def by (blast intro: has_derivative_diff)
   526 
   527 lemma differentiable_mult [simp, derivative_intros]:
   528   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_algebra"
   529   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x * g x) differentiable (at x within s)"
   530   unfolding differentiable_def by (blast intro: has_derivative_mult)
   531 
   532 lemma differentiable_inverse [simp, derivative_intros]:
   533   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   534   shows "f differentiable (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow> (\<lambda>x. inverse (f x)) differentiable (at x within s)"
   535   unfolding differentiable_def by (blast intro: has_derivative_inverse)
   536 
   537 lemma differentiable_divide [simp, derivative_intros]:
   538   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   539   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow> (\<lambda>x. f x / g x) differentiable (at x within s)"
   540   unfolding divide_inverse using assms by simp
   541 
   542 lemma differentiable_power [simp, derivative_intros]:
   543   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   544   shows "f differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x ^ n) differentiable (at x within s)"
   545   unfolding differentiable_def by (blast intro: has_derivative_power)
   546 
   547 lemma differentiable_scaleR [simp, derivative_intros]:
   548   "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x *\<^sub>R g x) differentiable (at x within s)"
   549   unfolding differentiable_def by (blast intro: has_derivative_scaleR)
   550 
   551 lemma has_derivative_imp_has_field_derivative:
   552   "(f has_derivative D) F \<Longrightarrow> (\<And>x. x * D' = D x) \<Longrightarrow> (f has_field_derivative D') F"
   553   unfolding has_field_derivative_def 
   554   by (rule has_derivative_eq_rhs[of f D]) (simp_all add: fun_eq_iff mult.commute)
   555 
   556 lemma has_field_derivative_imp_has_derivative: "(f has_field_derivative D) F \<Longrightarrow> (f has_derivative op * D) F"
   557   by (simp add: has_field_derivative_def)
   558 
   559 lemma DERIV_subset: 
   560   "(f has_field_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s 
   561    \<Longrightarrow> (f has_field_derivative f') (at x within t)"
   562   by (simp add: has_field_derivative_def has_derivative_within_subset)
   563 
   564 lemma has_field_derivative_at_within:
   565     "(f has_field_derivative f') (at x) \<Longrightarrow> (f has_field_derivative f') (at x within s)"
   566   using DERIV_subset by blast
   567 
   568 abbreviation (input)
   569   DERIV :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
   570   ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
   571 where
   572   "DERIV f x :> D \<equiv> (f has_field_derivative D) (at x)"
   573 
   574 abbreviation 
   575   has_real_derivative :: "(real \<Rightarrow> real) \<Rightarrow> real \<Rightarrow> real filter \<Rightarrow> bool"
   576   (infix "(has'_real'_derivative)" 50)
   577 where
   578   "(f has_real_derivative D) F \<equiv> (f has_field_derivative D) F"
   579 
   580 lemma real_differentiable_def:
   581   "f differentiable at x within s \<longleftrightarrow> (\<exists>D. (f has_real_derivative D) (at x within s))"
   582 proof safe
   583   assume "f differentiable at x within s"
   584   then obtain f' where *: "(f has_derivative f') (at x within s)"
   585     unfolding differentiable_def by auto
   586   then obtain c where "f' = (op * c)"
   587     by (metis real_bounded_linear has_derivative_bounded_linear mult.commute fun_eq_iff)
   588   with * show "\<exists>D. (f has_real_derivative D) (at x within s)"
   589     unfolding has_field_derivative_def by auto
   590 qed (auto simp: differentiable_def has_field_derivative_def)
   591 
   592 lemma real_differentiableE [elim?]:
   593   assumes f: "f differentiable (at x within s)" obtains df where "(f has_real_derivative df) (at x within s)"
   594   using assms by (auto simp: real_differentiable_def)
   595 
   596 lemma differentiableD: "f differentiable (at x within s) \<Longrightarrow> \<exists>D. (f has_real_derivative D) (at x within s)"
   597   by (auto elim: real_differentiableE)
   598 
   599 lemma differentiableI: "(f has_real_derivative D) (at x within s) \<Longrightarrow> f differentiable (at x within s)"
   600   by (force simp add: real_differentiable_def)
   601 
   602 lemma DERIV_def: "DERIV f x :> D \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) -- 0 --> D"
   603   apply (simp add: has_field_derivative_def has_derivative_at bounded_linear_mult_right LIM_zero_iff[symmetric, of _ D])
   604   apply (subst (2) tendsto_norm_zero_iff[symmetric])
   605   apply (rule filterlim_cong)
   606   apply (simp_all add: eventually_at_filter field_simps nonzero_norm_divide)
   607   done
   608 
   609 lemma mult_commute_abs: "(\<lambda>x. x * c) = op * (c::'a::ab_semigroup_mult)"
   610   by (simp add: fun_eq_iff mult.commute)
   611 
   612 subsection \<open>Vector derivative\<close>
   613 
   614 lemma has_field_derivative_iff_has_vector_derivative:
   615   "(f has_field_derivative y) F \<longleftrightarrow> (f has_vector_derivative y) F"
   616   unfolding has_vector_derivative_def has_field_derivative_def real_scaleR_def mult_commute_abs ..
   617 
   618 lemma has_field_derivative_subset:
   619   "(f has_field_derivative y) (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> (f has_field_derivative y) (at x within t)"
   620   unfolding has_field_derivative_def by (rule has_derivative_subset)
   621 
   622 lemma has_vector_derivative_const[simp, derivative_intros]: "((\<lambda>x. c) has_vector_derivative 0) net"
   623   by (auto simp: has_vector_derivative_def)
   624 
   625 lemma has_vector_derivative_id[simp, derivative_intros]: "((\<lambda>x. x) has_vector_derivative 1) net"
   626   by (auto simp: has_vector_derivative_def)
   627 
   628 lemma has_vector_derivative_minus[derivative_intros]:
   629   "(f has_vector_derivative f') net \<Longrightarrow> ((\<lambda>x. - f x) has_vector_derivative (- f')) net"
   630   by (auto simp: has_vector_derivative_def)
   631 
   632 lemma has_vector_derivative_add[derivative_intros]:
   633   "(f has_vector_derivative f') net \<Longrightarrow> (g has_vector_derivative g') net \<Longrightarrow>
   634     ((\<lambda>x. f x + g x) has_vector_derivative (f' + g')) net"
   635   by (auto simp: has_vector_derivative_def scaleR_right_distrib)
   636 
   637 lemma has_vector_derivative_setsum[derivative_intros]:
   638   "(\<And>i. i \<in> I \<Longrightarrow> (f i has_vector_derivative f' i) net) \<Longrightarrow>
   639     ((\<lambda>x. \<Sum>i\<in>I. f i x) has_vector_derivative (\<Sum>i\<in>I. f' i)) net"
   640   by (auto simp: has_vector_derivative_def fun_eq_iff scaleR_setsum_right intro!: derivative_eq_intros)
   641 
   642 lemma has_vector_derivative_diff[derivative_intros]:
   643   "(f has_vector_derivative f') net \<Longrightarrow> (g has_vector_derivative g') net \<Longrightarrow>
   644     ((\<lambda>x. f x - g x) has_vector_derivative (f' - g')) net"
   645   by (auto simp: has_vector_derivative_def scaleR_diff_right)
   646 
   647 lemma has_vector_derivative_add_const:
   648      "((\<lambda>t. g t + z) has_vector_derivative f') (at x) = ((\<lambda>t. g t) has_vector_derivative f') (at x)"
   649 apply (intro iffI)
   650 apply (drule has_vector_derivative_diff [where g = "\<lambda>t. z", OF _ has_vector_derivative_const], simp)
   651 apply (drule has_vector_derivative_add [OF _ has_vector_derivative_const], simp)
   652 done
   653 
   654 lemma has_vector_derivative_diff_const:
   655      "((\<lambda>t. g t - z) has_vector_derivative f') (at x) = ((\<lambda>t. g t) has_vector_derivative f') (at x)"
   656 using has_vector_derivative_add_const [where z = "-z"]
   657 by simp
   658 
   659 lemma (in bounded_linear) has_vector_derivative:
   660   assumes "(g has_vector_derivative g') F"
   661   shows "((\<lambda>x. f (g x)) has_vector_derivative f g') F"
   662   using has_derivative[OF assms[unfolded has_vector_derivative_def]]
   663   by (simp add: has_vector_derivative_def scaleR)
   664 
   665 lemma (in bounded_bilinear) has_vector_derivative:
   666   assumes "(f has_vector_derivative f') (at x within s)"
   667     and "(g has_vector_derivative g') (at x within s)"
   668   shows "((\<lambda>x. f x ** g x) has_vector_derivative (f x ** g' + f' ** g x)) (at x within s)"
   669   using FDERIV[OF assms(1-2)[unfolded has_vector_derivative_def]]
   670   by (simp add: has_vector_derivative_def scaleR_right scaleR_left scaleR_right_distrib)
   671 
   672 lemma has_vector_derivative_scaleR[derivative_intros]:
   673   "(f has_field_derivative f') (at x within s) \<Longrightarrow> (g has_vector_derivative g') (at x within s) \<Longrightarrow>
   674     ((\<lambda>x. f x *\<^sub>R g x) has_vector_derivative (f x *\<^sub>R g' + f' *\<^sub>R g x)) (at x within s)"
   675   unfolding has_field_derivative_iff_has_vector_derivative
   676   by (rule bounded_bilinear.has_vector_derivative[OF bounded_bilinear_scaleR])
   677 
   678 lemma has_vector_derivative_mult[derivative_intros]:
   679   "(f has_vector_derivative f') (at x within s) \<Longrightarrow> (g has_vector_derivative g') (at x within s) \<Longrightarrow>
   680     ((\<lambda>x. f x * g x) has_vector_derivative (f x * g' + f' * g x :: 'a :: real_normed_algebra)) (at x within s)"
   681   by (rule bounded_bilinear.has_vector_derivative[OF bounded_bilinear_mult])
   682 
   683 lemma has_vector_derivative_of_real[derivative_intros]:
   684   "(f has_field_derivative D) F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_vector_derivative (of_real D)) F"
   685   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_of_real])
   686      (simp add: has_field_derivative_iff_has_vector_derivative)
   687 
   688 lemma has_vector_derivative_continuous: "(f has_vector_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   689   by (auto intro: has_derivative_continuous simp: has_vector_derivative_def)
   690 
   691 lemma has_vector_derivative_mult_right[derivative_intros]:
   692   fixes a :: "'a :: real_normed_algebra"
   693   shows "(f has_vector_derivative x) F \<Longrightarrow> ((\<lambda>x. a * f x) has_vector_derivative (a * x)) F"
   694   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_mult_right])
   695 
   696 lemma has_vector_derivative_mult_left[derivative_intros]:
   697   fixes a :: "'a :: real_normed_algebra"
   698   shows "(f has_vector_derivative x) F \<Longrightarrow> ((\<lambda>x. f x * a) has_vector_derivative (x * a)) F"
   699   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_mult_left])
   700 
   701 
   702 subsection \<open>Derivatives\<close>
   703 
   704 lemma DERIV_D: "DERIV f x :> D \<Longrightarrow> (\<lambda>h. (f (x + h) - f x) / h) -- 0 --> D"
   705   by (simp add: DERIV_def)
   706 
   707 lemma DERIV_const [simp, derivative_intros]: "((\<lambda>x. k) has_field_derivative 0) F"
   708   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_const]) auto
   709 
   710 lemma DERIV_ident [simp, derivative_intros]: "((\<lambda>x. x) has_field_derivative 1) F"
   711   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_ident]) auto
   712 
   713 lemma field_differentiable_add[derivative_intros]:
   714   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow> 
   715     ((\<lambda>z. f z + g z) has_field_derivative f' + g') F"
   716   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_add])
   717      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   718 
   719 corollary DERIV_add:
   720   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   721   ((\<lambda>x. f x + g x) has_field_derivative D + E) (at x within s)"
   722   by (rule field_differentiable_add)
   723 
   724 lemma field_differentiable_minus[derivative_intros]:
   725   "(f has_field_derivative f') F \<Longrightarrow> ((\<lambda>z. - (f z)) has_field_derivative -f') F"
   726   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_minus])
   727      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   728 
   729 corollary DERIV_minus: "(f has_field_derivative D) (at x within s) \<Longrightarrow> ((\<lambda>x. - f x) has_field_derivative -D) (at x within s)"
   730   by (rule field_differentiable_minus)
   731 
   732 lemma field_differentiable_diff[derivative_intros]:
   733   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow> ((\<lambda>z. f z - g z) has_field_derivative f' - g') F"
   734   by (simp only: assms diff_conv_add_uminus field_differentiable_add field_differentiable_minus)
   735 
   736 corollary DERIV_diff:
   737   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   738   ((\<lambda>x. f x - g x) has_field_derivative D - E) (at x within s)"
   739   by (rule field_differentiable_diff)
   740 
   741 lemma DERIV_continuous: "(f has_field_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   742   by (drule has_derivative_continuous[OF has_field_derivative_imp_has_derivative]) simp
   743 
   744 corollary DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
   745   by (rule DERIV_continuous)
   746 
   747 lemma DERIV_continuous_on:
   748   "(\<And>x. x \<in> s \<Longrightarrow> (f has_field_derivative D) (at x)) \<Longrightarrow> continuous_on s f"
   749   by (metis DERIV_continuous continuous_at_imp_continuous_on)
   750 
   751 lemma DERIV_mult':
   752   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   753   ((\<lambda>x. f x * g x) has_field_derivative f x * E + D * g x) (at x within s)"
   754   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   755      (auto simp: field_simps mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   756 
   757 lemma DERIV_mult[derivative_intros]:
   758   "(f has_field_derivative Da) (at x within s) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   759   ((\<lambda>x. f x * g x) has_field_derivative Da * g x + Db * f x) (at x within s)"
   760   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   761      (auto simp: field_simps dest: has_field_derivative_imp_has_derivative)
   762 
   763 text \<open>Derivative of linear multiplication\<close>
   764 
   765 lemma DERIV_cmult:
   766   "(f has_field_derivative D) (at x within s) ==> ((\<lambda>x. c * f x) has_field_derivative c * D) (at x within s)"
   767   by (drule DERIV_mult' [OF DERIV_const], simp)
   768 
   769 lemma DERIV_cmult_right:
   770   "(f has_field_derivative D) (at x within s) ==> ((\<lambda>x. f x * c) has_field_derivative D * c) (at x within s)"
   771   using DERIV_cmult by (force simp add: ac_simps)
   772 
   773 lemma DERIV_cmult_Id [simp]: "(op * c has_field_derivative c) (at x within s)"
   774   by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   775 
   776 lemma DERIV_cdivide:
   777   "(f has_field_derivative D) (at x within s) \<Longrightarrow> ((\<lambda>x. f x / c) has_field_derivative D / c) (at x within s)"
   778   using DERIV_cmult_right[of f D x s "1 / c"] by simp
   779 
   780 lemma DERIV_unique:
   781   "DERIV f x :> D \<Longrightarrow> DERIV f x :> E \<Longrightarrow> D = E"
   782   unfolding DERIV_def by (rule LIM_unique) 
   783 
   784 lemma DERIV_setsum[derivative_intros]:
   785   "(\<And> n. n \<in> S \<Longrightarrow> ((\<lambda>x. f x n) has_field_derivative (f' x n)) F) \<Longrightarrow> 
   786     ((\<lambda>x. setsum (f x) S) has_field_derivative setsum (f' x) S) F"
   787   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_setsum])
   788      (auto simp: setsum_right_distrib mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   789 
   790 lemma DERIV_inverse'[derivative_intros]:
   791   assumes "(f has_field_derivative D) (at x within s)"
   792     and "f x \<noteq> 0"
   793   shows "((\<lambda>x. inverse (f x)) has_field_derivative - (inverse (f x) * D * inverse (f x))) (at x within s)"
   794 proof -
   795   have "(f has_derivative (\<lambda>x. x * D)) = (f has_derivative op * D)"
   796     by (rule arg_cong [of "\<lambda>x. x * D"]) (simp add: fun_eq_iff)
   797   with assms have "(f has_derivative (\<lambda>x. x * D)) (at x within s)"
   798     by (auto dest!: has_field_derivative_imp_has_derivative)
   799   then show ?thesis using \<open>f x \<noteq> 0\<close>
   800     by (auto intro: has_derivative_imp_has_field_derivative has_derivative_inverse)
   801 qed
   802 
   803 text \<open>Power of @{text "-1"}\<close>
   804 
   805 lemma DERIV_inverse:
   806   "x \<noteq> 0 \<Longrightarrow> ((\<lambda>x. inverse(x)) has_field_derivative - (inverse x ^ Suc (Suc 0))) (at x within s)"
   807   by (drule DERIV_inverse' [OF DERIV_ident]) simp
   808 
   809 text \<open>Derivative of inverse\<close>
   810 
   811 lemma DERIV_inverse_fun:
   812   "(f has_field_derivative d) (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow>
   813   ((\<lambda>x. inverse (f x)) has_field_derivative (- (d * inverse(f x ^ Suc (Suc 0))))) (at x within s)"
   814   by (drule (1) DERIV_inverse') (simp add: ac_simps nonzero_inverse_mult_distrib)
   815 
   816 text \<open>Derivative of quotient\<close>
   817 
   818 lemma DERIV_divide[derivative_intros]:
   819   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   820   (g has_field_derivative E) (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow>
   821   ((\<lambda>x. f x / g x) has_field_derivative (D * g x - f x * E) / (g x * g x)) (at x within s)"
   822   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_divide])
   823      (auto dest: has_field_derivative_imp_has_derivative simp: field_simps)
   824 
   825 lemma DERIV_quotient:
   826   "(f has_field_derivative d) (at x within s) \<Longrightarrow>
   827   (g has_field_derivative e) (at x within s)\<Longrightarrow> g x \<noteq> 0 \<Longrightarrow> 
   828   ((\<lambda>y. f y / g y) has_field_derivative (d * g x - (e * f x)) / (g x ^ Suc (Suc 0))) (at x within s)"
   829   by (drule (2) DERIV_divide) (simp add: mult.commute)
   830 
   831 lemma DERIV_power_Suc:
   832   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   833   ((\<lambda>x. f x ^ Suc n) has_field_derivative (1 + of_nat n) * (D * f x ^ n)) (at x within s)"
   834   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   835      (auto simp: has_field_derivative_def)
   836 
   837 lemma DERIV_power[derivative_intros]:
   838   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   839   ((\<lambda>x. f x ^ n) has_field_derivative of_nat n * (D * f x ^ (n - Suc 0))) (at x within s)"
   840   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   841      (auto simp: has_field_derivative_def)
   842 
   843 lemma DERIV_pow: "((\<lambda>x. x ^ n) has_field_derivative real n * (x ^ (n - Suc 0))) (at x within s)"
   844   apply (cut_tac DERIV_power [OF DERIV_ident])
   845   apply (simp add: real_of_nat_def)
   846   done
   847 
   848 lemma DERIV_chain': "(f has_field_derivative D) (at x within s) \<Longrightarrow> DERIV g (f x) :> E \<Longrightarrow> 
   849   ((\<lambda>x. g (f x)) has_field_derivative E * D) (at x within s)"
   850   using has_derivative_compose[of f "op * D" x s g "op * E"]
   851   unfolding has_field_derivative_def mult_commute_abs ac_simps .
   852 
   853 corollary DERIV_chain2: "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   854   ((\<lambda>x. f (g x)) has_field_derivative Da * Db) (at x within s)"
   855   by (rule DERIV_chain')
   856 
   857 text \<open>Standard version\<close>
   858 
   859 lemma DERIV_chain:
   860   "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow> 
   861   (f o g has_field_derivative Da * Db) (at x within s)"
   862   by (drule (1) DERIV_chain', simp add: o_def mult.commute)
   863 
   864 lemma DERIV_image_chain: 
   865   "(f has_field_derivative Da) (at (g x) within (g ` s)) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   866   (f o g has_field_derivative Da * Db) (at x within s)"
   867   using has_derivative_in_compose [of g "op * Db" x s f "op * Da "]
   868   by (simp add: has_field_derivative_def o_def mult_commute_abs ac_simps)
   869 
   870 (*These two are from HOL Light: HAS_COMPLEX_DERIVATIVE_CHAIN*)
   871 lemma DERIV_chain_s:
   872   assumes "(\<And>x. x \<in> s \<Longrightarrow> DERIV g x :> g'(x))"
   873       and "DERIV f x :> f'" 
   874       and "f x \<in> s"
   875     shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   876   by (metis (full_types) DERIV_chain' mult.commute assms)
   877 
   878 lemma DERIV_chain3: (*HAS_COMPLEX_DERIVATIVE_CHAIN_UNIV*)
   879   assumes "(\<And>x. DERIV g x :> g'(x))"
   880       and "DERIV f x :> f'" 
   881     shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   882   by (metis UNIV_I DERIV_chain_s [of UNIV] assms)
   883 
   884 declare
   885   DERIV_power[where 'a=real, unfolded real_of_nat_def[symmetric], derivative_intros]
   886 
   887 text\<open>Alternative definition for differentiability\<close>
   888 
   889 lemma DERIV_LIM_iff:
   890   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a" shows
   891      "((%h. (f(a + h) - f(a)) / h) -- 0 --> D) =
   892       ((%x. (f(x)-f(a)) / (x-a)) -- a --> D)"
   893 apply (rule iffI)
   894 apply (drule_tac k="- a" in LIM_offset)
   895 apply simp
   896 apply (drule_tac k="a" in LIM_offset)
   897 apply (simp add: add.commute)
   898 done
   899 
   900 lemma DERIV_iff2: "(DERIV f x :> D) \<longleftrightarrow> (\<lambda>z. (f z - f x) / (z - x)) --x --> D"
   901   by (simp add: DERIV_def DERIV_LIM_iff)
   902 
   903 lemma DERIV_cong_ev: "x = y \<Longrightarrow> eventually (\<lambda>x. f x = g x) (nhds x) \<Longrightarrow> u = v \<Longrightarrow>
   904     DERIV f x :> u \<longleftrightarrow> DERIV g y :> v"
   905   unfolding DERIV_iff2
   906 proof (rule filterlim_cong)
   907   assume *: "eventually (\<lambda>x. f x = g x) (nhds x)"
   908   moreover from * have "f x = g x" by (auto simp: eventually_nhds)
   909   moreover assume "x = y" "u = v"
   910   ultimately show "eventually (\<lambda>xa. (f xa - f x) / (xa - x) = (g xa - g y) / (xa - y)) (at x)"
   911     by (auto simp: eventually_at_filter elim: eventually_elim1)
   912 qed simp_all
   913 
   914 lemma DERIV_shift:
   915   "(DERIV f (x + z) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (x + z)) x :> y)"
   916   by (simp add: DERIV_def field_simps)
   917 
   918 lemma DERIV_mirror:
   919   "(DERIV f (- x) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (- x::real) :: real) x :> - y)"
   920   by (simp add: DERIV_def filterlim_at_split filterlim_at_left_to_right
   921                 tendsto_minus_cancel_left field_simps conj_commute)
   922 
   923 text \<open>Caratheodory formulation of derivative at a point\<close>
   924 
   925 lemma CARAT_DERIV: (*FIXME: SUPERSEDED BY THE ONE IN Deriv.thy. But still used by NSA/HDeriv.thy*)
   926   "(DERIV f x :> l) \<longleftrightarrow> (\<exists>g. (\<forall>z. f z - f x = g z * (z - x)) \<and> isCont g x \<and> g x = l)"
   927       (is "?lhs = ?rhs")
   928 proof
   929   assume der: "DERIV f x :> l"
   930   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   931   proof (intro exI conjI)
   932     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   933     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   934     show "isCont ?g x" using der
   935       by (simp add: isCont_iff DERIV_def cong: LIM_equal [rule_format])
   936     show "?g x = l" by simp
   937   qed
   938 next
   939   assume "?rhs"
   940   then obtain g where
   941     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   942   thus "(DERIV f x :> l)"
   943      by (auto simp add: isCont_iff DERIV_def cong: LIM_cong)
   944 qed
   945 
   946 
   947 subsection \<open>Local extrema\<close>
   948 
   949 text\<open>If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right\<close>
   950 
   951 lemma DERIV_pos_inc_right:
   952   fixes f :: "real => real"
   953   assumes der: "DERIV f x :> l"
   954       and l:   "0 < l"
   955   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   956 proof -
   957   from l der [THEN DERIV_D, THEN LIM_D [where r = "l"]]
   958   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l)"
   959     by simp
   960   then obtain s
   961         where s:   "0 < s"
   962           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l"
   963     by auto
   964   thus ?thesis
   965   proof (intro exI conjI strip)
   966     show "0<s" using s .
   967     fix h::real
   968     assume "0 < h" "h < s"
   969     with all [of h] show "f x < f (x+h)"
   970     proof (simp add: abs_if pos_less_divide_eq split add: split_if_asm)
   971       assume "~ (f (x+h) - f x) / h < l" and h: "0 < h"
   972       with l
   973       have "0 < (f (x+h) - f x) / h" by arith
   974       thus "f x < f (x+h)"
   975   by (simp add: pos_less_divide_eq h)
   976     qed
   977   qed
   978 qed
   979 
   980 lemma DERIV_neg_dec_left:
   981   fixes f :: "real => real"
   982   assumes der: "DERIV f x :> l"
   983       and l:   "l < 0"
   984   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
   985 proof -
   986   from l der [THEN DERIV_D, THEN LIM_D [where r = "-l"]]
   987   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l)"
   988     by simp
   989   then obtain s
   990         where s:   "0 < s"
   991           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l"
   992     by auto
   993   thus ?thesis
   994   proof (intro exI conjI strip)
   995     show "0<s" using s .
   996     fix h::real
   997     assume "0 < h" "h < s"
   998     with all [of "-h"] show "f x < f (x-h)"
   999     proof (simp add: abs_if pos_less_divide_eq split add: split_if_asm)
  1000       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
  1001       with l
  1002       have "0 < (f (x-h) - f x) / h" by arith
  1003       thus "f x < f (x-h)"
  1004   by (simp add: pos_less_divide_eq h)
  1005     qed
  1006   qed
  1007 qed
  1008 
  1009 lemma DERIV_pos_inc_left:
  1010   fixes f :: "real => real"
  1011   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x - h) < f(x)"
  1012   apply (rule DERIV_neg_dec_left [of "%x. - f x" "-l" x, simplified])
  1013   apply (auto simp add: DERIV_minus)
  1014   done
  1015 
  1016 lemma DERIV_neg_dec_right:
  1017   fixes f :: "real => real"
  1018   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x) > f(x + h)"
  1019   apply (rule DERIV_pos_inc_right [of "%x. - f x" "-l" x, simplified])
  1020   apply (auto simp add: DERIV_minus)
  1021   done
  1022 
  1023 lemma DERIV_local_max:
  1024   fixes f :: "real => real"
  1025   assumes der: "DERIV f x :> l"
  1026       and d:   "0 < d"
  1027       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
  1028   shows "l = 0"
  1029 proof (cases rule: linorder_cases [of l 0])
  1030   case equal thus ?thesis .
  1031 next
  1032   case less
  1033   from DERIV_neg_dec_left [OF der less]
  1034   obtain d' where d': "0 < d'"
  1035              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
  1036   from real_lbound_gt_zero [OF d d']
  1037   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
  1038   with lt le [THEN spec [where x="x-e"]]
  1039   show ?thesis by (auto simp add: abs_if)
  1040 next
  1041   case greater
  1042   from DERIV_pos_inc_right [OF der greater]
  1043   obtain d' where d': "0 < d'"
  1044              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
  1045   from real_lbound_gt_zero [OF d d']
  1046   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
  1047   with lt le [THEN spec [where x="x+e"]]
  1048   show ?thesis by (auto simp add: abs_if)
  1049 qed
  1050 
  1051 
  1052 text\<open>Similar theorem for a local minimum\<close>
  1053 lemma DERIV_local_min:
  1054   fixes f :: "real => real"
  1055   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
  1056 by (drule DERIV_minus [THEN DERIV_local_max], auto)
  1057 
  1058 
  1059 text\<open>In particular, if a function is locally flat\<close>
  1060 lemma DERIV_local_const:
  1061   fixes f :: "real => real"
  1062   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
  1063 by (auto dest!: DERIV_local_max)
  1064 
  1065 
  1066 subsection \<open>Rolle's Theorem\<close>
  1067 
  1068 text\<open>Lemma about introducing open ball in open interval\<close>
  1069 lemma lemma_interval_lt:
  1070      "[| a < x;  x < b |]
  1071       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
  1072 
  1073 apply (simp add: abs_less_iff)
  1074 apply (insert linorder_linear [of "x-a" "b-x"], safe)
  1075 apply (rule_tac x = "x-a" in exI)
  1076 apply (rule_tac [2] x = "b-x" in exI, auto)
  1077 done
  1078 
  1079 lemma lemma_interval: "[| a < x;  x < b |] ==>
  1080         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
  1081 apply (drule lemma_interval_lt, auto)
  1082 apply force
  1083 done
  1084 
  1085 text\<open>Rolle's Theorem.
  1086    If @{term f} is defined and continuous on the closed interval
  1087    @{text "[a,b]"} and differentiable on the open interval @{text "(a,b)"},
  1088    and @{term "f(a) = f(b)"},
  1089    then there exists @{text "x0 \<in> (a,b)"} such that @{term "f'(x0) = 0"}\<close>
  1090 theorem Rolle:
  1091   assumes lt: "a < b"
  1092       and eq: "f(a) = f(b)"
  1093       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1094       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable (at x)"
  1095   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
  1096 proof -
  1097   have le: "a \<le> b" using lt by simp
  1098   from isCont_eq_Ub [OF le con]
  1099   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
  1100              and alex: "a \<le> x" and xleb: "x \<le> b"
  1101     by blast
  1102   from isCont_eq_Lb [OF le con]
  1103   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
  1104               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
  1105     by blast
  1106   show ?thesis
  1107   proof cases
  1108     assume axb: "a < x & x < b"
  1109         --\<open>@{term f} attains its maximum within the interval\<close>
  1110     hence ax: "a<x" and xb: "x<b" by arith + 
  1111     from lemma_interval [OF ax xb]
  1112     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1113       by blast
  1114     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
  1115       by blast
  1116     from differentiableD [OF dif [OF axb]]
  1117     obtain l where der: "DERIV f x :> l" ..
  1118     have "l=0" by (rule DERIV_local_max [OF der d bound'])
  1119         --\<open>the derivative at a local maximum is zero\<close>
  1120     thus ?thesis using ax xb der by auto
  1121   next
  1122     assume notaxb: "~ (a < x & x < b)"
  1123     hence xeqab: "x=a | x=b" using alex xleb by arith
  1124     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
  1125     show ?thesis
  1126     proof cases
  1127       assume ax'b: "a < x' & x' < b"
  1128         --\<open>@{term f} attains its minimum within the interval\<close>
  1129       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
  1130       from lemma_interval [OF ax' x'b]
  1131       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1132   by blast
  1133       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
  1134   by blast
  1135       from differentiableD [OF dif [OF ax'b]]
  1136       obtain l where der: "DERIV f x' :> l" ..
  1137       have "l=0" by (rule DERIV_local_min [OF der d bound'])
  1138         --\<open>the derivative at a local minimum is zero\<close>
  1139       thus ?thesis using ax' x'b der by auto
  1140     next
  1141       assume notax'b: "~ (a < x' & x' < b)"
  1142         --\<open>@{term f} is constant througout the interval\<close>
  1143       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
  1144       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
  1145       from dense [OF lt]
  1146       obtain r where ar: "a < r" and rb: "r < b" by blast
  1147       from lemma_interval [OF ar rb]
  1148       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1149   by blast
  1150       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
  1151       proof (clarify)
  1152         fix z::real
  1153         assume az: "a \<le> z" and zb: "z \<le> b"
  1154         show "f z = f b"
  1155         proof (rule order_antisym)
  1156           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
  1157           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
  1158         qed
  1159       qed
  1160       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
  1161       proof (intro strip)
  1162         fix y::real
  1163         assume lt: "\<bar>r-y\<bar> < d"
  1164         hence "f y = f b" by (simp add: eq_fb bound)
  1165         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
  1166       qed
  1167       from differentiableD [OF dif [OF conjI [OF ar rb]]]
  1168       obtain l where der: "DERIV f r :> l" ..
  1169       have "l=0" by (rule DERIV_local_const [OF der d bound'])
  1170         --\<open>the derivative of a constant function is zero\<close>
  1171       thus ?thesis using ar rb der by auto
  1172     qed
  1173   qed
  1174 qed
  1175 
  1176 
  1177 subsection\<open>Mean Value Theorem\<close>
  1178 
  1179 lemma lemma_MVT:
  1180      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
  1181   by (cases "a = b") (simp_all add: field_simps)
  1182 
  1183 theorem MVT:
  1184   assumes lt:  "a < b"
  1185       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1186       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable (at x)"
  1187   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1188                    (f(b) - f(a) = (b-a) * l)"
  1189 proof -
  1190   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1191   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x"
  1192     using con by (fast intro: continuous_intros)
  1193   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable (at x)"
  1194   proof (clarify)
  1195     fix x::real
  1196     assume ax: "a < x" and xb: "x < b"
  1197     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1198     obtain l where der: "DERIV f x :> l" ..
  1199     show "?F differentiable (at x)"
  1200       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1201           blast intro: DERIV_diff DERIV_cmult_Id der)
  1202   qed
  1203   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1204   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1205     by blast
  1206   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1207     by (rule DERIV_cmult_Id)
  1208   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1209                    :> 0 + (f b - f a) / (b - a)"
  1210     by (rule DERIV_add [OF der])
  1211   show ?thesis
  1212   proof (intro exI conjI)
  1213     show "a < z" using az .
  1214     show "z < b" using zb .
  1215     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1216     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1217   qed
  1218 qed
  1219 
  1220 lemma MVT2:
  1221      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1222       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1223 apply (drule MVT)
  1224 apply (blast intro: DERIV_isCont)
  1225 apply (force dest: order_less_imp_le simp add: real_differentiable_def)
  1226 apply (blast dest: DERIV_unique order_less_imp_le)
  1227 done
  1228 
  1229 
  1230 text\<open>A function is constant if its derivative is 0 over an interval.\<close>
  1231 
  1232 lemma DERIV_isconst_end:
  1233   fixes f :: "real => real"
  1234   shows "[| a < b;
  1235          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1236          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1237         ==> f b = f a"
  1238 apply (drule MVT, assumption)
  1239 apply (blast intro: differentiableI)
  1240 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1241 done
  1242 
  1243 lemma DERIV_isconst1:
  1244   fixes f :: "real => real"
  1245   shows "[| a < b;
  1246          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1247          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1248         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1249 apply safe
  1250 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1251 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1252 done
  1253 
  1254 lemma DERIV_isconst2:
  1255   fixes f :: "real => real"
  1256   shows "[| a < b;
  1257          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1258          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1259          a \<le> x; x \<le> b |]
  1260         ==> f x = f a"
  1261 apply (blast dest: DERIV_isconst1)
  1262 done
  1263 
  1264 lemma DERIV_isconst3: fixes a b x y :: real
  1265   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1266   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1267   shows "f x = f y"
  1268 proof (cases "x = y")
  1269   case False
  1270   let ?a = "min x y"
  1271   let ?b = "max x y"
  1272   
  1273   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1274   proof (rule allI, rule impI)
  1275     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1276     hence "a < z" and "z < b" using \<open>x \<in> {a <..< b}\<close> and \<open>y \<in> {a <..< b}\<close> by auto
  1277     hence "z \<in> {a<..<b}" by auto
  1278     thus "DERIV f z :> 0" by (rule derivable)
  1279   qed
  1280   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1281     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1282 
  1283   have "?a < ?b" using \<open>x \<noteq> y\<close> by auto
  1284   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1285   show ?thesis by auto
  1286 qed auto
  1287 
  1288 lemma DERIV_isconst_all:
  1289   fixes f :: "real => real"
  1290   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1291 apply (rule linorder_cases [of x y])
  1292 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1293 done
  1294 
  1295 lemma DERIV_const_ratio_const:
  1296   fixes f :: "real => real"
  1297   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1298 apply (rule linorder_cases [of a b], auto)
  1299 apply (drule_tac [!] f = f in MVT)
  1300 apply (auto dest: DERIV_isCont DERIV_unique simp add: real_differentiable_def)
  1301 apply (auto dest: DERIV_unique simp add: ring_distribs)
  1302 done
  1303 
  1304 lemma DERIV_const_ratio_const2:
  1305   fixes f :: "real => real"
  1306   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1307 apply (rule_tac c1 = "b-a" in mult_right_cancel [THEN iffD1])
  1308 apply (auto dest!: DERIV_const_ratio_const simp add: mult.assoc)
  1309 done
  1310 
  1311 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1312 by (simp)
  1313 
  1314 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1315 by (simp)
  1316 
  1317 text\<open>Gallileo's "trick": average velocity = av. of end velocities\<close>
  1318 
  1319 lemma DERIV_const_average:
  1320   fixes v :: "real => real"
  1321   assumes neq: "a \<noteq> (b::real)"
  1322       and der: "\<forall>x. DERIV v x :> k"
  1323   shows "v ((a + b)/2) = (v a + v b)/2"
  1324 proof (cases rule: linorder_cases [of a b])
  1325   case equal with neq show ?thesis by simp
  1326 next
  1327   case less
  1328   have "(v b - v a) / (b - a) = k"
  1329     by (rule DERIV_const_ratio_const2 [OF neq der])
  1330   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1331   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1332     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1333   ultimately show ?thesis using neq by force
  1334 next
  1335   case greater
  1336   have "(v b - v a) / (b - a) = k"
  1337     by (rule DERIV_const_ratio_const2 [OF neq der])
  1338   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1339   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1340     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1341   ultimately show ?thesis using neq by (force simp add: add.commute)
  1342 qed
  1343 
  1344 (* A function with positive derivative is increasing. 
  1345    A simple proof using the MVT, by Jeremy Avigad. And variants.
  1346 *)
  1347 lemma DERIV_pos_imp_increasing_open:
  1348   fixes a::real and b::real and f::"real => real"
  1349   assumes "a < b" and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (EX y. DERIV f x :> y & y > 0)"
  1350       and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1351   shows "f a < f b"
  1352 proof (rule ccontr)
  1353   assume f: "~ f a < f b"
  1354   have "EX l z. a < z & z < b & DERIV f z :> l
  1355       & f b - f a = (b - a) * l"
  1356     apply (rule MVT)
  1357       using assms Deriv.differentiableI
  1358       apply force+
  1359     done
  1360   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1361       and "f b - f a = (b - a) * l"
  1362     by auto
  1363   with assms f have "~(l > 0)"
  1364     by (metis linorder_not_le mult_le_0_iff diff_le_0_iff_le)
  1365   with assms z show False
  1366     by (metis DERIV_unique)
  1367 qed
  1368 
  1369 lemma DERIV_pos_imp_increasing:
  1370   fixes a::real and b::real and f::"real => real"
  1371   assumes "a < b" and "\<forall>x. a \<le> x & x \<le> b --> (EX y. DERIV f x :> y & y > 0)"
  1372   shows "f a < f b"
  1373 by (metis DERIV_pos_imp_increasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1374 
  1375 lemma DERIV_nonneg_imp_nondecreasing:
  1376   fixes a::real and b::real and f::"real => real"
  1377   assumes "a \<le> b" and
  1378     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<ge> 0)"
  1379   shows "f a \<le> f b"
  1380 proof (rule ccontr, cases "a = b")
  1381   assume "~ f a \<le> f b" and "a = b"
  1382   then show False by auto
  1383 next
  1384   assume A: "~ f a \<le> f b"
  1385   assume B: "a ~= b"
  1386   with assms have "EX l z. a < z & z < b & DERIV f z :> l
  1387       & f b - f a = (b - a) * l"
  1388     apply -
  1389     apply (rule MVT)
  1390       apply auto
  1391       apply (metis DERIV_isCont)
  1392      apply (metis differentiableI less_le)
  1393     done
  1394   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1395       and C: "f b - f a = (b - a) * l"
  1396     by auto
  1397   with A have "a < b" "f b < f a" by auto
  1398   with C have "\<not> l \<ge> 0" by (auto simp add: not_le algebra_simps)
  1399     (metis A add_le_cancel_right assms(1) less_eq_real_def mult_right_mono add_left_mono linear order_refl)
  1400   with assms z show False
  1401     by (metis DERIV_unique order_less_imp_le)
  1402 qed
  1403 
  1404 lemma DERIV_neg_imp_decreasing_open:
  1405   fixes a::real and b::real and f::"real => real"
  1406   assumes "a < b" and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (EX y. DERIV f x :> y & y < 0)"
  1407       and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1408   shows "f a > f b"
  1409 proof -
  1410   have "(%x. -f x) a < (%x. -f x) b"
  1411     apply (rule DERIV_pos_imp_increasing_open [of a b "%x. -f x"])
  1412     using assms
  1413     apply auto
  1414     apply (metis field_differentiable_minus neg_0_less_iff_less)
  1415     done
  1416   thus ?thesis
  1417     by simp
  1418 qed
  1419 
  1420 lemma DERIV_neg_imp_decreasing:
  1421   fixes a::real and b::real and f::"real => real"
  1422   assumes "a < b" and
  1423     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y < 0)"
  1424   shows "f a > f b"
  1425 by (metis DERIV_neg_imp_decreasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1426 
  1427 lemma DERIV_nonpos_imp_nonincreasing:
  1428   fixes a::real and b::real and f::"real => real"
  1429   assumes "a \<le> b" and
  1430     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<le> 0)"
  1431   shows "f a \<ge> f b"
  1432 proof -
  1433   have "(%x. -f x) a \<le> (%x. -f x) b"
  1434     apply (rule DERIV_nonneg_imp_nondecreasing [of a b "%x. -f x"])
  1435     using assms
  1436     apply auto
  1437     apply (metis DERIV_minus neg_0_le_iff_le)
  1438     done
  1439   thus ?thesis
  1440     by simp
  1441 qed
  1442 
  1443 lemma DERIV_pos_imp_increasing_at_bot:
  1444   fixes f :: "real => real"
  1445   assumes "\<And>x. x \<le> b \<Longrightarrow> (EX y. DERIV f x :> y & y > 0)"
  1446       and lim: "(f ---> flim) at_bot"
  1447   shows "flim < f b"
  1448 proof -
  1449   have "flim \<le> f (b - 1)"
  1450     apply (rule tendsto_ge_const [OF _ lim])
  1451     apply (auto simp: trivial_limit_at_bot_linorder eventually_at_bot_linorder)
  1452     apply (rule_tac x="b - 2" in exI)
  1453     apply (force intro: order.strict_implies_order DERIV_pos_imp_increasing [where f=f] assms)
  1454     done
  1455   also have "... < f b"
  1456     by (force intro: DERIV_pos_imp_increasing [where f=f] assms)
  1457   finally show ?thesis .
  1458 qed
  1459 
  1460 lemma DERIV_neg_imp_decreasing_at_top:
  1461   fixes f :: "real => real"
  1462   assumes der: "\<And>x. x \<ge> b \<Longrightarrow> (EX y. DERIV f x :> y & y < 0)"
  1463       and lim: "(f ---> flim) at_top"
  1464   shows "flim < f b"
  1465   apply (rule DERIV_pos_imp_increasing_at_bot [where f = "\<lambda>i. f (-i)" and b = "-b", simplified])
  1466   apply (metis DERIV_mirror der le_minus_iff neg_0_less_iff_less)
  1467   apply (metis filterlim_at_top_mirror lim)
  1468   done
  1469 
  1470 text \<open>Derivative of inverse function\<close>
  1471 
  1472 lemma DERIV_inverse_function:
  1473   fixes f g :: "real \<Rightarrow> real"
  1474   assumes der: "DERIV f (g x) :> D"
  1475   assumes neq: "D \<noteq> 0"
  1476   assumes a: "a < x" and b: "x < b"
  1477   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1478   assumes cont: "isCont g x"
  1479   shows "DERIV g x :> inverse D"
  1480 unfolding DERIV_iff2
  1481 proof (rule LIM_equal2)
  1482   show "0 < min (x - a) (b - x)"
  1483     using a b by arith 
  1484 next
  1485   fix y
  1486   assume "norm (y - x) < min (x - a) (b - x)"
  1487   hence "a < y" and "y < b" 
  1488     by (simp_all add: abs_less_iff)
  1489   thus "(g y - g x) / (y - x) =
  1490         inverse ((f (g y) - x) / (g y - g x))"
  1491     by (simp add: inj)
  1492 next
  1493   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) -- g x --> D"
  1494     by (rule der [unfolded DERIV_iff2])
  1495   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) -- g x --> D"
  1496     using inj a b by simp
  1497   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1498   proof (rule exI, safe)
  1499     show "0 < min (x - a) (b - x)"
  1500       using a b by simp
  1501   next
  1502     fix y
  1503     assume "norm (y - x) < min (x - a) (b - x)"
  1504     hence y: "a < y" "y < b"
  1505       by (simp_all add: abs_less_iff)
  1506     assume "g y = g x"
  1507     hence "f (g y) = f (g x)" by simp
  1508     hence "y = x" using inj y a b by simp
  1509     also assume "y \<noteq> x"
  1510     finally show False by simp
  1511   qed
  1512   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) -- x --> D"
  1513     using cont 1 2 by (rule isCont_LIM_compose2)
  1514   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1515         -- x --> inverse D"
  1516     using neq by (rule tendsto_inverse)
  1517 qed
  1518 
  1519 subsection \<open>Generalized Mean Value Theorem\<close>
  1520 
  1521 theorem GMVT:
  1522   fixes a b :: real
  1523   assumes alb: "a < b"
  1524     and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1525     and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable (at x)"
  1526     and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1527     and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable (at x)"
  1528   shows "\<exists>g'c f'c c.
  1529     DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1530 proof -
  1531   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1532   from assms have "a < b" by simp
  1533   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1534     using fc gc by simp
  1535   moreover have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable (at x)"
  1536     using fd gd by simp
  1537   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1538   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1539   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1540 
  1541   from cdef have cint: "a < c \<and> c < b" by auto
  1542   with gd have "g differentiable (at c)" by simp
  1543   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1544   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1545 
  1546   from cdef have "a < c \<and> c < b" by auto
  1547   with fd have "f differentiable (at c)" by simp
  1548   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1549   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1550 
  1551   from cdef have "DERIV ?h c :> l" by auto
  1552   moreover have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1553     using g'cdef f'cdef by (auto intro!: derivative_eq_intros)
  1554   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1555 
  1556   {
  1557     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1558     also from leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1559     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1560   }
  1561   moreover
  1562   {
  1563     have "?h b - ?h a =
  1564          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1565           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1566       by (simp add: algebra_simps)
  1567     hence "?h b - ?h a = 0" by auto
  1568   }
  1569   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1570   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1571   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1572   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: ac_simps)
  1573 
  1574   with g'cdef f'cdef cint show ?thesis by auto
  1575 qed
  1576 
  1577 lemma GMVT':
  1578   fixes f g :: "real \<Rightarrow> real"
  1579   assumes "a < b"
  1580   assumes isCont_f: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont f z"
  1581   assumes isCont_g: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont g z"
  1582   assumes DERIV_g: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV g z :> (g' z)"
  1583   assumes DERIV_f: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV f z :> (f' z)"
  1584   shows "\<exists>c. a < c \<and> c < b \<and> (f b - f a) * g' c = (g b - g a) * f' c"
  1585 proof -
  1586   have "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and>
  1587     a < c \<and> c < b \<and> (f b - f a) * g'c = (g b - g a) * f'c"
  1588     using assms by (intro GMVT) (force simp: real_differentiable_def)+
  1589   then obtain c where "a < c" "c < b" "(f b - f a) * g' c = (g b - g a) * f' c"
  1590     using DERIV_f DERIV_g by (force dest: DERIV_unique)
  1591   then show ?thesis
  1592     by auto
  1593 qed
  1594 
  1595 
  1596 subsection \<open>L'Hopitals rule\<close>
  1597 
  1598 lemma isCont_If_ge:
  1599   fixes a :: "'a :: linorder_topology"
  1600   shows "continuous (at_left a) g \<Longrightarrow> (f ---> g a) (at_right a) \<Longrightarrow> isCont (\<lambda>x. if x \<le> a then g x else f x) a"
  1601   unfolding isCont_def continuous_within
  1602   apply (intro filterlim_split_at)
  1603   apply (subst filterlim_cong[OF refl refl, where g=g])
  1604   apply (simp_all add: eventually_at_filter less_le)
  1605   apply (subst filterlim_cong[OF refl refl, where g=f])
  1606   apply (simp_all add: eventually_at_filter less_le)
  1607   done
  1608 
  1609 lemma lhopital_right_0:
  1610   fixes f0 g0 :: "real \<Rightarrow> real"
  1611   assumes f_0: "(f0 ---> 0) (at_right 0)"
  1612   assumes g_0: "(g0 ---> 0) (at_right 0)"
  1613   assumes ev:
  1614     "eventually (\<lambda>x. g0 x \<noteq> 0) (at_right 0)"
  1615     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1616     "eventually (\<lambda>x. DERIV f0 x :> f' x) (at_right 0)"
  1617     "eventually (\<lambda>x. DERIV g0 x :> g' x) (at_right 0)"
  1618   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) (at_right 0)"
  1619   shows "((\<lambda> x. f0 x / g0 x) ---> x) (at_right 0)"
  1620 proof -
  1621   def f \<equiv> "\<lambda>x. if x \<le> 0 then 0 else f0 x"
  1622   then have "f 0 = 0" by simp
  1623 
  1624   def g \<equiv> "\<lambda>x. if x \<le> 0 then 0 else g0 x"
  1625   then have "g 0 = 0" by simp
  1626 
  1627   have "eventually (\<lambda>x. g0 x \<noteq> 0 \<and> g' x \<noteq> 0 \<and>
  1628       DERIV f0 x :> (f' x) \<and> DERIV g0 x :> (g' x)) (at_right 0)"
  1629     using ev by eventually_elim auto
  1630   then obtain a where [arith]: "0 < a"
  1631     and g0_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g0 x \<noteq> 0"
  1632     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1633     and f0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV f0 x :> (f' x)"
  1634     and g0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV g0 x :> (g' x)"
  1635     unfolding eventually_at by (auto simp: dist_real_def)
  1636 
  1637   have g_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g x \<noteq> 0"
  1638     using g0_neq_0 by (simp add: g_def)
  1639 
  1640   { fix x assume x: "0 < x" "x < a" then have "DERIV f x :> (f' x)"
  1641       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ f0[OF x]])
  1642          (auto simp: f_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1643   note f = this
  1644 
  1645   { fix x assume x: "0 < x" "x < a" then have "DERIV g x :> (g' x)"
  1646       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ g0[OF x]])
  1647          (auto simp: g_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1648   note g = this
  1649 
  1650   have "isCont f 0"
  1651     unfolding f_def by (intro isCont_If_ge f_0 continuous_const)
  1652 
  1653   have "isCont g 0"
  1654     unfolding g_def by (intro isCont_If_ge g_0 continuous_const)
  1655 
  1656   have "\<exists>\<zeta>. \<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)"
  1657   proof (rule bchoice, rule)
  1658     fix x assume "x \<in> {0 <..< a}"
  1659     then have x[arith]: "0 < x" "x < a" by auto
  1660     with g'_neq_0 g_neq_0 \<open>g 0 = 0\<close> have g': "\<And>x. 0 < x \<Longrightarrow> x < a  \<Longrightarrow> 0 \<noteq> g' x" "g 0 \<noteq> g x"
  1661       by auto
  1662     have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont f x"
  1663       using \<open>isCont f 0\<close> f by (auto intro: DERIV_isCont simp: le_less)
  1664     moreover have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont g x"
  1665       using \<open>isCont g 0\<close> g by (auto intro: DERIV_isCont simp: le_less)
  1666     ultimately have "\<exists>c. 0 < c \<and> c < x \<and> (f x - f 0) * g' c = (g x - g 0) * f' c"
  1667       using f g \<open>x < a\<close> by (intro GMVT') auto
  1668     then obtain c where *: "0 < c" "c < x" "(f x - f 0) * g' c = (g x - g 0) * f' c"
  1669       by blast
  1670     moreover
  1671     from * g'(1)[of c] g'(2) have "(f x - f 0)  / (g x - g 0) = f' c / g' c"
  1672       by (simp add: field_simps)
  1673     ultimately show "\<exists>y. 0 < y \<and> y < x \<and> f x / g x = f' y / g' y"
  1674       using \<open>f 0 = 0\<close> \<open>g 0 = 0\<close> by (auto intro!: exI[of _ c])
  1675   qed
  1676   then obtain \<zeta> where "\<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)" ..
  1677   then have \<zeta>: "eventually (\<lambda>x. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)) (at_right 0)"
  1678     unfolding eventually_at by (intro exI[of _ a]) (auto simp: dist_real_def)
  1679   moreover
  1680   from \<zeta> have "eventually (\<lambda>x. norm (\<zeta> x) \<le> x) (at_right 0)"
  1681     by eventually_elim auto
  1682   then have "((\<lambda>x. norm (\<zeta> x)) ---> 0) (at_right 0)"
  1683     by (rule_tac real_tendsto_sandwich[where f="\<lambda>x. 0" and h="\<lambda>x. x"]) auto
  1684   then have "(\<zeta> ---> 0) (at_right 0)"
  1685     by (rule tendsto_norm_zero_cancel)
  1686   with \<zeta> have "filterlim \<zeta> (at_right 0) (at_right 0)"
  1687     by (auto elim!: eventually_elim1 simp: filterlim_at)
  1688   from this lim have "((\<lambda>t. f' (\<zeta> t) / g' (\<zeta> t)) ---> x) (at_right 0)"
  1689     by (rule_tac filterlim_compose[of _ _ _ \<zeta>])
  1690   ultimately have "((\<lambda>t. f t / g t) ---> x) (at_right 0)" (is ?P)
  1691     by (rule_tac filterlim_cong[THEN iffD1, OF refl refl])
  1692        (auto elim: eventually_elim1)
  1693   also have "?P \<longleftrightarrow> ?thesis"
  1694     by (rule filterlim_cong) (auto simp: f_def g_def eventually_at_filter)
  1695   finally show ?thesis .
  1696 qed
  1697 
  1698 lemma lhopital_right:
  1699   "((f::real \<Rightarrow> real) ---> 0) (at_right x) \<Longrightarrow> (g ---> 0) (at_right x) \<Longrightarrow>
  1700     eventually (\<lambda>x. g x \<noteq> 0) (at_right x) \<Longrightarrow>
  1701     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1702     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1703     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1704     ((\<lambda> x. (f' x / g' x)) ---> y) (at_right x) \<Longrightarrow>
  1705   ((\<lambda> x. f x / g x) ---> y) (at_right x)"
  1706   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1707   by (rule lhopital_right_0)
  1708 
  1709 lemma lhopital_left:
  1710   "((f::real \<Rightarrow> real) ---> 0) (at_left x) \<Longrightarrow> (g ---> 0) (at_left x) \<Longrightarrow>
  1711     eventually (\<lambda>x. g x \<noteq> 0) (at_left x) \<Longrightarrow>
  1712     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1713     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1714     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1715     ((\<lambda> x. (f' x / g' x)) ---> y) (at_left x) \<Longrightarrow>
  1716   ((\<lambda> x. f x / g x) ---> y) (at_left x)"
  1717   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1718   by (rule lhopital_right[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1719 
  1720 lemma lhopital:
  1721   "((f::real \<Rightarrow> real) ---> 0) (at x) \<Longrightarrow> (g ---> 0) (at x) \<Longrightarrow>
  1722     eventually (\<lambda>x. g x \<noteq> 0) (at x) \<Longrightarrow>
  1723     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1724     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1725     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1726     ((\<lambda> x. (f' x / g' x)) ---> y) (at x) \<Longrightarrow>
  1727   ((\<lambda> x. f x / g x) ---> y) (at x)"
  1728   unfolding eventually_at_split filterlim_at_split
  1729   by (auto intro!: lhopital_right[of f x g g' f'] lhopital_left[of f x g g' f'])
  1730 
  1731 lemma lhopital_right_0_at_top:
  1732   fixes f g :: "real \<Rightarrow> real"
  1733   assumes g_0: "LIM x at_right 0. g x :> at_top"
  1734   assumes ev:
  1735     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1736     "eventually (\<lambda>x. DERIV f x :> f' x) (at_right 0)"
  1737     "eventually (\<lambda>x. DERIV g x :> g' x) (at_right 0)"
  1738   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) (at_right 0)"
  1739   shows "((\<lambda> x. f x / g x) ---> x) (at_right 0)"
  1740   unfolding tendsto_iff
  1741 proof safe
  1742   fix e :: real assume "0 < e"
  1743 
  1744   with lim[unfolded tendsto_iff, rule_format, of "e / 4"]
  1745   have "eventually (\<lambda>t. dist (f' t / g' t) x < e / 4) (at_right 0)" by simp
  1746   from eventually_conj[OF eventually_conj[OF ev(1) ev(2)] eventually_conj[OF ev(3) this]]
  1747   obtain a where [arith]: "0 < a"
  1748     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1749     and f0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV f x :> (f' x)"
  1750     and g0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV g x :> (g' x)"
  1751     and Df: "\<And>t. 0 < t \<Longrightarrow> t < a \<Longrightarrow> dist (f' t / g' t) x < e / 4"
  1752     unfolding eventually_at_le by (auto simp: dist_real_def)
  1753     
  1754 
  1755   from Df have
  1756     "eventually (\<lambda>t. t < a) (at_right 0)" "eventually (\<lambda>t::real. 0 < t) (at_right 0)"
  1757     unfolding eventually_at by (auto intro!: exI[of _ a] simp: dist_real_def)
  1758 
  1759   moreover
  1760   have "eventually (\<lambda>t. 0 < g t) (at_right 0)" "eventually (\<lambda>t. g a < g t) (at_right 0)"
  1761     using g_0 by (auto elim: eventually_elim1 simp: filterlim_at_top_dense)
  1762 
  1763   moreover
  1764   have inv_g: "((\<lambda>x. inverse (g x)) ---> 0) (at_right 0)"
  1765     using tendsto_inverse_0 filterlim_mono[OF g_0 at_top_le_at_infinity order_refl]
  1766     by (rule filterlim_compose)
  1767   then have "((\<lambda>x. norm (1 - g a * inverse (g x))) ---> norm (1 - g a * 0)) (at_right 0)"
  1768     by (intro tendsto_intros)
  1769   then have "((\<lambda>x. norm (1 - g a / g x)) ---> 1) (at_right 0)"
  1770     by (simp add: inverse_eq_divide)
  1771   from this[unfolded tendsto_iff, rule_format, of 1]
  1772   have "eventually (\<lambda>x. norm (1 - g a / g x) < 2) (at_right 0)"
  1773     by (auto elim!: eventually_elim1 simp: dist_real_def)
  1774 
  1775   moreover
  1776   from inv_g have "((\<lambda>t. norm ((f a - x * g a) * inverse (g t))) ---> norm ((f a - x * g a) * 0)) (at_right 0)"
  1777     by (intro tendsto_intros)
  1778   then have "((\<lambda>t. norm (f a - x * g a) / norm (g t)) ---> 0) (at_right 0)"
  1779     by (simp add: inverse_eq_divide)
  1780   from this[unfolded tendsto_iff, rule_format, of "e / 2"] \<open>0 < e\<close>
  1781   have "eventually (\<lambda>t. norm (f a - x * g a) / norm (g t) < e / 2) (at_right 0)"
  1782     by (auto simp: dist_real_def)
  1783 
  1784   ultimately show "eventually (\<lambda>t. dist (f t / g t) x < e) (at_right 0)"
  1785   proof eventually_elim
  1786     fix t assume t[arith]: "0 < t" "t < a" "g a < g t" "0 < g t"
  1787     assume ineq: "norm (1 - g a / g t) < 2" "norm (f a - x * g a) / norm (g t) < e / 2"
  1788 
  1789     have "\<exists>y. t < y \<and> y < a \<and> (g a - g t) * f' y = (f a - f t) * g' y"
  1790       using f0 g0 t(1,2) by (intro GMVT') (force intro!: DERIV_isCont)+
  1791     then obtain y where [arith]: "t < y" "y < a"
  1792       and D_eq0: "(g a - g t) * f' y = (f a - f t) * g' y"
  1793       by blast
  1794     from D_eq0 have D_eq: "(f t - f a) / (g t - g a) = f' y / g' y"
  1795       using \<open>g a < g t\<close> g'_neq_0[of y] by (auto simp add: field_simps)
  1796 
  1797     have *: "f t / g t - x = ((f t - f a) / (g t - g a) - x) * (1 - g a / g t) + (f a - x * g a) / g t"
  1798       by (simp add: field_simps)
  1799     have "norm (f t / g t - x) \<le>
  1800         norm (((f t - f a) / (g t - g a) - x) * (1 - g a / g t)) + norm ((f a - x * g a) / g t)"
  1801       unfolding * by (rule norm_triangle_ineq)
  1802     also have "\<dots> = dist (f' y / g' y) x * norm (1 - g a / g t) + norm (f a - x * g a) / norm (g t)"
  1803       by (simp add: abs_mult D_eq dist_real_def)
  1804     also have "\<dots> < (e / 4) * 2 + e / 2"
  1805       using ineq Df[of y] \<open>0 < e\<close> by (intro add_le_less_mono mult_mono) auto
  1806     finally show "dist (f t / g t) x < e"
  1807       by (simp add: dist_real_def)
  1808   qed
  1809 qed
  1810 
  1811 lemma lhopital_right_at_top:
  1812   "LIM x at_right x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1813     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1814     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1815     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1816     ((\<lambda> x. (f' x / g' x)) ---> y) (at_right x) \<Longrightarrow>
  1817     ((\<lambda> x. f x / g x) ---> y) (at_right x)"
  1818   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1819   by (rule lhopital_right_0_at_top)
  1820 
  1821 lemma lhopital_left_at_top:
  1822   "LIM x at_left x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1823     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1824     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1825     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1826     ((\<lambda> x. (f' x / g' x)) ---> y) (at_left x) \<Longrightarrow>
  1827     ((\<lambda> x. f x / g x) ---> y) (at_left x)"
  1828   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1829   by (rule lhopital_right_at_top[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1830 
  1831 lemma lhopital_at_top:
  1832   "LIM x at x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1833     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1834     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1835     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1836     ((\<lambda> x. (f' x / g' x)) ---> y) (at x) \<Longrightarrow>
  1837     ((\<lambda> x. f x / g x) ---> y) (at x)"
  1838   unfolding eventually_at_split filterlim_at_split
  1839   by (auto intro!: lhopital_right_at_top[of g x g' f f'] lhopital_left_at_top[of g x g' f f'])
  1840 
  1841 lemma lhospital_at_top_at_top:
  1842   fixes f g :: "real \<Rightarrow> real"
  1843   assumes g_0: "LIM x at_top. g x :> at_top"
  1844   assumes g': "eventually (\<lambda>x. g' x \<noteq> 0) at_top"
  1845   assumes Df: "eventually (\<lambda>x. DERIV f x :> f' x) at_top"
  1846   assumes Dg: "eventually (\<lambda>x. DERIV g x :> g' x) at_top"
  1847   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) at_top"
  1848   shows "((\<lambda> x. f x / g x) ---> x) at_top"
  1849   unfolding filterlim_at_top_to_right
  1850 proof (rule lhopital_right_0_at_top)
  1851   let ?F = "\<lambda>x. f (inverse x)"
  1852   let ?G = "\<lambda>x. g (inverse x)"
  1853   let ?R = "at_right (0::real)"
  1854   let ?D = "\<lambda>f' x. f' (inverse x) * - (inverse x ^ Suc (Suc 0))"
  1855 
  1856   show "LIM x ?R. ?G x :> at_top"
  1857     using g_0 unfolding filterlim_at_top_to_right .
  1858 
  1859   show "eventually (\<lambda>x. DERIV ?G x  :> ?D g' x) ?R"
  1860     unfolding eventually_at_right_to_top
  1861     using Dg eventually_ge_at_top[where c="1::real"]
  1862     apply eventually_elim
  1863     apply (rule DERIV_cong)
  1864     apply (rule DERIV_chain'[where f=inverse])
  1865     apply (auto intro!:  DERIV_inverse)
  1866     done
  1867 
  1868   show "eventually (\<lambda>x. DERIV ?F x  :> ?D f' x) ?R"
  1869     unfolding eventually_at_right_to_top
  1870     using Df eventually_ge_at_top[where c="1::real"]
  1871     apply eventually_elim
  1872     apply (rule DERIV_cong)
  1873     apply (rule DERIV_chain'[where f=inverse])
  1874     apply (auto intro!:  DERIV_inverse)
  1875     done
  1876 
  1877   show "eventually (\<lambda>x. ?D g' x \<noteq> 0) ?R"
  1878     unfolding eventually_at_right_to_top
  1879     using g' eventually_ge_at_top[where c="1::real"]
  1880     by eventually_elim auto
  1881     
  1882   show "((\<lambda>x. ?D f' x / ?D g' x) ---> x) ?R"
  1883     unfolding filterlim_at_right_to_top
  1884     apply (intro filterlim_cong[THEN iffD2, OF refl refl _ lim])
  1885     using eventually_ge_at_top[where c="1::real"]
  1886     by eventually_elim simp
  1887 qed
  1888 
  1889 end