src/Pure/System/isar.ML
author wenzelm
Thu Aug 18 17:53:32 2011 +0200 (2011-08-18)
changeset 44270 3eaad39e520c
parent 43684 85388f5570c4
child 46961 5c6955f487e5
permissions -rw-r--r--
more careful treatment of exception serial numbers, with propagation to message channel;
     1 (*  Title:      Pure/System/isar.ML
     2     Author:     Makarius
     3 
     4 Global state of the raw Isar read-eval-print loop.
     5 *)
     6 
     7 signature ISAR =
     8 sig
     9   val init: unit -> unit
    10   val exn: unit -> (exn * string) option
    11   val state: unit -> Toplevel.state
    12   val goal: unit -> {context: Proof.context, facts: thm list, goal: thm}
    13   val print: unit -> unit
    14   val >> : Toplevel.transition -> bool
    15   val >>> : Toplevel.transition list -> unit
    16   val linear_undo: int -> unit
    17   val undo: int -> unit
    18   val kill: unit -> unit
    19   val kill_proof: unit -> unit
    20   val crashes: exn list Synchronized.var
    21   val toplevel_loop: TextIO.instream ->
    22     {init: bool, welcome: bool, sync: bool, secure: bool} -> unit
    23   val loop: unit -> unit
    24   val main: unit -> unit
    25 end;
    26 
    27 structure Isar: ISAR =
    28 struct
    29 
    30 
    31 (** TTY model -- SINGLE-THREADED! **)
    32 
    33 (* the global state *)
    34 
    35 type history = (Toplevel.state * Toplevel.transition) list;
    36   (*previous state, state transition -- regular commands only*)
    37 
    38 local
    39   val global_history = Unsynchronized.ref ([]: history);
    40   val global_state = Unsynchronized.ref Toplevel.toplevel;
    41   val global_exn = Unsynchronized.ref (NONE: (exn * string) option);
    42 in
    43 
    44 fun edit_history count f = NAMED_CRITICAL "Isar" (fn () =>
    45   let
    46     fun edit 0 (st, hist) = (global_history := hist; global_state := st; global_exn := NONE)
    47       | edit n (st, hist) = edit (n - 1) (f st hist);
    48   in edit count (! global_state, ! global_history) end);
    49 
    50 fun state () = ! global_state;
    51 
    52 fun exn () = ! global_exn;
    53 fun set_exn exn =  global_exn := exn;
    54 
    55 end;
    56 
    57 
    58 fun init () = edit_history 1 (K (K (Toplevel.toplevel, [])));
    59 
    60 fun goal () = Proof.goal (Toplevel.proof_of (state ()))
    61   handle Toplevel.UNDEF => error "No goal present";
    62 
    63 fun print () = Toplevel.print_state false (state ());
    64 
    65 
    66 (* history navigation *)
    67 
    68 local
    69 
    70 fun find_and_undo _ [] = error "Undo history exhausted"
    71   | find_and_undo which ((prev, tr) :: hist) =
    72       if which (Toplevel.name_of tr) then (prev, hist) else find_and_undo which hist;
    73 
    74 in
    75 
    76 fun linear_undo n = edit_history n (K (find_and_undo (K true)));
    77 
    78 fun undo n = edit_history n (fn st => fn hist =>
    79   find_and_undo (if Toplevel.is_proof st then K true else Keyword.is_theory) hist);
    80 
    81 fun kill () = edit_history 1 (fn st => fn hist =>
    82   find_and_undo
    83     (if Toplevel.is_proof st then Keyword.is_theory else Keyword.is_theory_begin) hist);
    84 
    85 fun kill_proof () = edit_history 1 (fn st => fn hist =>
    86   if Toplevel.is_proof st then find_and_undo Keyword.is_theory hist
    87   else raise Toplevel.UNDEF);
    88 
    89 end;
    90 
    91 
    92 (* interactive state transformations *)
    93 
    94 fun op >> tr =
    95   (case Toplevel.transition true tr (state ()) of
    96     NONE => false
    97   | SOME (_, SOME exn_info) =>
    98      (set_exn (SOME exn_info);
    99       Toplevel.error_msg tr (serial (), ML_Compiler.exn_message (Runtime.EXCURSION_FAIL exn_info));
   100       true)
   101   | SOME (st', NONE) =>
   102       let
   103         val name = Toplevel.name_of tr;
   104         val _ = if Keyword.is_theory_begin name then init () else ();
   105         val _ =
   106           if Keyword.is_regular name
   107           then edit_history 1 (fn st => fn hist => (st', (st, tr) :: hist)) else ();
   108       in true end);
   109 
   110 fun op >>> [] = ()
   111   | op >>> (tr :: trs) = if op >> tr then op >>> trs else ();
   112 
   113 
   114 (* toplevel loop -- uninterruptible *)
   115 
   116 val crashes = Synchronized.var "Isar.crashes" ([]: exn list);
   117 
   118 local
   119 
   120 fun raw_loop secure src =
   121   let
   122     fun check_secure () =
   123       (if secure then warning "Secure loop -- cannot exit to ML" else (); secure);
   124   in
   125     (case Source.get_single (Source.set_prompt Source.default_prompt src) of
   126       NONE => if secure then quit () else ()
   127     | SOME (tr, src') => if op >> tr orelse check_secure () then raw_loop secure src' else ())
   128     handle exn =>
   129       (Output.error_msg (ML_Compiler.exn_message exn)
   130         handle crash =>
   131           (Synchronized.change crashes (cons crash);
   132             warning "Recovering from Isar toplevel crash -- see also Isar.crashes");
   133         raw_loop secure src)
   134   end;
   135 
   136 in
   137 
   138 fun toplevel_loop in_stream {init = do_init, welcome, sync, secure} =
   139  (Context.set_thread_data NONE;
   140   if do_init then init () else ();
   141   if welcome then writeln (Session.welcome ()) else ();
   142   uninterruptible (fn _ => fn () => raw_loop secure (Outer_Syntax.isar in_stream sync)) ());
   143 
   144 end;
   145 
   146 fun loop () =
   147   toplevel_loop TextIO.stdIn
   148     {init = false, welcome = false, sync = false, secure = Secure.is_secure ()};
   149 
   150 fun main () =
   151   toplevel_loop TextIO.stdIn
   152     {init = true, welcome = true, sync = false, secure = Secure.is_secure ()};
   153 
   154 
   155 
   156 (** command syntax **)
   157 
   158 local
   159 
   160 val op >> = Scan.>>;
   161 
   162 in
   163 
   164 (* global history *)
   165 
   166 val _ =
   167   Outer_Syntax.improper_command "init_toplevel" "init toplevel point-of-interest" Keyword.control
   168     (Scan.succeed (Toplevel.no_timing o Toplevel.imperative init));
   169 
   170 val _ =
   171   Outer_Syntax.improper_command "linear_undo" "undo commands" Keyword.control
   172     (Scan.optional Parse.nat 1 >>
   173       (fn n => Toplevel.no_timing o Toplevel.imperative (fn () => linear_undo n)));
   174 
   175 val _ =
   176   Outer_Syntax.improper_command "undo" "undo commands (skipping closed proofs)" Keyword.control
   177     (Scan.optional Parse.nat 1 >>
   178       (fn n => Toplevel.no_timing o Toplevel.imperative (fn () => undo n)));
   179 
   180 val _ =
   181   Outer_Syntax.improper_command "undos_proof" "undo commands (skipping closed proofs)"
   182     Keyword.control
   183     (Scan.optional Parse.nat 1 >> (fn n => Toplevel.no_timing o
   184       Toplevel.keep (fn state =>
   185         if Toplevel.is_proof state then (undo n; print ()) else raise Toplevel.UNDEF)));
   186 
   187 val _ =
   188   Outer_Syntax.improper_command "cannot_undo" "partial undo -- Proof General legacy"
   189     Keyword.control
   190     (Parse.name >>
   191       (fn "end" => Toplevel.no_timing o Toplevel.imperative (fn () => undo 1)
   192         | txt => Toplevel.imperative (fn () => error ("Cannot undo " ^ quote txt))));
   193 
   194 val _ =
   195   Outer_Syntax.improper_command "kill" "kill partial proof or theory development" Keyword.control
   196     (Scan.succeed (Toplevel.no_timing o Toplevel.imperative kill));
   197 
   198 end;
   199 
   200 end;