src/HOL/Hilbert_Choice.thy
author nipkow
Sun May 14 12:46:32 2017 +0200 (2017-05-14)
changeset 65815 416aa3b00cbe
parent 64591 240a39af9ec4
child 65952 dec96cb3fbe0
permissions -rw-r--r--
added lemma
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson, Tobias Nipkow
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 section \<open>Hilbert's Epsilon-Operator and the Axiom of Choice\<close>
     7 
     8 theory Hilbert_Choice
     9   imports Wellfounded
    10   keywords "specification" :: thy_goal
    11 begin
    12 
    13 subsection \<open>Hilbert's epsilon\<close>
    14 
    15 axiomatization Eps :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    16   where someI: "P x \<Longrightarrow> P (Eps P)"
    17 
    18 syntax (epsilon)
    19   "_Eps" :: "pttrn \<Rightarrow> bool \<Rightarrow> 'a"  ("(3\<some>_./ _)" [0, 10] 10)
    20 syntax (input)
    21   "_Eps" :: "pttrn \<Rightarrow> bool \<Rightarrow> 'a"  ("(3@ _./ _)" [0, 10] 10)
    22 syntax
    23   "_Eps" :: "pttrn \<Rightarrow> bool \<Rightarrow> 'a"  ("(3SOME _./ _)" [0, 10] 10)
    24 translations
    25   "SOME x. P" \<rightleftharpoons> "CONST Eps (\<lambda>x. P)"
    26 
    27 print_translation \<open>
    28   [(@{const_syntax Eps}, fn _ => fn [Abs abs] =>
    29       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
    30       in Syntax.const @{syntax_const "_Eps"} $ x $ t end)]
    31 \<close> \<comment> \<open>to avoid eta-contraction of body\<close>
    32 
    33 definition inv_into :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
    34 "inv_into A f = (\<lambda>x. SOME y. y \<in> A \<and> f y = x)"
    35 
    36 lemma inv_into_def2: "inv_into A f x = (SOME y. y \<in> A \<and> f y = x)"
    37 by(simp add: inv_into_def)
    38 
    39 abbreviation inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
    40 "inv \<equiv> inv_into UNIV"
    41 
    42 
    43 subsection \<open>Hilbert's Epsilon-operator\<close>
    44 
    45 text \<open>
    46   Easier to apply than \<open>someI\<close> if the witness comes from an
    47   existential formula.
    48 \<close>
    49 lemma someI_ex [elim?]: "\<exists>x. P x \<Longrightarrow> P (SOME x. P x)"
    50   apply (erule exE)
    51   apply (erule someI)
    52   done
    53 
    54 text \<open>
    55   Easier to apply than \<open>someI\<close> because the conclusion has only one
    56   occurrence of @{term P}.
    57 \<close>
    58 lemma someI2: "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (SOME x. P x)"
    59   by (blast intro: someI)
    60 
    61 text \<open>
    62   Easier to apply than \<open>someI2\<close> if the witness comes from an
    63   existential formula.
    64 \<close>
    65 lemma someI2_ex: "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (SOME x. P x)"
    66   by (blast intro: someI2)
    67 
    68 lemma someI2_bex: "\<exists>a\<in>A. P a \<Longrightarrow> (\<And>x. x \<in> A \<and> P x \<Longrightarrow> Q x) \<Longrightarrow> Q (SOME x. x \<in> A \<and> P x)"
    69   by (blast intro: someI2)
    70 
    71 lemma some_equality [intro]: "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> x = a) \<Longrightarrow> (SOME x. P x) = a"
    72   by (blast intro: someI2)
    73 
    74 lemma some1_equality: "\<exists>!x. P x \<Longrightarrow> P a \<Longrightarrow> (SOME x. P x) = a"
    75   by blast
    76 
    77 lemma some_eq_ex: "P (SOME x. P x) \<longleftrightarrow> (\<exists>x. P x)"
    78   by (blast intro: someI)
    79 
    80 lemma some_in_eq: "(SOME x. x \<in> A) \<in> A \<longleftrightarrow> A \<noteq> {}"
    81   unfolding ex_in_conv[symmetric] by (rule some_eq_ex)
    82 
    83 lemma some_eq_trivial [simp]: "(SOME y. y = x) = x"
    84   by (rule some_equality) (rule refl)
    85 
    86 lemma some_sym_eq_trivial [simp]: "(SOME y. x = y) = x"
    87   apply (rule some_equality)
    88    apply (rule refl)
    89   apply (erule sym)
    90   done
    91 
    92 
    93 subsection \<open>Axiom of Choice, Proved Using the Description Operator\<close>
    94 
    95 lemma choice: "\<forall>x. \<exists>y. Q x y \<Longrightarrow> \<exists>f. \<forall>x. Q x (f x)"
    96   by (fast elim: someI)
    97 
    98 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y \<Longrightarrow> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    99   by (fast elim: someI)
   100 
   101 lemma choice_iff: "(\<forall>x. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x. Q x (f x))"
   102   by (fast elim: someI)
   103 
   104 lemma choice_iff': "(\<forall>x. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x. P x \<longrightarrow> Q x (f x))"
   105   by (fast elim: someI)
   106 
   107 lemma bchoice_iff: "(\<forall>x\<in>S. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. Q x (f x))"
   108   by (fast elim: someI)
   109 
   110 lemma bchoice_iff': "(\<forall>x\<in>S. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. P x \<longrightarrow> Q x (f x))"
   111   by (fast elim: someI)
   112 
   113 lemma dependent_nat_choice:
   114   assumes 1: "\<exists>x. P 0 x"
   115     and 2: "\<And>x n. P n x \<Longrightarrow> \<exists>y. P (Suc n) y \<and> Q n x y"
   116   shows "\<exists>f. \<forall>n. P n (f n) \<and> Q n (f n) (f (Suc n))"
   117 proof (intro exI allI conjI)
   118   fix n
   119   define f where "f = rec_nat (SOME x. P 0 x) (\<lambda>n x. SOME y. P (Suc n) y \<and> Q n x y)"
   120   then have "P 0 (f 0)" "\<And>n. P n (f n) \<Longrightarrow> P (Suc n) (f (Suc n)) \<and> Q n (f n) (f (Suc n))"
   121     using someI_ex[OF 1] someI_ex[OF 2] by simp_all
   122   then show "P n (f n)" "Q n (f n) (f (Suc n))"
   123     by (induct n) auto
   124 qed
   125 
   126 
   127 subsection \<open>Function Inverse\<close>
   128 
   129 lemma inv_def: "inv f = (\<lambda>y. SOME x. f x = y)"
   130   by (simp add: inv_into_def)
   131 
   132 lemma inv_into_into: "x \<in> f ` A \<Longrightarrow> inv_into A f x \<in> A"
   133   by (simp add: inv_into_def) (fast intro: someI2)
   134 
   135 lemma inv_identity [simp]: "inv (\<lambda>a. a) = (\<lambda>a. a)"
   136   by (simp add: inv_def)
   137 
   138 lemma inv_id [simp]: "inv id = id"
   139   by (simp add: id_def)
   140 
   141 lemma inv_into_f_f [simp]: "inj_on f A \<Longrightarrow> x \<in> A \<Longrightarrow> inv_into A f (f x) = x"
   142   by (simp add: inv_into_def inj_on_def) (blast intro: someI2)
   143 
   144 lemma inv_f_f: "inj f \<Longrightarrow> inv f (f x) = x"
   145   by simp
   146 
   147 lemma f_inv_into_f: "y : f`A \<Longrightarrow> f (inv_into A f y) = y"
   148   by (simp add: inv_into_def) (fast intro: someI2)
   149 
   150 lemma inv_into_f_eq: "inj_on f A \<Longrightarrow> x \<in> A \<Longrightarrow> f x = y \<Longrightarrow> inv_into A f y = x"
   151   by (erule subst) (fast intro: inv_into_f_f)
   152 
   153 lemma inv_f_eq: "inj f \<Longrightarrow> f x = y \<Longrightarrow> inv f y = x"
   154   by (simp add:inv_into_f_eq)
   155 
   156 lemma inj_imp_inv_eq: "inj f \<Longrightarrow> \<forall>x. f (g x) = x \<Longrightarrow> inv f = g"
   157   by (blast intro: inv_into_f_eq)
   158 
   159 text \<open>But is it useful?\<close>
   160 lemma inj_transfer:
   161   assumes inj: "inj f"
   162     and minor: "\<And>y. y \<in> range f \<Longrightarrow> P (inv f y)"
   163   shows "P x"
   164 proof -
   165   have "f x \<in> range f" by auto
   166   then have "P(inv f (f x))" by (rule minor)
   167   then show "P x" by (simp add: inv_into_f_f [OF inj])
   168 qed
   169 
   170 lemma inj_iff: "inj f \<longleftrightarrow> inv f \<circ> f = id"
   171   by (simp add: o_def fun_eq_iff) (blast intro: inj_on_inverseI inv_into_f_f)
   172 
   173 lemma inv_o_cancel[simp]: "inj f \<Longrightarrow> inv f \<circ> f = id"
   174   by (simp add: inj_iff)
   175 
   176 lemma o_inv_o_cancel[simp]: "inj f \<Longrightarrow> g \<circ> inv f \<circ> f = g"
   177   by (simp add: comp_assoc)
   178 
   179 lemma inv_into_image_cancel[simp]: "inj_on f A \<Longrightarrow> S \<subseteq> A \<Longrightarrow> inv_into A f ` f ` S = S"
   180   by (fastforce simp: image_def)
   181 
   182 lemma inj_imp_surj_inv: "inj f \<Longrightarrow> surj (inv f)"
   183   by (blast intro!: surjI inv_into_f_f)
   184 
   185 lemma surj_f_inv_f: "surj f \<Longrightarrow> f (inv f y) = y"
   186   by (simp add: f_inv_into_f)
   187 
   188 lemma inv_into_injective:
   189   assumes eq: "inv_into A f x = inv_into A f y"
   190     and x: "x \<in> f`A"
   191     and y: "y \<in> f`A"
   192   shows "x = y"
   193 proof -
   194   from eq have "f (inv_into A f x) = f (inv_into A f y)"
   195     by simp
   196   with x y show ?thesis
   197     by (simp add: f_inv_into_f)
   198 qed
   199 
   200 lemma inj_on_inv_into: "B \<subseteq> f`A \<Longrightarrow> inj_on (inv_into A f) B"
   201   by (blast intro: inj_onI dest: inv_into_injective injD)
   202 
   203 lemma bij_betw_inv_into: "bij_betw f A B \<Longrightarrow> bij_betw (inv_into A f) B A"
   204   by (auto simp add: bij_betw_def inj_on_inv_into)
   205 
   206 lemma surj_imp_inj_inv: "surj f \<Longrightarrow> inj (inv f)"
   207   by (simp add: inj_on_inv_into)
   208 
   209 lemma surj_iff: "surj f \<longleftrightarrow> f \<circ> inv f = id"
   210   by (auto intro!: surjI simp: surj_f_inv_f fun_eq_iff[where 'b='a])
   211 
   212 lemma surj_iff_all: "surj f \<longleftrightarrow> (\<forall>x. f (inv f x) = x)"
   213   by (simp add: o_def surj_iff fun_eq_iff)
   214 
   215 lemma surj_imp_inv_eq: "surj f \<Longrightarrow> \<forall>x. g (f x) = x \<Longrightarrow> inv f = g"
   216   apply (rule ext)
   217   apply (drule_tac x = "inv f x" in spec)
   218   apply (simp add: surj_f_inv_f)
   219   done
   220 
   221 lemma bij_imp_bij_inv: "bij f \<Longrightarrow> bij (inv f)"
   222   by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   223 
   224 lemma inv_equality: "(\<And>x. g (f x) = x) \<Longrightarrow> (\<And>y. f (g y) = y) \<Longrightarrow> inv f = g"
   225   by (rule ext) (auto simp add: inv_into_def)
   226 
   227 lemma inv_inv_eq: "bij f \<Longrightarrow> inv (inv f) = f"
   228   by (rule inv_equality) (auto simp add: bij_def surj_f_inv_f)
   229 
   230 text \<open>
   231   \<open>bij (inv f)\<close> implies little about \<open>f\<close>. Consider \<open>f :: bool \<Rightarrow> bool\<close> such
   232   that \<open>f True = f False = True\<close>. Then it ia consistent with axiom \<open>someI\<close>
   233   that \<open>inv f\<close> could be any function at all, including the identity function.
   234   If \<open>inv f = id\<close> then \<open>inv f\<close> is a bijection, but \<open>inj f\<close>, \<open>surj f\<close> and \<open>inv
   235   (inv f) = f\<close> all fail.
   236 \<close>
   237 
   238 lemma inv_into_comp:
   239   "inj_on f (g ` A) \<Longrightarrow> inj_on g A \<Longrightarrow> x \<in> f ` g ` A \<Longrightarrow>
   240     inv_into A (f \<circ> g) x = (inv_into A g \<circ> inv_into (g ` A) f) x"
   241   apply (rule inv_into_f_eq)
   242     apply (fast intro: comp_inj_on)
   243    apply (simp add: inv_into_into)
   244   apply (simp add: f_inv_into_f inv_into_into)
   245   done
   246 
   247 lemma o_inv_distrib: "bij f \<Longrightarrow> bij g \<Longrightarrow> inv (f \<circ> g) = inv g \<circ> inv f"
   248   by (rule inv_equality) (auto simp add: bij_def surj_f_inv_f)
   249 
   250 lemma image_f_inv_f: "surj f \<Longrightarrow> f ` (inv f ` A) = A"
   251   by (simp add: surj_f_inv_f image_comp comp_def)
   252 
   253 lemma image_inv_f_f: "inj f \<Longrightarrow> inv f ` (f ` A) = A"
   254   by simp
   255 
   256 lemma bij_image_Collect_eq: "bij f \<Longrightarrow> f ` Collect P = {y. P (inv f y)}"
   257   apply auto
   258    apply (force simp add: bij_is_inj)
   259   apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   260   done
   261 
   262 lemma bij_vimage_eq_inv_image: "bij f \<Longrightarrow> f -` A = inv f ` A"
   263   apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   264   apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
   265   done
   266 
   267 lemma finite_fun_UNIVD1:
   268   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
   269     and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
   270   shows "finite (UNIV :: 'a set)"
   271 proof -
   272   let ?UNIV_b = "UNIV :: 'b set"
   273   from fin have "finite ?UNIV_b"
   274     by (rule finite_fun_UNIVD2)
   275   with card have "card ?UNIV_b \<ge> Suc (Suc 0)"
   276     by (cases "card ?UNIV_b") (auto simp: card_eq_0_iff)
   277   then have "card ?UNIV_b = Suc (Suc (card ?UNIV_b - Suc (Suc 0)))"
   278     by simp
   279   then obtain b1 b2 :: 'b where b1b2: "b1 \<noteq> b2"
   280     by (auto simp: card_Suc_eq)
   281   from fin have fin': "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))"
   282     by (rule finite_imageI)
   283   have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
   284   proof (rule UNIV_eq_I)
   285     fix x :: 'a
   286     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1"
   287       by (simp add: inv_into_def)
   288     then show "x \<in> range (\<lambda>f::'a \<Rightarrow> 'b. inv f b1)"
   289       by blast
   290   qed
   291   with fin' show ?thesis
   292     by simp
   293 qed
   294 
   295 text \<open>
   296   Every infinite set contains a countable subset. More precisely we
   297   show that a set \<open>S\<close> is infinite if and only if there exists an
   298   injective function from the naturals into \<open>S\<close>.
   299 
   300   The ``only if'' direction is harder because it requires the
   301   construction of a sequence of pairwise different elements of an
   302   infinite set \<open>S\<close>. The idea is to construct a sequence of
   303   non-empty and infinite subsets of \<open>S\<close> obtained by successively
   304   removing elements of \<open>S\<close>.
   305 \<close>
   306 
   307 lemma infinite_countable_subset:
   308   assumes inf: "\<not> finite S"
   309   shows "\<exists>f::nat \<Rightarrow> 'a. inj f \<and> range f \<subseteq> S"
   310   \<comment> \<open>Courtesy of Stephan Merz\<close>
   311 proof -
   312   define Sseq where "Sseq = rec_nat S (\<lambda>n T. T - {SOME e. e \<in> T})"
   313   define pick where "pick n = (SOME e. e \<in> Sseq n)" for n
   314   have *: "Sseq n \<subseteq> S" "\<not> finite (Sseq n)" for n
   315     by (induct n) (auto simp: Sseq_def inf)
   316   then have **: "\<And>n. pick n \<in> Sseq n"
   317     unfolding pick_def by (subst (asm) finite.simps) (auto simp add: ex_in_conv intro: someI_ex)
   318   with * have "range pick \<subseteq> S" by auto
   319   moreover have "pick n \<noteq> pick (n + Suc m)" for m n
   320   proof -
   321     have "pick n \<notin> Sseq (n + Suc m)"
   322       by (induct m) (auto simp add: Sseq_def pick_def)
   323     with ** show ?thesis by auto
   324   qed
   325   then have "inj pick"
   326     by (intro linorder_injI) (auto simp add: less_iff_Suc_add)
   327   ultimately show ?thesis by blast
   328 qed
   329 
   330 lemma infinite_iff_countable_subset: "\<not> finite S \<longleftrightarrow> (\<exists>f::nat \<Rightarrow> 'a. inj f \<and> range f \<subseteq> S)"
   331   \<comment> \<open>Courtesy of Stephan Merz\<close>
   332   using finite_imageD finite_subset infinite_UNIV_char_0 infinite_countable_subset by auto
   333 
   334 lemma image_inv_into_cancel:
   335   assumes surj: "f`A = A'"
   336     and sub: "B' \<subseteq> A'"
   337   shows "f `((inv_into A f)`B') = B'"
   338   using assms
   339 proof (auto simp: f_inv_into_f)
   340   let ?f' = "inv_into A f"
   341   fix a'
   342   assume *: "a' \<in> B'"
   343   with sub have "a' \<in> A'" by auto
   344   with surj have "a' = f (?f' a')"
   345     by (auto simp: f_inv_into_f)
   346   with * show "a' \<in> f ` (?f' ` B')" by blast
   347 qed
   348 
   349 lemma inv_into_inv_into_eq:
   350   assumes "bij_betw f A A'"
   351     and a: "a \<in> A"
   352   shows "inv_into A' (inv_into A f) a = f a"
   353 proof -
   354   let ?f' = "inv_into A f"
   355   let ?f'' = "inv_into A' ?f'"
   356   from assms have *: "bij_betw ?f' A' A"
   357     by (auto simp: bij_betw_inv_into)
   358   with a obtain a' where a': "a' \<in> A'" "?f' a' = a"
   359     unfolding bij_betw_def by force
   360   with a * have "?f'' a = a'"
   361     by (auto simp: f_inv_into_f bij_betw_def)
   362   moreover from assms a' have "f a = a'"
   363     by (auto simp: bij_betw_def)
   364   ultimately show "?f'' a = f a" by simp
   365 qed
   366 
   367 lemma inj_on_iff_surj:
   368   assumes "A \<noteq> {}"
   369   shows "(\<exists>f. inj_on f A \<and> f ` A \<subseteq> A') \<longleftrightarrow> (\<exists>g. g ` A' = A)"
   370 proof safe
   371   fix f
   372   assume inj: "inj_on f A" and incl: "f ` A \<subseteq> A'"
   373   let ?phi = "\<lambda>a' a. a \<in> A \<and> f a = a'"
   374   let ?csi = "\<lambda>a. a \<in> A"
   375   let ?g = "\<lambda>a'. if a' \<in> f ` A then (SOME a. ?phi a' a) else (SOME a. ?csi a)"
   376   have "?g ` A' = A"
   377   proof
   378     show "?g ` A' \<subseteq> A"
   379     proof clarify
   380       fix a'
   381       assume *: "a' \<in> A'"
   382       show "?g a' \<in> A"
   383       proof (cases "a' \<in> f ` A")
   384         case True
   385         then obtain a where "?phi a' a" by blast
   386         then have "?phi a' (SOME a. ?phi a' a)"
   387           using someI[of "?phi a'" a] by blast
   388         with True show ?thesis by auto
   389       next
   390         case False
   391         with assms have "?csi (SOME a. ?csi a)"
   392           using someI_ex[of ?csi] by blast
   393         with False show ?thesis by auto
   394       qed
   395     qed
   396   next
   397     show "A \<subseteq> ?g ` A'"
   398     proof -
   399       have "?g (f a) = a \<and> f a \<in> A'" if a: "a \<in> A" for a
   400       proof -
   401         let ?b = "SOME aa. ?phi (f a) aa"
   402         from a have "?phi (f a) a" by auto
   403         then have *: "?phi (f a) ?b"
   404           using someI[of "?phi(f a)" a] by blast
   405         then have "?g (f a) = ?b" using a by auto
   406         moreover from inj * a have "a = ?b"
   407           by (auto simp add: inj_on_def)
   408         ultimately have "?g(f a) = a" by simp
   409         with incl a show ?thesis by auto
   410       qed
   411       then show ?thesis by force
   412     qed
   413   qed
   414   then show "\<exists>g. g ` A' = A" by blast
   415 next
   416   fix g
   417   let ?f = "inv_into A' g"
   418   have "inj_on ?f (g ` A')"
   419     by (auto simp: inj_on_inv_into)
   420   moreover have "?f (g a') \<in> A'" if a': "a' \<in> A'" for a'
   421   proof -
   422     let ?phi = "\<lambda> b'. b' \<in> A' \<and> g b' = g a'"
   423     from a' have "?phi a'" by auto
   424     then have "?phi (SOME b'. ?phi b')"
   425       using someI[of ?phi] by blast
   426     then show ?thesis by (auto simp: inv_into_def)
   427   qed
   428   ultimately show "\<exists>f. inj_on f (g ` A') \<and> f ` g ` A' \<subseteq> A'"
   429     by auto
   430 qed
   431 
   432 lemma Ex_inj_on_UNION_Sigma:
   433   "\<exists>f. (inj_on f (\<Union>i \<in> I. A i) \<and> f ` (\<Union>i \<in> I. A i) \<subseteq> (SIGMA i : I. A i))"
   434 proof
   435   let ?phi = "\<lambda>a i. i \<in> I \<and> a \<in> A i"
   436   let ?sm = "\<lambda>a. SOME i. ?phi a i"
   437   let ?f = "\<lambda>a. (?sm a, a)"
   438   have "inj_on ?f (\<Union>i \<in> I. A i)"
   439     by (auto simp: inj_on_def)
   440   moreover
   441   have "?sm a \<in> I \<and> a \<in> A(?sm a)" if "i \<in> I" and "a \<in> A i" for i a
   442     using that someI[of "?phi a" i] by auto
   443   then have "?f ` (\<Union>i \<in> I. A i) \<subseteq> (SIGMA i : I. A i)"
   444     by auto
   445   ultimately show "inj_on ?f (\<Union>i \<in> I. A i) \<and> ?f ` (\<Union>i \<in> I. A i) \<subseteq> (SIGMA i : I. A i)"
   446     by auto
   447 qed
   448 
   449 lemma inv_unique_comp:
   450   assumes fg: "f \<circ> g = id"
   451     and gf: "g \<circ> f = id"
   452   shows "inv f = g"
   453   using fg gf inv_equality[of g f] by (auto simp add: fun_eq_iff)
   454 
   455 
   456 subsection \<open>Other Consequences of Hilbert's Epsilon\<close>
   457 
   458 text \<open>Hilbert's Epsilon and the @{term split} Operator\<close>
   459 
   460 text \<open>Looping simprule!\<close>
   461 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a, b). P (a, b))"
   462   by simp
   463 
   464 lemma Eps_case_prod: "Eps (case_prod P) = (SOME xy. P (fst xy) (snd xy))"
   465   by (simp add: split_def)
   466 
   467 lemma Eps_case_prod_eq [simp]: "(SOME (x', y'). x = x' \<and> y = y') = (x, y)"
   468   by blast
   469 
   470 
   471 text \<open>A relation is wellfounded iff it has no infinite descending chain.\<close>
   472 lemma wf_iff_no_infinite_down_chain: "wf r \<longleftrightarrow> (\<nexists>f. \<forall>i. (f (Suc i), f i) \<in> r)"
   473   (is "_ \<longleftrightarrow> \<not> ?ex")
   474 proof
   475   assume "wf r"
   476   show "\<not> ?ex"
   477   proof
   478     assume ?ex
   479     then obtain f where f: "(f (Suc i), f i) \<in> r" for i
   480       by blast
   481     from \<open>wf r\<close> have minimal: "x \<in> Q \<Longrightarrow> \<exists>z\<in>Q. \<forall>y. (y, z) \<in> r \<longrightarrow> y \<notin> Q" for x Q
   482       by (auto simp: wf_eq_minimal)
   483     let ?Q = "{w. \<exists>i. w = f i}"
   484     fix n
   485     have "f n \<in> ?Q" by blast
   486     from minimal [OF this] obtain j where "(y, f j) \<in> r \<Longrightarrow> y \<notin> ?Q" for y by blast
   487     with this [OF \<open>(f (Suc j), f j) \<in> r\<close>] have "f (Suc j) \<notin> ?Q" by simp
   488     then show False by blast
   489   qed
   490 next
   491   assume "\<not> ?ex"
   492   then show "wf r"
   493   proof (rule contrapos_np)
   494     assume "\<not> wf r"
   495     then obtain Q x where x: "x \<in> Q" and rec: "z \<in> Q \<Longrightarrow> \<exists>y. (y, z) \<in> r \<and> y \<in> Q" for z
   496       by (auto simp add: wf_eq_minimal)
   497     obtain descend :: "nat \<Rightarrow> 'a"
   498       where descend_0: "descend 0 = x"
   499         and descend_Suc: "descend (Suc n) = (SOME y. y \<in> Q \<and> (y, descend n) \<in> r)" for n
   500       by (rule that [of "rec_nat x (\<lambda>_ rec. (SOME y. y \<in> Q \<and> (y, rec) \<in> r))"]) simp_all
   501     have descend_Q: "descend n \<in> Q" for n
   502     proof (induct n)
   503       case 0
   504       with x show ?case by (simp only: descend_0)
   505     next
   506       case Suc
   507       then show ?case by (simp only: descend_Suc) (rule someI2_ex; use rec in blast)
   508     qed
   509     have "(descend (Suc i), descend i) \<in> r" for i
   510       by (simp only: descend_Suc) (rule someI2_ex; use descend_Q rec in blast)
   511     then show "\<exists>f. \<forall>i. (f (Suc i), f i) \<in> r" by blast
   512   qed
   513 qed
   514 
   515 lemma wf_no_infinite_down_chainE:
   516   assumes "wf r"
   517   obtains k where "(f (Suc k), f k) \<notin> r"
   518   using assms wf_iff_no_infinite_down_chain[of r] by blast
   519 
   520 
   521 text \<open>A dynamically-scoped fact for TFL\<close>
   522 lemma tfl_some: "\<forall>P x. P x \<longrightarrow> P (Eps P)"
   523   by (blast intro: someI)
   524 
   525 
   526 subsection \<open>Least value operator\<close>
   527 
   528 definition LeastM :: "('a \<Rightarrow> 'b::ord) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'a"
   529   where "LeastM m P \<equiv> (SOME x. P x \<and> (\<forall>y. P y \<longrightarrow> m x \<le> m y))"
   530 
   531 syntax
   532   "_LeastM" :: "pttrn \<Rightarrow> ('a \<Rightarrow> 'b::ord) \<Rightarrow> bool \<Rightarrow> 'a"  ("LEAST _ WRT _. _" [0, 4, 10] 10)
   533 translations
   534   "LEAST x WRT m. P" \<rightleftharpoons> "CONST LeastM m (\<lambda>x. P)"
   535 
   536 lemma LeastMI2:
   537   "P x \<Longrightarrow>
   538     (\<And>y. P y \<Longrightarrow> m x \<le> m y) \<Longrightarrow>
   539     (\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> m x \<le> m y \<Longrightarrow> Q x) \<Longrightarrow>
   540     Q (LeastM m P)"
   541   apply (simp add: LeastM_def)
   542   apply (rule someI2_ex)
   543    apply blast
   544   apply blast
   545   done
   546 
   547 lemma LeastM_equality: "P k \<Longrightarrow> (\<And>x. P x \<Longrightarrow> m k \<le> m x) \<Longrightarrow> m (LEAST x WRT m. P x) = m k"
   548   for m :: "_ \<Rightarrow> 'a::order"
   549   apply (rule LeastMI2)
   550     apply assumption
   551    apply blast
   552   apply (blast intro!: order_antisym)
   553   done
   554 
   555 lemma wf_linord_ex_has_least:
   556   "wf r \<Longrightarrow> \<forall>x y. (x, y) \<in> r\<^sup>+ \<longleftrightarrow> (y, x) \<notin> r\<^sup>* \<Longrightarrow> P k \<Longrightarrow> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> (m x, m y) \<in> r\<^sup>*)"
   557   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   558   apply (drule_tac x = "m ` Collect P" in spec)
   559   apply force
   560   done
   561 
   562 lemma ex_has_least_nat: "P k \<Longrightarrow> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> m x \<le> m y)"
   563   for m :: "'a \<Rightarrow> nat"
   564   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   565   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   566    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le)
   567   apply assumption
   568   done
   569 
   570 lemma LeastM_nat_lemma: "P k \<Longrightarrow> P (LeastM m P) \<and> (\<forall>y. P y \<longrightarrow> m (LeastM m P) \<le> m y)"
   571   for m :: "'a \<Rightarrow> nat"
   572   apply (simp add: LeastM_def)
   573   apply (rule someI_ex)
   574   apply (erule ex_has_least_nat)
   575   done
   576 
   577 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1]
   578 
   579 lemma LeastM_nat_le: "P x \<Longrightarrow> m (LeastM m P) \<le> m x"
   580   for m :: "'a \<Rightarrow> nat"
   581   by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp])
   582 
   583 
   584 subsection \<open>Greatest value operator\<close>
   585 
   586 definition GreatestM :: "('a \<Rightarrow> 'b::ord) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'a"
   587   where "GreatestM m P \<equiv> SOME x. P x \<and> (\<forall>y. P y \<longrightarrow> m y \<le> m x)"
   588 
   589 definition Greatest :: "('a::ord \<Rightarrow> bool) \<Rightarrow> 'a"  (binder "GREATEST " 10)
   590   where "Greatest \<equiv> GreatestM (\<lambda>x. x)"
   591 
   592 syntax
   593   "_GreatestM" :: "pttrn \<Rightarrow> ('a \<Rightarrow> 'b::ord) \<Rightarrow> bool \<Rightarrow> 'a"  ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   594 translations
   595   "GREATEST x WRT m. P" \<rightleftharpoons> "CONST GreatestM m (\<lambda>x. P)"
   596 
   597 lemma GreatestMI2:
   598   "P x \<Longrightarrow>
   599     (\<And>y. P y \<Longrightarrow> m y \<le> m x) \<Longrightarrow>
   600     (\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> m y \<le> m x \<Longrightarrow> Q x) \<Longrightarrow>
   601     Q (GreatestM m P)"
   602   apply (simp add: GreatestM_def)
   603   apply (rule someI2_ex)
   604    apply blast
   605   apply blast
   606   done
   607 
   608 lemma GreatestM_equality: "P k \<Longrightarrow> (\<And>x. P x \<Longrightarrow> m x \<le> m k) \<Longrightarrow> m (GREATEST x WRT m. P x) = m k"
   609   for m :: "_ \<Rightarrow> 'a::order"
   610   apply (rule GreatestMI2 [where m = m])
   611     apply assumption
   612    apply blast
   613   apply (blast intro!: order_antisym)
   614   done
   615 
   616 lemma Greatest_equality: "P k \<Longrightarrow> (\<And>x. P x \<Longrightarrow> x \<le> k) \<Longrightarrow> (GREATEST x. P x) = k"
   617   for k :: "'a::order"
   618   apply (simp add: Greatest_def)
   619   apply (erule GreatestM_equality)
   620   apply blast
   621   done
   622 
   623 lemma ex_has_greatest_nat_lemma:
   624   "P k \<Longrightarrow> \<forall>x. P x \<longrightarrow> (\<exists>y. P y \<and> \<not> m y \<le> m x) \<Longrightarrow> \<exists>y. P y \<and> \<not> m y < m k + n"
   625   for m :: "'a \<Rightarrow> nat"
   626   by (induct n) (force simp: le_Suc_eq)+
   627 
   628 lemma ex_has_greatest_nat:
   629   "P k \<Longrightarrow> \<forall>y. P y \<longrightarrow> m y < b \<Longrightarrow> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> m y \<le> m x)"
   630   for m :: "'a \<Rightarrow> nat"
   631   apply (rule ccontr)
   632   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   633     apply (subgoal_tac [3] "m k \<le> b")
   634      apply auto
   635   done
   636 
   637 lemma GreatestM_nat_lemma:
   638   "P k \<Longrightarrow> \<forall>y. P y \<longrightarrow> m y < b \<Longrightarrow> P (GreatestM m P) \<and> (\<forall>y. P y \<longrightarrow> m y \<le> m (GreatestM m P))"
   639   for m :: "'a \<Rightarrow> nat"
   640   apply (simp add: GreatestM_def)
   641   apply (rule someI_ex)
   642   apply (erule ex_has_greatest_nat)
   643   apply assumption
   644   done
   645 
   646 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1]
   647 
   648 lemma GreatestM_nat_le: "P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> m y < b \<Longrightarrow> m x \<le> m (GreatestM m P)"
   649   for m :: "'a \<Rightarrow> nat"
   650   by (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   651 
   652 
   653 text \<open>\<^medskip> Specialization to \<open>GREATEST\<close>.\<close>
   654 
   655 lemma GreatestI: "P k \<Longrightarrow> \<forall>y. P y \<longrightarrow> y < b \<Longrightarrow> P (GREATEST x. P x)"
   656   for k :: nat
   657   unfolding Greatest_def by (rule GreatestM_natI) auto
   658 
   659 lemma Greatest_le: "P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> y < b \<Longrightarrow> x \<le> (GREATEST x. P x)"
   660   for x :: nat
   661   unfolding Greatest_def by (rule GreatestM_nat_le) auto
   662 
   663 lemma GreatestI_ex: "\<exists>k::nat. P k \<Longrightarrow> \<forall>y. P y \<longrightarrow> y < b \<Longrightarrow> P (GREATEST x. P x)"
   664   apply (erule exE)
   665   apply (rule GreatestI)
   666    apply assumption+
   667   done
   668 
   669 
   670 subsection \<open>An aside: bounded accessible part\<close>
   671 
   672 text \<open>Finite monotone eventually stable sequences\<close>
   673 
   674 lemma finite_mono_remains_stable_implies_strict_prefix:
   675   fixes f :: "nat \<Rightarrow> 'a::order"
   676   assumes S: "finite (range f)" "mono f"
   677     and eq: "\<forall>n. f n = f (Suc n) \<longrightarrow> f (Suc n) = f (Suc (Suc n))"
   678   shows "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m < f n) \<and> (\<forall>n\<ge>N. f N = f n)"
   679   using assms
   680 proof -
   681   have "\<exists>n. f n = f (Suc n)"
   682   proof (rule ccontr)
   683     assume "\<not> ?thesis"
   684     then have "\<And>n. f n \<noteq> f (Suc n)" by auto
   685     with \<open>mono f\<close> have "\<And>n. f n < f (Suc n)"
   686       by (auto simp: le_less mono_iff_le_Suc)
   687     with lift_Suc_mono_less_iff[of f] have *: "\<And>n m. n < m \<Longrightarrow> f n < f m"
   688       by auto
   689     have "inj f"
   690     proof (intro injI)
   691       fix x y
   692       assume "f x = f y"
   693       then show "x = y"
   694         by (cases x y rule: linorder_cases) (auto dest: *)
   695     qed
   696     with \<open>finite (range f)\<close> have "finite (UNIV::nat set)"
   697       by (rule finite_imageD)
   698     then show False by simp
   699   qed
   700   then obtain n where n: "f n = f (Suc n)" ..
   701   define N where "N = (LEAST n. f n = f (Suc n))"
   702   have N: "f N = f (Suc N)"
   703     unfolding N_def using n by (rule LeastI)
   704   show ?thesis
   705   proof (intro exI[of _ N] conjI allI impI)
   706     fix n
   707     assume "N \<le> n"
   708     then have "\<And>m. N \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m = f N"
   709     proof (induct rule: dec_induct)
   710       case base
   711       then show ?case by simp
   712     next
   713       case (step n)
   714       then show ?case
   715         using eq [rule_format, of "n - 1"] N
   716         by (cases n) (auto simp add: le_Suc_eq)
   717     qed
   718     from this[of n] \<open>N \<le> n\<close> show "f N = f n" by auto
   719   next
   720     fix n m :: nat
   721     assume "m < n" "n \<le> N"
   722     then show "f m < f n"
   723     proof (induct rule: less_Suc_induct)
   724       case (1 i)
   725       then have "i < N" by simp
   726       then have "f i \<noteq> f (Suc i)"
   727         unfolding N_def by (rule not_less_Least)
   728       with \<open>mono f\<close> show ?case by (simp add: mono_iff_le_Suc less_le)
   729     next
   730       case 2
   731       then show ?case by simp
   732     qed
   733   qed
   734 qed
   735 
   736 lemma finite_mono_strict_prefix_implies_finite_fixpoint:
   737   fixes f :: "nat \<Rightarrow> 'a set"
   738   assumes S: "\<And>i. f i \<subseteq> S" "finite S"
   739     and ex: "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n) \<and> (\<forall>n\<ge>N. f N = f n)"
   740   shows "f (card S) = (\<Union>n. f n)"
   741 proof -
   742   from ex obtain N where inj: "\<And>n m. n \<le> N \<Longrightarrow> m \<le> N \<Longrightarrow> m < n \<Longrightarrow> f m \<subset> f n"
   743     and eq: "\<forall>n\<ge>N. f N = f n"
   744     by atomize auto
   745   have "i \<le> N \<Longrightarrow> i \<le> card (f i)" for i
   746   proof (induct i)
   747     case 0
   748     then show ?case by simp
   749   next
   750     case (Suc i)
   751     with inj [of "Suc i" i] have "(f i) \<subset> (f (Suc i))" by auto
   752     moreover have "finite (f (Suc i))" using S by (rule finite_subset)
   753     ultimately have "card (f i) < card (f (Suc i))" by (intro psubset_card_mono)
   754     with Suc inj show ?case by auto
   755   qed
   756   then have "N \<le> card (f N)" by simp
   757   also have "\<dots> \<le> card S" using S by (intro card_mono)
   758   finally have "f (card S) = f N" using eq by auto
   759   then show ?thesis
   760     using eq inj [of N]
   761     apply auto
   762     apply (case_tac "n < N")
   763      apply (auto simp: not_less)
   764     done
   765 qed
   766 
   767 
   768 subsection \<open>More on injections, bijections, and inverses\<close>
   769 
   770 locale bijection =
   771   fixes f :: "'a \<Rightarrow> 'a"
   772   assumes bij: "bij f"
   773 begin
   774 
   775 lemma bij_inv: "bij (inv f)"
   776   using bij by (rule bij_imp_bij_inv)
   777 
   778 lemma surj [simp]: "surj f"
   779   using bij by (rule bij_is_surj)
   780 
   781 lemma inj: "inj f"
   782   using bij by (rule bij_is_inj)
   783 
   784 lemma surj_inv [simp]: "surj (inv f)"
   785   using inj by (rule inj_imp_surj_inv)
   786 
   787 lemma inj_inv: "inj (inv f)"
   788   using surj by (rule surj_imp_inj_inv)
   789 
   790 lemma eqI: "f a = f b \<Longrightarrow> a = b"
   791   using inj by (rule injD)
   792 
   793 lemma eq_iff [simp]: "f a = f b \<longleftrightarrow> a = b"
   794   by (auto intro: eqI)
   795 
   796 lemma eq_invI: "inv f a = inv f b \<Longrightarrow> a = b"
   797   using inj_inv by (rule injD)
   798 
   799 lemma eq_inv_iff [simp]: "inv f a = inv f b \<longleftrightarrow> a = b"
   800   by (auto intro: eq_invI)
   801 
   802 lemma inv_left [simp]: "inv f (f a) = a"
   803   using inj by (simp add: inv_f_eq)
   804 
   805 lemma inv_comp_left [simp]: "inv f \<circ> f = id"
   806   by (simp add: fun_eq_iff)
   807 
   808 lemma inv_right [simp]: "f (inv f a) = a"
   809   using surj by (simp add: surj_f_inv_f)
   810 
   811 lemma inv_comp_right [simp]: "f \<circ> inv f = id"
   812   by (simp add: fun_eq_iff)
   813 
   814 lemma inv_left_eq_iff [simp]: "inv f a = b \<longleftrightarrow> f b = a"
   815   by auto
   816 
   817 lemma inv_right_eq_iff [simp]: "b = inv f a \<longleftrightarrow> f b = a"
   818   by auto
   819 
   820 end
   821 
   822 lemma infinite_imp_bij_betw:
   823   assumes infinite: "\<not> finite A"
   824   shows "\<exists>h. bij_betw h A (A - {a})"
   825 proof (cases "a \<in> A")
   826   case False
   827   then have "A - {a} = A" by blast
   828   then show ?thesis
   829     using bij_betw_id[of A] by auto
   830 next
   831   case True
   832   with infinite have "\<not> finite (A - {a})" by auto
   833   with infinite_iff_countable_subset[of "A - {a}"]
   834   obtain f :: "nat \<Rightarrow> 'a" where 1: "inj f" and 2: "f ` UNIV \<subseteq> A - {a}" by blast
   835   define g where "g n = (if n = 0 then a else f (Suc n))" for n
   836   define A' where "A' = g ` UNIV"
   837   have *: "\<forall>y. f y \<noteq> a" using 2 by blast
   838   have 3: "inj_on g UNIV \<and> g ` UNIV \<subseteq> A \<and> a \<in> g ` UNIV"
   839     apply (auto simp add: True g_def [abs_def])
   840      apply (unfold inj_on_def)
   841      apply (intro ballI impI)
   842      apply (case_tac "x = 0")
   843       apply (auto simp add: 2)
   844   proof -
   845     fix y
   846     assume "a = (if y = 0 then a else f (Suc y))"
   847     then show "y = 0" by (cases "y = 0") (use * in auto)
   848   next
   849     fix x y
   850     assume "f (Suc x) = (if y = 0 then a else f (Suc y))"
   851     with 1 * show "x = y" by (cases "y = 0") (auto simp: inj_on_def)
   852   next
   853     fix n
   854     from 2 show "f (Suc n) \<in> A" by blast
   855   qed
   856   then have 4: "bij_betw g UNIV A' \<and> a \<in> A' \<and> A' \<subseteq> A"
   857     using inj_on_imp_bij_betw[of g] by (auto simp: A'_def)
   858   then have 5: "bij_betw (inv g) A' UNIV"
   859     by (auto simp add: bij_betw_inv_into)
   860   from 3 obtain n where n: "g n = a" by auto
   861   have 6: "bij_betw g (UNIV - {n}) (A' - {a})"
   862     by (rule bij_betw_subset) (use 3 4 n in \<open>auto simp: image_set_diff A'_def\<close>)
   863   define v where "v m = (if m < n then m else Suc m)" for m
   864   have 7: "bij_betw v UNIV (UNIV - {n})"
   865   proof (unfold bij_betw_def inj_on_def, intro conjI, clarify)
   866     fix m1 m2
   867     assume "v m1 = v m2"
   868     then show "m1 = m2"
   869       apply (cases "m1 < n")
   870        apply (cases "m2 < n")
   871         apply (auto simp: inj_on_def v_def [abs_def])
   872       apply (cases "m2 < n")
   873        apply auto
   874       done
   875   next
   876     show "v ` UNIV = UNIV - {n}"
   877     proof (auto simp: v_def [abs_def])
   878       fix m
   879       assume "m \<noteq> n"
   880       assume *: "m \<notin> Suc ` {m'. \<not> m' < n}"
   881       have False if "n \<le> m"
   882       proof -
   883         from \<open>m \<noteq> n\<close> that have **: "Suc n \<le> m" by auto
   884         from Suc_le_D [OF this] obtain m' where m': "m = Suc m'" ..
   885         with ** have "n \<le> m'" by auto
   886         with m' * show ?thesis by auto
   887       qed
   888       then show "m < n" by force
   889     qed
   890   qed
   891   define h' where "h' = g \<circ> v \<circ> (inv g)"
   892   with 5 6 7 have 8: "bij_betw h' A' (A' - {a})"
   893     by (auto simp add: bij_betw_trans)
   894   define h where "h b = (if b \<in> A' then h' b else b)" for b
   895   then have "\<forall>b \<in> A'. h b = h' b" by simp
   896   with 8 have "bij_betw h  A' (A' - {a})"
   897     using bij_betw_cong[of A' h] by auto
   898   moreover
   899   have "\<forall>b \<in> A - A'. h b = b" by (auto simp: h_def)
   900   then have "bij_betw h  (A - A') (A - A')"
   901     using bij_betw_cong[of "A - A'" h id] bij_betw_id[of "A - A'"] by auto
   902   moreover
   903   from 4 have "(A' \<inter> (A - A') = {} \<and> A' \<union> (A - A') = A) \<and>
   904     ((A' - {a}) \<inter> (A - A') = {} \<and> (A' - {a}) \<union> (A - A') = A - {a})"
   905     by blast
   906   ultimately have "bij_betw h A (A - {a})"
   907     using bij_betw_combine[of h A' "A' - {a}" "A - A'" "A - A'"] by simp
   908   then show ?thesis by blast
   909 qed
   910 
   911 lemma infinite_imp_bij_betw2:
   912   assumes "\<not> finite A"
   913   shows "\<exists>h. bij_betw h A (A \<union> {a})"
   914 proof (cases "a \<in> A")
   915   case True
   916   then have "A \<union> {a} = A" by blast
   917   then show ?thesis using bij_betw_id[of A] by auto
   918 next
   919   case False
   920   let ?A' = "A \<union> {a}"
   921   from False have "A = ?A' - {a}" by blast
   922   moreover from assms have "\<not> finite ?A'" by auto
   923   ultimately obtain f where "bij_betw f ?A' A"
   924     using infinite_imp_bij_betw[of ?A' a] by auto
   925   then have "bij_betw (inv_into ?A' f) A ?A'" by (rule bij_betw_inv_into)
   926   then show ?thesis by auto
   927 qed
   928 
   929 lemma bij_betw_inv_into_left: "bij_betw f A A' \<Longrightarrow> a \<in> A \<Longrightarrow> inv_into A f (f a) = a"
   930   unfolding bij_betw_def by clarify (rule inv_into_f_f)
   931 
   932 lemma bij_betw_inv_into_right: "bij_betw f A A' \<Longrightarrow> a' \<in> A' \<Longrightarrow> f (inv_into A f a') = a'"
   933   unfolding bij_betw_def using f_inv_into_f by force
   934 
   935 lemma bij_betw_inv_into_subset:
   936   "bij_betw f A A' \<Longrightarrow> B \<subseteq> A \<Longrightarrow> f ` B = B' \<Longrightarrow> bij_betw (inv_into A f) B' B"
   937   by (auto simp: bij_betw_def intro: inj_on_inv_into)
   938 
   939 
   940 subsection \<open>Specification package -- Hilbertized version\<close>
   941 
   942 lemma exE_some: "Ex P \<Longrightarrow> c \<equiv> Eps P \<Longrightarrow> P c"
   943   by (simp only: someI_ex)
   944 
   945 ML_file "Tools/choice_specification.ML"
   946 
   947 end