src/HOL/Library/Multiset.thy
author nipkow
Fri Apr 10 12:16:58 2015 +0200 (2015-04-10)
changeset 59999 3fa68bacfa2b
parent 59997 90fb391a15c1
parent 59998 c54d36be22ef
child 60397 f8a513fedb31
permissions -rw-r--r--
merged
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     5     Author:     Dmitriy Traytel, TU Muenchen
     6     Author:     Mathias Fleury, MPII
     7 *)
     8 
     9 section {* (Finite) multisets *}
    10 
    11 theory Multiset
    12 imports Main
    13 begin
    14 
    15 subsection {* The type of multisets *}
    16 
    17 definition "multiset = {f :: 'a => nat. finite {x. f x > 0}}"
    18 
    19 typedef 'a multiset = "multiset :: ('a => nat) set"
    20   morphisms count Abs_multiset
    21   unfolding multiset_def
    22 proof
    23   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    24 qed
    25 
    26 setup_lifting type_definition_multiset
    27 
    28 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    29   "a :# M == 0 < count M a"
    30 
    31 notation (xsymbols)
    32   Melem (infix "\<in>#" 50)
    33 
    34 lemma multiset_eq_iff:
    35   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    36   by (simp only: count_inject [symmetric] fun_eq_iff)
    37 
    38 lemma multiset_eqI:
    39   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    40   using multiset_eq_iff by auto
    41 
    42 text {*
    43  \medskip Preservation of the representing set @{term multiset}.
    44 *}
    45 
    46 lemma const0_in_multiset:
    47   "(\<lambda>a. 0) \<in> multiset"
    48   by (simp add: multiset_def)
    49 
    50 lemma only1_in_multiset:
    51   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    52   by (simp add: multiset_def)
    53 
    54 lemma union_preserves_multiset:
    55   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    56   by (simp add: multiset_def)
    57 
    58 lemma diff_preserves_multiset:
    59   assumes "M \<in> multiset"
    60   shows "(\<lambda>a. M a - N a) \<in> multiset"
    61 proof -
    62   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    63     by auto
    64   with assms show ?thesis
    65     by (auto simp add: multiset_def intro: finite_subset)
    66 qed
    67 
    68 lemma filter_preserves_multiset:
    69   assumes "M \<in> multiset"
    70   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    71 proof -
    72   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    73     by auto
    74   with assms show ?thesis
    75     by (auto simp add: multiset_def intro: finite_subset)
    76 qed
    77 
    78 lemmas in_multiset = const0_in_multiset only1_in_multiset
    79   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    80 
    81 
    82 subsection {* Representing multisets *}
    83 
    84 text {* Multiset enumeration *}
    85 
    86 instantiation multiset :: (type) cancel_comm_monoid_add
    87 begin
    88 
    89 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    90 by (rule const0_in_multiset)
    91 
    92 abbreviation Mempty :: "'a multiset" ("{#}") where
    93   "Mempty \<equiv> 0"
    94 
    95 lift_definition plus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    96 by (rule union_preserves_multiset)
    97 
    98 lift_definition minus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
    99 by (rule diff_preserves_multiset)
   100 
   101 instance
   102   by default (transfer, simp add: fun_eq_iff)+
   103 
   104 end
   105 
   106 lift_definition single :: "'a => 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   107 by (rule only1_in_multiset)
   108 
   109 syntax
   110   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
   111 translations
   112   "{#x, xs#}" == "{#x#} + {#xs#}"
   113   "{#x#}" == "CONST single x"
   114 
   115 lemma count_empty [simp]: "count {#} a = 0"
   116   by (simp add: zero_multiset.rep_eq)
   117 
   118 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   119   by (simp add: single.rep_eq)
   120 
   121 
   122 subsection {* Basic operations *}
   123 
   124 subsubsection {* Union *}
   125 
   126 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   127   by (simp add: plus_multiset.rep_eq)
   128 
   129 
   130 subsubsection {* Difference *}
   131 
   132 instantiation multiset :: (type) comm_monoid_diff
   133 begin
   134 
   135 instance
   136 by default (transfer, simp add: fun_eq_iff)+
   137 
   138 end
   139 
   140 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   141   by (simp add: minus_multiset.rep_eq)
   142 
   143 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   144   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   145 
   146 lemma diff_cancel[simp]: "A - A = {#}"
   147   by (fact Groups.diff_cancel)
   148 
   149 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   150   by (fact add_diff_cancel_right')
   151 
   152 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   153   by (fact add_diff_cancel_left')
   154 
   155 lemma diff_right_commute:
   156   "(M::'a multiset) - N - Q = M - Q - N"
   157   by (fact diff_right_commute)
   158 
   159 lemma diff_add:
   160   "(M::'a multiset) - (N + Q) = M - N - Q"
   161   by (rule sym) (fact diff_diff_add)
   162 
   163 lemma insert_DiffM:
   164   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   165   by (clarsimp simp: multiset_eq_iff)
   166 
   167 lemma insert_DiffM2 [simp]:
   168   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   169   by (clarsimp simp: multiset_eq_iff)
   170 
   171 lemma diff_union_swap:
   172   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   173   by (auto simp add: multiset_eq_iff)
   174 
   175 lemma diff_union_single_conv:
   176   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   177   by (simp add: multiset_eq_iff)
   178 
   179 
   180 subsubsection {* Equality of multisets *}
   181 
   182 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   183   by (simp add: multiset_eq_iff)
   184 
   185 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   192   by (auto simp add: multiset_eq_iff)
   193 
   194 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   195   by (auto simp add: multiset_eq_iff)
   196 
   197 lemma diff_single_trivial:
   198   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   199   by (auto simp add: multiset_eq_iff)
   200 
   201 lemma diff_single_eq_union:
   202   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   203   by auto
   204 
   205 lemma union_single_eq_diff:
   206   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   207   by (auto dest: sym)
   208 
   209 lemma union_single_eq_member:
   210   "M + {#x#} = N \<Longrightarrow> x \<in># N"
   211   by auto
   212 
   213 lemma union_is_single:
   214   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")
   215 proof
   216   assume ?rhs then show ?lhs by auto
   217 next
   218   assume ?lhs then show ?rhs
   219     by (simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
   220 qed
   221 
   222 lemma single_is_union:
   223   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   224   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   225 
   226 lemma add_eq_conv_diff:
   227   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
   228 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   229 proof
   230   assume ?rhs then show ?lhs
   231   by (auto simp add: add.assoc add.commute [of "{#b#}"])
   232     (drule sym, simp add: add.assoc [symmetric])
   233 next
   234   assume ?lhs
   235   show ?rhs
   236   proof (cases "a = b")
   237     case True with `?lhs` show ?thesis by simp
   238   next
   239     case False
   240     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   241     with False have "a \<in># N" by auto
   242     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   243     moreover note False
   244     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   245   qed
   246 qed
   247 
   248 lemma insert_noteq_member:
   249   assumes BC: "B + {#b#} = C + {#c#}"
   250    and bnotc: "b \<noteq> c"
   251   shows "c \<in># B"
   252 proof -
   253   have "c \<in># C + {#c#}" by simp
   254   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   255   then have "c \<in># B + {#b#}" using BC by simp
   256   then show "c \<in># B" using nc by simp
   257 qed
   258 
   259 lemma add_eq_conv_ex:
   260   "(M + {#a#} = N + {#b#}) =
   261     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   262   by (auto simp add: add_eq_conv_diff)
   263 
   264 lemma multi_member_split:
   265   "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   266   by (rule_tac x = "M - {#x#}" in exI, simp)
   267 
   268 lemma multiset_add_sub_el_shuffle:
   269   assumes "c \<in># B" and "b \<noteq> c"
   270   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   271 proof -
   272   from `c \<in># B` obtain A where B: "B = A + {#c#}"
   273     by (blast dest: multi_member_split)
   274   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   275   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}"
   276     by (simp add: ac_simps)
   277   then show ?thesis using B by simp
   278 qed
   279 
   280 
   281 subsubsection {* Pointwise ordering induced by count *}
   282 
   283 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
   284 begin
   285 
   286 lift_definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" is "\<lambda> A B. (\<forall>a. A a \<le> B a)" .
   287 
   288 lemmas mset_le_def = less_eq_multiset_def
   289 
   290 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   291   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
   292 
   293 instance
   294   by default (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
   295 
   296 end
   297 
   298 abbreviation less_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
   299   "A <# B \<equiv> A < B"
   300 abbreviation (xsymbols) subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "\<subset>#" 50) where
   301   "A \<subset># B \<equiv> A < B"
   302 
   303 abbreviation less_eq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
   304   "A <=# B \<equiv> A \<le> B"
   305 abbreviation (xsymbols) leq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "\<le>#" 50) where
   306   "A \<le># B \<equiv> A \<le> B"
   307 abbreviation (xsymbols) subseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "\<subseteq>#" 50) where
   308   "A \<subseteq># B \<equiv> A \<le> B"
   309 
   310 lemma mset_less_eqI:
   311   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
   312   by (simp add: mset_le_def)
   313 
   314 lemma mset_le_exists_conv:
   315   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
   316 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   317 apply (auto intro: multiset_eq_iff [THEN iffD2])
   318 done
   319 
   320 instance multiset :: (type) ordered_cancel_comm_monoid_diff
   321   by default (simp, fact mset_le_exists_conv)
   322 
   323 lemma mset_le_mono_add_right_cancel [simp]:
   324   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
   325   by (fact add_le_cancel_right)
   326 
   327 lemma mset_le_mono_add_left_cancel [simp]:
   328   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
   329   by (fact add_le_cancel_left)
   330 
   331 lemma mset_le_mono_add:
   332   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
   333   by (fact add_mono)
   334 
   335 lemma mset_le_add_left [simp]:
   336   "(A::'a multiset) \<le> A + B"
   337   unfolding mset_le_def by auto
   338 
   339 lemma mset_le_add_right [simp]:
   340   "B \<le> (A::'a multiset) + B"
   341   unfolding mset_le_def by auto
   342 
   343 lemma mset_le_single:
   344   "a :# B \<Longrightarrow> {#a#} \<le> B"
   345   by (simp add: mset_le_def)
   346 
   347 lemma multiset_diff_union_assoc:
   348   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
   349   by (simp add: multiset_eq_iff mset_le_def)
   350 
   351 lemma mset_le_multiset_union_diff_commute:
   352   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
   353 by (simp add: multiset_eq_iff mset_le_def)
   354 
   355 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
   356 by(simp add: mset_le_def)
   357 
   358 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   359 apply (clarsimp simp: mset_le_def mset_less_def)
   360 apply (erule_tac x=x in allE)
   361 apply auto
   362 done
   363 
   364 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   365 apply (clarsimp simp: mset_le_def mset_less_def)
   366 apply (erule_tac x = x in allE)
   367 apply auto
   368 done
   369 
   370 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
   371 apply (rule conjI)
   372  apply (simp add: mset_lessD)
   373 apply (clarsimp simp: mset_le_def mset_less_def)
   374 apply safe
   375  apply (erule_tac x = a in allE)
   376  apply (auto split: split_if_asm)
   377 done
   378 
   379 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
   380 apply (rule conjI)
   381  apply (simp add: mset_leD)
   382 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
   383 done
   384 
   385 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
   386   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
   387 
   388 lemma empty_le[simp]: "{#} \<le> A"
   389   unfolding mset_le_exists_conv by auto
   390 
   391 lemma le_empty[simp]: "(M \<le> {#}) = (M = {#})"
   392   unfolding mset_le_exists_conv by auto
   393 
   394 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
   395   by (auto simp: mset_le_def mset_less_def)
   396 
   397 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
   398   by simp
   399 
   400 lemma mset_less_add_bothsides: "N + {#x#} < M + {#x#} \<Longrightarrow> N < M"
   401   by (fact add_less_imp_less_right)
   402 
   403 lemma mset_less_empty_nonempty:
   404   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
   405   by (auto simp: mset_le_def mset_less_def)
   406 
   407 lemma mset_less_diff_self:
   408   "c \<in># B \<Longrightarrow> B - {#c#} < B"
   409   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
   410 
   411 
   412 subsubsection {* Intersection *}
   413 
   414 instantiation multiset :: (type) semilattice_inf
   415 begin
   416 
   417 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   418   multiset_inter_def: "inf_multiset A B = A - (A - B)"
   419 
   420 instance
   421 proof -
   422   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
   423   show "OFCLASS('a multiset, semilattice_inf_class)"
   424     by default (auto simp add: multiset_inter_def mset_le_def aux)
   425 qed
   426 
   427 end
   428 
   429 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   430   "multiset_inter \<equiv> inf"
   431 
   432 lemma multiset_inter_count [simp]:
   433   "count (A #\<inter> B) x = min (count A x) (count B x)"
   434   by (simp add: multiset_inter_def)
   435 
   436 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   437   by (rule multiset_eqI) auto
   438 
   439 lemma multiset_union_diff_commute:
   440   assumes "B #\<inter> C = {#}"
   441   shows "A + B - C = A - C + B"
   442 proof (rule multiset_eqI)
   443   fix x
   444   from assms have "min (count B x) (count C x) = 0"
   445     by (auto simp add: multiset_eq_iff)
   446   then have "count B x = 0 \<or> count C x = 0"
   447     by auto
   448   then show "count (A + B - C) x = count (A - C + B) x"
   449     by auto
   450 qed
   451 
   452 lemma empty_inter [simp]:
   453   "{#} #\<inter> M = {#}"
   454   by (simp add: multiset_eq_iff)
   455 
   456 lemma inter_empty [simp]:
   457   "M #\<inter> {#} = {#}"
   458   by (simp add: multiset_eq_iff)
   459 
   460 lemma inter_add_left1:
   461   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   462   by (simp add: multiset_eq_iff)
   463 
   464 lemma inter_add_left2:
   465   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   466   by (simp add: multiset_eq_iff)
   467 
   468 lemma inter_add_right1:
   469   "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   470   by (simp add: multiset_eq_iff)
   471 
   472 lemma inter_add_right2:
   473   "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   474   by (simp add: multiset_eq_iff)
   475 
   476 
   477 subsubsection {* Bounded union *}
   478 
   479 instantiation multiset :: (type) semilattice_sup
   480 begin
   481 
   482 definition sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   483   "sup_multiset A B = A + (B - A)"
   484 
   485 instance
   486 proof -
   487   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" by arith
   488   show "OFCLASS('a multiset, semilattice_sup_class)"
   489     by default (auto simp add: sup_multiset_def mset_le_def aux)
   490 qed
   491 
   492 end
   493 
   494 abbreviation sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<union>" 70) where
   495   "sup_multiset \<equiv> sup"
   496 
   497 lemma sup_multiset_count [simp]:
   498   "count (A #\<union> B) x = max (count A x) (count B x)"
   499   by (simp add: sup_multiset_def)
   500 
   501 lemma empty_sup [simp]:
   502   "{#} #\<union> M = M"
   503   by (simp add: multiset_eq_iff)
   504 
   505 lemma sup_empty [simp]:
   506   "M #\<union> {#} = M"
   507   by (simp add: multiset_eq_iff)
   508 
   509 lemma sup_add_left1:
   510   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   511   by (simp add: multiset_eq_iff)
   512 
   513 lemma sup_add_left2:
   514   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   515   by (simp add: multiset_eq_iff)
   516 
   517 lemma sup_add_right1:
   518   "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   519   by (simp add: multiset_eq_iff)
   520 
   521 lemma sup_add_right2:
   522   "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   523   by (simp add: multiset_eq_iff)
   524 
   525 
   526 subsubsection {* Filter (with comprehension syntax) *}
   527 
   528 text {* Multiset comprehension *}
   529 
   530 lift_definition filter_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"
   531 is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   532 by (rule filter_preserves_multiset)
   533 
   534 lemma count_filter_mset [simp]:
   535   "count (filter_mset P M) a = (if P a then count M a else 0)"
   536   by (simp add: filter_mset.rep_eq)
   537 
   538 lemma filter_empty_mset [simp]:
   539   "filter_mset P {#} = {#}"
   540   by (rule multiset_eqI) simp
   541 
   542 lemma filter_single_mset [simp]:
   543   "filter_mset P {#x#} = (if P x then {#x#} else {#})"
   544   by (rule multiset_eqI) simp
   545 
   546 lemma filter_union_mset [simp]:
   547   "filter_mset P (M + N) = filter_mset P M + filter_mset P N"
   548   by (rule multiset_eqI) simp
   549 
   550 lemma filter_diff_mset [simp]:
   551   "filter_mset P (M - N) = filter_mset P M - filter_mset P N"
   552   by (rule multiset_eqI) simp
   553 
   554 lemma filter_inter_mset [simp]:
   555   "filter_mset P (M #\<inter> N) = filter_mset P M #\<inter> filter_mset P N"
   556   by (rule multiset_eqI) simp
   557 
   558 lemma multiset_filter_subset[simp]: "filter_mset f M \<le> M"
   559   unfolding less_eq_multiset.rep_eq by auto
   560 
   561 lemma multiset_filter_mono: assumes "A \<le> B"
   562   shows "filter_mset f A \<le> filter_mset f B"
   563 proof -
   564   from assms[unfolded mset_le_exists_conv]
   565   obtain C where B: "B = A + C" by auto
   566   show ?thesis unfolding B by auto
   567 qed
   568 
   569 syntax
   570   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   571 syntax (xsymbol)
   572   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   573 translations
   574   "{#x \<in># M. P#}" == "CONST filter_mset (\<lambda>x. P) M"
   575 
   576 
   577 subsubsection {* Set of elements *}
   578 
   579 definition set_of :: "'a multiset => 'a set" where
   580   "set_of M = {x. x :# M}"
   581 
   582 lemma set_of_empty [simp]: "set_of {#} = {}"
   583 by (simp add: set_of_def)
   584 
   585 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   586 by (simp add: set_of_def)
   587 
   588 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   589 by (auto simp add: set_of_def)
   590 
   591 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   592 by (auto simp add: set_of_def multiset_eq_iff)
   593 
   594 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   595 by (auto simp add: set_of_def)
   596 
   597 lemma set_of_filter [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   598 by (auto simp add: set_of_def)
   599 
   600 lemma finite_set_of [iff]: "finite (set_of M)"
   601   using count [of M] by (simp add: multiset_def set_of_def)
   602 
   603 lemma finite_Collect_mem [iff]: "finite {x. x :# M}"
   604   unfolding set_of_def[symmetric] by simp
   605 
   606 lemma set_of_mono: "A \<le> B \<Longrightarrow> set_of A \<subseteq> set_of B"
   607   by (metis mset_leD subsetI mem_set_of_iff)
   608 
   609 lemma ball_set_of_iff: "(\<forall>x \<in> set_of M. P x) \<longleftrightarrow> (\<forall>x. x \<in># M \<longrightarrow> P x)"
   610   by auto
   611 
   612 
   613 subsubsection {* Size *}
   614 
   615 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
   616 
   617 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
   618   by (auto simp: wcount_def add_mult_distrib)
   619 
   620 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
   621   "size_multiset f M = setsum (wcount f M) (set_of M)"
   622 
   623 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
   624 
   625 instantiation multiset :: (type) size begin
   626 definition size_multiset where
   627   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
   628 instance ..
   629 end
   630 
   631 lemmas size_multiset_overloaded_eq =
   632   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
   633 
   634 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
   635 by (simp add: size_multiset_def)
   636 
   637 lemma size_empty [simp]: "size {#} = 0"
   638 by (simp add: size_multiset_overloaded_def)
   639 
   640 lemma size_multiset_single [simp]: "size_multiset f {#b#} = Suc (f b)"
   641 by (simp add: size_multiset_eq)
   642 
   643 lemma size_single [simp]: "size {#b#} = 1"
   644 by (simp add: size_multiset_overloaded_def)
   645 
   646 lemma setsum_wcount_Int:
   647   "finite A \<Longrightarrow> setsum (wcount f N) (A \<inter> set_of N) = setsum (wcount f N) A"
   648 apply (induct rule: finite_induct)
   649  apply simp
   650 apply (simp add: Int_insert_left set_of_def wcount_def)
   651 done
   652 
   653 lemma size_multiset_union [simp]:
   654   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
   655 apply (simp add: size_multiset_def setsum_Un_nat setsum.distrib setsum_wcount_Int wcount_union)
   656 apply (subst Int_commute)
   657 apply (simp add: setsum_wcount_Int)
   658 done
   659 
   660 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   661 by (auto simp add: size_multiset_overloaded_def)
   662 
   663 lemma size_multiset_eq_0_iff_empty [iff]: "(size_multiset f M = 0) = (M = {#})"
   664 by (auto simp add: size_multiset_eq multiset_eq_iff)
   665 
   666 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   667 by (auto simp add: size_multiset_overloaded_def)
   668 
   669 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   670 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   671 
   672 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   673 apply (unfold size_multiset_overloaded_eq)
   674 apply (drule setsum_SucD)
   675 apply auto
   676 done
   677 
   678 lemma size_eq_Suc_imp_eq_union:
   679   assumes "size M = Suc n"
   680   shows "\<exists>a N. M = N + {#a#}"
   681 proof -
   682   from assms obtain a where "a \<in># M"
   683     by (erule size_eq_Suc_imp_elem [THEN exE])
   684   then have "M = M - {#a#} + {#a#}" by simp
   685   then show ?thesis by blast
   686 qed
   687 
   688 lemma size_mset_mono: assumes "A \<le> B"
   689   shows "size A \<le> size(B::_ multiset)"
   690 proof -
   691   from assms[unfolded mset_le_exists_conv]
   692   obtain C where B: "B = A + C" by auto
   693   show ?thesis unfolding B by (induct C, auto)
   694 qed
   695 
   696 lemma size_filter_mset_lesseq[simp]: "size (filter_mset f M) \<le> size M"
   697 by (rule size_mset_mono[OF multiset_filter_subset])
   698 
   699 lemma size_Diff_submset:
   700   "M \<le> M' \<Longrightarrow> size (M' - M) = size M' - size(M::'a multiset)"
   701 by (metis add_diff_cancel_left' size_union mset_le_exists_conv)
   702 
   703 subsection {* Induction and case splits *}
   704 
   705 theorem multiset_induct [case_names empty add, induct type: multiset]:
   706   assumes empty: "P {#}"
   707   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   708   shows "P M"
   709 proof (induct n \<equiv> "size M" arbitrary: M)
   710   case 0 thus "P M" by (simp add: empty)
   711 next
   712   case (Suc k)
   713   obtain N x where "M = N + {#x#}"
   714     using `Suc k = size M` [symmetric]
   715     using size_eq_Suc_imp_eq_union by fast
   716   with Suc add show "P M" by simp
   717 qed
   718 
   719 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   720 by (induct M) auto
   721 
   722 lemma multiset_cases [cases type]:
   723   obtains (empty) "M = {#}"
   724     | (add) N x where "M = N + {#x#}"
   725   using assms by (induct M) simp_all
   726 
   727 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   728 by (cases "B = {#}") (auto dest: multi_member_split)
   729 
   730 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   731 apply (subst multiset_eq_iff)
   732 apply auto
   733 done
   734 
   735 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
   736 proof (induct A arbitrary: B)
   737   case (empty M)
   738   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   739   then obtain M' x where "M = M' + {#x#}"
   740     by (blast dest: multi_nonempty_split)
   741   then show ?case by simp
   742 next
   743   case (add S x T)
   744   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
   745   have SxsubT: "S + {#x#} < T" by fact
   746   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
   747   then obtain T' where T: "T = T' + {#x#}"
   748     by (blast dest: multi_member_split)
   749   then have "S < T'" using SxsubT
   750     by (blast intro: mset_less_add_bothsides)
   751   then have "size S < size T'" using IH by simp
   752   then show ?case using T by simp
   753 qed
   754 
   755 
   756 lemma size_1_singleton_mset: "size M = 1 \<Longrightarrow> \<exists>a. M = {#a#}"
   757 by (cases M) auto
   758 
   759 subsubsection {* Strong induction and subset induction for multisets *}
   760 
   761 text {* Well-foundedness of strict subset relation *}
   762 
   763 lemma wf_less_mset_rel: "wf {(M, N :: 'a multiset). M < N}"
   764 apply (rule wf_measure [THEN wf_subset, where f1=size])
   765 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   766 done
   767 
   768 lemma full_multiset_induct [case_names less]:
   769 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
   770 shows "P B"
   771 apply (rule wf_less_mset_rel [THEN wf_induct])
   772 apply (rule ih, auto)
   773 done
   774 
   775 lemma multi_subset_induct [consumes 2, case_names empty add]:
   776 assumes "F \<le> A"
   777   and empty: "P {#}"
   778   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   779 shows "P F"
   780 proof -
   781   from `F \<le> A`
   782   show ?thesis
   783   proof (induct F)
   784     show "P {#}" by fact
   785   next
   786     fix x F
   787     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
   788     show "P (F + {#x#})"
   789     proof (rule insert)
   790       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   791       from i have "F \<le> A" by (auto dest: mset_le_insertD)
   792       with P show "P F" .
   793     qed
   794   qed
   795 qed
   796 
   797 
   798 subsection {* The fold combinator *}
   799 
   800 definition fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   801 where
   802   "fold_mset f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_of M)"
   803 
   804 lemma fold_mset_empty [simp]:
   805   "fold_mset f s {#} = s"
   806   by (simp add: fold_mset_def)
   807 
   808 context comp_fun_commute
   809 begin
   810 
   811 lemma fold_mset_insert:
   812   "fold_mset f s (M + {#x#}) = f x (fold_mset f s M)"
   813 proof -
   814   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   815     by (fact comp_fun_commute_funpow)
   816   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   817     by (fact comp_fun_commute_funpow)
   818   show ?thesis
   819   proof (cases "x \<in> set_of M")
   820     case False
   821     then have *: "count (M + {#x#}) x = 1" by simp
   822     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_of M) =
   823       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_of M)"
   824       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   825     with False * show ?thesis
   826       by (simp add: fold_mset_def del: count_union)
   827   next
   828     case True
   829     def N \<equiv> "set_of M - {x}"
   830     from N_def True have *: "set_of M = insert x N" "x \<notin> N" "finite N" by auto
   831     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   832       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   833       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   834     with * show ?thesis by (simp add: fold_mset_def del: count_union) simp
   835   qed
   836 qed
   837 
   838 corollary fold_mset_single [simp]:
   839   "fold_mset f s {#x#} = f x s"
   840 proof -
   841   have "fold_mset f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   842   then show ?thesis by simp
   843 qed
   844 
   845 lemma fold_mset_fun_left_comm:
   846   "f x (fold_mset f s M) = fold_mset f (f x s) M"
   847   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   848 
   849 lemma fold_mset_union [simp]:
   850   "fold_mset f s (M + N) = fold_mset f (fold_mset f s M) N"
   851 proof (induct M)
   852   case empty then show ?case by simp
   853 next
   854   case (add M x)
   855   have "M + {#x#} + N = (M + N) + {#x#}"
   856     by (simp add: ac_simps)
   857   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   858 qed
   859 
   860 lemma fold_mset_fusion:
   861   assumes "comp_fun_commute g"
   862   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold_mset g w A) = fold_mset f (h w) A" (is "PROP ?P")
   863 proof -
   864   interpret comp_fun_commute g by (fact assms)
   865   show "PROP ?P" by (induct A) auto
   866 qed
   867 
   868 end
   869 
   870 text {*
   871   A note on code generation: When defining some function containing a
   872   subterm @{term "fold_mset F"}, code generation is not automatic. When
   873   interpreting locale @{text left_commutative} with @{text F}, the
   874   would be code thms for @{const fold_mset} become thms like
   875   @{term "fold_mset F z {#} = z"} where @{text F} is not a pattern but
   876   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   877   constant with its own code thms needs to be introduced for @{text
   878   F}. See the image operator below.
   879 *}
   880 
   881 
   882 subsection {* Image *}
   883 
   884 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   885   "image_mset f = fold_mset (plus o single o f) {#}"
   886 
   887 lemma comp_fun_commute_mset_image:
   888   "comp_fun_commute (plus o single o f)"
   889 proof
   890 qed (simp add: ac_simps fun_eq_iff)
   891 
   892 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   893   by (simp add: image_mset_def)
   894 
   895 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   896 proof -
   897   interpret comp_fun_commute "plus o single o f"
   898     by (fact comp_fun_commute_mset_image)
   899   show ?thesis by (simp add: image_mset_def)
   900 qed
   901 
   902 lemma image_mset_union [simp]:
   903   "image_mset f (M + N) = image_mset f M + image_mset f N"
   904 proof -
   905   interpret comp_fun_commute "plus o single o f"
   906     by (fact comp_fun_commute_mset_image)
   907   show ?thesis by (induct N) (simp_all add: image_mset_def ac_simps)
   908 qed
   909 
   910 corollary image_mset_insert:
   911   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   912   by simp
   913 
   914 lemma set_of_image_mset [simp]:
   915   "set_of (image_mset f M) = image f (set_of M)"
   916   by (induct M) simp_all
   917 
   918 lemma size_image_mset [simp]:
   919   "size (image_mset f M) = size M"
   920   by (induct M) simp_all
   921 
   922 lemma image_mset_is_empty_iff [simp]:
   923   "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   924   by (cases M) auto
   925 
   926 syntax
   927   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   928       ("({#_/. _ :# _#})")
   929 translations
   930   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
   931 
   932 syntax (xsymbols)
   933   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   934       ("({#_/. _ \<in># _#})")
   935 translations
   936   "{#e. x \<in># M#}" == "CONST image_mset (\<lambda>x. e) M"
   937 
   938 syntax
   939   "_comprehension3_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   940       ("({#_/ | _ :# _./ _#})")
   941 translations
   942   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
   943 
   944 syntax
   945   "_comprehension4_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   946       ("({#_/ | _ \<in># _./ _#})")
   947 translations
   948   "{#e | x\<in>#M. P#}" => "{#e. x \<in># {# x\<in>#M. P#}#}"
   949 
   950 text {*
   951   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
   952   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
   953   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
   954   @{term "{#x+x|x:#M. x<c#}"}.
   955 *}
   956 
   957 lemma in_image_mset: "y \<in># {#f x. x \<in># M#} \<longleftrightarrow> y \<in> f ` set_of M"
   958   by (metis mem_set_of_iff set_of_image_mset)
   959 
   960 functor image_mset: image_mset
   961 proof -
   962   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   963   proof
   964     fix A
   965     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   966       by (induct A) simp_all
   967   qed
   968   show "image_mset id = id"
   969   proof
   970     fix A
   971     show "image_mset id A = id A"
   972       by (induct A) simp_all
   973   qed
   974 qed
   975 
   976 declare
   977   image_mset.id [simp]
   978   image_mset.identity [simp]
   979 
   980 lemma image_mset_id[simp]: "image_mset id x = x"
   981   unfolding id_def by auto
   982 
   983 lemma image_mset_cong: "(\<And>x. x \<in># M \<Longrightarrow> f x = g x) \<Longrightarrow> {#f x. x \<in># M#} = {#g x. x \<in># M#}"
   984   by (induct M) auto
   985 
   986 lemma image_mset_cong_pair:
   987   "(\<forall>x y. (x, y) \<in># M \<longrightarrow> f x y = g x y) \<Longrightarrow> {#f x y. (x, y) \<in># M#} = {#g x y. (x, y) \<in># M#}"
   988   by (metis image_mset_cong split_cong)
   989 
   990 
   991 subsection {* Further conversions *}
   992 
   993 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   994   "multiset_of [] = {#}" |
   995   "multiset_of (a # x) = multiset_of x + {# a #}"
   996 
   997 lemma in_multiset_in_set:
   998   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
   999   by (induct xs) simp_all
  1000 
  1001 lemma count_multiset_of:
  1002   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
  1003   by (induct xs) simp_all
  1004 
  1005 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
  1006   by (induct x) auto
  1007 
  1008 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
  1009 by (induct x) auto
  1010 
  1011 lemma set_of_multiset_of[simp]: "set_of (multiset_of x) = set x"
  1012 by (induct x) auto
  1013 
  1014 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
  1015 by (induct xs) auto
  1016 
  1017 lemma size_multiset_of [simp]: "size (multiset_of xs) = length xs"
  1018   by (induct xs) simp_all
  1019 
  1020 lemma multiset_of_append [simp]:
  1021   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
  1022   by (induct xs arbitrary: ys) (auto simp: ac_simps)
  1023 
  1024 lemma multiset_of_filter:
  1025   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
  1026   by (induct xs) simp_all
  1027 
  1028 lemma multiset_of_rev [simp]:
  1029   "multiset_of (rev xs) = multiset_of xs"
  1030   by (induct xs) simp_all
  1031 
  1032 lemma surj_multiset_of: "surj multiset_of"
  1033 apply (unfold surj_def)
  1034 apply (rule allI)
  1035 apply (rule_tac M = y in multiset_induct)
  1036  apply auto
  1037 apply (rule_tac x = "x # xa" in exI)
  1038 apply auto
  1039 done
  1040 
  1041 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
  1042 by (induct x) auto
  1043 
  1044 lemma distinct_count_atmost_1:
  1045   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
  1046 apply (induct x, simp, rule iffI, simp_all)
  1047 apply (rename_tac a b)
  1048 apply (rule conjI)
  1049 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
  1050 apply (erule_tac x = a in allE, simp, clarify)
  1051 apply (erule_tac x = aa in allE, simp)
  1052 done
  1053 
  1054 lemma multiset_of_eq_setD:
  1055   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
  1056 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
  1057 
  1058 lemma set_eq_iff_multiset_of_eq_distinct:
  1059   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
  1060     (set x = set y) = (multiset_of x = multiset_of y)"
  1061 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
  1062 
  1063 lemma set_eq_iff_multiset_of_remdups_eq:
  1064    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
  1065 apply (rule iffI)
  1066 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
  1067 apply (drule distinct_remdups [THEN distinct_remdups
  1068       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
  1069 apply simp
  1070 done
  1071 
  1072 lemma multiset_of_compl_union [simp]:
  1073   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
  1074   by (induct xs) (auto simp: ac_simps)
  1075 
  1076 lemma count_multiset_of_length_filter:
  1077   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
  1078   by (induct xs) auto
  1079 
  1080 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
  1081 apply (induct ls arbitrary: i)
  1082  apply simp
  1083 apply (case_tac i)
  1084  apply auto
  1085 done
  1086 
  1087 lemma multiset_of_remove1[simp]:
  1088   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
  1089 by (induct xs) (auto simp add: multiset_eq_iff)
  1090 
  1091 lemma multiset_of_eq_length:
  1092   assumes "multiset_of xs = multiset_of ys"
  1093   shows "length xs = length ys"
  1094   using assms by (metis size_multiset_of)
  1095 
  1096 lemma multiset_of_eq_length_filter:
  1097   assumes "multiset_of xs = multiset_of ys"
  1098   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1099   using assms by (metis count_multiset_of)
  1100 
  1101 lemma fold_multiset_equiv:
  1102   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1103     and equiv: "multiset_of xs = multiset_of ys"
  1104   shows "List.fold f xs = List.fold f ys"
  1105 using f equiv [symmetric]
  1106 proof (induct xs arbitrary: ys)
  1107   case Nil then show ?case by simp
  1108 next
  1109   case (Cons x xs)
  1110   then have *: "set ys = set (x # xs)" by (blast dest: multiset_of_eq_setD)
  1111   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1112     by (rule Cons.prems(1)) (simp_all add: *)
  1113   moreover from * have "x \<in> set ys" by simp
  1114   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x" by (fact fold_remove1_split)
  1115   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)" by (auto intro: Cons.hyps)
  1116   ultimately show ?case by simp
  1117 qed
  1118 
  1119 lemma multiset_of_insort [simp]:
  1120   "multiset_of (insort x xs) = multiset_of xs + {#x#}"
  1121   by (induct xs) (simp_all add: ac_simps)
  1122 
  1123 lemma multiset_of_map:
  1124   "multiset_of (map f xs) = image_mset f (multiset_of xs)"
  1125   by (induct xs) simp_all
  1126 
  1127 definition multiset_of_set :: "'a set \<Rightarrow> 'a multiset"
  1128 where
  1129   "multiset_of_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
  1130 
  1131 interpretation multiset_of_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
  1132 where
  1133   "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set"
  1134 proof -
  1135   interpret comp_fun_commute "\<lambda>x M. {#x#} + M" by default (simp add: fun_eq_iff ac_simps)
  1136   show "folding (\<lambda>x M. {#x#} + M)" by default (fact comp_fun_commute)
  1137   from multiset_of_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set" ..
  1138 qed
  1139 
  1140 lemma count_multiset_of_set [simp]:
  1141   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (multiset_of_set A) x = 1" (is "PROP ?P")
  1142   "\<not> finite A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?Q")
  1143   "x \<notin> A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?R")
  1144 proof -
  1145   { fix A
  1146     assume "x \<notin> A"
  1147     have "count (multiset_of_set A) x = 0"
  1148     proof (cases "finite A")
  1149       case False then show ?thesis by simp
  1150     next
  1151       case True from True `x \<notin> A` show ?thesis by (induct A) auto
  1152     qed
  1153   } note * = this
  1154   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1155   by (auto elim!: Set.set_insert)
  1156 qed -- {* TODO: maybe define @{const multiset_of_set} also in terms of @{const Abs_multiset} *}
  1157 
  1158 lemma elem_multiset_of_set[simp, intro]: "finite A \<Longrightarrow> x \<in># multiset_of_set A \<longleftrightarrow> x \<in> A"
  1159   by (induct A rule: finite_induct) simp_all
  1160 
  1161 context linorder
  1162 begin
  1163 
  1164 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1165 where
  1166   "sorted_list_of_multiset M = fold_mset insort [] M"
  1167 
  1168 lemma sorted_list_of_multiset_empty [simp]:
  1169   "sorted_list_of_multiset {#} = []"
  1170   by (simp add: sorted_list_of_multiset_def)
  1171 
  1172 lemma sorted_list_of_multiset_singleton [simp]:
  1173   "sorted_list_of_multiset {#x#} = [x]"
  1174 proof -
  1175   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1176   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1177 qed
  1178 
  1179 lemma sorted_list_of_multiset_insert [simp]:
  1180   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1181 proof -
  1182   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1183   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1184 qed
  1185 
  1186 end
  1187 
  1188 lemma multiset_of_sorted_list_of_multiset [simp]:
  1189   "multiset_of (sorted_list_of_multiset M) = M"
  1190   by (induct M) simp_all
  1191 
  1192 lemma sorted_list_of_multiset_multiset_of [simp]:
  1193   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  1194   by (induct xs) simp_all
  1195 
  1196 lemma finite_set_of_multiset_of_set:
  1197   assumes "finite A"
  1198   shows "set_of (multiset_of_set A) = A"
  1199   using assms by (induct A) simp_all
  1200 
  1201 lemma infinite_set_of_multiset_of_set:
  1202   assumes "\<not> finite A"
  1203   shows "set_of (multiset_of_set A) = {}"
  1204   using assms by simp
  1205 
  1206 lemma set_sorted_list_of_multiset [simp]:
  1207   "set (sorted_list_of_multiset M) = set_of M"
  1208   by (induct M) (simp_all add: set_insort)
  1209 
  1210 lemma sorted_list_of_multiset_of_set [simp]:
  1211   "sorted_list_of_multiset (multiset_of_set A) = sorted_list_of_set A"
  1212   by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1213 
  1214 
  1215 subsection {* Big operators *}
  1216 
  1217 no_notation times (infixl "*" 70)
  1218 no_notation Groups.one ("1")
  1219 
  1220 locale comm_monoid_mset = comm_monoid
  1221 begin
  1222 
  1223 definition F :: "'a multiset \<Rightarrow> 'a"
  1224 where
  1225   eq_fold: "F M = fold_mset f 1 M"
  1226 
  1227 lemma empty [simp]:
  1228   "F {#} = 1"
  1229   by (simp add: eq_fold)
  1230 
  1231 lemma singleton [simp]:
  1232   "F {#x#} = x"
  1233 proof -
  1234   interpret comp_fun_commute
  1235     by default (simp add: fun_eq_iff left_commute)
  1236   show ?thesis by (simp add: eq_fold)
  1237 qed
  1238 
  1239 lemma union [simp]:
  1240   "F (M + N) = F M * F N"
  1241 proof -
  1242   interpret comp_fun_commute f
  1243     by default (simp add: fun_eq_iff left_commute)
  1244   show ?thesis by (induct N) (simp_all add: left_commute eq_fold)
  1245 qed
  1246 
  1247 end
  1248 
  1249 lemma comp_fun_commute_plus_mset[simp]: "comp_fun_commute (op + \<Colon> 'a multiset \<Rightarrow> _ \<Rightarrow> _)"
  1250   by default (simp add: add_ac comp_def)
  1251 
  1252 declare comp_fun_commute.fold_mset_insert[OF comp_fun_commute_plus_mset, simp]
  1253 
  1254 lemma in_mset_fold_plus_iff[iff]: "x \<in># fold_mset (op +) M NN \<longleftrightarrow> x \<in># M \<or> (\<exists>N. N \<in># NN \<and> x \<in># N)"
  1255   by (induct NN) auto
  1256 
  1257 notation times (infixl "*" 70)
  1258 notation Groups.one ("1")
  1259 
  1260 context comm_monoid_add
  1261 begin
  1262 
  1263 definition msetsum :: "'a multiset \<Rightarrow> 'a"
  1264 where
  1265   "msetsum = comm_monoid_mset.F plus 0"
  1266 
  1267 sublocale msetsum!: comm_monoid_mset plus 0
  1268 where
  1269   "comm_monoid_mset.F plus 0 = msetsum"
  1270 proof -
  1271   show "comm_monoid_mset plus 0" ..
  1272   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1273 qed
  1274 
  1275 lemma setsum_unfold_msetsum:
  1276   "setsum f A = msetsum (image_mset f (multiset_of_set A))"
  1277   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1278 
  1279 end
  1280 
  1281 lemma msetsum_diff:
  1282   fixes M N :: "('a \<Colon> ordered_cancel_comm_monoid_diff) multiset"
  1283   shows "N \<le> M \<Longrightarrow> msetsum (M - N) = msetsum M - msetsum N"
  1284   by (metis add_diff_cancel_left' msetsum.union ordered_cancel_comm_monoid_diff_class.add_diff_inverse)
  1285 
  1286 lemma size_eq_msetsum: "size M = msetsum (image_mset (\<lambda>_. 1) M)"
  1287 proof (induct M)
  1288   case empty then show ?case by simp
  1289 next
  1290   case (add M x) then show ?case
  1291     by (cases "x \<in> set_of M")
  1292       (simp_all del: mem_set_of_iff add: size_multiset_overloaded_eq setsum.distrib setsum.delta' insert_absorb, simp)
  1293 qed
  1294 
  1295 
  1296 abbreviation Union_mset :: "'a multiset multiset \<Rightarrow> 'a multiset" where
  1297   "Union_mset MM \<equiv> msetsum MM"
  1298 
  1299 notation (xsymbols) Union_mset ("\<Union>#_" [900] 900)
  1300 
  1301 lemma set_of_Union_mset[simp]: "set_of (\<Union># MM) = (\<Union>M \<in> set_of MM. set_of M)"
  1302   by (induct MM) auto
  1303 
  1304 lemma in_Union_mset_iff[iff]: "x \<in># \<Union># MM \<longleftrightarrow> (\<exists>M. M \<in># MM \<and> x \<in># M)"
  1305   by (induct MM) auto
  1306 
  1307 syntax
  1308   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1309       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1310 
  1311 syntax (xsymbols)
  1312   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1313       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1314 
  1315 syntax (HTML output)
  1316   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1317       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1318 
  1319 translations
  1320   "SUM i :# A. b" == "CONST msetsum (CONST image_mset (\<lambda>i. b) A)"
  1321 
  1322 context comm_monoid_mult
  1323 begin
  1324 
  1325 definition msetprod :: "'a multiset \<Rightarrow> 'a"
  1326 where
  1327   "msetprod = comm_monoid_mset.F times 1"
  1328 
  1329 sublocale msetprod!: comm_monoid_mset times 1
  1330 where
  1331   "comm_monoid_mset.F times 1 = msetprod"
  1332 proof -
  1333   show "comm_monoid_mset times 1" ..
  1334   from msetprod_def show "comm_monoid_mset.F times 1 = msetprod" ..
  1335 qed
  1336 
  1337 lemma msetprod_empty:
  1338   "msetprod {#} = 1"
  1339   by (fact msetprod.empty)
  1340 
  1341 lemma msetprod_singleton:
  1342   "msetprod {#x#} = x"
  1343   by (fact msetprod.singleton)
  1344 
  1345 lemma msetprod_Un:
  1346   "msetprod (A + B) = msetprod A * msetprod B"
  1347   by (fact msetprod.union)
  1348 
  1349 lemma setprod_unfold_msetprod:
  1350   "setprod f A = msetprod (image_mset f (multiset_of_set A))"
  1351   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1352 
  1353 lemma msetprod_multiplicity:
  1354   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_of M)"
  1355   by (simp add: fold_mset_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1356 
  1357 end
  1358 
  1359 syntax
  1360   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1361       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1362 
  1363 syntax (xsymbols)
  1364   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1365       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1366 
  1367 syntax (HTML output)
  1368   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1369       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1370 
  1371 translations
  1372   "PROD i :# A. b" == "CONST msetprod (CONST image_mset (\<lambda>i. b) A)"
  1373 
  1374 lemma (in comm_semiring_1) dvd_msetprod:
  1375   assumes "x \<in># A"
  1376   shows "x dvd msetprod A"
  1377 proof -
  1378   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1379   then obtain B where "A = B + {#x#}" ..
  1380   then show ?thesis by simp
  1381 qed
  1382 
  1383 
  1384 subsection {* Replicate operation *}
  1385 
  1386 definition replicate_mset :: "nat \<Rightarrow> 'a \<Rightarrow> 'a multiset" where
  1387   "replicate_mset n x = ((op + {#x#}) ^^ n) {#}"
  1388 
  1389 lemma replicate_mset_0[simp]: "replicate_mset 0 x = {#}"
  1390   unfolding replicate_mset_def by simp
  1391 
  1392 lemma replicate_mset_Suc[simp]: "replicate_mset (Suc n) x = replicate_mset n x + {#x#}"
  1393   unfolding replicate_mset_def by (induct n) (auto intro: add.commute)
  1394 
  1395 lemma in_replicate_mset[simp]: "x \<in># replicate_mset n y \<longleftrightarrow> n > 0 \<and> x = y"
  1396   unfolding replicate_mset_def by (induct n) simp_all
  1397 
  1398 lemma count_replicate_mset[simp]: "count (replicate_mset n x) y = (if y = x then n else 0)"
  1399   unfolding replicate_mset_def by (induct n) simp_all
  1400 
  1401 lemma set_of_replicate_mset_subset[simp]: "set_of (replicate_mset n x) = (if n = 0 then {} else {x})"
  1402   by (auto split: if_splits)
  1403 
  1404 lemma size_replicate_mset[simp]: "size (replicate_mset n M) = n"
  1405   by (induct n, simp_all)
  1406 
  1407 lemma count_le_replicate_mset_le: "n \<le> count M x \<longleftrightarrow> replicate_mset n x \<le> M"
  1408   by (auto simp add: assms mset_less_eqI) (metis count_replicate_mset less_eq_multiset.rep_eq)
  1409 
  1410 lemma filter_eq_replicate_mset: "{#y \<in># D. y = x#} = replicate_mset (count D x) x"
  1411   by (induct D) simp_all
  1412 
  1413 
  1414 subsection {* Alternative representations *}
  1415 
  1416 subsubsection {* Lists *}
  1417 
  1418 context linorder
  1419 begin
  1420 
  1421 lemma multiset_of_insort [simp]:
  1422   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
  1423   by (induct xs) (simp_all add: ac_simps)
  1424 
  1425 lemma multiset_of_sort [simp]:
  1426   "multiset_of (sort_key k xs) = multiset_of xs"
  1427   by (induct xs) (simp_all add: ac_simps)
  1428 
  1429 text {*
  1430   This lemma shows which properties suffice to show that a function
  1431   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1432 *}
  1433 
  1434 lemma properties_for_sort_key:
  1435   assumes "multiset_of ys = multiset_of xs"
  1436   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1437   and "sorted (map f ys)"
  1438   shows "sort_key f xs = ys"
  1439 using assms
  1440 proof (induct xs arbitrary: ys)
  1441   case Nil then show ?case by simp
  1442 next
  1443   case (Cons x xs)
  1444   from Cons.prems(2) have
  1445     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1446     by (simp add: filter_remove1)
  1447   with Cons.prems have "sort_key f xs = remove1 x ys"
  1448     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1449   moreover from Cons.prems have "x \<in> set ys"
  1450     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1451   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1452 qed
  1453 
  1454 lemma properties_for_sort:
  1455   assumes multiset: "multiset_of ys = multiset_of xs"
  1456   and "sorted ys"
  1457   shows "sort xs = ys"
  1458 proof (rule properties_for_sort_key)
  1459   from multiset show "multiset_of ys = multiset_of xs" .
  1460   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
  1461   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
  1462     by (rule multiset_of_eq_length_filter)
  1463   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
  1464     by simp
  1465   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
  1466     by (simp add: replicate_length_filter)
  1467 qed
  1468 
  1469 lemma sort_key_by_quicksort:
  1470   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1471     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1472     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1473 proof (rule properties_for_sort_key)
  1474   show "multiset_of ?rhs = multiset_of ?lhs"
  1475     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
  1476 next
  1477   show "sorted (map f ?rhs)"
  1478     by (auto simp add: sorted_append intro: sorted_map_same)
  1479 next
  1480   fix l
  1481   assume "l \<in> set ?rhs"
  1482   let ?pivot = "f (xs ! (length xs div 2))"
  1483   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1484   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1485     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1486   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1487   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1488   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1489     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1490   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1491   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1492   proof (cases "f l" ?pivot rule: linorder_cases)
  1493     case less
  1494     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1495     with less show ?thesis
  1496       by (simp add: filter_sort [symmetric] ** ***)
  1497   next
  1498     case equal then show ?thesis
  1499       by (simp add: * less_le)
  1500   next
  1501     case greater
  1502     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1503     with greater show ?thesis
  1504       by (simp add: filter_sort [symmetric] ** ***)
  1505   qed
  1506 qed
  1507 
  1508 lemma sort_by_quicksort:
  1509   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1510     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1511     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1512   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1513 
  1514 text {* A stable parametrized quicksort *}
  1515 
  1516 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1517   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1518 
  1519 lemma part_code [code]:
  1520   "part f pivot [] = ([], [], [])"
  1521   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1522      if x' < pivot then (x # lts, eqs, gts)
  1523      else if x' > pivot then (lts, eqs, x # gts)
  1524      else (lts, x # eqs, gts))"
  1525   by (auto simp add: part_def Let_def split_def)
  1526 
  1527 lemma sort_key_by_quicksort_code [code]:
  1528   "sort_key f xs = (case xs of [] \<Rightarrow> []
  1529     | [x] \<Rightarrow> xs
  1530     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1531     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1532        in sort_key f lts @ eqs @ sort_key f gts))"
  1533 proof (cases xs)
  1534   case Nil then show ?thesis by simp
  1535 next
  1536   case (Cons _ ys) note hyps = Cons show ?thesis
  1537   proof (cases ys)
  1538     case Nil with hyps show ?thesis by simp
  1539   next
  1540     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1541     proof (cases zs)
  1542       case Nil with hyps show ?thesis by auto
  1543     next
  1544       case Cons
  1545       from sort_key_by_quicksort [of f xs]
  1546       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1547         in sort_key f lts @ eqs @ sort_key f gts)"
  1548       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1549       with hyps Cons show ?thesis by (simp only: list.cases)
  1550     qed
  1551   qed
  1552 qed
  1553 
  1554 end
  1555 
  1556 hide_const (open) part
  1557 
  1558 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
  1559   by (induct xs) (auto intro: order_trans)
  1560 
  1561 lemma multiset_of_update:
  1562   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
  1563 proof (induct ls arbitrary: i)
  1564   case Nil then show ?case by simp
  1565 next
  1566   case (Cons x xs)
  1567   show ?case
  1568   proof (cases i)
  1569     case 0 then show ?thesis by simp
  1570   next
  1571     case (Suc i')
  1572     with Cons show ?thesis
  1573       apply simp
  1574       apply (subst add.assoc)
  1575       apply (subst add.commute [of "{#v#}" "{#x#}"])
  1576       apply (subst add.assoc [symmetric])
  1577       apply simp
  1578       apply (rule mset_le_multiset_union_diff_commute)
  1579       apply (simp add: mset_le_single nth_mem_multiset_of)
  1580       done
  1581   qed
  1582 qed
  1583 
  1584 lemma multiset_of_swap:
  1585   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1586     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
  1587   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
  1588 
  1589 
  1590 subsection {* The multiset order *}
  1591 
  1592 subsubsection {* Well-foundedness *}
  1593 
  1594 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1595   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1596       (\<forall>b. b :# K --> (b, a) \<in> r)}"
  1597 
  1598 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1599   "mult r = (mult1 r)\<^sup>+"
  1600 
  1601 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1602 by (simp add: mult1_def)
  1603 
  1604 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
  1605     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1606     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
  1607   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
  1608 proof (unfold mult1_def)
  1609   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
  1610   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1611   let ?case1 = "?case1 {(N, M). ?R N M}"
  1612 
  1613   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
  1614   then have "\<exists>a' M0' K.
  1615       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
  1616   then show "?case1 \<or> ?case2"
  1617   proof (elim exE conjE)
  1618     fix a' M0' K
  1619     assume N: "N = M0' + K" and r: "?r K a'"
  1620     assume "M0 + {#a#} = M0' + {#a'#}"
  1621     then have "M0 = M0' \<and> a = a' \<or>
  1622         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
  1623       by (simp only: add_eq_conv_ex)
  1624     then show ?thesis
  1625     proof (elim disjE conjE exE)
  1626       assume "M0 = M0'" "a = a'"
  1627       with N r have "?r K a \<and> N = M0 + K" by simp
  1628       then have ?case2 .. then show ?thesis ..
  1629     next
  1630       fix K'
  1631       assume "M0' = K' + {#a#}"
  1632       with N have n: "N = K' + K + {#a#}" by (simp add: ac_simps)
  1633 
  1634       assume "M0 = K' + {#a'#}"
  1635       with r have "?R (K' + K) M0" by blast
  1636       with n have ?case1 by simp then show ?thesis ..
  1637     qed
  1638   qed
  1639 qed
  1640 
  1641 lemma all_accessible: "wf r ==> \<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1642 proof
  1643   let ?R = "mult1 r"
  1644   let ?W = "Wellfounded.acc ?R"
  1645   {
  1646     fix M M0 a
  1647     assume M0: "M0 \<in> ?W"
  1648       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1649       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
  1650     have "M0 + {#a#} \<in> ?W"
  1651     proof (rule accI [of "M0 + {#a#}"])
  1652       fix N
  1653       assume "(N, M0 + {#a#}) \<in> ?R"
  1654       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
  1655           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
  1656         by (rule less_add)
  1657       then show "N \<in> ?W"
  1658       proof (elim exE disjE conjE)
  1659         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
  1660         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
  1661         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
  1662         then show "N \<in> ?W" by (simp only: N)
  1663       next
  1664         fix K
  1665         assume N: "N = M0 + K"
  1666         assume "\<forall>b. b :# K --> (b, a) \<in> r"
  1667         then have "M0 + K \<in> ?W"
  1668         proof (induct K)
  1669           case empty
  1670           from M0 show "M0 + {#} \<in> ?W" by simp
  1671         next
  1672           case (add K x)
  1673           from add.prems have "(x, a) \<in> r" by simp
  1674           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1675           moreover from add have "M0 + K \<in> ?W" by simp
  1676           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1677           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add.assoc)
  1678         qed
  1679         then show "N \<in> ?W" by (simp only: N)
  1680       qed
  1681     qed
  1682   } note tedious_reasoning = this
  1683 
  1684   assume wf: "wf r"
  1685   fix M
  1686   show "M \<in> ?W"
  1687   proof (induct M)
  1688     show "{#} \<in> ?W"
  1689     proof (rule accI)
  1690       fix b assume "(b, {#}) \<in> ?R"
  1691       with not_less_empty show "b \<in> ?W" by contradiction
  1692     qed
  1693 
  1694     fix M a assume "M \<in> ?W"
  1695     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1696     proof induct
  1697       fix a
  1698       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1699       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1700       proof
  1701         fix M assume "M \<in> ?W"
  1702         then show "M + {#a#} \<in> ?W"
  1703           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1704       qed
  1705     qed
  1706     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
  1707   qed
  1708 qed
  1709 
  1710 theorem wf_mult1: "wf r ==> wf (mult1 r)"
  1711 by (rule acc_wfI) (rule all_accessible)
  1712 
  1713 theorem wf_mult: "wf r ==> wf (mult r)"
  1714 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1715 
  1716 
  1717 subsubsection {* Closure-free presentation *}
  1718 
  1719 text {* One direction. *}
  1720 
  1721 lemma mult_implies_one_step:
  1722   "trans r ==> (M, N) \<in> mult r ==>
  1723     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1724     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
  1725 apply (unfold mult_def mult1_def set_of_def)
  1726 apply (erule converse_trancl_induct, clarify)
  1727  apply (rule_tac x = M0 in exI, simp, clarify)
  1728 apply (case_tac "a :# K")
  1729  apply (rule_tac x = I in exI)
  1730  apply (simp (no_asm))
  1731  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1732  apply (simp (no_asm_simp) add: add.assoc [symmetric])
  1733  apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong)
  1734  apply (simp add: diff_union_single_conv)
  1735  apply (simp (no_asm_use) add: trans_def)
  1736  apply blast
  1737 apply (subgoal_tac "a :# I")
  1738  apply (rule_tac x = "I - {#a#}" in exI)
  1739  apply (rule_tac x = "J + {#a#}" in exI)
  1740  apply (rule_tac x = "K + Ka" in exI)
  1741  apply (rule conjI)
  1742   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1743  apply (rule conjI)
  1744   apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong, simp)
  1745   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1746  apply (simp (no_asm_use) add: trans_def)
  1747  apply blast
  1748 apply (subgoal_tac "a :# (M0 + {#a#})")
  1749  apply simp
  1750 apply (simp (no_asm))
  1751 done
  1752 
  1753 lemma one_step_implies_mult_aux:
  1754   "trans r ==>
  1755     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
  1756       --> (I + K, I + J) \<in> mult r"
  1757 apply (induct_tac n, auto)
  1758 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1759 apply (rename_tac "J'", simp)
  1760 apply (erule notE, auto)
  1761 apply (case_tac "J' = {#}")
  1762  apply (simp add: mult_def)
  1763  apply (rule r_into_trancl)
  1764  apply (simp add: mult1_def set_of_def, blast)
  1765 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
  1766 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1767 apply (erule_tac P = "\<forall>k \<in> set_of K. P k" for P in rev_mp)
  1768 apply (erule ssubst)
  1769 apply (simp add: Ball_def, auto)
  1770 apply (subgoal_tac
  1771   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
  1772     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
  1773  prefer 2
  1774  apply force
  1775 apply (simp (no_asm_use) add: add.assoc [symmetric] mult_def)
  1776 apply (erule trancl_trans)
  1777 apply (rule r_into_trancl)
  1778 apply (simp add: mult1_def set_of_def)
  1779 apply (rule_tac x = a in exI)
  1780 apply (rule_tac x = "I + J'" in exI)
  1781 apply (simp add: ac_simps)
  1782 done
  1783 
  1784 lemma one_step_implies_mult:
  1785   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
  1786     ==> (I + K, I + J) \<in> mult r"
  1787 using one_step_implies_mult_aux by blast
  1788 
  1789 
  1790 subsubsection {* Partial-order properties *}
  1791 
  1792 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<#" 50) where
  1793   "M' #<# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1794 
  1795 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<=#" 50) where
  1796   "M' #<=# M \<longleftrightarrow> M' #<# M \<or> M' = M"
  1797 
  1798 notation (xsymbols) less_multiset (infix "#\<subset>#" 50)
  1799 notation (xsymbols) le_multiset (infix "#\<subseteq>#" 50)
  1800 
  1801 interpretation multiset_order: order le_multiset less_multiset
  1802 proof -
  1803   have irrefl: "\<And>M :: 'a multiset. \<not> M #\<subset># M"
  1804   proof
  1805     fix M :: "'a multiset"
  1806     assume "M #\<subset># M"
  1807     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1808     have "trans {(x'::'a, x). x' < x}"
  1809       by (rule transI) simp
  1810     moreover note MM
  1811     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1812       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
  1813       by (rule mult_implies_one_step)
  1814     then obtain I J K where "M = I + J" and "M = I + K"
  1815       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
  1816     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
  1817     have "finite (set_of K)" by simp
  1818     moreover note aux2
  1819     ultimately have "set_of K = {}"
  1820       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1821     with aux1 show False by simp
  1822   qed
  1823   have trans: "\<And>K M N :: 'a multiset. K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># N"
  1824     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1825   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1826     by default (auto simp add: le_multiset_def irrefl dest: trans)
  1827 qed
  1828 
  1829 lemma mult_less_irrefl [elim!]: "M #\<subset># (M::'a::order multiset) ==> R"
  1830   by simp
  1831 
  1832 
  1833 subsubsection {* Monotonicity of multiset union *}
  1834 
  1835 lemma mult1_union: "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
  1836 apply (unfold mult1_def)
  1837 apply auto
  1838 apply (rule_tac x = a in exI)
  1839 apply (rule_tac x = "C + M0" in exI)
  1840 apply (simp add: add.assoc)
  1841 done
  1842 
  1843 lemma union_less_mono2: "B #\<subset># D ==> C + B #\<subset># C + (D::'a::order multiset)"
  1844 apply (unfold less_multiset_def mult_def)
  1845 apply (erule trancl_induct)
  1846  apply (blast intro: mult1_union)
  1847 apply (blast intro: mult1_union trancl_trans)
  1848 done
  1849 
  1850 lemma union_less_mono1: "B #\<subset># D ==> B + C #\<subset># D + (C::'a::order multiset)"
  1851 apply (subst add.commute [of B C])
  1852 apply (subst add.commute [of D C])
  1853 apply (erule union_less_mono2)
  1854 done
  1855 
  1856 lemma union_less_mono:
  1857   "A #\<subset># C ==> B #\<subset># D ==> A + B #\<subset># C + (D::'a::order multiset)"
  1858   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1859 
  1860 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1861 proof
  1862 qed (auto simp add: le_multiset_def intro: union_less_mono2)
  1863 
  1864 
  1865 subsubsection {* Termination proofs with multiset orders *}
  1866 
  1867 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1868   and multi_member_this: "x \<in># {# x #} + XS"
  1869   and multi_member_last: "x \<in># {# x #}"
  1870   by auto
  1871 
  1872 definition "ms_strict = mult pair_less"
  1873 definition "ms_weak = ms_strict \<union> Id"
  1874 
  1875 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1876 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1877 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1878 
  1879 lemma smsI:
  1880   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1881   unfolding ms_strict_def
  1882 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1883 
  1884 lemma wmsI:
  1885   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1886   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1887 unfolding ms_weak_def ms_strict_def
  1888 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1889 
  1890 inductive pw_leq
  1891 where
  1892   pw_leq_empty: "pw_leq {#} {#}"
  1893 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1894 
  1895 lemma pw_leq_lstep:
  1896   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1897 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1898 
  1899 lemma pw_leq_split:
  1900   assumes "pw_leq X Y"
  1901   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1902   using assms
  1903 proof (induct)
  1904   case pw_leq_empty thus ?case by auto
  1905 next
  1906   case (pw_leq_step x y X Y)
  1907   then obtain A B Z where
  1908     [simp]: "X = A + Z" "Y = B + Z"
  1909       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
  1910     by auto
  1911   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less"
  1912     unfolding pair_leq_def by auto
  1913   thus ?case
  1914   proof
  1915     assume [simp]: "x = y"
  1916     have
  1917       "{#x#} + X = A + ({#y#}+Z)
  1918       \<and> {#y#} + Y = B + ({#y#}+Z)
  1919       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1920       by (auto simp: ac_simps)
  1921     thus ?case by (intro exI)
  1922   next
  1923     assume A: "(x, y) \<in> pair_less"
  1924     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1925     have "{#x#} + X = ?A' + Z"
  1926       "{#y#} + Y = ?B' + Z"
  1927       by (auto simp add: ac_simps)
  1928     moreover have
  1929       "(set_of ?A', set_of ?B') \<in> max_strict"
  1930       using 1 A unfolding max_strict_def
  1931       by (auto elim!: max_ext.cases)
  1932     ultimately show ?thesis by blast
  1933   qed
  1934 qed
  1935 
  1936 lemma
  1937   assumes pwleq: "pw_leq Z Z'"
  1938   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1939   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1940   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1941 proof -
  1942   from pw_leq_split[OF pwleq]
  1943   obtain A' B' Z''
  1944     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1945     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1946     by blast
  1947   {
  1948     assume max: "(set_of A, set_of B) \<in> max_strict"
  1949     from mx_or_empty
  1950     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1951     proof
  1952       assume max': "(set_of A', set_of B') \<in> max_strict"
  1953       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1954         by (auto simp: max_strict_def intro: max_ext_additive)
  1955       thus ?thesis by (rule smsI)
  1956     next
  1957       assume [simp]: "A' = {#} \<and> B' = {#}"
  1958       show ?thesis by (rule smsI) (auto intro: max)
  1959     qed
  1960     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:ac_simps)
  1961     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1962   }
  1963   from mx_or_empty
  1964   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1965   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:ac_simps)
  1966 qed
  1967 
  1968 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1969 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1970 and nonempty_single: "{# x #} \<noteq> {#}"
  1971 by auto
  1972 
  1973 setup {*
  1974 let
  1975   fun msetT T = Type (@{type_name multiset}, [T]);
  1976 
  1977   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1978     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1979     | mk_mset T (x :: xs) =
  1980           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1981                 mk_mset T [x] $ mk_mset T xs
  1982 
  1983   fun mset_member_tac m i =
  1984       (if m <= 0 then
  1985            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1986        else
  1987            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1988 
  1989   val mset_nonempty_tac =
  1990       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  1991 
  1992   fun regroup_munion_conv ctxt =
  1993     Function_Lib.regroup_conv ctxt @{const_abbrev Mempty} @{const_name plus}
  1994       (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  1995 
  1996   fun unfold_pwleq_tac i =
  1997     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  1998       ORELSE (rtac @{thm pw_leq_lstep} i)
  1999       ORELSE (rtac @{thm pw_leq_empty} i)
  2000 
  2001   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  2002                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  2003 in
  2004   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
  2005   {
  2006     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  2007     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  2008     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  2009     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  2010     reduction_pair= @{thm ms_reduction_pair}
  2011   })
  2012 end
  2013 *}
  2014 
  2015 
  2016 subsection {* Legacy theorem bindings *}
  2017 
  2018 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  2019 
  2020 lemma union_commute: "M + N = N + (M::'a multiset)"
  2021   by (fact add.commute)
  2022 
  2023 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  2024   by (fact add.assoc)
  2025 
  2026 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  2027   by (fact add.left_commute)
  2028 
  2029 lemmas union_ac = union_assoc union_commute union_lcomm
  2030 
  2031 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  2032   by (fact add_right_cancel)
  2033 
  2034 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  2035   by (fact add_left_cancel)
  2036 
  2037 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  2038   by (fact add_left_imp_eq)
  2039 
  2040 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
  2041   by (fact order_less_trans)
  2042 
  2043 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  2044   by (fact inf.commute)
  2045 
  2046 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  2047   by (fact inf.assoc [symmetric])
  2048 
  2049 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  2050   by (fact inf.left_commute)
  2051 
  2052 lemmas multiset_inter_ac =
  2053   multiset_inter_commute
  2054   multiset_inter_assoc
  2055   multiset_inter_left_commute
  2056 
  2057 lemma mult_less_not_refl:
  2058   "\<not> M #\<subset># (M::'a::order multiset)"
  2059   by (fact multiset_order.less_irrefl)
  2060 
  2061 lemma mult_less_trans:
  2062   "K #\<subset># M ==> M #\<subset># N ==> K #\<subset># (N::'a::order multiset)"
  2063   by (fact multiset_order.less_trans)
  2064 
  2065 lemma mult_less_not_sym:
  2066   "M #\<subset># N ==> \<not> N #\<subset># (M::'a::order multiset)"
  2067   by (fact multiset_order.less_not_sym)
  2068 
  2069 lemma mult_less_asym:
  2070   "M #\<subset># N ==> (\<not> P ==> N #\<subset># (M::'a::order multiset)) ==> P"
  2071   by (fact multiset_order.less_asym)
  2072 
  2073 ML {*
  2074 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
  2075                       (Const _ $ t') =
  2076     let
  2077       val (maybe_opt, ps) =
  2078         Nitpick_Model.dest_plain_fun t' ||> op ~~
  2079         ||> map (apsnd (snd o HOLogic.dest_number))
  2080       fun elems_for t =
  2081         case AList.lookup (op =) ps t of
  2082           SOME n => replicate n t
  2083         | NONE => [Const (maybe_name, elem_T --> elem_T) $ t]
  2084     in
  2085       case maps elems_for (all_values elem_T) @
  2086            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
  2087             else []) of
  2088         [] => Const (@{const_name zero_class.zero}, T)
  2089       | ts => foldl1 (fn (t1, t2) =>
  2090                          Const (@{const_name plus_class.plus}, T --> T --> T)
  2091                          $ t1 $ t2)
  2092                      (map (curry (op $) (Const (@{const_name single},
  2093                                                 elem_T --> T))) ts)
  2094     end
  2095   | multiset_postproc _ _ _ _ t = t
  2096 *}
  2097 
  2098 declaration {*
  2099 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
  2100     multiset_postproc
  2101 *}
  2102 
  2103 
  2104 subsection {* Naive implementation using lists *}
  2105 
  2106 code_datatype multiset_of
  2107 
  2108 lemma [code]:
  2109   "{#} = multiset_of []"
  2110   by simp
  2111 
  2112 lemma [code]:
  2113   "{#x#} = multiset_of [x]"
  2114   by simp
  2115 
  2116 lemma union_code [code]:
  2117   "multiset_of xs + multiset_of ys = multiset_of (xs @ ys)"
  2118   by simp
  2119 
  2120 lemma [code]:
  2121   "image_mset f (multiset_of xs) = multiset_of (map f xs)"
  2122   by (simp add: multiset_of_map)
  2123 
  2124 lemma [code]:
  2125   "filter_mset f (multiset_of xs) = multiset_of (filter f xs)"
  2126   by (simp add: multiset_of_filter)
  2127 
  2128 lemma [code]:
  2129   "multiset_of xs - multiset_of ys = multiset_of (fold remove1 ys xs)"
  2130   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2131 
  2132 lemma [code]:
  2133   "multiset_of xs #\<inter> multiset_of ys =
  2134     multiset_of (snd (fold (\<lambda>x (ys, zs).
  2135       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2136 proof -
  2137   have "\<And>zs. multiset_of (snd (fold (\<lambda>x (ys, zs).
  2138     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2139       (multiset_of xs #\<inter> multiset_of ys) + multiset_of zs"
  2140     by (induct xs arbitrary: ys)
  2141       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2142   then show ?thesis by simp
  2143 qed
  2144 
  2145 lemma [code]:
  2146   "multiset_of xs #\<union> multiset_of ys =
  2147     multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2148 proof -
  2149   have "\<And>zs. multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2150       (multiset_of xs #\<union> multiset_of ys) + multiset_of zs"
  2151     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2152   then show ?thesis by simp
  2153 qed
  2154 
  2155 declare in_multiset_in_set [code_unfold]
  2156 
  2157 lemma [code]:
  2158   "count (multiset_of xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2159 proof -
  2160   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (multiset_of xs) x + n"
  2161     by (induct xs) simp_all
  2162   then show ?thesis by simp
  2163 qed
  2164 
  2165 declare set_of_multiset_of [code]
  2166 
  2167 declare sorted_list_of_multiset_multiset_of [code]
  2168 
  2169 lemma [code]: -- {* not very efficient, but representation-ignorant! *}
  2170   "multiset_of_set A = multiset_of (sorted_list_of_set A)"
  2171   apply (cases "finite A")
  2172   apply simp_all
  2173   apply (induct A rule: finite_induct)
  2174   apply (simp_all add: add.commute)
  2175   done
  2176 
  2177 declare size_multiset_of [code]
  2178 
  2179 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
  2180   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
  2181 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of
  2182      None \<Rightarrow> None
  2183    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
  2184 
  2185 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> multiset_of xs \<le> multiset_of ys) \<and>
  2186   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> multiset_of xs < multiset_of ys) \<and>
  2187   (ms_lesseq_impl xs ys = Some False \<longrightarrow> multiset_of xs = multiset_of ys)"
  2188 proof (induct xs arbitrary: ys)
  2189   case (Nil ys)
  2190   show ?case by (auto simp: mset_less_empty_nonempty)
  2191 next
  2192   case (Cons x xs ys)
  2193   show ?case
  2194   proof (cases "List.extract (op = x) ys")
  2195     case None
  2196     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  2197     {
  2198       assume "multiset_of (x # xs) \<le> multiset_of ys"
  2199       from set_of_mono[OF this] x have False by simp
  2200     } note nle = this
  2201     moreover
  2202     {
  2203       assume "multiset_of (x # xs) < multiset_of ys"
  2204       hence "multiset_of (x # xs) \<le> multiset_of ys" by auto
  2205       from nle[OF this] have False .
  2206     }
  2207     ultimately show ?thesis using None by auto
  2208   next
  2209     case (Some res)
  2210     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  2211     note Some = Some[unfolded res]
  2212     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  2213     hence id: "multiset_of ys = multiset_of (ys1 @ ys2) + {#x#}"
  2214       by (auto simp: ac_simps)
  2215     show ?thesis unfolding ms_lesseq_impl.simps
  2216       unfolding Some option.simps split
  2217       unfolding id
  2218       using Cons[of "ys1 @ ys2"]
  2219       unfolding mset_le_def mset_less_def by auto
  2220   qed
  2221 qed
  2222 
  2223 lemma [code]: "multiset_of xs \<le> multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
  2224   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2225 
  2226 lemma [code]: "multiset_of xs < multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
  2227   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2228 
  2229 instantiation multiset :: (equal) equal
  2230 begin
  2231 
  2232 definition
  2233   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  2234 lemma [code]: "HOL.equal (multiset_of xs) (multiset_of ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
  2235   unfolding equal_multiset_def
  2236   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2237 
  2238 instance
  2239   by default (simp add: equal_multiset_def)
  2240 end
  2241 
  2242 lemma [code]:
  2243   "msetsum (multiset_of xs) = listsum xs"
  2244   by (induct xs) (simp_all add: add.commute)
  2245 
  2246 lemma [code]:
  2247   "msetprod (multiset_of xs) = fold times xs 1"
  2248 proof -
  2249   have "\<And>x. fold times xs x = msetprod (multiset_of xs) * x"
  2250     by (induct xs) (simp_all add: mult.assoc)
  2251   then show ?thesis by simp
  2252 qed
  2253 
  2254 text {*
  2255   Exercise for the casual reader: add implementations for @{const le_multiset}
  2256   and @{const less_multiset} (multiset order).
  2257 *}
  2258 
  2259 text {* Quickcheck generators *}
  2260 
  2261 definition (in term_syntax)
  2262   msetify :: "'a\<Colon>typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2263     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2264   [code_unfold]: "msetify xs = Code_Evaluation.valtermify multiset_of {\<cdot>} xs"
  2265 
  2266 notation fcomp (infixl "\<circ>>" 60)
  2267 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2268 
  2269 instantiation multiset :: (random) random
  2270 begin
  2271 
  2272 definition
  2273   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2274 
  2275 instance ..
  2276 
  2277 end
  2278 
  2279 no_notation fcomp (infixl "\<circ>>" 60)
  2280 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2281 
  2282 instantiation multiset :: (full_exhaustive) full_exhaustive
  2283 begin
  2284 
  2285 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2286 where
  2287   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2288 
  2289 instance ..
  2290 
  2291 end
  2292 
  2293 hide_const (open) msetify
  2294 
  2295 
  2296 subsection {* BNF setup *}
  2297 
  2298 definition rel_mset where
  2299   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. multiset_of xs = X \<and> multiset_of ys = Y \<and> list_all2 R xs ys)"
  2300 
  2301 lemma multiset_of_zip_take_Cons_drop_twice:
  2302   assumes "length xs = length ys" "j \<le> length xs"
  2303   shows "multiset_of (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
  2304     multiset_of (zip xs ys) + {#(x, y)#}"
  2305 using assms
  2306 proof (induct xs ys arbitrary: x y j rule: list_induct2)
  2307   case Nil
  2308   thus ?case
  2309     by simp
  2310 next
  2311   case (Cons x xs y ys)
  2312   thus ?case
  2313   proof (cases "j = 0")
  2314     case True
  2315     thus ?thesis
  2316       by simp
  2317   next
  2318     case False
  2319     then obtain k where k: "j = Suc k"
  2320       by (case_tac j) simp
  2321     hence "k \<le> length xs"
  2322       using Cons.prems by auto
  2323     hence "multiset_of (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
  2324       multiset_of (zip xs ys) + {#(x, y)#}"
  2325       by (rule Cons.hyps(2))
  2326     thus ?thesis
  2327       unfolding k by (auto simp: add.commute union_lcomm)
  2328   qed
  2329 qed
  2330 
  2331 lemma ex_multiset_of_zip_left:
  2332   assumes "length xs = length ys" "multiset_of xs' = multiset_of xs"
  2333   shows "\<exists>ys'. length ys' = length xs' \<and> multiset_of (zip xs' ys') = multiset_of (zip xs ys)"
  2334 using assms
  2335 proof (induct xs ys arbitrary: xs' rule: list_induct2)
  2336   case Nil
  2337   thus ?case
  2338     by auto
  2339 next
  2340   case (Cons x xs y ys xs')
  2341   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
  2342     by (metis Cons.prems in_set_conv_nth list.set_intros(1) multiset_of_eq_setD)
  2343 
  2344   def xsa \<equiv> "take j xs' @ drop (Suc j) xs'"
  2345   have "multiset_of xs' = {#x#} + multiset_of xsa"
  2346     unfolding xsa_def using j_len nth_j
  2347     by (metis (no_types) ab_semigroup_add_class.add_ac(1) append_take_drop_id Cons_nth_drop_Suc
  2348       multiset_of.simps(2) union_code add.commute)
  2349   hence ms_x: "multiset_of xsa = multiset_of xs"
  2350     by (metis Cons.prems add.commute add_right_imp_eq multiset_of.simps(2))
  2351   then obtain ysa where
  2352     len_a: "length ysa = length xsa" and ms_a: "multiset_of (zip xsa ysa) = multiset_of (zip xs ys)"
  2353     using Cons.hyps(2) by blast
  2354 
  2355   def ys' \<equiv> "take j ysa @ y # drop j ysa"
  2356   have xs': "xs' = take j xsa @ x # drop j xsa"
  2357     using ms_x j_len nth_j Cons.prems xsa_def
  2358     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc Cons_nth_drop_Suc length_Cons
  2359       length_drop size_multiset_of)
  2360   have j_len': "j \<le> length xsa"
  2361     using j_len xs' xsa_def
  2362     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
  2363   have "length ys' = length xs'"
  2364     unfolding ys'_def using Cons.prems len_a ms_x
  2365     by (metis add_Suc_right append_take_drop_id length_Cons length_append multiset_of_eq_length)
  2366   moreover have "multiset_of (zip xs' ys') = multiset_of (zip (x # xs) (y # ys))"
  2367     unfolding xs' ys'_def
  2368     by (rule trans[OF multiset_of_zip_take_Cons_drop_twice])
  2369       (auto simp: len_a ms_a j_len' add.commute)
  2370   ultimately show ?case
  2371     by blast
  2372 qed
  2373 
  2374 lemma list_all2_reorder_left_invariance:
  2375   assumes rel: "list_all2 R xs ys" and ms_x: "multiset_of xs' = multiset_of xs"
  2376   shows "\<exists>ys'. list_all2 R xs' ys' \<and> multiset_of ys' = multiset_of ys"
  2377 proof -
  2378   have len: "length xs = length ys"
  2379     using rel list_all2_conv_all_nth by auto
  2380   obtain ys' where
  2381     len': "length xs' = length ys'" and ms_xy: "multiset_of (zip xs' ys') = multiset_of (zip xs ys)"
  2382     using len ms_x by (metis ex_multiset_of_zip_left)
  2383   have "list_all2 R xs' ys'"
  2384     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: multiset_of_eq_setD)
  2385   moreover have "multiset_of ys' = multiset_of ys"
  2386     using len len' ms_xy map_snd_zip multiset_of_map by metis
  2387   ultimately show ?thesis
  2388     by blast
  2389 qed
  2390 
  2391 lemma ex_multiset_of: "\<exists>xs. multiset_of xs = X"
  2392   by (induct X) (simp, metis multiset_of.simps(2))
  2393 
  2394 bnf "'a multiset"
  2395   map: image_mset
  2396   sets: set_of
  2397   bd: natLeq
  2398   wits: "{#}"
  2399   rel: rel_mset
  2400 proof -
  2401   show "image_mset id = id"
  2402     by (rule image_mset.id)
  2403 next
  2404   show "\<And>f g. image_mset (g \<circ> f) = image_mset g \<circ> image_mset f"
  2405     unfolding comp_def by (rule ext) (simp add: comp_def image_mset.compositionality)
  2406 next
  2407   fix X :: "'a multiset"
  2408   show "\<And>f g. (\<And>z. z \<in> set_of X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X"
  2409     by (induct X, (simp (no_asm))+,
  2410       metis One_nat_def Un_iff count_single mem_set_of_iff set_of_union zero_less_Suc)
  2411 next
  2412   show "\<And>f. set_of \<circ> image_mset f = op ` f \<circ> set_of"
  2413     by auto
  2414 next
  2415   show "card_order natLeq"
  2416     by (rule natLeq_card_order)
  2417 next
  2418   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
  2419     by (rule natLeq_cinfinite)
  2420 next
  2421   show "\<And>X. ordLeq3 (card_of (set_of X)) natLeq"
  2422     by transfer
  2423       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2424 next
  2425   show "\<And>R S. rel_mset R OO rel_mset S \<le> rel_mset (R OO S)"
  2426     unfolding rel_mset_def[abs_def] OO_def
  2427     apply clarify
  2428     apply (rename_tac X Z Y xs ys' ys zs)
  2429     apply (drule_tac xs = ys' and ys = zs and xs' = ys in list_all2_reorder_left_invariance)
  2430     by (auto intro: list_all2_trans)
  2431 next
  2432   show "\<And>R. rel_mset R =
  2433     (BNF_Def.Grp {x. set_of x \<subseteq> {(x, y). R x y}} (image_mset fst))\<inverse>\<inverse> OO
  2434     BNF_Def.Grp {x. set_of x \<subseteq> {(x, y). R x y}} (image_mset snd)"
  2435     unfolding rel_mset_def[abs_def] BNF_Def.Grp_def OO_def
  2436     apply (rule ext)+
  2437     apply auto
  2438      apply (rule_tac x = "multiset_of (zip xs ys)" in exI; auto)
  2439         apply (metis list_all2_lengthD map_fst_zip multiset_of_map)
  2440        apply (auto simp: list_all2_iff)[1]
  2441       apply (metis list_all2_lengthD map_snd_zip multiset_of_map)
  2442      apply (auto simp: list_all2_iff)[1]
  2443     apply (rename_tac XY)
  2444     apply (cut_tac X = XY in ex_multiset_of)
  2445     apply (erule exE)
  2446     apply (rename_tac xys)
  2447     apply (rule_tac x = "map fst xys" in exI)
  2448     apply (auto simp: multiset_of_map)
  2449     apply (rule_tac x = "map snd xys" in exI)
  2450     apply (auto simp: multiset_of_map list_all2I subset_eq zip_map_fst_snd)
  2451     done
  2452 next
  2453   show "\<And>z. z \<in> set_of {#} \<Longrightarrow> False"
  2454     by auto
  2455 qed
  2456 
  2457 inductive rel_mset' where
  2458   Zero[intro]: "rel_mset' R {#} {#}"
  2459 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (M + {#a#}) (N + {#b#})"
  2460 
  2461 lemma rel_mset_Zero: "rel_mset R {#} {#}"
  2462 unfolding rel_mset_def Grp_def by auto
  2463 
  2464 declare multiset.count[simp]
  2465 declare Abs_multiset_inverse[simp]
  2466 declare multiset.count_inverse[simp]
  2467 declare union_preserves_multiset[simp]
  2468 
  2469 lemma rel_mset_Plus:
  2470 assumes ab: "R a b" and MN: "rel_mset R M N"
  2471 shows "rel_mset R (M + {#a#}) (N + {#b#})"
  2472 proof-
  2473   {fix y assume "R a b" and "set_of y \<subseteq> {(x, y). R x y}"
  2474    hence "\<exists>ya. image_mset fst y + {#a#} = image_mset fst ya \<and>
  2475                image_mset snd y + {#b#} = image_mset snd ya \<and>
  2476                set_of ya \<subseteq> {(x, y). R x y}"
  2477    apply(intro exI[of _ "y + {#(a,b)#}"]) by auto
  2478   }
  2479   thus ?thesis
  2480   using assms
  2481   unfolding multiset.rel_compp_Grp Grp_def by blast
  2482 qed
  2483 
  2484 lemma rel_mset'_imp_rel_mset:
  2485   "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
  2486 apply(induct rule: rel_mset'.induct)
  2487 using rel_mset_Zero rel_mset_Plus by auto
  2488 
  2489 lemma rel_mset_size:
  2490   "rel_mset R M N \<Longrightarrow> size M = size N"
  2491 unfolding multiset.rel_compp_Grp Grp_def by auto
  2492 
  2493 lemma multiset_induct2[case_names empty addL addR]:
  2494 assumes empty: "P {#} {#}"
  2495 and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2496 and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2497 shows "P M N"
  2498 apply(induct N rule: multiset_induct)
  2499   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2500   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2501 done
  2502 
  2503 lemma multiset_induct2_size[consumes 1, case_names empty add]:
  2504 assumes c: "size M = size N"
  2505 and empty: "P {#} {#}"
  2506 and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2507 shows "P M N"
  2508 using c proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  2509   case (less M)  show ?case
  2510   proof(cases "M = {#}")
  2511     case True hence "N = {#}" using less.prems by auto
  2512     thus ?thesis using True empty by auto
  2513   next
  2514     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2515     have "N \<noteq> {#}" using False less.prems by auto
  2516     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2517     have "size M1 = size N1" using less.prems unfolding M N by auto
  2518     thus ?thesis using M N less.hyps add by auto
  2519   qed
  2520 qed
  2521 
  2522 lemma msed_map_invL:
  2523 assumes "image_mset f (M + {#a#}) = N"
  2524 shows "\<exists>N1. N = N1 + {#f a#} \<and> image_mset f M = N1"
  2525 proof-
  2526   have "f a \<in># N"
  2527   using assms multiset.set_map[of f "M + {#a#}"] by auto
  2528   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2529   have "image_mset f M = N1" using assms unfolding N by simp
  2530   thus ?thesis using N by blast
  2531 qed
  2532 
  2533 lemma msed_map_invR:
  2534 assumes "image_mset f M = N + {#b#}"
  2535 shows "\<exists>M1 a. M = M1 + {#a#} \<and> f a = b \<and> image_mset f M1 = N"
  2536 proof-
  2537   obtain a where a: "a \<in># M" and fa: "f a = b"
  2538   using multiset.set_map[of f M] unfolding assms
  2539   by (metis image_iff mem_set_of_iff union_single_eq_member)
  2540   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2541   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
  2542   thus ?thesis using M fa by blast
  2543 qed
  2544 
  2545 lemma msed_rel_invL:
  2546 assumes "rel_mset R (M + {#a#}) N"
  2547 shows "\<exists>N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_mset R M N1"
  2548 proof-
  2549   obtain K where KM: "image_mset fst K = M + {#a#}"
  2550   and KN: "image_mset snd K = N" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2551   using assms
  2552   unfolding multiset.rel_compp_Grp Grp_def by auto
  2553   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2554   and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
  2555   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "image_mset snd K1 = N1"
  2556   using msed_map_invL[OF KN[unfolded K]] by auto
  2557   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2558   have "rel_mset R M N1" using sK K1M K1N1
  2559   unfolding K multiset.rel_compp_Grp Grp_def by auto
  2560   thus ?thesis using N Rab by auto
  2561 qed
  2562 
  2563 lemma msed_rel_invR:
  2564 assumes "rel_mset R M (N + {#b#})"
  2565 shows "\<exists>M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_mset R M1 N"
  2566 proof-
  2567   obtain K where KN: "image_mset snd K = N + {#b#}"
  2568   and KM: "image_mset fst K = M" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2569   using assms
  2570   unfolding multiset.rel_compp_Grp Grp_def by auto
  2571   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2572   and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
  2573   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "image_mset fst K1 = M1"
  2574   using msed_map_invL[OF KM[unfolded K]] by auto
  2575   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  2576   have "rel_mset R M1 N" using sK K1N K1M1
  2577   unfolding K multiset.rel_compp_Grp Grp_def by auto
  2578   thus ?thesis using M Rab by auto
  2579 qed
  2580 
  2581 lemma rel_mset_imp_rel_mset':
  2582 assumes "rel_mset R M N"
  2583 shows "rel_mset' R M N"
  2584 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  2585   case (less M)
  2586   have c: "size M = size N" using rel_mset_size[OF less.prems] .
  2587   show ?case
  2588   proof(cases "M = {#}")
  2589     case True hence "N = {#}" using c by simp
  2590     thus ?thesis using True rel_mset'.Zero by auto
  2591   next
  2592     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2593     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_mset R M1 N1"
  2594     using msed_rel_invL[OF less.prems[unfolded M]] by auto
  2595     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  2596     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
  2597   qed
  2598 qed
  2599 
  2600 lemma rel_mset_rel_mset':
  2601 "rel_mset R M N = rel_mset' R M N"
  2602 using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
  2603 
  2604 (* The main end product for rel_mset: inductive characterization *)
  2605 theorems rel_mset_induct[case_names empty add, induct pred: rel_mset] =
  2606          rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
  2607 
  2608 
  2609 subsection {* Size setup *}
  2610 
  2611 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
  2612   unfolding o_apply by (rule ext) (induct_tac, auto)
  2613 
  2614 setup {*
  2615 BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  2616   @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  2617     size_union}
  2618   @{thms multiset_size_o_map}
  2619 *}
  2620 
  2621 hide_const (open) wcount
  2622 
  2623 end