src/HOL/Limits.thy
author wenzelm
Fri Mar 07 22:30:58 2014 +0100 (2014-03-07)
changeset 55990 41c6b99c5fb7
parent 55415 05f5fdb8d093
child 56330 5c4d3be7a6b0
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 
     7 *)
     8 
     9 header {* Limits on Real Vector Spaces *}
    10 
    11 theory Limits
    12 imports Real_Vector_Spaces
    13 begin
    14 
    15 subsection {* Filter going to infinity norm *}
    16 
    17 definition at_infinity :: "'a::real_normed_vector filter" where
    18   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    19 
    20 lemma eventually_at_infinity:
    21   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    22 unfolding at_infinity_def
    23 proof (rule eventually_Abs_filter, rule is_filter.intro)
    24   fix P Q :: "'a \<Rightarrow> bool"
    25   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    26   then obtain r s where
    27     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    28   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    29   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    30 qed auto
    31 
    32 lemma at_infinity_eq_at_top_bot:
    33   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    34   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    35 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    36   fix P :: "real \<Rightarrow> bool"
    37   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    38   then obtain r where "\<forall>x. r \<le> norm x \<longrightarrow> P x" ..
    39   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    40   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    41 next
    42   fix P :: "real \<Rightarrow> bool"
    43   assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    44   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    45   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    46     by (intro exI[of _ "max p (-q)"]) (auto simp: abs_real_def)
    47 qed
    48 
    49 lemma at_top_le_at_infinity:
    50   "at_top \<le> (at_infinity :: real filter)"
    51   unfolding at_infinity_eq_at_top_bot by simp
    52 
    53 lemma at_bot_le_at_infinity:
    54   "at_bot \<le> (at_infinity :: real filter)"
    55   unfolding at_infinity_eq_at_top_bot by simp
    56 
    57 subsubsection {* Boundedness *}
    58 
    59 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    60   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    61 
    62 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    63   "Bseq X \<equiv> Bfun X sequentially"
    64 
    65 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    66 
    67 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    68   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    69 
    70 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    71   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    72 
    73 lemma Bfun_def:
    74   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    75   unfolding Bfun_metric_def norm_conv_dist
    76 proof safe
    77   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    78   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    79     by (intro always_eventually) (metis dist_commute dist_triangle)
    80   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    81     by eventually_elim auto
    82   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    83     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    84 qed auto
    85 
    86 lemma BfunI:
    87   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    88 unfolding Bfun_def
    89 proof (intro exI conjI allI)
    90   show "0 < max K 1" by simp
    91 next
    92   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    93     using K by (rule eventually_elim1, simp)
    94 qed
    95 
    96 lemma BfunE:
    97   assumes "Bfun f F"
    98   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    99 using assms unfolding Bfun_def by fast
   100 
   101 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   102   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   103   apply (erule_tac x=1 in allE)
   104   apply simp
   105   apply safe
   106   apply (rule_tac x="X M" in exI)
   107   apply (rule_tac x=1 in exI)
   108   apply (erule_tac x=M in allE)
   109   apply simp
   110   apply (rule_tac x=M in exI)
   111   apply (auto simp: dist_commute)
   112   done
   113 
   114 
   115 subsubsection {* Bounded Sequences *}
   116 
   117 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   118   by (intro BfunI) (auto simp: eventually_sequentially)
   119 
   120 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   121   by (intro BfunI) (auto simp: eventually_sequentially)
   122 
   123 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   124   unfolding Bfun_def eventually_sequentially
   125 proof safe
   126   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   127   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   128     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   129        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   130 qed auto
   131 
   132 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   133 unfolding Bseq_def by auto
   134 
   135 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   136 by (simp add: Bseq_def)
   137 
   138 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   139 by (auto simp add: Bseq_def)
   140 
   141 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   142 proof (elim BseqE, intro bdd_aboveI2)
   143   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   144     by (auto elim!: allE[of _ n])
   145 qed
   146 
   147 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   148 proof (elim BseqE, intro bdd_belowI2)
   149   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   150     by (auto elim!: allE[of _ n])
   151 qed
   152 
   153 lemma lemma_NBseq_def:
   154   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   155 proof safe
   156   fix K :: real
   157   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   158   then have "K \<le> real (Suc n)" by auto
   159   moreover assume "\<forall>m. norm (X m) \<le> K"
   160   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   161     by (blast intro: order_trans)
   162   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   163 qed (force simp add: real_of_nat_Suc)
   164 
   165 text{* alternative definition for Bseq *}
   166 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   167 apply (simp add: Bseq_def)
   168 apply (simp (no_asm) add: lemma_NBseq_def)
   169 done
   170 
   171 lemma lemma_NBseq_def2:
   172      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   173 apply (subst lemma_NBseq_def, auto)
   174 apply (rule_tac x = "Suc N" in exI)
   175 apply (rule_tac [2] x = N in exI)
   176 apply (auto simp add: real_of_nat_Suc)
   177  prefer 2 apply (blast intro: order_less_imp_le)
   178 apply (drule_tac x = n in spec, simp)
   179 done
   180 
   181 (* yet another definition for Bseq *)
   182 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   183 by (simp add: Bseq_def lemma_NBseq_def2)
   184 
   185 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   186 
   187 text{*alternative formulation for boundedness*}
   188 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   189 apply (unfold Bseq_def, safe)
   190 apply (rule_tac [2] x = "k + norm x" in exI)
   191 apply (rule_tac x = K in exI, simp)
   192 apply (rule exI [where x = 0], auto)
   193 apply (erule order_less_le_trans, simp)
   194 apply (drule_tac x=n in spec)
   195 apply (drule order_trans [OF norm_triangle_ineq2])
   196 apply simp
   197 done
   198 
   199 text{*alternative formulation for boundedness*}
   200 lemma Bseq_iff3:
   201   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   202 proof
   203   assume ?P
   204   then obtain K
   205     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   206   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   207   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   208     by (auto intro: order_trans norm_triangle_ineq4)
   209   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   210     by simp
   211   with `0 < K + norm (X 0)` show ?Q by blast
   212 next
   213   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   214 qed
   215 
   216 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   217 apply (simp add: Bseq_def)
   218 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   219 apply (drule_tac x = n in spec, arith)
   220 done
   221 
   222 
   223 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   224 
   225 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   226   by (simp add: Bseq_def)
   227 
   228 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   229   apply (simp add: subset_eq)
   230   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   231   apply (erule_tac x=n in allE)
   232   apply auto
   233   done
   234 
   235 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   236   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   237 
   238 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   239   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   240 
   241 subsection {* Bounded Monotonic Sequences *}
   242 
   243 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   244 
   245 (* TODO: delete *)
   246 (* FIXME: one use in NSA/HSEQ.thy *)
   247 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   248   apply (rule_tac x="X m" in exI)
   249   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   250   unfolding eventually_sequentially
   251   apply blast
   252   done
   253 
   254 subsection {* Convergence to Zero *}
   255 
   256 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   257   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   258 
   259 lemma ZfunI:
   260   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   261   unfolding Zfun_def by simp
   262 
   263 lemma ZfunD:
   264   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   265   unfolding Zfun_def by simp
   266 
   267 lemma Zfun_ssubst:
   268   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   269   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   270 
   271 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   272   unfolding Zfun_def by simp
   273 
   274 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   275   unfolding Zfun_def by simp
   276 
   277 lemma Zfun_imp_Zfun:
   278   assumes f: "Zfun f F"
   279   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   280   shows "Zfun (\<lambda>x. g x) F"
   281 proof (cases)
   282   assume K: "0 < K"
   283   show ?thesis
   284   proof (rule ZfunI)
   285     fix r::real assume "0 < r"
   286     hence "0 < r / K"
   287       using K by (rule divide_pos_pos)
   288     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   289       using ZfunD [OF f] by fast
   290     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   291     proof eventually_elim
   292       case (elim x)
   293       hence "norm (f x) * K < r"
   294         by (simp add: pos_less_divide_eq K)
   295       thus ?case
   296         by (simp add: order_le_less_trans [OF elim(1)])
   297     qed
   298   qed
   299 next
   300   assume "\<not> 0 < K"
   301   hence K: "K \<le> 0" by (simp only: not_less)
   302   show ?thesis
   303   proof (rule ZfunI)
   304     fix r :: real
   305     assume "0 < r"
   306     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   307     proof eventually_elim
   308       case (elim x)
   309       also have "norm (f x) * K \<le> norm (f x) * 0"
   310         using K norm_ge_zero by (rule mult_left_mono)
   311       finally show ?case
   312         using `0 < r` by simp
   313     qed
   314   qed
   315 qed
   316 
   317 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   318   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   319 
   320 lemma Zfun_add:
   321   assumes f: "Zfun f F" and g: "Zfun g F"
   322   shows "Zfun (\<lambda>x. f x + g x) F"
   323 proof (rule ZfunI)
   324   fix r::real assume "0 < r"
   325   hence r: "0 < r / 2" by simp
   326   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   327     using f r by (rule ZfunD)
   328   moreover
   329   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   330     using g r by (rule ZfunD)
   331   ultimately
   332   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   333   proof eventually_elim
   334     case (elim x)
   335     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   336       by (rule norm_triangle_ineq)
   337     also have "\<dots> < r/2 + r/2"
   338       using elim by (rule add_strict_mono)
   339     finally show ?case
   340       by simp
   341   qed
   342 qed
   343 
   344 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   345   unfolding Zfun_def by simp
   346 
   347 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   348   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   349 
   350 lemma (in bounded_linear) Zfun:
   351   assumes g: "Zfun g F"
   352   shows "Zfun (\<lambda>x. f (g x)) F"
   353 proof -
   354   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   355     using bounded by fast
   356   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   357     by simp
   358   with g show ?thesis
   359     by (rule Zfun_imp_Zfun)
   360 qed
   361 
   362 lemma (in bounded_bilinear) Zfun:
   363   assumes f: "Zfun f F"
   364   assumes g: "Zfun g F"
   365   shows "Zfun (\<lambda>x. f x ** g x) F"
   366 proof (rule ZfunI)
   367   fix r::real assume r: "0 < r"
   368   obtain K where K: "0 < K"
   369     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   370     using pos_bounded by fast
   371   from K have K': "0 < inverse K"
   372     by (rule positive_imp_inverse_positive)
   373   have "eventually (\<lambda>x. norm (f x) < r) F"
   374     using f r by (rule ZfunD)
   375   moreover
   376   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   377     using g K' by (rule ZfunD)
   378   ultimately
   379   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   380   proof eventually_elim
   381     case (elim x)
   382     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   383       by (rule norm_le)
   384     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   385       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   386     also from K have "r * inverse K * K = r"
   387       by simp
   388     finally show ?case .
   389   qed
   390 qed
   391 
   392 lemma (in bounded_bilinear) Zfun_left:
   393   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   394   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   395 
   396 lemma (in bounded_bilinear) Zfun_right:
   397   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   398   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   399 
   400 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   401 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   402 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   403 
   404 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   405   by (simp only: tendsto_iff Zfun_def dist_norm)
   406 
   407 subsubsection {* Distance and norms *}
   408 
   409 lemma tendsto_dist [tendsto_intros]:
   410   fixes l m :: "'a :: metric_space"
   411   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   412   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   413 proof (rule tendstoI)
   414   fix e :: real assume "0 < e"
   415   hence e2: "0 < e/2" by simp
   416   from tendstoD [OF f e2] tendstoD [OF g e2]
   417   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   418   proof (eventually_elim)
   419     case (elim x)
   420     then show "dist (dist (f x) (g x)) (dist l m) < e"
   421       unfolding dist_real_def
   422       using dist_triangle2 [of "f x" "g x" "l"]
   423       using dist_triangle2 [of "g x" "l" "m"]
   424       using dist_triangle3 [of "l" "m" "f x"]
   425       using dist_triangle [of "f x" "m" "g x"]
   426       by arith
   427   qed
   428 qed
   429 
   430 lemma continuous_dist[continuous_intros]:
   431   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   432   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   433   unfolding continuous_def by (rule tendsto_dist)
   434 
   435 lemma continuous_on_dist[continuous_on_intros]:
   436   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   437   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   438   unfolding continuous_on_def by (auto intro: tendsto_dist)
   439 
   440 lemma tendsto_norm [tendsto_intros]:
   441   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   442   unfolding norm_conv_dist by (intro tendsto_intros)
   443 
   444 lemma continuous_norm [continuous_intros]:
   445   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   446   unfolding continuous_def by (rule tendsto_norm)
   447 
   448 lemma continuous_on_norm [continuous_on_intros]:
   449   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   450   unfolding continuous_on_def by (auto intro: tendsto_norm)
   451 
   452 lemma tendsto_norm_zero:
   453   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   454   by (drule tendsto_norm, simp)
   455 
   456 lemma tendsto_norm_zero_cancel:
   457   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   458   unfolding tendsto_iff dist_norm by simp
   459 
   460 lemma tendsto_norm_zero_iff:
   461   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   462   unfolding tendsto_iff dist_norm by simp
   463 
   464 lemma tendsto_rabs [tendsto_intros]:
   465   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   466   by (fold real_norm_def, rule tendsto_norm)
   467 
   468 lemma continuous_rabs [continuous_intros]:
   469   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   470   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   471 
   472 lemma continuous_on_rabs [continuous_on_intros]:
   473   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   474   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   475 
   476 lemma tendsto_rabs_zero:
   477   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   478   by (fold real_norm_def, rule tendsto_norm_zero)
   479 
   480 lemma tendsto_rabs_zero_cancel:
   481   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   482   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   483 
   484 lemma tendsto_rabs_zero_iff:
   485   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   486   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   487 
   488 subsubsection {* Addition and subtraction *}
   489 
   490 lemma tendsto_add [tendsto_intros]:
   491   fixes a b :: "'a::real_normed_vector"
   492   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   493   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   494 
   495 lemma continuous_add [continuous_intros]:
   496   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   497   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   498   unfolding continuous_def by (rule tendsto_add)
   499 
   500 lemma continuous_on_add [continuous_on_intros]:
   501   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   502   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   503   unfolding continuous_on_def by (auto intro: tendsto_add)
   504 
   505 lemma tendsto_add_zero:
   506   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   507   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   508   by (drule (1) tendsto_add, simp)
   509 
   510 lemma tendsto_minus [tendsto_intros]:
   511   fixes a :: "'a::real_normed_vector"
   512   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   513   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   514 
   515 lemma continuous_minus [continuous_intros]:
   516   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   517   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   518   unfolding continuous_def by (rule tendsto_minus)
   519 
   520 lemma continuous_on_minus [continuous_on_intros]:
   521   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   522   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   523   unfolding continuous_on_def by (auto intro: tendsto_minus)
   524 
   525 lemma tendsto_minus_cancel:
   526   fixes a :: "'a::real_normed_vector"
   527   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   528   by (drule tendsto_minus, simp)
   529 
   530 lemma tendsto_minus_cancel_left:
   531     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   532   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   533   by auto
   534 
   535 lemma tendsto_diff [tendsto_intros]:
   536   fixes a b :: "'a::real_normed_vector"
   537   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   538   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   539 
   540 lemma continuous_diff [continuous_intros]:
   541   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   542   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   543   unfolding continuous_def by (rule tendsto_diff)
   544 
   545 lemma continuous_on_diff [continuous_on_intros]:
   546   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   547   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   548   unfolding continuous_on_def by (auto intro: tendsto_diff)
   549 
   550 lemma tendsto_setsum [tendsto_intros]:
   551   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   552   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   553   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   554 proof (cases "finite S")
   555   assume "finite S" thus ?thesis using assms
   556     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   557 next
   558   assume "\<not> finite S" thus ?thesis
   559     by (simp add: tendsto_const)
   560 qed
   561 
   562 lemma continuous_setsum [continuous_intros]:
   563   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   564   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   565   unfolding continuous_def by (rule tendsto_setsum)
   566 
   567 lemma continuous_on_setsum [continuous_intros]:
   568   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   569   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   570   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   571 
   572 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   573 
   574 subsubsection {* Linear operators and multiplication *}
   575 
   576 lemma (in bounded_linear) tendsto:
   577   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   578   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   579 
   580 lemma (in bounded_linear) continuous:
   581   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   582   using tendsto[of g _ F] by (auto simp: continuous_def)
   583 
   584 lemma (in bounded_linear) continuous_on:
   585   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   586   using tendsto[of g] by (auto simp: continuous_on_def)
   587 
   588 lemma (in bounded_linear) tendsto_zero:
   589   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   590   by (drule tendsto, simp only: zero)
   591 
   592 lemma (in bounded_bilinear) tendsto:
   593   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   594   by (simp only: tendsto_Zfun_iff prod_diff_prod
   595                  Zfun_add Zfun Zfun_left Zfun_right)
   596 
   597 lemma (in bounded_bilinear) continuous:
   598   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   599   using tendsto[of f _ F g] by (auto simp: continuous_def)
   600 
   601 lemma (in bounded_bilinear) continuous_on:
   602   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   603   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   604 
   605 lemma (in bounded_bilinear) tendsto_zero:
   606   assumes f: "(f ---> 0) F"
   607   assumes g: "(g ---> 0) F"
   608   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   609   using tendsto [OF f g] by (simp add: zero_left)
   610 
   611 lemma (in bounded_bilinear) tendsto_left_zero:
   612   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   613   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   614 
   615 lemma (in bounded_bilinear) tendsto_right_zero:
   616   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   617   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   618 
   619 lemmas tendsto_of_real [tendsto_intros] =
   620   bounded_linear.tendsto [OF bounded_linear_of_real]
   621 
   622 lemmas tendsto_scaleR [tendsto_intros] =
   623   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   624 
   625 lemmas tendsto_mult [tendsto_intros] =
   626   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   627 
   628 lemmas continuous_of_real [continuous_intros] =
   629   bounded_linear.continuous [OF bounded_linear_of_real]
   630 
   631 lemmas continuous_scaleR [continuous_intros] =
   632   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   633 
   634 lemmas continuous_mult [continuous_intros] =
   635   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   636 
   637 lemmas continuous_on_of_real [continuous_on_intros] =
   638   bounded_linear.continuous_on [OF bounded_linear_of_real]
   639 
   640 lemmas continuous_on_scaleR [continuous_on_intros] =
   641   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   642 
   643 lemmas continuous_on_mult [continuous_on_intros] =
   644   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   645 
   646 lemmas tendsto_mult_zero =
   647   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   648 
   649 lemmas tendsto_mult_left_zero =
   650   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   651 
   652 lemmas tendsto_mult_right_zero =
   653   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   654 
   655 lemma tendsto_power [tendsto_intros]:
   656   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   657   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   658   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   659 
   660 lemma continuous_power [continuous_intros]:
   661   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   662   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   663   unfolding continuous_def by (rule tendsto_power)
   664 
   665 lemma continuous_on_power [continuous_on_intros]:
   666   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   667   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   668   unfolding continuous_on_def by (auto intro: tendsto_power)
   669 
   670 lemma tendsto_setprod [tendsto_intros]:
   671   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   672   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   673   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   674 proof (cases "finite S")
   675   assume "finite S" thus ?thesis using assms
   676     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   677 next
   678   assume "\<not> finite S" thus ?thesis
   679     by (simp add: tendsto_const)
   680 qed
   681 
   682 lemma continuous_setprod [continuous_intros]:
   683   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   684   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   685   unfolding continuous_def by (rule tendsto_setprod)
   686 
   687 lemma continuous_on_setprod [continuous_intros]:
   688   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   689   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   690   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   691 
   692 subsubsection {* Inverse and division *}
   693 
   694 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   695   assumes f: "Zfun f F"
   696   assumes g: "Bfun g F"
   697   shows "Zfun (\<lambda>x. f x ** g x) F"
   698 proof -
   699   obtain K where K: "0 \<le> K"
   700     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   701     using nonneg_bounded by fast
   702   obtain B where B: "0 < B"
   703     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   704     using g by (rule BfunE)
   705   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   706   using norm_g proof eventually_elim
   707     case (elim x)
   708     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   709       by (rule norm_le)
   710     also have "\<dots> \<le> norm (f x) * B * K"
   711       by (intro mult_mono' order_refl norm_g norm_ge_zero
   712                 mult_nonneg_nonneg K elim)
   713     also have "\<dots> = norm (f x) * (B * K)"
   714       by (rule mult_assoc)
   715     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   716   qed
   717   with f show ?thesis
   718     by (rule Zfun_imp_Zfun)
   719 qed
   720 
   721 lemma (in bounded_bilinear) flip:
   722   "bounded_bilinear (\<lambda>x y. y ** x)"
   723   apply default
   724   apply (rule add_right)
   725   apply (rule add_left)
   726   apply (rule scaleR_right)
   727   apply (rule scaleR_left)
   728   apply (subst mult_commute)
   729   using bounded by fast
   730 
   731 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   732   assumes f: "Bfun f F"
   733   assumes g: "Zfun g F"
   734   shows "Zfun (\<lambda>x. f x ** g x) F"
   735   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   736 
   737 lemma Bfun_inverse_lemma:
   738   fixes x :: "'a::real_normed_div_algebra"
   739   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   740   apply (subst nonzero_norm_inverse, clarsimp)
   741   apply (erule (1) le_imp_inverse_le)
   742   done
   743 
   744 lemma Bfun_inverse:
   745   fixes a :: "'a::real_normed_div_algebra"
   746   assumes f: "(f ---> a) F"
   747   assumes a: "a \<noteq> 0"
   748   shows "Bfun (\<lambda>x. inverse (f x)) F"
   749 proof -
   750   from a have "0 < norm a" by simp
   751   hence "\<exists>r>0. r < norm a" by (rule dense)
   752   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   753   have "eventually (\<lambda>x. dist (f x) a < r) F"
   754     using tendstoD [OF f r1] by fast
   755   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   756   proof eventually_elim
   757     case (elim x)
   758     hence 1: "norm (f x - a) < r"
   759       by (simp add: dist_norm)
   760     hence 2: "f x \<noteq> 0" using r2 by auto
   761     hence "norm (inverse (f x)) = inverse (norm (f x))"
   762       by (rule nonzero_norm_inverse)
   763     also have "\<dots> \<le> inverse (norm a - r)"
   764     proof (rule le_imp_inverse_le)
   765       show "0 < norm a - r" using r2 by simp
   766     next
   767       have "norm a - norm (f x) \<le> norm (a - f x)"
   768         by (rule norm_triangle_ineq2)
   769       also have "\<dots> = norm (f x - a)"
   770         by (rule norm_minus_commute)
   771       also have "\<dots> < r" using 1 .
   772       finally show "norm a - r \<le> norm (f x)" by simp
   773     qed
   774     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   775   qed
   776   thus ?thesis by (rule BfunI)
   777 qed
   778 
   779 lemma tendsto_inverse [tendsto_intros]:
   780   fixes a :: "'a::real_normed_div_algebra"
   781   assumes f: "(f ---> a) F"
   782   assumes a: "a \<noteq> 0"
   783   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   784 proof -
   785   from a have "0 < norm a" by simp
   786   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   787     by (rule tendstoD)
   788   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   789     unfolding dist_norm by (auto elim!: eventually_elim1)
   790   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   791     - (inverse (f x) * (f x - a) * inverse a)) F"
   792     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   793   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   794     by (intro Zfun_minus Zfun_mult_left
   795       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   796       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   797   ultimately show ?thesis
   798     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   799 qed
   800 
   801 lemma continuous_inverse:
   802   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   803   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   804   shows "continuous F (\<lambda>x. inverse (f x))"
   805   using assms unfolding continuous_def by (rule tendsto_inverse)
   806 
   807 lemma continuous_at_within_inverse[continuous_intros]:
   808   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   809   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   810   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   811   using assms unfolding continuous_within by (rule tendsto_inverse)
   812 
   813 lemma isCont_inverse[continuous_intros, simp]:
   814   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   815   assumes "isCont f a" and "f a \<noteq> 0"
   816   shows "isCont (\<lambda>x. inverse (f x)) a"
   817   using assms unfolding continuous_at by (rule tendsto_inverse)
   818 
   819 lemma continuous_on_inverse[continuous_on_intros]:
   820   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   821   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   822   shows "continuous_on s (\<lambda>x. inverse (f x))"
   823   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   824 
   825 lemma tendsto_divide [tendsto_intros]:
   826   fixes a b :: "'a::real_normed_field"
   827   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   828     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   829   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   830 
   831 lemma continuous_divide:
   832   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   833   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   834   shows "continuous F (\<lambda>x. (f x) / (g x))"
   835   using assms unfolding continuous_def by (rule tendsto_divide)
   836 
   837 lemma continuous_at_within_divide[continuous_intros]:
   838   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   839   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   840   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   841   using assms unfolding continuous_within by (rule tendsto_divide)
   842 
   843 lemma isCont_divide[continuous_intros, simp]:
   844   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   845   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   846   shows "isCont (\<lambda>x. (f x) / g x) a"
   847   using assms unfolding continuous_at by (rule tendsto_divide)
   848 
   849 lemma continuous_on_divide[continuous_on_intros]:
   850   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   851   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   852   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   853   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   854 
   855 lemma tendsto_sgn [tendsto_intros]:
   856   fixes l :: "'a::real_normed_vector"
   857   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   858   unfolding sgn_div_norm by (simp add: tendsto_intros)
   859 
   860 lemma continuous_sgn:
   861   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   862   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   863   shows "continuous F (\<lambda>x. sgn (f x))"
   864   using assms unfolding continuous_def by (rule tendsto_sgn)
   865 
   866 lemma continuous_at_within_sgn[continuous_intros]:
   867   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   868   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   869   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   870   using assms unfolding continuous_within by (rule tendsto_sgn)
   871 
   872 lemma isCont_sgn[continuous_intros]:
   873   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   874   assumes "isCont f a" and "f a \<noteq> 0"
   875   shows "isCont (\<lambda>x. sgn (f x)) a"
   876   using assms unfolding continuous_at by (rule tendsto_sgn)
   877 
   878 lemma continuous_on_sgn[continuous_on_intros]:
   879   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   880   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   881   shows "continuous_on s (\<lambda>x. sgn (f x))"
   882   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   883 
   884 lemma filterlim_at_infinity:
   885   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   886   assumes "0 \<le> c"
   887   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   888   unfolding filterlim_iff eventually_at_infinity
   889 proof safe
   890   fix P :: "'a \<Rightarrow> bool" and b
   891   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   892     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   893   have "max b (c + 1) > c" by auto
   894   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   895     by auto
   896   then show "eventually (\<lambda>x. P (f x)) F"
   897   proof eventually_elim
   898     fix x assume "max b (c + 1) \<le> norm (f x)"
   899     with P show "P (f x)" by auto
   900   qed
   901 qed force
   902 
   903 
   904 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   905 
   906 text {*
   907 
   908 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   909 @{term "at_right x"} and also @{term "at_right 0"}.
   910 
   911 *}
   912 
   913 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   914 
   915 lemma filtermap_homeomorph:
   916   assumes f: "continuous (at a) f"
   917   assumes g: "continuous (at (f a)) g"
   918   assumes bij1: "\<forall>x. f (g x) = x" and bij2: "\<forall>x. g (f x) = x"
   919   shows "filtermap f (nhds a) = nhds (f a)"
   920   unfolding filter_eq_iff eventually_filtermap eventually_nhds
   921 proof safe
   922   fix P S assume S: "open S" "f a \<in> S" and P: "\<forall>x\<in>S. P x"
   923   from continuous_within_topological[THEN iffD1, rule_format, OF f S] P
   924   show "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P (f x))" by auto
   925 next
   926   fix P S assume S: "open S" "a \<in> S" and P: "\<forall>x\<in>S. P (f x)"
   927   with continuous_within_topological[THEN iffD1, rule_format, OF g, of S] bij2
   928   obtain A where "open A" "f a \<in> A" "(\<forall>y\<in>A. g y \<in> S)"
   929     by (metis UNIV_I)
   930   with P bij1 show "\<exists>S. open S \<and> f a \<in> S \<and> (\<forall>x\<in>S. P x)"
   931     by (force intro!: exI[of _ A])
   932 qed
   933 
   934 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   935   by (rule filtermap_homeomorph[where g="\<lambda>x. x + d"]) (auto intro: continuous_intros)
   936 
   937 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   938   by (rule filtermap_homeomorph[where g=uminus]) (auto intro: continuous_minus)
   939 
   940 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   941   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   942 
   943 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   944   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   945 
   946 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   947   using filtermap_at_right_shift[of "-a" 0] by simp
   948 
   949 lemma filterlim_at_right_to_0:
   950   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   951   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   952 
   953 lemma eventually_at_right_to_0:
   954   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   955   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   956 
   957 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   958   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   959 
   960 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   961   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   962 
   963 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   964   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   965 
   966 lemma filterlim_at_left_to_right:
   967   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   968   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   969 
   970 lemma eventually_at_left_to_right:
   971   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   972   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   973 
   974 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   975   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   976   by (metis le_minus_iff minus_minus)
   977 
   978 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   979   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   980 
   981 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   982   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   983 
   984 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   985   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   986 
   987 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   988   unfolding filterlim_at_top eventually_at_bot_dense
   989   by (metis leI minus_less_iff order_less_asym)
   990 
   991 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   992   unfolding filterlim_at_bot eventually_at_top_dense
   993   by (metis leI less_minus_iff order_less_asym)
   994 
   995 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   996   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   997   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   998   by auto
   999 
  1000 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1001   unfolding filterlim_uminus_at_top by simp
  1002 
  1003 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1004   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1005 proof safe
  1006   fix Z :: real assume [arith]: "0 < Z"
  1007   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1008     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1009   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1010     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1011 qed
  1012 
  1013 lemma filterlim_inverse_at_top:
  1014   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1015   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1016      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1017 
  1018 lemma filterlim_inverse_at_bot_neg:
  1019   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1020   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1021 
  1022 lemma filterlim_inverse_at_bot:
  1023   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1024   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1025   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1026 
  1027 lemma tendsto_inverse_0:
  1028   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1029   shows "(inverse ---> (0::'a)) at_infinity"
  1030   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1031 proof safe
  1032   fix r :: real assume "0 < r"
  1033   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1034   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1035     fix x :: 'a
  1036     from `0 < r` have "0 < inverse (r / 2)" by simp
  1037     also assume *: "inverse (r / 2) \<le> norm x"
  1038     finally show "norm (inverse x) < r"
  1039       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1040   qed
  1041 qed
  1042 
  1043 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1044 proof (rule antisym)
  1045   have "(inverse ---> (0::real)) at_top"
  1046     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1047   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1048     by (simp add: le_principal eventually_filtermap eventually_gt_at_top filterlim_def at_within_def)
  1049 next
  1050   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1051     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1052   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1053     by (simp add: filtermap_ident filtermap_filtermap)
  1054 qed
  1055 
  1056 lemma eventually_at_right_to_top:
  1057   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1058   unfolding at_right_to_top eventually_filtermap ..
  1059 
  1060 lemma filterlim_at_right_to_top:
  1061   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1062   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1063 
  1064 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1065   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1066 
  1067 lemma eventually_at_top_to_right:
  1068   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1069   unfolding at_top_to_right eventually_filtermap ..
  1070 
  1071 lemma filterlim_at_top_to_right:
  1072   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1073   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1074 
  1075 lemma filterlim_inverse_at_infinity:
  1076   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1077   shows "filterlim inverse at_infinity (at (0::'a))"
  1078   unfolding filterlim_at_infinity[OF order_refl]
  1079 proof safe
  1080   fix r :: real assume "0 < r"
  1081   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1082     unfolding eventually_at norm_inverse
  1083     by (intro exI[of _ "inverse r"])
  1084        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1085 qed
  1086 
  1087 lemma filterlim_inverse_at_iff:
  1088   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1089   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1090   unfolding filterlim_def filtermap_filtermap[symmetric]
  1091 proof
  1092   assume "filtermap g F \<le> at_infinity"
  1093   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1094     by (rule filtermap_mono)
  1095   also have "\<dots> \<le> at 0"
  1096     using tendsto_inverse_0[where 'a='b]
  1097     by (auto intro!: exI[of _ 1]
  1098              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1099   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1100 next
  1101   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1102   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1103     by (rule filtermap_mono)
  1104   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1105     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1106 qed
  1107 
  1108 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1109  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1110 
  1111 text {*
  1112 
  1113 We only show rules for multiplication and addition when the functions are either against a real
  1114 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1115 
  1116 *}
  1117 
  1118 lemma filterlim_tendsto_pos_mult_at_top: 
  1119   assumes f: "(f ---> c) F" and c: "0 < c"
  1120   assumes g: "LIM x F. g x :> at_top"
  1121   shows "LIM x F. (f x * g x :: real) :> at_top"
  1122   unfolding filterlim_at_top_gt[where c=0]
  1123 proof safe
  1124   fix Z :: real assume "0 < Z"
  1125   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1126     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1127              simp: dist_real_def abs_real_def split: split_if_asm)
  1128   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1129     unfolding filterlim_at_top by auto
  1130   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1131   proof eventually_elim
  1132     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1133     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1134       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1135     with `0 < c` show "Z \<le> f x * g x"
  1136        by simp
  1137   qed
  1138 qed
  1139 
  1140 lemma filterlim_at_top_mult_at_top: 
  1141   assumes f: "LIM x F. f x :> at_top"
  1142   assumes g: "LIM x F. g x :> at_top"
  1143   shows "LIM x F. (f x * g x :: real) :> at_top"
  1144   unfolding filterlim_at_top_gt[where c=0]
  1145 proof safe
  1146   fix Z :: real assume "0 < Z"
  1147   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1148     unfolding filterlim_at_top by auto
  1149   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1150     unfolding filterlim_at_top by auto
  1151   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1152   proof eventually_elim
  1153     fix x assume "1 \<le> f x" "Z \<le> g x"
  1154     with `0 < Z` have "1 * Z \<le> f x * g x"
  1155       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1156     then show "Z \<le> f x * g x"
  1157        by simp
  1158   qed
  1159 qed
  1160 
  1161 lemma filterlim_tendsto_pos_mult_at_bot:
  1162   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1163   shows "LIM x F. f x * g x :> at_bot"
  1164   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1165   unfolding filterlim_uminus_at_bot by simp
  1166 
  1167 lemma filterlim_tendsto_add_at_top: 
  1168   assumes f: "(f ---> c) F"
  1169   assumes g: "LIM x F. g x :> at_top"
  1170   shows "LIM x F. (f x + g x :: real) :> at_top"
  1171   unfolding filterlim_at_top_gt[where c=0]
  1172 proof safe
  1173   fix Z :: real assume "0 < Z"
  1174   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1175     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1176   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1177     unfolding filterlim_at_top by auto
  1178   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1179     by eventually_elim simp
  1180 qed
  1181 
  1182 lemma LIM_at_top_divide:
  1183   fixes f g :: "'a \<Rightarrow> real"
  1184   assumes f: "(f ---> a) F" "0 < a"
  1185   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1186   shows "LIM x F. f x / g x :> at_top"
  1187   unfolding divide_inverse
  1188   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1189 
  1190 lemma filterlim_at_top_add_at_top: 
  1191   assumes f: "LIM x F. f x :> at_top"
  1192   assumes g: "LIM x F. g x :> at_top"
  1193   shows "LIM x F. (f x + g x :: real) :> at_top"
  1194   unfolding filterlim_at_top_gt[where c=0]
  1195 proof safe
  1196   fix Z :: real assume "0 < Z"
  1197   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1198     unfolding filterlim_at_top by auto
  1199   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1200     unfolding filterlim_at_top by auto
  1201   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1202     by eventually_elim simp
  1203 qed
  1204 
  1205 lemma tendsto_divide_0:
  1206   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1207   assumes f: "(f ---> c) F"
  1208   assumes g: "LIM x F. g x :> at_infinity"
  1209   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1210   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1211 
  1212 lemma linear_plus_1_le_power:
  1213   fixes x :: real
  1214   assumes x: "0 \<le> x"
  1215   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1216 proof (induct n)
  1217   case (Suc n)
  1218   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1219     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1220   also have "\<dots> \<le> (x + 1)^Suc n"
  1221     using Suc x by (simp add: mult_left_mono)
  1222   finally show ?case .
  1223 qed simp
  1224 
  1225 lemma filterlim_realpow_sequentially_gt1:
  1226   fixes x :: "'a :: real_normed_div_algebra"
  1227   assumes x[arith]: "1 < norm x"
  1228   shows "LIM n sequentially. x ^ n :> at_infinity"
  1229 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1230   fix y :: real assume "0 < y"
  1231   have "0 < norm x - 1" by simp
  1232   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1233   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1234   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1235   also have "\<dots> = norm x ^ N" by simp
  1236   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1237     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1238   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1239     unfolding eventually_sequentially
  1240     by (auto simp: norm_power)
  1241 qed simp
  1242 
  1243 
  1244 subsection {* Limits of Sequences *}
  1245 
  1246 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1247   by simp
  1248 
  1249 lemma LIMSEQ_iff:
  1250   fixes L :: "'a::real_normed_vector"
  1251   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1252 unfolding LIMSEQ_def dist_norm ..
  1253 
  1254 lemma LIMSEQ_I:
  1255   fixes L :: "'a::real_normed_vector"
  1256   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1257 by (simp add: LIMSEQ_iff)
  1258 
  1259 lemma LIMSEQ_D:
  1260   fixes L :: "'a::real_normed_vector"
  1261   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1262 by (simp add: LIMSEQ_iff)
  1263 
  1264 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1265   unfolding tendsto_def eventually_sequentially
  1266   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
  1267 
  1268 lemma Bseq_inverse_lemma:
  1269   fixes x :: "'a::real_normed_div_algebra"
  1270   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1271 apply (subst nonzero_norm_inverse, clarsimp)
  1272 apply (erule (1) le_imp_inverse_le)
  1273 done
  1274 
  1275 lemma Bseq_inverse:
  1276   fixes a :: "'a::real_normed_div_algebra"
  1277   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1278   by (rule Bfun_inverse)
  1279 
  1280 lemma LIMSEQ_diff_approach_zero:
  1281   fixes L :: "'a::real_normed_vector"
  1282   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1283   by (drule (1) tendsto_add, simp)
  1284 
  1285 lemma LIMSEQ_diff_approach_zero2:
  1286   fixes L :: "'a::real_normed_vector"
  1287   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1288   by (drule (1) tendsto_diff, simp)
  1289 
  1290 text{*An unbounded sequence's inverse tends to 0*}
  1291 
  1292 lemma LIMSEQ_inverse_zero:
  1293   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1294   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1295   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1296   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1297   done
  1298 
  1299 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1300 
  1301 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1302   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1303             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1304 
  1305 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1306 infinity is now easily proved*}
  1307 
  1308 lemma LIMSEQ_inverse_real_of_nat_add:
  1309      "(%n. r + inverse(real(Suc n))) ----> r"
  1310   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1311 
  1312 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1313      "(%n. r + -inverse(real(Suc n))) ----> r"
  1314   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1315   by auto
  1316 
  1317 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1318      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1319   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1320   by auto
  1321 
  1322 subsection {* Convergence on sequences *}
  1323 
  1324 lemma convergent_add:
  1325   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1326   assumes "convergent (\<lambda>n. X n)"
  1327   assumes "convergent (\<lambda>n. Y n)"
  1328   shows "convergent (\<lambda>n. X n + Y n)"
  1329   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1330 
  1331 lemma convergent_setsum:
  1332   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1333   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1334   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1335 proof (cases "finite A")
  1336   case True from this and assms show ?thesis
  1337     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1338 qed (simp add: convergent_const)
  1339 
  1340 lemma (in bounded_linear) convergent:
  1341   assumes "convergent (\<lambda>n. X n)"
  1342   shows "convergent (\<lambda>n. f (X n))"
  1343   using assms unfolding convergent_def by (fast intro: tendsto)
  1344 
  1345 lemma (in bounded_bilinear) convergent:
  1346   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1347   shows "convergent (\<lambda>n. X n ** Y n)"
  1348   using assms unfolding convergent_def by (fast intro: tendsto)
  1349 
  1350 lemma convergent_minus_iff:
  1351   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1352   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1353 apply (simp add: convergent_def)
  1354 apply (auto dest: tendsto_minus)
  1355 apply (drule tendsto_minus, auto)
  1356 done
  1357 
  1358 
  1359 text {* A monotone sequence converges to its least upper bound. *}
  1360 
  1361 lemma LIMSEQ_incseq_SUP:
  1362   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1363   assumes u: "bdd_above (range X)"
  1364   assumes X: "incseq X"
  1365   shows "X ----> (SUP i. X i)"
  1366   by (rule order_tendstoI)
  1367      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1368 
  1369 lemma LIMSEQ_decseq_INF:
  1370   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1371   assumes u: "bdd_below (range X)"
  1372   assumes X: "decseq X"
  1373   shows "X ----> (INF i. X i)"
  1374   by (rule order_tendstoI)
  1375      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1376 
  1377 text{*Main monotonicity theorem*}
  1378 
  1379 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1380   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1381 
  1382 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1383   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1384 
  1385 lemma Cauchy_iff:
  1386   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1387   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1388   unfolding Cauchy_def dist_norm ..
  1389 
  1390 lemma CauchyI:
  1391   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1392   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1393 by (simp add: Cauchy_iff)
  1394 
  1395 lemma CauchyD:
  1396   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1397   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1398 by (simp add: Cauchy_iff)
  1399 
  1400 lemma incseq_convergent:
  1401   fixes X :: "nat \<Rightarrow> real"
  1402   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1403   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1404 proof atomize_elim
  1405   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1406   obtain L where "X ----> L"
  1407     by (auto simp: convergent_def monoseq_def incseq_def)
  1408   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1409     by (auto intro!: exI[of _ L] incseq_le)
  1410 qed
  1411 
  1412 lemma decseq_convergent:
  1413   fixes X :: "nat \<Rightarrow> real"
  1414   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1415   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1416 proof atomize_elim
  1417   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1418   obtain L where "X ----> L"
  1419     by (auto simp: convergent_def monoseq_def decseq_def)
  1420   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1421     by (auto intro!: exI[of _ L] decseq_le)
  1422 qed
  1423 
  1424 subsubsection {* Cauchy Sequences are Bounded *}
  1425 
  1426 text{*A Cauchy sequence is bounded -- this is the standard
  1427   proof mechanization rather than the nonstandard proof*}
  1428 
  1429 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1430           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1431 apply (clarify, drule spec, drule (1) mp)
  1432 apply (simp only: norm_minus_commute)
  1433 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1434 apply simp
  1435 done
  1436 
  1437 subsection {* Power Sequences *}
  1438 
  1439 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1440 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1441   also fact that bounded and monotonic sequence converges.*}
  1442 
  1443 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1444 apply (simp add: Bseq_def)
  1445 apply (rule_tac x = 1 in exI)
  1446 apply (simp add: power_abs)
  1447 apply (auto dest: power_mono)
  1448 done
  1449 
  1450 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1451 apply (clarify intro!: mono_SucI2)
  1452 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1453 done
  1454 
  1455 lemma convergent_realpow:
  1456   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1457 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1458 
  1459 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1460   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1461 
  1462 lemma LIMSEQ_realpow_zero:
  1463   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1464 proof cases
  1465   assume "0 \<le> x" and "x \<noteq> 0"
  1466   hence x0: "0 < x" by simp
  1467   assume x1: "x < 1"
  1468   from x0 x1 have "1 < inverse x"
  1469     by (rule one_less_inverse)
  1470   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1471     by (rule LIMSEQ_inverse_realpow_zero)
  1472   thus ?thesis by (simp add: power_inverse)
  1473 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1474 
  1475 lemma LIMSEQ_power_zero:
  1476   fixes x :: "'a::{real_normed_algebra_1}"
  1477   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1478 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1479 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1480 apply (simp add: power_abs norm_power_ineq)
  1481 done
  1482 
  1483 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1484   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1485 
  1486 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1487 
  1488 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1489   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1490 
  1491 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1492   by (rule LIMSEQ_power_zero) simp
  1493 
  1494 
  1495 subsection {* Limits of Functions *}
  1496 
  1497 lemma LIM_eq:
  1498   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1499   shows "f -- a --> L =
  1500      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1501 by (simp add: LIM_def dist_norm)
  1502 
  1503 lemma LIM_I:
  1504   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1505   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1506       ==> f -- a --> L"
  1507 by (simp add: LIM_eq)
  1508 
  1509 lemma LIM_D:
  1510   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1511   shows "[| f -- a --> L; 0<r |]
  1512       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1513 by (simp add: LIM_eq)
  1514 
  1515 lemma LIM_offset:
  1516   fixes a :: "'a::real_normed_vector"
  1517   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1518   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1519 
  1520 lemma LIM_offset_zero:
  1521   fixes a :: "'a::real_normed_vector"
  1522   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1523 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
  1524 
  1525 lemma LIM_offset_zero_cancel:
  1526   fixes a :: "'a::real_normed_vector"
  1527   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1528 by (drule_tac k="- a" in LIM_offset, simp)
  1529 
  1530 lemma LIM_offset_zero_iff:
  1531   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1532   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1533   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1534 
  1535 lemma LIM_zero:
  1536   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1537   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1538 unfolding tendsto_iff dist_norm by simp
  1539 
  1540 lemma LIM_zero_cancel:
  1541   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1542   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1543 unfolding tendsto_iff dist_norm by simp
  1544 
  1545 lemma LIM_zero_iff:
  1546   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1547   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1548 unfolding tendsto_iff dist_norm by simp
  1549 
  1550 lemma LIM_imp_LIM:
  1551   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1552   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1553   assumes f: "f -- a --> l"
  1554   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1555   shows "g -- a --> m"
  1556   by (rule metric_LIM_imp_LIM [OF f],
  1557     simp add: dist_norm le)
  1558 
  1559 lemma LIM_equal2:
  1560   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1561   assumes 1: "0 < R"
  1562   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1563   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1564 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1565 
  1566 lemma LIM_compose2:
  1567   fixes a :: "'a::real_normed_vector"
  1568   assumes f: "f -- a --> b"
  1569   assumes g: "g -- b --> c"
  1570   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1571   shows "(\<lambda>x. g (f x)) -- a --> c"
  1572 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1573 
  1574 lemma real_LIM_sandwich_zero:
  1575   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1576   assumes f: "f -- a --> 0"
  1577   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1578   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1579   shows "g -- a --> 0"
  1580 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1581   fix x assume x: "x \<noteq> a"
  1582   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1583   also have "g x \<le> f x" by (rule 2 [OF x])
  1584   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1585   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1586   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1587 qed
  1588 
  1589 
  1590 subsection {* Continuity *}
  1591 
  1592 lemma LIM_isCont_iff:
  1593   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1594   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1595 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1596 
  1597 lemma isCont_iff:
  1598   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1599   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1600 by (simp add: isCont_def LIM_isCont_iff)
  1601 
  1602 lemma isCont_LIM_compose2:
  1603   fixes a :: "'a::real_normed_vector"
  1604   assumes f [unfolded isCont_def]: "isCont f a"
  1605   assumes g: "g -- f a --> l"
  1606   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1607   shows "(\<lambda>x. g (f x)) -- a --> l"
  1608 by (rule LIM_compose2 [OF f g inj])
  1609 
  1610 
  1611 lemma isCont_norm [simp]:
  1612   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1613   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1614   by (fact continuous_norm)
  1615 
  1616 lemma isCont_rabs [simp]:
  1617   fixes f :: "'a::t2_space \<Rightarrow> real"
  1618   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1619   by (fact continuous_rabs)
  1620 
  1621 lemma isCont_add [simp]:
  1622   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1623   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1624   by (fact continuous_add)
  1625 
  1626 lemma isCont_minus [simp]:
  1627   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1628   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1629   by (fact continuous_minus)
  1630 
  1631 lemma isCont_diff [simp]:
  1632   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1633   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1634   by (fact continuous_diff)
  1635 
  1636 lemma isCont_mult [simp]:
  1637   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1638   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1639   by (fact continuous_mult)
  1640 
  1641 lemma (in bounded_linear) isCont:
  1642   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1643   by (fact continuous)
  1644 
  1645 lemma (in bounded_bilinear) isCont:
  1646   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1647   by (fact continuous)
  1648 
  1649 lemmas isCont_scaleR [simp] = 
  1650   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1651 
  1652 lemmas isCont_of_real [simp] =
  1653   bounded_linear.isCont [OF bounded_linear_of_real]
  1654 
  1655 lemma isCont_power [simp]:
  1656   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1657   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1658   by (fact continuous_power)
  1659 
  1660 lemma isCont_setsum [simp]:
  1661   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1662   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1663   by (auto intro: continuous_setsum)
  1664 
  1665 lemmas isCont_intros =
  1666   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
  1667   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
  1668   isCont_of_real isCont_power isCont_sgn isCont_setsum
  1669 
  1670 subsection {* Uniform Continuity *}
  1671 
  1672 definition
  1673   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1674   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1675 
  1676 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1677 by (simp add: isUCont_def isCont_def LIM_def, force)
  1678 
  1679 lemma isUCont_Cauchy:
  1680   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1681 unfolding isUCont_def
  1682 apply (rule metric_CauchyI)
  1683 apply (drule_tac x=e in spec, safe)
  1684 apply (drule_tac e=s in metric_CauchyD, safe)
  1685 apply (rule_tac x=M in exI, simp)
  1686 done
  1687 
  1688 lemma (in bounded_linear) isUCont: "isUCont f"
  1689 unfolding isUCont_def dist_norm
  1690 proof (intro allI impI)
  1691   fix r::real assume r: "0 < r"
  1692   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1693     using pos_bounded by fast
  1694   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1695   proof (rule exI, safe)
  1696     from r K show "0 < r / K" by (rule divide_pos_pos)
  1697   next
  1698     fix x y :: 'a
  1699     assume xy: "norm (x - y) < r / K"
  1700     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1701     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1702     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1703     finally show "norm (f x - f y) < r" .
  1704   qed
  1705 qed
  1706 
  1707 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1708 by (rule isUCont [THEN isUCont_Cauchy])
  1709 
  1710 lemma LIM_less_bound: 
  1711   fixes f :: "real \<Rightarrow> real"
  1712   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1713   shows "0 \<le> f x"
  1714 proof (rule tendsto_le_const)
  1715   show "(f ---> f x) (at_left x)"
  1716     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1717   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1718     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1719 qed simp
  1720 
  1721 
  1722 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1723 
  1724 lemma nested_sequence_unique:
  1725   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1726   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1727 proof -
  1728   have "incseq f" unfolding incseq_Suc_iff by fact
  1729   have "decseq g" unfolding decseq_Suc_iff by fact
  1730 
  1731   { fix n
  1732     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1733     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1734   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1735     using incseq_convergent[OF `incseq f`] by auto
  1736   moreover
  1737   { fix n
  1738     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1739     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1740   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1741     using decseq_convergent[OF `decseq g`] by auto
  1742   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1743   ultimately show ?thesis by auto
  1744 qed
  1745 
  1746 lemma Bolzano[consumes 1, case_names trans local]:
  1747   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1748   assumes [arith]: "a \<le> b"
  1749   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1750   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1751   shows "P a b"
  1752 proof -
  1753   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1754   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1755   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1756     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1757     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1758 
  1759   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1760 
  1761   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1762   proof (safe intro!: nested_sequence_unique)
  1763     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1764   next
  1765     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1766     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1767   qed fact
  1768   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1769   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1770     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1771 
  1772   show "P a b"
  1773   proof (rule ccontr)
  1774     assume "\<not> P a b" 
  1775     { fix n have "\<not> P (l n) (u n)"
  1776       proof (induct n)
  1777         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1778       qed (simp add: `\<not> P a b`) }
  1779     moreover
  1780     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1781         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1782       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1783         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1784       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1785       proof eventually_elim
  1786         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1787         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1788         with x show "P (l n) (u n)" by (rule d)
  1789       qed }
  1790     ultimately show False by simp
  1791   qed
  1792 qed
  1793 
  1794 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1795 proof (cases "a \<le> b", rule compactI)
  1796   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1797   def T == "{a .. b}"
  1798   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1799   proof (induct rule: Bolzano)
  1800     case (trans a b c)
  1801     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1802     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1803       by (auto simp: *)
  1804     with trans show ?case
  1805       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1806   next
  1807     case (local x)
  1808     then have "x \<in> \<Union>C" using C by auto
  1809     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1810     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1811       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1812     with `c \<in> C` show ?case
  1813       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1814   qed
  1815 qed simp
  1816 
  1817 
  1818 subsection {* Boundedness of continuous functions *}
  1819 
  1820 text{*By bisection, function continuous on closed interval is bounded above*}
  1821 
  1822 lemma isCont_eq_Ub:
  1823   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1824   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1825     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1826   using continuous_attains_sup[of "{a .. b}" f]
  1827   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1828 
  1829 lemma isCont_eq_Lb:
  1830   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1831   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1832     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1833   using continuous_attains_inf[of "{a .. b}" f]
  1834   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1835 
  1836 lemma isCont_bounded:
  1837   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1838   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1839   using isCont_eq_Ub[of a b f] by auto
  1840 
  1841 lemma isCont_has_Ub:
  1842   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1843   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1844     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1845   using isCont_eq_Ub[of a b f] by auto
  1846 
  1847 (*HOL style here: object-level formulations*)
  1848 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1849       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1850       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1851   by (blast intro: IVT)
  1852 
  1853 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1854       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1855       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1856   by (blast intro: IVT2)
  1857 
  1858 lemma isCont_Lb_Ub:
  1859   fixes f :: "real \<Rightarrow> real"
  1860   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1861   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and> 
  1862                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  1863 proof -
  1864   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  1865     using isCont_eq_Ub[OF assms] by auto
  1866   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  1867     using isCont_eq_Lb[OF assms] by auto
  1868   show ?thesis
  1869     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  1870     apply (rule_tac x="f L" in exI)
  1871     apply (rule_tac x="f M" in exI)
  1872     apply (cases "L \<le> M")
  1873     apply (simp, metis order_trans)
  1874     apply (simp, metis order_trans)
  1875     done
  1876 qed
  1877 
  1878 
  1879 text{*Continuity of inverse function*}
  1880 
  1881 lemma isCont_inverse_function:
  1882   fixes f g :: "real \<Rightarrow> real"
  1883   assumes d: "0 < d"
  1884       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  1885       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  1886   shows "isCont g (f x)"
  1887 proof -
  1888   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  1889 
  1890   have f: "continuous_on ?D f"
  1891     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  1892   then have g: "continuous_on (f`?D) g"
  1893     using inj by (intro continuous_on_inv) auto
  1894 
  1895   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  1896     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  1897   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  1898     by (rule continuous_on_subset)
  1899   moreover
  1900   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  1901     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  1902   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  1903     by auto
  1904   ultimately
  1905   show ?thesis
  1906     by (simp add: continuous_on_eq_continuous_at)
  1907 qed
  1908 
  1909 lemma isCont_inverse_function2:
  1910   fixes f g :: "real \<Rightarrow> real" shows
  1911   "\<lbrakk>a < x; x < b;
  1912     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  1913     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  1914    \<Longrightarrow> isCont g (f x)"
  1915 apply (rule isCont_inverse_function
  1916        [where f=f and d="min (x - a) (b - x)"])
  1917 apply (simp_all add: abs_le_iff)
  1918 done
  1919 
  1920 (* need to rename second isCont_inverse *)
  1921 
  1922 lemma isCont_inv_fun:
  1923   fixes f g :: "real \<Rightarrow> real"
  1924   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1925          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1926       ==> isCont g (f x)"
  1927 by (rule isCont_inverse_function)
  1928 
  1929 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1930 lemma LIM_fun_gt_zero:
  1931   fixes f :: "real \<Rightarrow> real"
  1932   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  1933 apply (drule (1) LIM_D, clarify)
  1934 apply (rule_tac x = s in exI)
  1935 apply (simp add: abs_less_iff)
  1936 done
  1937 
  1938 lemma LIM_fun_less_zero:
  1939   fixes f :: "real \<Rightarrow> real"
  1940   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  1941 apply (drule LIM_D [where r="-l"], simp, clarify)
  1942 apply (rule_tac x = s in exI)
  1943 apply (simp add: abs_less_iff)
  1944 done
  1945 
  1946 lemma LIM_fun_not_zero:
  1947   fixes f :: "real \<Rightarrow> real"
  1948   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  1949   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  1950 
  1951 end
  1952