src/Pure/Isar/outer_syntax.ML
author wenzelm
Tue Jul 19 20:47:01 2005 +0200 (2005-07-19)
changeset 16894 40f80823b451
parent 16727 e264077b68a7
child 17071 f753d6dd9bd0
permissions -rw-r--r--
Inttab.defined;
     1 (*  Title:      Pure/Isar/outer_syntax.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The global Isabelle/Isar outer syntax.
     6 *)
     7 
     8 signature BASIC_OUTER_SYNTAX =
     9 sig
    10   structure Isar:
    11     sig
    12       val main: unit -> unit
    13       val loop: unit -> unit
    14       val sync_main: unit -> unit
    15       val sync_loop: unit -> unit
    16     end;
    17 end;
    18 
    19 signature OUTER_SYNTAX =
    20 sig
    21   include BASIC_OUTER_SYNTAX
    22   structure Keyword:
    23     sig
    24       val control: string
    25       val diag: string
    26       val thy_begin: string
    27       val thy_switch: string
    28       val thy_end: string
    29       val thy_heading: string
    30       val thy_decl: string
    31       val thy_script: string
    32       val thy_goal: string
    33       val qed: string
    34       val qed_block: string
    35       val qed_global: string
    36       val prf_heading: string
    37       val prf_goal: string
    38       val prf_block: string
    39       val prf_open: string
    40       val prf_close: string
    41       val prf_chain: string
    42       val prf_decl: string
    43       val prf_asm: string
    44       val prf_asm_goal: string
    45       val prf_script: string
    46       val kinds: string list
    47     end
    48   type token
    49   type parser
    50   val command: string -> string -> string ->
    51     (token list -> (Toplevel.transition -> Toplevel.transition) * token list) -> parser
    52   val markup_command: IsarOutput.markup -> string -> string -> string ->
    53     (token list -> (Toplevel.transition -> Toplevel.transition) * token list) -> parser
    54   val improper_command: string -> string -> string ->
    55     (token list -> (Toplevel.transition -> Toplevel.transition) * token list) -> parser
    56   val is_keyword: string -> bool
    57   val dest_keywords: unit -> string list
    58   val dest_parsers: unit -> (string * string * string * bool) list
    59   val print_outer_syntax: unit -> unit
    60   val print_commands: Toplevel.transition -> Toplevel.transition
    61   val add_keywords: string list -> unit
    62   val add_parsers: parser list -> unit
    63   val check_text: string * Position.T -> bool -> Toplevel.state -> unit
    64   val deps_thy: string -> bool -> Path.T -> string list * Path.T list
    65   val load_thy: string -> bool -> bool -> Path.T -> unit
    66   val isar: bool -> bool -> unit Toplevel.isar
    67   val scan: string -> OuterLex.token list
    68   val read: OuterLex.token list -> (string * OuterLex.token list * Toplevel.transition) list
    69 end;
    70 
    71 structure OuterSyntax : OUTER_SYNTAX  =
    72 struct
    73 
    74 structure T = OuterLex;
    75 structure P = OuterParse;
    76 
    77 
    78 (** outer syntax **)
    79 
    80 (* command keyword classification *)
    81 
    82 structure Keyword =
    83 struct
    84   val control = "control";
    85   val diag = "diag";
    86   val thy_begin = "theory-begin";
    87   val thy_switch = "theory-switch";
    88   val thy_end = "theory-end";
    89   val thy_heading = "theory-heading";
    90   val thy_decl = "theory-decl";
    91   val thy_script = "theory-script";
    92   val thy_goal = "theory-goal";
    93   val qed = "qed";
    94   val qed_block = "qed-block";
    95   val qed_global = "qed-global";
    96   val prf_heading = "proof-heading";
    97   val prf_goal = "proof-goal";
    98   val prf_block = "proof-block";
    99   val prf_open = "proof-open";
   100   val prf_close = "proof-close";
   101   val prf_chain = "proof-chain";
   102   val prf_decl = "proof-decl";
   103   val prf_asm = "proof-asm";
   104   val prf_asm_goal = "proof-asm-goal";
   105   val prf_script = "proof-script";
   106 
   107   val kinds = [control, diag, thy_begin, thy_switch, thy_end, thy_heading, thy_decl, thy_script,
   108     thy_goal, qed, qed_block, qed_global, prf_heading, prf_goal, prf_block, prf_open, prf_close,
   109     prf_chain, prf_decl, prf_asm, prf_asm_goal, prf_script];
   110 end;
   111 
   112 
   113 (* parsers *)
   114 
   115 type token = T.token;
   116 type parser_fn = token list -> (Toplevel.transition -> Toplevel.transition) * token list;
   117 
   118 datatype parser =
   119   Parser of string * (string * string * IsarOutput.markup option) * bool * parser_fn;
   120 
   121 fun parser int_only markup name comment kind parse =
   122   Parser (name, (comment, kind, markup), int_only, parse);
   123 
   124 
   125 (* parse command *)
   126 
   127 local
   128 
   129 fun terminate false = Scan.succeed ()
   130   | terminate true = P.group "end of input" (Scan.option P.sync -- P.semicolon >> K ());
   131 
   132 fun trace false parse = parse
   133   | trace true parse = Scan.trace parse >> (fn (f, toks) => f o Toplevel.source toks);
   134 
   135 fun body cmd trc (name, _) =
   136   (case cmd name of
   137     SOME (int_only, parse) =>
   138       P.!!! (Scan.prompt (name ^ "# ") (trace trc parse >> pair int_only))
   139   | NONE => sys_error ("no parser for outer syntax command " ^ quote name));
   140 
   141 in
   142 
   143 fun command do_terminate do_trace cmd =
   144   P.semicolon >> K NONE ||
   145   P.sync >> K NONE ||
   146   (P.position P.command :-- body cmd do_trace) --| terminate do_terminate
   147     >> (fn ((name, pos), (int_only, f)) =>
   148       SOME (Toplevel.empty |> Toplevel.name name |> Toplevel.position pos |>
   149         Toplevel.interactive int_only |> f));
   150 
   151 end;
   152 
   153 
   154 
   155 (** global outer syntax **)
   156 
   157 local
   158 
   159 val global_lexicons = ref (Scan.empty_lexicon, Scan.empty_lexicon);
   160 val global_parsers =
   161   ref (Symtab.empty: (((string * string) * (bool * parser_fn)) * IsarOutput.markup option)
   162     Symtab.table);
   163 val global_markups = ref ([]: (string * IsarOutput.markup) list);
   164 
   165 fun change_lexicons f =
   166   let val lexs = f (! global_lexicons) in
   167     (case (op inter_string) (pairself Scan.dest_lexicon lexs) of
   168       [] => global_lexicons := lexs
   169     | bads => error ("Clash of outer syntax commands and keywords: " ^ commas_quote bads))
   170   end;
   171 
   172 fun get_markup (ms, (name, (_, SOME m))) = (name, m) :: ms
   173   | get_markup (ms, _) = ms;
   174 
   175 fun make_markups () = global_markups := Symtab.foldl get_markup ([], ! global_parsers);
   176 fun change_parsers f = (Library.change global_parsers f; make_markups ());
   177 
   178 in
   179 
   180 
   181 (* access current syntax *)
   182 
   183 (*Note: the syntax for files is statically determined at the very
   184   beginning; for interactive processing it may change dynamically.*)
   185 
   186 fun get_lexicons () = ! global_lexicons;
   187 fun get_parsers () = ! global_parsers;
   188 fun get_parser () = Option.map (#2 o #1) o curry Symtab.lookup (! global_parsers);
   189 
   190 fun is_markup kind name =
   191   (case assoc (! global_markups, name) of SOME k => k = kind | NONE => false);
   192 fun markup kind = Scan.one (T.is_kind T.Command andf is_markup kind o T.val_of);
   193 
   194 
   195 (* augment syntax *)
   196 
   197 fun add_keywords keywords = change_lexicons (apfst (fn lex =>
   198   (Scan.extend_lexicon lex (map Symbol.explode keywords))));
   199 
   200 fun add_parser (tab, Parser (name, (comment, kind, markup), int_only, parse)) =
   201  (if not (Symtab.defined tab name) then ()
   202   else warning ("Redefined outer syntax command " ^ quote name);
   203   Symtab.update ((name, (((comment, kind), (int_only, parse)), markup)), tab));
   204 
   205 fun add_parsers parsers =
   206   (change_parsers (fn tab => Library.foldl add_parser (tab, parsers));
   207     change_lexicons (apsnd (fn lex => Scan.extend_lexicon lex
   208       (map (fn Parser (name, _, _, _) => Symbol.explode name) parsers))));
   209 
   210 end;
   211 
   212 
   213 (* print syntax *)
   214 
   215 fun is_keyword s = Scan.is_literal (#1 (get_lexicons ())) (Symbol.explode s);
   216 fun dest_keywords () = Scan.dest_lexicon (#1 (get_lexicons ()));
   217 
   218 fun dest_parsers () =
   219   get_parsers () |> Symtab.dest |> sort_wrt #1
   220   |> map (fn (name, (((cmt, kind), (int_only, _)), _)) => (name, cmt, kind, int_only));
   221 
   222 fun print_outer_syntax () =
   223   let
   224     fun pretty_cmd (name, comment, _, _) =
   225       Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
   226     val (int_cmds, cmds) = List.partition #4 (dest_parsers ());
   227   in
   228     [Pretty.strs ("syntax keywords:" :: map quote (dest_keywords ())),
   229       Pretty.big_list "proper commands:" (map pretty_cmd cmds),
   230       Pretty.big_list "improper commands (interactive-only):" (map pretty_cmd int_cmds)]
   231     |> Pretty.chunks |> Pretty.writeln
   232   end;
   233 
   234 val print_commands = Toplevel.imperative print_outer_syntax;
   235 
   236 
   237 
   238 (** toplevel parsing **)
   239 
   240 (* basic sources *)
   241 
   242 fun toplevel_source term trc do_recover cmd src =
   243   let
   244     val no_terminator =
   245       Scan.unless P.semicolon (Scan.one (T.not_sync andf T.not_eof));
   246     fun recover x = (Scan.prompt "recover# " (Scan.repeat no_terminator) >> K [NONE]) x;
   247   in
   248     src
   249     |> T.source_proper
   250     |> Source.source T.stopper
   251       (Scan.bulk (P.$$$ "--" -- P.!!! P.text >> K NONE || P.not_eof >> SOME))
   252       (if do_recover then SOME recover else NONE)
   253     |> Source.mapfilter I
   254     |> Source.source T.stopper (Scan.bulk (fn xs => P.!!! (command term trc (cmd ())) xs))
   255       (if do_recover then SOME recover else NONE)
   256     |> Source.mapfilter I
   257   end;
   258 
   259 
   260 (* interactive source of toplevel transformers *)
   261 
   262 fun isar term no_pos =
   263   Source.tty
   264   |> Symbol.source true
   265   |> T.source true get_lexicons
   266     (if no_pos then Position.none else Position.line_name 1 "stdin")
   267   |> toplevel_source term false true get_parser;
   268 
   269 
   270 (* scan text *)
   271 
   272 fun scan str =
   273   Source.of_string str
   274   |> Symbol.source false
   275   |> T.source true get_lexicons Position.none
   276   |> Source.exhaust;
   277 
   278 
   279 (* read tokens with trace *)
   280 
   281 fun read toks =
   282   Source.of_list toks
   283   |> toplevel_source false true true get_parser
   284   |> Source.exhaust
   285   |> map (fn tr => (Toplevel.name_of tr, the (Toplevel.source_of tr), tr));
   286 
   287 
   288 
   289 (** read theory **)
   290 
   291 (* check_text *)
   292 
   293 fun check_text s true state = (IsarOutput.eval_antiquote (#1 (get_lexicons ())) state s; ())
   294   | check_text _ false _ = ();
   295 
   296 
   297 (* deps_thy *)
   298 
   299 fun deps_thy name ml path =
   300   let
   301     val src = Source.of_string (File.read path);
   302     val pos = Path.position path;
   303     val (name', parents, files) = ThyHeader.scan (src, pos);
   304     val ml_path = ThyLoad.ml_path name;
   305     val ml_file = if ml andalso is_some (ThyLoad.check_file NONE ml_path) then [ml_path] else [];
   306   in
   307     if name <> name' then
   308       error ("Filename " ^ quote (Path.pack path) ^
   309         " does not agree with theory name " ^ quote name')
   310     else (parents, map (Path.unpack o #1) files @ ml_file)
   311   end;
   312 
   313 
   314 (* load_thy *)
   315 
   316 local
   317 
   318 fun try_ml_file name time =
   319   let
   320     val path = ThyLoad.ml_path name;
   321     val tr = Toplevel.imperative (fn () => ThyInfo.load_file time path);
   322     val tr_name = if time then "time_use" else "use";
   323   in
   324     if is_none (ThyLoad.check_file NONE path) then ()
   325     else Toplevel.excursion [Toplevel.empty |> Toplevel.name tr_name |> tr]
   326   end;
   327 
   328 fun parse_thy src =
   329   src
   330   |> toplevel_source false false false (K (get_parser ()))
   331   |> Source.exhaust;
   332 
   333 fun run_thy name path =
   334   let
   335     val pos = Path.position path;
   336     val text = Library.untabify (explode (File.read path));
   337     val text_src = Source.of_list text;
   338     fun present_text () = Source.exhaust (Symbol.source false text_src);
   339   in
   340     Present.init_theory name;
   341     Present.verbatim_source name present_text;
   342     if ThyHeader.is_old (text_src, pos) then (ThySyn.load_thy name text;
   343       Present.old_symbol_source name present_text)   (*note: text presented twice*)
   344     else
   345       let
   346         val tok_src = text_src
   347           |> Symbol.source false
   348           |> T.source false (K (get_lexicons ())) pos
   349           |> Source.exhausted;
   350         val out = Toplevel.excursion_result
   351           (IsarOutput.parse_thy markup (#1 (get_lexicons ()))
   352             (parse_thy tok_src) tok_src);
   353       in Present.theory_output name (Buffer.content out) end
   354   end;
   355 
   356 in
   357 
   358 fun load_thy name ml time path =
   359  (if time then
   360     timeit (fn () =>
   361      (writeln ("\n**** Starting theory " ^ quote name ^ " ****");
   362       run_thy name path;
   363       writeln ("**** Finished theory " ^ quote name ^ " ****\n")))
   364   else run_thy name path;
   365   Context.context (ThyInfo.get_theory name);
   366   if ml then try_ml_file name time else ());
   367 
   368 end;
   369 
   370 
   371 
   372 (** the read-eval-print loop **)
   373 
   374 (* main loop *)
   375 
   376 fun gen_loop term no_pos =
   377  (Context.reset_context ();
   378   Toplevel.loop (isar term no_pos);
   379   ml_prompts "ML> " "ML# ");
   380 
   381 fun gen_main term no_pos =
   382  (Toplevel.set_state Toplevel.toplevel;
   383   writeln (Session.welcome ());
   384   gen_loop term no_pos);
   385 
   386 structure Isar =
   387 struct
   388   fun main () = gen_main false false;
   389   fun loop () = gen_loop false false;
   390   fun sync_main () = gen_main true true;
   391   fun sync_loop () = gen_loop true true;
   392 end;
   393 
   394 
   395 (*final declarations of this structure!*)
   396 val command = parser false NONE;
   397 val markup_command = parser false o SOME;
   398 val improper_command = parser true NONE;
   399 
   400 end;
   401 
   402 (*setup theory syntax dependent operations*)
   403 ThyLoad.deps_thy_fn := OuterSyntax.deps_thy;
   404 ThyLoad.load_thy_fn := OuterSyntax.load_thy;
   405 structure ThyLoad: THY_LOAD = ThyLoad;
   406 
   407 structure BasicOuterSyntax: BASIC_OUTER_SYNTAX = OuterSyntax;
   408 open BasicOuterSyntax;
   409 open Isar;