src/Pure/context.ML
author wenzelm
Tue Jul 19 20:47:01 2005 +0200 (2005-07-19)
changeset 16894 40f80823b451
parent 16719 5c5eb939f6eb
child 17060 cca2f3938443
permissions -rw-r--r--
Inttab.defined;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 development graph and history support.  Implicit theory contexts in ML.
     7 Generic proof contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15   val context: theory -> unit
    16   val the_context: unit -> theory
    17 end;
    18 
    19 signature CONTEXT =
    20 sig
    21   include BASIC_CONTEXT
    22   exception DATA_FAIL of exn * string
    23   (*theory context*)
    24   val theory_name: theory -> string
    25   val parents_of: theory -> theory list
    26   val ancestors_of: theory -> theory list
    27   val is_stale: theory -> bool
    28   val ProtoPureN: string
    29   val PureN: string
    30   val CPureN: string
    31   val draftN: string
    32   val exists_name: string -> theory -> bool
    33   val names_of: theory -> string list
    34   val pretty_thy: theory -> Pretty.T
    35   val string_of_thy: theory -> string
    36   val pprint_thy: theory -> pprint_args -> unit
    37   val pretty_abbrev_thy: theory -> Pretty.T
    38   val str_of_thy: theory -> string
    39   val check_thy: theory -> theory
    40   val eq_thy: theory * theory -> bool
    41   val subthy: theory * theory -> bool
    42   val joinable: theory * theory -> bool
    43   val merge: theory * theory -> theory                     (*exception TERM*)
    44   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    45   val self_ref: theory -> theory_ref
    46   val deref: theory_ref -> theory
    47   val copy_thy: theory -> theory
    48   val checkpoint_thy: theory -> theory
    49   val finish_thy: theory -> theory
    50   val theory_data_of: theory -> string list
    51   val pre_pure_thy: theory
    52   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    53   (*ML theory context*)
    54   val get_context: unit -> theory option
    55   val set_context: theory option -> unit
    56   val reset_context: unit -> unit
    57   val setmp: theory option -> ('a -> 'b) -> 'a -> 'b
    58   val pass: theory option -> ('a -> 'b) -> 'a -> 'b * theory option
    59   val pass_theory: theory -> ('a -> 'b) -> 'a -> 'b * theory
    60   val save: ('a -> 'b) -> 'a -> 'b
    61   val >> : (theory -> theory) -> unit
    62   val ml_output: (string -> unit) * (string -> unit)
    63   val use_mltext: string -> bool -> theory option -> unit
    64   val use_mltext_theory: string -> bool -> theory -> theory
    65   val use_let: string -> string -> string -> theory -> theory
    66   val add_setup: (theory -> theory) list -> unit
    67   val setup: unit -> (theory -> theory) list
    68   (*proof context*)
    69   type proof
    70   val theory_of_proof: proof -> theory
    71   val init_proof: theory -> proof
    72   val proof_data_of: theory -> string list
    73   (*generic context*)
    74   datatype context = Theory of theory | Proof of proof
    75   val theory_of: context -> theory
    76   val proof_of: context -> proof
    77 end;
    78 
    79 signature PRIVATE_CONTEXT =
    80 sig
    81   include CONTEXT
    82   structure TheoryData:
    83   sig
    84     val declare: string -> Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    85       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    86     val init: serial -> theory -> theory
    87     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    88     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    89   end
    90   structure ProofData:
    91   sig
    92     val declare: string -> (theory -> Object.T) -> serial
    93     val init: serial -> theory -> theory
    94     val get: serial -> (Object.T -> 'a) -> proof -> 'a
    95     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
    96   end
    97 end;
    98 
    99 structure Context: PRIVATE_CONTEXT =
   100 struct
   101 
   102 (*** theory context ***)
   103 
   104 (** theory data **)
   105 
   106 (* data kinds and access methods *)
   107 
   108 exception DATA_FAIL of exn * string;
   109 
   110 local
   111 
   112 type kind =
   113  {name: string,
   114   empty: Object.T,
   115   copy: Object.T -> Object.T,
   116   extend: Object.T -> Object.T,
   117   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   118 
   119 val kinds = ref (Inttab.empty: kind Inttab.table);
   120 
   121 fun invoke meth_name meth_fn k =
   122   (case Inttab.lookup (! kinds, k) of
   123     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   124       DATA_FAIL (exn, "Theory data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   125   | NONE => sys_error ("Invalid theory data identifier " ^ string_of_int k));
   126 
   127 in
   128 
   129 fun invoke_name k    = invoke "name" (K o #name) k ();
   130 fun invoke_empty k   = invoke "empty" (K o #empty) k ();
   131 val invoke_copy      = invoke "copy" #copy;
   132 val invoke_extend    = invoke "extend" #extend;
   133 fun invoke_merge pp  = invoke "merge" (fn kind => #merge kind pp);
   134 
   135 fun declare_theory_data name empty copy extend merge =
   136   let
   137     val k = serial ();
   138     val kind = {name = name, empty = empty, copy = copy, extend = extend, merge = merge};
   139     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   140       warning ("Duplicate declaration of theory data " ^ quote name));
   141     val _ = kinds := Inttab.update ((k, kind), ! kinds);
   142   in k end;
   143 
   144 val copy_data = Inttab.map' invoke_copy;
   145 val extend_data = Inttab.map' invoke_extend;
   146 fun merge_data pp = Inttab.join (SOME oo invoke_merge pp) o pairself extend_data;
   147 
   148 end;
   149 
   150 
   151 
   152 (** datatype theory **)
   153 
   154 datatype theory =
   155   Theory of
   156    (*identity*)
   157    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   158     id: serial * string,                (*identifier of this theory*)
   159     ids: string Inttab.table,           (*identifiers of ancestors*)
   160     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   161    (*data*)
   162    {theory: Object.T Inttab.table,      (*theory data record*)
   163     proof: unit Inttab.table} *         (*proof data kinds*)
   164    (*ancestry*)
   165    {parents: theory list,               (*immediate predecessors*)
   166     ancestors: theory list} *           (*all predecessors*)
   167    (*history*)
   168    {name: string,                       (*prospective name of finished theory*)
   169     version: int,                       (*checkpoint counter*)
   170     intermediates: theory list};        (*intermediate checkpoints*)
   171 
   172 exception THEORY of string * theory list;
   173 
   174 fun rep_theory (Theory args) = args;
   175 
   176 val identity_of = #1 o rep_theory;
   177 val data_of     = #2 o rep_theory;
   178 val ancestry_of = #3 o rep_theory;
   179 val history_of  = #4 o rep_theory;
   180 
   181 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   182 fun make_data theory proof = {theory = theory, proof = proof};
   183 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   184 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   185 
   186 fun map_theory f {theory, proof} = make_data (f theory) proof;
   187 fun map_proof f {theory, proof} = make_data theory (f proof);
   188 
   189 val the_self = the o #self o identity_of;
   190 val parents_of = #parents o ancestry_of;
   191 val ancestors_of = #ancestors o ancestry_of;
   192 val theory_name = #name o history_of;
   193 
   194 
   195 (* staleness *)
   196 
   197 fun eq_id ((i: int, _), (j, _)) = (i = j);
   198 
   199 fun is_stale
   200     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   201       not (eq_id (id, id'))
   202   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   203 
   204 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   205   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   206       let
   207         val r = ref thy;
   208         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   209       in r := thy'; thy' end;
   210 
   211 
   212 (* names *)
   213 
   214 val ProtoPureN = "ProtoPure";
   215 val PureN = "Pure";
   216 val CPureN = "CPure";
   217 
   218 val draftN = "#";
   219 fun draft_id (_, name) = (name = draftN);
   220 val is_draft = draft_id o #id o identity_of;
   221 
   222 fun exists_name name (Theory ({id, ids, iids, ...}, _, _, _)) =
   223   name = #2 id orelse
   224   Inttab.exists (equal name o #2) ids orelse
   225   Inttab.exists (equal name o #2) iids;
   226 
   227 fun names_of (Theory ({id, ids, iids, ...}, _, _, _)) =
   228   rev (#2 id :: Inttab.fold (cons o #2) iids (Inttab.fold (cons o #2) ids []));
   229 
   230 fun pretty_thy thy =
   231   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   232 
   233 val string_of_thy = Pretty.string_of o pretty_thy;
   234 val pprint_thy = Pretty.pprint o pretty_thy;
   235 
   236 fun pretty_abbrev_thy thy =
   237   let
   238     val names = names_of thy;
   239     val n = length names;
   240     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   241   in Pretty.str_list "{" "}" abbrev end;
   242 
   243 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   244 
   245 
   246 (* consistency *)    (*exception TERM*)
   247 
   248 fun check_thy thy =
   249   if is_stale thy then
   250     raise TERM ("Stale theory encountered:\n" ^ string_of_thy thy, [])
   251   else thy;
   252 
   253 fun check_ins id ids =
   254   if draft_id id orelse Inttab.defined ids (#1 id) then ids
   255   else if Inttab.exists (equal (#2 id) o #2) ids then
   256     raise TERM ("Different versions of theory component " ^ quote (#2 id), [])
   257   else Inttab.update (id, ids);
   258 
   259 fun check_insert intermediate id (ids, iids) =
   260   let val ids' = check_ins id ids and iids' = check_ins id iids
   261   in if intermediate then (ids, iids') else (ids', iids) end;
   262 
   263 fun check_merge
   264     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   265     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   266   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   267   |> check_insert (#version history1 > 0) id1
   268   |> check_insert (#version history2 > 0) id2;
   269 
   270 
   271 (* equality and inclusion *)
   272 
   273 val eq_thy = eq_id o pairself (#id o identity_of o check_thy);
   274 
   275 fun proper_subthy
   276     (Theory ({id = (i, _), ...}, _, _, _), Theory ({ids, iids, ...}, _, _, _)) =
   277   Inttab.defined ids i orelse Inttab.defined iids i;
   278 
   279 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   280 
   281 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   282 
   283 
   284 (* theory references *)
   285 
   286 (*theory_ref provides a safe way to store dynamic references to a
   287   theory in external data structures -- a plain theory value would
   288   become stale as the self reference moves on*)
   289 
   290 datatype theory_ref = TheoryRef of theory ref;
   291 
   292 val self_ref = TheoryRef o the_self o check_thy;
   293 fun deref (TheoryRef (ref thy)) = thy;
   294 
   295 
   296 (* trivial merge *)    (*exception TERM*)
   297 
   298 fun merge (thy1, thy2) =
   299   if eq_thy (thy1, thy2) then thy1
   300   else if proper_subthy (thy2, thy1) then thy1
   301   else if proper_subthy (thy1, thy2) then thy2
   302   else (check_merge thy1 thy2;
   303     raise TERM (cat_lines ["Attempt to perform non-trivial merge of theories:",
   304       str_of_thy thy1, str_of_thy thy2], []));
   305 
   306 fun merge_refs (ref1, ref2) =
   307   if ref1 = ref2 then ref1
   308   else self_ref (merge (deref ref1, deref ref2));
   309 
   310 
   311 
   312 (** build theories **)
   313 
   314 (* primitives *)
   315 
   316 fun create_thy name self id ids iids data ancestry history =
   317   let
   318     val intermediate = #version history > 0;
   319     val (ids', iids') = check_insert intermediate id (ids, iids);
   320     val id' = (serial (), name);
   321     val _ = check_insert intermediate id' (ids', iids');
   322     val identity' = make_identity self id' ids' iids';
   323   in vitalize (Theory (identity', data, ancestry, history)) end;
   324 
   325 fun change_thy name f (thy as Theory ({self, id, ids, iids}, data, ancestry, history)) =
   326   let
   327     val _ = check_thy thy;
   328     val (self', data', ancestry') =
   329       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   330       else if #version history > 0
   331       then (NONE, map_theory copy_data data, ancestry)
   332       else (NONE, map_theory extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   333     val data'' = f data';
   334   in create_thy name self' id ids iids data'' ancestry' history end;
   335 
   336 fun name_thy name = change_thy name I;
   337 val modify_thy = change_thy draftN;
   338 val extend_thy = modify_thy I;
   339 
   340 fun copy_thy (thy as Theory ({id, ids, iids, ...}, data, ancestry, history)) =
   341   (check_thy thy;
   342     create_thy draftN NONE id ids iids (map_theory copy_data data) ancestry history);
   343 
   344 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   345   (make_data Inttab.empty Inttab.empty) (make_ancestry [] []) (make_history ProtoPureN 0 []);
   346 
   347 
   348 (* named theory nodes *)
   349 
   350 fun merge_thys pp (thy1, thy2) =
   351   if exists_name CPureN thy1 <> exists_name CPureN thy2 then
   352     error "Cannot merge Pure and CPure developments"
   353   else
   354     let
   355       val (ids, iids) = check_merge thy1 thy2;
   356       val data1 = data_of thy1 and data2 = data_of thy2;
   357       val data = make_data
   358         (merge_data (pp thy1) (#theory data1, #theory data2))
   359         (Inttab.merge (K true) (#proof data1, #proof data2));
   360       val ancestry = make_ancestry [] [];
   361       val history = make_history "" 0 [];
   362     in create_thy draftN NONE (serial (), draftN) ids iids data ancestry history end;
   363 
   364 fun maximal_thys thys =
   365   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   366 
   367 fun begin_thy pp name imports =
   368   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   369   else
   370     let
   371       val parents =
   372         maximal_thys (gen_distinct eq_thy (map check_thy imports));
   373       val ancestors = gen_distinct eq_thy (parents @ List.concat (map ancestors_of parents));
   374       val Theory ({id, ids, iids, ...}, data, _, _) =
   375         (case parents of
   376           [] => error "No parent theories"
   377         | [thy] => extend_thy thy
   378         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   379       val ancestry = make_ancestry parents ancestors;
   380       val history = make_history name 0 [];
   381     in create_thy draftN NONE id ids iids data ancestry history end;
   382 
   383 
   384 (* undoable checkpoints *)
   385 
   386 fun checkpoint_thy thy =
   387   if not (is_draft thy) then thy
   388   else
   389     let
   390       val {name, version, intermediates} = history_of thy;
   391       val thy' as Theory (identity', data', ancestry', _) =
   392         name_thy (name ^ ":" ^ string_of_int version) thy;
   393       val history' = make_history name (version + 1) (thy' :: intermediates);
   394     in vitalize (Theory (identity', data', ancestry', history')) end;
   395 
   396 fun finish_thy thy =
   397   let
   398     val {name, version, intermediates} = history_of thy;
   399     val rs = map (the_self o check_thy) intermediates;
   400     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   401     val identity' = make_identity self id ids Inttab.empty;
   402     val history' = make_history name 0 [];
   403     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   404     val _ = List.app (fn r => r := thy'') rs;
   405   in thy'' end;
   406 
   407 
   408 (* theory data *)
   409 
   410 fun dest_data name_of tab =
   411   map name_of (Inttab.keys tab)
   412   |> map (rpair ()) |> Symtab.make_multi |> Symtab.dest
   413   |> map (apsnd length)
   414   |> map (fn (name, 1) => name | (name, n) => name ^ enclose "[" "]" (string_of_int n));
   415 
   416 val theory_data_of = dest_data invoke_name o #theory o data_of;
   417 
   418 structure TheoryData =
   419 struct
   420 
   421 val declare = declare_theory_data;
   422 
   423 fun get k dest thy =
   424   (case Inttab.lookup (#theory (data_of thy), k) of
   425     SOME x => (dest x handle Match =>
   426       error ("Failed to access theory data " ^ quote (invoke_name k)))
   427   | NONE => error ("Uninitialized theory data " ^ quote (invoke_name k)));
   428 
   429 fun put k mk x = modify_thy (map_theory (curry Inttab.update (k, mk x)));
   430 fun init k = put k I (invoke_empty k);
   431 
   432 end;
   433 
   434 
   435 
   436 (*** ML theory context ***)
   437 
   438 local
   439   val current_theory = ref (NONE: theory option);
   440 in
   441   fun get_context () = ! current_theory;
   442   fun set_context opt_thy = current_theory := opt_thy;
   443   fun setmp opt_thy f x = Library.setmp current_theory opt_thy f x;
   444 end;
   445 
   446 fun the_context () =
   447   (case get_context () of
   448     SOME thy => thy
   449   | _ => error "Unknown theory context");
   450 
   451 fun context thy = set_context (SOME thy);
   452 fun reset_context () = set_context NONE;
   453 
   454 fun pass opt_thy f x =
   455   setmp opt_thy (fn x => let val y = f x in (y, get_context ()) end) x;
   456 
   457 fun pass_theory thy f x =
   458   (case pass (SOME thy) f x of
   459     (y, SOME thy') => (y, thy')
   460   | (_, NONE) => error "Lost theory context in ML");
   461 
   462 fun save f x = setmp (get_context ()) f x;
   463 
   464 
   465 (* map context *)
   466 
   467 nonfix >>;
   468 fun >> f = set_context (SOME (f (the_context ())));
   469 
   470 
   471 (* use ML text *)
   472 
   473 val ml_output = (writeln, error_msg);
   474 
   475 fun use_output verb txt = use_text ml_output verb (Symbol.escape txt);
   476 
   477 fun use_mltext txt verb opt_thy = setmp opt_thy (fn () => use_output verb txt) ();
   478 fun use_mltext_theory txt verb thy = #2 (pass_theory thy (use_output verb) txt);
   479 
   480 fun use_context txt = use_mltext_theory ("Context.>> (" ^ txt ^ ");") false;
   481 
   482 fun use_let bind body txt =
   483   use_context ("let " ^ bind ^ " = " ^ txt ^ " in\n" ^ body ^ " end");
   484 
   485 
   486 (* delayed theory setup *)
   487 
   488 local
   489   val setup_fns = ref ([]: (theory -> theory) list);
   490 in
   491   fun add_setup fns = setup_fns := ! setup_fns @ fns;
   492   fun setup () = let val fns = ! setup_fns in setup_fns := []; fns end;
   493 end;
   494 
   495 
   496 
   497 (*** proof context ***)
   498 
   499 (* datatype proof *)
   500 
   501 datatype proof = Proof of theory * Object.T Inttab.table;
   502 
   503 fun theory_of_proof (Proof (thy, _)) = thy;
   504 fun data_of_proof (Proof (_, data)) = data;
   505 fun map_prf f (Proof (thy, data)) = Proof (thy, f data);
   506 
   507 
   508 (* proof data kinds *)
   509 
   510 local
   511 
   512 type kind =
   513  {name: string,
   514   init: theory -> Object.T};
   515 
   516 val kinds = ref (Inttab.empty: kind Inttab.table);
   517 
   518 fun invoke meth_name meth_fn k =
   519   (case Inttab.lookup (! kinds, k) of
   520     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   521       DATA_FAIL (exn, "Proof data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   522   | NONE => sys_error ("Invalid proof data identifier " ^ string_of_int k));
   523 
   524 fun invoke_name k = invoke "name" (K o #name) k ();
   525 val invoke_init   = invoke "init" #init;
   526 
   527 in
   528 
   529 val proof_data_of = dest_data invoke_name o #proof o data_of;
   530 
   531 fun init_proof thy =
   532   Proof (thy, Inttab.map' (fn k => fn _ => invoke_init k thy) (#proof (data_of thy)));
   533 
   534 structure ProofData =
   535 struct
   536 
   537 fun declare name init =
   538   let
   539     val k = serial ();
   540     val kind = {name = name, init = init};
   541     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   542       warning ("Duplicate declaration of proof data " ^ quote name));
   543     val _ = kinds := Inttab.update ((k, kind), ! kinds);
   544   in k end;
   545 
   546 fun init k = modify_thy (map_proof (curry Inttab.update (k, ())));
   547 
   548 fun get k dest prf =
   549   (case Inttab.lookup (data_of_proof prf, k) of
   550     SOME x => (dest x handle Match =>
   551       error ("Failed to access proof data " ^ quote (invoke_name k)))
   552   | NONE => error ("Uninitialized proof data " ^ quote (invoke_name k)));
   553 
   554 fun put k mk x = map_prf (curry Inttab.update (k, mk x));
   555 
   556 end;
   557 
   558 end;
   559 
   560 
   561 (*** generic context ***)
   562 
   563 datatype context = Theory of theory | Proof of proof;
   564 
   565 fun theory_of (Theory thy) = thy
   566   | theory_of (Proof prf) = theory_of_proof prf;
   567 
   568 fun proof_of (Theory thy) = init_proof thy
   569   | proof_of (Proof prf) = prf;
   570 
   571 end;
   572 
   573 structure BasicContext: BASIC_CONTEXT = Context;
   574 open BasicContext;
   575 
   576 
   577 
   578 (*** type-safe interfaces for data declarations ***)
   579 
   580 (** theory data **)
   581 
   582 signature THEORY_DATA_ARGS =
   583 sig
   584   val name: string
   585   type T
   586   val empty: T
   587   val copy: T -> T
   588   val extend: T -> T
   589   val merge: Pretty.pp -> T * T -> T
   590   val print: theory -> T -> unit
   591 end;
   592 
   593 signature THEORY_DATA =
   594 sig
   595   type T
   596   val init: theory -> theory
   597   val print: theory -> unit
   598   val get: theory -> T
   599   val get_sg: theory -> T    (*obsolete*)
   600   val put: T -> theory -> theory
   601   val map: (T -> T) -> theory -> theory
   602 end;
   603 
   604 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   605 struct
   606 
   607 structure TheoryData = Context.TheoryData;
   608 
   609 type T = Data.T;
   610 exception Data of T;
   611 
   612 val kind = TheoryData.declare Data.name
   613   (Data Data.empty)
   614   (fn Data x => Data (Data.copy x))
   615   (fn Data x => Data (Data.extend x))
   616   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   617 
   618 val init = TheoryData.init kind;
   619 val get = TheoryData.get kind (fn Data x => x);
   620 val get_sg = get;
   621 fun print thy = Data.print thy (get thy);
   622 val put = TheoryData.put kind Data;
   623 fun map f thy = put (f (get thy)) thy;
   624 
   625 end;
   626 
   627 
   628 
   629 (** proof data **)
   630 
   631 signature PROOF_DATA_ARGS =
   632 sig
   633   val name: string
   634   type T
   635   val init: theory -> T
   636   val print: Context.proof -> T -> unit
   637 end;
   638 
   639 signature PROOF_DATA =
   640 sig
   641   type T
   642   val init: theory -> theory
   643   val print: Context.proof -> unit
   644   val get: Context.proof -> T
   645   val put: T -> Context.proof -> Context.proof
   646   val map: (T -> T) -> Context.proof -> Context.proof
   647 end;
   648 
   649 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   650 struct
   651 
   652 structure ProofData = Context.ProofData;
   653 
   654 type T = Data.T;
   655 exception Data of T;
   656 
   657 val kind = ProofData.declare Data.name (Data o Data.init);
   658 
   659 val init = ProofData.init kind;
   660 val get = ProofData.get kind (fn Data x => x);
   661 fun print prf = Data.print prf (get prf);
   662 val put = ProofData.put kind Data;
   663 fun map f prf = put (f (get prf)) prf;
   664 
   665 end;
   666 
   667 (*hide private interface*)
   668 structure Context: CONTEXT = Context;