src/HOL/Topological_Spaces.thy
author haftmann
Thu Jul 25 08:57:16 2013 +0200 (2013-07-25)
changeset 52729 412c9e0381a1
parent 52265 bb907eba5902
child 53215 5e47c31c6f7c
permissions -rw-r--r--
factored syntactic type classes for bot and top (by Alessandro Coglio)
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 subsection {* Topological space *}
    13 
    14 class "open" =
    15   fixes "open" :: "'a set \<Rightarrow> bool"
    16 
    17 class topological_space = "open" +
    18   assumes open_UNIV [simp, intro]: "open UNIV"
    19   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    20   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    21 begin
    22 
    23 definition
    24   closed :: "'a set \<Rightarrow> bool" where
    25   "closed S \<longleftrightarrow> open (- S)"
    26 
    27 lemma open_empty [intro, simp]: "open {}"
    28   using open_Union [of "{}"] by simp
    29 
    30 lemma open_Un [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    31   using open_Union [of "{S, T}"] by simp
    32 
    33 lemma open_UN [intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    34   unfolding SUP_def by (rule open_Union) auto
    35 
    36 lemma open_Inter [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    37   by (induct set: finite) auto
    38 
    39 lemma open_INT [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    40   unfolding INF_def by (rule open_Inter) auto
    41 
    42 lemma openI:
    43   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    44   shows "open S"
    45 proof -
    46   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    47   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    48   ultimately show "open S" by simp
    49 qed
    50 
    51 lemma closed_empty [intro, simp]:  "closed {}"
    52   unfolding closed_def by simp
    53 
    54 lemma closed_Un [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    55   unfolding closed_def by auto
    56 
    57 lemma closed_UNIV [intro, simp]: "closed UNIV"
    58   unfolding closed_def by simp
    59 
    60 lemma closed_Int [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    61   unfolding closed_def by auto
    62 
    63 lemma closed_INT [intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    64   unfolding closed_def by auto
    65 
    66 lemma closed_Inter [intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    67   unfolding closed_def uminus_Inf by auto
    68 
    69 lemma closed_Union [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    70   by (induct set: finite) auto
    71 
    72 lemma closed_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    73   unfolding SUP_def by (rule closed_Union) auto
    74 
    75 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    76   unfolding closed_def by simp
    77 
    78 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    79   unfolding closed_def by simp
    80 
    81 lemma open_Diff [intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    82   unfolding closed_open Diff_eq by (rule open_Int)
    83 
    84 lemma closed_Diff [intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    85   unfolding open_closed Diff_eq by (rule closed_Int)
    86 
    87 lemma open_Compl [intro]: "closed S \<Longrightarrow> open (- S)"
    88   unfolding closed_open .
    89 
    90 lemma closed_Compl [intro]: "open S \<Longrightarrow> closed (- S)"
    91   unfolding open_closed .
    92 
    93 end
    94 
    95 subsection{* Hausdorff and other separation properties *}
    96 
    97 class t0_space = topological_space +
    98   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
    99 
   100 class t1_space = topological_space +
   101   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   102 
   103 instance t1_space \<subseteq> t0_space
   104 proof qed (fast dest: t1_space)
   105 
   106 lemma separation_t1:
   107   fixes x y :: "'a::t1_space"
   108   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   109   using t1_space[of x y] by blast
   110 
   111 lemma closed_singleton:
   112   fixes a :: "'a::t1_space"
   113   shows "closed {a}"
   114 proof -
   115   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   116   have "open ?T" by (simp add: open_Union)
   117   also have "?T = - {a}"
   118     by (simp add: set_eq_iff separation_t1, auto)
   119   finally show "closed {a}" unfolding closed_def .
   120 qed
   121 
   122 lemma closed_insert [simp]:
   123   fixes a :: "'a::t1_space"
   124   assumes "closed S" shows "closed (insert a S)"
   125 proof -
   126   from closed_singleton assms
   127   have "closed ({a} \<union> S)" by (rule closed_Un)
   128   thus "closed (insert a S)" by simp
   129 qed
   130 
   131 lemma finite_imp_closed:
   132   fixes S :: "'a::t1_space set"
   133   shows "finite S \<Longrightarrow> closed S"
   134 by (induct set: finite, simp_all)
   135 
   136 text {* T2 spaces are also known as Hausdorff spaces. *}
   137 
   138 class t2_space = topological_space +
   139   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   140 
   141 instance t2_space \<subseteq> t1_space
   142 proof qed (fast dest: hausdorff)
   143 
   144 lemma separation_t2:
   145   fixes x y :: "'a::t2_space"
   146   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   147   using hausdorff[of x y] by blast
   148 
   149 lemma separation_t0:
   150   fixes x y :: "'a::t0_space"
   151   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   152   using t0_space[of x y] by blast
   153 
   154 text {* A perfect space is a topological space with no isolated points. *}
   155 
   156 class perfect_space = topological_space +
   157   assumes not_open_singleton: "\<not> open {x}"
   158 
   159 
   160 subsection {* Generators for toplogies *}
   161 
   162 inductive generate_topology for S where
   163   UNIV: "generate_topology S UNIV"
   164 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   165 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   166 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   167 
   168 hide_fact (open) UNIV Int UN Basis 
   169 
   170 lemma generate_topology_Union: 
   171   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   172   unfolding SUP_def by (intro generate_topology.UN) auto
   173 
   174 lemma topological_space_generate_topology:
   175   "class.topological_space (generate_topology S)"
   176   by default (auto intro: generate_topology.intros)
   177 
   178 subsection {* Order topologies *}
   179 
   180 class order_topology = order + "open" +
   181   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   182 begin
   183 
   184 subclass topological_space
   185   unfolding open_generated_order
   186   by (rule topological_space_generate_topology)
   187 
   188 lemma open_greaterThan [simp]: "open {a <..}"
   189   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   190 
   191 lemma open_lessThan [simp]: "open {..< a}"
   192   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   193 
   194 lemma open_greaterThanLessThan [simp]: "open {a <..< b}"
   195    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   196 
   197 end
   198 
   199 class linorder_topology = linorder + order_topology
   200 
   201 lemma closed_atMost [simp]: "closed {.. a::'a::linorder_topology}"
   202   by (simp add: closed_open)
   203 
   204 lemma closed_atLeast [simp]: "closed {a::'a::linorder_topology ..}"
   205   by (simp add: closed_open)
   206 
   207 lemma closed_atLeastAtMost [simp]: "closed {a::'a::linorder_topology .. b}"
   208 proof -
   209   have "{a .. b} = {a ..} \<inter> {.. b}"
   210     by auto
   211   then show ?thesis
   212     by (simp add: closed_Int)
   213 qed
   214 
   215 lemma (in linorder) less_separate:
   216   assumes "x < y"
   217   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   218 proof cases
   219   assume "\<exists>z. x < z \<and> z < y"
   220   then guess z ..
   221   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   222     by auto
   223   then show ?thesis by blast
   224 next
   225   assume "\<not> (\<exists>z. x < z \<and> z < y)"
   226   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   227     by auto
   228   then show ?thesis by blast
   229 qed
   230 
   231 instance linorder_topology \<subseteq> t2_space
   232 proof
   233   fix x y :: 'a
   234   from less_separate[of x y] less_separate[of y x]
   235   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   236     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   237 qed
   238 
   239 lemma (in linorder_topology) open_right:
   240   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   241   using assms unfolding open_generated_order
   242 proof induction
   243   case (Int A B)
   244   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   245   then show ?case by (auto intro!: exI[of _ "min a b"])
   246 next
   247   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   248 qed blast+
   249 
   250 lemma (in linorder_topology) open_left:
   251   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   252   using assms unfolding open_generated_order
   253 proof induction
   254   case (Int A B)
   255   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   256   then show ?case by (auto intro!: exI[of _ "max a b"])
   257 next
   258   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   259 qed blast+
   260 
   261 subsection {* Filters *}
   262 
   263 text {*
   264   This definition also allows non-proper filters.
   265 *}
   266 
   267 locale is_filter =
   268   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   269   assumes True: "F (\<lambda>x. True)"
   270   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   271   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   272 
   273 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   274 proof
   275   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   276 qed
   277 
   278 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   279   using Rep_filter [of F] by simp
   280 
   281 lemma Abs_filter_inverse':
   282   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   283   using assms by (simp add: Abs_filter_inverse)
   284 
   285 
   286 subsubsection {* Eventually *}
   287 
   288 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   289   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   290 
   291 lemma eventually_Abs_filter:
   292   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   293   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   294 
   295 lemma filter_eq_iff:
   296   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   297   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   298 
   299 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   300   unfolding eventually_def
   301   by (rule is_filter.True [OF is_filter_Rep_filter])
   302 
   303 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   304 proof -
   305   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   306   thus "eventually P F" by simp
   307 qed
   308 
   309 lemma eventually_mono:
   310   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   311   unfolding eventually_def
   312   by (rule is_filter.mono [OF is_filter_Rep_filter])
   313 
   314 lemma eventually_conj:
   315   assumes P: "eventually (\<lambda>x. P x) F"
   316   assumes Q: "eventually (\<lambda>x. Q x) F"
   317   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   318   using assms unfolding eventually_def
   319   by (rule is_filter.conj [OF is_filter_Rep_filter])
   320 
   321 lemma eventually_Ball_finite:
   322   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   323   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   324 using assms by (induct set: finite, simp, simp add: eventually_conj)
   325 
   326 lemma eventually_all_finite:
   327   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   328   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   329   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   330 using eventually_Ball_finite [of UNIV P] assms by simp
   331 
   332 lemma eventually_mp:
   333   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   334   assumes "eventually (\<lambda>x. P x) F"
   335   shows "eventually (\<lambda>x. Q x) F"
   336 proof (rule eventually_mono)
   337   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   338   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   339     using assms by (rule eventually_conj)
   340 qed
   341 
   342 lemma eventually_rev_mp:
   343   assumes "eventually (\<lambda>x. P x) F"
   344   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   345   shows "eventually (\<lambda>x. Q x) F"
   346 using assms(2) assms(1) by (rule eventually_mp)
   347 
   348 lemma eventually_conj_iff:
   349   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   350   by (auto intro: eventually_conj elim: eventually_rev_mp)
   351 
   352 lemma eventually_elim1:
   353   assumes "eventually (\<lambda>i. P i) F"
   354   assumes "\<And>i. P i \<Longrightarrow> Q i"
   355   shows "eventually (\<lambda>i. Q i) F"
   356   using assms by (auto elim!: eventually_rev_mp)
   357 
   358 lemma eventually_elim2:
   359   assumes "eventually (\<lambda>i. P i) F"
   360   assumes "eventually (\<lambda>i. Q i) F"
   361   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   362   shows "eventually (\<lambda>i. R i) F"
   363   using assms by (auto elim!: eventually_rev_mp)
   364 
   365 lemma eventually_subst:
   366   assumes "eventually (\<lambda>n. P n = Q n) F"
   367   shows "eventually P F = eventually Q F" (is "?L = ?R")
   368 proof -
   369   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   370       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   371     by (auto elim: eventually_elim1)
   372   then show ?thesis by (auto elim: eventually_elim2)
   373 qed
   374 
   375 ML {*
   376   fun eventually_elim_tac ctxt thms thm =
   377     let
   378       val thy = Proof_Context.theory_of ctxt
   379       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   380       val raw_elim_thm =
   381         (@{thm allI} RS @{thm always_eventually})
   382         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   383         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   384       val cases_prop = prop_of (raw_elim_thm RS thm)
   385       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   386     in
   387       CASES cases (rtac raw_elim_thm 1) thm
   388     end
   389 *}
   390 
   391 method_setup eventually_elim = {*
   392   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   393 *} "elimination of eventually quantifiers"
   394 
   395 
   396 subsubsection {* Finer-than relation *}
   397 
   398 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   399 filter @{term F'}. *}
   400 
   401 instantiation filter :: (type) complete_lattice
   402 begin
   403 
   404 definition le_filter_def:
   405   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   406 
   407 definition
   408   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   409 
   410 definition
   411   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   412 
   413 definition
   414   "bot = Abs_filter (\<lambda>P. True)"
   415 
   416 definition
   417   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   418 
   419 definition
   420   "inf F F' = Abs_filter
   421       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   422 
   423 definition
   424   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   425 
   426 definition
   427   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   428 
   429 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   430   unfolding top_filter_def
   431   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   432 
   433 lemma eventually_bot [simp]: "eventually P bot"
   434   unfolding bot_filter_def
   435   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   436 
   437 lemma eventually_sup:
   438   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   439   unfolding sup_filter_def
   440   by (rule eventually_Abs_filter, rule is_filter.intro)
   441      (auto elim!: eventually_rev_mp)
   442 
   443 lemma eventually_inf:
   444   "eventually P (inf F F') \<longleftrightarrow>
   445    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   446   unfolding inf_filter_def
   447   apply (rule eventually_Abs_filter, rule is_filter.intro)
   448   apply (fast intro: eventually_True)
   449   apply clarify
   450   apply (intro exI conjI)
   451   apply (erule (1) eventually_conj)
   452   apply (erule (1) eventually_conj)
   453   apply simp
   454   apply auto
   455   done
   456 
   457 lemma eventually_Sup:
   458   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   459   unfolding Sup_filter_def
   460   apply (rule eventually_Abs_filter, rule is_filter.intro)
   461   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   462   done
   463 
   464 instance proof
   465   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   466   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   467     by (rule less_filter_def) }
   468   { show "F \<le> F"
   469     unfolding le_filter_def by simp }
   470   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   471     unfolding le_filter_def by simp }
   472   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   473     unfolding le_filter_def filter_eq_iff by fast }
   474   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   475     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   476   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   477     unfolding le_filter_def eventually_inf
   478     by (auto elim!: eventually_mono intro: eventually_conj) }
   479   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   480     unfolding le_filter_def eventually_sup by simp_all }
   481   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   482     unfolding le_filter_def eventually_sup by simp }
   483   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   484     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   485   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   486     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   487   { assume "F \<in> S" thus "F \<le> Sup S"
   488     unfolding le_filter_def eventually_Sup by simp }
   489   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   490     unfolding le_filter_def eventually_Sup by simp }
   491   { show "Inf {} = (top::'a filter)"
   492     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   493       (metis (full_types) Topological_Spaces.top_filter_def always_eventually eventually_top) }
   494   { show "Sup {} = (bot::'a filter)"
   495     by (auto simp: bot_filter_def Sup_filter_def) }
   496 qed
   497 
   498 end
   499 
   500 lemma filter_leD:
   501   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   502   unfolding le_filter_def by simp
   503 
   504 lemma filter_leI:
   505   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   506   unfolding le_filter_def by simp
   507 
   508 lemma eventually_False:
   509   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   510   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   511 
   512 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   513   where "trivial_limit F \<equiv> F = bot"
   514 
   515 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   516   by (rule eventually_False [symmetric])
   517 
   518 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   519   by (cases P) (simp_all add: eventually_False)
   520 
   521 
   522 subsubsection {* Map function for filters *}
   523 
   524 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   525   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   526 
   527 lemma eventually_filtermap:
   528   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   529   unfolding filtermap_def
   530   apply (rule eventually_Abs_filter)
   531   apply (rule is_filter.intro)
   532   apply (auto elim!: eventually_rev_mp)
   533   done
   534 
   535 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   536   by (simp add: filter_eq_iff eventually_filtermap)
   537 
   538 lemma filtermap_filtermap:
   539   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   540   by (simp add: filter_eq_iff eventually_filtermap)
   541 
   542 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   543   unfolding le_filter_def eventually_filtermap by simp
   544 
   545 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   546   by (simp add: filter_eq_iff eventually_filtermap)
   547 
   548 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   549   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   550 
   551 subsubsection {* Order filters *}
   552 
   553 definition at_top :: "('a::order) filter"
   554   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   555 
   556 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   557   unfolding at_top_def
   558 proof (rule eventually_Abs_filter, rule is_filter.intro)
   559   fix P Q :: "'a \<Rightarrow> bool"
   560   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   561   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   562   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   563   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   564 qed auto
   565 
   566 lemma eventually_ge_at_top:
   567   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   568   unfolding eventually_at_top_linorder by auto
   569 
   570 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::dense_linorder. \<forall>n>N. P n)"
   571   unfolding eventually_at_top_linorder
   572 proof safe
   573   fix N assume "\<forall>n\<ge>N. P n" then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   574 next
   575   fix N assume "\<forall>n>N. P n"
   576   moreover from gt_ex[of N] guess y ..
   577   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   578 qed
   579 
   580 lemma eventually_gt_at_top:
   581   "eventually (\<lambda>x. (c::_::dense_linorder) < x) at_top"
   582   unfolding eventually_at_top_dense by auto
   583 
   584 definition at_bot :: "('a::order) filter"
   585   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   586 
   587 lemma eventually_at_bot_linorder:
   588   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   589   unfolding at_bot_def
   590 proof (rule eventually_Abs_filter, rule is_filter.intro)
   591   fix P Q :: "'a \<Rightarrow> bool"
   592   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   593   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   594   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   595   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   596 qed auto
   597 
   598 lemma eventually_le_at_bot:
   599   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   600   unfolding eventually_at_bot_linorder by auto
   601 
   602 lemma eventually_at_bot_dense:
   603   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   604   unfolding eventually_at_bot_linorder
   605 proof safe
   606   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   607 next
   608   fix N assume "\<forall>n<N. P n" 
   609   moreover from lt_ex[of N] guess y ..
   610   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   611 qed
   612 
   613 lemma eventually_gt_at_bot:
   614   "eventually (\<lambda>x. x < (c::_::dense_linorder)) at_bot"
   615   unfolding eventually_at_bot_dense by auto
   616 
   617 subsection {* Sequentially *}
   618 
   619 abbreviation sequentially :: "nat filter"
   620   where "sequentially == at_top"
   621 
   622 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   623   unfolding at_top_def by simp
   624 
   625 lemma eventually_sequentially:
   626   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   627   by (rule eventually_at_top_linorder)
   628 
   629 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   630   unfolding filter_eq_iff eventually_sequentially by auto
   631 
   632 lemmas trivial_limit_sequentially = sequentially_bot
   633 
   634 lemma eventually_False_sequentially [simp]:
   635   "\<not> eventually (\<lambda>n. False) sequentially"
   636   by (simp add: eventually_False)
   637 
   638 lemma le_sequentially:
   639   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   640   unfolding le_filter_def eventually_sequentially
   641   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   642 
   643 lemma eventually_sequentiallyI:
   644   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   645   shows "eventually P sequentially"
   646 using assms by (auto simp: eventually_sequentially)
   647 
   648 lemma eventually_sequentially_seg:
   649   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   650   unfolding eventually_sequentially
   651   apply safe
   652    apply (rule_tac x="N + k" in exI)
   653    apply rule
   654    apply (erule_tac x="n - k" in allE)
   655    apply auto []
   656   apply (rule_tac x=N in exI)
   657   apply auto []
   658   done
   659 
   660 subsubsection {* Standard filters *}
   661 
   662 definition principal :: "'a set \<Rightarrow> 'a filter" where
   663   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   664 
   665 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   666   unfolding principal_def
   667   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   668 
   669 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   670   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   671 
   672 lemma principal_UNIV[simp]: "principal UNIV = top"
   673   by (auto simp: filter_eq_iff eventually_principal)
   674 
   675 lemma principal_empty[simp]: "principal {} = bot"
   676   by (auto simp: filter_eq_iff eventually_principal)
   677 
   678 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   679   by (auto simp: le_filter_def eventually_principal)
   680 
   681 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   682   unfolding le_filter_def eventually_principal
   683   apply safe
   684   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   685   apply (auto elim: eventually_elim1)
   686   done
   687 
   688 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   689   unfolding eq_iff by simp
   690 
   691 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   692   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   693 
   694 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   695   unfolding filter_eq_iff eventually_inf eventually_principal
   696   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   697 
   698 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   699   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   700 
   701 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   702   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   703 
   704 subsubsection {* Topological filters *}
   705 
   706 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   707   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   708 
   709 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   710   where "at a within s = inf (nhds a) (principal (s - {a}))"
   711 
   712 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   713   "at x \<equiv> at x within (CONST UNIV)"
   714 
   715 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   716   "at_right x \<equiv> at x within {x <..}"
   717 
   718 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   719   "at_left x \<equiv> at x within {..< x}"
   720 
   721 lemma (in topological_space) eventually_nhds:
   722   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   723   unfolding nhds_def
   724 proof (rule eventually_Abs_filter, rule is_filter.intro)
   725   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   726   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   727 next
   728   fix P Q
   729   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   730      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   731   then obtain S T where
   732     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   733     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   734   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   735     by (simp add: open_Int)
   736   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   737 qed auto
   738 
   739 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   740   unfolding trivial_limit_def eventually_nhds by simp
   741 
   742 lemma eventually_at_filter:
   743   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   744   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   745 
   746 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   747   unfolding at_within_def by (intro inf_mono) auto
   748 
   749 lemma eventually_at_topological:
   750   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   751   unfolding eventually_nhds eventually_at_filter by simp
   752 
   753 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   754   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   755 
   756 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   757   unfolding trivial_limit_def eventually_at_topological
   758   by (safe, case_tac "S = {a}", simp, fast, fast)
   759 
   760 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   761   by (simp add: at_eq_bot_iff not_open_singleton)
   762 
   763 lemma eventually_at_right:
   764   fixes x :: "'a :: {no_top, linorder_topology}"
   765   shows "eventually P (at_right x) \<longleftrightarrow> (\<exists>b. x < b \<and> (\<forall>z. x < z \<and> z < b \<longrightarrow> P z))"
   766   unfolding eventually_at_topological
   767 proof safe
   768   from gt_ex[of x] guess y ..
   769   moreover fix S assume "open S" "x \<in> S" note open_right[OF this, of y]
   770   moreover note gt_ex[of x]
   771   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {x<..} \<longrightarrow> P s"
   772   ultimately show "\<exists>b>x. \<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   773     by (auto simp: subset_eq Ball_def)
   774 next
   775   fix b assume "x < b" "\<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   776   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>xa\<in>S. xa \<noteq> x \<longrightarrow> xa \<in> {x<..} \<longrightarrow> P xa)"
   777     by (intro exI[of _ "{..< b}"]) auto
   778 qed
   779 
   780 lemma eventually_at_left:
   781   fixes x :: "'a :: {no_bot, linorder_topology}"
   782   shows "eventually P (at_left x) \<longleftrightarrow> (\<exists>b. x > b \<and> (\<forall>z. b < z \<and> z < x \<longrightarrow> P z))"
   783   unfolding eventually_at_topological
   784 proof safe
   785   from lt_ex[of x] guess y ..
   786   moreover fix S assume "open S" "x \<in> S" note open_left[OF this, of y]
   787   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s"
   788   ultimately show "\<exists>b<x. \<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   789     by (auto simp: subset_eq Ball_def)
   790 next
   791   fix b assume "b < x" "\<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   792   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s)"
   793     by (intro exI[of _ "{b <..}"]) auto
   794 qed
   795 
   796 lemma trivial_limit_at_left_real [simp]:
   797   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_linorder, linorder_topology}))"
   798   unfolding trivial_limit_def eventually_at_left by (auto dest: dense)
   799 
   800 lemma trivial_limit_at_right_real [simp]:
   801   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_linorder, linorder_topology}))"
   802   unfolding trivial_limit_def eventually_at_right by (auto dest: dense)
   803 
   804 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   805   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   806            elim: eventually_elim2 eventually_elim1)
   807 
   808 lemma eventually_at_split:
   809   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   810   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   811 
   812 subsection {* Limits *}
   813 
   814 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   815   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   816 
   817 syntax
   818   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   819 
   820 translations
   821   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   822 
   823 lemma filterlim_iff:
   824   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   825   unfolding filterlim_def le_filter_def eventually_filtermap ..
   826 
   827 lemma filterlim_compose:
   828   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   829   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   830 
   831 lemma filterlim_mono:
   832   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   833   unfolding filterlim_def by (metis filtermap_mono order_trans)
   834 
   835 lemma filterlim_ident: "LIM x F. x :> F"
   836   by (simp add: filterlim_def filtermap_ident)
   837 
   838 lemma filterlim_cong:
   839   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   840   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   841 
   842 lemma filterlim_principal:
   843   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   844   unfolding filterlim_def eventually_filtermap le_principal ..
   845 
   846 lemma filterlim_inf:
   847   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   848   unfolding filterlim_def by simp
   849 
   850 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   851   unfolding filterlim_def filtermap_filtermap ..
   852 
   853 lemma filterlim_sup:
   854   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   855   unfolding filterlim_def filtermap_sup by auto
   856 
   857 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   858   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   859 
   860 subsubsection {* Tendsto *}
   861 
   862 abbreviation (in topological_space)
   863   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   864   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   865 
   866 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   867   "Lim A f = (THE l. (f ---> l) A)"
   868 
   869 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
   870   by simp
   871 
   872 ML {*
   873 
   874 structure Tendsto_Intros = Named_Thms
   875 (
   876   val name = @{binding tendsto_intros}
   877   val description = "introduction rules for tendsto"
   878 )
   879 
   880 *}
   881 
   882 setup {*
   883   Tendsto_Intros.setup #>
   884   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   885     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
   886 *}
   887 
   888 lemma (in topological_space) tendsto_def:
   889    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   890   unfolding filterlim_def
   891 proof safe
   892   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   893   then show "eventually (\<lambda>x. f x \<in> S) F"
   894     unfolding eventually_nhds eventually_filtermap le_filter_def
   895     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   896 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   897 
   898 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   899   unfolding tendsto_def le_filter_def by fast
   900 
   901 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
   902   by (blast intro: tendsto_mono at_le)
   903 
   904 lemma filterlim_at:
   905   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
   906   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   907 
   908 lemma (in topological_space) topological_tendstoI:
   909   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
   910   unfolding tendsto_def by auto
   911 
   912 lemma (in topological_space) topological_tendstoD:
   913   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   914   unfolding tendsto_def by auto
   915 
   916 lemma order_tendstoI:
   917   fixes y :: "_ :: order_topology"
   918   assumes "\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   919   assumes "\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   920   shows "(f ---> y) F"
   921 proof (rule topological_tendstoI)
   922   fix S assume "open S" "y \<in> S"
   923   then show "eventually (\<lambda>x. f x \<in> S) F"
   924     unfolding open_generated_order
   925   proof induct
   926     case (UN K)
   927     then obtain k where "y \<in> k" "k \<in> K" by auto
   928     with UN(2)[of k] show ?case
   929       by (auto elim: eventually_elim1)
   930   qed (insert assms, auto elim: eventually_elim2)
   931 qed
   932 
   933 lemma order_tendstoD:
   934   fixes y :: "_ :: order_topology"
   935   assumes y: "(f ---> y) F"
   936   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   937     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   938   using topological_tendstoD[OF y, of "{..< a}"] topological_tendstoD[OF y, of "{a <..}"] by auto
   939 
   940 lemma order_tendsto_iff: 
   941   fixes f :: "_ \<Rightarrow> 'a :: order_topology"
   942   shows "(f ---> x) F \<longleftrightarrow>(\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   943   by (metis order_tendstoI order_tendstoD)
   944 
   945 lemma tendsto_bot [simp]: "(f ---> a) bot"
   946   unfolding tendsto_def by simp
   947 
   948 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
   949   unfolding tendsto_def eventually_at_topological by auto
   950 
   951 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   952   by (simp add: tendsto_def)
   953 
   954 lemma (in t2_space) tendsto_unique:
   955   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   956   shows "a = b"
   957 proof (rule ccontr)
   958   assume "a \<noteq> b"
   959   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   960     using hausdorff [OF `a \<noteq> b`] by fast
   961   have "eventually (\<lambda>x. f x \<in> U) F"
   962     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   963   moreover
   964   have "eventually (\<lambda>x. f x \<in> V) F"
   965     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   966   ultimately
   967   have "eventually (\<lambda>x. False) F"
   968   proof eventually_elim
   969     case (elim x)
   970     hence "f x \<in> U \<inter> V" by simp
   971     with `U \<inter> V = {}` show ?case by simp
   972   qed
   973   with `\<not> trivial_limit F` show "False"
   974     by (simp add: trivial_limit_def)
   975 qed
   976 
   977 lemma (in t2_space) tendsto_const_iff:
   978   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
   979   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   980 
   981 lemma increasing_tendsto:
   982   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   983   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   984       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   985   shows "(f ---> l) F"
   986   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   987 
   988 lemma decreasing_tendsto:
   989   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   990   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   991       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   992   shows "(f ---> l) F"
   993   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   994 
   995 lemma tendsto_sandwich:
   996   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
   997   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   998   assumes lim: "(f ---> c) net" "(h ---> c) net"
   999   shows "(g ---> c) net"
  1000 proof (rule order_tendstoI)
  1001   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1002     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1003 next
  1004   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1005     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1006 qed
  1007 
  1008 lemma tendsto_le:
  1009   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1010   assumes F: "\<not> trivial_limit F"
  1011   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1012   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1013   shows "y \<le> x"
  1014 proof (rule ccontr)
  1015   assume "\<not> y \<le> x"
  1016   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1017     by (auto simp: not_le)
  1018   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1019     using x y by (auto intro: order_tendstoD)
  1020   with ev have "eventually (\<lambda>x. False) F"
  1021     by eventually_elim (insert xy, fastforce)
  1022   with F show False
  1023     by (simp add: eventually_False)
  1024 qed
  1025 
  1026 lemma tendsto_le_const:
  1027   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1028   assumes F: "\<not> trivial_limit F"
  1029   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>x. a \<le> f x) F"
  1030   shows "a \<le> x"
  1031   using F x tendsto_const a by (rule tendsto_le)
  1032 
  1033 subsubsection {* Rules about @{const Lim} *}
  1034 
  1035 lemma (in t2_space) tendsto_Lim:
  1036   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1037   unfolding Lim_def using tendsto_unique[of net f] by auto
  1038 
  1039 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1040   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1041 
  1042 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1043 
  1044 lemma filterlim_at_top:
  1045   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1046   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1047   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1048 
  1049 lemma filterlim_at_top_dense:
  1050   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1051   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1052   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1053             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1054 
  1055 lemma filterlim_at_top_ge:
  1056   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1057   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1058   unfolding filterlim_at_top
  1059 proof safe
  1060   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1061   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1062     by (auto elim!: eventually_elim1)
  1063 qed simp
  1064 
  1065 lemma filterlim_at_top_at_top:
  1066   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1067   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1068   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1069   assumes Q: "eventually Q at_top"
  1070   assumes P: "eventually P at_top"
  1071   shows "filterlim f at_top at_top"
  1072 proof -
  1073   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1074     unfolding eventually_at_top_linorder by auto
  1075   show ?thesis
  1076   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1077     fix z assume "x \<le> z"
  1078     with x have "P z" by auto
  1079     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1080       by (rule eventually_ge_at_top)
  1081     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1082       by eventually_elim (metis mono bij `P z`)
  1083   qed
  1084 qed
  1085 
  1086 lemma filterlim_at_top_gt:
  1087   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1088   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1089   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1090 
  1091 lemma filterlim_at_bot: 
  1092   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1093   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1094   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1095 
  1096 lemma filterlim_at_bot_le:
  1097   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1098   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1099   unfolding filterlim_at_bot
  1100 proof safe
  1101   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1102   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1103     by (auto elim!: eventually_elim1)
  1104 qed simp
  1105 
  1106 lemma filterlim_at_bot_lt:
  1107   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1108   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1109   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1110 
  1111 lemma filterlim_at_bot_at_right:
  1112   fixes f :: "'a::{no_top, linorder_topology} \<Rightarrow> 'b::linorder"
  1113   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1114   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1115   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1116   assumes P: "eventually P at_bot"
  1117   shows "filterlim f at_bot (at_right a)"
  1118 proof -
  1119   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1120     unfolding eventually_at_bot_linorder by auto
  1121   show ?thesis
  1122   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1123     fix z assume "z \<le> x"
  1124     with x have "P z" by auto
  1125     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1126       using bound[OF bij(2)[OF `P z`]]
  1127       unfolding eventually_at_right by (auto intro!: exI[of _ "g z"])
  1128     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1129       by eventually_elim (metis bij `P z` mono)
  1130   qed
  1131 qed
  1132 
  1133 lemma filterlim_at_top_at_left:
  1134   fixes f :: "'a::{no_bot, linorder_topology} \<Rightarrow> 'b::linorder"
  1135   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1136   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1137   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1138   assumes P: "eventually P at_top"
  1139   shows "filterlim f at_top (at_left a)"
  1140 proof -
  1141   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1142     unfolding eventually_at_top_linorder by auto
  1143   show ?thesis
  1144   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1145     fix z assume "x \<le> z"
  1146     with x have "P z" by auto
  1147     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1148       using bound[OF bij(2)[OF `P z`]]
  1149       unfolding eventually_at_left by (auto intro!: exI[of _ "g z"])
  1150     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1151       by eventually_elim (metis bij `P z` mono)
  1152   qed
  1153 qed
  1154 
  1155 lemma filterlim_split_at:
  1156   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1157   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1158 
  1159 lemma filterlim_at_split:
  1160   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1161   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1162 
  1163 
  1164 subsection {* Limits on sequences *}
  1165 
  1166 abbreviation (in topological_space)
  1167   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1168     ("((_)/ ----> (_))" [60, 60] 60) where
  1169   "X ----> L \<equiv> (X ---> L) sequentially"
  1170 
  1171 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1172   "lim X \<equiv> Lim sequentially X"
  1173 
  1174 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1175   "convergent X = (\<exists>L. X ----> L)"
  1176 
  1177 lemma lim_def: "lim X = (THE L. X ----> L)"
  1178   unfolding Lim_def ..
  1179 
  1180 subsubsection {* Monotone sequences and subsequences *}
  1181 
  1182 definition
  1183   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1184     --{*Definition of monotonicity.
  1185         The use of disjunction here complicates proofs considerably.
  1186         One alternative is to add a Boolean argument to indicate the direction.
  1187         Another is to develop the notions of increasing and decreasing first.*}
  1188   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1189 
  1190 definition
  1191   incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1192     --{*Increasing sequence*}
  1193   "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
  1194 
  1195 definition
  1196   decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1197     --{*Decreasing sequence*}
  1198   "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1199 
  1200 definition
  1201   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1202     --{*Definition of subsequence*}
  1203   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1204 
  1205 lemma incseq_mono: "mono f \<longleftrightarrow> incseq f"
  1206   unfolding mono_def incseq_def by auto
  1207 
  1208 lemma incseq_SucI:
  1209   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1210   using lift_Suc_mono_le[of X]
  1211   by (auto simp: incseq_def)
  1212 
  1213 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1214   by (auto simp: incseq_def)
  1215 
  1216 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1217   using incseqD[of A i "Suc i"] by auto
  1218 
  1219 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1220   by (auto intro: incseq_SucI dest: incseq_SucD)
  1221 
  1222 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1223   unfolding incseq_def by auto
  1224 
  1225 lemma decseq_SucI:
  1226   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1227   using order.lift_Suc_mono_le[OF dual_order, of X]
  1228   by (auto simp: decseq_def)
  1229 
  1230 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1231   by (auto simp: decseq_def)
  1232 
  1233 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1234   using decseqD[of A i "Suc i"] by auto
  1235 
  1236 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1237   by (auto intro: decseq_SucI dest: decseq_SucD)
  1238 
  1239 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1240   unfolding decseq_def by auto
  1241 
  1242 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1243   unfolding monoseq_def incseq_def decseq_def ..
  1244 
  1245 lemma monoseq_Suc:
  1246   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1247   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1248 
  1249 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1250 by (simp add: monoseq_def)
  1251 
  1252 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1253 by (simp add: monoseq_def)
  1254 
  1255 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1256 by (simp add: monoseq_Suc)
  1257 
  1258 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1259 by (simp add: monoseq_Suc)
  1260 
  1261 lemma monoseq_minus:
  1262   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1263   assumes "monoseq a"
  1264   shows "monoseq (\<lambda> n. - a n)"
  1265 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1266   case True
  1267   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1268   thus ?thesis by (rule monoI2)
  1269 next
  1270   case False
  1271   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1272   thus ?thesis by (rule monoI1)
  1273 qed
  1274 
  1275 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1276 
  1277 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1278 apply (simp add: subseq_def)
  1279 apply (auto dest!: less_imp_Suc_add)
  1280 apply (induct_tac k)
  1281 apply (auto intro: less_trans)
  1282 done
  1283 
  1284 text{* for any sequence, there is a monotonic subsequence *}
  1285 lemma seq_monosub:
  1286   fixes s :: "nat => 'a::linorder"
  1287   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
  1288 proof cases
  1289   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
  1290   assume *: "\<forall>n. \<exists>p. ?P p n"
  1291   def f \<equiv> "nat_rec (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
  1292   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
  1293   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
  1294   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
  1295   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
  1296   then have "subseq f" unfolding subseq_Suc_iff by auto
  1297   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
  1298   proof (intro disjI2 allI)
  1299     fix n show "s (f (Suc n)) \<le> s (f n)"
  1300     proof (cases n)
  1301       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
  1302     next
  1303       case (Suc m)
  1304       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
  1305       with P_Suc Suc show ?thesis by simp
  1306     qed
  1307   qed
  1308   ultimately show ?thesis by auto
  1309 next
  1310   let "?P p m" = "m < p \<and> s m < s p"
  1311   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1312   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1313   def f \<equiv> "nat_rec (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
  1314   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
  1315   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
  1316   have P_0: "?P (f 0) (Suc N)"
  1317     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
  1318   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
  1319       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
  1320   note P' = this
  1321   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
  1322       by (induct i) (insert P_0 P', auto) }
  1323   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
  1324     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
  1325   then show ?thesis by auto
  1326 qed
  1327 
  1328 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1329 proof(induct n)
  1330   case 0 thus ?case by simp
  1331 next
  1332   case (Suc n)
  1333   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1334   have "n < f (Suc n)" by arith
  1335   thus ?case by arith
  1336 qed
  1337 
  1338 lemma eventually_subseq:
  1339   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1340   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1341 
  1342 lemma not_eventually_sequentiallyD:
  1343   assumes P: "\<not> eventually P sequentially"
  1344   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1345 proof -
  1346   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1347     unfolding eventually_sequentially by (simp add: not_less)
  1348   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1349     by (auto simp: choice_iff)
  1350   then show ?thesis
  1351     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1352              simp: less_eq_Suc_le subseq_Suc_iff)
  1353 qed
  1354 
  1355 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1356   unfolding filterlim_iff by (metis eventually_subseq)
  1357 
  1358 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1359   unfolding subseq_def by simp
  1360 
  1361 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1362   using assms by (auto simp: subseq_def)
  1363 
  1364 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1365   by (simp add: incseq_def monoseq_def)
  1366 
  1367 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1368   by (simp add: decseq_def monoseq_def)
  1369 
  1370 lemma decseq_eq_incseq:
  1371   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1372   by (simp add: decseq_def incseq_def)
  1373 
  1374 lemma INT_decseq_offset:
  1375   assumes "decseq F"
  1376   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1377 proof safe
  1378   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1379   show "x \<in> F i"
  1380   proof cases
  1381     from x have "x \<in> F n" by auto
  1382     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1383       unfolding decseq_def by simp
  1384     finally show ?thesis .
  1385   qed (insert x, simp)
  1386 qed auto
  1387 
  1388 lemma LIMSEQ_const_iff:
  1389   fixes k l :: "'a::t2_space"
  1390   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1391   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1392 
  1393 lemma LIMSEQ_SUP:
  1394   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1395   by (intro increasing_tendsto)
  1396      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1397 
  1398 lemma LIMSEQ_INF:
  1399   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1400   by (intro decreasing_tendsto)
  1401      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1402 
  1403 lemma LIMSEQ_ignore_initial_segment:
  1404   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1405   unfolding tendsto_def
  1406   by (subst eventually_sequentially_seg[where k=k])
  1407 
  1408 lemma LIMSEQ_offset:
  1409   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1410   unfolding tendsto_def
  1411   by (subst (asm) eventually_sequentially_seg[where k=k])
  1412 
  1413 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1414 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1415 
  1416 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1417 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1418 
  1419 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1420 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1421 
  1422 lemma LIMSEQ_unique:
  1423   fixes a b :: "'a::t2_space"
  1424   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1425   using trivial_limit_sequentially by (rule tendsto_unique)
  1426 
  1427 lemma LIMSEQ_le_const:
  1428   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1429   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1430 
  1431 lemma LIMSEQ_le:
  1432   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1433   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1434 
  1435 lemma LIMSEQ_le_const2:
  1436   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1437   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1438 
  1439 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1440 by (simp add: convergent_def)
  1441 
  1442 lemma convergentI: "(X ----> L) ==> convergent X"
  1443 by (auto simp add: convergent_def)
  1444 
  1445 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1446 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1447 
  1448 lemma convergent_const: "convergent (\<lambda>n. c)"
  1449   by (rule convergentI, rule tendsto_const)
  1450 
  1451 lemma monoseq_le:
  1452   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1453     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1454   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1455 
  1456 lemma LIMSEQ_subseq_LIMSEQ:
  1457   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1458   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1459 
  1460 lemma convergent_subseq_convergent:
  1461   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1462   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1463 
  1464 lemma limI: "X ----> L ==> lim X = L"
  1465 apply (simp add: lim_def)
  1466 apply (blast intro: LIMSEQ_unique)
  1467 done
  1468 
  1469 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1470   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1471 
  1472 subsubsection{*Increasing and Decreasing Series*}
  1473 
  1474 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1475   by (metis incseq_def LIMSEQ_le_const)
  1476 
  1477 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1478   by (metis decseq_def LIMSEQ_le_const2)
  1479 
  1480 subsection {* First countable topologies *}
  1481 
  1482 class first_countable_topology = topological_space +
  1483   assumes first_countable_basis:
  1484     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1485 
  1486 lemma (in first_countable_topology) countable_basis_at_decseq:
  1487   obtains A :: "nat \<Rightarrow> 'a set" where
  1488     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1489     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1490 proof atomize_elim
  1491   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1492     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1493     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1494   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1495   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1496       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1497   proof (safe intro!: exI[of _ F])
  1498     fix i
  1499     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1500     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1501   next
  1502     fix S assume "open S" "x \<in> S"
  1503     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1504     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1505       by (auto simp: F_def)
  1506     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1507       by (auto simp: eventually_sequentially)
  1508   qed
  1509 qed
  1510 
  1511 lemma (in first_countable_topology) countable_basis:
  1512   obtains A :: "nat \<Rightarrow> 'a set" where
  1513     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1514     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1515 proof atomize_elim
  1516   from countable_basis_at_decseq[of x] guess A . note A = this
  1517   { fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1518     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1519       by (auto elim: eventually_elim1 simp: subset_eq) }
  1520   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1521     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1522 qed
  1523 
  1524 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1525   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1526   shows "eventually P (inf (nhds a) (principal s))"
  1527 proof (rule ccontr)
  1528   from countable_basis[of a] guess A . note A = this
  1529   assume "\<not> eventually P (inf (nhds a) (principal s))"
  1530   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1531     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1532   then guess F ..
  1533   hence F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1534     by fast+
  1535   with A have "F ----> a" by auto
  1536   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1537     using assms F0 by simp
  1538   thus "False" by (simp add: F3)
  1539 qed
  1540 
  1541 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1542   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1543     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1544 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1545   assume "eventually P (inf (nhds a) (principal s))" 
  1546   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1547     by (auto simp: eventually_inf_principal eventually_nhds)
  1548   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1549   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1550     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1551 qed
  1552 
  1553 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1554   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1555   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1556 
  1557 subsection {* Function limit at a point *}
  1558 
  1559 abbreviation
  1560   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1561         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1562   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1563 
  1564 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1565   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1566 
  1567 lemma LIM_const_not_eq[tendsto_intros]:
  1568   fixes a :: "'a::perfect_space"
  1569   fixes k L :: "'b::t2_space"
  1570   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1571   by (simp add: tendsto_const_iff)
  1572 
  1573 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1574 
  1575 lemma LIM_const_eq:
  1576   fixes a :: "'a::perfect_space"
  1577   fixes k L :: "'b::t2_space"
  1578   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1579   by (simp add: tendsto_const_iff)
  1580 
  1581 lemma LIM_unique:
  1582   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1583   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1584   using at_neq_bot by (rule tendsto_unique)
  1585 
  1586 text {* Limits are equal for functions equal except at limit point *}
  1587 
  1588 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1589   unfolding tendsto_def eventually_at_topological by simp
  1590 
  1591 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1592   by (simp add: LIM_equal)
  1593 
  1594 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1595   by simp
  1596 
  1597 lemma tendsto_at_iff_tendsto_nhds:
  1598   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1599   unfolding tendsto_def eventually_at_filter
  1600   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1601 
  1602 lemma tendsto_compose:
  1603   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1604   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1605 
  1606 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1607   unfolding o_def by (rule tendsto_compose)
  1608 
  1609 lemma tendsto_compose_eventually:
  1610   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1611   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1612 
  1613 lemma LIM_compose_eventually:
  1614   assumes f: "f -- a --> b"
  1615   assumes g: "g -- b --> c"
  1616   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1617   shows "(\<lambda>x. g (f x)) -- a --> c"
  1618   using g f inj by (rule tendsto_compose_eventually)
  1619 
  1620 subsubsection {* Relation of LIM and LIMSEQ *}
  1621 
  1622 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1623   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1624     eventually P (at a within s)"
  1625   unfolding at_within_def
  1626   by (intro sequentially_imp_eventually_nhds_within) auto
  1627 
  1628 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1629   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1630   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1631 
  1632 lemma LIMSEQ_SEQ_conv1:
  1633   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1634   assumes f: "f -- a --> l"
  1635   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1636   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1637 
  1638 lemma LIMSEQ_SEQ_conv2:
  1639   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1640   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1641   shows "f -- a --> l"
  1642   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1643 
  1644 lemma LIMSEQ_SEQ_conv:
  1645   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1646    (X -- a --> (L::'b::topological_space))"
  1647   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1648 
  1649 subsection {* Continuity *}
  1650 
  1651 subsubsection {* Continuity on a set *}
  1652 
  1653 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1654   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  1655 
  1656 lemma continuous_on_cong [cong]:
  1657   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1658   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1659 
  1660 lemma continuous_on_topological:
  1661   "continuous_on s f \<longleftrightarrow>
  1662     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1663   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1664 
  1665 lemma continuous_on_open_invariant:
  1666   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1667 proof safe
  1668   fix B :: "'b set" assume "continuous_on s f" "open B"
  1669   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1670     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1671   then guess A unfolding bchoice_iff ..
  1672   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1673     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1674 next
  1675   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1676   show "continuous_on s f"
  1677     unfolding continuous_on_topological
  1678   proof safe
  1679     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1680     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1681     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1682       by (intro exI[of _ A]) auto
  1683   qed
  1684 qed
  1685 
  1686 lemma continuous_on_open_vimage:
  1687   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1688   unfolding continuous_on_open_invariant
  1689   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1690 
  1691 lemma continuous_on_closed_invariant:
  1692   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1693 proof -
  1694   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1695     by (metis double_compl)
  1696   show ?thesis
  1697     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1698 qed
  1699 
  1700 lemma continuous_on_closed_vimage:
  1701   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1702   unfolding continuous_on_closed_invariant
  1703   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1704 
  1705 lemma continuous_on_open_Union:
  1706   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1707   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1708 
  1709 lemma continuous_on_open_UN:
  1710   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1711   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1712 
  1713 lemma continuous_on_closed_Un:
  1714   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1715   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1716 
  1717 lemma continuous_on_If:
  1718   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1719     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1720   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1721 proof-
  1722   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1723     by auto
  1724   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1725     by simp_all
  1726   with closed show ?thesis
  1727     by (rule continuous_on_closed_Un)
  1728 qed
  1729 
  1730 ML {*
  1731 
  1732 structure Continuous_On_Intros = Named_Thms
  1733 (
  1734   val name = @{binding continuous_on_intros}
  1735   val description = "Structural introduction rules for setwise continuity"
  1736 )
  1737 
  1738 *}
  1739 
  1740 setup Continuous_On_Intros.setup
  1741 
  1742 lemma continuous_on_id[continuous_on_intros]: "continuous_on s (\<lambda>x. x)"
  1743   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  1744 
  1745 lemma continuous_on_const[continuous_on_intros]: "continuous_on s (\<lambda>x. c)"
  1746   unfolding continuous_on_def by (auto intro: tendsto_const)
  1747 
  1748 lemma continuous_on_compose[continuous_on_intros]:
  1749   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1750   unfolding continuous_on_topological by simp metis
  1751 
  1752 lemma continuous_on_compose2:
  1753   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1754   using continuous_on_compose[of s f g] by (simp add: comp_def)
  1755 
  1756 subsubsection {* Continuity at a point *}
  1757 
  1758 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1759   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  1760 
  1761 ML {*
  1762 
  1763 structure Continuous_Intros = Named_Thms
  1764 (
  1765   val name = @{binding continuous_intros}
  1766   val description = "Structural introduction rules for pointwise continuity"
  1767 )
  1768 
  1769 *}
  1770 
  1771 setup Continuous_Intros.setup
  1772 
  1773 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1774   unfolding continuous_def by auto
  1775 
  1776 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1777   by simp
  1778 
  1779 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  1780   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1781 
  1782 lemma continuous_within_topological:
  1783   "continuous (at x within s) f \<longleftrightarrow>
  1784     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1785   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1786 
  1787 lemma continuous_within_compose[continuous_intros]:
  1788   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1789   continuous (at x within s) (g o f)"
  1790   by (simp add: continuous_within_topological) metis
  1791 
  1792 lemma continuous_within_compose2:
  1793   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1794   continuous (at x within s) (\<lambda>x. g (f x))"
  1795   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1796 
  1797 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  1798   using continuous_within[of x UNIV f] by simp
  1799 
  1800 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1801   unfolding continuous_within by (rule tendsto_ident_at)
  1802 
  1803 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1804   unfolding continuous_def by (rule tendsto_const)
  1805 
  1806 lemma continuous_on_eq_continuous_within:
  1807   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1808   unfolding continuous_on_def continuous_within ..
  1809 
  1810 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1811   "isCont f a \<equiv> continuous (at a) f"
  1812 
  1813 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  1814   by (rule continuous_at)
  1815 
  1816 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1817   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1818 
  1819 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1820   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1821 
  1822 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1823   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1824 
  1825 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1826   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  1827 
  1828 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  1829   by simp
  1830 
  1831 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  1832   using continuous_ident by (rule isContI_continuous)
  1833 
  1834 lemmas isCont_const = continuous_const
  1835 
  1836 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1837   unfolding isCont_def by (rule tendsto_compose)
  1838 
  1839 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1840   unfolding o_def by (rule isCont_o2)
  1841 
  1842 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1843   unfolding isCont_def by (rule tendsto_compose)
  1844 
  1845 lemma continuous_within_compose3:
  1846   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1847   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  1848 
  1849 subsubsection{* Open-cover compactness *}
  1850 
  1851 context topological_space
  1852 begin
  1853 
  1854 definition compact :: "'a set \<Rightarrow> bool" where
  1855   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  1856     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1857 
  1858 lemma compactI:
  1859   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  1860   shows "compact s"
  1861   unfolding compact_eq_heine_borel using assms by metis
  1862 
  1863 lemma compact_empty[simp]: "compact {}"
  1864   by (auto intro!: compactI)
  1865 
  1866 lemma compactE:
  1867   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1868   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1869   using assms unfolding compact_eq_heine_borel by metis
  1870 
  1871 lemma compactE_image:
  1872   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1873   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1874   using assms unfolding ball_simps[symmetric] SUP_def
  1875   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1876 
  1877 lemma compact_inter_closed [intro]:
  1878   assumes "compact s" and "closed t"
  1879   shows "compact (s \<inter> t)"
  1880 proof (rule compactI)
  1881   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1882   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1883   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1884   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1885     using `compact s` unfolding compact_eq_heine_borel by auto
  1886   then guess D ..
  1887   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1888     by (intro exI[of _ "D - {-t}"]) auto
  1889 qed
  1890 
  1891 end
  1892 
  1893 lemma (in t2_space) compact_imp_closed:
  1894   assumes "compact s" shows "closed s"
  1895 unfolding closed_def
  1896 proof (rule openI)
  1897   fix y assume "y \<in> - s"
  1898   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  1899   note `compact s`
  1900   moreover have "\<forall>u\<in>?C. open u" by simp
  1901   moreover have "s \<subseteq> \<Union>?C"
  1902   proof
  1903     fix x assume "x \<in> s"
  1904     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  1905     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  1906       by (rule hausdorff)
  1907     with `x \<in> s` show "x \<in> \<Union>?C"
  1908       unfolding eventually_nhds by auto
  1909   qed
  1910   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  1911     by (rule compactE)
  1912   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  1913   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  1914     by (simp add: eventually_Ball_finite)
  1915   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  1916     by (auto elim!: eventually_mono [rotated])
  1917   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  1918     by (simp add: eventually_nhds subset_eq)
  1919 qed
  1920 
  1921 lemma compact_continuous_image:
  1922   assumes f: "continuous_on s f" and s: "compact s"
  1923   shows "compact (f ` s)"
  1924 proof (rule compactI)
  1925   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  1926   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  1927     unfolding continuous_on_open_invariant by blast
  1928   then guess A unfolding bchoice_iff .. note A = this
  1929   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  1930     by (fastforce simp add: subset_eq set_eq_iff)+
  1931   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  1932   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  1933     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  1934 qed
  1935 
  1936 lemma continuous_on_inv:
  1937   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1938   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  1939   shows "continuous_on (f ` s) g"
  1940 unfolding continuous_on_topological
  1941 proof (clarsimp simp add: assms(3))
  1942   fix x :: 'a and B :: "'a set"
  1943   assume "x \<in> s" and "open B" and "x \<in> B"
  1944   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  1945     using assms(3) by (auto, metis)
  1946   have "continuous_on (s - B) f"
  1947     using `continuous_on s f` Diff_subset
  1948     by (rule continuous_on_subset)
  1949   moreover have "compact (s - B)"
  1950     using `open B` and `compact s`
  1951     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  1952   ultimately have "compact (f ` (s - B))"
  1953     by (rule compact_continuous_image)
  1954   hence "closed (f ` (s - B))"
  1955     by (rule compact_imp_closed)
  1956   hence "open (- f ` (s - B))"
  1957     by (rule open_Compl)
  1958   moreover have "f x \<in> - f ` (s - B)"
  1959     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  1960   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  1961     by (simp add: 1)
  1962   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  1963     by fast
  1964 qed
  1965 
  1966 lemma continuous_on_inv_into:
  1967   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1968   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  1969   shows "continuous_on (f ` s) (the_inv_into s f)"
  1970   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  1971 
  1972 lemma (in linorder_topology) compact_attains_sup:
  1973   assumes "compact S" "S \<noteq> {}"
  1974   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  1975 proof (rule classical)
  1976   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  1977   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  1978     by (metis not_le)
  1979   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  1980     by auto
  1981   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  1982     by (erule compactE_image)
  1983   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  1984     by (auto intro!: Max_in)
  1985   with C have "S \<subseteq> {..< Max (t`C)}"
  1986     by (auto intro: less_le_trans simp: subset_eq)
  1987   with t Max `C \<subseteq> S` show ?thesis
  1988     by fastforce
  1989 qed
  1990 
  1991 lemma (in linorder_topology) compact_attains_inf:
  1992   assumes "compact S" "S \<noteq> {}"
  1993   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  1994 proof (rule classical)
  1995   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  1996   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  1997     by (metis not_le)
  1998   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  1999     by auto
  2000   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2001     by (erule compactE_image)
  2002   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2003     by (auto intro!: Min_in)
  2004   with C have "S \<subseteq> {Min (t`C) <..}"
  2005     by (auto intro: le_less_trans simp: subset_eq)
  2006   with t Min `C \<subseteq> S` show ?thesis
  2007     by fastforce
  2008 qed
  2009 
  2010 lemma continuous_attains_sup:
  2011   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2012   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2013   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2014 
  2015 lemma continuous_attains_inf:
  2016   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2017   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2018   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2019 
  2020 
  2021 subsection {* Connectedness *}
  2022 
  2023 context topological_space
  2024 begin
  2025 
  2026 definition "connected S \<longleftrightarrow>
  2027   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2028 
  2029 lemma connectedI:
  2030   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2031   \<Longrightarrow> connected U"
  2032   by (auto simp: connected_def)
  2033 
  2034 lemma connected_empty[simp]: "connected {}"
  2035   by (auto intro!: connectedI)
  2036 
  2037 end
  2038 
  2039 lemma (in linorder_topology) connectedD_interval:
  2040   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2041   shows "z \<in> U"
  2042 proof -
  2043   have eq: "{..<z} \<union> {z<..} = - {z}"
  2044     by auto
  2045   { assume "z \<notin> U" "x < z" "z < y"
  2046     with xy have "\<not> connected U"
  2047       unfolding connected_def simp_thms
  2048       apply (rule_tac exI[of _ "{..< z}"])
  2049       apply (rule_tac exI[of _ "{z <..}"])
  2050       apply (auto simp add: eq)
  2051       done }
  2052   with assms show "z \<in> U"
  2053     by (metis less_le)
  2054 qed
  2055 
  2056 lemma connected_continuous_image:
  2057   assumes *: "continuous_on s f"
  2058   assumes "connected s"
  2059   shows "connected (f ` s)"
  2060 proof (rule connectedI)
  2061   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2062     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2063   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2064     using * `open A` unfolding continuous_on_open_invariant by metis
  2065   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2066     using * `open B` unfolding continuous_on_open_invariant by metis
  2067 
  2068   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2069   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2070     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2071     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2072   next
  2073     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2074     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2075   qed (insert A' B' A B, auto)
  2076   with `connected s` show False
  2077     unfolding connected_def by blast
  2078 qed
  2079 
  2080 
  2081 section {* Connectedness *}
  2082 
  2083 class linear_continuum_topology = linorder_topology + linear_continuum
  2084 begin
  2085 
  2086 lemma Inf_notin_open:
  2087   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2088   shows "Inf A \<notin> A"
  2089 proof
  2090   assume "Inf A \<in> A"
  2091   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2092     using open_left[of A "Inf A" x] assms by auto
  2093   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2094     by (auto simp: subset_eq)
  2095   then show False
  2096     using cInf_lower[OF `c \<in> A`, of x] bnd by (metis less_imp_le not_le)
  2097 qed
  2098 
  2099 lemma Sup_notin_open:
  2100   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2101   shows "Sup A \<notin> A"
  2102 proof
  2103   assume "Sup A \<in> A"
  2104   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2105     using open_right[of A "Sup A" x] assms by auto
  2106   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2107     by (auto simp: subset_eq)
  2108   then show False
  2109     using cSup_upper[OF `c \<in> A`, of x] bnd by (metis less_imp_le not_le)
  2110 qed
  2111 
  2112 end
  2113 
  2114 instance linear_continuum_topology \<subseteq> perfect_space
  2115 proof
  2116   fix x :: 'a
  2117   from ex_gt_or_lt [of x] guess y ..
  2118   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2119   show "\<not> open {x}"
  2120     by auto
  2121 qed
  2122 
  2123 lemma connectedI_interval:
  2124   fixes U :: "'a :: linear_continuum_topology set"
  2125   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2126   shows "connected U"
  2127 proof (rule connectedI)
  2128   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2129     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2130 
  2131     let ?z = "Inf (B \<inter> {x <..})"
  2132 
  2133     have "x \<le> ?z" "?z \<le> y"
  2134       using `y \<in> B` `x < y` by (auto intro: cInf_lower[where z=x] cInf_greatest)
  2135     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2136       by (rule *)
  2137     moreover have "?z \<notin> B \<inter> {x <..}"
  2138       using `open B` by (intro Inf_notin_open) auto
  2139     ultimately have "?z \<in> A"
  2140       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2141 
  2142     { assume "?z < y"
  2143       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2144         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2145       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2146         using cInf_less_iff[of "B \<inter> {x <..}" x "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2147         by (auto intro: less_imp_le)
  2148       moreover then have "?z \<le> b"
  2149         by (intro cInf_lower[where z=x]) auto
  2150       moreover have "b \<in> U"
  2151         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2152         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2153       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2154         by (intro bexI[of _ b]) auto }
  2155     then have False
  2156       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2157   note not_disjoint = this
  2158 
  2159   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2160   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2161   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2162   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2163   ultimately show False by (cases x y rule: linorder_cases) auto
  2164 qed
  2165 
  2166 lemma connected_iff_interval:
  2167   fixes U :: "'a :: linear_continuum_topology set"
  2168   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2169   by (auto intro: connectedI_interval dest: connectedD_interval)
  2170 
  2171 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2172   unfolding connected_iff_interval by auto
  2173 
  2174 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2175   unfolding connected_iff_interval by auto
  2176 
  2177 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2178   unfolding connected_iff_interval by auto
  2179 
  2180 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2181   unfolding connected_iff_interval by auto
  2182 
  2183 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2184   unfolding connected_iff_interval by auto
  2185 
  2186 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2187   unfolding connected_iff_interval by auto
  2188 
  2189 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2190   unfolding connected_iff_interval by auto
  2191 
  2192 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2193   unfolding connected_iff_interval by auto
  2194 
  2195 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2196   unfolding connected_iff_interval by auto
  2197 
  2198 lemma connected_contains_Ioo: 
  2199   fixes A :: "'a :: linorder_topology set"
  2200   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2201   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2202 
  2203 subsection {* Intermediate Value Theorem *}
  2204 
  2205 lemma IVT':
  2206   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2207   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2208   assumes *: "continuous_on {a .. b} f"
  2209   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2210 proof -
  2211   have "connected {a..b}"
  2212     unfolding connected_iff_interval by auto
  2213   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2214   show ?thesis
  2215     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2216 qed
  2217 
  2218 lemma IVT2':
  2219   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2220   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2221   assumes *: "continuous_on {a .. b} f"
  2222   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2223 proof -
  2224   have "connected {a..b}"
  2225     unfolding connected_iff_interval by auto
  2226   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2227   show ?thesis
  2228     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2229 qed
  2230 
  2231 lemma IVT:
  2232   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2233   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2234   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2235 
  2236 lemma IVT2:
  2237   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2238   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2239   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2240 
  2241 lemma continuous_inj_imp_mono:
  2242   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2243   assumes x: "a < x" "x < b"
  2244   assumes cont: "continuous_on {a..b} f"
  2245   assumes inj: "inj_on f {a..b}"
  2246   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2247 proof -
  2248   note I = inj_on_iff[OF inj]
  2249   { assume "f x < f a" "f x < f b"
  2250     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2251       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2252       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2253     with x I have False by auto }
  2254   moreover
  2255   { assume "f a < f x" "f b < f x"
  2256     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2257       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2258       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2259     with x I have False by auto }
  2260   ultimately show ?thesis
  2261     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2262 qed
  2263 
  2264 end
  2265