src/Pure/Syntax/syn_trans.ML
author wenzelm
Sun Dec 10 15:30:53 2006 +0100 (2006-12-10)
changeset 21750 41986849fee0
parent 21535 07f8cd0d7962
child 21773 0038f5fc2065
permissions -rw-r--r--
abs/binder_tr': support printing of idtdummy;
     1 (*  Title:      Pure/Syntax/syn_trans.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     4 
     5 Syntax translation functions.
     6 *)
     7 
     8 signature SYN_TRANS0 =
     9 sig
    10   val eta_contract: bool ref
    11   val atomic_abs_tr': string * typ * term -> term * term
    12   val mk_binder_tr: string * string -> string * (term list -> term)
    13   val mk_binder_tr': string * string -> string * (term list -> term)
    14   val dependent_tr': string * string -> term list -> term
    15   val antiquote_tr: string -> term -> term
    16   val quote_tr: string -> term -> term
    17   val quote_antiquote_tr: string -> string -> string -> string * (term list -> term)
    18   val antiquote_tr': string -> term -> term
    19   val quote_tr': string -> term -> term
    20   val quote_antiquote_tr': string -> string -> string -> string * (term list -> term)
    21   val mark_bound: string -> term
    22   val mark_boundT: string * typ -> term
    23   val bound_vars: (string * typ) list -> term -> term
    24   val variant_abs: string * typ * term -> string * term
    25   val variant_abs': string * typ * term -> string * term
    26 end;
    27 
    28 signature SYN_TRANS1 =
    29 sig
    30   include SYN_TRANS0
    31   val non_typed_tr': (term list -> term) -> bool -> typ -> term list -> term
    32   val non_typed_tr'': ('a -> term list -> term) -> 'a -> bool -> typ -> term list -> term
    33   val constrainAbsC: string
    34   val pure_trfuns:
    35       (string * (Ast.ast list -> Ast.ast)) list *
    36       (string * (term list -> term)) list *
    37       (string * (term list -> term)) list *
    38       (string * (Ast.ast list -> Ast.ast)) list
    39   val pure_trfunsT: (string * (bool -> typ -> term list -> term)) list
    40   val struct_trfuns: string list ->
    41       (string * (Ast.ast list -> Ast.ast)) list *
    42       (string * (term list -> term)) list *
    43       (string * (bool -> typ -> term list -> term)) list *
    44       (string * (Ast.ast list -> Ast.ast)) list
    45 end;
    46 
    47 signature SYN_TRANS =
    48 sig
    49   include SYN_TRANS1
    50   val abs_tr': term -> term
    51   val prop_tr': term -> term
    52   val appl_ast_tr': Ast.ast * Ast.ast list -> Ast.ast
    53   val applC_ast_tr': Ast.ast * Ast.ast list -> Ast.ast
    54   val pts_to_asts: Context.generic ->
    55     (string -> (Context.generic -> Ast.ast list -> Ast.ast) option) ->
    56     Parser.parsetree list -> Ast.ast list
    57   val asts_to_terms: Context.generic ->
    58     (string -> (Context.generic -> term list -> term) option) -> Ast.ast list -> term list
    59 end;
    60 
    61 structure SynTrans: SYN_TRANS =
    62 struct
    63 
    64 
    65 (** parse (ast) translations **)
    66 
    67 (* constify *)
    68 
    69 fun constify_ast_tr [Ast.Variable c] = Ast.Constant c
    70   | constify_ast_tr asts = raise Ast.AST ("constify_ast_tr", asts);
    71 
    72 
    73 (* application *)
    74 
    75 fun appl_ast_tr [f, args] = Ast.Appl (f :: Ast.unfold_ast "_args" args)
    76   | appl_ast_tr asts = raise Ast.AST ("appl_ast_tr", asts);
    77 
    78 fun applC_ast_tr [f, args] = Ast.Appl (f :: Ast.unfold_ast "_cargs" args)
    79   | applC_ast_tr asts = raise Ast.AST ("applC_ast_tr", asts);
    80 
    81 
    82 (* abstraction *)
    83 
    84 fun idtyp_ast_tr (*"_idtyp"*) [x, ty] = Ast.Appl [Ast.Constant "_constrain", x, ty]
    85   | idtyp_ast_tr (*"_idtyp"*) asts = raise Ast.AST ("idtyp_ast_tr", asts);
    86 
    87 fun idtypdummy_ast_tr (*"_idtypdummy"*) [ty] =
    88       Ast.Appl [Ast.Constant "_constrain", Ast.Constant "_idtdummy", ty]
    89   | idtypdummy_ast_tr (*"_idtypdummy"*) asts = raise Ast.AST ("idtyp_ast_tr", asts);
    90 
    91 fun lambda_ast_tr (*"_lambda"*) [pats, body] =
    92       Ast.fold_ast_p "_abs" (Ast.unfold_ast "_pttrns" pats, body)
    93   | lambda_ast_tr (*"_lambda"*) asts = raise Ast.AST ("lambda_ast_tr", asts);
    94 
    95 val constrainAbsC = "_constrainAbs";
    96 
    97 fun abs_tr (*"_abs"*) [Free (x, T), t] = Term.absfree (x, T, t)
    98   | abs_tr (*"_abs"*) [Const ("_idtdummy", T), t] = Term.absdummy (T, t)
    99   | abs_tr (*"_abs"*) [Const ("_constrain", _) $ Free (x, T) $ tT, t] =
   100       Lexicon.const constrainAbsC $ Term.absfree (x, T, t) $ tT
   101   | abs_tr (*"_abs"*) [Const ("_constrain", _) $ Const ("_idtdummy", T) $ tT, t] =
   102       Lexicon.const constrainAbsC $ Term.absdummy (T, t) $ tT
   103   | abs_tr (*"_abs"*) ts = raise TERM ("abs_tr", ts);
   104 
   105 
   106 (* binder *)
   107 
   108 fun mk_binder_tr (syn, name) =
   109   let
   110     fun tr (Free (x, T), t) = Lexicon.const name $ Term.absfree (x, T, t)
   111       | tr (Const ("_idtdummy", T), t) = Lexicon.const name $ Term.absdummy (T, t)
   112       | tr (Const ("_constrain", _) $ Free (x, T) $ tT, t) =
   113           Lexicon.const name $ (Lexicon.const constrainAbsC $ Term.absfree (x, T, t) $ tT)
   114       | tr (Const ("_constrain", _) $ Const ("_idtdummy", T) $ tT, t) =
   115           Lexicon.const name $ (Lexicon.const constrainAbsC $ Term.absdummy (T, t) $ tT)
   116       | tr (Const ("_idts", _) $ idt $ idts, t) = tr (idt, tr (idts, t))
   117       | tr (t1, t2) = raise TERM ("binder_tr", [t1, t2]);
   118 
   119     fun binder_tr [idts, body] = tr (idts, body)
   120       | binder_tr ts = raise TERM ("binder_tr", ts);
   121   in (syn, binder_tr) end;
   122 
   123 
   124 (* meta propositions *)
   125 
   126 fun aprop_tr (*"_aprop"*) [t] = Lexicon.const "_constrain" $ t $ Lexicon.const "prop"
   127   | aprop_tr (*"_aprop"*) ts = raise TERM ("aprop_tr", ts);
   128 
   129 fun ofclass_tr (*"_ofclass"*) [ty, cls] =
   130       cls $ (Lexicon.const "_constrain" $ Lexicon.const "TYPE" $
   131         (Lexicon.const "itself" $ ty))
   132   | ofclass_tr (*"_ofclass"*) ts = raise TERM ("ofclass_tr", ts);
   133 
   134 
   135 (* meta implication *)
   136 
   137 fun bigimpl_ast_tr (*"_bigimpl"*) (asts as [asms, concl]) =
   138       let val prems =
   139         (case Ast.unfold_ast_p "_asms" asms of
   140           (asms', Ast.Appl [Ast.Constant "_asm", asm']) => asms' @ [asm']
   141         | _ => raise Ast.AST ("bigimpl_ast_tr", asts))
   142       in Ast.fold_ast_p "==>" (prems, concl) end
   143   | bigimpl_ast_tr (*"_bigimpl"*) asts = raise Ast.AST ("bigimpl_ast_tr", asts);
   144 
   145 
   146 (* type reflection *)
   147 
   148 fun type_tr (*"_TYPE"*) [ty] =
   149       Lexicon.const "_constrain" $ Lexicon.const "TYPE" $ (Lexicon.const "itself" $ ty)
   150   | type_tr (*"_TYPE"*) ts = raise TERM ("type_tr", ts);
   151 
   152 
   153 (* dddot *)
   154 
   155 fun dddot_tr (*"_DDDOT"*) ts = Term.list_comb (Lexicon.var SynExt.dddot_indexname, ts);
   156 
   157 
   158 (* quote / antiquote *)
   159 
   160 fun antiquote_tr name =
   161   let
   162     fun tr i ((t as Const (c, _)) $ u) =
   163           if c = name then tr i u $ Bound i
   164           else tr i t $ tr i u
   165       | tr i (t $ u) = tr i t $ tr i u
   166       | tr i (Abs (x, T, t)) = Abs (x, T, tr (i + 1) t)
   167       | tr _ a = a;
   168   in tr 0 end;
   169 
   170 fun quote_tr name t = Abs ("s", dummyT, antiquote_tr name (Term.incr_boundvars 1 t));
   171 
   172 fun quote_antiquote_tr quoteN antiquoteN name =
   173   let
   174     fun tr [t] = Lexicon.const name $ quote_tr antiquoteN t
   175       | tr ts = raise TERM ("quote_tr", ts);
   176   in (quoteN, tr) end;
   177 
   178 
   179 (* indexed syntax *)
   180 
   181 fun struct_ast_tr (*"_struct"*) [Ast.Appl [Ast.Constant "_index", ast]] = ast
   182   | struct_ast_tr (*"_struct"*) asts = Ast.mk_appl (Ast.Constant "_struct") asts;
   183 
   184 fun index_ast_tr ast =
   185   Ast.mk_appl (Ast.Constant "_index") [Ast.mk_appl (Ast.Constant "_struct") [ast]];
   186 
   187 fun indexdefault_ast_tr (*"_indexdefault"*) [] =
   188       index_ast_tr (Ast.Constant "_indexdefault")
   189   | indexdefault_ast_tr (*"_indexdefault"*) asts =
   190       raise Ast.AST ("indexdefault_ast_tr", asts);
   191 
   192 fun indexnum_ast_tr (*"_indexnum"*) [ast] =
   193       index_ast_tr (Ast.mk_appl (Ast.Constant "_indexnum") [ast])
   194   | indexnum_ast_tr (*"_indexnum"*) asts = raise Ast.AST ("indexnum_ast_tr", asts);
   195 
   196 fun indexvar_ast_tr (*"_indexvar"*) [] =
   197       Ast.mk_appl (Ast.Constant "_index") [Ast.Variable "some_index"]
   198   | indexvar_ast_tr (*"_indexvar"*) asts = raise Ast.AST ("indexvar_ast_tr", asts);
   199 
   200 fun index_tr (*"_index"*) [t] = t
   201   | index_tr (*"_index"*) ts = raise TERM ("index_tr", ts);
   202 
   203 
   204 (* implicit structures *)
   205 
   206 fun the_struct structs i =
   207   if 1 <= i andalso i <= length structs then List.nth (structs, i - 1)
   208   else raise error ("Illegal reference to implicit structure #" ^ string_of_int i);
   209 
   210 fun struct_tr structs (*"_struct"*) [Const ("_indexdefault", _)] =
   211       Lexicon.free (the_struct structs 1)
   212   | struct_tr structs (*"_struct"*) [t as (Const ("_indexnum", _) $ Const (s, _))] =
   213       Lexicon.free (the_struct structs
   214         (case Lexicon.read_nat s of SOME n => n | NONE => raise TERM ("struct_tr", [t])))
   215   | struct_tr _ (*"_struct"*) ts = raise TERM ("struct_tr", ts);
   216 
   217 
   218 
   219 (** print (ast) translations **)
   220 
   221 (* types *)
   222 
   223 fun non_typed_tr' f _ _ ts = f ts;
   224 fun non_typed_tr'' f x _ _ ts = f x ts;
   225 
   226 
   227 (* application *)
   228 
   229 fun appl_ast_tr' (f, []) = raise Ast.AST ("appl_ast_tr'", [f])
   230   | appl_ast_tr' (f, args) = Ast.Appl [Ast.Constant "_appl", f, Ast.fold_ast "_args" args];
   231 
   232 fun applC_ast_tr' (f, []) = raise Ast.AST ("applC_ast_tr'", [f])
   233   | applC_ast_tr' (f, args) = Ast.Appl [Ast.Constant "_applC", f, Ast.fold_ast "_cargs" args];
   234 
   235 
   236 (* abstraction *)
   237 
   238 fun mark_boundT (x, T) = Const ("_bound", T --> T) $ Free (x, T);
   239 fun mark_bound x = mark_boundT (x, dummyT);
   240 
   241 fun bound_vars vars body =
   242   subst_bounds (map mark_boundT (Term.rename_wrt_term body vars), body);
   243 
   244 fun strip_abss vars_of body_of tm =
   245   let
   246     val vars = vars_of tm;
   247     val body = body_of tm;
   248     val rev_new_vars = rename_wrt_term body vars;
   249     fun subst (x, T) b =
   250       if can Name.dest_internal x andalso not (Term.loose_bvar1 (b, 0))
   251       then (Const ("_idtdummy", T), incr_boundvars ~1 b)
   252       else (mark_boundT (x, T), Term.subst_bound (mark_bound x, b));
   253     val (rev_vars', body') = fold_map subst rev_new_vars body;
   254   in (rev rev_vars', body') end;
   255 
   256 
   257 (*do (partial) eta-contraction before printing*)
   258 
   259 val eta_contract = ref true;
   260 
   261 fun eta_contr tm =
   262   let
   263     fun is_aprop (Const ("_aprop", _)) = true
   264       | is_aprop _ = false;
   265 
   266     fun eta_abs (Abs (a, T, t)) =
   267           (case eta_abs t of
   268             t' as f $ u =>
   269               (case eta_abs u of
   270                 Bound 0 =>
   271                   if Term.loose_bvar1 (f, 0) orelse is_aprop f then Abs (a, T, t')
   272                   else  incr_boundvars ~1 f
   273               | _ => Abs (a, T, t'))
   274           | t' => Abs (a, T, t'))
   275       | eta_abs t = t;
   276   in
   277     if ! eta_contract then eta_abs tm else tm
   278   end;
   279 
   280 
   281 fun abs_tr' tm =
   282   uncurry (fold_rev (fn x => fn t => Lexicon.const "_abs" $ x $ t))
   283     (strip_abss strip_abs_vars strip_abs_body (eta_contr tm));
   284 
   285 fun atomic_abs_tr' (x, T, t) =
   286   let val [xT] = rename_wrt_term t [(x, T)]
   287   in (mark_boundT xT, subst_bound (mark_bound (fst xT), t)) end;
   288 
   289 fun abs_ast_tr' (*"_abs"*) asts =
   290   (case Ast.unfold_ast_p "_abs" (Ast.Appl (Ast.Constant "_abs" :: asts)) of
   291     ([], _) => raise Ast.AST ("abs_ast_tr'", asts)
   292   | (xs, body) => Ast.Appl [Ast.Constant "_lambda", Ast.fold_ast "_pttrns" xs, body]);
   293 
   294 
   295 (* binder *)
   296 
   297 fun mk_binder_tr' (name, syn) =
   298   let
   299     fun mk_idts [] = raise Match    (*abort translation*)
   300       | mk_idts [idt] = idt
   301       | mk_idts (idt :: idts) = Lexicon.const "_idts" $ idt $ mk_idts idts;
   302 
   303     fun tr' t =
   304       let
   305         val (xs, bd) = strip_abss (strip_qnt_vars name) (strip_qnt_body name) t;
   306       in Lexicon.const syn $ mk_idts xs $ bd end;
   307 
   308     fun binder_tr' (t :: ts) = Term.list_comb (tr' (Lexicon.const name $ t), ts)
   309       | binder_tr' [] = raise Match;
   310   in (name, binder_tr') end;
   311 
   312 
   313 (* idtyp constraints *)
   314 
   315 fun idtyp_ast_tr' a [Ast.Appl [Ast.Constant c, x, ty], xs] =
   316       if c = "_constrain" then
   317         Ast.Appl [ Ast.Constant a,  Ast.Appl [Ast.Constant "_idtyp", x, ty], xs]
   318       else raise Match
   319   | idtyp_ast_tr' _ _ = raise Match;
   320 
   321 
   322 (* meta propositions *)
   323 
   324 fun prop_tr' tm =
   325   let
   326     fun aprop t = Lexicon.const "_aprop" $ t;
   327 
   328     fun is_prop Ts t =
   329       fastype_of1 (Ts, t) = propT handle TERM _ => false;
   330 
   331     fun is_term (Const ("ProtoPure.term", _) $ _) = true
   332       | is_term _ = false;
   333 
   334     fun tr' _ (t as Const _) = t
   335       | tr' Ts (t as Const ("_bound", _) $ u) =
   336           if is_prop Ts u then aprop t else t
   337       | tr' _ (t as Free (x, T)) =
   338           if T = propT then aprop (Lexicon.free x) else t
   339       | tr' _ (t as Var (xi, T)) =
   340           if T = propT then aprop (Lexicon.var xi) else t
   341       | tr' Ts (t as Bound _) =
   342           if is_prop Ts t then aprop t else t
   343       | tr' Ts (Abs (x, T, t)) = Abs (x, T, tr' (T :: Ts) t)
   344       | tr' Ts (t as t1 $ (t2 as Const ("TYPE", Type ("itself", [T])))) =
   345           if is_prop Ts t andalso not (is_term t) then Const ("_mk_ofclass", T) $ tr' Ts t1
   346           else tr' Ts t1 $ tr' Ts t2
   347       | tr' Ts (t as t1 $ t2) =
   348           (if is_Const (Term.head_of t) orelse not (is_prop Ts t)
   349             then I else aprop) (tr' Ts t1 $ tr' Ts t2);
   350   in tr' [] tm end;
   351 
   352 fun mk_ofclass_tr' show_sorts (*"_mk_ofclass"*) T [t] =
   353       Lexicon.const "_ofclass" $ TypeExt.term_of_typ show_sorts T $ t
   354   | mk_ofclass_tr' _ (*"_mk_ofclass"*) T ts = raise TYPE ("mk_ofclass_tr'", [T], ts);
   355 
   356 
   357 (* meta implication *)
   358 
   359 fun impl_ast_tr' (*"==>"*) asts =
   360   if TypeExt.no_brackets () then raise Match
   361   else
   362     (case Ast.unfold_ast_p "==>" (Ast.Appl (Ast.Constant "==>" :: asts)) of
   363       (prems as _ :: _ :: _, concl) =>
   364         let
   365           val (asms, asm) = split_last prems;
   366           val asms' = Ast.fold_ast_p "_asms" (asms, Ast.Appl [Ast.Constant "_asm", asm]);
   367         in Ast.Appl [Ast.Constant "_bigimpl", asms', concl] end
   368     | _ => raise Match);
   369 
   370 
   371 (* type reflection *)
   372 
   373 fun type_tr' show_sorts (*"TYPE"*) (Type ("itself", [T])) ts =
   374       Term.list_comb (Lexicon.const "_TYPE" $ TypeExt.term_of_typ show_sorts T, ts)
   375   | type_tr' _ _ _ = raise Match;
   376 
   377 
   378 (* type constraints *)
   379 
   380 fun type_constraint_tr' show_sorts (*"_type_constraint_"*) (Type ("fun", [T, _])) (t :: ts) =
   381       Term.list_comb (Lexicon.const SynExt.constrainC $ t $ TypeExt.term_of_typ show_sorts T, ts)
   382   | type_constraint_tr' _ _ _ = raise Match;
   383 
   384 
   385 (* dependent / nondependent quantifiers *)
   386 
   387 fun var_abs mark (x, T, b) =
   388   let val ([x'], _) = Name.variants [x] (Term.declare_term_names b Name.context)
   389   in (x', subst_bound (mark (x', T), b)) end;
   390 
   391 val variant_abs = var_abs Free;
   392 val variant_abs' = var_abs mark_boundT;
   393 
   394 fun dependent_tr' (q, r) (A :: Abs (x, T, B) :: ts) =
   395       if Term.loose_bvar1 (B, 0) then
   396         let val (x', B') = variant_abs' (x, dummyT, B);
   397         in Term.list_comb (Lexicon.const q $ mark_boundT (x', T) $ A $ B', ts) end
   398       else Term.list_comb (Lexicon.const r $ A $ B, ts)
   399   | dependent_tr' _ _ = raise Match;
   400 
   401 
   402 (* quote / antiquote *)
   403 
   404 fun antiquote_tr' name =
   405   let
   406     fun tr' i (t $ u) =
   407       if u aconv Bound i then Lexicon.const name $ tr' i t
   408       else tr' i t $ tr' i u
   409       | tr' i (Abs (x, T, t)) = Abs (x, T, tr' (i + 1) t)
   410       | tr' i a = if a aconv Bound i then raise Match else a;
   411   in tr' 0 end;
   412 
   413 fun quote_tr' name (Abs (_, _, t)) = Term.incr_boundvars ~1 (antiquote_tr' name t)
   414   | quote_tr' _ _ = raise Match;
   415 
   416 fun quote_antiquote_tr' quoteN antiquoteN name =
   417   let
   418     fun tr' (t :: ts) = Term.list_comb (Lexicon.const quoteN $ quote_tr' antiquoteN t, ts)
   419       | tr' _ = raise Match;
   420   in (name, tr') end;
   421 
   422 
   423 (* indexed syntax *)
   424 
   425 fun index_ast_tr' (*"_index"*) [Ast.Appl [Ast.Constant "_struct", ast]] = ast
   426   | index_ast_tr' _ = raise Match;
   427 
   428 
   429 (* implicit structures *)
   430 
   431 fun the_struct' structs s =
   432   [(case Lexicon.read_nat s of
   433     SOME i => Ast.Variable (the_struct structs i handle ERROR _ => raise Match)
   434   | NONE => raise Match)] |> Ast.mk_appl (Ast.Constant "_free");
   435 
   436 fun struct_ast_tr' structs (*"_struct"*) [Ast.Constant "_indexdefault"] =
   437       the_struct' structs "1"
   438   | struct_ast_tr' structs (*"_struct"*) [Ast.Appl [Ast.Constant "_indexnum", Ast.Constant s]] =
   439       the_struct' structs s
   440   | struct_ast_tr' _ _ = raise Match;
   441 
   442 
   443 
   444 (** Pure translations **)
   445 
   446 val pure_trfuns =
   447  ([("_constify", constify_ast_tr), ("_appl", appl_ast_tr), ("_applC", applC_ast_tr),
   448    ("_lambda", lambda_ast_tr), ("_idtyp", idtyp_ast_tr), ("_idtypdummy", idtypdummy_ast_tr),
   449    ("_bigimpl", bigimpl_ast_tr), ("_indexdefault", indexdefault_ast_tr),
   450    ("_indexnum", indexnum_ast_tr), ("_indexvar", indexvar_ast_tr), ("_struct", struct_ast_tr)],
   451   [("_abs", abs_tr), ("_aprop", aprop_tr), ("_ofclass", ofclass_tr),
   452    ("_TYPE", type_tr), ("_DDDOT", dddot_tr),
   453    ("_index", index_tr)],
   454   ([]: (string * (term list -> term)) list),
   455   [("_abs", abs_ast_tr'), ("_idts", idtyp_ast_tr' "_idts"),
   456    ("_pttrns", idtyp_ast_tr' "_pttrns"), ("==>", impl_ast_tr'),
   457    ("_index", index_ast_tr')]);
   458 
   459 val pure_trfunsT =
   460   [("_mk_ofclass", mk_ofclass_tr'), ("TYPE", type_tr'),
   461    ("_type_constraint_", type_constraint_tr')];
   462 
   463 fun struct_trfuns structs =
   464   ([], [("_struct", struct_tr structs)], [], [("_struct", struct_ast_tr' structs)]);
   465 
   466 
   467 
   468 (** pts_to_asts **)
   469 
   470 fun pts_to_asts context trf pts =
   471   let
   472     fun trans a args =
   473       (case trf a of
   474         NONE => Ast.mk_appl (Ast.Constant a) args
   475       | SOME f => transform_failure (fn exn =>
   476             EXCEPTION (exn, "Error in parse ast translation for " ^ quote a))
   477           (fn () => f context args) ());
   478 
   479     (*translate pt bottom-up*)
   480     fun ast_of (Parser.Node (a, pts)) = trans a (map ast_of pts)
   481       | ast_of (Parser.Tip tok) = Ast.Variable (Lexicon.str_of_token tok);
   482 
   483     val exn_results = map (capture ast_of) pts;
   484     val exns = map_filter get_exn exn_results;
   485     val results = map_filter get_result exn_results
   486   in (case (results, exns) of ([], exn :: _) => raise exn | _ => results) end;
   487 
   488 
   489 
   490 (** asts_to_terms **)
   491 
   492 fun asts_to_terms context trf asts =
   493   let
   494     fun trans a args =
   495       (case trf a of
   496         NONE => Term.list_comb (Lexicon.const a, args)
   497       | SOME f => transform_failure (fn exn =>
   498             EXCEPTION (exn, "Error in parse translation for " ^ quote a))
   499           (fn () => f context args) ());
   500 
   501     fun term_of (Ast.Constant a) = trans a []
   502       | term_of (Ast.Variable x) = Lexicon.read_var x
   503       | term_of (Ast.Appl (Ast.Constant a :: (asts as _ :: _))) =
   504           trans a (map term_of asts)
   505       | term_of (Ast.Appl (ast :: (asts as _ :: _))) =
   506           Term.list_comb (term_of ast, map term_of asts)
   507       | term_of (ast as Ast.Appl _) = raise Ast.AST ("ast_to_term: malformed ast", [ast]);
   508 
   509     val free_fixed = Term.map_aterms
   510       (fn t as Const (c, T) =>
   511           (case try (unprefix Lexicon.fixedN) c of
   512             NONE => t
   513           | SOME x => Free (x, T))
   514         | t => t);
   515 
   516     val exn_results = map (capture (term_of #> free_fixed)) asts;
   517     val exns = map_filter get_exn exn_results;
   518     val results = map_filter get_result exn_results
   519   in (case (results, exns) of ([], exn :: _) => raise exn | _ => results) end;
   520 
   521 end;