src/HOL/Complex.thy
author wenzelm
Fri Mar 07 22:30:58 2014 +0100 (2014-03-07)
changeset 55990 41c6b99c5fb7
parent 55759 fe3d8f585c20
child 56217 dc429a5b13c4
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec Re :: "complex \<Rightarrow> real"
    16   where Re: "Re (Complex x y) = x"
    17 
    18 primrec Im :: "complex \<Rightarrow> real"
    19   where Im: "Im (Complex x y) = y"
    20 
    21 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    22   by (induct z) simp
    23 
    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    25   by (induct x, induct y) simp
    26 
    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    28   by (induct x, induct y) simp
    29 
    30 
    31 subsection {* Addition and Subtraction *}
    32 
    33 instantiation complex :: ab_group_add
    34 begin
    35 
    36 definition complex_zero_def:
    37   "0 = Complex 0 0"
    38 
    39 definition complex_add_def:
    40   "x + y = Complex (Re x + Re y) (Im x + Im y)"
    41 
    42 definition complex_minus_def:
    43   "- x = Complex (- Re x) (- Im x)"
    44 
    45 definition complex_diff_def:
    46   "x - (y\<Colon>complex) = x + - y"
    47 
    48 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    49   by (simp add: complex_zero_def)
    50 
    51 lemma complex_Re_zero [simp]: "Re 0 = 0"
    52   by (simp add: complex_zero_def)
    53 
    54 lemma complex_Im_zero [simp]: "Im 0 = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_add [simp]:
    58   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    59   by (simp add: complex_add_def)
    60 
    61 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    62   by (simp add: complex_add_def)
    63 
    64 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_minus [simp]:
    68   "- (Complex a b) = Complex (- a) (- b)"
    69   by (simp add: complex_minus_def)
    70 
    71 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    72   by (simp add: complex_minus_def)
    73 
    74 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_diff [simp]:
    78   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    79   by (simp add: complex_diff_def)
    80 
    81 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    82   by (simp add: complex_diff_def)
    83 
    84 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    85   by (simp add: complex_diff_def)
    86 
    87 instance
    88   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    89 
    90 end
    91 
    92 
    93 subsection {* Multiplication and Division *}
    94 
    95 instantiation complex :: field_inverse_zero
    96 begin
    97 
    98 definition complex_one_def:
    99   "1 = Complex 1 0"
   100 
   101 definition complex_mult_def:
   102   "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   103 
   104 definition complex_inverse_def:
   105   "inverse x =
   106     Complex (Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)) (- Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2))"
   107 
   108 definition complex_divide_def:
   109   "x / (y\<Colon>complex) = x * inverse y"
   110 
   111 lemma Complex_eq_1 [simp]:
   112   "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
   113   by (simp add: complex_one_def)
   114 
   115 lemma Complex_eq_neg_1 [simp]:
   116   "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
   117   by (simp add: complex_one_def)
   118 
   119 lemma complex_Re_one [simp]: "Re 1 = 1"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Im_one [simp]: "Im 1 = 0"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_mult [simp]:
   126   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   127   by (simp add: complex_mult_def)
   128 
   129 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_inverse [simp]:
   136   "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
   137   by (simp add: complex_inverse_def)
   138 
   139 lemma complex_Re_inverse:
   140   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
   141   by (simp add: complex_inverse_def)
   142 
   143 lemma complex_Im_inverse:
   144   "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
   145   by (simp add: complex_inverse_def)
   146 
   147 instance
   148   by intro_classes (simp_all add: complex_mult_def
   149     distrib_left distrib_right right_diff_distrib left_diff_distrib
   150     complex_inverse_def complex_divide_def
   151     power2_eq_square add_divide_distrib [symmetric]
   152     complex_eq_iff)
   153 
   154 end
   155 
   156 
   157 subsection {* Numerals and Arithmetic *}
   158 
   159 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   160   by (induct n) simp_all
   161 
   162 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   163   by (induct n) simp_all
   164 
   165 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   166   by (cases z rule: int_diff_cases) simp
   167 
   168 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   169   by (cases z rule: int_diff_cases) simp
   170 
   171 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   172   using complex_Re_of_int [of "numeral v"] by simp
   173 
   174 lemma complex_Re_neg_numeral [simp]: "Re (- numeral v) = - numeral v"
   175   using complex_Re_of_int [of "- numeral v"] by simp
   176 
   177 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   178   using complex_Im_of_int [of "numeral v"] by simp
   179 
   180 lemma complex_Im_neg_numeral [simp]: "Im (- numeral v) = 0"
   181   using complex_Im_of_int [of "- numeral v"] by simp
   182 
   183 lemma Complex_eq_numeral [simp]:
   184   "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
   185   by (simp add: complex_eq_iff)
   186 
   187 lemma Complex_eq_neg_numeral [simp]:
   188   "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
   189   by (simp add: complex_eq_iff)
   190 
   191 
   192 subsection {* Scalar Multiplication *}
   193 
   194 instantiation complex :: real_field
   195 begin
   196 
   197 definition complex_scaleR_def:
   198   "scaleR r x = Complex (r * Re x) (r * Im x)"
   199 
   200 lemma complex_scaleR [simp]:
   201   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   202   unfolding complex_scaleR_def by simp
   203 
   204 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   205   unfolding complex_scaleR_def by simp
   206 
   207 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   208   unfolding complex_scaleR_def by simp
   209 
   210 instance
   211 proof
   212   fix a b :: real and x y :: complex
   213   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   214     by (simp add: complex_eq_iff distrib_left)
   215   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   216     by (simp add: complex_eq_iff distrib_right)
   217   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   218     by (simp add: complex_eq_iff mult_assoc)
   219   show "scaleR 1 x = x"
   220     by (simp add: complex_eq_iff)
   221   show "scaleR a x * y = scaleR a (x * y)"
   222     by (simp add: complex_eq_iff algebra_simps)
   223   show "x * scaleR a y = scaleR a (x * y)"
   224     by (simp add: complex_eq_iff algebra_simps)
   225 qed
   226 
   227 end
   228 
   229 
   230 subsection{* Properties of Embedding from Reals *}
   231 
   232 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   233   where "complex_of_real \<equiv> of_real"
   234 
   235 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   236   by (simp add: of_real_def complex_scaleR_def)
   237 
   238 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   239   by (simp add: complex_of_real_def)
   240 
   241 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   242   by (simp add: complex_of_real_def)
   243 
   244 lemma Complex_add_complex_of_real [simp]:
   245   shows "Complex x y + complex_of_real r = Complex (x+r) y"
   246   by (simp add: complex_of_real_def)
   247 
   248 lemma complex_of_real_add_Complex [simp]:
   249   shows "complex_of_real r + Complex x y = Complex (r+x) y"
   250   by (simp add: complex_of_real_def)
   251 
   252 lemma Complex_mult_complex_of_real:
   253   shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   254   by (simp add: complex_of_real_def)
   255 
   256 lemma complex_of_real_mult_Complex:
   257   shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   258   by (simp add: complex_of_real_def)
   259 
   260 lemma complex_eq_cancel_iff2 [simp]:
   261   shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   262   by (simp add: complex_of_real_def)
   263 
   264 lemma complex_split_polar:
   265      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   266   by (simp add: complex_eq_iff polar_Ex)
   267 
   268 
   269 subsection {* Vector Norm *}
   270 
   271 instantiation complex :: real_normed_field
   272 begin
   273 
   274 definition complex_norm_def:
   275   "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   276 
   277 abbreviation cmod :: "complex \<Rightarrow> real"
   278   where "cmod \<equiv> norm"
   279 
   280 definition complex_sgn_def:
   281   "sgn x = x /\<^sub>R cmod x"
   282 
   283 definition dist_complex_def:
   284   "dist x y = cmod (x - y)"
   285 
   286 definition open_complex_def:
   287   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   288 
   289 lemmas cmod_def = complex_norm_def
   290 
   291 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
   292   by (simp add: complex_norm_def)
   293 
   294 instance proof
   295   fix r :: real and x y :: complex and S :: "complex set"
   296   show "(norm x = 0) = (x = 0)"
   297     by (induct x) simp
   298   show "norm (x + y) \<le> norm x + norm y"
   299     by (induct x, induct y)
   300        (simp add: real_sqrt_sum_squares_triangle_ineq)
   301   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   302     by (induct x)
   303        (simp add: power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
   304   show "norm (x * y) = norm x * norm y"
   305     by (induct x, induct y)
   306        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   307   show "sgn x = x /\<^sub>R cmod x"
   308     by (rule complex_sgn_def)
   309   show "dist x y = cmod (x - y)"
   310     by (rule dist_complex_def)
   311   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   312     by (rule open_complex_def)
   313 qed
   314 
   315 end
   316 
   317 lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"
   318   by simp
   319 
   320 lemma cmod_complex_polar:
   321   "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   322   by (simp add: norm_mult)
   323 
   324 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   325   unfolding complex_norm_def
   326   by (rule real_sqrt_sum_squares_ge1)
   327 
   328 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   329   by (rule order_trans [OF _ norm_ge_zero], simp)
   330 
   331 lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"
   332   by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   333 
   334 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   335   by (cases x) simp
   336 
   337 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   338   by (cases x) simp
   339 
   340 text {* Properties of complex signum. *}
   341 
   342 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   343   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)
   344 
   345 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   346   by (simp add: complex_sgn_def divide_inverse)
   347 
   348 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   349   by (simp add: complex_sgn_def divide_inverse)
   350 
   351 
   352 subsection {* Completeness of the Complexes *}
   353 
   354 lemma bounded_linear_Re: "bounded_linear Re"
   355   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   356 
   357 lemma bounded_linear_Im: "bounded_linear Im"
   358   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   359 
   360 lemmas tendsto_Re [tendsto_intros] =
   361   bounded_linear.tendsto [OF bounded_linear_Re]
   362 
   363 lemmas tendsto_Im [tendsto_intros] =
   364   bounded_linear.tendsto [OF bounded_linear_Im]
   365 
   366 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   367 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   368 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   369 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   370 
   371 lemma tendsto_Complex [tendsto_intros]:
   372   assumes "(f ---> a) F" and "(g ---> b) F"
   373   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
   374 proof (rule tendstoI)
   375   fix r :: real assume "0 < r"
   376   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)
   377   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"
   378     using `(f ---> a) F` and `0 < r / sqrt 2` by (rule tendstoD)
   379   moreover
   380   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"
   381     using `(g ---> b) F` and `0 < r / sqrt 2` by (rule tendstoD)
   382   ultimately
   383   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"
   384     by (rule eventually_elim2)
   385        (simp add: dist_norm real_sqrt_sum_squares_less)
   386 qed
   387 
   388 instance complex :: banach
   389 proof
   390   fix X :: "nat \<Rightarrow> complex"
   391   assume X: "Cauchy X"
   392   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   393     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   394   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   395     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   396   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   397     using tendsto_Complex [OF 1 2] by simp
   398   thus "convergent X"
   399     by (rule convergentI)
   400 qed
   401 
   402 
   403 subsection {* The Complex Number $i$ *}
   404 
   405 definition "ii" :: complex  ("\<i>")
   406   where i_def: "ii \<equiv> Complex 0 1"
   407 
   408 lemma complex_Re_i [simp]: "Re ii = 0"
   409   by (simp add: i_def)
   410 
   411 lemma complex_Im_i [simp]: "Im ii = 1"
   412   by (simp add: i_def)
   413 
   414 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   415   by (simp add: i_def)
   416 
   417 lemma norm_ii [simp]: "norm ii = 1"
   418   by (simp add: i_def)
   419 
   420 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   421   by (simp add: complex_eq_iff)
   422 
   423 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   424   by (simp add: complex_eq_iff)
   425 
   426 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
   427   by (simp add: complex_eq_iff)
   428 
   429 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
   430   by (simp add: complex_eq_iff)
   431 
   432 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   433   by (simp add: complex_eq_iff)
   434 
   435 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   436   by (simp add: complex_eq_iff)
   437 
   438 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   439   by (simp add: i_def complex_of_real_def)
   440 
   441 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   442   by (simp add: i_def complex_of_real_def)
   443 
   444 lemma i_squared [simp]: "ii * ii = -1"
   445   by (simp add: i_def)
   446 
   447 lemma power2_i [simp]: "ii\<^sup>2 = -1"
   448   by (simp add: power2_eq_square)
   449 
   450 lemma inverse_i [simp]: "inverse ii = - ii"
   451   by (rule inverse_unique, simp)
   452 
   453 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   454   by (simp add: mult_assoc [symmetric])
   455 
   456 
   457 subsection {* Complex Conjugation *}
   458 
   459 definition cnj :: "complex \<Rightarrow> complex" where
   460   "cnj z = Complex (Re z) (- Im z)"
   461 
   462 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   463   by (simp add: cnj_def)
   464 
   465 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   466   by (simp add: cnj_def)
   467 
   468 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   469   by (simp add: cnj_def)
   470 
   471 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   472   by (simp add: complex_eq_iff)
   473 
   474 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   475   by (simp add: cnj_def)
   476 
   477 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   478   by (simp add: complex_eq_iff)
   479 
   480 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   481   by (simp add: complex_eq_iff)
   482 
   483 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   484   by (simp add: complex_eq_iff)
   485 
   486 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   487   by (simp add: complex_eq_iff)
   488 
   489 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   490   by (simp add: complex_eq_iff)
   491 
   492 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   493   by (simp add: complex_eq_iff)
   494 
   495 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   496   by (simp add: complex_eq_iff)
   497 
   498 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   499   by (simp add: complex_inverse_def)
   500 
   501 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   502   by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   503 
   504 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   505   by (induct n, simp_all add: complex_cnj_mult)
   506 
   507 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   508   by (simp add: complex_eq_iff)
   509 
   510 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   511   by (simp add: complex_eq_iff)
   512 
   513 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   514   by (simp add: complex_eq_iff)
   515 
   516 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   517   by (simp add: complex_eq_iff)
   518 
   519 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   520   by (simp add: complex_eq_iff)
   521 
   522 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   523   by (simp add: complex_norm_def)
   524 
   525 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   526   by (simp add: complex_eq_iff)
   527 
   528 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   529   by (simp add: complex_eq_iff)
   530 
   531 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   532   by (simp add: complex_eq_iff)
   533 
   534 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   535   by (simp add: complex_eq_iff)
   536 
   537 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   538   by (simp add: complex_eq_iff power2_eq_square)
   539 
   540 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   541   by (simp add: norm_mult power2_eq_square)
   542 
   543 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   544   by (simp add: cmod_def power2_eq_square)
   545 
   546 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   547   by simp
   548 
   549 lemma bounded_linear_cnj: "bounded_linear cnj"
   550   using complex_cnj_add complex_cnj_scaleR
   551   by (rule bounded_linear_intro [where K=1], simp)
   552 
   553 lemmas tendsto_cnj [tendsto_intros] =
   554   bounded_linear.tendsto [OF bounded_linear_cnj]
   555 
   556 lemmas isCont_cnj [simp] =
   557   bounded_linear.isCont [OF bounded_linear_cnj]
   558 
   559 
   560 subsection{*Basic Lemmas*}
   561 
   562 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   563   by (metis complex_Im_zero complex_Re_zero complex_eqI sum_power2_eq_zero_iff)
   564 
   565 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   566 by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   567 
   568 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   569 apply (cases z, auto)
   570 by (metis complex_of_real_def of_real_add of_real_power power2_eq_square)
   571 
   572 lemma complex_div_eq_0: 
   573     "(Re(a / b) = 0 \<longleftrightarrow> Re(a * cnj b) = 0) & (Im(a / b) = 0 \<longleftrightarrow> Im(a * cnj b) = 0)"
   574 proof (cases "b=0")
   575   case True then show ?thesis by auto
   576 next
   577   case False
   578   show ?thesis
   579   proof (cases b)
   580     case (Complex x y)
   581     then have "x\<^sup>2 + y\<^sup>2 > 0"
   582       by (metis Complex_eq_0 False sum_power2_gt_zero_iff)
   583     then have "!!u v. u / (x\<^sup>2 + y\<^sup>2) + v / (x\<^sup>2 + y\<^sup>2) = (u + v) / (x\<^sup>2 + y\<^sup>2)"
   584       by (metis add_divide_distrib)
   585     with Complex False show ?thesis
   586       by (auto simp: complex_divide_def)
   587   qed
   588 qed
   589 
   590 lemma re_complex_div_eq_0: "Re(a / b) = 0 \<longleftrightarrow> Re(a * cnj b) = 0"
   591   and im_complex_div_eq_0: "Im(a / b) = 0 \<longleftrightarrow> Im(a * cnj b) = 0"
   592 using complex_div_eq_0 by auto
   593 
   594 
   595 lemma complex_div_gt_0: 
   596     "(Re(a / b) > 0 \<longleftrightarrow> Re(a * cnj b) > 0) & (Im(a / b) > 0 \<longleftrightarrow> Im(a * cnj b) > 0)"
   597 proof (cases "b=0")
   598   case True then show ?thesis by auto
   599 next
   600   case False
   601   show ?thesis
   602   proof (cases b)
   603     case (Complex x y)
   604     then have "x\<^sup>2 + y\<^sup>2 > 0"
   605       by (metis Complex_eq_0 False sum_power2_gt_zero_iff)
   606     moreover have "!!u v. u / (x\<^sup>2 + y\<^sup>2) + v / (x\<^sup>2 + y\<^sup>2) = (u + v) / (x\<^sup>2 + y\<^sup>2)"
   607       by (metis add_divide_distrib)
   608     ultimately show ?thesis using Complex False `0 < x\<^sup>2 + y\<^sup>2`
   609       apply (simp add: complex_divide_def  zero_less_divide_iff less_divide_eq)
   610       apply (metis less_divide_eq mult_zero_left diff_conv_add_uminus minus_divide_left)
   611       done
   612   qed
   613 qed
   614 
   615 lemma re_complex_div_gt_0: "Re(a / b) > 0 \<longleftrightarrow> Re(a * cnj b) > 0"
   616   and im_complex_div_gt_0: "Im(a / b) > 0 \<longleftrightarrow> Im(a * cnj b) > 0"
   617 using complex_div_gt_0 by auto
   618 
   619 lemma re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
   620   by (metis le_less re_complex_div_eq_0 re_complex_div_gt_0)
   621 
   622 lemma im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
   623   by (metis im_complex_div_eq_0 im_complex_div_gt_0 le_less)
   624 
   625 lemma re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
   626   by (metis less_asym neq_iff re_complex_div_eq_0 re_complex_div_gt_0)
   627 
   628 lemma im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
   629   by (metis im_complex_div_eq_0 im_complex_div_gt_0 less_asym neq_iff)
   630 
   631 lemma re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
   632   by (metis not_le re_complex_div_gt_0)
   633 
   634 lemma im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
   635   by (metis im_complex_div_gt_0 not_le)
   636 
   637 lemma Re_setsum: "finite s \<Longrightarrow> Re(setsum f s) = setsum (%x. Re(f x)) s"
   638   by (induct s rule: finite_induct) auto
   639 
   640 lemma Im_setsum: "finite s \<Longrightarrow> Im(setsum f s) = setsum (%x. Im(f x)) s"
   641   by (induct s rule: finite_induct) auto
   642 
   643 lemma Complex_setsum': "finite s \<Longrightarrow> setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
   644   by (induct s rule: finite_induct) auto
   645 
   646 lemma Complex_setsum: "finite s \<Longrightarrow> Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
   647   by (metis Complex_setsum')
   648 
   649 lemma cnj_setsum: "finite s \<Longrightarrow> cnj (setsum f s) = setsum (%x. cnj (f x)) s"
   650   by (induct s rule: finite_induct) (auto simp: complex_cnj_add)
   651 
   652 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   653 by (metis Reals_cases Reals_of_real complex.exhaust complex.inject complex_cnj 
   654           complex_of_real_def equal_neg_zero)
   655 
   656 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
   657   by (metis Reals_of_real complex_of_real_def)
   658 
   659 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"
   660   by (metis Re_complex_of_real Reals_cases norm_of_real)
   661 
   662 
   663 subsection{*Finally! Polar Form for Complex Numbers*}
   664 
   665 subsubsection {* $\cos \theta + i \sin \theta$ *}
   666 
   667 definition cis :: "real \<Rightarrow> complex" where
   668   "cis a = Complex (cos a) (sin a)"
   669 
   670 lemma Re_cis [simp]: "Re (cis a) = cos a"
   671   by (simp add: cis_def)
   672 
   673 lemma Im_cis [simp]: "Im (cis a) = sin a"
   674   by (simp add: cis_def)
   675 
   676 lemma cis_zero [simp]: "cis 0 = 1"
   677   by (simp add: cis_def)
   678 
   679 lemma norm_cis [simp]: "norm (cis a) = 1"
   680   by (simp add: cis_def)
   681 
   682 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   683   by (simp add: sgn_div_norm)
   684 
   685 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   686   by (metis norm_cis norm_zero zero_neq_one)
   687 
   688 lemma cis_mult: "cis a * cis b = cis (a + b)"
   689   by (simp add: cis_def cos_add sin_add)
   690 
   691 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   692   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
   693 
   694 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   695   by (simp add: cis_def)
   696 
   697 lemma cis_divide: "cis a / cis b = cis (a - b)"
   698   by (simp add: complex_divide_def cis_mult)
   699 
   700 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   701   by (auto simp add: DeMoivre)
   702 
   703 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   704   by (auto simp add: DeMoivre)
   705 
   706 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}
   707 
   708 definition rcis :: "[real, real] \<Rightarrow> complex" where
   709   "rcis r a = complex_of_real r * cis a"
   710 
   711 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   712   by (simp add: rcis_def)
   713 
   714 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   715   by (simp add: rcis_def)
   716 
   717 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   718   by (simp add: complex_eq_iff polar_Ex)
   719 
   720 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   721   by (simp add: rcis_def norm_mult)
   722 
   723 lemma cis_rcis_eq: "cis a = rcis 1 a"
   724   by (simp add: rcis_def)
   725 
   726 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   727   by (simp add: rcis_def cis_mult)
   728 
   729 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   730   by (simp add: rcis_def)
   731 
   732 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   733   by (simp add: rcis_def)
   734 
   735 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   736   by (simp add: rcis_def)
   737 
   738 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   739   by (simp add: rcis_def power_mult_distrib DeMoivre)
   740 
   741 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   742   by (simp add: divide_inverse rcis_def)
   743 
   744 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   745   by (simp add: rcis_def cis_divide [symmetric])
   746 
   747 subsubsection {* Complex exponential *}
   748 
   749 abbreviation expi :: "complex \<Rightarrow> complex"
   750   where "expi \<equiv> exp"
   751 
   752 lemma cis_conv_exp: "cis b = exp (Complex 0 b)"
   753 proof (rule complex_eqI)
   754   { fix n have "Complex 0 b ^ n =
   755     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"
   756       apply (induct n)
   757       apply (simp add: cos_coeff_def sin_coeff_def)
   758       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)
   759       done } note * = this
   760   show "Re (cis b) = Re (exp (Complex 0 b))"
   761     unfolding exp_def cis_def cos_def
   762     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],
   763       simp add: * mult_assoc [symmetric])
   764   show "Im (cis b) = Im (exp (Complex 0 b))"
   765     unfolding exp_def cis_def sin_def
   766     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],
   767       simp add: * mult_assoc [symmetric])
   768 qed
   769 
   770 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"
   771   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp
   772 
   773 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   774   unfolding expi_def by simp
   775 
   776 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   777   unfolding expi_def by simp
   778 
   779 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   780 apply (insert rcis_Ex [of z])
   781 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   782 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   783 done
   784 
   785 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   786   by (simp add: expi_def cis_def)
   787 
   788 subsubsection {* Complex argument *}
   789 
   790 definition arg :: "complex \<Rightarrow> real" where
   791   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
   792 
   793 lemma arg_zero: "arg 0 = 0"
   794   by (simp add: arg_def)
   795 
   796 lemma of_nat_less_of_int_iff: (* TODO: move *)
   797   "(of_nat n :: 'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
   798   by (metis of_int_of_nat_eq of_int_less_iff)
   799 
   800 lemma real_of_nat_less_numeral_iff [simp]: (* TODO: move *)
   801   "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"
   802   using of_nat_less_of_int_iff [of n "numeral w", where 'a=real]
   803   by (simp add: real_of_nat_def zless_nat_eq_int_zless [symmetric])
   804 
   805 lemma arg_unique:
   806   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   807   shows "arg z = x"
   808 proof -
   809   from assms have "z \<noteq> 0" by auto
   810   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   811   proof
   812     fix a def d \<equiv> "a - x"
   813     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   814     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   815       unfolding d_def by simp
   816     moreover from a assms have "cos a = cos x" and "sin a = sin x"
   817       by (simp_all add: complex_eq_iff)
   818     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
   819     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
   820     ultimately have "d = 0"
   821       unfolding sin_zero_iff even_mult_two_ex
   822       by (auto simp add: numeral_2_eq_2 less_Suc_eq)
   823     thus "a = x" unfolding d_def by simp
   824   qed (simp add: assms del: Re_sgn Im_sgn)
   825   with `z \<noteq> 0` show "arg z = x"
   826     unfolding arg_def by simp
   827 qed
   828 
   829 lemma arg_correct:
   830   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   831 proof (simp add: arg_def assms, rule someI_ex)
   832   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
   833   with assms have "r \<noteq> 0" by auto
   834   def b \<equiv> "if 0 < r then a else a + pi"
   835   have b: "sgn z = cis b"
   836     unfolding z b_def rcis_def using `r \<noteq> 0`
   837     by (simp add: of_real_def sgn_scaleR sgn_if, simp add: cis_def)
   838   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
   839     by (induct_tac n, simp_all add: distrib_left cis_mult [symmetric],
   840       simp add: cis_def)
   841   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
   842     by (case_tac x rule: int_diff_cases,
   843       simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   844   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
   845   have "sgn z = cis c"
   846     unfolding b c_def
   847     by (simp add: cis_divide [symmetric] cis_2pi_int)
   848   moreover have "- pi < c \<and> c \<le> pi"
   849     using ceiling_correct [of "(b - pi) / (2*pi)"]
   850     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
   851   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
   852 qed
   853 
   854 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   855   by (cases "z = 0", simp_all add: arg_zero arg_correct)
   856 
   857 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   858   by (simp add: arg_correct)
   859 
   860 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   861   by (cases "z = 0", simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   862 
   863 lemma cos_arg_i_mult_zero [simp]:
   864      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   865   using cis_arg [of "Complex 0 y"] by (simp add: complex_eq_iff)
   866 
   867 text {* Legacy theorem names *}
   868 
   869 lemmas expand_complex_eq = complex_eq_iff
   870 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   871 lemmas complex_equality = complex_eqI
   872 
   873 end