src/HOL/Map.thy
author wenzelm
Fri Mar 07 22:30:58 2014 +0100 (2014-03-07)
changeset 55990 41c6b99c5fb7
parent 55466 786edc984c98
child 56545 8f1e7596deb7
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     6 *)
     7 
     8 header {* Maps *}
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 type_synonym ('a,'b) "map" = "'a => 'b option" (infixr "~=>" 0)
    15 
    16 type_notation (xsymbols)
    17   "map" (infixr "\<rightharpoonup>" 0)
    18 
    19 abbreviation
    20   empty :: "'a ~=> 'b" where
    21   "empty == %x. None"
    22 
    23 definition
    24   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    25   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    26 
    27 notation (xsymbols)
    28   map_comp  (infixl "\<circ>\<^sub>m" 55)
    29 
    30 definition
    31   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    32   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    33 
    34 definition
    35   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    36   "m|`A = (\<lambda>x. if x : A then m x else None)"
    37 
    38 notation (latex output)
    39   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    40 
    41 definition
    42   dom :: "('a ~=> 'b) => 'a set" where
    43   "dom m = {a. m a ~= None}"
    44 
    45 definition
    46   ran :: "('a ~=> 'b) => 'b set" where
    47   "ran m = {b. EX a. m a = Some b}"
    48 
    49 definition
    50   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    51   "(m\<^sub>1 \<subseteq>\<^sub>m m\<^sub>2) = (\<forall>a \<in> dom m\<^sub>1. m\<^sub>1 a = m\<^sub>2 a)"
    52 
    53 nonterminal maplets and maplet
    54 
    55 syntax
    56   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    57   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    58   ""         :: "maplet => maplets"             ("_")
    59   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    60   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    61   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    62 
    63 syntax (xsymbols)
    64   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    65   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    66 
    67 translations
    68   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    69   "_MapUpd m (_maplet  x y)"    == "m(x := CONST Some y)"
    70   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    71   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    72   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    73 
    74 primrec
    75   map_of :: "('a \<times> 'b) list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    76     "map_of [] = empty"
    77   | "map_of (p # ps) = (map_of ps)(fst p \<mapsto> snd p)"
    78 
    79 definition
    80   map_upds :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    81   "map_upds m xs ys = m ++ map_of (rev (zip xs ys))"
    82 
    83 translations
    84   "_MapUpd m (_maplets x y)"    == "CONST map_upds m x y"
    85 
    86 lemma map_of_Cons_code [code]: 
    87   "map_of [] k = None"
    88   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    89   by simp_all
    90 
    91 
    92 subsection {* @{term [source] empty} *}
    93 
    94 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    95 by (rule ext) simp
    96 
    97 
    98 subsection {* @{term [source] map_upd} *}
    99 
   100 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   101 by (rule ext) simp
   102 
   103 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   104 proof
   105   assume "t(k \<mapsto> x) = empty"
   106   then have "(t(k \<mapsto> x)) k = None" by simp
   107   then show False by simp
   108 qed
   109 
   110 lemma map_upd_eqD1:
   111   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   112   shows "x = y"
   113 proof -
   114   from assms have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   115   then show ?thesis by simp
   116 qed
   117 
   118 lemma map_upd_Some_unfold:
   119   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   120 by auto
   121 
   122 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   123 by auto
   124 
   125 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   126 unfolding image_def
   127 apply (simp (no_asm_use) add:full_SetCompr_eq)
   128 apply (rule finite_subset)
   129  prefer 2 apply assumption
   130 apply (auto)
   131 done
   132 
   133 
   134 subsection {* @{term [source] map_of} *}
   135 
   136 lemma map_of_eq_None_iff:
   137   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   138 by (induct xys) simp_all
   139 
   140 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   141 apply (induct xys)
   142  apply simp
   143 apply (clarsimp split: if_splits)
   144 done
   145 
   146 lemma map_of_eq_Some_iff [simp]:
   147   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   148 apply (induct xys)
   149  apply simp
   150 apply (auto simp: map_of_eq_None_iff [symmetric])
   151 done
   152 
   153 lemma Some_eq_map_of_iff [simp]:
   154   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   155 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   156 
   157 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   158     \<Longrightarrow> map_of xys x = Some y"
   159 apply (induct xys)
   160  apply simp
   161 apply force
   162 done
   163 
   164 lemma map_of_zip_is_None [simp]:
   165   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   166 by (induct rule: list_induct2) simp_all
   167 
   168 lemma map_of_zip_is_Some:
   169   assumes "length xs = length ys"
   170   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   171 using assms by (induct rule: list_induct2) simp_all
   172 
   173 lemma map_of_zip_upd:
   174   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   175   assumes "length ys = length xs"
   176     and "length zs = length xs"
   177     and "x \<notin> set xs"
   178     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   179   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   180 proof
   181   fix x' :: 'a
   182   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   183   proof (cases "x = x'")
   184     case True
   185     from assms True map_of_zip_is_None [of xs ys x']
   186       have "map_of (zip xs ys) x' = None" by simp
   187     moreover from assms True map_of_zip_is_None [of xs zs x']
   188       have "map_of (zip xs zs) x' = None" by simp
   189     ultimately show ?thesis by simp
   190   next
   191     case False from assms
   192       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   193     with False show ?thesis by simp
   194   qed
   195 qed
   196 
   197 lemma map_of_zip_inject:
   198   assumes "length ys = length xs"
   199     and "length zs = length xs"
   200     and dist: "distinct xs"
   201     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   202   shows "ys = zs"
   203 using assms(1) assms(2)[symmetric] using dist map_of proof (induct ys xs zs rule: list_induct3)
   204   case Nil show ?case by simp
   205 next
   206   case (Cons y ys x xs z zs)
   207   from `map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))`
   208     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   209   from Cons have "length ys = length xs" and "length zs = length xs"
   210     and "x \<notin> set xs" by simp_all
   211   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   212   with Cons.hyps `distinct (x # xs)` have "ys = zs" by simp
   213   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   214   ultimately show ?case by simp
   215 qed
   216 
   217 lemma map_of_zip_map:
   218   "map_of (zip xs (map f xs)) = (\<lambda>x. if x \<in> set xs then Some (f x) else None)"
   219   by (induct xs) (simp_all add: fun_eq_iff)
   220 
   221 lemma finite_range_map_of: "finite (range (map_of xys))"
   222 apply (induct xys)
   223  apply (simp_all add: image_constant)
   224 apply (rule finite_subset)
   225  prefer 2 apply assumption
   226 apply auto
   227 done
   228 
   229 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   230 by (induct xs) (simp, atomize (full), auto)
   231 
   232 lemma map_of_mapk_SomeI:
   233   "inj f ==> map_of t k = Some x ==>
   234    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   235 by (induct t) (auto simp add: inj_eq)
   236 
   237 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   238 by (induct l) auto
   239 
   240 lemma map_of_filter_in:
   241   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   242 by (induct xs) auto
   243 
   244 lemma map_of_map:
   245   "map_of (map (\<lambda>(k, v). (k, f v)) xs) = map_option f \<circ> map_of xs"
   246   by (induct xs) (auto simp add: fun_eq_iff)
   247 
   248 lemma dom_map_option:
   249   "dom (\<lambda>k. map_option (f k) (m k)) = dom m"
   250   by (simp add: dom_def)
   251 
   252 
   253 subsection {* @{const map_option} related *}
   254 
   255 lemma map_option_o_empty [simp]: "map_option f o empty = empty"
   256 by (rule ext) simp
   257 
   258 lemma map_option_o_map_upd [simp]:
   259   "map_option f o m(a|->b) = (map_option f o m)(a|->f b)"
   260 by (rule ext) simp
   261 
   262 
   263 subsection {* @{term [source] map_comp} related *}
   264 
   265 lemma map_comp_empty [simp]:
   266   "m \<circ>\<^sub>m empty = empty"
   267   "empty \<circ>\<^sub>m m = empty"
   268 by (auto simp add: map_comp_def split: option.splits)
   269 
   270 lemma map_comp_simps [simp]:
   271   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   272   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   273 by (auto simp add: map_comp_def)
   274 
   275 lemma map_comp_Some_iff:
   276   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   277 by (auto simp add: map_comp_def split: option.splits)
   278 
   279 lemma map_comp_None_iff:
   280   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   281 by (auto simp add: map_comp_def split: option.splits)
   282 
   283 
   284 subsection {* @{text "++"} *}
   285 
   286 lemma map_add_empty[simp]: "m ++ empty = m"
   287 by(simp add: map_add_def)
   288 
   289 lemma empty_map_add[simp]: "empty ++ m = m"
   290 by (rule ext) (simp add: map_add_def split: option.split)
   291 
   292 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   293 by (rule ext) (simp add: map_add_def split: option.split)
   294 
   295 lemma map_add_Some_iff:
   296   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   297 by (simp add: map_add_def split: option.split)
   298 
   299 lemma map_add_SomeD [dest!]:
   300   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   301 by (rule map_add_Some_iff [THEN iffD1])
   302 
   303 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   304 by (subst map_add_Some_iff) fast
   305 
   306 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   307 by (simp add: map_add_def split: option.split)
   308 
   309 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   310 by (rule ext) (simp add: map_add_def)
   311 
   312 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   313 by (simp add: map_upds_def)
   314 
   315 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   316 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   317 
   318 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   319 unfolding map_add_def
   320 apply (induct xs)
   321  apply simp
   322 apply (rule ext)
   323 apply (simp split add: option.split)
   324 done
   325 
   326 lemma finite_range_map_of_map_add:
   327   "finite (range f) ==> finite (range (f ++ map_of l))"
   328 apply (induct l)
   329  apply (auto simp del: fun_upd_apply)
   330 apply (erule finite_range_updI)
   331 done
   332 
   333 lemma inj_on_map_add_dom [iff]:
   334   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   335 by (fastforce simp: map_add_def dom_def inj_on_def split: option.splits)
   336 
   337 lemma map_upds_fold_map_upd:
   338   "m(ks[\<mapsto>]vs) = foldl (\<lambda>m (k, v). m(k \<mapsto> v)) m (zip ks vs)"
   339 unfolding map_upds_def proof (rule sym, rule zip_obtain_same_length)
   340   fix ks :: "'a list" and vs :: "'b list"
   341   assume "length ks = length vs"
   342   then show "foldl (\<lambda>m (k, v). m(k\<mapsto>v)) m (zip ks vs) = m ++ map_of (rev (zip ks vs))"
   343     by(induct arbitrary: m rule: list_induct2) simp_all
   344 qed
   345 
   346 lemma map_add_map_of_foldr:
   347   "m ++ map_of ps = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) ps m"
   348   by (induct ps) (auto simp add: fun_eq_iff map_add_def)
   349 
   350 
   351 subsection {* @{term [source] restrict_map} *}
   352 
   353 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   354 by (simp add: restrict_map_def)
   355 
   356 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   357 by (auto simp add: restrict_map_def)
   358 
   359 lemma restrict_map_empty [simp]: "empty|`D = empty"
   360 by (simp add: restrict_map_def)
   361 
   362 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   363 by (simp add: restrict_map_def)
   364 
   365 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   366 by (simp add: restrict_map_def)
   367 
   368 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   369 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   370 
   371 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   372 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   373 
   374 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   375 by (rule ext) (auto simp: restrict_map_def)
   376 
   377 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   378 by (rule ext) (auto simp: restrict_map_def)
   379 
   380 lemma restrict_fun_upd [simp]:
   381   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   382 by (simp add: restrict_map_def fun_eq_iff)
   383 
   384 lemma fun_upd_None_restrict [simp]:
   385   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   386 by (simp add: restrict_map_def fun_eq_iff)
   387 
   388 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   389 by (simp add: restrict_map_def fun_eq_iff)
   390 
   391 lemma fun_upd_restrict_conv [simp]:
   392   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   393 by (simp add: restrict_map_def fun_eq_iff)
   394 
   395 lemma map_of_map_restrict:
   396   "map_of (map (\<lambda>k. (k, f k)) ks) = (Some \<circ> f) |` set ks"
   397   by (induct ks) (simp_all add: fun_eq_iff restrict_map_insert)
   398 
   399 lemma restrict_complement_singleton_eq:
   400   "f |` (- {x}) = f(x := None)"
   401   by (simp add: restrict_map_def fun_eq_iff)
   402 
   403 
   404 subsection {* @{term [source] map_upds} *}
   405 
   406 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   407 by (simp add: map_upds_def)
   408 
   409 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   410 by (simp add:map_upds_def)
   411 
   412 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   413 by (simp add:map_upds_def)
   414 
   415 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   416   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   417 apply(induct xs)
   418  apply (clarsimp simp add: neq_Nil_conv)
   419 apply (case_tac ys)
   420  apply simp
   421 apply simp
   422 done
   423 
   424 lemma map_upds_list_update2_drop [simp]:
   425   "size xs \<le> i \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   426 apply (induct xs arbitrary: m ys i)
   427  apply simp
   428 apply (case_tac ys)
   429  apply simp
   430 apply (simp split: nat.split)
   431 done
   432 
   433 lemma map_upd_upds_conv_if:
   434   "(f(x|->y))(xs [|->] ys) =
   435    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   436                                     else (f(xs [|->] ys))(x|->y))"
   437 apply (induct xs arbitrary: x y ys f)
   438  apply simp
   439 apply (case_tac ys)
   440  apply (auto split: split_if simp: fun_upd_twist)
   441 done
   442 
   443 lemma map_upds_twist [simp]:
   444   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   445 using set_take_subset by (fastforce simp add: map_upd_upds_conv_if)
   446 
   447 lemma map_upds_apply_nontin [simp]:
   448   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   449 apply (induct xs arbitrary: ys)
   450  apply simp
   451 apply (case_tac ys)
   452  apply (auto simp: map_upd_upds_conv_if)
   453 done
   454 
   455 lemma fun_upds_append_drop [simp]:
   456   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   457 apply (induct xs arbitrary: m ys)
   458  apply simp
   459 apply (case_tac ys)
   460  apply simp_all
   461 done
   462 
   463 lemma fun_upds_append2_drop [simp]:
   464   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   465 apply (induct xs arbitrary: m ys)
   466  apply simp
   467 apply (case_tac ys)
   468  apply simp_all
   469 done
   470 
   471 
   472 lemma restrict_map_upds[simp]:
   473   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   474     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   475 apply (induct xs arbitrary: m ys)
   476  apply simp
   477 apply (case_tac ys)
   478  apply simp
   479 apply (simp add: Diff_insert [symmetric] insert_absorb)
   480 apply (simp add: map_upd_upds_conv_if)
   481 done
   482 
   483 
   484 subsection {* @{term [source] dom} *}
   485 
   486 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   487   by (auto simp: dom_def)
   488 
   489 lemma domI: "m a = Some b ==> a : dom m"
   490 by(simp add:dom_def)
   491 (* declare domI [intro]? *)
   492 
   493 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   494 by (cases "m a") (auto simp add: dom_def)
   495 
   496 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   497 by(simp add:dom_def)
   498 
   499 lemma dom_empty [simp]: "dom empty = {}"
   500 by(simp add:dom_def)
   501 
   502 lemma dom_fun_upd [simp]:
   503   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   504 by(auto simp add:dom_def)
   505 
   506 lemma dom_if:
   507   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   508   by (auto split: if_splits)
   509 
   510 lemma dom_map_of_conv_image_fst:
   511   "dom (map_of xys) = fst ` set xys"
   512   by (induct xys) (auto simp add: dom_if)
   513 
   514 lemma dom_map_of_zip [simp]: "length xs = length ys ==> dom (map_of (zip xs ys)) = set xs"
   515 by (induct rule: list_induct2) (auto simp add: dom_if)
   516 
   517 lemma finite_dom_map_of: "finite (dom (map_of l))"
   518 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   519 
   520 lemma dom_map_upds [simp]:
   521   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   522 apply (induct xs arbitrary: m ys)
   523  apply simp
   524 apply (case_tac ys)
   525  apply auto
   526 done
   527 
   528 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   529 by(auto simp:dom_def)
   530 
   531 lemma dom_override_on [simp]:
   532   "dom(override_on f g A) =
   533     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   534 by(auto simp: dom_def override_on_def)
   535 
   536 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   537 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   538 
   539 lemma map_add_dom_app_simps:
   540   "\<lbrakk> m\<in>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   541   "\<lbrakk> m\<notin>dom l1 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   542   "\<lbrakk> m\<notin>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l1 m"
   543 by (auto simp add: map_add_def split: option.split_asm)
   544 
   545 lemma dom_const [simp]:
   546   "dom (\<lambda>x. Some (f x)) = UNIV"
   547   by auto
   548 
   549 (* Due to John Matthews - could be rephrased with dom *)
   550 lemma finite_map_freshness:
   551   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   552    \<exists>x. f x = None"
   553 by(bestsimp dest:ex_new_if_finite)
   554 
   555 lemma dom_minus:
   556   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   557   unfolding dom_def by simp
   558 
   559 lemma insert_dom:
   560   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   561   unfolding dom_def by auto
   562 
   563 lemma map_of_map_keys:
   564   "set xs = dom m \<Longrightarrow> map_of (map (\<lambda>k. (k, the (m k))) xs) = m"
   565   by (rule ext) (auto simp add: map_of_map_restrict restrict_map_def)
   566 
   567 lemma map_of_eqI:
   568   assumes set_eq: "set (map fst xs) = set (map fst ys)"
   569   assumes map_eq: "\<forall>k\<in>set (map fst xs). map_of xs k = map_of ys k"
   570   shows "map_of xs = map_of ys"
   571 proof (rule ext)
   572   fix k show "map_of xs k = map_of ys k"
   573   proof (cases "map_of xs k")
   574     case None then have "k \<notin> set (map fst xs)" by (simp add: map_of_eq_None_iff)
   575     with set_eq have "k \<notin> set (map fst ys)" by simp
   576     then have "map_of ys k = None" by (simp add: map_of_eq_None_iff)
   577     with None show ?thesis by simp
   578   next
   579     case (Some v) then have "k \<in> set (map fst xs)" by (auto simp add: dom_map_of_conv_image_fst [symmetric])
   580     with map_eq show ?thesis by auto
   581   qed
   582 qed
   583 
   584 lemma map_of_eq_dom:
   585   assumes "map_of xs = map_of ys"
   586   shows "fst ` set xs = fst ` set ys"
   587 proof -
   588   from assms have "dom (map_of xs) = dom (map_of ys)" by simp
   589   then show ?thesis by (simp add: dom_map_of_conv_image_fst)
   590 qed
   591 
   592 lemma finite_set_of_finite_maps:
   593 assumes "finite A" "finite B"
   594 shows  "finite {m. dom m = A \<and> ran m \<subseteq> B}" (is "finite ?S")
   595 proof -
   596   let ?S' = "{m. \<forall>x. (x \<in> A \<longrightarrow> m x \<in> Some ` B) \<and> (x \<notin> A \<longrightarrow> m x = None)}"
   597   have "?S = ?S'"
   598   proof
   599     show "?S \<subseteq> ?S'" by(auto simp: dom_def ran_def image_def)
   600     show "?S' \<subseteq> ?S"
   601     proof
   602       fix m assume "m \<in> ?S'"
   603       hence 1: "dom m = A" by force
   604       hence 2: "ran m \<subseteq> B" using `m \<in> ?S'` by(auto simp: dom_def ran_def)
   605       from 1 2 show "m \<in> ?S" by blast
   606     qed
   607   qed
   608   with assms show ?thesis by(simp add: finite_set_of_finite_funs)
   609 qed
   610 
   611 subsection {* @{term [source] ran} *}
   612 
   613 lemma ranI: "m a = Some b ==> b : ran m"
   614 by(auto simp: ran_def)
   615 (* declare ranI [intro]? *)
   616 
   617 lemma ran_empty [simp]: "ran empty = {}"
   618 by(auto simp: ran_def)
   619 
   620 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   621 unfolding ran_def
   622 apply auto
   623 apply (subgoal_tac "aa ~= a")
   624  apply auto
   625 done
   626 
   627 lemma ran_distinct: 
   628   assumes dist: "distinct (map fst al)" 
   629   shows "ran (map_of al) = snd ` set al"
   630 using assms proof (induct al)
   631   case Nil then show ?case by simp
   632 next
   633   case (Cons kv al)
   634   then have "ran (map_of al) = snd ` set al" by simp
   635   moreover from Cons.prems have "map_of al (fst kv) = None"
   636     by (simp add: map_of_eq_None_iff)
   637   ultimately show ?case by (simp only: map_of.simps ran_map_upd) simp
   638 qed
   639 
   640 
   641 subsection {* @{text "map_le"} *}
   642 
   643 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   644 by (simp add: map_le_def)
   645 
   646 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   647 by (force simp add: map_le_def)
   648 
   649 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   650 by (fastforce simp add: map_le_def)
   651 
   652 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   653 by (force simp add: map_le_def)
   654 
   655 lemma map_le_upds [simp]:
   656   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   657 apply (induct as arbitrary: f g bs)
   658  apply simp
   659 apply (case_tac bs)
   660  apply auto
   661 done
   662 
   663 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   664 by (fastforce simp add: map_le_def dom_def)
   665 
   666 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   667 by (simp add: map_le_def)
   668 
   669 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   670 by (auto simp add: map_le_def dom_def)
   671 
   672 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   673 unfolding map_le_def
   674 apply (rule ext)
   675 apply (case_tac "x \<in> dom f", simp)
   676 apply (case_tac "x \<in> dom g", simp, fastforce)
   677 done
   678 
   679 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   680 by (fastforce simp add: map_le_def)
   681 
   682 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   683 by(fastforce simp: map_add_def map_le_def fun_eq_iff split: option.splits)
   684 
   685 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   686 by (fastforce simp add: map_le_def map_add_def dom_def)
   687 
   688 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   689 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   690 
   691 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   692 proof(rule iffI)
   693   assume "\<exists>v. f = [x \<mapsto> v]"
   694   thus "dom f = {x}" by(auto split: split_if_asm)
   695 next
   696   assume "dom f = {x}"
   697   then obtain v where "f x = Some v" by auto
   698   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   699   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using `dom f = {x}` `f x = Some v`
   700     by(auto simp add: map_le_def)
   701   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   702   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   703 qed
   704 
   705 
   706 subsection {* Various *}
   707 
   708 lemma set_map_of_compr:
   709   assumes distinct: "distinct (map fst xs)"
   710   shows "set xs = {(k, v). map_of xs k = Some v}"
   711 using assms proof (induct xs)
   712   case Nil then show ?case by simp
   713 next
   714   case (Cons x xs)
   715   obtain k v where "x = (k, v)" by (cases x) blast
   716   with Cons.prems have "k \<notin> dom (map_of xs)"
   717     by (simp add: dom_map_of_conv_image_fst)
   718   then have *: "insert (k, v) {(k, v). map_of xs k = Some v} =
   719     {(k', v'). (map_of xs(k \<mapsto> v)) k' = Some v'}"
   720     by (auto split: if_splits)
   721   from Cons have "set xs = {(k, v). map_of xs k = Some v}" by simp
   722   with * `x = (k, v)` show ?case by simp
   723 qed
   724 
   725 lemma map_of_inject_set:
   726   assumes distinct: "distinct (map fst xs)" "distinct (map fst ys)"
   727   shows "map_of xs = map_of ys \<longleftrightarrow> set xs = set ys" (is "?lhs \<longleftrightarrow> ?rhs")
   728 proof
   729   assume ?lhs
   730   moreover from `distinct (map fst xs)` have "set xs = {(k, v). map_of xs k = Some v}"
   731     by (rule set_map_of_compr)
   732   moreover from `distinct (map fst ys)` have "set ys = {(k, v). map_of ys k = Some v}"
   733     by (rule set_map_of_compr)
   734   ultimately show ?rhs by simp
   735 next
   736   assume ?rhs show ?lhs
   737   proof
   738     fix k
   739     show "map_of xs k = map_of ys k" proof (cases "map_of xs k")
   740       case None
   741       with `?rhs` have "map_of ys k = None"
   742         by (simp add: map_of_eq_None_iff)
   743       with None show ?thesis by simp
   744     next
   745       case (Some v)
   746       with distinct `?rhs` have "map_of ys k = Some v"
   747         by simp
   748       with Some show ?thesis by simp
   749     qed
   750   qed
   751 qed
   752 
   753 end