src/HOL/Set.ML
author nipkow
Fri Apr 04 16:33:28 1997 +0200 (1997-04-04)
changeset 2912 3fac3e8d5d3e
parent 2891 d8f254ad1ab9
child 2935 998cb95fdd43
permissions -rw-r--r--
moved inj and surj from Set to Fun and Inv -> inv.
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 AddIffs [mem_Collect_eq];
    14 
    15 goal Set.thy "!!a. P(a) ==> a : {x.P(x)}";
    16 by (Asm_simp_tac 1);
    17 qed "CollectI";
    18 
    19 val prems = goal Set.thy "!!a. a : {x.P(x)} ==> P(a)";
    20 by (Asm_full_simp_tac 1);
    21 qed "CollectD";
    22 
    23 val [prem] = goal Set.thy "[| !!x. (x:A) = (x:B) |] ==> A = B";
    24 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    25 by (rtac Collect_mem_eq 1);
    26 by (rtac Collect_mem_eq 1);
    27 qed "set_ext";
    28 
    29 val [prem] = goal Set.thy "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    30 by (rtac (prem RS ext RS arg_cong) 1);
    31 qed "Collect_cong";
    32 
    33 val CollectE = make_elim CollectD;
    34 
    35 AddSIs [CollectI];
    36 AddSEs [CollectE];
    37 
    38 
    39 section "Bounded quantifiers";
    40 
    41 val prems = goalw Set.thy [Ball_def]
    42     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    43 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    44 qed "ballI";
    45 
    46 val [major,minor] = goalw Set.thy [Ball_def]
    47     "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (rtac (minor RS (major RS spec RS mp)) 1);
    49 qed "bspec";
    50 
    51 val major::prems = goalw Set.thy [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 
    63 val prems = goalw Set.thy [Bex_def]
    64     "[| P(x);  x:A |] ==> ? x:A. P(x)";
    65 by (REPEAT (ares_tac (prems @ [exI,conjI]) 1));
    66 qed "bexI";
    67 
    68 qed_goal "bexCI" Set.thy 
    69    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A.P(x)"
    70  (fn prems=>
    71   [ (rtac classical 1),
    72     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    73 
    74 val major::prems = goalw Set.thy [Bex_def]
    75     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    76 by (rtac (major RS exE) 1);
    77 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    78 qed "bexE";
    79 
    80 AddIs  [bexI];
    81 AddSEs [bexE];
    82 
    83 (*Trival rewrite rule;   (! x:A.P)=P holds only if A is nonempty!*)
    84 goalw Set.thy [Ball_def] "(! x:A. True) = True";
    85 by (Simp_tac 1);
    86 qed "ball_True";
    87 
    88 (*Dual form for existentials*)
    89 goalw Set.thy [Bex_def] "(? x:A. False) = False";
    90 by (Simp_tac 1);
    91 qed "bex_False";
    92 
    93 Addsimps [ball_True, bex_False];
    94 
    95 (** Congruence rules **)
    96 
    97 val prems = goal Set.thy
    98     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
    99 \    (! x:A. P(x)) = (! x:B. Q(x))";
   100 by (resolve_tac (prems RL [ssubst]) 1);
   101 by (REPEAT (ares_tac [ballI,iffI] 1
   102      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   103 qed "ball_cong";
   104 
   105 val prems = goal Set.thy
   106     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   107 \    (? x:A. P(x)) = (? x:B. Q(x))";
   108 by (resolve_tac (prems RL [ssubst]) 1);
   109 by (REPEAT (etac bexE 1
   110      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   111 qed "bex_cong";
   112 
   113 section "Subsets";
   114 
   115 val prems = goalw Set.thy [subset_def] "(!!x.x:A ==> x:B) ==> A <= B";
   116 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   117 qed "subsetI";
   118 
   119 Blast.declConsts (["op <="], [subsetI]);	(*overloading of <=*)
   120 
   121 (*Rule in Modus Ponens style*)
   122 val major::prems = goalw Set.thy [subset_def] "[| A <= B;  c:A |] ==> c:B";
   123 by (rtac (major RS bspec) 1);
   124 by (resolve_tac prems 1);
   125 qed "subsetD";
   126 
   127 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   128 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   129  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   130 
   131 (*Converts A<=B to x:A ==> x:B*)
   132 fun impOfSubs th = th RSN (2, rev_subsetD);
   133 
   134 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   135  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   136 
   137 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   138  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   139 
   140 (*Classical elimination rule*)
   141 val major::prems = goalw Set.thy [subset_def] 
   142     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   143 by (rtac (major RS ballE) 1);
   144 by (REPEAT (eresolve_tac prems 1));
   145 qed "subsetCE";
   146 
   147 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   148 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   149 
   150 AddSIs [subsetI];
   151 AddEs  [subsetD, subsetCE];
   152 
   153 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   154  (fn _=> [Blast_tac 1]);
   155 
   156 val prems = goal Set.thy "!!B. [| A<=B;  B<=C |] ==> A<=(C::'a set)";
   157 by (Blast_tac 1);
   158 qed "subset_trans";
   159 
   160 
   161 section "Equality";
   162 
   163 (*Anti-symmetry of the subset relation*)
   164 val prems = goal Set.thy "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   165 by (rtac (iffI RS set_ext) 1);
   166 by (REPEAT (ares_tac (prems RL [subsetD]) 1));
   167 qed "subset_antisym";
   168 val equalityI = subset_antisym;
   169 
   170 Blast.declConsts (["op ="], [equalityI]);	(*overloading of equality*)
   171 AddSIs [equalityI];
   172 
   173 (* Equality rules from ZF set theory -- are they appropriate here? *)
   174 val prems = goal Set.thy "A = B ==> A<=(B::'a set)";
   175 by (resolve_tac (prems RL [subst]) 1);
   176 by (rtac subset_refl 1);
   177 qed "equalityD1";
   178 
   179 val prems = goal Set.thy "A = B ==> B<=(A::'a set)";
   180 by (resolve_tac (prems RL [subst]) 1);
   181 by (rtac subset_refl 1);
   182 qed "equalityD2";
   183 
   184 val prems = goal Set.thy
   185     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   186 by (resolve_tac prems 1);
   187 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   188 qed "equalityE";
   189 
   190 val major::prems = goal Set.thy
   191     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   192 by (rtac (major RS equalityE) 1);
   193 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   194 qed "equalityCE";
   195 
   196 (*Lemma for creating induction formulae -- for "pattern matching" on p
   197   To make the induction hypotheses usable, apply "spec" or "bspec" to
   198   put universal quantifiers over the free variables in p. *)
   199 val prems = goal Set.thy 
   200     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   201 by (rtac mp 1);
   202 by (REPEAT (resolve_tac (refl::prems) 1));
   203 qed "setup_induction";
   204 
   205 
   206 section "The empty set -- {}";
   207 
   208 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   209  (fn _ => [ (Blast_tac 1) ]);
   210 
   211 Addsimps [empty_iff];
   212 
   213 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   214  (fn _ => [Full_simp_tac 1]);
   215 
   216 AddSEs [emptyE];
   217 
   218 qed_goal "empty_subsetI" Set.thy "{} <= A"
   219  (fn _ => [ (Blast_tac 1) ]);
   220 
   221 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   222  (fn [prem]=>
   223   [ (fast_tac (!claset addIs [prem RS FalseE]) 1) ]);
   224 
   225 qed_goal "equals0D" Set.thy "!!a. [| A={};  a:A |] ==> P"
   226  (fn _ => [ (Blast_tac 1) ]);
   227 
   228 goal Set.thy "Ball {} P = True";
   229 by (simp_tac (HOL_ss addsimps [mem_Collect_eq, Ball_def, empty_def]) 1);
   230 qed "ball_empty";
   231 
   232 goal Set.thy "Bex {} P = False";
   233 by (simp_tac (HOL_ss addsimps [mem_Collect_eq, Bex_def, empty_def]) 1);
   234 qed "bex_empty";
   235 Addsimps [ball_empty, bex_empty];
   236 
   237 goalw Set.thy [Ball_def] "(!x:A.False) = (A = {})";
   238 by(Blast_tac 1);
   239 qed "ball_False";
   240 Addsimps [ball_False];
   241 
   242 (* The dual is probably not helpful:
   243 goal Set.thy "(? x:A.True) = (A ~= {})";
   244 by(Blast_tac 1);
   245 qed "bex_True";
   246 Addsimps [bex_True];
   247 *)
   248 
   249 
   250 section "The Powerset operator -- Pow";
   251 
   252 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   253  (fn _ => [ (Asm_simp_tac 1) ]);
   254 
   255 AddIffs [Pow_iff]; 
   256 
   257 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   258  (fn _ => [ (etac CollectI 1) ]);
   259 
   260 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   261  (fn _=> [ (etac CollectD 1) ]);
   262 
   263 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   264 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   265 
   266 
   267 section "Set complement -- Compl";
   268 
   269 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : Compl(A)) = (c~:A)"
   270  (fn _ => [ (Blast_tac 1) ]);
   271 
   272 Addsimps [Compl_iff];
   273 
   274 val prems = goalw Set.thy [Compl_def]
   275     "[| c:A ==> False |] ==> c : Compl(A)";
   276 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   277 qed "ComplI";
   278 
   279 (*This form, with negated conclusion, works well with the Classical prover.
   280   Negated assumptions behave like formulae on the right side of the notional
   281   turnstile...*)
   282 val major::prems = goalw Set.thy [Compl_def]
   283     "c : Compl(A) ==> c~:A";
   284 by (rtac (major RS CollectD) 1);
   285 qed "ComplD";
   286 
   287 val ComplE = make_elim ComplD;
   288 
   289 AddSIs [ComplI];
   290 AddSEs [ComplE];
   291 
   292 
   293 section "Binary union -- Un";
   294 
   295 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   296  (fn _ => [ Blast_tac 1 ]);
   297 
   298 Addsimps [Un_iff];
   299 
   300 goal Set.thy "!!c. c:A ==> c : A Un B";
   301 by (Asm_simp_tac 1);
   302 qed "UnI1";
   303 
   304 goal Set.thy "!!c. c:B ==> c : A Un B";
   305 by (Asm_simp_tac 1);
   306 qed "UnI2";
   307 
   308 (*Classical introduction rule: no commitment to A vs B*)
   309 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   310  (fn prems=>
   311   [ (Simp_tac 1),
   312     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   313 
   314 val major::prems = goalw Set.thy [Un_def]
   315     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   316 by (rtac (major RS CollectD RS disjE) 1);
   317 by (REPEAT (eresolve_tac prems 1));
   318 qed "UnE";
   319 
   320 AddSIs [UnCI];
   321 AddSEs [UnE];
   322 
   323 
   324 section "Binary intersection -- Int";
   325 
   326 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   327  (fn _ => [ (Blast_tac 1) ]);
   328 
   329 Addsimps [Int_iff];
   330 
   331 goal Set.thy "!!c. [| c:A;  c:B |] ==> c : A Int B";
   332 by (Asm_simp_tac 1);
   333 qed "IntI";
   334 
   335 goal Set.thy "!!c. c : A Int B ==> c:A";
   336 by (Asm_full_simp_tac 1);
   337 qed "IntD1";
   338 
   339 goal Set.thy "!!c. c : A Int B ==> c:B";
   340 by (Asm_full_simp_tac 1);
   341 qed "IntD2";
   342 
   343 val [major,minor] = goal Set.thy
   344     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   345 by (rtac minor 1);
   346 by (rtac (major RS IntD1) 1);
   347 by (rtac (major RS IntD2) 1);
   348 qed "IntE";
   349 
   350 AddSIs [IntI];
   351 AddSEs [IntE];
   352 
   353 section "Set difference";
   354 
   355 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   356  (fn _ => [ (Blast_tac 1) ]);
   357 
   358 Addsimps [Diff_iff];
   359 
   360 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   361  (fn _=> [ Asm_simp_tac 1 ]);
   362 
   363 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   364  (fn _=> [ (Asm_full_simp_tac 1) ]);
   365 
   366 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   367  (fn _=> [ (Asm_full_simp_tac 1) ]);
   368 
   369 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   370  (fn prems=>
   371   [ (resolve_tac prems 1),
   372     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   373 
   374 AddSIs [DiffI];
   375 AddSEs [DiffE];
   376 
   377 
   378 section "Augmenting a set -- insert";
   379 
   380 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   381  (fn _ => [Blast_tac 1]);
   382 
   383 Addsimps [insert_iff];
   384 
   385 qed_goal "insertI1" Set.thy "a : insert a B"
   386  (fn _ => [Simp_tac 1]);
   387 
   388 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   389  (fn _=> [Asm_simp_tac 1]);
   390 
   391 qed_goalw "insertE" Set.thy [insert_def]
   392     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   393  (fn major::prems=>
   394   [ (rtac (major RS UnE) 1),
   395     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   396 
   397 (*Classical introduction rule*)
   398 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   399  (fn prems=>
   400   [ (Simp_tac 1),
   401     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   402 
   403 AddSIs [insertCI]; 
   404 AddSEs [insertE];
   405 
   406 section "Singletons, using insert";
   407 
   408 qed_goal "singletonI" Set.thy "a : {a}"
   409  (fn _=> [ (rtac insertI1 1) ]);
   410 
   411 goal Set.thy "!!a. b : {a} ==> b=a";
   412 by (Blast_tac 1);
   413 qed "singletonD";
   414 
   415 bind_thm ("singletonE", make_elim singletonD);
   416 
   417 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   418 (fn _ => [Blast_tac 1]);
   419 
   420 goal Set.thy "!!a b. {a}={b} ==> a=b";
   421 by (fast_tac (!claset addEs [equalityE]) 1);
   422 qed "singleton_inject";
   423 
   424 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   425 AddSIs [singletonI];   
   426     
   427 AddSDs [singleton_inject];
   428 
   429 
   430 section "The universal set -- UNIV";
   431 
   432 qed_goal "UNIV_I" Set.thy "x : UNIV"
   433   (fn _ => [rtac ComplI 1, etac emptyE 1]);
   434 
   435 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   436   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   437 
   438 
   439 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   440 
   441 goalw Set.thy [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   442 by (Blast_tac 1);
   443 qed "UN_iff";
   444 
   445 Addsimps [UN_iff];
   446 
   447 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   448 goal Set.thy "!!b. [| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   449 by (Auto_tac());
   450 qed "UN_I";
   451 
   452 val major::prems = goalw Set.thy [UNION_def]
   453     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   454 by (rtac (major RS CollectD RS bexE) 1);
   455 by (REPEAT (ares_tac prems 1));
   456 qed "UN_E";
   457 
   458 AddIs  [UN_I];
   459 AddSEs [UN_E];
   460 
   461 val prems = goal Set.thy
   462     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   463 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   464 by (REPEAT (etac UN_E 1
   465      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   466                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   467 qed "UN_cong";
   468 
   469 
   470 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   471 
   472 goalw Set.thy [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   473 by (Auto_tac());
   474 qed "INT_iff";
   475 
   476 Addsimps [INT_iff];
   477 
   478 val prems = goalw Set.thy [INTER_def]
   479     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   480 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   481 qed "INT_I";
   482 
   483 goal Set.thy "!!b. [| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   484 by (Auto_tac());
   485 qed "INT_D";
   486 
   487 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   488 val major::prems = goalw Set.thy [INTER_def]
   489     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   490 by (rtac (major RS CollectD RS ballE) 1);
   491 by (REPEAT (eresolve_tac prems 1));
   492 qed "INT_E";
   493 
   494 AddSIs [INT_I];
   495 AddEs  [INT_D, INT_E];
   496 
   497 val prems = goal Set.thy
   498     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   499 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   500 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   501 by (REPEAT (dtac INT_D 1
   502      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   503 qed "INT_cong";
   504 
   505 
   506 section "Unions over a type; UNION1(B) = Union(range(B))";
   507 
   508 goalw Set.thy [UNION1_def] "(b: (UN x. B(x))) = (EX x. b: B(x))";
   509 by (Simp_tac 1);
   510 by (Blast_tac 1);
   511 qed "UN1_iff";
   512 
   513 Addsimps [UN1_iff];
   514 
   515 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   516 goal Set.thy "!!b. b: B(x) ==> b: (UN x. B(x))";
   517 by (Auto_tac());
   518 qed "UN1_I";
   519 
   520 val major::prems = goalw Set.thy [UNION1_def]
   521     "[| b : (UN x. B(x));  !!x. b: B(x) ==> R |] ==> R";
   522 by (rtac (major RS UN_E) 1);
   523 by (REPEAT (ares_tac prems 1));
   524 qed "UN1_E";
   525 
   526 AddIs  [UN1_I];
   527 AddSEs [UN1_E];
   528 
   529 
   530 section "Intersections over a type; INTER1(B) = Inter(range(B))";
   531 
   532 goalw Set.thy [INTER1_def] "(b: (INT x. B(x))) = (ALL x. b: B(x))";
   533 by (Simp_tac 1);
   534 by (Blast_tac 1);
   535 qed "INT1_iff";
   536 
   537 Addsimps [INT1_iff];
   538 
   539 val prems = goalw Set.thy [INTER1_def]
   540     "(!!x. b: B(x)) ==> b : (INT x. B(x))";
   541 by (REPEAT (ares_tac (INT_I::prems) 1));
   542 qed "INT1_I";
   543 
   544 goal Set.thy "!!b. b : (INT x. B(x)) ==> b: B(a)";
   545 by (Asm_full_simp_tac 1);
   546 qed "INT1_D";
   547 
   548 AddSIs [INT1_I]; 
   549 AddDs  [INT1_D];
   550 
   551 
   552 section "Union";
   553 
   554 goalw Set.thy [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   555 by (Blast_tac 1);
   556 qed "Union_iff";
   557 
   558 Addsimps [Union_iff];
   559 
   560 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   561 goal Set.thy "!!X. [| X:C;  A:X |] ==> A : Union(C)";
   562 by (Auto_tac());
   563 qed "UnionI";
   564 
   565 val major::prems = goalw Set.thy [Union_def]
   566     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   567 by (rtac (major RS UN_E) 1);
   568 by (REPEAT (ares_tac prems 1));
   569 qed "UnionE";
   570 
   571 AddIs  [UnionI];
   572 AddSEs [UnionE];
   573 
   574 
   575 section "Inter";
   576 
   577 goalw Set.thy [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   578 by (Blast_tac 1);
   579 qed "Inter_iff";
   580 
   581 Addsimps [Inter_iff];
   582 
   583 val prems = goalw Set.thy [Inter_def]
   584     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   585 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   586 qed "InterI";
   587 
   588 (*A "destruct" rule -- every X in C contains A as an element, but
   589   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   590 goal Set.thy "!!X. [| A : Inter(C);  X:C |] ==> A:X";
   591 by (Auto_tac());
   592 qed "InterD";
   593 
   594 (*"Classical" elimination rule -- does not require proving X:C *)
   595 val major::prems = goalw Set.thy [Inter_def]
   596     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   597 by (rtac (major RS INT_E) 1);
   598 by (REPEAT (eresolve_tac prems 1));
   599 qed "InterE";
   600 
   601 AddSIs [InterI];
   602 AddEs  [InterD, InterE];
   603 
   604 
   605 (*** Image of a set under a function ***)
   606 
   607 (*Frequently b does not have the syntactic form of f(x).*)
   608 val prems = goalw thy [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   609 by (REPEAT (resolve_tac (prems @ [CollectI,bexI,prem]) 1));
   610 qed "image_eqI";
   611 
   612 bind_thm ("imageI", refl RS image_eqI);
   613 
   614 (*The eta-expansion gives variable-name preservation.*)
   615 val major::prems = goalw thy [image_def]
   616     "[| b : (%x.f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   617 by (rtac (major RS CollectD RS bexE) 1);
   618 by (REPEAT (ares_tac prems 1));
   619 qed "imageE";
   620 
   621 AddIs  [image_eqI];
   622 AddSEs [imageE]; 
   623 
   624 goalw thy [o_def] "(f o g)``r = f``(g``r)";
   625 by (Fast_tac 1);
   626 qed "image_compose";
   627 
   628 goal thy "f``(A Un B) = f``A Un f``B";
   629 by (Fast_tac 1);
   630 qed "image_Un";
   631 
   632 
   633 (*** Range of a function -- just a translation for image! ***)
   634 
   635 goal thy "!!b. b=f(x) ==> b : range(f)";
   636 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   637 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   638 
   639 bind_thm ("rangeI", UNIV_I RS imageI);
   640 
   641 val [major,minor] = goal thy 
   642     "[| b : range(%x.f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   643 by (rtac (major RS imageE) 1);
   644 by (etac minor 1);
   645 qed "rangeE";
   646 
   647 AddIs  [rangeI]; 
   648 AddSEs [rangeE]; 
   649 
   650 
   651 (*** Set reasoning tools ***)
   652 
   653 
   654 (*Each of these has ALREADY been added to !simpset above.*)
   655 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   656                  mem_Collect_eq, 
   657 		 UN_iff, UN1_iff, Union_iff, 
   658 		 INT_iff, INT1_iff, Inter_iff];
   659 
   660 (*Not for Addsimps -- it can cause goals to blow up!*)
   661 goal Set.thy "(a : (if Q then x else y)) = ((Q --> a:x) & (~Q --> a : y))";
   662 by (simp_tac (!simpset setloop split_tac [expand_if]) 1);
   663 qed "mem_if";
   664 
   665 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   666 
   667 simpset := !simpset addcongs [ball_cong,bex_cong]
   668                     setmksimps (mksimps mksimps_pairs);