src/Pure/sign.ML
author wenzelm
Sat Jul 07 00:14:56 2007 +0200 (2007-07-07)
changeset 23615 40ab945ef5ff
parent 22846 fb79144af9a3
child 23660 18765718cf62
permissions -rw-r--r--
simplified pretty token metric: type int;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_trfuns:
    27     (string * (ast list -> ast)) list *
    28     (string * (term list -> term)) list *
    29     (string * (term list -> term)) list *
    30     (string * (ast list -> ast)) list -> theory -> theory
    31   val add_trfunsT:
    32     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    33   val add_advanced_trfuns:
    34     (string * (Proof.context -> ast list -> ast)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> term list -> term)) list *
    37     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    38   val add_advanced_trfunsT:
    39     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    40   val add_tokentrfuns:
    41     (string * string * (string -> string * int)) list -> theory -> theory
    42   val add_mode_tokentrfuns: string -> (string * (string -> string * int)) list
    43     -> theory -> theory
    44   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    46   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    48   val add_path: string -> theory -> theory
    49   val parent_path: theory -> theory
    50   val root_path: theory -> theory
    51   val absolute_path: theory -> theory
    52   val local_path: theory -> theory
    53   val no_base_names: theory -> theory
    54   val qualified_names: theory -> theory
    55   val sticky_prefix: string -> theory -> theory
    56   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    57     theory -> theory
    58   val restore_naming: theory -> theory -> theory
    59 end
    60 
    61 signature SIGN =
    62 sig
    63   val rep_sg: theory ->
    64    {naming: NameSpace.naming,
    65     syn: Syntax.syntax,
    66     tsig: Type.tsig,
    67     consts: Consts.T}
    68   val naming_of: theory -> NameSpace.naming
    69   val base_name: string -> bstring
    70   val full_name: theory -> bstring -> string
    71   val full_name_path: theory -> string -> bstring -> string
    72   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    73   val syn_of: theory -> Syntax.syntax
    74   val tsig_of: theory -> Type.tsig
    75   val classes_of: theory -> Sorts.algebra
    76   val all_classes: theory -> class list
    77   val super_classes: theory -> class -> class list
    78   val defaultS: theory -> sort
    79   val subsort: theory -> sort * sort -> bool
    80   val of_sort: theory -> typ * sort -> bool
    81   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    82   val universal_witness: theory -> (typ * sort) option
    83   val all_sorts_nonempty: theory -> bool
    84   val typ_instance: theory -> typ * typ -> bool
    85   val typ_equiv: theory -> typ * typ -> bool
    86   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    87   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    88   val is_logtype: theory -> string -> bool
    89   val consts_of: theory -> Consts.T
    90   val const_constraint: theory -> string -> typ option
    91   val the_const_constraint: theory -> string -> typ
    92   val const_type: theory -> string -> typ option
    93   val the_const_type: theory -> string -> typ
    94   val declared_tyname: theory -> string -> bool
    95   val declared_const: theory -> string -> bool
    96   val const_monomorphic: theory -> string -> bool
    97   val const_syntax_name: theory -> string -> string
    98   val const_typargs: theory -> string * typ -> typ list
    99   val const_instance: theory -> string * typ list -> typ
   100   val class_space: theory -> NameSpace.T
   101   val type_space: theory -> NameSpace.T
   102   val const_space: theory -> NameSpace.T
   103   val intern_class: theory -> xstring -> string
   104   val extern_class: theory -> string -> xstring
   105   val intern_type: theory -> xstring -> string
   106   val extern_type: theory -> string -> xstring
   107   val intern_const: theory -> xstring -> string
   108   val extern_const: theory -> string -> xstring
   109   val intern_sort: theory -> sort -> sort
   110   val extern_sort: theory -> sort -> sort
   111   val intern_typ: theory -> typ -> typ
   112   val extern_typ: theory -> typ -> typ
   113   val intern_term: theory -> term -> term
   114   val extern_term: (string -> xstring) -> theory -> term -> term
   115   val intern_tycons: theory -> typ -> typ
   116   val pretty_term': Proof.context -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   117   val pretty_term: theory -> term -> Pretty.T
   118   val pretty_typ: theory -> typ -> Pretty.T
   119   val pretty_sort: theory -> sort -> Pretty.T
   120   val pretty_classrel: theory -> class list -> Pretty.T
   121   val pretty_arity: theory -> arity -> Pretty.T
   122   val string_of_term: theory -> term -> string
   123   val string_of_typ: theory -> typ -> string
   124   val string_of_sort: theory -> sort -> string
   125   val string_of_classrel: theory -> class list -> string
   126   val string_of_arity: theory -> arity -> string
   127   val pp: theory -> Pretty.pp
   128   val arity_number: theory -> string -> int
   129   val arity_sorts: theory -> string -> sort -> sort list
   130   val certify_class: theory -> class -> class
   131   val certify_sort: theory -> sort -> sort
   132   val certify_typ: theory -> typ -> typ
   133   val certify_typ_syntax: theory -> typ -> typ
   134   val certify_typ_abbrev: theory -> typ -> typ
   135   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   136   val certify_term: theory -> term -> term * typ * int
   137   val certify_prop: theory -> term -> term * typ * int
   138   val cert_term: theory -> term -> term
   139   val cert_prop: theory -> term -> term
   140   val no_frees: Pretty.pp -> term -> term
   141   val no_vars: Pretty.pp -> term -> term
   142   val cert_def: Pretty.pp -> term -> (string * typ) * term
   143   val read_class: theory -> xstring -> class
   144   val read_sort': Syntax.syntax -> Proof.context -> string -> sort
   145   val read_sort: theory -> string -> sort
   146   val read_arity: theory -> xstring * string list * string -> arity
   147   val cert_arity: theory -> arity -> arity
   148   val get_sort: theory ->
   149     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   150   val read_typ': Syntax.syntax -> Proof.context -> (indexname -> sort option) -> string -> typ
   151   val read_typ_syntax': Syntax.syntax -> Proof.context ->
   152     (indexname -> sort option) -> string -> typ
   153   val read_typ_abbrev': Syntax.syntax -> Proof.context ->
   154     (indexname -> sort option) -> string -> typ
   155   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   156   val read_typ: theory -> string -> typ
   157   val read_typ_syntax: theory -> string -> typ
   158   val read_typ_abbrev: theory -> string -> typ
   159   val read_tyname: theory -> string -> typ
   160   val read_const: theory -> string -> term
   161   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   162     (string -> string option) -> Proof.context ->
   163     (indexname -> typ option) * (indexname -> sort option) ->
   164     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   165   val read_def_terms:
   166     theory * (indexname -> typ option) * (indexname -> sort option) ->
   167     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   168   val simple_read_term: theory -> typ -> string -> term
   169   val read_term: theory -> string -> term
   170   val read_prop: theory -> string -> term
   171   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   172   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   173   val add_abbrev: string -> bstring * term -> theory -> (term * term) * theory
   174   include SIGN_THEORY
   175   val add_const_constraint: xstring * string option -> theory -> theory
   176   val add_const_constraint_i: string * typ option -> theory -> theory
   177   val primitive_class: string * class list -> theory -> theory
   178   val primitive_classrel: class * class -> theory -> theory
   179   val primitive_arity: arity -> theory -> theory
   180   val hide_classes: bool -> xstring list -> theory -> theory
   181   val hide_classes_i: bool -> string list -> theory -> theory
   182   val hide_types: bool -> xstring list -> theory -> theory
   183   val hide_types_i: bool -> string list -> theory -> theory
   184   val hide_consts: bool -> xstring list -> theory -> theory
   185   val hide_consts_i: bool -> string list -> theory -> theory
   186   val hide_names: bool -> string * xstring list -> theory -> theory
   187   val hide_names_i: bool -> string * string list -> theory -> theory
   188 end
   189 
   190 structure Sign: SIGN =
   191 struct
   192 
   193 (** datatype sign **)
   194 
   195 datatype sign = Sign of
   196  {naming: NameSpace.naming,     (*common naming conventions*)
   197   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   198   tsig: Type.tsig,              (*order-sorted signature of types*)
   199   consts: Consts.T};            (*polymorphic constants*)
   200 
   201 fun make_sign (naming, syn, tsig, consts) =
   202   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   203 
   204 structure SignData = TheoryDataFun
   205 (
   206   type T = sign;
   207   val copy = I;
   208   fun extend (Sign {syn, tsig, consts, ...}) =
   209     make_sign (NameSpace.default_naming, syn, tsig, consts);
   210 
   211   val empty =
   212     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   213 
   214   fun merge pp (sign1, sign2) =
   215     let
   216       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   217       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   218 
   219       val naming = NameSpace.default_naming;
   220       val syn = Syntax.merge_syntaxes syn1 syn2;
   221       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   222       val consts = Consts.merge (consts1, consts2);
   223     in make_sign (naming, syn, tsig, consts) end;
   224 );
   225 
   226 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   227 
   228 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   229   make_sign (f (naming, syn, tsig, consts)));
   230 
   231 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   232 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   233 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   234 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   235 
   236 
   237 (* naming *)
   238 
   239 val naming_of = #naming o rep_sg;
   240 val base_name = NameSpace.base;
   241 val full_name = NameSpace.full o naming_of;
   242 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   243 val declare_name = NameSpace.declare o naming_of;
   244 
   245 
   246 (* syntax *)
   247 
   248 val syn_of = #syn o rep_sg;
   249 
   250 
   251 (* type signature *)
   252 
   253 val tsig_of = #tsig o rep_sg;
   254 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   255 val all_classes = Sorts.all_classes o classes_of;
   256 val minimal_classes = Sorts.minimal_classes o classes_of;
   257 val super_classes = Sorts.super_classes o classes_of;
   258 val defaultS = Type.defaultS o tsig_of;
   259 val subsort = Type.subsort o tsig_of;
   260 val of_sort = Type.of_sort o tsig_of;
   261 val witness_sorts = Type.witness_sorts o tsig_of;
   262 val universal_witness = Type.universal_witness o tsig_of;
   263 val all_sorts_nonempty = is_some o universal_witness;
   264 val typ_instance = Type.typ_instance o tsig_of;
   265 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   266 val typ_match = Type.typ_match o tsig_of;
   267 val typ_unify = Type.unify o tsig_of;
   268 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   269 
   270 
   271 (* polymorphic constants *)
   272 
   273 val consts_of = #consts o rep_sg;
   274 val the_const_constraint = Consts.the_constraint o consts_of;
   275 val const_constraint = try o the_const_constraint;
   276 val the_const_type = Consts.the_declaration o consts_of;
   277 val const_type = try o the_const_type;
   278 val const_monomorphic = Consts.is_monomorphic o consts_of;
   279 val const_syntax_name = Consts.syntax_name o consts_of;
   280 val const_typargs = Consts.typargs o consts_of;
   281 val const_instance = Consts.instance o consts_of;
   282 
   283 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   284 val declared_const = is_some oo const_constraint;
   285 
   286 
   287 
   288 (** intern / extern names **)
   289 
   290 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   291 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   292 val const_space = Consts.space_of o consts_of;
   293 
   294 val intern_class = NameSpace.intern o class_space;
   295 val extern_class = NameSpace.extern o class_space;
   296 val intern_type = NameSpace.intern o type_space;
   297 val extern_type = NameSpace.extern o type_space;
   298 val intern_const = NameSpace.intern o const_space;
   299 val extern_const = NameSpace.extern o const_space;
   300 
   301 val intern_sort = map o intern_class;
   302 val extern_sort = map o extern_class;
   303 
   304 local
   305 
   306 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   307   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   308   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   309 
   310 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   311   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   312   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   313   | map_term _ _ _ (t as Bound _) = t
   314   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   315   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   316 
   317 val add_classesT = Term.fold_atyps
   318   (fn TFree (_, S) => fold (insert (op =)) S
   319     | TVar (_, S) => fold (insert (op =)) S
   320     | _ => I);
   321 
   322 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   323   | add_tyconsT _ = I;
   324 
   325 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   326 
   327 fun mapping add_names f t =
   328   let
   329     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   330     val tab = map_filter f' (add_names t []);
   331     fun get x = the_default x (AList.lookup (op =) tab x);
   332   in get end;
   333 
   334 fun typ_mapping f g thy T =
   335   T |> map_typ
   336     (mapping add_classesT (f thy) T)
   337     (mapping add_tyconsT (g thy) T);
   338 
   339 fun term_mapping f g h thy t =
   340   t |> map_term
   341     (mapping (Term.fold_types add_classesT) (f thy) t)
   342     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   343     (mapping add_consts (h thy) t);
   344 
   345 in
   346 
   347 val intern_typ = typ_mapping intern_class intern_type;
   348 val extern_typ = typ_mapping extern_class extern_type;
   349 val intern_term = term_mapping intern_class intern_type intern_const;
   350 fun extern_term h = term_mapping extern_class extern_type (K h);
   351 val intern_tycons = typ_mapping (K I) intern_type;
   352 
   353 end;
   354 
   355 
   356 
   357 (** pretty printing of terms, types etc. **)
   358 
   359 fun pretty_term' ctxt syn ext t =
   360   let val curried = Context.exists_name Context.CPureN (ProofContext.theory_of ctxt)
   361   in Syntax.pretty_term ext ctxt syn curried t end;
   362 
   363 fun pretty_term thy t =
   364   pretty_term' (ProofContext.init thy) (syn_of thy) (Consts.extern (consts_of thy))
   365     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   366 
   367 fun pretty_typ thy T =
   368   Syntax.pretty_typ (ProofContext.init thy) (syn_of thy) (extern_typ thy T);
   369 
   370 fun pretty_sort thy S =
   371   Syntax.pretty_sort (ProofContext.init thy) (syn_of thy) (extern_sort thy S);
   372 
   373 fun pretty_classrel thy cs = Pretty.block (flat
   374   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   375 
   376 fun pretty_arity thy (a, Ss, S) =
   377   let
   378     val a' = extern_type thy a;
   379     val dom =
   380       if null Ss then []
   381       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   382   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   383 
   384 val string_of_term = Pretty.string_of oo pretty_term;
   385 val string_of_typ = Pretty.string_of oo pretty_typ;
   386 val string_of_sort = Pretty.string_of oo pretty_sort;
   387 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   388 val string_of_arity = Pretty.string_of oo pretty_arity;
   389 
   390 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   391   pretty_classrel thy, pretty_arity thy);
   392 
   393 
   394 
   395 (** certify entities **)    (*exception TYPE*)
   396 
   397 (* certify wrt. type signature *)
   398 
   399 val arity_number = Type.arity_number o tsig_of;
   400 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   401 
   402 fun certify cert = cert o tsig_of o Context.check_thy;
   403 
   404 val certify_class      = certify Type.cert_class;
   405 val certify_sort       = certify Type.cert_sort;
   406 val certify_typ        = certify Type.cert_typ;
   407 val certify_typ_syntax = certify Type.cert_typ_syntax;
   408 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   409 
   410 
   411 (* certify term/prop *)
   412 
   413 local
   414 
   415 fun type_check pp tm =
   416   let
   417     fun err_appl why bs t T u U =
   418       let
   419         val xs = map Free bs;           (*we do not rename here*)
   420         val t' = subst_bounds (xs, t);
   421         val u' = subst_bounds (xs, u);
   422         val msg = cat_lines
   423           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   424       in raise TYPE (msg, [T, U], [t', u']) end;
   425 
   426     fun typ_of (_, Const (_, T)) = T
   427       | typ_of (_, Free  (_, T)) = T
   428       | typ_of (_, Var (_, T)) = T
   429       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   430           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   431       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   432       | typ_of (bs, t $ u) =
   433           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   434             (case T of
   435               Type ("fun", [T1, T2]) =>
   436                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   437             | _ => err_appl "Operator not of function type" bs t T u U)
   438           end;
   439   in typ_of ([], tm) end;
   440 
   441 fun err msg = raise TYPE (msg, [], []);
   442 
   443 fun check_vars (t $ u) = (check_vars t; check_vars u)
   444   | check_vars (Abs (_, _, t)) = check_vars t
   445   | check_vars (Var (xi as (_, i), _)) =
   446       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   447   | check_vars _ = ();
   448 
   449 in
   450 
   451 fun certify' normalize prop pp consts thy tm =
   452   let
   453     val _ = Context.check_thy thy;
   454     val _ = check_vars tm;
   455     val tm' = Term.map_types (certify_typ thy) tm;
   456     val T = type_check pp tm';
   457     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   458     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   459     val tm'' = if normalize then tm'' else tm';
   460   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   461 
   462 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   463 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   464 
   465 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   466 val cert_term = #1 oo certify_term;
   467 val cert_prop = #1 oo certify_prop;
   468 
   469 end;
   470 
   471 
   472 (* specifications *)
   473 
   474 fun no_variables kind add addT mk mkT pp tm =
   475   (case (add tm [], addT tm []) of
   476     ([], []) => tm
   477   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   478       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   479        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   480 
   481 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   482 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   483 
   484 fun cert_def pp tm =
   485   let val ((lhs, rhs), _) = tm
   486     |> no_vars pp
   487     |> Logic.strip_imp_concl
   488     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   489   in (Term.dest_Const (Term.head_of lhs), rhs) end
   490   handle TERM (msg, _) => error msg;
   491 
   492 
   493 
   494 (** read and certify entities **)    (*exception ERROR*)
   495 
   496 (* classes and sorts *)
   497 
   498 fun read_class thy c = certify_class thy (intern_class thy c)
   499   handle TYPE (msg, _, _) => error msg;
   500 
   501 fun read_sort' syn ctxt str =
   502   let
   503     val thy = ProofContext.theory_of ctxt;
   504     val _ = Context.check_thy thy;
   505     val S = Syntax.read_sort ctxt syn (intern_sort thy) str;
   506   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   507 
   508 fun read_sort thy str = read_sort' (syn_of thy) (ProofContext.init thy) str;
   509 
   510 
   511 (* type arities *)
   512 
   513 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   514   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   515   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   516 
   517 val read_arity = prep_arity intern_type read_sort;
   518 val cert_arity = prep_arity (K I) certify_sort;
   519 
   520 
   521 (* types *)
   522 
   523 fun get_sort thy def_sort raw_env =
   524   let
   525     val tsig = tsig_of thy;
   526 
   527     fun eq ((xi, S), (xi', S')) =
   528       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   529     val env = distinct eq raw_env;
   530     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   531       | dups => error ("Inconsistent sort constraints for type variable(s) "
   532           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   533 
   534     fun get xi =
   535       (case (AList.lookup (op =) env xi, def_sort xi) of
   536         (NONE, NONE) => Type.defaultS tsig
   537       | (NONE, SOME S) => S
   538       | (SOME S, NONE) => S
   539       | (SOME S, SOME S') =>
   540           if Type.eq_sort tsig (S, S') then S'
   541           else error ("Sort constraint inconsistent with default for type variable " ^
   542             quote (Term.string_of_vname' xi)));
   543   in get end;
   544 
   545 local
   546 
   547 fun gen_read_typ' cert syn ctxt def_sort str =
   548   let
   549     val thy = ProofContext.theory_of ctxt;
   550     val _ = Context.check_thy thy;
   551     val T = intern_tycons thy
   552       (Syntax.read_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   553   in cert thy T handle TYPE (msg, _, _) => error msg end
   554   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   555 
   556 fun gen_read_typ cert (thy, def_sort) str =
   557   gen_read_typ' cert (syn_of thy) (ProofContext.init thy) def_sort str;
   558 
   559 in
   560 
   561 fun no_def_sort thy = (thy: theory, K NONE);
   562 
   563 val read_typ'        = gen_read_typ' certify_typ;
   564 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   565 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   566 val read_def_typ     = gen_read_typ certify_typ;
   567 
   568 val read_typ = read_def_typ o no_def_sort;
   569 val read_typ_syntax  = gen_read_typ certify_typ_syntax o no_def_sort;
   570 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev o no_def_sort;
   571 
   572 end;
   573 
   574 
   575 (* type and constant names *)
   576 
   577 fun read_tyname thy raw_c =
   578   let val c = intern_type thy raw_c
   579   in Type (c, replicate (arity_number thy c) dummyT) end;
   580 
   581 val read_const = Consts.read_const o consts_of;
   582 
   583 
   584 
   585 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   586 
   587 (*
   588   def_type: partial map from indexnames to types (constrains Frees and Vars)
   589   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   590   used: context of already used type variables
   591   freeze: if true then generated parameters are turned into TFrees, else TVars
   592 *)
   593 
   594 fun read_def_terms' pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze sTs =
   595   let
   596     val thy = ProofContext.theory_of ctxt;
   597 
   598     (*read terms -- potentially ambiguous*)
   599     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   600     val read =
   601       Syntax.read_term (get_sort thy def_sort) map_const map_free
   602         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn;
   603 
   604     val args = sTs |> map (fn (s, raw_T) =>
   605       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   606       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end);
   607 
   608     (*brute-force disambiguation via type-inference*)
   609     val termss = fold_rev (multiply o fst) args [[]];
   610     val typs = map snd args;
   611 
   612     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   613         (try (Consts.the_constraint consts)) def_type used freeze (ts ~~ typs) |>> map fst)
   614       handle TYPE (msg, _, _) => Exn (ERROR msg);
   615 
   616     val err_results = map infer termss;
   617     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   618     val results = map_filter get_result err_results;
   619 
   620     val ambiguity = length termss;
   621     fun ambig_msg () =
   622       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   623         "Got more than one parse tree.\n\
   624         \Retry with smaller Syntax.ambiguity_level for more information."
   625       else "";
   626   in
   627     if null results then cat_error (ambig_msg ()) (cat_lines errs)
   628     else if length results = 1 then
   629       (if ambiguity > ! Syntax.ambiguity_level then
   630         warning "Fortunately, only one parse tree is type correct.\n\
   631           \You may still want to disambiguate your grammar or your input."
   632       else (); hd results)
   633     else cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   634       cat_lines (map (Pretty.string_of_term pp) (maps fst results)))
   635   end;
   636 
   637 fun read_def_terms (thy, types, sorts) used freeze sTs =
   638   let
   639     val pp = pp thy;
   640     val consts = consts_of thy;
   641     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   642     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   643     val (ts, inst) =
   644       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   645         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   646   in (map cert_consts ts, inst) end;
   647 
   648 fun simple_read_term thy T s =
   649   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   650   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   651 
   652 fun read_term thy = simple_read_term thy dummyT;
   653 fun read_prop thy = simple_read_term thy propT;
   654 
   655 
   656 
   657 (** signature extension functions **)  (*exception ERROR/TYPE*)
   658 
   659 (* add default sort *)
   660 
   661 fun gen_add_defsort prep_sort s thy =
   662   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   663 
   664 val add_defsort = gen_add_defsort read_sort;
   665 val add_defsort_i = gen_add_defsort certify_sort;
   666 
   667 
   668 (* add type constructors *)
   669 
   670 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   671   let
   672     val syn' = Syntax.extend_type_gram types syn;
   673     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   674     val tsig' = Type.add_types naming decls tsig;
   675   in (naming, syn', tsig', consts) end);
   676 
   677 fun add_typedecls decls thy =
   678   let
   679     fun type_of (a, vs: string list, mx) =
   680       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   681       else error ("Duplicate parameters in type declaration: " ^ quote a);
   682   in add_types (map type_of decls) thy end;
   683 
   684 
   685 (* add nonterminals *)
   686 
   687 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   688   let
   689     val syn' = Syntax.extend_consts ns syn;
   690     val tsig' = Type.add_nonterminals naming ns tsig;
   691   in (naming, syn', tsig', consts) end);
   692 
   693 
   694 (* add type abbreviations *)
   695 
   696 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   697   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   698     let
   699       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   700       val a' = Syntax.type_name a mx;
   701       val abbr = (a', vs, prep_typ thy rhs)
   702         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   703       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   704     in (naming, syn', tsig', consts) end);
   705 
   706 val add_tyabbrs = fold (gen_add_tyabbr read_typ_syntax);
   707 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   708 
   709 
   710 (* modify syntax *)
   711 
   712 fun gen_syntax change_gram prep_typ mode args thy =
   713   let
   714     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   715       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   716   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   717 
   718 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   719 
   720 val add_modesyntax = gen_add_syntax read_typ_syntax;
   721 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   722 val add_syntax = add_modesyntax Syntax.default_mode;
   723 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   724 val del_modesyntax = gen_syntax Syntax.remove_const_gram read_typ_syntax;
   725 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   726 
   727 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   728   | const_syntax _ _ = NONE;
   729 
   730 fun add_notation mode args thy =
   731   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   732 
   733 
   734 (* add constants *)
   735 
   736 local
   737 
   738 fun gen_add_consts prep_typ authentic raw_args thy =
   739   let
   740     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   741     fun prep (raw_c, raw_T, raw_mx) =
   742       let
   743         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   744         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   745         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   746           cat_error msg ("in declaration of constant " ^ quote c);
   747       in (((c, T), authentic), (c', T, mx)) end;
   748     val args = map prep raw_args;
   749   in
   750     thy
   751     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   752     |> add_syntax_i (map #2 args)
   753   end;
   754 
   755 in
   756 
   757 val add_consts = gen_add_consts read_typ false;
   758 val add_consts_i = gen_add_consts certify_typ false;
   759 val add_consts_authentic = gen_add_consts certify_typ true;
   760 
   761 end;
   762 
   763 
   764 (* add abbreviations *)
   765 
   766 fun add_abbrev mode (c, raw_t) thy =
   767   let
   768     val pp = pp thy;
   769     val prep_tm = Compress.term thy o no_frees pp o
   770       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   771       Term.no_dummy_patterns o cert_term_abbrev thy;
   772     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   773       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   774     val (res, consts') = consts_of thy
   775       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (c, t);
   776   in (res, thy |> map_consts (K consts')) end;
   777 
   778 
   779 (* add constraints *)
   780 
   781 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   782   let
   783     val c = int_const thy raw_c;
   784     fun prepT raw_T =
   785       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   786       in cert_term thy (Const (c, T)); T end
   787       handle TYPE (msg, _, _) => error msg;
   788   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   789 
   790 val add_const_constraint = gen_add_constraint intern_const read_typ;
   791 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   792 
   793 
   794 (* primitive classes and arities *)
   795 
   796 fun primitive_class (bclass, classes) thy =
   797   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   798     let
   799       val syn' = Syntax.extend_consts [bclass] syn;
   800       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   801     in (naming, syn', tsig', consts) end)
   802   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   803 
   804 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   805 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   806 
   807 
   808 (* add translation functions *)
   809 
   810 local
   811 
   812 fun mk trs = map Syntax.mk_trfun trs;
   813 
   814 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   815   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   816 
   817 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   818 
   819 in
   820 
   821 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   822 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   823 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   824 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   825 
   826 end;
   827 
   828 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   829 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   830 
   831 
   832 (* translation rules *)
   833 
   834 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   835   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   836   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   837 
   838 val add_trrules = gen_trrules Syntax.extend_trrules;
   839 val del_trrules = gen_trrules Syntax.remove_trrules;
   840 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   841 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   842 
   843 
   844 (* modify naming *)
   845 
   846 val add_path        = map_naming o NameSpace.add_path;
   847 val no_base_names   = map_naming NameSpace.no_base_names;
   848 val qualified_names = map_naming NameSpace.qualified_names;
   849 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   850 val set_policy      = map_naming o NameSpace.set_policy;
   851 val restore_naming  = map_naming o K o naming_of;
   852 
   853 val parent_path   = add_path "..";
   854 val root_path     = add_path "/";
   855 val absolute_path = add_path "//";
   856 
   857 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   858 
   859 
   860 (* hide names *)
   861 
   862 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   863 val hide_classes_i = map_tsig oo Type.hide_classes;
   864 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   865 val hide_types_i = map_tsig oo Type.hide_types;
   866 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   867 val hide_consts_i = map_consts oo (fold o Consts.hide);
   868 
   869 local
   870 
   871 val kinds =
   872  [("class", (intern_class, can o certify_class, hide_classes_i)),
   873   ("type", (intern_type, declared_tyname, hide_types_i)),
   874   ("const", (intern_const, declared_const, hide_consts_i))];
   875 
   876 fun gen_hide int b (kind, xnames) thy =
   877   (case AList.lookup (op =) kinds kind of
   878     SOME (intern, check, hide) =>
   879       let
   880         val names = if int then map (intern thy) xnames else xnames;
   881         val bads = filter_out (check thy) names;
   882       in
   883         if null bads then hide b names thy
   884         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   885       end
   886   | NONE => error ("Bad name space specification: " ^ quote kind));
   887 
   888 in
   889 
   890 val hide_names = gen_hide true;
   891 val hide_names_i = gen_hide false;
   892 
   893 end;
   894 
   895 end;