src/HOL/Probability/Independent_Family.thy
author hoelzl
Thu May 26 17:59:39 2011 +0200 (2011-05-26)
changeset 42989 40adeda9a8d2
parent 42988 d8f3fc934ff6
child 43340 60e181c4eae4
permissions -rw-r--r--
introduce independence of two random variables
     1 (*  Title:      HOL/Probability/Independent_Family.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {* Independent families of events, event sets, and random variables *}
     6 
     7 theory Independent_Family
     8   imports Probability_Measure
     9 begin
    10 
    11 lemma INT_decseq_offset:
    12   assumes "decseq F"
    13   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
    14 proof safe
    15   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
    16   show "x \<in> F i"
    17   proof cases
    18     from x have "x \<in> F n" by auto
    19     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
    20       unfolding decseq_def by simp
    21     finally show ?thesis .
    22   qed (insert x, simp)
    23 qed auto
    24 
    25 definition (in prob_space)
    26   "indep_events A I \<longleftrightarrow> (A`I \<subseteq> events) \<and>
    27     (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j)))"
    28 
    29 definition (in prob_space)
    30   "indep_event A B \<longleftrightarrow> indep_events (bool_case A B) UNIV"
    31 
    32 definition (in prob_space)
    33   "indep_sets F I \<longleftrightarrow> (\<forall>i\<in>I. F i \<subseteq> events) \<and>
    34     (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> (\<forall>A\<in>Pi J F. prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))))"
    35 
    36 definition (in prob_space)
    37   "indep_set A B \<longleftrightarrow> indep_sets (bool_case A B) UNIV"
    38 
    39 definition (in prob_space)
    40   "indep_vars M' X I \<longleftrightarrow>
    41     (\<forall>i\<in>I. random_variable (M' i) (X i)) \<and>
    42     indep_sets (\<lambda>i. sigma_sets (space M) { X i -` A \<inter> space M | A. A \<in> sets (M' i)}) I"
    43 
    44 definition (in prob_space)
    45   "indep_var Ma A Mb B \<longleftrightarrow> indep_vars (bool_case Ma Mb) (bool_case A B) UNIV"
    46 
    47 lemma (in prob_space) indep_sets_cong[cong]:
    48   "I = J \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i = G i) \<Longrightarrow> indep_sets F I \<longleftrightarrow> indep_sets G J"
    49   by (simp add: indep_sets_def, intro conj_cong all_cong imp_cong ball_cong) blast+
    50 
    51 lemma (in prob_space) indep_sets_singleton_iff_indep_events:
    52   "indep_sets (\<lambda>i. {F i}) I \<longleftrightarrow> indep_events F I"
    53   unfolding indep_sets_def indep_events_def
    54   by (simp, intro conj_cong ball_cong all_cong imp_cong) (auto simp: Pi_iff)
    55 
    56 lemma (in prob_space) indep_events_finite_index_events:
    57   "indep_events F I \<longleftrightarrow> (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_events F J)"
    58   by (auto simp: indep_events_def)
    59 
    60 lemma (in prob_space) indep_sets_finite_index_sets:
    61   "indep_sets F I \<longleftrightarrow> (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_sets F J)"
    62 proof (intro iffI allI impI)
    63   assume *: "\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_sets F J"
    64   show "indep_sets F I" unfolding indep_sets_def
    65   proof (intro conjI ballI allI impI)
    66     fix i assume "i \<in> I"
    67     with *[THEN spec, of "{i}"] show "F i \<subseteq> events"
    68       by (auto simp: indep_sets_def)
    69   qed (insert *, auto simp: indep_sets_def)
    70 qed (auto simp: indep_sets_def)
    71 
    72 lemma (in prob_space) indep_sets_mono_index:
    73   "J \<subseteq> I \<Longrightarrow> indep_sets F I \<Longrightarrow> indep_sets F J"
    74   unfolding indep_sets_def by auto
    75 
    76 lemma (in prob_space) indep_sets_mono_sets:
    77   assumes indep: "indep_sets F I"
    78   assumes mono: "\<And>i. i\<in>I \<Longrightarrow> G i \<subseteq> F i"
    79   shows "indep_sets G I"
    80 proof -
    81   have "(\<forall>i\<in>I. F i \<subseteq> events) \<Longrightarrow> (\<forall>i\<in>I. G i \<subseteq> events)"
    82     using mono by auto
    83   moreover have "\<And>A J. J \<subseteq> I \<Longrightarrow> A \<in> (\<Pi> j\<in>J. G j) \<Longrightarrow> A \<in> (\<Pi> j\<in>J. F j)"
    84     using mono by (auto simp: Pi_iff)
    85   ultimately show ?thesis
    86     using indep by (auto simp: indep_sets_def)
    87 qed
    88 
    89 lemma (in prob_space) indep_setsI:
    90   assumes "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> events"
    91     and "\<And>A J. J \<noteq> {} \<Longrightarrow> J \<subseteq> I \<Longrightarrow> finite J \<Longrightarrow> (\<forall>j\<in>J. A j \<in> F j) \<Longrightarrow> prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
    92   shows "indep_sets F I"
    93   using assms unfolding indep_sets_def by (auto simp: Pi_iff)
    94 
    95 lemma (in prob_space) indep_setsD:
    96   assumes "indep_sets F I" and "J \<subseteq> I" "J \<noteq> {}" "finite J" "\<forall>j\<in>J. A j \<in> F j"
    97   shows "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
    98   using assms unfolding indep_sets_def by auto
    99 
   100 lemma (in prob_space) indep_setI:
   101   assumes ev: "A \<subseteq> events" "B \<subseteq> events"
   102     and indep: "\<And>a b. a \<in> A \<Longrightarrow> b \<in> B \<Longrightarrow> prob (a \<inter> b) = prob a * prob b"
   103   shows "indep_set A B"
   104   unfolding indep_set_def
   105 proof (rule indep_setsI)
   106   fix F J assume "J \<noteq> {}" "J \<subseteq> UNIV"
   107     and F: "\<forall>j\<in>J. F j \<in> (case j of True \<Rightarrow> A | False \<Rightarrow> B)"
   108   have "J \<in> Pow UNIV" by auto
   109   with F `J \<noteq> {}` indep[of "F True" "F False"]
   110   show "prob (\<Inter>j\<in>J. F j) = (\<Prod>j\<in>J. prob (F j))"
   111     unfolding UNIV_bool Pow_insert by (auto simp: ac_simps)
   112 qed (auto split: bool.split simp: ev)
   113 
   114 lemma (in prob_space) indep_setD:
   115   assumes indep: "indep_set A B" and ev: "a \<in> A" "b \<in> B"
   116   shows "prob (a \<inter> b) = prob a * prob b"
   117   using indep[unfolded indep_set_def, THEN indep_setsD, of UNIV "bool_case a b"] ev
   118   by (simp add: ac_simps UNIV_bool)
   119 
   120 lemma (in prob_space)
   121   assumes indep: "indep_set A B"
   122   shows indep_setD_ev1: "A \<subseteq> events"
   123     and indep_setD_ev2: "B \<subseteq> events"
   124   using indep unfolding indep_set_def indep_sets_def UNIV_bool by auto
   125 
   126 lemma (in prob_space) indep_sets_dynkin:
   127   assumes indep: "indep_sets F I"
   128   shows "indep_sets (\<lambda>i. sets (dynkin \<lparr> space = space M, sets = F i \<rparr>)) I"
   129     (is "indep_sets ?F I")
   130 proof (subst indep_sets_finite_index_sets, intro allI impI ballI)
   131   fix J assume "finite J" "J \<subseteq> I" "J \<noteq> {}"
   132   with indep have "indep_sets F J"
   133     by (subst (asm) indep_sets_finite_index_sets) auto
   134   { fix J K assume "indep_sets F K"
   135     let "?G S i" = "if i \<in> S then ?F i else F i"
   136     assume "finite J" "J \<subseteq> K"
   137     then have "indep_sets (?G J) K"
   138     proof induct
   139       case (insert j J)
   140       moreover def G \<equiv> "?G J"
   141       ultimately have G: "indep_sets G K" "\<And>i. i \<in> K \<Longrightarrow> G i \<subseteq> events" and "j \<in> K"
   142         by (auto simp: indep_sets_def)
   143       let ?D = "{E\<in>events. indep_sets (G(j := {E})) K }"
   144       { fix X assume X: "X \<in> events"
   145         assume indep: "\<And>J A. J \<noteq> {} \<Longrightarrow> J \<subseteq> K \<Longrightarrow> finite J \<Longrightarrow> j \<notin> J \<Longrightarrow> (\<forall>i\<in>J. A i \<in> G i)
   146           \<Longrightarrow> prob ((\<Inter>i\<in>J. A i) \<inter> X) = prob X * (\<Prod>i\<in>J. prob (A i))"
   147         have "indep_sets (G(j := {X})) K"
   148         proof (rule indep_setsI)
   149           fix i assume "i \<in> K" then show "(G(j:={X})) i \<subseteq> events"
   150             using G X by auto
   151         next
   152           fix A J assume J: "J \<noteq> {}" "J \<subseteq> K" "finite J" "\<forall>i\<in>J. A i \<in> (G(j := {X})) i"
   153           show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   154           proof cases
   155             assume "j \<in> J"
   156             with J have "A j = X" by auto
   157             show ?thesis
   158             proof cases
   159               assume "J = {j}" then show ?thesis by simp
   160             next
   161               assume "J \<noteq> {j}"
   162               have "prob (\<Inter>i\<in>J. A i) = prob ((\<Inter>i\<in>J-{j}. A i) \<inter> X)"
   163                 using `j \<in> J` `A j = X` by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   164               also have "\<dots> = prob X * (\<Prod>i\<in>J-{j}. prob (A i))"
   165               proof (rule indep)
   166                 show "J - {j} \<noteq> {}" "J - {j} \<subseteq> K" "finite (J - {j})" "j \<notin> J - {j}"
   167                   using J `J \<noteq> {j}` `j \<in> J` by auto
   168                 show "\<forall>i\<in>J - {j}. A i \<in> G i"
   169                   using J by auto
   170               qed
   171               also have "\<dots> = prob (A j) * (\<Prod>i\<in>J-{j}. prob (A i))"
   172                 using `A j = X` by simp
   173               also have "\<dots> = (\<Prod>i\<in>J. prob (A i))"
   174                 unfolding setprod.insert_remove[OF `finite J`, symmetric, of "\<lambda>i. prob  (A i)"]
   175                 using `j \<in> J` by (simp add: insert_absorb)
   176               finally show ?thesis .
   177             qed
   178           next
   179             assume "j \<notin> J"
   180             with J have "\<forall>i\<in>J. A i \<in> G i" by (auto split: split_if_asm)
   181             with J show ?thesis
   182               by (intro indep_setsD[OF G(1)]) auto
   183           qed
   184         qed }
   185       note indep_sets_insert = this
   186       have "dynkin_system \<lparr> space = space M, sets = ?D \<rparr>"
   187       proof (rule dynkin_systemI', simp_all cong del: indep_sets_cong, safe)
   188         show "indep_sets (G(j := {{}})) K"
   189           by (rule indep_sets_insert) auto
   190       next
   191         fix X assume X: "X \<in> events" and G': "indep_sets (G(j := {X})) K"
   192         show "indep_sets (G(j := {space M - X})) K"
   193         proof (rule indep_sets_insert)
   194           fix J A assume J: "J \<noteq> {}" "J \<subseteq> K" "finite J" "j \<notin> J" and A: "\<forall>i\<in>J. A i \<in> G i"
   195           then have A_sets: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> events"
   196             using G by auto
   197           have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) =
   198               prob ((\<Inter>j\<in>J. A j) - (\<Inter>i\<in>insert j J. (A(j := X)) i))"
   199             using A_sets sets_into_space X `J \<noteq> {}`
   200             by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   201           also have "\<dots> = prob (\<Inter>j\<in>J. A j) - prob (\<Inter>i\<in>insert j J. (A(j := X)) i)"
   202             using J `J \<noteq> {}` `j \<notin> J` A_sets X sets_into_space
   203             by (auto intro!: finite_measure_Diff finite_INT split: split_if_asm)
   204           finally have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) =
   205               prob (\<Inter>j\<in>J. A j) - prob (\<Inter>i\<in>insert j J. (A(j := X)) i)" .
   206           moreover {
   207             have "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   208               using J A `finite J` by (intro indep_setsD[OF G(1)]) auto
   209             then have "prob (\<Inter>j\<in>J. A j) = prob (space M) * (\<Prod>i\<in>J. prob (A i))"
   210               using prob_space by simp }
   211           moreover {
   212             have "prob (\<Inter>i\<in>insert j J. (A(j := X)) i) = (\<Prod>i\<in>insert j J. prob ((A(j := X)) i))"
   213               using J A `j \<in> K` by (intro indep_setsD[OF G']) auto
   214             then have "prob (\<Inter>i\<in>insert j J. (A(j := X)) i) = prob X * (\<Prod>i\<in>J. prob (A i))"
   215               using `finite J` `j \<notin> J` by (auto intro!: setprod_cong) }
   216           ultimately have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) = (prob (space M) - prob X) * (\<Prod>i\<in>J. prob (A i))"
   217             by (simp add: field_simps)
   218           also have "\<dots> = prob (space M - X) * (\<Prod>i\<in>J. prob (A i))"
   219             using X A by (simp add: finite_measure_compl)
   220           finally show "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) = prob (space M - X) * (\<Prod>i\<in>J. prob (A i))" .
   221         qed (insert X, auto)
   222       next
   223         fix F :: "nat \<Rightarrow> 'a set" assume disj: "disjoint_family F" and "range F \<subseteq> ?D"
   224         then have F: "\<And>i. F i \<in> events" "\<And>i. indep_sets (G(j:={F i})) K" by auto
   225         show "indep_sets (G(j := {\<Union>k. F k})) K"
   226         proof (rule indep_sets_insert)
   227           fix J A assume J: "j \<notin> J" "J \<noteq> {}" "J \<subseteq> K" "finite J" and A: "\<forall>i\<in>J. A i \<in> G i"
   228           then have A_sets: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> events"
   229             using G by auto
   230           have "prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)) = prob (\<Union>k. (\<Inter>i\<in>insert j J. (A(j := F k)) i))"
   231             using `J \<noteq> {}` `j \<notin> J` `j \<in> K` by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   232           moreover have "(\<lambda>k. prob (\<Inter>i\<in>insert j J. (A(j := F k)) i)) sums prob (\<Union>k. (\<Inter>i\<in>insert j J. (A(j := F k)) i))"
   233           proof (rule finite_measure_UNION)
   234             show "disjoint_family (\<lambda>k. \<Inter>i\<in>insert j J. (A(j := F k)) i)"
   235               using disj by (rule disjoint_family_on_bisimulation) auto
   236             show "range (\<lambda>k. \<Inter>i\<in>insert j J. (A(j := F k)) i) \<subseteq> events"
   237               using A_sets F `finite J` `J \<noteq> {}` `j \<notin> J` by (auto intro!: Int)
   238           qed
   239           moreover { fix k
   240             from J A `j \<in> K` have "prob (\<Inter>i\<in>insert j J. (A(j := F k)) i) = prob (F k) * (\<Prod>i\<in>J. prob (A i))"
   241               by (subst indep_setsD[OF F(2)]) (auto intro!: setprod_cong split: split_if_asm)
   242             also have "\<dots> = prob (F k) * prob (\<Inter>i\<in>J. A i)"
   243               using J A `j \<in> K` by (subst indep_setsD[OF G(1)]) auto
   244             finally have "prob (\<Inter>i\<in>insert j J. (A(j := F k)) i) = prob (F k) * prob (\<Inter>i\<in>J. A i)" . }
   245           ultimately have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)))"
   246             by simp
   247           moreover
   248           have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob (\<Union>k. F k) * prob (\<Inter>i\<in>J. A i))"
   249             using disj F(1) by (intro finite_measure_UNION sums_mult2) auto
   250           then have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob (\<Union>k. F k) * (\<Prod>i\<in>J. prob (A i)))"
   251             using J A `j \<in> K` by (subst indep_setsD[OF G(1), symmetric]) auto
   252           ultimately
   253           show "prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)) = prob (\<Union>k. F k) * (\<Prod>j\<in>J. prob (A j))"
   254             by (auto dest!: sums_unique)
   255         qed (insert F, auto)
   256       qed (insert sets_into_space, auto)
   257       then have mono: "sets (dynkin \<lparr>space = space M, sets = G j\<rparr>) \<subseteq>
   258         sets \<lparr>space = space M, sets = {E \<in> events. indep_sets (G(j := {E})) K}\<rparr>"
   259       proof (rule dynkin_system.dynkin_subset, simp_all cong del: indep_sets_cong, safe)
   260         fix X assume "X \<in> G j"
   261         then show "X \<in> events" using G `j \<in> K` by auto
   262         from `indep_sets G K`
   263         show "indep_sets (G(j := {X})) K"
   264           by (rule indep_sets_mono_sets) (insert `X \<in> G j`, auto)
   265       qed
   266       have "indep_sets (G(j:=?D)) K"
   267       proof (rule indep_setsI)
   268         fix i assume "i \<in> K" then show "(G(j := ?D)) i \<subseteq> events"
   269           using G(2) by auto
   270       next
   271         fix A J assume J: "J\<noteq>{}" "J \<subseteq> K" "finite J" and A: "\<forall>i\<in>J. A i \<in> (G(j := ?D)) i"
   272         show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   273         proof cases
   274           assume "j \<in> J"
   275           with A have indep: "indep_sets (G(j := {A j})) K" by auto
   276           from J A show ?thesis
   277             by (intro indep_setsD[OF indep]) auto
   278         next
   279           assume "j \<notin> J"
   280           with J A have "\<forall>i\<in>J. A i \<in> G i" by (auto split: split_if_asm)
   281           with J show ?thesis
   282             by (intro indep_setsD[OF G(1)]) auto
   283         qed
   284       qed
   285       then have "indep_sets (G(j:=sets (dynkin \<lparr>space = space M, sets = G j\<rparr>))) K"
   286         by (rule indep_sets_mono_sets) (insert mono, auto)
   287       then show ?case
   288         by (rule indep_sets_mono_sets) (insert `j \<in> K` `j \<notin> J`, auto simp: G_def)
   289     qed (insert `indep_sets F K`, simp) }
   290   from this[OF `indep_sets F J` `finite J` subset_refl]
   291   show "indep_sets (\<lambda>i. sets (dynkin \<lparr> space = space M, sets = F i \<rparr>)) J"
   292     by (rule indep_sets_mono_sets) auto
   293 qed
   294 
   295 lemma (in prob_space) indep_sets_sigma:
   296   assumes indep: "indep_sets F I"
   297   assumes stable: "\<And>i. i \<in> I \<Longrightarrow> Int_stable \<lparr> space = space M, sets = F i \<rparr>"
   298   shows "indep_sets (\<lambda>i. sets (sigma \<lparr> space = space M, sets = F i \<rparr>)) I"
   299 proof -
   300   from indep_sets_dynkin[OF indep]
   301   show ?thesis
   302   proof (rule indep_sets_mono_sets, subst sigma_eq_dynkin, simp_all add: stable)
   303     fix i assume "i \<in> I"
   304     with indep have "F i \<subseteq> events" by (auto simp: indep_sets_def)
   305     with sets_into_space show "F i \<subseteq> Pow (space M)" by auto
   306   qed
   307 qed
   308 
   309 lemma (in prob_space) indep_sets_sigma_sets:
   310   assumes "indep_sets F I"
   311   assumes "\<And>i. i \<in> I \<Longrightarrow> Int_stable \<lparr> space = space M, sets = F i \<rparr>"
   312   shows "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I"
   313   using indep_sets_sigma[OF assms] by (simp add: sets_sigma)
   314 
   315 lemma (in prob_space) indep_sets_sigma_sets_iff:
   316   assumes "\<And>i. i \<in> I \<Longrightarrow> Int_stable \<lparr> space = space M, sets = F i \<rparr>"
   317   shows "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I \<longleftrightarrow> indep_sets F I"
   318 proof
   319   assume "indep_sets F I" then show "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I"
   320     by (rule indep_sets_sigma_sets) fact
   321 next
   322   assume "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I" then show "indep_sets F I"
   323     by (rule indep_sets_mono_sets) (intro subsetI sigma_sets.Basic)
   324 qed
   325 
   326 lemma (in prob_space) indep_sets2_eq:
   327   "indep_set A B \<longleftrightarrow> A \<subseteq> events \<and> B \<subseteq> events \<and> (\<forall>a\<in>A. \<forall>b\<in>B. prob (a \<inter> b) = prob a * prob b)"
   328   unfolding indep_set_def
   329 proof (intro iffI ballI conjI)
   330   assume indep: "indep_sets (bool_case A B) UNIV"
   331   { fix a b assume "a \<in> A" "b \<in> B"
   332     with indep_setsD[OF indep, of UNIV "bool_case a b"]
   333     show "prob (a \<inter> b) = prob a * prob b"
   334       unfolding UNIV_bool by (simp add: ac_simps) }
   335   from indep show "A \<subseteq> events" "B \<subseteq> events"
   336     unfolding indep_sets_def UNIV_bool by auto
   337 next
   338   assume *: "A \<subseteq> events \<and> B \<subseteq> events \<and> (\<forall>a\<in>A. \<forall>b\<in>B. prob (a \<inter> b) = prob a * prob b)"
   339   show "indep_sets (bool_case A B) UNIV"
   340   proof (rule indep_setsI)
   341     fix i show "(case i of True \<Rightarrow> A | False \<Rightarrow> B) \<subseteq> events"
   342       using * by (auto split: bool.split)
   343   next
   344     fix J X assume "J \<noteq> {}" "J \<subseteq> UNIV" and X: "\<forall>j\<in>J. X j \<in> (case j of True \<Rightarrow> A | False \<Rightarrow> B)"
   345     then have "J = {True} \<or> J = {False} \<or> J = {True,False}"
   346       by (auto simp: UNIV_bool)
   347     then show "prob (\<Inter>j\<in>J. X j) = (\<Prod>j\<in>J. prob (X j))"
   348       using X * by auto
   349   qed
   350 qed
   351 
   352 lemma (in prob_space) indep_set_sigma_sets:
   353   assumes "indep_set A B"
   354   assumes A: "Int_stable \<lparr> space = space M, sets = A \<rparr>"
   355   assumes B: "Int_stable \<lparr> space = space M, sets = B \<rparr>"
   356   shows "indep_set (sigma_sets (space M) A) (sigma_sets (space M) B)"
   357 proof -
   358   have "indep_sets (\<lambda>i. sigma_sets (space M) (case i of True \<Rightarrow> A | False \<Rightarrow> B)) UNIV"
   359   proof (rule indep_sets_sigma_sets)
   360     show "indep_sets (bool_case A B) UNIV"
   361       by (rule `indep_set A B`[unfolded indep_set_def])
   362     fix i show "Int_stable \<lparr>space = space M, sets = case i of True \<Rightarrow> A | False \<Rightarrow> B\<rparr>"
   363       using A B by (cases i) auto
   364   qed
   365   then show ?thesis
   366     unfolding indep_set_def
   367     by (rule indep_sets_mono_sets) (auto split: bool.split)
   368 qed
   369 
   370 lemma (in prob_space) indep_sets_collect_sigma:
   371   fixes I :: "'j \<Rightarrow> 'i set" and J :: "'j set" and E :: "'i \<Rightarrow> 'a set set"
   372   assumes indep: "indep_sets E (\<Union>j\<in>J. I j)"
   373   assumes Int_stable: "\<And>i j. j \<in> J \<Longrightarrow> i \<in> I j \<Longrightarrow> Int_stable \<lparr>space = space M, sets = E i\<rparr>"
   374   assumes disjoint: "disjoint_family_on I J"
   375   shows "indep_sets (\<lambda>j. sigma_sets (space M) (\<Union>i\<in>I j. E i)) J"
   376 proof -
   377   let "?E j" = "{\<Inter>k\<in>K. E' k| E' K. finite K \<and> K \<noteq> {} \<and> K \<subseteq> I j \<and> (\<forall>k\<in>K. E' k \<in> E k) }"
   378 
   379   from indep have E: "\<And>j i. j \<in> J \<Longrightarrow> i \<in> I j \<Longrightarrow> E i \<subseteq> events"
   380     unfolding indep_sets_def by auto
   381   { fix j
   382     let ?S = "sigma \<lparr> space = space M, sets = (\<Union>i\<in>I j. E i) \<rparr>"
   383     assume "j \<in> J"
   384     from E[OF this] interpret S: sigma_algebra ?S
   385       using sets_into_space by (intro sigma_algebra_sigma) auto
   386 
   387     have "sigma_sets (space M) (\<Union>i\<in>I j. E i) = sigma_sets (space M) (?E j)"
   388     proof (rule sigma_sets_eqI)
   389       fix A assume "A \<in> (\<Union>i\<in>I j. E i)"
   390       then guess i ..
   391       then show "A \<in> sigma_sets (space M) (?E j)"
   392         by (auto intro!: sigma_sets.intros exI[of _ "{i}"] exI[of _ "\<lambda>i. A"])
   393     next
   394       fix A assume "A \<in> ?E j"
   395       then obtain E' K where "finite K" "K \<noteq> {}" "K \<subseteq> I j" "\<And>k. k \<in> K \<Longrightarrow> E' k \<in> E k"
   396         and A: "A = (\<Inter>k\<in>K. E' k)"
   397         by auto
   398       then have "A \<in> sets ?S" unfolding A
   399         by (safe intro!: S.finite_INT)
   400            (auto simp: sets_sigma intro!: sigma_sets.Basic)
   401       then show "A \<in> sigma_sets (space M) (\<Union>i\<in>I j. E i)"
   402         by (simp add: sets_sigma)
   403     qed }
   404   moreover have "indep_sets (\<lambda>j. sigma_sets (space M) (?E j)) J"
   405   proof (rule indep_sets_sigma_sets)
   406     show "indep_sets ?E J"
   407     proof (intro indep_setsI)
   408       fix j assume "j \<in> J" with E show "?E j \<subseteq> events" by (force  intro!: finite_INT)
   409     next
   410       fix K A assume K: "K \<noteq> {}" "K \<subseteq> J" "finite K"
   411         and "\<forall>j\<in>K. A j \<in> ?E j"
   412       then have "\<forall>j\<in>K. \<exists>E' L. A j = (\<Inter>l\<in>L. E' l) \<and> finite L \<and> L \<noteq> {} \<and> L \<subseteq> I j \<and> (\<forall>l\<in>L. E' l \<in> E l)"
   413         by simp
   414       from bchoice[OF this] guess E' ..
   415       from bchoice[OF this] obtain L
   416         where A: "\<And>j. j\<in>K \<Longrightarrow> A j = (\<Inter>l\<in>L j. E' j l)"
   417         and L: "\<And>j. j\<in>K \<Longrightarrow> finite (L j)" "\<And>j. j\<in>K \<Longrightarrow> L j \<noteq> {}" "\<And>j. j\<in>K \<Longrightarrow> L j \<subseteq> I j"
   418         and E': "\<And>j l. j\<in>K \<Longrightarrow> l \<in> L j \<Longrightarrow> E' j l \<in> E l"
   419         by auto
   420 
   421       { fix k l j assume "k \<in> K" "j \<in> K" "l \<in> L j" "l \<in> L k"
   422         have "k = j"
   423         proof (rule ccontr)
   424           assume "k \<noteq> j"
   425           with disjoint `K \<subseteq> J` `k \<in> K` `j \<in> K` have "I k \<inter> I j = {}"
   426             unfolding disjoint_family_on_def by auto
   427           with L(2,3)[OF `j \<in> K`] L(2,3)[OF `k \<in> K`]
   428           show False using `l \<in> L k` `l \<in> L j` by auto
   429         qed }
   430       note L_inj = this
   431 
   432       def k \<equiv> "\<lambda>l. (SOME k. k \<in> K \<and> l \<in> L k)"
   433       { fix x j l assume *: "j \<in> K" "l \<in> L j"
   434         have "k l = j" unfolding k_def
   435         proof (rule some_equality)
   436           fix k assume "k \<in> K \<and> l \<in> L k"
   437           with * L_inj show "k = j" by auto
   438         qed (insert *, simp) }
   439       note k_simp[simp] = this
   440       let "?E' l" = "E' (k l) l"
   441       have "prob (\<Inter>j\<in>K. A j) = prob (\<Inter>l\<in>(\<Union>k\<in>K. L k). ?E' l)"
   442         by (auto simp: A intro!: arg_cong[where f=prob])
   443       also have "\<dots> = (\<Prod>l\<in>(\<Union>k\<in>K. L k). prob (?E' l))"
   444         using L K E' by (intro indep_setsD[OF indep]) (simp_all add: UN_mono)
   445       also have "\<dots> = (\<Prod>j\<in>K. \<Prod>l\<in>L j. prob (E' j l))"
   446         using K L L_inj by (subst setprod_UN_disjoint) auto
   447       also have "\<dots> = (\<Prod>j\<in>K. prob (A j))"
   448         using K L E' by (auto simp add: A intro!: setprod_cong indep_setsD[OF indep, symmetric]) blast
   449       finally show "prob (\<Inter>j\<in>K. A j) = (\<Prod>j\<in>K. prob (A j))" .
   450     qed
   451   next
   452     fix j assume "j \<in> J"
   453     show "Int_stable \<lparr> space = space M, sets = ?E j \<rparr>"
   454     proof (rule Int_stableI)
   455       fix a assume "a \<in> ?E j" then obtain Ka Ea
   456         where a: "a = (\<Inter>k\<in>Ka. Ea k)" "finite Ka" "Ka \<noteq> {}" "Ka \<subseteq> I j" "\<And>k. k\<in>Ka \<Longrightarrow> Ea k \<in> E k" by auto
   457       fix b assume "b \<in> ?E j" then obtain Kb Eb
   458         where b: "b = (\<Inter>k\<in>Kb. Eb k)" "finite Kb" "Kb \<noteq> {}" "Kb \<subseteq> I j" "\<And>k. k\<in>Kb \<Longrightarrow> Eb k \<in> E k" by auto
   459       let ?A = "\<lambda>k. (if k \<in> Ka \<inter> Kb then Ea k \<inter> Eb k else if k \<in> Kb then Eb k else if k \<in> Ka then Ea k else {})"
   460       have "a \<inter> b = INTER (Ka \<union> Kb) ?A"
   461         by (simp add: a b set_eq_iff) auto
   462       with a b `j \<in> J` Int_stableD[OF Int_stable] show "a \<inter> b \<in> ?E j"
   463         by (intro CollectI exI[of _ "Ka \<union> Kb"] exI[of _ ?A]) auto
   464     qed
   465   qed
   466   ultimately show ?thesis
   467     by (simp cong: indep_sets_cong)
   468 qed
   469 
   470 definition (in prob_space) terminal_events where
   471   "terminal_events A = (\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   472 
   473 lemma (in prob_space) terminal_events_sets:
   474   assumes A: "\<And>i. A i \<subseteq> events"
   475   assumes "\<And>i::nat. sigma_algebra \<lparr>space = space M, sets = A i\<rparr>"
   476   assumes X: "X \<in> terminal_events A"
   477   shows "X \<in> events"
   478 proof -
   479   let ?A = "(\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   480   interpret A: sigma_algebra "\<lparr>space = space M, sets = A i\<rparr>" for i by fact
   481   from X have "\<And>n. X \<in> sigma_sets (space M) (UNION {n..} A)" by (auto simp: terminal_events_def)
   482   from this[of 0] have "X \<in> sigma_sets (space M) (UNION UNIV A)" by simp
   483   then show "X \<in> events"
   484     by induct (insert A, auto)
   485 qed
   486 
   487 lemma (in prob_space) sigma_algebra_terminal_events:
   488   assumes "\<And>i::nat. sigma_algebra \<lparr>space = space M, sets = A i\<rparr>"
   489   shows "sigma_algebra \<lparr> space = space M, sets = terminal_events A \<rparr>"
   490   unfolding terminal_events_def
   491 proof (simp add: sigma_algebra_iff2, safe)
   492   let ?A = "(\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   493   interpret A: sigma_algebra "\<lparr>space = space M, sets = A i\<rparr>" for i by fact
   494   { fix X x assume "X \<in> ?A" "x \<in> X" 
   495     then have "\<And>n. X \<in> sigma_sets (space M) (UNION {n..} A)" by auto
   496     from this[of 0] have "X \<in> sigma_sets (space M) (UNION UNIV A)" by simp
   497     then have "X \<subseteq> space M"
   498       by induct (insert A.sets_into_space, auto)
   499     with `x \<in> X` show "x \<in> space M" by auto }
   500   { fix F :: "nat \<Rightarrow> 'a set" and n assume "range F \<subseteq> ?A"
   501     then show "(UNION UNIV F) \<in> sigma_sets (space M) (UNION {n..} A)"
   502       by (intro sigma_sets.Union) auto }
   503 qed (auto intro!: sigma_sets.Compl sigma_sets.Empty)
   504 
   505 lemma (in prob_space) kolmogorov_0_1_law:
   506   fixes A :: "nat \<Rightarrow> 'a set set"
   507   assumes A: "\<And>i. A i \<subseteq> events"
   508   assumes "\<And>i::nat. sigma_algebra \<lparr>space = space M, sets = A i\<rparr>"
   509   assumes indep: "indep_sets A UNIV"
   510   and X: "X \<in> terminal_events A"
   511   shows "prob X = 0 \<or> prob X = 1"
   512 proof -
   513   let ?D = "\<lparr> space = space M, sets = {D \<in> events. prob (X \<inter> D) = prob X * prob D} \<rparr>"
   514   interpret A: sigma_algebra "\<lparr>space = space M, sets = A i\<rparr>" for i by fact
   515   interpret T: sigma_algebra "\<lparr> space = space M, sets = terminal_events A \<rparr>"
   516     by (rule sigma_algebra_terminal_events) fact
   517   have "X \<subseteq> space M" using T.space_closed X by auto
   518 
   519   have X_in: "X \<in> events"
   520     by (rule terminal_events_sets) fact+
   521 
   522   interpret D: dynkin_system ?D
   523   proof (rule dynkin_systemI)
   524     fix D assume "D \<in> sets ?D" then show "D \<subseteq> space ?D"
   525       using sets_into_space by auto
   526   next
   527     show "space ?D \<in> sets ?D"
   528       using prob_space `X \<subseteq> space M` by (simp add: Int_absorb2)
   529   next
   530     fix A assume A: "A \<in> sets ?D"
   531     have "prob (X \<inter> (space M - A)) = prob (X - (X \<inter> A))"
   532       using `X \<subseteq> space M` by (auto intro!: arg_cong[where f=prob])
   533     also have "\<dots> = prob X - prob (X \<inter> A)"
   534       using X_in A by (intro finite_measure_Diff) auto
   535     also have "\<dots> = prob X * prob (space M) - prob X * prob A"
   536       using A prob_space by auto
   537     also have "\<dots> = prob X * prob (space M - A)"
   538       using X_in A sets_into_space
   539       by (subst finite_measure_Diff) (auto simp: field_simps)
   540     finally show "space ?D - A \<in> sets ?D"
   541       using A `X \<subseteq> space M` by auto
   542   next
   543     fix F :: "nat \<Rightarrow> 'a set" assume dis: "disjoint_family F" and "range F \<subseteq> sets ?D"
   544     then have F: "range F \<subseteq> events" "\<And>i. prob (X \<inter> F i) = prob X * prob (F i)"
   545       by auto
   546     have "(\<lambda>i. prob (X \<inter> F i)) sums prob (\<Union>i. X \<inter> F i)"
   547     proof (rule finite_measure_UNION)
   548       show "range (\<lambda>i. X \<inter> F i) \<subseteq> events"
   549         using F X_in by auto
   550       show "disjoint_family (\<lambda>i. X \<inter> F i)"
   551         using dis by (rule disjoint_family_on_bisimulation) auto
   552     qed
   553     with F have "(\<lambda>i. prob X * prob (F i)) sums prob (X \<inter> (\<Union>i. F i))"
   554       by simp
   555     moreover have "(\<lambda>i. prob X * prob (F i)) sums (prob X * prob (\<Union>i. F i))"
   556       by (intro mult_right.sums finite_measure_UNION F dis)
   557     ultimately have "prob (X \<inter> (\<Union>i. F i)) = prob X * prob (\<Union>i. F i)"
   558       by (auto dest!: sums_unique)
   559     with F show "(\<Union>i. F i) \<in> sets ?D"
   560       by auto
   561   qed
   562 
   563   { fix n
   564     have "indep_sets (\<lambda>b. sigma_sets (space M) (\<Union>m\<in>bool_case {..n} {Suc n..} b. A m)) UNIV"
   565     proof (rule indep_sets_collect_sigma)
   566       have *: "(\<Union>b. case b of True \<Rightarrow> {..n} | False \<Rightarrow> {Suc n..}) = UNIV" (is "?U = _")
   567         by (simp split: bool.split add: set_eq_iff) (metis not_less_eq_eq)
   568       with indep show "indep_sets A ?U" by simp
   569       show "disjoint_family (bool_case {..n} {Suc n..})"
   570         unfolding disjoint_family_on_def by (auto split: bool.split)
   571       fix m
   572       show "Int_stable \<lparr>space = space M, sets = A m\<rparr>"
   573         unfolding Int_stable_def using A.Int by auto
   574     qed
   575     also have "(\<lambda>b. sigma_sets (space M) (\<Union>m\<in>bool_case {..n} {Suc n..} b. A m)) = 
   576       bool_case (sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) (sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m))"
   577       by (auto intro!: ext split: bool.split)
   578     finally have indep: "indep_set (sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) (sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m))"
   579       unfolding indep_set_def by simp
   580 
   581     have "sigma_sets (space M) (\<Union>m\<in>{..n}. A m) \<subseteq> sets ?D"
   582     proof (simp add: subset_eq, rule)
   583       fix D assume D: "D \<in> sigma_sets (space M) (\<Union>m\<in>{..n}. A m)"
   584       have "X \<in> sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m)"
   585         using X unfolding terminal_events_def by simp
   586       from indep_setD[OF indep D this] indep_setD_ev1[OF indep] D
   587       show "D \<in> events \<and> prob (X \<inter> D) = prob X * prob D"
   588         by (auto simp add: ac_simps)
   589     qed }
   590   then have "(\<Union>n. sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) \<subseteq> sets ?D" (is "?A \<subseteq> _")
   591     by auto
   592 
   593   have "sigma \<lparr> space = space M, sets = ?A \<rparr> =
   594     dynkin \<lparr> space = space M, sets = ?A \<rparr>" (is "sigma ?UA = dynkin ?UA")
   595   proof (rule sigma_eq_dynkin)
   596     { fix B n assume "B \<in> sigma_sets (space M) (\<Union>m\<in>{..n}. A m)"
   597       then have "B \<subseteq> space M"
   598         by induct (insert A sets_into_space, auto) }
   599     then show "sets ?UA \<subseteq> Pow (space ?UA)" by auto
   600     show "Int_stable ?UA"
   601     proof (rule Int_stableI)
   602       fix a assume "a \<in> ?A" then guess n .. note a = this
   603       fix b assume "b \<in> ?A" then guess m .. note b = this
   604       interpret Amn: sigma_algebra "sigma \<lparr>space = space M, sets = (\<Union>i\<in>{..max m n}. A i)\<rparr>"
   605         using A sets_into_space by (intro sigma_algebra_sigma) auto
   606       have "sigma_sets (space M) (\<Union>i\<in>{..n}. A i) \<subseteq> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   607         by (intro sigma_sets_subseteq UN_mono) auto
   608       with a have "a \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)" by auto
   609       moreover
   610       have "sigma_sets (space M) (\<Union>i\<in>{..m}. A i) \<subseteq> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   611         by (intro sigma_sets_subseteq UN_mono) auto
   612       with b have "b \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)" by auto
   613       ultimately have "a \<inter> b \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   614         using Amn.Int[of a b] by (simp add: sets_sigma)
   615       then show "a \<inter> b \<in> (\<Union>n. sigma_sets (space M) (\<Union>i\<in>{..n}. A i))" by auto
   616     qed
   617   qed
   618   moreover have "sets (dynkin ?UA) \<subseteq> sets ?D"
   619   proof (rule D.dynkin_subset)
   620     show "sets ?UA \<subseteq> sets ?D" using `?A \<subseteq> sets ?D` by auto
   621   qed simp
   622   ultimately have "sets (sigma ?UA) \<subseteq> sets ?D" by simp
   623   moreover
   624   have "\<And>n. sigma_sets (space M) (\<Union>i\<in>{n..}. A i) \<subseteq> sigma_sets (space M) ?A"
   625     by (intro sigma_sets_subseteq UN_mono) (auto intro: sigma_sets.Basic)
   626   then have "terminal_events A \<subseteq> sets (sigma ?UA)"
   627     unfolding sets_sigma terminal_events_def by auto
   628   moreover note `X \<in> terminal_events A`
   629   ultimately have "X \<in> sets ?D" by auto
   630   then show ?thesis by auto
   631 qed
   632 
   633 lemma (in prob_space) borel_0_1_law:
   634   fixes F :: "nat \<Rightarrow> 'a set"
   635   assumes F: "range F \<subseteq> events" "indep_events F UNIV"
   636   shows "prob (\<Inter>n. \<Union>m\<in>{n..}. F m) = 0 \<or> prob (\<Inter>n. \<Union>m\<in>{n..}. F m) = 1"
   637 proof (rule kolmogorov_0_1_law[of "\<lambda>i. sigma_sets (space M) { F i }"])
   638   show "\<And>i. sigma_sets (space M) {F i} \<subseteq> events"
   639     using F(1) sets_into_space
   640     by (subst sigma_sets_singleton) auto
   641   { fix i show "sigma_algebra \<lparr>space = space M, sets = sigma_sets (space M) {F i}\<rparr>"
   642       using sigma_algebra_sigma[of "\<lparr>space = space M, sets = {F i}\<rparr>"] F sets_into_space
   643       by (auto simp add: sigma_def) }
   644   show "indep_sets (\<lambda>i. sigma_sets (space M) {F i}) UNIV"
   645   proof (rule indep_sets_sigma_sets)
   646     show "indep_sets (\<lambda>i. {F i}) UNIV"
   647       unfolding indep_sets_singleton_iff_indep_events by fact
   648     fix i show "Int_stable \<lparr>space = space M, sets = {F i}\<rparr>"
   649       unfolding Int_stable_def by simp
   650   qed
   651   let "?Q n" = "\<Union>i\<in>{n..}. F i"
   652   show "(\<Inter>n. \<Union>m\<in>{n..}. F m) \<in> terminal_events (\<lambda>i. sigma_sets (space M) {F i})"
   653     unfolding terminal_events_def
   654   proof
   655     fix j
   656     interpret S: sigma_algebra "sigma \<lparr> space = space M, sets = (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})\<rparr>"
   657       using order_trans[OF F(1) space_closed]
   658       by (intro sigma_algebra_sigma) (simp add: sigma_sets_singleton subset_eq)
   659     have "(\<Inter>n. ?Q n) = (\<Inter>n\<in>{j..}. ?Q n)"
   660       by (intro decseq_SucI INT_decseq_offset UN_mono) auto
   661     also have "\<dots> \<in> sets (sigma \<lparr> space = space M, sets = (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})\<rparr>)"
   662       using order_trans[OF F(1) space_closed]
   663       by (safe intro!: S.countable_INT S.countable_UN)
   664          (auto simp: sets_sigma sigma_sets_singleton intro!: sigma_sets.Basic bexI)
   665     finally show "(\<Inter>n. ?Q n) \<in> sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   666       by (simp add: sets_sigma)
   667   qed
   668 qed
   669 
   670 lemma (in prob_space) indep_sets_finite:
   671   assumes I: "I \<noteq> {}" "finite I"
   672     and F: "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> events" "\<And>i. i \<in> I \<Longrightarrow> space M \<in> F i"
   673   shows "indep_sets F I \<longleftrightarrow> (\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j)))"
   674 proof
   675   assume *: "indep_sets F I"
   676   from I show "\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j))"
   677     by (intro indep_setsD[OF *] ballI) auto
   678 next
   679   assume indep: "\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j))"
   680   show "indep_sets F I"
   681   proof (rule indep_setsI[OF F(1)])
   682     fix A J assume J: "J \<noteq> {}" "J \<subseteq> I" "finite J"
   683     assume A: "\<forall>j\<in>J. A j \<in> F j"
   684     let "?A j" = "if j \<in> J then A j else space M"
   685     have "prob (\<Inter>j\<in>I. ?A j) = prob (\<Inter>j\<in>J. A j)"
   686       using subset_trans[OF F(1) space_closed] J A
   687       by (auto intro!: arg_cong[where f=prob] split: split_if_asm) blast
   688     also
   689     from A F have "(\<lambda>j. if j \<in> J then A j else space M) \<in> Pi I F" (is "?A \<in> _")
   690       by (auto split: split_if_asm)
   691     with indep have "prob (\<Inter>j\<in>I. ?A j) = (\<Prod>j\<in>I. prob (?A j))"
   692       by auto
   693     also have "\<dots> = (\<Prod>j\<in>J. prob (A j))"
   694       unfolding if_distrib setprod.If_cases[OF `finite I`]
   695       using prob_space `J \<subseteq> I` by (simp add: Int_absorb1 setprod_1)
   696     finally show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))" ..
   697   qed
   698 qed
   699 
   700 lemma (in prob_space) indep_vars_finite:
   701   fixes I :: "'i set"
   702   assumes I: "I \<noteq> {}" "finite I"
   703     and rv: "\<And>i. i \<in> I \<Longrightarrow> random_variable (sigma (M' i)) (X i)"
   704     and Int_stable: "\<And>i. i \<in> I \<Longrightarrow> Int_stable (M' i)"
   705     and space: "\<And>i. i \<in> I \<Longrightarrow> space (M' i) \<in> sets (M' i)"
   706   shows "indep_vars (\<lambda>i. sigma (M' i)) X I \<longleftrightarrow>
   707     (\<forall>A\<in>(\<Pi> i\<in>I. sets (M' i)). prob (\<Inter>j\<in>I. X j -` A j \<inter> space M) = (\<Prod>j\<in>I. prob (X j -` A j \<inter> space M)))"
   708 proof -
   709   from rv have X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> space M \<rightarrow> space (M' i)"
   710     unfolding measurable_def by simp
   711 
   712   { fix i assume "i\<in>I"
   713     have "sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (sigma (M' i))}
   714       = sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   715       unfolding sigma_sets_vimage_commute[OF X, OF `i \<in> I`]
   716       by (subst sigma_sets_sigma_sets_eq) auto }
   717   note this[simp]
   718 
   719   { fix i assume "i\<in>I"
   720     have "Int_stable \<lparr>space = space M, sets = {X i -` A \<inter> space M |A. A \<in> sets (M' i)}\<rparr>"
   721     proof (rule Int_stableI)
   722       fix a assume "a \<in> {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   723       then obtain A where "a = X i -` A \<inter> space M" "A \<in> sets (M' i)" by auto
   724       moreover
   725       fix b assume "b \<in> {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   726       then obtain B where "b = X i -` B \<inter> space M" "B \<in> sets (M' i)" by auto
   727       moreover
   728       have "(X i -` A \<inter> space M) \<inter> (X i -` B \<inter> space M) = X i -` (A \<inter> B) \<inter> space M" by auto
   729       moreover note Int_stable[OF `i \<in> I`]
   730       ultimately
   731       show "a \<inter> b \<in> {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   732         by (auto simp del: vimage_Int intro!: exI[of _ "A \<inter> B"] dest: Int_stableD)
   733     qed }
   734   note indep_sets_sigma_sets_iff[OF this, simp]
   735  
   736   { fix i assume "i \<in> I"
   737     { fix A assume "A \<in> sets (M' i)"
   738       then have "A \<in> sets (sigma (M' i))" by (auto simp: sets_sigma intro: sigma_sets.Basic)
   739       moreover
   740       from rv[OF `i\<in>I`] have "X i \<in> measurable M (sigma (M' i))" by auto
   741       ultimately
   742       have "X i -` A \<inter> space M \<in> sets M" by (auto intro: measurable_sets) }
   743     with X[OF `i\<in>I`] space[OF `i\<in>I`]
   744     have "{X i -` A \<inter> space M |A. A \<in> sets (M' i)} \<subseteq> events"
   745       "space M \<in> {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   746       by (auto intro!: exI[of _ "space (M' i)"]) }
   747   note indep_sets_finite[OF I this, simp]
   748   
   749   have "(\<forall>A\<in>\<Pi> i\<in>I. {X i -` A \<inter> space M |A. A \<in> sets (M' i)}. prob (INTER I A) = (\<Prod>j\<in>I. prob (A j))) =
   750     (\<forall>A\<in>\<Pi> i\<in>I. sets (M' i). prob ((\<Inter>j\<in>I. X j -` A j) \<inter> space M) = (\<Prod>x\<in>I. prob (X x -` A x \<inter> space M)))"
   751     (is "?L = ?R")
   752   proof safe
   753     fix A assume ?L and A: "A \<in> (\<Pi> i\<in>I. sets (M' i))"
   754     from `?L`[THEN bspec, of "\<lambda>i. X i -` A i \<inter> space M"] A `I \<noteq> {}`
   755     show "prob ((\<Inter>j\<in>I. X j -` A j) \<inter> space M) = (\<Prod>x\<in>I. prob (X x -` A x \<inter> space M))"
   756       by (auto simp add: Pi_iff)
   757   next
   758     fix A assume ?R and A: "A \<in> (\<Pi> i\<in>I. {X i -` A \<inter> space M |A. A \<in> sets (M' i)})"
   759     from A have "\<forall>i\<in>I. \<exists>B. A i = X i -` B \<inter> space M \<and> B \<in> sets (M' i)" by auto
   760     from bchoice[OF this] obtain B where B: "\<forall>i\<in>I. A i = X i -` B i \<inter> space M"
   761       "B \<in> (\<Pi> i\<in>I. sets (M' i))" by auto
   762     from `?R`[THEN bspec, OF B(2)] B(1) `I \<noteq> {}`
   763     show "prob (INTER I A) = (\<Prod>j\<in>I. prob (A j))"
   764       by simp
   765   qed
   766   then show ?thesis using `I \<noteq> {}`
   767     by (simp add: rv indep_vars_def)
   768 qed
   769 
   770 lemma (in prob_space) indep_vars_compose:
   771   assumes "indep_vars M' X I"
   772   assumes rv:
   773     "\<And>i. i \<in> I \<Longrightarrow> sigma_algebra (N i)"
   774     "\<And>i. i \<in> I \<Longrightarrow> Y i \<in> measurable (M' i) (N i)"
   775   shows "indep_vars N (\<lambda>i. Y i \<circ> X i) I"
   776   unfolding indep_vars_def
   777 proof
   778   from rv `indep_vars M' X I`
   779   show "\<forall>i\<in>I. random_variable (N i) (Y i \<circ> X i)"
   780     by (auto intro!: measurable_comp simp: indep_vars_def)
   781 
   782   have "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   783     using `indep_vars M' X I` by (simp add: indep_vars_def)
   784   then show "indep_sets (\<lambda>i. sigma_sets (space M) {(Y i \<circ> X i) -` A \<inter> space M |A. A \<in> sets (N i)}) I"
   785   proof (rule indep_sets_mono_sets)
   786     fix i assume "i \<in> I"
   787     with `indep_vars M' X I` have X: "X i \<in> space M \<rightarrow> space (M' i)"
   788       unfolding indep_vars_def measurable_def by auto
   789     { fix A assume "A \<in> sets (N i)"
   790       then have "\<exists>B. (Y i \<circ> X i) -` A \<inter> space M = X i -` B \<inter> space M \<and> B \<in> sets (M' i)"
   791         by (intro exI[of _ "Y i -` A \<inter> space (M' i)"])
   792            (auto simp: vimage_compose intro!: measurable_sets rv `i \<in> I` funcset_mem[OF X]) }
   793     then show "sigma_sets (space M) {(Y i \<circ> X i) -` A \<inter> space M |A. A \<in> sets (N i)} \<subseteq>
   794       sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   795       by (intro sigma_sets_subseteq) (auto simp: vimage_compose)
   796   qed
   797 qed
   798 
   799 lemma (in prob_space) indep_varsD:
   800   assumes X: "indep_vars M' X I"
   801   assumes I: "I \<noteq> {}" "finite I" "\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M' i)"
   802   shows "prob (\<Inter>i\<in>I. X i -` A i \<inter> space M) = (\<Prod>i\<in>I. prob (X i -` A i \<inter> space M))"
   803 proof (rule indep_setsD)
   804   show "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   805     using X by (auto simp: indep_vars_def)
   806   show "I \<subseteq> I" "I \<noteq> {}" "finite I" using I by auto
   807   show "\<forall>i\<in>I. X i -` A i \<inter> space M \<in> sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   808     using I by (auto intro: sigma_sets.Basic)
   809 qed
   810 
   811 lemma (in prob_space) indep_distribution_eq_measure:
   812   assumes I: "I \<noteq> {}" "finite I"
   813   assumes rv: "\<And>i. random_variable (M' i) (X i)"
   814   shows "indep_vars M' X I \<longleftrightarrow>
   815     (\<forall>A\<in>sets (\<Pi>\<^isub>M i\<in>I. (M' i \<lparr> measure := extreal\<circ>distribution (X i) \<rparr>)).
   816       distribution (\<lambda>x. \<lambda>i\<in>I. X i x) A =
   817       finite_measure.\<mu>' (\<Pi>\<^isub>M i\<in>I. (M' i \<lparr> measure := extreal\<circ>distribution (X i) \<rparr>)) A)"
   818     (is "_ \<longleftrightarrow> (\<forall>X\<in>_. distribution ?D X = finite_measure.\<mu>' (Pi\<^isub>M I ?M) X)")
   819 proof -
   820   interpret M': prob_space "?M i" for i
   821     using rv by (rule distribution_prob_space)
   822   interpret P: finite_product_prob_space ?M I
   823     proof qed fact
   824 
   825   let ?D' = "(Pi\<^isub>M I ?M) \<lparr> measure := extreal \<circ> distribution ?D \<rparr>"
   826   have "random_variable P.P ?D"
   827     using `finite I` rv by (intro random_variable_restrict) auto
   828   then interpret D: prob_space ?D'
   829     by (rule distribution_prob_space)
   830 
   831   show ?thesis
   832   proof (intro iffI ballI)
   833     assume "indep_vars M' X I"
   834     fix A assume "A \<in> sets P.P"
   835     moreover
   836     have "D.prob A = P.prob A"
   837     proof (rule prob_space_unique_Int_stable)
   838       show "prob_space ?D'" by default
   839       show "prob_space (Pi\<^isub>M I ?M)" by default
   840       show "Int_stable P.G" using M'.Int
   841         by (intro Int_stable_product_algebra_generator) (simp add: Int_stable_def)
   842       show "space P.G \<in> sets P.G"
   843         using M'.top by (simp add: product_algebra_generator_def)
   844       show "space ?D' = space P.G"  "sets ?D' = sets (sigma P.G)"
   845         by (simp_all add: product_algebra_def product_algebra_generator_def sets_sigma)
   846       show "space P.P = space P.G" "sets P.P = sets (sigma P.G)"
   847         by (simp_all add: product_algebra_def)
   848       show "A \<in> sets (sigma P.G)"
   849         using `A \<in> sets P.P` by (simp add: product_algebra_def)
   850     
   851       fix E assume E: "E \<in> sets P.G"
   852       then have "E \<in> sets P.P"
   853         by (simp add: sets_sigma sigma_sets.Basic product_algebra_def)
   854       then have "D.prob E = distribution ?D E"
   855         unfolding D.\<mu>'_def by simp
   856       also
   857       from E obtain F where "E = Pi\<^isub>E I F" and F: "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets (M' i)"
   858         by (auto simp: product_algebra_generator_def)
   859       with `I \<noteq> {}` have "distribution ?D E = prob (\<Inter>i\<in>I. X i -` F i \<inter> space M)"
   860         using `I \<noteq> {}` by (auto intro!: arg_cong[where f=prob] simp: Pi_iff distribution_def)
   861       also have "\<dots> = (\<Prod>i\<in>I. prob (X i -` F i \<inter> space M))"
   862         using `indep_vars M' X I` I F by (rule indep_varsD)
   863       also have "\<dots> = P.prob E"
   864         using F by (simp add: `E = Pi\<^isub>E I F` P.prob_times M'.\<mu>'_def distribution_def)
   865       finally show "D.prob E = P.prob E" .
   866     qed
   867     ultimately show "distribution ?D A = P.prob A"
   868       by (simp add: D.\<mu>'_def)
   869   next
   870     assume eq: "\<forall>A\<in>sets P.P. distribution ?D A = P.prob A"
   871     have [simp]: "\<And>i. sigma (M' i) = M' i"
   872       using rv by (intro sigma_algebra.sigma_eq) simp
   873     have "indep_vars (\<lambda>i. sigma (M' i)) X I"
   874     proof (subst indep_vars_finite[OF I])
   875       fix i assume [simp]: "i \<in> I"
   876       show "random_variable (sigma (M' i)) (X i)"
   877         using rv[of i] by simp
   878       show "Int_stable (M' i)" "space (M' i) \<in> sets (M' i)"
   879         using M'.Int[of _ i] M'.top by (auto simp: Int_stable_def)
   880     next
   881       show "\<forall>A\<in>\<Pi> i\<in>I. sets (M' i). prob (\<Inter>j\<in>I. X j -` A j \<inter> space M) = (\<Prod>j\<in>I. prob (X j -` A j \<inter> space M))"
   882       proof
   883         fix A assume A: "A \<in> (\<Pi> i\<in>I. sets (M' i))"
   884         then have A_in_P: "(Pi\<^isub>E I A) \<in> sets P.P"
   885           by (auto intro!: product_algebraI)
   886         have "prob (\<Inter>j\<in>I. X j -` A j \<inter> space M) = distribution ?D (Pi\<^isub>E I A)"
   887           using `I \<noteq> {}`by (auto intro!: arg_cong[where f=prob] simp: Pi_iff distribution_def)
   888         also have "\<dots> = P.prob (Pi\<^isub>E I A)" using A_in_P eq by simp
   889         also have "\<dots> = (\<Prod>i\<in>I. M'.prob i (A i))"
   890           using A by (intro P.prob_times) auto
   891         also have "\<dots> = (\<Prod>i\<in>I. prob (X i -` A i \<inter> space M))"
   892           using A by (auto intro!: setprod_cong simp: M'.\<mu>'_def Pi_iff distribution_def)
   893         finally show "prob (\<Inter>j\<in>I. X j -` A j \<inter> space M) = (\<Prod>j\<in>I. prob (X j -` A j \<inter> space M))" .
   894       qed
   895     qed
   896     then show "indep_vars M' X I"
   897       by simp
   898   qed
   899 qed
   900 
   901 lemma (in prob_space) indep_varD:
   902   assumes indep: "indep_var Ma A Mb B"
   903   assumes sets: "Xa \<in> sets Ma" "Xb \<in> sets Mb"
   904   shows "prob ((\<lambda>x. (A x, B x)) -` (Xa \<times> Xb) \<inter> space M) =
   905     prob (A -` Xa \<inter> space M) * prob (B -` Xb \<inter> space M)"
   906 proof -
   907   have "prob ((\<lambda>x. (A x, B x)) -` (Xa \<times> Xb) \<inter> space M) =
   908     prob (\<Inter>i\<in>UNIV. (bool_case A B i -` bool_case Xa Xb i \<inter> space M))"
   909     by (auto intro!: arg_cong[where f=prob] simp: UNIV_bool)
   910   also have "\<dots> = (\<Prod>i\<in>UNIV. prob (bool_case A B i -` bool_case Xa Xb i \<inter> space M))"
   911     using indep unfolding indep_var_def
   912     by (rule indep_varsD) (auto split: bool.split intro: sets)
   913   also have "\<dots> = prob (A -` Xa \<inter> space M) * prob (B -` Xb \<inter> space M)"
   914     unfolding UNIV_bool by simp
   915   finally show ?thesis .
   916 qed
   917 
   918 lemma (in prob_space) indep_var_distributionD:
   919   assumes "indep_var Ma A Mb B"
   920   assumes "Xa \<in> sets Ma" "Xb \<in> sets Mb"
   921   shows "joint_distribution A B (Xa \<times> Xb) = distribution A Xa * distribution B Xb"
   922   unfolding distribution_def using assms by (rule indep_varD)
   923 
   924 end