src/HOL/Product_Type.thy
author haftmann
Sat Jul 02 22:55:58 2011 +0200 (2011-07-02)
changeset 43654 3f1a44c2d645
parent 43595 7ae4a23b5be6
child 43866 8a50dc70cbff
permissions -rw-r--r--
install case certificate for If after code_datatype declaration for bool
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 lemma If_case_cert:
    32   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    33   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    34   using assms by simp_all
    35 
    36 setup {*
    37   Code.add_case @{thm If_case_cert}
    38 *}
    39 
    40 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    41   (Haskell infix 4 "==")
    42 
    43 code_instance bool :: equal
    44   (Haskell -)
    45 
    46 
    47 subsection {* The @{text unit} type *}
    48 
    49 typedef (open) unit = "{True}"
    50 proof
    51   show "True : ?unit" ..
    52 qed
    53 
    54 definition
    55   Unity :: unit    ("'(')")
    56 where
    57   "() = Abs_unit True"
    58 
    59 lemma unit_eq [no_atp]: "u = ()"
    60   by (induct u) (simp add: Unity_def)
    61 
    62 text {*
    63   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    64   this rule directly --- it loops!
    65 *}
    66 
    67 simproc_setup unit_eq ("x::unit") = {*
    68   fn _ => fn _ => fn ct =>
    69     if HOLogic.is_unit (term_of ct) then NONE
    70     else SOME (mk_meta_eq @{thm unit_eq})
    71 *}
    72 
    73 rep_datatype "()" by simp
    74 
    75 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    76   by simp
    77 
    78 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    79   by (rule triv_forall_equality)
    80 
    81 text {*
    82   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    83   [source] "%u::unit. f u"}, replacing it by @{term [source]
    84   f} rather than by @{term [source] "%u. f ()"}.
    85 *}
    86 
    87 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    88   by (rule ext) simp
    89 
    90 instantiation unit :: default
    91 begin
    92 
    93 definition "default = ()"
    94 
    95 instance ..
    96 
    97 end
    98 
    99 lemma [code]:
   100   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   101 
   102 code_type unit
   103   (SML "unit")
   104   (OCaml "unit")
   105   (Haskell "()")
   106   (Scala "Unit")
   107 
   108 code_const Unity
   109   (SML "()")
   110   (OCaml "()")
   111   (Haskell "()")
   112   (Scala "()")
   113 
   114 code_instance unit :: equal
   115   (Haskell -)
   116 
   117 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   118   (Haskell infix 4 "==")
   119 
   120 code_reserved SML
   121   unit
   122 
   123 code_reserved OCaml
   124   unit
   125 
   126 code_reserved Scala
   127   Unit
   128 
   129 
   130 subsection {* The product type *}
   131 
   132 subsubsection {* Type definition *}
   133 
   134 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   135   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   136 
   137 typedef ('a, 'b) prod (infixr "*" 20)
   138   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   139 proof
   140   fix a b show "Pair_Rep a b \<in> ?prod"
   141     by rule+
   142 qed
   143 
   144 type_notation (xsymbols)
   145   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   146 type_notation (HTML output)
   147   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   148 
   149 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   150   "Pair a b = Abs_prod (Pair_Rep a b)"
   151 
   152 rep_datatype Pair proof -
   153   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   154   assume "\<And>a b. P (Pair a b)"
   155   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   156 next
   157   fix a c :: 'a and b d :: 'b
   158   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   159     by (auto simp add: Pair_Rep_def fun_eq_iff)
   160   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   161     by (auto simp add: prod_def)
   162   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   163     by (simp add: Pair_def Abs_prod_inject)
   164 qed
   165 
   166 declare prod.simps(2) [nitpick_simp del]
   167 
   168 declare prod.weak_case_cong [cong del]
   169 
   170 
   171 subsubsection {* Tuple syntax *}
   172 
   173 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   174   "split \<equiv> prod_case"
   175 
   176 text {*
   177   Patterns -- extends pre-defined type @{typ pttrn} used in
   178   abstractions.
   179 *}
   180 
   181 nonterminal tuple_args and patterns
   182 
   183 syntax
   184   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   185   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   186   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   187   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   188   ""            :: "pttrn => patterns"                  ("_")
   189   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   190 
   191 translations
   192   "(x, y)" == "CONST Pair x y"
   193   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   194   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   195   "%(x, y). b" == "CONST prod_case (%x y. b)"
   196   "_abs (CONST Pair x y) t" => "%(x, y). t"
   197   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   198      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   199 
   200 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   201   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   202 print_translation {*
   203 let
   204   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   205         (* split (%x y. t) => %(x,y) t *)
   206         let
   207           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   208           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   209         in
   210           Syntax.const @{syntax_const "_abs"} $
   211             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   212         end
   213     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   214         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   215         let
   216           val Const (@{syntax_const "_abs"}, _) $
   217             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   218           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   219         in
   220           Syntax.const @{syntax_const "_abs"} $
   221             (Syntax.const @{syntax_const "_pattern"} $ x' $
   222               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   223         end
   224     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   225         (* split (split (%x y z. t)) => %((x, y), z). t *)
   226         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   227     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   228         (* split (%pttrn z. t) => %(pttrn,z). t *)
   229         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   230           Syntax.const @{syntax_const "_abs"} $
   231             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   232         end
   233     | split_tr' _ = raise Match;
   234 in [(@{const_syntax prod_case}, split_tr')] end
   235 *}
   236 
   237 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   238 typed_print_translation {*
   239 let
   240   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   241     | split_guess_names_tr' T [Abs (x, xT, t)] =
   242         (case (head_of t) of
   243           Const (@{const_syntax prod_case}, _) => raise Match
   244         | _ =>
   245           let 
   246             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   247             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   248             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   249           in
   250             Syntax.const @{syntax_const "_abs"} $
   251               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   252           end)
   253     | split_guess_names_tr' T [t] =
   254         (case head_of t of
   255           Const (@{const_syntax prod_case}, _) => raise Match
   256         | _ =>
   257           let
   258             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   259             val (y, t') =
   260               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   261             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   262           in
   263             Syntax.const @{syntax_const "_abs"} $
   264               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   265           end)
   266     | split_guess_names_tr' _ _ = raise Match;
   267 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   268 *}
   269 
   270 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   271    where Q is some bounded quantifier or set operator.
   272    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   273    whereas we want "Q (x,y):A. P x y".
   274    Otherwise prevent eta-contraction.
   275 *)
   276 print_translation {*
   277 let
   278   fun contract Q f ts =
   279     case ts of
   280       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   281       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   282     | _ => f ts;
   283   fun contract2 (Q,f) = (Q, contract Q f);
   284   val pairs =
   285     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   286      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   287      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   288      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   289 in map contract2 pairs end
   290 *}
   291 
   292 subsubsection {* Code generator setup *}
   293 
   294 code_type prod
   295   (SML infix 2 "*")
   296   (OCaml infix 2 "*")
   297   (Haskell "!((_),/ (_))")
   298   (Scala "((_),/ (_))")
   299 
   300 code_const Pair
   301   (SML "!((_),/ (_))")
   302   (OCaml "!((_),/ (_))")
   303   (Haskell "!((_),/ (_))")
   304   (Scala "!((_),/ (_))")
   305 
   306 code_instance prod :: equal
   307   (Haskell -)
   308 
   309 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   310   (Haskell infix 4 "==")
   311 
   312 types_code
   313   "prod"     ("(_ */ _)")
   314 attach (term_of) {*
   315 fun term_of_prod aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   316 *}
   317 attach (test) {*
   318 fun gen_prod aG aT bG bT i =
   319   let
   320     val (x, t) = aG i;
   321     val (y, u) = bG i
   322   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   323 *}
   324 
   325 consts_code
   326   "Pair"    ("(_,/ _)")
   327 
   328 setup {*
   329 let
   330 
   331 fun strip_abs_split 0 t = ([], t)
   332   | strip_abs_split i (Abs (s, T, t)) =
   333       let
   334         val s' = Codegen.new_name t s;
   335         val v = Free (s', T)
   336       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   337   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   338       (case strip_abs_split (i+1) t of
   339         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   340       | _ => ([], u))
   341   | strip_abs_split i t =
   342       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   343 
   344 fun let_codegen thy mode defs dep thyname brack t gr =
   345   (case strip_comb t of
   346     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   347     let
   348       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   349           (case strip_abs_split 1 u of
   350              ([p], u') => apfst (cons (p, t)) (dest_let u')
   351            | _ => ([], l))
   352         | dest_let t = ([], t);
   353       fun mk_code (l, r) gr =
   354         let
   355           val (pl, gr1) = Codegen.invoke_codegen thy mode defs dep thyname false l gr;
   356           val (pr, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false r gr1;
   357         in ((pl, pr), gr2) end
   358     in case dest_let (t1 $ t2 $ t3) of
   359         ([], _) => NONE
   360       | (ps, u) =>
   361           let
   362             val (qs, gr1) = fold_map mk_code ps gr;
   363             val (pu, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false u gr1;
   364             val (pargs, gr3) = fold_map
   365               (Codegen.invoke_codegen thy mode defs dep thyname true) ts gr2
   366           in
   367             SOME (Codegen.mk_app brack
   368               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   369                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   370                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   371                        Pretty.brk 1, pr]]) qs))),
   372                 Pretty.brk 1, Codegen.str "in ", pu,
   373                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   374           end
   375     end
   376   | _ => NONE);
   377 
   378 fun split_codegen thy mode defs dep thyname brack t gr = (case strip_comb t of
   379     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   380       let
   381         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   382         val (q, gr1) = Codegen.invoke_codegen thy mode defs dep thyname false p gr;
   383         val (pu, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false u gr1;
   384         val (pargs, gr3) = fold_map
   385           (Codegen.invoke_codegen thy mode defs dep thyname true) ts gr2
   386       in
   387         SOME (Codegen.mk_app brack
   388           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   389             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   390       end
   391   | _ => NONE);
   392 
   393 in
   394 
   395   Codegen.add_codegen "let_codegen" let_codegen
   396   #> Codegen.add_codegen "split_codegen" split_codegen
   397 
   398 end
   399 *}
   400 
   401 
   402 subsubsection {* Fundamental operations and properties *}
   403 
   404 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   405   by (cases p) simp
   406 
   407 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   408   "fst p = (case p of (a, b) \<Rightarrow> a)"
   409 
   410 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   411   "snd p = (case p of (a, b) \<Rightarrow> b)"
   412 
   413 lemma fst_conv [simp, code]: "fst (a, b) = a"
   414   unfolding fst_def by simp
   415 
   416 lemma snd_conv [simp, code]: "snd (a, b) = b"
   417   unfolding snd_def by simp
   418 
   419 code_const fst and snd
   420   (Haskell "fst" and "snd")
   421 
   422 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   423   by (simp add: fun_eq_iff split: prod.split)
   424 
   425 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   426   by simp
   427 
   428 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   429   by simp
   430 
   431 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   432   by (cases p) simp
   433 
   434 lemmas surjective_pairing = pair_collapse [symmetric]
   435 
   436 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   437   by (cases s, cases t) simp
   438 
   439 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   440   by (simp add: Pair_fst_snd_eq)
   441 
   442 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   443   by (fact prod.cases)
   444 
   445 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   446   by (rule split_conv [THEN iffD2])
   447 
   448 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   449   by (rule split_conv [THEN iffD1])
   450 
   451 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   452   by (simp add: fun_eq_iff split: prod.split)
   453 
   454 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   455   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   456   by (simp add: fun_eq_iff split: prod.split)
   457 
   458 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   459   by (cases x) simp
   460 
   461 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   462   by (cases p) simp
   463 
   464 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   465   by (simp add: prod_case_unfold)
   466 
   467 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   468   -- {* Prevents simplification of @{term c}: much faster *}
   469   by (fact prod.weak_case_cong)
   470 
   471 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   472   by (simp add: split_eta)
   473 
   474 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   475 proof
   476   fix a b
   477   assume "!!x. PROP P x"
   478   then show "PROP P (a, b)" .
   479 next
   480   fix x
   481   assume "!!a b. PROP P (a, b)"
   482   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   483 qed
   484 
   485 text {*
   486   The rule @{thm [source] split_paired_all} does not work with the
   487   Simplifier because it also affects premises in congrence rules,
   488   where this can lead to premises of the form @{text "!!a b. ... =
   489   ?P(a, b)"} which cannot be solved by reflexivity.
   490 *}
   491 
   492 lemmas split_tupled_all = split_paired_all unit_all_eq2
   493 
   494 ML {*
   495   (* replace parameters of product type by individual component parameters *)
   496   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   497   local (* filtering with exists_paired_all is an essential optimization *)
   498     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   499           can HOLogic.dest_prodT T orelse exists_paired_all t
   500       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   501       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   502       | exists_paired_all _ = false;
   503     val ss = HOL_basic_ss
   504       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   505       addsimprocs [@{simproc unit_eq}];
   506   in
   507     val split_all_tac = SUBGOAL (fn (t, i) =>
   508       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   509     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   510       if exists_paired_all t then full_simp_tac ss i else no_tac);
   511     fun split_all th =
   512    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   513   end;
   514 *}
   515 
   516 declaration {* fn _ =>
   517   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   518 *}
   519 
   520 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   521   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   522   by fast
   523 
   524 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   525   by fast
   526 
   527 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   528   -- {* Can't be added to simpset: loops! *}
   529   by (simp add: split_eta)
   530 
   531 text {*
   532   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   533   @{thm [source] split_eta} as a rewrite rule is not general enough,
   534   and using @{thm [source] cond_split_eta} directly would render some
   535   existing proofs very inefficient; similarly for @{text
   536   split_beta}.
   537 *}
   538 
   539 ML {*
   540 local
   541   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   542   fun Pair_pat k 0 (Bound m) = (m = k)
   543     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   544         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   545     | Pair_pat _ _ _ = false;
   546   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   547     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   548     | no_args k i (Bound m) = m < k orelse m > k + i
   549     | no_args _ _ _ = true;
   550   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   551     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   552     | split_pat tp i _ = NONE;
   553   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   554         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   555         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   556 
   557   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   558     | beta_term_pat k i (t $ u) =
   559         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   560     | beta_term_pat k i t = no_args k i t;
   561   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   562     | eta_term_pat _ _ _ = false;
   563   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   564     | subst arg k i (t $ u) =
   565         if Pair_pat k i (t $ u) then incr_boundvars k arg
   566         else (subst arg k i t $ subst arg k i u)
   567     | subst arg k i t = t;
   568 in
   569   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   570         (case split_pat beta_term_pat 1 t of
   571           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   572         | NONE => NONE)
   573     | beta_proc _ _ = NONE;
   574   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   575         (case split_pat eta_term_pat 1 t of
   576           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   577         | NONE => NONE)
   578     | eta_proc _ _ = NONE;
   579 end;
   580 *}
   581 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   582 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   583 
   584 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   585   by (subst surjective_pairing, rule split_conv)
   586 
   587 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   588   -- {* For use with @{text split} and the Simplifier. *}
   589   by (insert surj_pair [of p], clarify, simp)
   590 
   591 text {*
   592   @{thm [source] split_split} could be declared as @{text "[split]"}
   593   done after the Splitter has been speeded up significantly;
   594   precompute the constants involved and don't do anything unless the
   595   current goal contains one of those constants.
   596 *}
   597 
   598 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   599 by (subst split_split, simp)
   600 
   601 text {*
   602   \medskip @{term split} used as a logical connective or set former.
   603 
   604   \medskip These rules are for use with @{text blast}; could instead
   605   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   606 
   607 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   608   apply (simp only: split_tupled_all)
   609   apply (simp (no_asm_simp))
   610   done
   611 
   612 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   613   apply (simp only: split_tupled_all)
   614   apply (simp (no_asm_simp))
   615   done
   616 
   617 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   618   by (induct p) auto
   619 
   620 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   621   by (induct p) auto
   622 
   623 lemma splitE2:
   624   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   625 proof -
   626   assume q: "Q (split P z)"
   627   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   628   show R
   629     apply (rule r surjective_pairing)+
   630     apply (rule split_beta [THEN subst], rule q)
   631     done
   632 qed
   633 
   634 lemma splitD': "split R (a,b) c ==> R a b c"
   635   by simp
   636 
   637 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   638   by simp
   639 
   640 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   641 by (simp only: split_tupled_all, simp)
   642 
   643 lemma mem_splitE:
   644   assumes major: "z \<in> split c p"
   645     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   646   shows Q
   647   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   648 
   649 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   650 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   651 
   652 ML {*
   653 local (* filtering with exists_p_split is an essential optimization *)
   654   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   655     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   656     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   657     | exists_p_split _ = false;
   658   val ss = HOL_basic_ss addsimps @{thms split_conv};
   659 in
   660 val split_conv_tac = SUBGOAL (fn (t, i) =>
   661     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   662 end;
   663 *}
   664 
   665 (* This prevents applications of splitE for already splitted arguments leading
   666    to quite time-consuming computations (in particular for nested tuples) *)
   667 declaration {* fn _ =>
   668   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   669 *}
   670 
   671 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   672   by (rule ext) fast
   673 
   674 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   675   by (rule ext) fast
   676 
   677 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   678   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   679   by (rule ext) blast
   680 
   681 (* Do NOT make this a simp rule as it
   682    a) only helps in special situations
   683    b) can lead to nontermination in the presence of split_def
   684 *)
   685 lemma split_comp_eq: 
   686   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   687   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   688   by (rule ext) auto
   689 
   690 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   691   apply (rule_tac x = "(a, b)" in image_eqI)
   692    apply auto
   693   done
   694 
   695 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   696   by blast
   697 
   698 (*
   699 the following  would be slightly more general,
   700 but cannot be used as rewrite rule:
   701 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   702 ### ?y = .x
   703 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   704 by (rtac some_equality 1)
   705 by ( Simp_tac 1)
   706 by (split_all_tac 1)
   707 by (Asm_full_simp_tac 1)
   708 qed "The_split_eq";
   709 *)
   710 
   711 text {*
   712   Setup of internal @{text split_rule}.
   713 *}
   714 
   715 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   716 
   717 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   718   by (fact splitI2)
   719 
   720 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   721   by (fact splitI2')
   722 
   723 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   724   by (fact splitE)
   725 
   726 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   727   by (fact splitE')
   728 
   729 declare prod_caseI [intro!]
   730 
   731 lemma prod_case_beta:
   732   "prod_case f p = f (fst p) (snd p)"
   733   by (fact split_beta)
   734 
   735 lemma prod_cases3 [cases type]:
   736   obtains (fields) a b c where "y = (a, b, c)"
   737   by (cases y, case_tac b) blast
   738 
   739 lemma prod_induct3 [case_names fields, induct type]:
   740     "(!!a b c. P (a, b, c)) ==> P x"
   741   by (cases x) blast
   742 
   743 lemma prod_cases4 [cases type]:
   744   obtains (fields) a b c d where "y = (a, b, c, d)"
   745   by (cases y, case_tac c) blast
   746 
   747 lemma prod_induct4 [case_names fields, induct type]:
   748     "(!!a b c d. P (a, b, c, d)) ==> P x"
   749   by (cases x) blast
   750 
   751 lemma prod_cases5 [cases type]:
   752   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   753   by (cases y, case_tac d) blast
   754 
   755 lemma prod_induct5 [case_names fields, induct type]:
   756     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   757   by (cases x) blast
   758 
   759 lemma prod_cases6 [cases type]:
   760   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   761   by (cases y, case_tac e) blast
   762 
   763 lemma prod_induct6 [case_names fields, induct type]:
   764     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   765   by (cases x) blast
   766 
   767 lemma prod_cases7 [cases type]:
   768   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   769   by (cases y, case_tac f) blast
   770 
   771 lemma prod_induct7 [case_names fields, induct type]:
   772     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   773   by (cases x) blast
   774 
   775 lemma split_def:
   776   "split = (\<lambda>c p. c (fst p) (snd p))"
   777   by (fact prod_case_unfold)
   778 
   779 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   780   "internal_split == split"
   781 
   782 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   783   by (simp only: internal_split_def split_conv)
   784 
   785 use "Tools/split_rule.ML"
   786 setup Split_Rule.setup
   787 
   788 hide_const internal_split
   789 
   790 
   791 subsubsection {* Derived operations *}
   792 
   793 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   794   "curry = (\<lambda>c x y. c (x, y))"
   795 
   796 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   797   by (simp add: curry_def)
   798 
   799 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   800   by (simp add: curry_def)
   801 
   802 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   803   by (simp add: curry_def)
   804 
   805 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   806   by (simp add: curry_def)
   807 
   808 lemma curry_split [simp]: "curry (split f) = f"
   809   by (simp add: curry_def split_def)
   810 
   811 lemma split_curry [simp]: "split (curry f) = f"
   812   by (simp add: curry_def split_def)
   813 
   814 text {*
   815   The composition-uncurry combinator.
   816 *}
   817 
   818 notation fcomp (infixl "\<circ>>" 60)
   819 
   820 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   821   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   822 
   823 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   824   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   825 
   826 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   827   by (simp add: scomp_unfold prod_case_unfold)
   828 
   829 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   830   by (simp add: fun_eq_iff scomp_apply)
   831 
   832 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   833   by (simp add: fun_eq_iff scomp_apply)
   834 
   835 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   836   by (simp add: fun_eq_iff scomp_unfold)
   837 
   838 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   839   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   840 
   841 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   842   by (simp add: fun_eq_iff scomp_unfold fcomp_apply)
   843 
   844 code_const scomp
   845   (Eval infixl 3 "#->")
   846 
   847 no_notation fcomp (infixl "\<circ>>" 60)
   848 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   849 
   850 text {*
   851   @{term map_pair} --- action of the product functor upon
   852   functions.
   853 *}
   854 
   855 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   856   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   857 
   858 lemma map_pair_simp [simp, code]:
   859   "map_pair f g (a, b) = (f a, g b)"
   860   by (simp add: map_pair_def)
   861 
   862 enriched_type map_pair: map_pair
   863   by (auto simp add: split_paired_all intro: ext)
   864 
   865 lemma fst_map_pair [simp]:
   866   "fst (map_pair f g x) = f (fst x)"
   867   by (cases x) simp_all
   868 
   869 lemma snd_prod_fun [simp]:
   870   "snd (map_pair f g x) = g (snd x)"
   871   by (cases x) simp_all
   872 
   873 lemma fst_comp_map_pair [simp]:
   874   "fst \<circ> map_pair f g = f \<circ> fst"
   875   by (rule ext) simp_all
   876 
   877 lemma snd_comp_map_pair [simp]:
   878   "snd \<circ> map_pair f g = g \<circ> snd"
   879   by (rule ext) simp_all
   880 
   881 lemma map_pair_compose:
   882   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   883   by (rule ext) (simp add: map_pair.compositionality comp_def)
   884 
   885 lemma map_pair_ident [simp]:
   886   "map_pair (%x. x) (%y. y) = (%z. z)"
   887   by (rule ext) (simp add: map_pair.identity)
   888 
   889 lemma map_pair_imageI [intro]:
   890   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   891   by (rule image_eqI) simp_all
   892 
   893 lemma prod_fun_imageE [elim!]:
   894   assumes major: "c \<in> map_pair f g ` R"
   895     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   896   shows P
   897   apply (rule major [THEN imageE])
   898   apply (case_tac x)
   899   apply (rule cases)
   900   apply simp_all
   901   done
   902 
   903 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   904   "apfst f = map_pair f id"
   905 
   906 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   907   "apsnd f = map_pair id f"
   908 
   909 lemma apfst_conv [simp, code]:
   910   "apfst f (x, y) = (f x, y)" 
   911   by (simp add: apfst_def)
   912 
   913 lemma apsnd_conv [simp, code]:
   914   "apsnd f (x, y) = (x, f y)" 
   915   by (simp add: apsnd_def)
   916 
   917 lemma fst_apfst [simp]:
   918   "fst (apfst f x) = f (fst x)"
   919   by (cases x) simp
   920 
   921 lemma fst_apsnd [simp]:
   922   "fst (apsnd f x) = fst x"
   923   by (cases x) simp
   924 
   925 lemma snd_apfst [simp]:
   926   "snd (apfst f x) = snd x"
   927   by (cases x) simp
   928 
   929 lemma snd_apsnd [simp]:
   930   "snd (apsnd f x) = f (snd x)"
   931   by (cases x) simp
   932 
   933 lemma apfst_compose:
   934   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   935   by (cases x) simp
   936 
   937 lemma apsnd_compose:
   938   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   939   by (cases x) simp
   940 
   941 lemma apfst_apsnd [simp]:
   942   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   943   by (cases x) simp
   944 
   945 lemma apsnd_apfst [simp]:
   946   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   947   by (cases x) simp
   948 
   949 lemma apfst_id [simp] :
   950   "apfst id = id"
   951   by (simp add: fun_eq_iff)
   952 
   953 lemma apsnd_id [simp] :
   954   "apsnd id = id"
   955   by (simp add: fun_eq_iff)
   956 
   957 lemma apfst_eq_conv [simp]:
   958   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   959   by (cases x) simp
   960 
   961 lemma apsnd_eq_conv [simp]:
   962   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   963   by (cases x) simp
   964 
   965 lemma apsnd_apfst_commute:
   966   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   967   by simp
   968 
   969 text {*
   970   Disjoint union of a family of sets -- Sigma.
   971 *}
   972 
   973 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   974   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   975 
   976 abbreviation
   977   Times :: "['a set, 'b set] => ('a * 'b) set"
   978     (infixr "<*>" 80) where
   979   "A <*> B == Sigma A (%_. B)"
   980 
   981 notation (xsymbols)
   982   Times  (infixr "\<times>" 80)
   983 
   984 notation (HTML output)
   985   Times  (infixr "\<times>" 80)
   986 
   987 syntax
   988   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   989 translations
   990   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   991 
   992 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   993   by (unfold Sigma_def) blast
   994 
   995 lemma SigmaE [elim!]:
   996     "[| c: Sigma A B;
   997         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   998      |] ==> P"
   999   -- {* The general elimination rule. *}
  1000   by (unfold Sigma_def) blast
  1001 
  1002 text {*
  1003   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1004   eigenvariables.
  1005 *}
  1006 
  1007 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1008   by blast
  1009 
  1010 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1011   by blast
  1012 
  1013 lemma SigmaE2:
  1014     "[| (a, b) : Sigma A B;
  1015         [| a:A;  b:B(a) |] ==> P
  1016      |] ==> P"
  1017   by blast
  1018 
  1019 lemma Sigma_cong:
  1020      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1021       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1022   by auto
  1023 
  1024 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1025   by blast
  1026 
  1027 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1028   by blast
  1029 
  1030 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1031   by blast
  1032 
  1033 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1034   by auto
  1035 
  1036 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1037   by auto
  1038 
  1039 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1040   by auto
  1041 
  1042 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1043   by blast
  1044 
  1045 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1046   by blast
  1047 
  1048 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1049   by (blast elim: equalityE)
  1050 
  1051 lemma SetCompr_Sigma_eq:
  1052     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1053   by blast
  1054 
  1055 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1056   by blast
  1057 
  1058 lemma UN_Times_distrib:
  1059   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1060   -- {* Suggested by Pierre Chartier *}
  1061   by blast
  1062 
  1063 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1064     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1065   by blast
  1066 
  1067 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1068     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1069   by blast
  1070 
  1071 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1072   by blast
  1073 
  1074 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1075   by blast
  1076 
  1077 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1078   by blast
  1079 
  1080 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1081   by blast
  1082 
  1083 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1084   by blast
  1085 
  1086 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1087   by blast
  1088 
  1089 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1090   by blast
  1091 
  1092 text {*
  1093   Non-dependent versions are needed to avoid the need for higher-order
  1094   matching, especially when the rules are re-oriented.
  1095 *}
  1096 
  1097 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1098 by blast
  1099 
  1100 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1101 by blast
  1102 
  1103 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1104 by blast
  1105 
  1106 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1107   by auto
  1108 
  1109 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1110   by (auto intro!: image_eqI)
  1111 
  1112 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1113   by (auto intro!: image_eqI)
  1114 
  1115 lemma insert_times_insert[simp]:
  1116   "insert a A \<times> insert b B =
  1117    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1118 by blast
  1119 
  1120 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1121   by (auto, case_tac "f x", auto)
  1122 
  1123 lemma swap_inj_on:
  1124   "inj_on (\<lambda>(i, j). (j, i)) A"
  1125   by (auto intro!: inj_onI)
  1126 
  1127 lemma swap_product:
  1128   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1129   by (simp add: split_def image_def) blast
  1130 
  1131 lemma image_split_eq_Sigma:
  1132   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1133 proof (safe intro!: imageI vimageI)
  1134   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1135   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1136     using * eq[symmetric] by auto
  1137 qed simp_all
  1138 
  1139 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1140 
  1141 lemma map_pair_inj_on:
  1142   assumes "inj_on f A" and "inj_on g B"
  1143   shows "inj_on (map_pair f g) (A \<times> B)"
  1144 proof (rule inj_onI)
  1145   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1146   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1147   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1148   assume "map_pair f g x = map_pair f g y"
  1149   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1150   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1151   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1152   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1153   moreover from `map_pair f g x = map_pair f g y`
  1154   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1155   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1156   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1157   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1158   ultimately show "x = y" by(rule prod_eqI)
  1159 qed
  1160 
  1161 lemma map_pair_surj:
  1162   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1163   assumes "surj f" and "surj g"
  1164   shows "surj (map_pair f g)"
  1165 unfolding surj_def
  1166 proof
  1167   fix y :: "'b \<times> 'd"
  1168   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1169   moreover
  1170   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1171   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1172   thus "\<exists>x. y = map_pair f g x" by auto
  1173 qed
  1174 
  1175 lemma map_pair_surj_on:
  1176   assumes "f ` A = A'" and "g ` B = B'"
  1177   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1178 unfolding image_def
  1179 proof(rule set_eqI,rule iffI)
  1180   fix x :: "'a \<times> 'c"
  1181   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1182   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1183   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1184   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1185   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1186   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1187 next
  1188   fix x :: "'a \<times> 'c"
  1189   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1190   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1191   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1192   moreover from `image g B = B'` and `snd x \<in> B'`
  1193   obtain b where "b \<in> B" and "snd x = g b" by auto
  1194   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1195   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1196   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1197   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1198 qed
  1199 
  1200 
  1201 subsection {* Inductively defined sets *}
  1202 
  1203 use "Tools/inductive_codegen.ML"
  1204 setup Inductive_Codegen.setup
  1205 
  1206 use "Tools/inductive_set.ML"
  1207 setup Inductive_Set.setup
  1208 
  1209 
  1210 subsection {* Legacy theorem bindings and duplicates *}
  1211 
  1212 lemma PairE:
  1213   obtains x y where "p = (x, y)"
  1214   by (fact prod.exhaust)
  1215 
  1216 lemma Pair_inject:
  1217   assumes "(a, b) = (a', b')"
  1218     and "a = a' ==> b = b' ==> R"
  1219   shows R
  1220   using assms by simp
  1221 
  1222 lemmas Pair_eq = prod.inject
  1223 
  1224 lemmas split = split_conv  -- {* for backwards compatibility *}
  1225 
  1226 end