src/HOL/HOL.thy
author wenzelm
Tue Jun 10 19:15:19 2008 +0200 (2008-06-10)
changeset 27126 3ede9103de8e
parent 27107 4a7415c67063
child 27212 3a3686dd4433
permissions -rw-r--r--
eliminated obsolete case_split_thm -- use case_split;
added case_split_tac (works without context);
setup for induct_tacs.ML;
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports Pure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/atomize_elim.ML"
    27   "~~/src/Tools/induct.ML"
    28   ("~~/src/HOL/Tools/induct_tacs.ML")
    29   "~~/src/Tools/code/code_name.ML"
    30   "~~/src/Tools/code/code_funcgr.ML"
    31   "~~/src/Tools/code/code_thingol.ML"
    32   "~~/src/Tools/code/code_target.ML"
    33   "~~/src/Tools/nbe.ML"
    34 begin
    35 
    36 subsection {* Primitive logic *}
    37 
    38 subsubsection {* Core syntax *}
    39 
    40 classes type
    41 defaultsort type
    42 setup {* ObjectLogic.add_base_sort @{sort type} *}
    43 
    44 arities
    45   "fun" :: (type, type) type
    46   itself :: (type) type
    47 
    48 global
    49 
    50 typedecl bool
    51 
    52 judgment
    53   Trueprop      :: "bool => prop"                   ("(_)" 5)
    54 
    55 consts
    56   Not           :: "bool => bool"                   ("~ _" [40] 40)
    57   True          :: bool
    58   False         :: bool
    59   arbitrary     :: 'a
    60 
    61   The           :: "('a => bool) => 'a"
    62   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    63   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    64   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    65   Let           :: "['a, 'a => 'b] => 'b"
    66 
    67   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    68   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    69   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    70   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    71 
    72 local
    73 
    74 consts
    75   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    76 
    77 
    78 subsubsection {* Additional concrete syntax *}
    79 
    80 notation (output)
    81   "op ="  (infix "=" 50)
    82 
    83 abbreviation
    84   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    85   "x ~= y == ~ (x = y)"
    86 
    87 notation (output)
    88   not_equal  (infix "~=" 50)
    89 
    90 notation (xsymbols)
    91   Not  ("\<not> _" [40] 40) and
    92   "op &"  (infixr "\<and>" 35) and
    93   "op |"  (infixr "\<or>" 30) and
    94   "op -->"  (infixr "\<longrightarrow>" 25) and
    95   not_equal  (infix "\<noteq>" 50)
    96 
    97 notation (HTML output)
    98   Not  ("\<not> _" [40] 40) and
    99   "op &"  (infixr "\<and>" 35) and
   100   "op |"  (infixr "\<or>" 30) and
   101   not_equal  (infix "\<noteq>" 50)
   102 
   103 abbreviation (iff)
   104   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   105   "A <-> B == A = B"
   106 
   107 notation (xsymbols)
   108   iff  (infixr "\<longleftrightarrow>" 25)
   109 
   110 
   111 nonterminals
   112   letbinds  letbind
   113   case_syn  cases_syn
   114 
   115 syntax
   116   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   117 
   118   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   119   ""            :: "letbind => letbinds"                 ("_")
   120   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   121   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   122 
   123   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   124   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   125   ""            :: "case_syn => cases_syn"               ("_")
   126   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   127 
   128 translations
   129   "THE x. P"              == "The (%x. P)"
   130   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   131   "let x = a in e"        == "Let a (%x. e)"
   132 
   133 print_translation {*
   134 (* To avoid eta-contraction of body: *)
   135 [("The", fn [Abs abs] =>
   136      let val (x,t) = atomic_abs_tr' abs
   137      in Syntax.const "_The" $ x $ t end)]
   138 *}
   139 
   140 syntax (xsymbols)
   141   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   142 
   143 notation (xsymbols)
   144   All  (binder "\<forall>" 10) and
   145   Ex  (binder "\<exists>" 10) and
   146   Ex1  (binder "\<exists>!" 10)
   147 
   148 notation (HTML output)
   149   All  (binder "\<forall>" 10) and
   150   Ex  (binder "\<exists>" 10) and
   151   Ex1  (binder "\<exists>!" 10)
   152 
   153 notation (HOL)
   154   All  (binder "! " 10) and
   155   Ex  (binder "? " 10) and
   156   Ex1  (binder "?! " 10)
   157 
   158 
   159 subsubsection {* Axioms and basic definitions *}
   160 
   161 axioms
   162   eq_reflection:  "(x=y) ==> (x==y)"
   163 
   164   refl:           "t = (t::'a)"
   165 
   166   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   167     -- {*Extensionality is built into the meta-logic, and this rule expresses
   168          a related property.  It is an eta-expanded version of the traditional
   169          rule, and similar to the ABS rule of HOL*}
   170 
   171   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   172 
   173   impI:           "(P ==> Q) ==> P-->Q"
   174   mp:             "[| P-->Q;  P |] ==> Q"
   175 
   176 
   177 defs
   178   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   179   All_def:      "All(P)    == (P = (%x. True))"
   180   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   181   False_def:    "False     == (!P. P)"
   182   not_def:      "~ P       == P-->False"
   183   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   184   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   185   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   186 
   187 axioms
   188   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   189   True_or_False:  "(P=True) | (P=False)"
   190 
   191 defs
   192   Let_def:      "Let s f == f(s)"
   193   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   194 
   195 finalconsts
   196   "op ="
   197   "op -->"
   198   The
   199   arbitrary
   200 
   201 axiomatization
   202   undefined :: 'a
   203 
   204 axiomatization where
   205   undefined_fun: "undefined x = undefined"
   206 
   207 
   208 subsubsection {* Generic classes and algebraic operations *}
   209 
   210 class default = type +
   211   fixes default :: 'a
   212 
   213 class zero = type + 
   214   fixes zero :: 'a  ("0")
   215 
   216 class one = type +
   217   fixes one  :: 'a  ("1")
   218 
   219 hide (open) const zero one
   220 
   221 class plus = type +
   222   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   223 
   224 class minus = type +
   225   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   226 
   227 class uminus = type +
   228   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   229 
   230 class times = type +
   231   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   232 
   233 class inverse = type +
   234   fixes inverse :: "'a \<Rightarrow> 'a"
   235     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   236 
   237 class abs = type +
   238   fixes abs :: "'a \<Rightarrow> 'a"
   239 begin
   240 
   241 notation (xsymbols)
   242   abs  ("\<bar>_\<bar>")
   243 
   244 notation (HTML output)
   245   abs  ("\<bar>_\<bar>")
   246 
   247 end
   248 
   249 class sgn = type +
   250   fixes sgn :: "'a \<Rightarrow> 'a"
   251 
   252 class ord = type +
   253   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   254     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   255 begin
   256 
   257 notation
   258   less_eq  ("op <=") and
   259   less_eq  ("(_/ <= _)" [51, 51] 50) and
   260   less  ("op <") and
   261   less  ("(_/ < _)"  [51, 51] 50)
   262   
   263 notation (xsymbols)
   264   less_eq  ("op \<le>") and
   265   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   266 
   267 notation (HTML output)
   268   less_eq  ("op \<le>") and
   269   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   270 
   271 abbreviation (input)
   272   greater_eq  (infix ">=" 50) where
   273   "x >= y \<equiv> y <= x"
   274 
   275 notation (input)
   276   greater_eq  (infix "\<ge>" 50)
   277 
   278 abbreviation (input)
   279   greater  (infix ">" 50) where
   280   "x > y \<equiv> y < x"
   281 
   282 end
   283 
   284 syntax
   285   "_index1"  :: index    ("\<^sub>1")
   286 translations
   287   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   288 
   289 typed_print_translation {*
   290 let
   291   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   292     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   293     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   294 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   295 *} -- {* show types that are presumably too general *}
   296 
   297 
   298 subsection {* Fundamental rules *}
   299 
   300 subsubsection {* Equality *}
   301 
   302 text {* Thanks to Stephan Merz *}
   303 lemma subst:
   304   assumes eq: "s = t" and p: "P s"
   305   shows "P t"
   306 proof -
   307   from eq have meta: "s \<equiv> t"
   308     by (rule eq_reflection)
   309   from p show ?thesis
   310     by (unfold meta)
   311 qed
   312 
   313 lemma sym: "s = t ==> t = s"
   314   by (erule subst) (rule refl)
   315 
   316 lemma ssubst: "t = s ==> P s ==> P t"
   317   by (drule sym) (erule subst)
   318 
   319 lemma trans: "[| r=s; s=t |] ==> r=t"
   320   by (erule subst)
   321 
   322 lemma meta_eq_to_obj_eq: 
   323   assumes meq: "A == B"
   324   shows "A = B"
   325   by (unfold meq) (rule refl)
   326 
   327 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   328      (* a = b
   329         |   |
   330         c = d   *)
   331 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   332 apply (rule trans)
   333 apply (rule trans)
   334 apply (rule sym)
   335 apply assumption+
   336 done
   337 
   338 text {* For calculational reasoning: *}
   339 
   340 lemma forw_subst: "a = b ==> P b ==> P a"
   341   by (rule ssubst)
   342 
   343 lemma back_subst: "P a ==> a = b ==> P b"
   344   by (rule subst)
   345 
   346 
   347 subsubsection {*Congruence rules for application*}
   348 
   349 (*similar to AP_THM in Gordon's HOL*)
   350 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   351 apply (erule subst)
   352 apply (rule refl)
   353 done
   354 
   355 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   356 lemma arg_cong: "x=y ==> f(x)=f(y)"
   357 apply (erule subst)
   358 apply (rule refl)
   359 done
   360 
   361 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   362 apply (erule ssubst)+
   363 apply (rule refl)
   364 done
   365 
   366 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   367 apply (erule subst)+
   368 apply (rule refl)
   369 done
   370 
   371 
   372 subsubsection {*Equality of booleans -- iff*}
   373 
   374 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   375   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   376 
   377 lemma iffD2: "[| P=Q; Q |] ==> P"
   378   by (erule ssubst)
   379 
   380 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   381   by (erule iffD2)
   382 
   383 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   384   by (drule sym) (rule iffD2)
   385 
   386 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   387   by (drule sym) (rule rev_iffD2)
   388 
   389 lemma iffE:
   390   assumes major: "P=Q"
   391     and minor: "[| P --> Q; Q --> P |] ==> R"
   392   shows R
   393   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   394 
   395 
   396 subsubsection {*True*}
   397 
   398 lemma TrueI: "True"
   399   unfolding True_def by (rule refl)
   400 
   401 lemma eqTrueI: "P ==> P = True"
   402   by (iprover intro: iffI TrueI)
   403 
   404 lemma eqTrueE: "P = True ==> P"
   405   by (erule iffD2) (rule TrueI)
   406 
   407 
   408 subsubsection {*Universal quantifier*}
   409 
   410 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   411   unfolding All_def by (iprover intro: ext eqTrueI assms)
   412 
   413 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   414 apply (unfold All_def)
   415 apply (rule eqTrueE)
   416 apply (erule fun_cong)
   417 done
   418 
   419 lemma allE:
   420   assumes major: "ALL x. P(x)"
   421     and minor: "P(x) ==> R"
   422   shows R
   423   by (iprover intro: minor major [THEN spec])
   424 
   425 lemma all_dupE:
   426   assumes major: "ALL x. P(x)"
   427     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   428   shows R
   429   by (iprover intro: minor major major [THEN spec])
   430 
   431 
   432 subsubsection {* False *}
   433 
   434 text {*
   435   Depends upon @{text spec}; it is impossible to do propositional
   436   logic before quantifiers!
   437 *}
   438 
   439 lemma FalseE: "False ==> P"
   440   apply (unfold False_def)
   441   apply (erule spec)
   442   done
   443 
   444 lemma False_neq_True: "False = True ==> P"
   445   by (erule eqTrueE [THEN FalseE])
   446 
   447 
   448 subsubsection {* Negation *}
   449 
   450 lemma notI:
   451   assumes "P ==> False"
   452   shows "~P"
   453   apply (unfold not_def)
   454   apply (iprover intro: impI assms)
   455   done
   456 
   457 lemma False_not_True: "False ~= True"
   458   apply (rule notI)
   459   apply (erule False_neq_True)
   460   done
   461 
   462 lemma True_not_False: "True ~= False"
   463   apply (rule notI)
   464   apply (drule sym)
   465   apply (erule False_neq_True)
   466   done
   467 
   468 lemma notE: "[| ~P;  P |] ==> R"
   469   apply (unfold not_def)
   470   apply (erule mp [THEN FalseE])
   471   apply assumption
   472   done
   473 
   474 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   475   by (erule notE [THEN notI]) (erule meta_mp)
   476 
   477 
   478 subsubsection {*Implication*}
   479 
   480 lemma impE:
   481   assumes "P-->Q" "P" "Q ==> R"
   482   shows "R"
   483 by (iprover intro: assms mp)
   484 
   485 (* Reduces Q to P-->Q, allowing substitution in P. *)
   486 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   487 by (iprover intro: mp)
   488 
   489 lemma contrapos_nn:
   490   assumes major: "~Q"
   491       and minor: "P==>Q"
   492   shows "~P"
   493 by (iprover intro: notI minor major [THEN notE])
   494 
   495 (*not used at all, but we already have the other 3 combinations *)
   496 lemma contrapos_pn:
   497   assumes major: "Q"
   498       and minor: "P ==> ~Q"
   499   shows "~P"
   500 by (iprover intro: notI minor major notE)
   501 
   502 lemma not_sym: "t ~= s ==> s ~= t"
   503   by (erule contrapos_nn) (erule sym)
   504 
   505 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   506   by (erule subst, erule ssubst, assumption)
   507 
   508 (*still used in HOLCF*)
   509 lemma rev_contrapos:
   510   assumes pq: "P ==> Q"
   511       and nq: "~Q"
   512   shows "~P"
   513 apply (rule nq [THEN contrapos_nn])
   514 apply (erule pq)
   515 done
   516 
   517 subsubsection {*Existential quantifier*}
   518 
   519 lemma exI: "P x ==> EX x::'a. P x"
   520 apply (unfold Ex_def)
   521 apply (iprover intro: allI allE impI mp)
   522 done
   523 
   524 lemma exE:
   525   assumes major: "EX x::'a. P(x)"
   526       and minor: "!!x. P(x) ==> Q"
   527   shows "Q"
   528 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   529 apply (iprover intro: impI [THEN allI] minor)
   530 done
   531 
   532 
   533 subsubsection {*Conjunction*}
   534 
   535 lemma conjI: "[| P; Q |] ==> P&Q"
   536 apply (unfold and_def)
   537 apply (iprover intro: impI [THEN allI] mp)
   538 done
   539 
   540 lemma conjunct1: "[| P & Q |] ==> P"
   541 apply (unfold and_def)
   542 apply (iprover intro: impI dest: spec mp)
   543 done
   544 
   545 lemma conjunct2: "[| P & Q |] ==> Q"
   546 apply (unfold and_def)
   547 apply (iprover intro: impI dest: spec mp)
   548 done
   549 
   550 lemma conjE:
   551   assumes major: "P&Q"
   552       and minor: "[| P; Q |] ==> R"
   553   shows "R"
   554 apply (rule minor)
   555 apply (rule major [THEN conjunct1])
   556 apply (rule major [THEN conjunct2])
   557 done
   558 
   559 lemma context_conjI:
   560   assumes "P" "P ==> Q" shows "P & Q"
   561 by (iprover intro: conjI assms)
   562 
   563 
   564 subsubsection {*Disjunction*}
   565 
   566 lemma disjI1: "P ==> P|Q"
   567 apply (unfold or_def)
   568 apply (iprover intro: allI impI mp)
   569 done
   570 
   571 lemma disjI2: "Q ==> P|Q"
   572 apply (unfold or_def)
   573 apply (iprover intro: allI impI mp)
   574 done
   575 
   576 lemma disjE:
   577   assumes major: "P|Q"
   578       and minorP: "P ==> R"
   579       and minorQ: "Q ==> R"
   580   shows "R"
   581 by (iprover intro: minorP minorQ impI
   582                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   583 
   584 
   585 subsubsection {*Classical logic*}
   586 
   587 lemma classical:
   588   assumes prem: "~P ==> P"
   589   shows "P"
   590 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   591 apply assumption
   592 apply (rule notI [THEN prem, THEN eqTrueI])
   593 apply (erule subst)
   594 apply assumption
   595 done
   596 
   597 lemmas ccontr = FalseE [THEN classical, standard]
   598 
   599 (*notE with premises exchanged; it discharges ~R so that it can be used to
   600   make elimination rules*)
   601 lemma rev_notE:
   602   assumes premp: "P"
   603       and premnot: "~R ==> ~P"
   604   shows "R"
   605 apply (rule ccontr)
   606 apply (erule notE [OF premnot premp])
   607 done
   608 
   609 (*Double negation law*)
   610 lemma notnotD: "~~P ==> P"
   611 apply (rule classical)
   612 apply (erule notE)
   613 apply assumption
   614 done
   615 
   616 lemma contrapos_pp:
   617   assumes p1: "Q"
   618       and p2: "~P ==> ~Q"
   619   shows "P"
   620 by (iprover intro: classical p1 p2 notE)
   621 
   622 
   623 subsubsection {*Unique existence*}
   624 
   625 lemma ex1I:
   626   assumes "P a" "!!x. P(x) ==> x=a"
   627   shows "EX! x. P(x)"
   628 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   629 
   630 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   631 lemma ex_ex1I:
   632   assumes ex_prem: "EX x. P(x)"
   633       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   634   shows "EX! x. P(x)"
   635 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   636 
   637 lemma ex1E:
   638   assumes major: "EX! x. P(x)"
   639       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   640   shows "R"
   641 apply (rule major [unfolded Ex1_def, THEN exE])
   642 apply (erule conjE)
   643 apply (iprover intro: minor)
   644 done
   645 
   646 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   647 apply (erule ex1E)
   648 apply (rule exI)
   649 apply assumption
   650 done
   651 
   652 
   653 subsubsection {*THE: definite description operator*}
   654 
   655 lemma the_equality:
   656   assumes prema: "P a"
   657       and premx: "!!x. P x ==> x=a"
   658   shows "(THE x. P x) = a"
   659 apply (rule trans [OF _ the_eq_trivial])
   660 apply (rule_tac f = "The" in arg_cong)
   661 apply (rule ext)
   662 apply (rule iffI)
   663  apply (erule premx)
   664 apply (erule ssubst, rule prema)
   665 done
   666 
   667 lemma theI:
   668   assumes "P a" and "!!x. P x ==> x=a"
   669   shows "P (THE x. P x)"
   670 by (iprover intro: assms the_equality [THEN ssubst])
   671 
   672 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   673 apply (erule ex1E)
   674 apply (erule theI)
   675 apply (erule allE)
   676 apply (erule mp)
   677 apply assumption
   678 done
   679 
   680 (*Easier to apply than theI: only one occurrence of P*)
   681 lemma theI2:
   682   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   683   shows "Q (THE x. P x)"
   684 by (iprover intro: assms theI)
   685 
   686 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   687 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   688            elim:allE impE)
   689 
   690 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   691 apply (rule the_equality)
   692 apply  assumption
   693 apply (erule ex1E)
   694 apply (erule all_dupE)
   695 apply (drule mp)
   696 apply  assumption
   697 apply (erule ssubst)
   698 apply (erule allE)
   699 apply (erule mp)
   700 apply assumption
   701 done
   702 
   703 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   704 apply (rule the_equality)
   705 apply (rule refl)
   706 apply (erule sym)
   707 done
   708 
   709 
   710 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   711 
   712 lemma disjCI:
   713   assumes "~Q ==> P" shows "P|Q"
   714 apply (rule classical)
   715 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   716 done
   717 
   718 lemma excluded_middle: "~P | P"
   719 by (iprover intro: disjCI)
   720 
   721 text {*
   722   case distinction as a natural deduction rule.
   723   Note that @{term "~P"} is the second case, not the first
   724 *}
   725 lemma case_split [case_names True False]:
   726   assumes prem1: "P ==> Q"
   727       and prem2: "~P ==> Q"
   728   shows "Q"
   729 apply (rule excluded_middle [THEN disjE])
   730 apply (erule prem2)
   731 apply (erule prem1)
   732 done
   733 
   734 ML {*
   735   fun case_split_tac P = res_inst_tac [("P", P)] @{thm case_split}
   736 *}
   737 
   738 (*Classical implies (-->) elimination. *)
   739 lemma impCE:
   740   assumes major: "P-->Q"
   741       and minor: "~P ==> R" "Q ==> R"
   742   shows "R"
   743 apply (rule excluded_middle [of P, THEN disjE])
   744 apply (iprover intro: minor major [THEN mp])+
   745 done
   746 
   747 (*This version of --> elimination works on Q before P.  It works best for
   748   those cases in which P holds "almost everywhere".  Can't install as
   749   default: would break old proofs.*)
   750 lemma impCE':
   751   assumes major: "P-->Q"
   752       and minor: "Q ==> R" "~P ==> R"
   753   shows "R"
   754 apply (rule excluded_middle [of P, THEN disjE])
   755 apply (iprover intro: minor major [THEN mp])+
   756 done
   757 
   758 (*Classical <-> elimination. *)
   759 lemma iffCE:
   760   assumes major: "P=Q"
   761       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   762   shows "R"
   763 apply (rule major [THEN iffE])
   764 apply (iprover intro: minor elim: impCE notE)
   765 done
   766 
   767 lemma exCI:
   768   assumes "ALL x. ~P(x) ==> P(a)"
   769   shows "EX x. P(x)"
   770 apply (rule ccontr)
   771 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   772 done
   773 
   774 
   775 subsubsection {* Intuitionistic Reasoning *}
   776 
   777 lemma impE':
   778   assumes 1: "P --> Q"
   779     and 2: "Q ==> R"
   780     and 3: "P --> Q ==> P"
   781   shows R
   782 proof -
   783   from 3 and 1 have P .
   784   with 1 have Q by (rule impE)
   785   with 2 show R .
   786 qed
   787 
   788 lemma allE':
   789   assumes 1: "ALL x. P x"
   790     and 2: "P x ==> ALL x. P x ==> Q"
   791   shows Q
   792 proof -
   793   from 1 have "P x" by (rule spec)
   794   from this and 1 show Q by (rule 2)
   795 qed
   796 
   797 lemma notE':
   798   assumes 1: "~ P"
   799     and 2: "~ P ==> P"
   800   shows R
   801 proof -
   802   from 2 and 1 have P .
   803   with 1 show R by (rule notE)
   804 qed
   805 
   806 lemma TrueE: "True ==> P ==> P" .
   807 lemma notFalseE: "~ False ==> P ==> P" .
   808 
   809 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   810   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   811   and [Pure.elim 2] = allE notE' impE'
   812   and [Pure.intro] = exI disjI2 disjI1
   813 
   814 lemmas [trans] = trans
   815   and [sym] = sym not_sym
   816   and [Pure.elim?] = iffD1 iffD2 impE
   817 
   818 use "hologic.ML"
   819 
   820 
   821 subsubsection {* Atomizing meta-level connectives *}
   822 
   823 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   824 proof
   825   assume "!!x. P x"
   826   then show "ALL x. P x" ..
   827 next
   828   assume "ALL x. P x"
   829   then show "!!x. P x" by (rule allE)
   830 qed
   831 
   832 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   833 proof
   834   assume r: "A ==> B"
   835   show "A --> B" by (rule impI) (rule r)
   836 next
   837   assume "A --> B" and A
   838   then show B by (rule mp)
   839 qed
   840 
   841 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   842 proof
   843   assume r: "A ==> False"
   844   show "~A" by (rule notI) (rule r)
   845 next
   846   assume "~A" and A
   847   then show False by (rule notE)
   848 qed
   849 
   850 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   851 proof
   852   assume "x == y"
   853   show "x = y" by (unfold `x == y`) (rule refl)
   854 next
   855   assume "x = y"
   856   then show "x == y" by (rule eq_reflection)
   857 qed
   858 
   859 lemma atomize_conj [atomize]:
   860   includes meta_conjunction_syntax
   861   shows "(A && B) == Trueprop (A & B)"
   862 proof
   863   assume conj: "A && B"
   864   show "A & B"
   865   proof (rule conjI)
   866     from conj show A by (rule conjunctionD1)
   867     from conj show B by (rule conjunctionD2)
   868   qed
   869 next
   870   assume conj: "A & B"
   871   show "A && B"
   872   proof -
   873     from conj show A ..
   874     from conj show B ..
   875   qed
   876 qed
   877 
   878 lemmas [symmetric, rulify] = atomize_all atomize_imp
   879   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   880 
   881 
   882 subsubsection {* Atomizing elimination rules *}
   883 
   884 setup AtomizeElim.setup
   885 
   886 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   887   by rule iprover+
   888 
   889 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   890   by rule iprover+
   891 
   892 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   893   by rule iprover+
   894 
   895 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   896 
   897 
   898 subsection {* Package setup *}
   899 
   900 subsubsection {* Classical Reasoner setup *}
   901 
   902 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   903   by (rule classical) iprover
   904 
   905 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   906   by (rule classical) iprover
   907 
   908 lemma thin_refl:
   909   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   910 
   911 ML {*
   912 structure Hypsubst = HypsubstFun(
   913 struct
   914   structure Simplifier = Simplifier
   915   val dest_eq = HOLogic.dest_eq
   916   val dest_Trueprop = HOLogic.dest_Trueprop
   917   val dest_imp = HOLogic.dest_imp
   918   val eq_reflection = @{thm eq_reflection}
   919   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   920   val imp_intr = @{thm impI}
   921   val rev_mp = @{thm rev_mp}
   922   val subst = @{thm subst}
   923   val sym = @{thm sym}
   924   val thin_refl = @{thm thin_refl};
   925 end);
   926 open Hypsubst;
   927 
   928 structure Classical = ClassicalFun(
   929 struct
   930   val imp_elim = @{thm imp_elim}
   931   val not_elim = @{thm notE}
   932   val swap = @{thm swap}
   933   val classical = @{thm classical}
   934   val sizef = Drule.size_of_thm
   935   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   936 end);
   937 
   938 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   939 open BasicClassical;
   940 
   941 ML_Context.value_antiq "claset"
   942   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   943 
   944 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   945 
   946 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   947 *}
   948 
   949 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   950   These theorems typically produce clauses that are prolific (match too many equality or
   951   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   952 
   953 setup {*
   954 let
   955   (*prevent substitution on bool*)
   956   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   957     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   958       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   959 in
   960   Hypsubst.hypsubst_setup
   961   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   962   #> Classical.setup
   963   #> ResAtpset.setup
   964   #> ResBlacklist.setup
   965 end
   966 *}
   967 
   968 declare iffI [intro!]
   969   and notI [intro!]
   970   and impI [intro!]
   971   and disjCI [intro!]
   972   and conjI [intro!]
   973   and TrueI [intro!]
   974   and refl [intro!]
   975 
   976 declare iffCE [elim!]
   977   and FalseE [elim!]
   978   and impCE [elim!]
   979   and disjE [elim!]
   980   and conjE [elim!]
   981   and conjE [elim!]
   982 
   983 declare ex_ex1I [intro!]
   984   and allI [intro!]
   985   and the_equality [intro]
   986   and exI [intro]
   987 
   988 declare exE [elim!]
   989   allE [elim]
   990 
   991 ML {* val HOL_cs = @{claset} *}
   992 
   993 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   994   apply (erule swap)
   995   apply (erule (1) meta_mp)
   996   done
   997 
   998 declare ex_ex1I [rule del, intro! 2]
   999   and ex1I [intro]
  1000 
  1001 lemmas [intro?] = ext
  1002   and [elim?] = ex1_implies_ex
  1003 
  1004 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
  1005 lemma alt_ex1E [elim!]:
  1006   assumes major: "\<exists>!x. P x"
  1007       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
  1008   shows R
  1009 apply (rule ex1E [OF major])
  1010 apply (rule prem)
  1011 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1012 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1013 apply iprover
  1014 done
  1015 
  1016 ML {*
  1017 structure Blast = BlastFun
  1018 (
  1019   type claset = Classical.claset
  1020   val equality_name = @{const_name "op ="}
  1021   val not_name = @{const_name Not}
  1022   val notE = @{thm notE}
  1023   val ccontr = @{thm ccontr}
  1024   val contr_tac = Classical.contr_tac
  1025   val dup_intr = Classical.dup_intr
  1026   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1027   val claset = Classical.claset
  1028   val rep_cs = Classical.rep_cs
  1029   val cla_modifiers = Classical.cla_modifiers
  1030   val cla_meth' = Classical.cla_meth'
  1031 );
  1032 val Blast_tac = Blast.Blast_tac;
  1033 val blast_tac = Blast.blast_tac;
  1034 *}
  1035 
  1036 setup Blast.setup
  1037 
  1038 
  1039 subsubsection {* Simplifier *}
  1040 
  1041 lemma eta_contract_eq: "(%s. f s) = f" ..
  1042 
  1043 lemma simp_thms:
  1044   shows not_not: "(~ ~ P) = P"
  1045   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1046   and
  1047     "(P ~= Q) = (P = (~Q))"
  1048     "(P | ~P) = True"    "(~P | P) = True"
  1049     "(x = x) = True"
  1050   and not_True_eq_False: "(\<not> True) = False"
  1051   and not_False_eq_True: "(\<not> False) = True"
  1052   and
  1053     "(~P) ~= P"  "P ~= (~P)"
  1054     "(True=P) = P"
  1055   and eq_True: "(P = True) = P"
  1056   and "(False=P) = (~P)"
  1057   and eq_False: "(P = False) = (\<not> P)"
  1058   and
  1059     "(True --> P) = P"  "(False --> P) = True"
  1060     "(P --> True) = True"  "(P --> P) = True"
  1061     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1062     "(P & True) = P"  "(True & P) = P"
  1063     "(P & False) = False"  "(False & P) = False"
  1064     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1065     "(P & ~P) = False"    "(~P & P) = False"
  1066     "(P | True) = True"  "(True | P) = True"
  1067     "(P | False) = P"  "(False | P) = P"
  1068     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1069     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1070     -- {* needed for the one-point-rule quantifier simplification procs *}
  1071     -- {* essential for termination!! *} and
  1072     "!!P. (EX x. x=t & P(x)) = P(t)"
  1073     "!!P. (EX x. t=x & P(x)) = P(t)"
  1074     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1075     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1076   by (blast, blast, blast, blast, blast, iprover+)
  1077 
  1078 lemma disj_absorb: "(A | A) = A"
  1079   by blast
  1080 
  1081 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1082   by blast
  1083 
  1084 lemma conj_absorb: "(A & A) = A"
  1085   by blast
  1086 
  1087 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1088   by blast
  1089 
  1090 lemma eq_ac:
  1091   shows eq_commute: "(a=b) = (b=a)"
  1092     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1093     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1094 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1095 
  1096 lemma conj_comms:
  1097   shows conj_commute: "(P&Q) = (Q&P)"
  1098     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1099 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1100 
  1101 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1102 
  1103 lemma disj_comms:
  1104   shows disj_commute: "(P|Q) = (Q|P)"
  1105     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1106 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1107 
  1108 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1109 
  1110 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1111 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1112 
  1113 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1114 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1115 
  1116 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1117 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1118 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1119 
  1120 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1121 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1122 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1123 
  1124 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1125 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1126 
  1127 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1128   by iprover
  1129 
  1130 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1131 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1132 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1133 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1134 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1135 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1136   by blast
  1137 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1138 
  1139 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1140 
  1141 
  1142 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1143   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1144   -- {* cases boil down to the same thing. *}
  1145   by blast
  1146 
  1147 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1148 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1149 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1150 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1151 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1152 
  1153 declare All_def [noatp]
  1154 
  1155 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1156 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1157 
  1158 text {*
  1159   \medskip The @{text "&"} congruence rule: not included by default!
  1160   May slow rewrite proofs down by as much as 50\% *}
  1161 
  1162 lemma conj_cong:
  1163     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1164   by iprover
  1165 
  1166 lemma rev_conj_cong:
  1167     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1168   by iprover
  1169 
  1170 text {* The @{text "|"} congruence rule: not included by default! *}
  1171 
  1172 lemma disj_cong:
  1173     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1174   by blast
  1175 
  1176 
  1177 text {* \medskip if-then-else rules *}
  1178 
  1179 lemma if_True: "(if True then x else y) = x"
  1180   by (unfold if_def) blast
  1181 
  1182 lemma if_False: "(if False then x else y) = y"
  1183   by (unfold if_def) blast
  1184 
  1185 lemma if_P: "P ==> (if P then x else y) = x"
  1186   by (unfold if_def) blast
  1187 
  1188 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1189   by (unfold if_def) blast
  1190 
  1191 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1192   apply (rule case_split [of Q])
  1193    apply (simplesubst if_P)
  1194     prefer 3 apply (simplesubst if_not_P, blast+)
  1195   done
  1196 
  1197 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1198 by (simplesubst split_if, blast)
  1199 
  1200 lemmas if_splits [noatp] = split_if split_if_asm
  1201 
  1202 lemma if_cancel: "(if c then x else x) = x"
  1203 by (simplesubst split_if, blast)
  1204 
  1205 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1206 by (simplesubst split_if, blast)
  1207 
  1208 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1209   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1210   by (rule split_if)
  1211 
  1212 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1213   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1214   apply (simplesubst split_if, blast)
  1215   done
  1216 
  1217 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1218 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1219 
  1220 text {* \medskip let rules for simproc *}
  1221 
  1222 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1223   by (unfold Let_def)
  1224 
  1225 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1226   by (unfold Let_def)
  1227 
  1228 text {*
  1229   The following copy of the implication operator is useful for
  1230   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1231   its premise.
  1232 *}
  1233 
  1234 constdefs
  1235   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1236   [code func del]: "simp_implies \<equiv> op ==>"
  1237 
  1238 lemma simp_impliesI:
  1239   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1240   shows "PROP P =simp=> PROP Q"
  1241   apply (unfold simp_implies_def)
  1242   apply (rule PQ)
  1243   apply assumption
  1244   done
  1245 
  1246 lemma simp_impliesE:
  1247   assumes PQ: "PROP P =simp=> PROP Q"
  1248   and P: "PROP P"
  1249   and QR: "PROP Q \<Longrightarrow> PROP R"
  1250   shows "PROP R"
  1251   apply (rule QR)
  1252   apply (rule PQ [unfolded simp_implies_def])
  1253   apply (rule P)
  1254   done
  1255 
  1256 lemma simp_implies_cong:
  1257   assumes PP' :"PROP P == PROP P'"
  1258   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1259   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1260 proof (unfold simp_implies_def, rule equal_intr_rule)
  1261   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1262   and P': "PROP P'"
  1263   from PP' [symmetric] and P' have "PROP P"
  1264     by (rule equal_elim_rule1)
  1265   then have "PROP Q" by (rule PQ)
  1266   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1267 next
  1268   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1269   and P: "PROP P"
  1270   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1271   then have "PROP Q'" by (rule P'Q')
  1272   with P'QQ' [OF P', symmetric] show "PROP Q"
  1273     by (rule equal_elim_rule1)
  1274 qed
  1275 
  1276 lemma uncurry:
  1277   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1278   shows "P \<and> Q \<longrightarrow> R"
  1279   using assms by blast
  1280 
  1281 lemma iff_allI:
  1282   assumes "\<And>x. P x = Q x"
  1283   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1284   using assms by blast
  1285 
  1286 lemma iff_exI:
  1287   assumes "\<And>x. P x = Q x"
  1288   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1289   using assms by blast
  1290 
  1291 lemma all_comm:
  1292   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1293   by blast
  1294 
  1295 lemma ex_comm:
  1296   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1297   by blast
  1298 
  1299 use "simpdata.ML"
  1300 ML {* open Simpdata *}
  1301 
  1302 setup {*
  1303   Simplifier.method_setup Splitter.split_modifiers
  1304   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1305   #> Splitter.setup
  1306   #> clasimp_setup
  1307   #> EqSubst.setup
  1308 *}
  1309 
  1310 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1311 
  1312 simproc_setup neq ("x = y") = {* fn _ =>
  1313 let
  1314   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1315   fun is_neq eq lhs rhs thm =
  1316     (case Thm.prop_of thm of
  1317       _ $ (Not $ (eq' $ l' $ r')) =>
  1318         Not = HOLogic.Not andalso eq' = eq andalso
  1319         r' aconv lhs andalso l' aconv rhs
  1320     | _ => false);
  1321   fun proc ss ct =
  1322     (case Thm.term_of ct of
  1323       eq $ lhs $ rhs =>
  1324         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1325           SOME thm => SOME (thm RS neq_to_EQ_False)
  1326         | NONE => NONE)
  1327      | _ => NONE);
  1328 in proc end;
  1329 *}
  1330 
  1331 simproc_setup let_simp ("Let x f") = {*
  1332 let
  1333   val (f_Let_unfold, x_Let_unfold) =
  1334     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1335     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1336   val (f_Let_folded, x_Let_folded) =
  1337     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1338     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1339   val g_Let_folded =
  1340     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1341 
  1342   fun proc _ ss ct =
  1343     let
  1344       val ctxt = Simplifier.the_context ss;
  1345       val thy = ProofContext.theory_of ctxt;
  1346       val t = Thm.term_of ct;
  1347       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1348     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1349       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1350         if is_Free x orelse is_Bound x orelse is_Const x
  1351         then SOME @{thm Let_def}
  1352         else
  1353           let
  1354             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1355             val cx = cterm_of thy x;
  1356             val {T=xT,...} = rep_cterm cx;
  1357             val cf = cterm_of thy f;
  1358             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1359             val (_$_$g) = prop_of fx_g;
  1360             val g' = abstract_over (x,g);
  1361           in (if (g aconv g')
  1362                then
  1363                   let
  1364                     val rl =
  1365                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1366                   in SOME (rl OF [fx_g]) end
  1367                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1368                else let
  1369                      val abs_g'= Abs (n,xT,g');
  1370                      val g'x = abs_g'$x;
  1371                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1372                      val rl = cterm_instantiate
  1373                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1374                                 (g_Let_folded,cterm_of thy abs_g')]
  1375                                @{thm Let_folded};
  1376                    in SOME (rl OF [transitive fx_g g_g'x])
  1377                    end)
  1378           end
  1379       | _ => NONE)
  1380     end
  1381 in proc end *}
  1382 
  1383 
  1384 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1385 proof
  1386   assume "True \<Longrightarrow> PROP P"
  1387   from this [OF TrueI] show "PROP P" .
  1388 next
  1389   assume "PROP P"
  1390   then show "PROP P" .
  1391 qed
  1392 
  1393 lemma ex_simps:
  1394   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1395   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1396   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1397   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1398   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1399   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1400   -- {* Miniscoping: pushing in existential quantifiers. *}
  1401   by (iprover | blast)+
  1402 
  1403 lemma all_simps:
  1404   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1405   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1406   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1407   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1408   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1409   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1410   -- {* Miniscoping: pushing in universal quantifiers. *}
  1411   by (iprover | blast)+
  1412 
  1413 lemmas [simp] =
  1414   triv_forall_equality (*prunes params*)
  1415   True_implies_equals  (*prune asms `True'*)
  1416   if_True
  1417   if_False
  1418   if_cancel
  1419   if_eq_cancel
  1420   imp_disjL
  1421   (*In general it seems wrong to add distributive laws by default: they
  1422     might cause exponential blow-up.  But imp_disjL has been in for a while
  1423     and cannot be removed without affecting existing proofs.  Moreover,
  1424     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1425     grounds that it allows simplification of R in the two cases.*)
  1426   conj_assoc
  1427   disj_assoc
  1428   de_Morgan_conj
  1429   de_Morgan_disj
  1430   imp_disj1
  1431   imp_disj2
  1432   not_imp
  1433   disj_not1
  1434   not_all
  1435   not_ex
  1436   cases_simp
  1437   the_eq_trivial
  1438   the_sym_eq_trivial
  1439   ex_simps
  1440   all_simps
  1441   simp_thms
  1442 
  1443 lemmas [cong] = imp_cong simp_implies_cong
  1444 lemmas [split] = split_if
  1445 
  1446 ML {* val HOL_ss = @{simpset} *}
  1447 
  1448 text {* Simplifies x assuming c and y assuming ~c *}
  1449 lemma if_cong:
  1450   assumes "b = c"
  1451       and "c \<Longrightarrow> x = u"
  1452       and "\<not> c \<Longrightarrow> y = v"
  1453   shows "(if b then x else y) = (if c then u else v)"
  1454   unfolding if_def using assms by simp
  1455 
  1456 text {* Prevents simplification of x and y:
  1457   faster and allows the execution of functional programs. *}
  1458 lemma if_weak_cong [cong]:
  1459   assumes "b = c"
  1460   shows "(if b then x else y) = (if c then x else y)"
  1461   using assms by (rule arg_cong)
  1462 
  1463 text {* Prevents simplification of t: much faster *}
  1464 lemma let_weak_cong:
  1465   assumes "a = b"
  1466   shows "(let x = a in t x) = (let x = b in t x)"
  1467   using assms by (rule arg_cong)
  1468 
  1469 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1470 lemma eq_cong2:
  1471   assumes "u = u'"
  1472   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1473   using assms by simp
  1474 
  1475 lemma if_distrib:
  1476   "f (if c then x else y) = (if c then f x else f y)"
  1477   by simp
  1478 
  1479 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1480   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1481 lemma restrict_to_left:
  1482   assumes "x = y"
  1483   shows "(x = z) = (y = z)"
  1484   using assms by simp
  1485 
  1486 
  1487 subsubsection {* Generic cases and induction *}
  1488 
  1489 text {* Rule projections: *}
  1490 
  1491 ML {*
  1492 structure ProjectRule = ProjectRuleFun
  1493 (
  1494   val conjunct1 = @{thm conjunct1}
  1495   val conjunct2 = @{thm conjunct2}
  1496   val mp = @{thm mp}
  1497 )
  1498 *}
  1499 
  1500 constdefs
  1501   induct_forall where "induct_forall P == \<forall>x. P x"
  1502   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1503   induct_equal where "induct_equal x y == x = y"
  1504   induct_conj where "induct_conj A B == A \<and> B"
  1505 
  1506 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1507   by (unfold atomize_all induct_forall_def)
  1508 
  1509 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1510   by (unfold atomize_imp induct_implies_def)
  1511 
  1512 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1513   by (unfold atomize_eq induct_equal_def)
  1514 
  1515 lemma induct_conj_eq:
  1516   includes meta_conjunction_syntax
  1517   shows "(A && B) == Trueprop (induct_conj A B)"
  1518   by (unfold atomize_conj induct_conj_def)
  1519 
  1520 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1521 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1522 lemmas induct_rulify_fallback =
  1523   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1524 
  1525 
  1526 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1527     induct_conj (induct_forall A) (induct_forall B)"
  1528   by (unfold induct_forall_def induct_conj_def) iprover
  1529 
  1530 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1531     induct_conj (induct_implies C A) (induct_implies C B)"
  1532   by (unfold induct_implies_def induct_conj_def) iprover
  1533 
  1534 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1535 proof
  1536   assume r: "induct_conj A B ==> PROP C" and A B
  1537   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1538 next
  1539   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1540   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1541 qed
  1542 
  1543 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1544 
  1545 hide const induct_forall induct_implies induct_equal induct_conj
  1546 
  1547 text {* Method setup. *}
  1548 
  1549 ML {*
  1550 structure Induct = InductFun
  1551 (
  1552   val cases_default = @{thm case_split}
  1553   val atomize = @{thms induct_atomize}
  1554   val rulify = @{thms induct_rulify}
  1555   val rulify_fallback = @{thms induct_rulify_fallback}
  1556 )
  1557 *}
  1558 
  1559 setup Induct.setup
  1560 
  1561 use "~~/src/HOL/Tools/induct_tacs.ML"
  1562 setup InductTacs.setup
  1563 
  1564 
  1565 subsection {* Other simple lemmas and lemma duplicates *}
  1566 
  1567 lemma Let_0 [simp]: "Let 0 f = f 0"
  1568   unfolding Let_def ..
  1569 
  1570 lemma Let_1 [simp]: "Let 1 f = f 1"
  1571   unfolding Let_def ..
  1572 
  1573 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1574   by blast+
  1575 
  1576 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1577   apply (rule iffI)
  1578   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1579   apply (fast dest!: theI')
  1580   apply (fast intro: ext the1_equality [symmetric])
  1581   apply (erule ex1E)
  1582   apply (rule allI)
  1583   apply (rule ex1I)
  1584   apply (erule spec)
  1585   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1586   apply (erule impE)
  1587   apply (rule allI)
  1588   apply (case_tac "xa = x")
  1589   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1590   done
  1591 
  1592 lemma mk_left_commute:
  1593   fixes f (infix "\<otimes>" 60)
  1594   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1595           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1596   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1597   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1598 
  1599 lemmas eq_sym_conv = eq_commute
  1600 
  1601 lemma nnf_simps:
  1602   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1603   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1604   "(\<not> \<not>(P)) = P"
  1605 by blast+
  1606 
  1607 
  1608 subsection {* Basic ML bindings *}
  1609 
  1610 ML {*
  1611 val FalseE = @{thm FalseE}
  1612 val Let_def = @{thm Let_def}
  1613 val TrueI = @{thm TrueI}
  1614 val allE = @{thm allE}
  1615 val allI = @{thm allI}
  1616 val all_dupE = @{thm all_dupE}
  1617 val arg_cong = @{thm arg_cong}
  1618 val box_equals = @{thm box_equals}
  1619 val ccontr = @{thm ccontr}
  1620 val classical = @{thm classical}
  1621 val conjE = @{thm conjE}
  1622 val conjI = @{thm conjI}
  1623 val conjunct1 = @{thm conjunct1}
  1624 val conjunct2 = @{thm conjunct2}
  1625 val disjCI = @{thm disjCI}
  1626 val disjE = @{thm disjE}
  1627 val disjI1 = @{thm disjI1}
  1628 val disjI2 = @{thm disjI2}
  1629 val eq_reflection = @{thm eq_reflection}
  1630 val ex1E = @{thm ex1E}
  1631 val ex1I = @{thm ex1I}
  1632 val ex1_implies_ex = @{thm ex1_implies_ex}
  1633 val exE = @{thm exE}
  1634 val exI = @{thm exI}
  1635 val excluded_middle = @{thm excluded_middle}
  1636 val ext = @{thm ext}
  1637 val fun_cong = @{thm fun_cong}
  1638 val iffD1 = @{thm iffD1}
  1639 val iffD2 = @{thm iffD2}
  1640 val iffI = @{thm iffI}
  1641 val impE = @{thm impE}
  1642 val impI = @{thm impI}
  1643 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1644 val mp = @{thm mp}
  1645 val notE = @{thm notE}
  1646 val notI = @{thm notI}
  1647 val not_all = @{thm not_all}
  1648 val not_ex = @{thm not_ex}
  1649 val not_iff = @{thm not_iff}
  1650 val not_not = @{thm not_not}
  1651 val not_sym = @{thm not_sym}
  1652 val refl = @{thm refl}
  1653 val rev_mp = @{thm rev_mp}
  1654 val spec = @{thm spec}
  1655 val ssubst = @{thm ssubst}
  1656 val subst = @{thm subst}
  1657 val sym = @{thm sym}
  1658 val trans = @{thm trans}
  1659 *}
  1660 
  1661 
  1662 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1663 
  1664 code_datatype Trueprop "prop"
  1665 
  1666 code_datatype "TYPE('a\<Colon>{})"
  1667 
  1668 lemma Let_case_cert:
  1669   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1670   shows "CASE x \<equiv> f x"
  1671   using assms by simp_all
  1672 
  1673 lemma If_case_cert:
  1674   includes meta_conjunction_syntax
  1675   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1676   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1677   using assms by simp_all
  1678 
  1679 setup {*
  1680   Code.add_case @{thm Let_case_cert}
  1681   #> Code.add_case @{thm If_case_cert}
  1682   #> Code.add_undefined @{const_name undefined}
  1683 *}
  1684 
  1685 class eq = type +
  1686   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1687   assumes eq: "eq x y \<longleftrightarrow> x = y "
  1688 begin
  1689 
  1690 lemma equals_eq [code inline, code func]: "op = \<equiv> eq"
  1691   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq)
  1692 
  1693 declare equals_eq [symmetric, code post]
  1694 
  1695 end
  1696 
  1697 hide (open) const eq
  1698 hide const eq
  1699 
  1700 setup {*
  1701   CodeUnit.add_const_alias @{thm equals_eq}
  1702   #> CodeName.setup
  1703   #> CodeTarget.setup
  1704   #> Nbe.setup
  1705 *}
  1706 
  1707 lemma [code func]:
  1708   shows "False \<and> x \<longleftrightarrow> False"
  1709     and "True \<and> x \<longleftrightarrow> x"
  1710     and "x \<and> False \<longleftrightarrow> False"
  1711     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1712 
  1713 lemma [code func]:
  1714   shows "False \<or> x \<longleftrightarrow> x"
  1715     and "True \<or> x \<longleftrightarrow> True"
  1716     and "x \<or> False \<longleftrightarrow> x"
  1717     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1718 
  1719 lemma [code func]:
  1720   shows "\<not> True \<longleftrightarrow> False"
  1721     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1722 
  1723 
  1724 
  1725 subsection {* Legacy tactics and ML bindings *}
  1726 
  1727 ML {*
  1728 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1729 
  1730 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1731 local
  1732   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1733     | wrong_prem (Bound _) = true
  1734     | wrong_prem _ = false;
  1735   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1736 in
  1737   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1738   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1739 end;
  1740 
  1741 val all_conj_distrib = thm "all_conj_distrib";
  1742 val all_simps = thms "all_simps";
  1743 val atomize_not = thm "atomize_not";
  1744 val case_split = thm "case_split";
  1745 val cases_simp = thm "cases_simp";
  1746 val choice_eq = thm "choice_eq"
  1747 val cong = thm "cong"
  1748 val conj_comms = thms "conj_comms";
  1749 val conj_cong = thm "conj_cong";
  1750 val de_Morgan_conj = thm "de_Morgan_conj";
  1751 val de_Morgan_disj = thm "de_Morgan_disj";
  1752 val disj_assoc = thm "disj_assoc";
  1753 val disj_comms = thms "disj_comms";
  1754 val disj_cong = thm "disj_cong";
  1755 val eq_ac = thms "eq_ac";
  1756 val eq_cong2 = thm "eq_cong2"
  1757 val Eq_FalseI = thm "Eq_FalseI";
  1758 val Eq_TrueI = thm "Eq_TrueI";
  1759 val Ex1_def = thm "Ex1_def"
  1760 val ex_disj_distrib = thm "ex_disj_distrib";
  1761 val ex_simps = thms "ex_simps";
  1762 val if_cancel = thm "if_cancel";
  1763 val if_eq_cancel = thm "if_eq_cancel";
  1764 val if_False = thm "if_False";
  1765 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1766 val iff = thm "iff"
  1767 val if_splits = thms "if_splits";
  1768 val if_True = thm "if_True";
  1769 val if_weak_cong = thm "if_weak_cong"
  1770 val imp_all = thm "imp_all";
  1771 val imp_cong = thm "imp_cong";
  1772 val imp_conjL = thm "imp_conjL";
  1773 val imp_conjR = thm "imp_conjR";
  1774 val imp_conv_disj = thm "imp_conv_disj";
  1775 val simp_implies_def = thm "simp_implies_def";
  1776 val simp_thms = thms "simp_thms";
  1777 val split_if = thm "split_if";
  1778 val the1_equality = thm "the1_equality"
  1779 val theI = thm "theI"
  1780 val theI' = thm "theI'"
  1781 val True_implies_equals = thm "True_implies_equals";
  1782 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1783 
  1784 *}
  1785 
  1786 end