src/Pure/sign.ML
author wenzelm
Fri Jul 01 14:41:59 2005 +0200 (2005-07-01)
changeset 16655 3e4d726aaed1
parent 16597 5a5229a55964
child 16723 9a9c034f1d57
permissions -rw-r--r--
added all_sorts_nonempty;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, constant declarations.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_classes: (bstring * xstring list) list -> theory -> theory
    29   val add_classes_i: (bstring * class list) list -> theory -> theory
    30   val add_classrel: (xstring * xstring) list -> theory -> theory
    31   val add_classrel_i: (class * class) list -> theory -> theory
    32   val add_trfuns:
    33     (string * (ast list -> ast)) list *
    34     (string * (term list -> term)) list *
    35     (string * (term list -> term)) list *
    36     (string * (ast list -> ast)) list -> theory -> theory
    37   val add_trfunsT:
    38     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    39   val add_advanced_trfuns:
    40     (string * (theory -> ast list -> ast)) list *
    41     (string * (theory -> term list -> term)) list *
    42     (string * (theory -> term list -> term)) list *
    43     (string * (theory -> ast list -> ast)) list -> theory -> theory
    44   val add_advanced_trfunsT:
    45     (string * (theory -> bool -> typ -> term list -> term)) list -> theory -> theory
    46   val add_tokentrfuns:
    47     (string * string * (string -> string * real)) list -> theory -> theory
    48   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    49     -> theory -> theory
    50   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    51   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    52   val add_path: string -> theory -> theory
    53   val parent_path: theory -> theory
    54   val root_path: theory -> theory
    55   val absolute_path: theory -> theory
    56   val local_path: theory -> theory
    57   val qualified_names: theory -> theory
    58   val no_base_names: theory -> theory
    59   val custom_accesses: (string list -> string list list) -> theory -> theory
    60   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    61     theory -> theory
    62   val restore_naming: theory -> theory -> theory
    63   val hide_classes: bool -> xstring list -> theory -> theory
    64   val hide_classes_i: bool -> string list -> theory -> theory
    65   val hide_types: bool -> xstring list -> theory -> theory
    66   val hide_types_i: bool -> string list -> theory -> theory
    67   val hide_consts: bool -> xstring list -> theory -> theory
    68   val hide_consts_i: bool -> string list -> theory -> theory
    69 end
    70 
    71 signature SIGN =
    72 sig
    73   type sg    (*obsolete*)
    74   val init_data: theory -> theory
    75   val rep_sg: theory ->
    76    {naming: NameSpace.naming,
    77     syn: Syntax.syntax,
    78     tsig: Type.tsig,
    79     consts: (typ * stamp) NameSpace.table}
    80   val naming_of: theory -> NameSpace.naming
    81   val base_name: string -> bstring
    82   val full_name: theory -> bstring -> string
    83   val full_name_path: theory -> string -> bstring -> string
    84   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    85   val syn_of: theory -> Syntax.syntax
    86   val tsig_of: theory -> Type.tsig
    87   val classes: theory -> class list
    88   val defaultS: theory -> sort
    89   val subsort: theory -> sort * sort -> bool
    90   val of_sort: theory -> typ * sort -> bool
    91   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    92   val universal_witness: theory -> (typ * sort) option
    93   val all_sorts_nonempty: theory -> bool
    94   val typ_instance: theory -> typ * typ -> bool
    95   val is_logtype: theory -> string -> bool
    96   val const_type: theory -> string -> typ option
    97   val the_const_type: theory -> string -> typ
    98   val declared_tyname: theory -> string -> bool
    99   val declared_const: theory -> string -> bool
   100   val class_space: theory -> NameSpace.T
   101   val type_space: theory -> NameSpace.T
   102   val const_space: theory -> NameSpace.T
   103   val intern_class: theory -> xstring -> string
   104   val extern_class: theory -> string -> xstring
   105   val intern_type: theory -> xstring -> string
   106   val extern_type: theory -> string -> xstring
   107   val intern_const: theory -> xstring -> string
   108   val extern_const: theory -> string -> xstring
   109   val intern_sort: theory -> sort -> sort
   110   val extern_sort: theory -> sort -> sort
   111   val intern_typ: theory -> typ -> typ
   112   val extern_typ: theory -> typ -> typ
   113   val intern_term: theory -> term -> term
   114   val extern_term: theory -> term -> term
   115   val intern_tycons: theory -> typ -> typ
   116   val pretty_term': Syntax.syntax -> theory -> term -> Pretty.T
   117   val pretty_term: theory -> term -> Pretty.T
   118   val pretty_typ: theory -> typ -> Pretty.T
   119   val pretty_sort: theory -> sort -> Pretty.T
   120   val pretty_classrel: theory -> class list -> Pretty.T
   121   val pretty_arity: theory -> arity -> Pretty.T
   122   val string_of_term: theory -> term -> string
   123   val string_of_typ: theory -> typ -> string
   124   val string_of_sort: theory -> sort -> string
   125   val string_of_classrel: theory -> class list -> string
   126   val string_of_arity: theory -> arity -> string
   127   val pprint_term: theory -> term -> pprint_args -> unit
   128   val pprint_typ: theory -> typ -> pprint_args -> unit
   129   val pp: theory -> Pretty.pp
   130   val certify_class: theory -> class -> class
   131   val certify_sort: theory -> sort -> sort
   132   val certify_typ: theory -> typ -> typ
   133   val certify_typ_syntax: theory -> typ -> typ
   134   val certify_typ_abbrev: theory -> typ -> typ
   135   val certify_term: Pretty.pp -> theory -> term -> term * typ * int
   136   val certify_prop: Pretty.pp -> theory -> term -> term * typ * int
   137   val cert_term: theory -> term -> term
   138   val cert_prop: theory -> term -> term
   139   val read_sort': Syntax.syntax -> theory -> string -> sort
   140   val read_sort: theory -> string -> sort
   141   val read_typ': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   142   val read_typ_syntax': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   143   val read_typ_abbrev': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   144   val read_typ: theory * (indexname -> sort option) -> string -> typ
   145   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   146   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   147   val read_tyname: theory -> string -> typ
   148   val read_const: theory -> string -> term
   149   val infer_types_simult: Pretty.pp -> theory -> (indexname -> typ option) ->
   150     (indexname -> sort option) -> string list -> bool
   151     -> (term list * typ) list -> term list * (indexname * typ) list
   152   val infer_types: Pretty.pp -> theory -> (indexname -> typ option) ->
   153     (indexname -> sort option) -> string list -> bool
   154     -> term list * typ -> term * (indexname * typ) list
   155   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax ->
   156     theory * (indexname -> typ option) * (indexname -> sort option) ->
   157     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   158   val read_def_terms:
   159     theory * (indexname -> typ option) * (indexname -> sort option) ->
   160     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   161   val simple_read_term: theory -> typ -> string -> term
   162   val read_term: theory -> string -> term
   163   val read_prop: theory -> string -> term
   164   val const_of_class: class -> string
   165   val class_of_const: string -> class
   166   include SIGN_THEORY
   167 end
   168 
   169 structure Sign: SIGN =
   170 struct
   171 
   172 type sg = theory;
   173 
   174 
   175 (** datatype sign **)
   176 
   177 datatype sign = Sign of
   178  {naming: NameSpace.naming,                 (*common naming conventions*)
   179   syn: Syntax.syntax,                       (*concrete syntax for terms, types, sorts*)
   180   tsig: Type.tsig,                          (*order-sorted signature of types*)
   181   consts: (typ * stamp) NameSpace.table};   (*type schemes of term constants*)
   182 
   183 fun make_sign (naming, syn, tsig, consts) =
   184   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   185 
   186 fun err_dup_consts cs =
   187   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   188 
   189 structure SignData = TheoryDataFun
   190 (struct
   191   val name = "Pure/sign";
   192   type T = sign;
   193   val copy = I;
   194   val extend = I;
   195 
   196   val empty =
   197     make_sign (NameSpace.default_naming, Syntax.pure_syn, Type.empty_tsig, NameSpace.empty_table);
   198 
   199   fun merge pp (sign1, sign2) =
   200     let
   201       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   202       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   203 
   204       val naming = NameSpace.default_naming;
   205       val syn = Syntax.merge_syntaxes syn1 syn2;
   206       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   207       val consts = NameSpace.merge_tables eq_snd (consts1, consts2)
   208         handle Symtab.DUPS cs => err_dup_consts cs;
   209     in make_sign (naming, syn, tsig, consts) end;
   210 
   211   fun print _ _ = ();
   212 end);
   213 
   214 val init_data = SignData.init;
   215 
   216 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   217 
   218 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   219   make_sign (f (naming, syn, tsig, consts)));
   220 
   221 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   222 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   223 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   224 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   225 
   226 
   227 (* naming *)
   228 
   229 val naming_of = #naming o rep_sg;
   230 val base_name = NameSpace.base;
   231 val full_name = NameSpace.full o naming_of;
   232 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   233 val declare_name = NameSpace.declare o naming_of;
   234 
   235 
   236 (* syntax *)
   237 
   238 val syn_of = #syn o rep_sg;
   239 
   240 
   241 (* type signature *)
   242 
   243 val tsig_of = #tsig o rep_sg;
   244 val classes = Type.classes o tsig_of;
   245 val defaultS = Type.defaultS o tsig_of;
   246 val subsort = Type.subsort o tsig_of;
   247 val of_sort = Type.of_sort o tsig_of;
   248 val witness_sorts = Type.witness_sorts o tsig_of;
   249 val universal_witness = Type.universal_witness o tsig_of;
   250 val all_sorts_nonempty = is_some o universal_witness;
   251 val typ_instance = Type.typ_instance o tsig_of;
   252 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   253 
   254 
   255 (* consts signature *)
   256 
   257 fun const_type thy c = Option.map #1 (Symtab.lookup (#2 (#consts (rep_sg thy)), c));
   258 
   259 fun the_const_type thy c =
   260   (case const_type thy c of SOME T => T
   261   | NONE => raise TYPE ("Undeclared constant " ^ quote c, [], []));
   262 
   263 fun declared_tyname thy c =
   264   is_some (Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy))), c));
   265 
   266 val declared_const = is_some oo const_type;
   267 
   268 
   269 
   270 (** intern / extern names **)
   271 
   272 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   273 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   274 val const_space = #1 o #consts o rep_sg
   275 
   276 val intern_class = NameSpace.intern o class_space;
   277 val extern_class = NameSpace.extern o class_space;
   278 val intern_type = NameSpace.intern o type_space;
   279 val extern_type = NameSpace.extern o type_space;
   280 val intern_const = NameSpace.intern o const_space;
   281 val extern_const = NameSpace.extern o const_space;
   282 
   283 val intern_sort = map o intern_class;
   284 val extern_sort = map o extern_class;
   285 
   286 local
   287 
   288 fun mapping add_names f t =
   289   let
   290     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   291     val tab = List.mapPartial f' (add_names (t, []));
   292     fun get x = if_none (assoc_string (tab, x)) x;
   293   in get end;
   294 
   295 fun typ_mapping f g thy T =
   296   T |> Term.map_typ
   297     (mapping add_typ_classes (f thy) T)
   298     (mapping add_typ_tycons (g thy) T);
   299 
   300 fun term_mapping f g h thy t =
   301   t |> Term.map_term
   302     (mapping add_term_classes (f thy) t)
   303     (mapping add_term_tycons (g thy) t)
   304     (mapping add_term_consts (h thy) t);
   305 
   306 in
   307 
   308 val intern_typ = typ_mapping intern_class intern_type;
   309 val extern_typ = typ_mapping extern_class extern_type;
   310 val intern_term = term_mapping intern_class intern_type intern_const;
   311 val extern_term = term_mapping extern_class extern_type extern_const;
   312 val intern_tycons = typ_mapping (K I) intern_type;
   313 
   314 end;
   315 
   316 
   317 
   318 (** pretty printing of terms, types etc. **)
   319 
   320 fun pretty_term' syn thy t =
   321   Syntax.pretty_term thy syn (Context.exists_name Context.CPureN thy) (extern_term thy t);
   322 fun pretty_term thy t = pretty_term' (syn_of thy) thy t;
   323 fun pretty_typ thy T = Syntax.pretty_typ thy (syn_of thy) (extern_typ thy T);
   324 fun pretty_sort thy S = Syntax.pretty_sort thy (syn_of thy) (extern_sort thy S);
   325 
   326 fun pretty_classrel thy cs = Pretty.block (List.concat
   327   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   328 
   329 fun pretty_arity thy (a, Ss, S) =
   330   let
   331     val a' = extern_type thy a;
   332     val dom =
   333       if null Ss then []
   334       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   335   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   336 
   337 val string_of_term = Pretty.string_of oo pretty_term;
   338 val string_of_typ = Pretty.string_of oo pretty_typ;
   339 val string_of_sort = Pretty.string_of oo pretty_sort;
   340 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   341 val string_of_arity = Pretty.string_of oo pretty_arity;
   342 
   343 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   344 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   345 
   346 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   347   pretty_classrel thy, pretty_arity thy);
   348 
   349 
   350 
   351 (** certify entities **)    (*exception TYPE*)
   352 
   353 (* certify wrt. type signature *)
   354 
   355 fun certify cert = cert o tsig_of o Context.check_thy "Sign.certify";
   356 
   357 val certify_class      = certify Type.cert_class;
   358 val certify_sort       = certify Type.cert_sort;
   359 val certify_typ        = certify Type.cert_typ;
   360 val certify_typ_syntax = certify Type.cert_typ_syntax;
   361 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   362 
   363 
   364 (* certify_term *)
   365 
   366 local
   367 
   368 (*determine and check the type of a term*)
   369 fun type_check pp tm =
   370   let
   371     fun err_appl why bs t T u U =
   372       let
   373         val xs = map Free bs;           (*we do not rename here*)
   374         val t' = subst_bounds (xs, t);
   375         val u' = subst_bounds (xs, u);
   376         val msg = cat_lines
   377           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   378       in raise TYPE (msg, [T, U], [t', u']) end;
   379 
   380     fun typ_of (_, Const (_, T)) = T
   381       | typ_of (_, Free  (_, T)) = T
   382       | typ_of (_, Var (_, T)) = T
   383       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   384           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   385       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   386       | typ_of (bs, t $ u) =
   387           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   388             (case T of
   389               Type ("fun", [T1, T2]) =>
   390                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   391             | _ => err_appl "Operator not of function type" bs t T u U)
   392           end;
   393 
   394   in typ_of ([], tm) end;
   395 
   396 in
   397 
   398 fun certify_term pp thy tm =
   399   let
   400     val _ = Context.check_thy "Sign.certify_term" thy;
   401 
   402     val tm' = map_term_types (certify_typ thy) tm;
   403     val tm' = if tm = tm' then tm else tm';  (*avoid copying of already normal term*)
   404 
   405     fun err msg = raise TYPE (msg, [], [tm']);
   406 
   407     fun show_const a T = quote a ^ " :: " ^ Pretty.string_of_typ pp T;
   408 
   409     fun check_atoms (t $ u) = (check_atoms t; check_atoms u)
   410       | check_atoms (Abs (_, _, t)) = check_atoms t
   411       | check_atoms (Const (a, T)) =
   412           (case const_type thy a of
   413             NONE => err ("Undeclared constant " ^ show_const a T)
   414           | SOME U =>
   415               if typ_instance thy (T, U) then ()
   416               else err ("Illegal type for constant " ^ show_const a T))
   417       | check_atoms (Var ((x, i), _)) =
   418           if i < 0 then err ("Malformed variable: " ^ quote x) else ()
   419       | check_atoms _ = ();
   420   in
   421     check_atoms tm';
   422     (tm', type_check pp tm', maxidx_of_term tm')
   423   end;
   424 
   425 end;
   426 
   427 fun certify_prop pp thy tm =
   428   let val res as (tm', T, _) = certify_term pp thy tm
   429   in if T <> propT then raise TYPE ("Term not of type prop", [T], [tm']) else res end;
   430 
   431 fun cert_term thy tm = #1 (certify_term (pp thy) thy tm);
   432 fun cert_prop thy tm = #1 (certify_prop (pp thy) thy tm);
   433 
   434 
   435 
   436 (** read and certify entities **)    (*exception ERROR*)
   437 
   438 (* sorts *)
   439 
   440 fun read_sort' syn thy str =
   441   let
   442     val _ = Context.check_thy "Sign.read_sort'" thy;
   443     val S = intern_sort thy (Syntax.read_sort thy syn str);
   444   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   445 
   446 fun read_sort thy str = read_sort' (syn_of thy) thy str;
   447 
   448 
   449 (* types *)
   450 
   451 local
   452 
   453 fun gen_read_typ' cert syn (thy, def_sort) str =
   454   let
   455     val _ = Context.check_thy "Sign.gen_read_typ'" thy;
   456     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   457     val T = intern_tycons thy (Syntax.read_typ thy syn get_sort (intern_sort thy) str);
   458   in cert thy T handle TYPE (msg, _, _) => error msg end
   459   handle ERROR => error ("The error(s) above occurred in type " ^ quote str);
   460 
   461 fun gen_read_typ cert (thy, def_sort) str =
   462   gen_read_typ' cert (syn_of thy) (thy, def_sort) str;
   463 
   464 in
   465 
   466 fun no_def_sort thy = (thy: theory, K NONE);
   467 
   468 val read_typ'        = gen_read_typ' certify_typ;
   469 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   470 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   471 val read_typ         = gen_read_typ certify_typ;
   472 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   473 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   474 
   475 end;
   476 
   477 
   478 (* type and constant names *)
   479 
   480 fun read_tyname thy raw_c =
   481   let val c = intern_type thy raw_c in
   482     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy))), c) of
   483       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   484     | _ => error ("Undeclared type constructor: " ^ quote c))
   485   end;
   486 
   487 fun read_const thy raw_c =
   488   let
   489     val c = intern_const thy raw_c;
   490     val _ = the_const_type thy c handle TYPE (msg, _, _) => error msg;
   491   in Const (c, dummyT) end;
   492 
   493 
   494 
   495 (** infer_types **)         (*exception ERROR*)
   496 
   497 (*
   498   def_type: partial map from indexnames to types (constrains Frees and Vars)
   499   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   500   used: list of already used type variables
   501   freeze: if true then generated parameters are turned into TFrees, else TVars
   502 
   503   termss: lists of alternative parses (only one combination should be type-correct)
   504   typs: expected types
   505 *)
   506 
   507 fun infer_types_simult pp thy def_type def_sort used freeze args =
   508   let
   509     val termss = foldr multiply [[]] (map fst args);
   510     val typs =
   511       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   512 
   513     fun infer ts = OK (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   514         (const_type thy) def_type def_sort (intern_const thy) (intern_tycons thy)
   515         (intern_sort thy) used freeze typs ts)
   516       handle TYPE (msg, _, _) => Error msg;
   517 
   518     val err_results = map infer termss;
   519     val errs = List.mapPartial get_error err_results;
   520     val results = List.mapPartial get_ok err_results;
   521 
   522     val ambiguity = length termss;
   523 
   524     fun ambig_msg () =
   525       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   526       then
   527         error_msg "Got more than one parse tree.\n\
   528           \Retry with smaller Syntax.ambiguity_level for more information."
   529       else ();
   530   in
   531     if null results then (ambig_msg (); error (cat_lines errs))
   532     else if length results = 1 then
   533       (if ambiguity > ! Syntax.ambiguity_level then
   534         warning "Fortunately, only one parse tree is type correct.\n\
   535           \You may still want to disambiguate your grammar or your input."
   536       else (); hd results)
   537     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   538       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   539   end;
   540 
   541 fun infer_types pp thy def_type def_sort used freeze tsT =
   542   apfst hd (infer_types_simult pp thy def_type def_sort used freeze [tsT]);
   543 
   544 
   545 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   546 
   547 fun read_def_terms' pp is_logtype syn (thy, types, sorts) used freeze sTs =
   548   let
   549     fun read (s, T) =
   550       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   551       in (Syntax.read thy is_logtype syn T' s, T') end;
   552   in infer_types_simult pp thy types sorts used freeze (map read sTs) end;
   553 
   554 fun read_def_terms (thy, types, sorts) =
   555   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (thy, types, sorts);
   556 
   557 fun simple_read_term thy T s =
   558   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   559   in t end
   560   handle ERROR => error ("The error(s) above occurred for term " ^ s);
   561 
   562 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   563 fun read_prop thy = simple_read_term thy propT;
   564 
   565 
   566 
   567 (** signature extension functions **)  (*exception ERROR/TYPE*)
   568 
   569 (* add default sort *)
   570 
   571 fun gen_add_defsort prep_sort s thy =
   572   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   573 
   574 val add_defsort = gen_add_defsort read_sort;
   575 val add_defsort_i = gen_add_defsort certify_sort;
   576 
   577 
   578 (* add type constructors *)
   579 
   580 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   581   let
   582     val syn' = Syntax.extend_type_gram types syn;
   583     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   584     val tsig' = Type.add_types naming decls tsig;
   585   in (naming, syn', tsig', consts) end);
   586 
   587 fun add_typedecls decls thy =
   588   let
   589     fun type_of (a, vs, mx) =
   590       if null (duplicates vs) then (a, length vs, mx)
   591       else error ("Duplicate parameters in type declaration: " ^ quote a);
   592   in add_types (map type_of decls) thy end;
   593 
   594 
   595 (* add nonterminals *)
   596 
   597 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   598   let
   599     val syn' = Syntax.extend_consts ns syn;
   600     val tsig' = Type.add_nonterminals naming ns tsig;
   601   in (naming, syn', tsig', consts) end);
   602 
   603 
   604 (* add type abbreviations *)
   605 
   606 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   607   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   608     let
   609       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   610       val a' = Syntax.type_name a mx;
   611       val abbr = (a', vs, prep_typ thy rhs)
   612         handle ERROR => error ("in type abbreviation " ^ quote a');
   613       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   614     in (naming, syn', tsig', consts) end);
   615 
   616 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   617 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   618 
   619 
   620 (* add type arities *)
   621 
   622 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   623   let
   624     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   625       handle ERROR => error ("in arity for type " ^ quote a);
   626     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   627   in tsig' end);
   628 
   629 val add_arities = gen_add_arities intern_type read_sort;
   630 val add_arities_i = gen_add_arities (K I) certify_sort;
   631 
   632 
   633 (* modify syntax *)
   634 
   635 fun gen_syntax change_gram prep_typ prmode args thy =
   636   let
   637     fun prep (c, T, mx) = (c, prep_typ thy T, mx)
   638       handle ERROR => error ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   639   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   640 
   641 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   642 
   643 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   644 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   645 val add_syntax = add_modesyntax Syntax.default_mode;
   646 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   647 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   648 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   649 
   650 
   651 (* add constants *)
   652 
   653 fun gen_add_consts prep_typ raw_args thy =
   654   let
   655     val prepT = compress_type o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   656     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   657       handle ERROR => error ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   658     val args = map prep raw_args;
   659     val decls = args |> map (fn (c, T, mx) => (Syntax.const_name c mx, (T, stamp ())));
   660 
   661     fun extend_consts consts = NameSpace.extend_table (naming_of thy) (consts, decls)
   662       handle Symtab.DUPS cs => err_dup_consts cs;
   663   in
   664     thy
   665     |> map_consts extend_consts
   666     |> add_syntax_i args
   667   end;
   668 
   669 val add_consts = gen_add_consts (read_typ o no_def_sort);
   670 val add_consts_i = gen_add_consts certify_typ;
   671 
   672 
   673 (* add type classes *)
   674 
   675 val classN = "_class";
   676 
   677 val const_of_class = suffix classN;
   678 fun class_of_const c = unsuffix classN c
   679   handle Fail _ => raise TERM ("class_of_const: bad name " ^ quote c, []);
   680 
   681 fun gen_add_class int_class (bclass, raw_classes) thy =
   682   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   683     let
   684       val classes = map (int_class thy) raw_classes;
   685       val syn' = Syntax.extend_consts [bclass] syn;
   686       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   687     in (naming, syn', tsig', consts) end)
   688   |> add_consts_i [(const_of_class bclass, a_itselfT --> propT, Syntax.NoSyn)];
   689 
   690 val add_classes = fold (gen_add_class intern_class);
   691 val add_classes_i = fold (gen_add_class (K I));
   692 
   693 
   694 (* add to classrel *)
   695 
   696 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   697   let
   698     val pairs = map (pairself (int_class thy)) raw_pairs;
   699     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   700   in tsig' end);
   701 
   702 val add_classrel = gen_add_classrel intern_class;
   703 val add_classrel_i = gen_add_classrel (K I);
   704 
   705 
   706 (* add translation functions *)
   707 
   708 local
   709 
   710 fun mk trs = map Syntax.mk_trfun trs;
   711 
   712 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   713   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   714 
   715 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   716 
   717 in
   718 
   719 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   720 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   721 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   722 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   723 
   724 end;
   725 
   726 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   727 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   728 
   729 
   730 (* add translation rules *)
   731 
   732 fun add_trrules args thy = thy |> map_syn (fn syn =>
   733   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   734   in Syntax.extend_trrules thy (is_logtype thy) syn rules syn end);
   735 
   736 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   737 
   738 
   739 (* modify naming *)
   740 
   741 val add_path        = map_naming o NameSpace.add_path;
   742 val qualified_names = map_naming NameSpace.qualified_names;
   743 val no_base_names   = map_naming NameSpace.no_base_names;
   744 val custom_accesses = map_naming o NameSpace.custom_accesses;
   745 val set_policy      = map_naming o NameSpace.set_policy;
   746 val restore_naming  = map_naming o K o naming_of;
   747 
   748 val parent_path     = add_path "..";
   749 val root_path       = add_path "/";
   750 val absolute_path   = add_path "//";
   751 
   752 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   753 
   754 
   755 (* hide names *)
   756 
   757 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   758 val hide_classes_i = map_tsig oo Type.hide_classes;
   759 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   760 val hide_types_i = map_tsig oo Type.hide_types;
   761 fun hide_consts b xs thy =
   762   thy |> map_consts (apfst (fold (NameSpace.hide b o intern_const thy) xs));
   763 val hide_consts_i = (map_consts o apfst) oo (fold o NameSpace.hide);
   764 
   765 end;