src/HOL/Product_Type.thy
author wenzelm
Fri Mar 07 22:30:58 2014 +0100 (2014-03-07)
changeset 55990 41c6b99c5fb7
parent 55932 68c5104d2204
child 56077 d397030fb27e
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 free_constructors case_bool for =: True | False
    16 by auto
    17 
    18 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    19 
    20 setup {* Sign.mandatory_path "old" *}
    21 
    22 rep_datatype True False by (auto intro: bool_induct)
    23 
    24 setup {* Sign.parent_path *}
    25 
    26 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    27 
    28 setup {* Sign.mandatory_path "bool" *}
    29 
    30 lemmas induct = old.bool.induct
    31 lemmas inducts = old.bool.inducts
    32 lemmas rec = old.bool.rec
    33 lemmas simps = bool.distinct bool.case bool.rec
    34 
    35 setup {* Sign.parent_path *}
    36 
    37 declare case_split [cases type: bool]
    38   -- "prefer plain propositional version"
    39 
    40 lemma
    41   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    42     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    43     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    44     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    45     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    46   by (simp_all add: equal)
    47 
    48 lemma If_case_cert:
    49   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    50   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    51   using assms by simp_all
    52 
    53 setup {*
    54   Code.add_case @{thm If_case_cert}
    55 *}
    56 
    57 code_printing
    58   constant "HOL.equal :: bool \<Rightarrow> bool \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
    59 | class_instance "bool" :: "equal" \<rightharpoonup> (Haskell) -
    60 
    61 
    62 subsection {* The @{text unit} type *}
    63 
    64 typedef unit = "{True}"
    65   by auto
    66 
    67 definition Unity :: unit  ("'(')")
    68   where "() = Abs_unit True"
    69 
    70 lemma unit_eq [no_atp]: "u = ()"
    71   by (induct u) (simp add: Unity_def)
    72 
    73 text {*
    74   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    75   this rule directly --- it loops!
    76 *}
    77 
    78 simproc_setup unit_eq ("x::unit") = {*
    79   fn _ => fn _ => fn ct =>
    80     if HOLogic.is_unit (term_of ct) then NONE
    81     else SOME (mk_meta_eq @{thm unit_eq})
    82 *}
    83 
    84 free_constructors case_unit for "()"
    85 by auto
    86 
    87 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    88 
    89 setup {* Sign.mandatory_path "old" *}
    90 
    91 rep_datatype "()" by simp
    92 
    93 setup {* Sign.parent_path *}
    94 
    95 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    96 
    97 setup {* Sign.mandatory_path "unit" *}
    98 
    99 lemmas induct = old.unit.induct
   100 lemmas inducts = old.unit.inducts
   101 lemmas rec = old.unit.rec
   102 lemmas simps = unit.case unit.rec
   103 
   104 setup {* Sign.parent_path *}
   105 
   106 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
   107   by simp
   108 
   109 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
   110   by (rule triv_forall_equality)
   111 
   112 text {*
   113   This rewrite counters the effect of simproc @{text unit_eq} on @{term
   114   [source] "%u::unit. f u"}, replacing it by @{term [source]
   115   f} rather than by @{term [source] "%u. f ()"}.
   116 *}
   117 
   118 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
   119   by (rule ext) simp
   120 
   121 lemma UNIV_unit:
   122   "UNIV = {()}" by auto
   123 
   124 instantiation unit :: default
   125 begin
   126 
   127 definition "default = ()"
   128 
   129 instance ..
   130 
   131 end
   132 
   133 lemma [code]:
   134   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   135 
   136 code_printing
   137   type_constructor unit \<rightharpoonup>
   138     (SML) "unit"
   139     and (OCaml) "unit"
   140     and (Haskell) "()"
   141     and (Scala) "Unit"
   142 | constant Unity \<rightharpoonup>
   143     (SML) "()"
   144     and (OCaml) "()"
   145     and (Haskell) "()"
   146     and (Scala) "()"
   147 | class_instance unit :: equal \<rightharpoonup>
   148     (Haskell) -
   149 | constant "HOL.equal :: unit \<Rightarrow> unit \<Rightarrow> bool" \<rightharpoonup>
   150     (Haskell) infix 4 "=="
   151 
   152 code_reserved SML
   153   unit
   154 
   155 code_reserved OCaml
   156   unit
   157 
   158 code_reserved Scala
   159   Unit
   160 
   161 
   162 subsection {* The product type *}
   163 
   164 subsubsection {* Type definition *}
   165 
   166 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   167   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   168 
   169 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   170 
   171 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   172   unfolding prod_def by auto
   173 
   174 type_notation (xsymbols)
   175   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   176 type_notation (HTML output)
   177   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   178 
   179 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   180   "Pair a b = Abs_prod (Pair_Rep a b)"
   181 
   182 lemma prod_cases: "(\<And>a b. P (Pair a b)) \<Longrightarrow> P p"
   183   by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   184 
   185 free_constructors case_prod for Pair fst snd
   186 proof -
   187   fix P :: bool and p :: "'a \<times> 'b"
   188   show "(\<And>x1 x2. p = Pair x1 x2 \<Longrightarrow> P) \<Longrightarrow> P"
   189     by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   190 next
   191   fix a c :: 'a and b d :: 'b
   192   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   193     by (auto simp add: Pair_Rep_def fun_eq_iff)
   194   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   195     by (auto simp add: prod_def)
   196   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   197     by (simp add: Pair_def Abs_prod_inject)
   198 qed
   199 
   200 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
   201 
   202 setup {* Sign.mandatory_path "old" *}
   203 
   204 rep_datatype Pair
   205 by (erule prod_cases) (rule prod.inject)
   206 
   207 setup {* Sign.parent_path *}
   208 
   209 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   210 
   211 setup {* Sign.mandatory_path "prod" *}
   212 
   213 declare
   214   old.prod.inject[iff del]
   215 
   216 lemmas induct = old.prod.induct
   217 lemmas inducts = old.prod.inducts
   218 lemmas rec = old.prod.rec
   219 lemmas simps = prod.inject prod.case prod.rec
   220 
   221 setup {* Sign.parent_path *}
   222 
   223 declare prod.case [nitpick_simp del]
   224 declare prod.weak_case_cong [cong del]
   225 
   226 
   227 subsubsection {* Tuple syntax *}
   228 
   229 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   230   "split \<equiv> case_prod"
   231 
   232 text {*
   233   Patterns -- extends pre-defined type @{typ pttrn} used in
   234   abstractions.
   235 *}
   236 
   237 nonterminal tuple_args and patterns
   238 
   239 syntax
   240   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   241   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   242   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   243   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   244   ""            :: "pttrn => patterns"                  ("_")
   245   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   246 
   247 translations
   248   "(x, y)" == "CONST Pair x y"
   249   "_pattern x y" => "CONST Pair x y"
   250   "_patterns x y" => "CONST Pair x y"
   251   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   252   "%(x, y, zs). b" == "CONST case_prod (%x (y, zs). b)"
   253   "%(x, y). b" == "CONST case_prod (%x y. b)"
   254   "_abs (CONST Pair x y) t" => "%(x, y). t"
   255   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   256      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   257 
   258 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   259   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   260 print_translation {*
   261   let
   262     fun split_tr' [Abs (x, T, t as (Abs abs))] =
   263           (* split (%x y. t) => %(x,y) t *)
   264           let
   265             val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   266             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   267           in
   268             Syntax.const @{syntax_const "_abs"} $
   269               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   270           end
   271       | split_tr' [Abs (x, T, (s as Const (@{const_syntax case_prod}, _) $ t))] =
   272           (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   273           let
   274             val Const (@{syntax_const "_abs"}, _) $
   275               (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   276             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   277           in
   278             Syntax.const @{syntax_const "_abs"} $
   279               (Syntax.const @{syntax_const "_pattern"} $ x' $
   280                 (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   281           end
   282       | split_tr' [Const (@{const_syntax case_prod}, _) $ t] =
   283           (* split (split (%x y z. t)) => %((x, y), z). t *)
   284           split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   285       | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   286           (* split (%pttrn z. t) => %(pttrn,z). t *)
   287           let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   288             Syntax.const @{syntax_const "_abs"} $
   289               (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   290           end
   291       | split_tr' _ = raise Match;
   292   in [(@{const_syntax case_prod}, K split_tr')] end
   293 *}
   294 
   295 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   296 typed_print_translation {*
   297   let
   298     fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   299       | split_guess_names_tr' T [Abs (x, xT, t)] =
   300           (case (head_of t) of
   301             Const (@{const_syntax case_prod}, _) => raise Match
   302           | _ =>
   303             let 
   304               val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   305               val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   306               val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   307             in
   308               Syntax.const @{syntax_const "_abs"} $
   309                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   310             end)
   311       | split_guess_names_tr' T [t] =
   312           (case head_of t of
   313             Const (@{const_syntax case_prod}, _) => raise Match
   314           | _ =>
   315             let
   316               val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   317               val (y, t') =
   318                 Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   319               val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   320             in
   321               Syntax.const @{syntax_const "_abs"} $
   322                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   323             end)
   324       | split_guess_names_tr' _ _ = raise Match;
   325   in [(@{const_syntax case_prod}, K split_guess_names_tr')] end
   326 *}
   327 
   328 (* Force eta-contraction for terms of the form "Q A (%p. case_prod P p)"
   329    where Q is some bounded quantifier or set operator.
   330    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   331    whereas we want "Q (x,y):A. P x y".
   332    Otherwise prevent eta-contraction.
   333 *)
   334 print_translation {*
   335   let
   336     fun contract Q tr ctxt ts =
   337       (case ts of
   338         [A, Abs (_, _, (s as Const (@{const_syntax case_prod},_) $ t) $ Bound 0)] =>
   339           if Term.is_dependent t then tr ctxt ts
   340           else Syntax.const Q $ A $ s
   341       | _ => tr ctxt ts);
   342   in
   343     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   344      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   345      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   346      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   347     |> map (fn (Q, tr) => (Q, contract Q tr))
   348   end
   349 *}
   350 
   351 subsubsection {* Code generator setup *}
   352 
   353 code_printing
   354   type_constructor prod \<rightharpoonup>
   355     (SML) infix 2 "*"
   356     and (OCaml) infix 2 "*"
   357     and (Haskell) "!((_),/ (_))"
   358     and (Scala) "((_),/ (_))"
   359 | constant Pair \<rightharpoonup>
   360     (SML) "!((_),/ (_))"
   361     and (OCaml) "!((_),/ (_))"
   362     and (Haskell) "!((_),/ (_))"
   363     and (Scala) "!((_),/ (_))"
   364 | class_instance  prod :: equal \<rightharpoonup>
   365     (Haskell) -
   366 | constant "HOL.equal :: 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool" \<rightharpoonup>
   367     (Haskell) infix 4 "=="
   368 
   369 
   370 subsubsection {* Fundamental operations and properties *}
   371 
   372 lemma Pair_inject:
   373   assumes "(a, b) = (a', b')"
   374     and "a = a' ==> b = b' ==> R"
   375   shows R
   376   using assms by simp
   377 
   378 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   379   by (cases p) simp
   380 
   381 code_printing
   382   constant fst \<rightharpoonup> (Haskell) "fst"
   383 | constant snd \<rightharpoonup> (Haskell) "snd"
   384 
   385 lemma case_prod_unfold [nitpick_unfold]: "case_prod = (%c p. c (fst p) (snd p))"
   386   by (simp add: fun_eq_iff split: prod.split)
   387 
   388 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   389   by simp
   390 
   391 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   392   by simp
   393 
   394 lemmas surjective_pairing = prod.collapse [symmetric]
   395 
   396 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   397   by (cases s, cases t) simp
   398 
   399 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   400   by (simp add: prod_eq_iff)
   401 
   402 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   403   by (fact prod.case)
   404 
   405 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   406   by (rule split_conv [THEN iffD2])
   407 
   408 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   409   by (rule split_conv [THEN iffD1])
   410 
   411 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   412   by (simp add: fun_eq_iff split: prod.split)
   413 
   414 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   415   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   416   by (simp add: fun_eq_iff split: prod.split)
   417 
   418 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   419   by (cases x) simp
   420 
   421 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   422   by (cases p) simp
   423 
   424 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   425   by (simp add: case_prod_unfold)
   426 
   427 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   428   -- {* Prevents simplification of @{term c}: much faster *}
   429   by (fact prod.weak_case_cong)
   430 
   431 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   432   by (simp add: split_eta)
   433 
   434 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   435 proof
   436   fix a b
   437   assume "!!x. PROP P x"
   438   then show "PROP P (a, b)" .
   439 next
   440   fix x
   441   assume "!!a b. PROP P (a, b)"
   442   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   443 qed
   444 
   445 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   446   by (cases x) simp
   447 
   448 text {*
   449   The rule @{thm [source] split_paired_all} does not work with the
   450   Simplifier because it also affects premises in congrence rules,
   451   where this can lead to premises of the form @{text "!!a b. ... =
   452   ?P(a, b)"} which cannot be solved by reflexivity.
   453 *}
   454 
   455 lemmas split_tupled_all = split_paired_all unit_all_eq2
   456 
   457 ML {*
   458   (* replace parameters of product type by individual component parameters *)
   459   local (* filtering with exists_paired_all is an essential optimization *)
   460     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   461           can HOLogic.dest_prodT T orelse exists_paired_all t
   462       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   463       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   464       | exists_paired_all _ = false;
   465     val ss =
   466       simpset_of
   467        (put_simpset HOL_basic_ss @{context}
   468         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   469         addsimprocs [@{simproc unit_eq}]);
   470   in
   471     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   472       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   473 
   474     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   475       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   476 
   477     fun split_all ctxt th =
   478       if exists_paired_all (Thm.prop_of th)
   479       then full_simplify (put_simpset ss ctxt) th else th;
   480   end;
   481 *}
   482 
   483 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   484 
   485 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   486   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   487   by fast
   488 
   489 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   490   by fast
   491 
   492 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   493   -- {* Can't be added to simpset: loops! *}
   494   by (simp add: split_eta)
   495 
   496 text {*
   497   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   498   @{thm [source] split_eta} as a rewrite rule is not general enough,
   499   and using @{thm [source] cond_split_eta} directly would render some
   500   existing proofs very inefficient; similarly for @{text
   501   split_beta}.
   502 *}
   503 
   504 ML {*
   505 local
   506   val cond_split_eta_ss =
   507     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   508   fun Pair_pat k 0 (Bound m) = (m = k)
   509     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   510         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   511     | Pair_pat _ _ _ = false;
   512   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   513     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   514     | no_args k i (Bound m) = m < k orelse m > k + i
   515     | no_args _ _ _ = true;
   516   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   517     | split_pat tp i (Const (@{const_name case_prod}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   518     | split_pat tp i _ = NONE;
   519   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   520         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   521         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   522 
   523   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   524     | beta_term_pat k i (t $ u) =
   525         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   526     | beta_term_pat k i t = no_args k i t;
   527   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   528     | eta_term_pat _ _ _ = false;
   529   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   530     | subst arg k i (t $ u) =
   531         if Pair_pat k i (t $ u) then incr_boundvars k arg
   532         else (subst arg k i t $ subst arg k i u)
   533     | subst arg k i t = t;
   534 in
   535   fun beta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t) $ arg) =
   536         (case split_pat beta_term_pat 1 t of
   537           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   538         | NONE => NONE)
   539     | beta_proc _ _ = NONE;
   540   fun eta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t)) =
   541         (case split_pat eta_term_pat 1 t of
   542           SOME (_, ft) => SOME (metaeq ctxt s (let val (f $ arg) = ft in f end))
   543         | NONE => NONE)
   544     | eta_proc _ _ = NONE;
   545 end;
   546 *}
   547 simproc_setup split_beta ("split f z") = {* fn _ => fn ctxt => fn ct => beta_proc ctxt (term_of ct) *}
   548 simproc_setup split_eta ("split f") = {* fn _ => fn ctxt => fn ct => eta_proc ctxt (term_of ct) *}
   549 
   550 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   551   by (subst surjective_pairing, rule split_conv)
   552 
   553 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   554   by (auto simp: fun_eq_iff)
   555 
   556 
   557 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   558   -- {* For use with @{text split} and the Simplifier. *}
   559   by (insert surj_pair [of p], clarify, simp)
   560 
   561 text {*
   562   @{thm [source] split_split} could be declared as @{text "[split]"}
   563   done after the Splitter has been speeded up significantly;
   564   precompute the constants involved and don't do anything unless the
   565   current goal contains one of those constants.
   566 *}
   567 
   568 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   569 by (subst split_split, simp)
   570 
   571 text {*
   572   \medskip @{term split} used as a logical connective or set former.
   573 
   574   \medskip These rules are for use with @{text blast}; could instead
   575   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   576 
   577 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   578   apply (simp only: split_tupled_all)
   579   apply (simp (no_asm_simp))
   580   done
   581 
   582 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   583   apply (simp only: split_tupled_all)
   584   apply (simp (no_asm_simp))
   585   done
   586 
   587 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   588   by (induct p) auto
   589 
   590 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   591   by (induct p) auto
   592 
   593 lemma splitE2:
   594   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   595 proof -
   596   assume q: "Q (split P z)"
   597   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   598   show R
   599     apply (rule r surjective_pairing)+
   600     apply (rule split_beta [THEN subst], rule q)
   601     done
   602 qed
   603 
   604 lemma splitD': "split R (a,b) c ==> R a b c"
   605   by simp
   606 
   607 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   608   by simp
   609 
   610 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   611 by (simp only: split_tupled_all, simp)
   612 
   613 lemma mem_splitE:
   614   assumes major: "z \<in> split c p"
   615     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   616   shows Q
   617   by (rule major [unfolded case_prod_unfold] cases surjective_pairing)+
   618 
   619 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   620 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   621 
   622 ML {*
   623 local (* filtering with exists_p_split is an essential optimization *)
   624   fun exists_p_split (Const (@{const_name case_prod},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   625     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   626     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   627     | exists_p_split _ = false;
   628 in
   629 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   630   if exists_p_split t
   631   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   632   else no_tac);
   633 end;
   634 *}
   635 
   636 (* This prevents applications of splitE for already splitted arguments leading
   637    to quite time-consuming computations (in particular for nested tuples) *)
   638 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   639 
   640 lemma split_eta_SetCompr [simp, no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   641   by (rule ext) fast
   642 
   643 lemma split_eta_SetCompr2 [simp, no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   644   by (rule ext) fast
   645 
   646 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   647   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   648   by (rule ext) blast
   649 
   650 (* Do NOT make this a simp rule as it
   651    a) only helps in special situations
   652    b) can lead to nontermination in the presence of split_def
   653 *)
   654 lemma split_comp_eq: 
   655   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   656   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   657   by (rule ext) auto
   658 
   659 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   660   apply (rule_tac x = "(a, b)" in image_eqI)
   661    apply auto
   662   done
   663 
   664 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   665   by blast
   666 
   667 (*
   668 the following  would be slightly more general,
   669 but cannot be used as rewrite rule:
   670 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   671 ### ?y = .x
   672 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   673 by (rtac some_equality 1)
   674 by ( Simp_tac 1)
   675 by (split_all_tac 1)
   676 by (Asm_full_simp_tac 1)
   677 qed "The_split_eq";
   678 *)
   679 
   680 text {*
   681   Setup of internal @{text split_rule}.
   682 *}
   683 
   684 lemmas case_prodI = prod.case [THEN iffD2]
   685 
   686 lemma case_prodI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> case_prod c p"
   687   by (fact splitI2)
   688 
   689 lemma case_prodI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> case_prod c p x"
   690   by (fact splitI2')
   691 
   692 lemma case_prodE: "case_prod c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   693   by (fact splitE)
   694 
   695 lemma case_prodE': "case_prod c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   696   by (fact splitE')
   697 
   698 declare case_prodI [intro!]
   699 
   700 lemma case_prod_beta:
   701   "case_prod f p = f (fst p) (snd p)"
   702   by (fact split_beta)
   703 
   704 lemma prod_cases3 [cases type]:
   705   obtains (fields) a b c where "y = (a, b, c)"
   706   by (cases y, case_tac b) blast
   707 
   708 lemma prod_induct3 [case_names fields, induct type]:
   709     "(!!a b c. P (a, b, c)) ==> P x"
   710   by (cases x) blast
   711 
   712 lemma prod_cases4 [cases type]:
   713   obtains (fields) a b c d where "y = (a, b, c, d)"
   714   by (cases y, case_tac c) blast
   715 
   716 lemma prod_induct4 [case_names fields, induct type]:
   717     "(!!a b c d. P (a, b, c, d)) ==> P x"
   718   by (cases x) blast
   719 
   720 lemma prod_cases5 [cases type]:
   721   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   722   by (cases y, case_tac d) blast
   723 
   724 lemma prod_induct5 [case_names fields, induct type]:
   725     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   726   by (cases x) blast
   727 
   728 lemma prod_cases6 [cases type]:
   729   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   730   by (cases y, case_tac e) blast
   731 
   732 lemma prod_induct6 [case_names fields, induct type]:
   733     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   734   by (cases x) blast
   735 
   736 lemma prod_cases7 [cases type]:
   737   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   738   by (cases y, case_tac f) blast
   739 
   740 lemma prod_induct7 [case_names fields, induct type]:
   741     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   742   by (cases x) blast
   743 
   744 lemma split_def:
   745   "split = (\<lambda>c p. c (fst p) (snd p))"
   746   by (fact case_prod_unfold)
   747 
   748 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   749   "internal_split == split"
   750 
   751 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   752   by (simp only: internal_split_def split_conv)
   753 
   754 ML_file "Tools/split_rule.ML"
   755 setup Split_Rule.setup
   756 
   757 hide_const internal_split
   758 
   759 
   760 subsubsection {* Derived operations *}
   761 
   762 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   763   "curry = (\<lambda>c x y. c (x, y))"
   764 
   765 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   766   by (simp add: curry_def)
   767 
   768 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   769   by (simp add: curry_def)
   770 
   771 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   772   by (simp add: curry_def)
   773 
   774 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   775   by (simp add: curry_def)
   776 
   777 lemma curry_split [simp]: "curry (split f) = f"
   778   by (simp add: curry_def split_def)
   779 
   780 lemma split_curry [simp]: "split (curry f) = f"
   781   by (simp add: curry_def split_def)
   782 
   783 lemma curry_K: "curry (\<lambda>x. c) = (\<lambda>x y. c)"
   784 by(simp add: fun_eq_iff)
   785 
   786 text {*
   787   The composition-uncurry combinator.
   788 *}
   789 
   790 notation fcomp (infixl "\<circ>>" 60)
   791 
   792 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   793   "f \<circ>\<rightarrow> g = (\<lambda>x. case_prod g (f x))"
   794 
   795 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   796   by (simp add: fun_eq_iff scomp_def case_prod_unfold)
   797 
   798 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = case_prod g (f x)"
   799   by (simp add: scomp_unfold case_prod_unfold)
   800 
   801 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   802   by (simp add: fun_eq_iff)
   803 
   804 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   805   by (simp add: fun_eq_iff)
   806 
   807 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   808   by (simp add: fun_eq_iff scomp_unfold)
   809 
   810 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   811   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   812 
   813 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   814   by (simp add: fun_eq_iff scomp_unfold)
   815 
   816 code_printing
   817   constant scomp \<rightharpoonup> (Eval) infixl 3 "#->"
   818 
   819 no_notation fcomp (infixl "\<circ>>" 60)
   820 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   821 
   822 text {*
   823   @{term map_prod} --- action of the product functor upon
   824   functions.
   825 *}
   826 
   827 definition map_prod :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   828   "map_prod f g = (\<lambda>(x, y). (f x, g y))"
   829 
   830 lemma map_prod_simp [simp, code]:
   831   "map_prod f g (a, b) = (f a, g b)"
   832   by (simp add: map_prod_def)
   833 
   834 functor map_prod: map_prod
   835   by (auto simp add: split_paired_all)
   836 
   837 lemma fst_map_prod [simp]:
   838   "fst (map_prod f g x) = f (fst x)"
   839   by (cases x) simp_all
   840 
   841 lemma snd_prod_fun [simp]:
   842   "snd (map_prod f g x) = g (snd x)"
   843   by (cases x) simp_all
   844 
   845 lemma fst_comp_map_prod [simp]:
   846   "fst \<circ> map_prod f g = f \<circ> fst"
   847   by (rule ext) simp_all
   848 
   849 lemma snd_comp_map_prod [simp]:
   850   "snd \<circ> map_prod f g = g \<circ> snd"
   851   by (rule ext) simp_all
   852 
   853 lemma map_prod_compose:
   854   "map_prod (f1 o f2) (g1 o g2) = (map_prod f1 g1 o map_prod f2 g2)"
   855   by (rule ext) (simp add: map_prod.compositionality comp_def)
   856 
   857 lemma map_prod_ident [simp]:
   858   "map_prod (%x. x) (%y. y) = (%z. z)"
   859   by (rule ext) (simp add: map_prod.identity)
   860 
   861 lemma map_prod_imageI [intro]:
   862   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_prod f g ` R"
   863   by (rule image_eqI) simp_all
   864 
   865 lemma prod_fun_imageE [elim!]:
   866   assumes major: "c \<in> map_prod f g ` R"
   867     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   868   shows P
   869   apply (rule major [THEN imageE])
   870   apply (case_tac x)
   871   apply (rule cases)
   872   apply simp_all
   873   done
   874 
   875 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   876   "apfst f = map_prod f id"
   877 
   878 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   879   "apsnd f = map_prod id f"
   880 
   881 lemma apfst_conv [simp, code]:
   882   "apfst f (x, y) = (f x, y)" 
   883   by (simp add: apfst_def)
   884 
   885 lemma apsnd_conv [simp, code]:
   886   "apsnd f (x, y) = (x, f y)" 
   887   by (simp add: apsnd_def)
   888 
   889 lemma fst_apfst [simp]:
   890   "fst (apfst f x) = f (fst x)"
   891   by (cases x) simp
   892 
   893 lemma fst_comp_apfst [simp]:
   894   "fst \<circ> apfst f = f \<circ> fst"
   895   by (simp add: fun_eq_iff)
   896 
   897 lemma fst_apsnd [simp]:
   898   "fst (apsnd f x) = fst x"
   899   by (cases x) simp
   900 
   901 lemma fst_comp_apsnd [simp]:
   902   "fst \<circ> apsnd f = fst"
   903   by (simp add: fun_eq_iff)
   904 
   905 lemma snd_apfst [simp]:
   906   "snd (apfst f x) = snd x"
   907   by (cases x) simp
   908 
   909 lemma snd_comp_apfst [simp]:
   910   "snd \<circ> apfst f = snd"
   911   by (simp add: fun_eq_iff)
   912 
   913 lemma snd_apsnd [simp]:
   914   "snd (apsnd f x) = f (snd x)"
   915   by (cases x) simp
   916 
   917 lemma snd_comp_apsnd [simp]:
   918   "snd \<circ> apsnd f = f \<circ> snd"
   919   by (simp add: fun_eq_iff)
   920 
   921 lemma apfst_compose:
   922   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   923   by (cases x) simp
   924 
   925 lemma apsnd_compose:
   926   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   927   by (cases x) simp
   928 
   929 lemma apfst_apsnd [simp]:
   930   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   931   by (cases x) simp
   932 
   933 lemma apsnd_apfst [simp]:
   934   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   935   by (cases x) simp
   936 
   937 lemma apfst_id [simp] :
   938   "apfst id = id"
   939   by (simp add: fun_eq_iff)
   940 
   941 lemma apsnd_id [simp] :
   942   "apsnd id = id"
   943   by (simp add: fun_eq_iff)
   944 
   945 lemma apfst_eq_conv [simp]:
   946   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   947   by (cases x) simp
   948 
   949 lemma apsnd_eq_conv [simp]:
   950   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   951   by (cases x) simp
   952 
   953 lemma apsnd_apfst_commute:
   954   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   955   by simp
   956 
   957 text {*
   958   Disjoint union of a family of sets -- Sigma.
   959 *}
   960 
   961 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
   962   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   963 
   964 abbreviation
   965   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
   966     (infixr "<*>" 80) where
   967   "A <*> B == Sigma A (%_. B)"
   968 
   969 notation (xsymbols)
   970   Times  (infixr "\<times>" 80)
   971 
   972 notation (HTML output)
   973   Times  (infixr "\<times>" 80)
   974 
   975 hide_const (open) Times
   976 
   977 syntax
   978   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   979 translations
   980   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   981 
   982 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   983   by (unfold Sigma_def) blast
   984 
   985 lemma SigmaE [elim!]:
   986     "[| c: Sigma A B;
   987         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   988      |] ==> P"
   989   -- {* The general elimination rule. *}
   990   by (unfold Sigma_def) blast
   991 
   992 text {*
   993   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   994   eigenvariables.
   995 *}
   996 
   997 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   998   by blast
   999 
  1000 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1001   by blast
  1002 
  1003 lemma SigmaE2:
  1004     "[| (a, b) : Sigma A B;
  1005         [| a:A;  b:B(a) |] ==> P
  1006      |] ==> P"
  1007   by blast
  1008 
  1009 lemma Sigma_cong:
  1010      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1011       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1012   by auto
  1013 
  1014 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1015   by blast
  1016 
  1017 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1018   by blast
  1019 
  1020 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1021   by blast
  1022 
  1023 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1024   by auto
  1025 
  1026 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1027   by auto
  1028 
  1029 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1030   by auto
  1031 
  1032 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1033   by blast
  1034 
  1035 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1036   by blast
  1037 
  1038 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1039   by (blast elim: equalityE)
  1040 
  1041 lemma SetCompr_Sigma_eq:
  1042     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1043   by blast
  1044 
  1045 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1046   by blast
  1047 
  1048 lemma UN_Times_distrib:
  1049   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1050   -- {* Suggested by Pierre Chartier *}
  1051   by blast
  1052 
  1053 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1054     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1055   by blast
  1056 
  1057 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1058     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1059   by blast
  1060 
  1061 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1062   by blast
  1063 
  1064 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1065   by blast
  1066 
  1067 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1068   by blast
  1069 
  1070 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1071   by blast
  1072 
  1073 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1074   by blast
  1075 
  1076 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1077   by blast
  1078 
  1079 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1080   by blast
  1081 
  1082 text {*
  1083   Non-dependent versions are needed to avoid the need for higher-order
  1084   matching, especially when the rules are re-oriented.
  1085 *}
  1086 
  1087 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1088 by blast
  1089 
  1090 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1091 by blast
  1092 
  1093 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1094 by blast
  1095 
  1096 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1097   by auto
  1098 
  1099 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1100   by auto
  1101 
  1102 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1103   by force
  1104 
  1105 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1106   by force
  1107 
  1108 lemma insert_times_insert[simp]:
  1109   "insert a A \<times> insert b B =
  1110    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1111 by blast
  1112 
  1113 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1114   apply auto
  1115   apply (case_tac "f x")
  1116   apply auto
  1117   done
  1118 
  1119 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1120   by auto
  1121 
  1122 lemma swap_inj_on:
  1123   "inj_on (\<lambda>(i, j). (j, i)) A"
  1124   by (auto intro!: inj_onI)
  1125 
  1126 lemma swap_product:
  1127   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1128   by (simp add: split_def image_def) blast
  1129 
  1130 lemma image_split_eq_Sigma:
  1131   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1132 proof (safe intro!: imageI)
  1133   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1134   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1135     using * eq[symmetric] by auto
  1136 qed simp_all
  1137 
  1138 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1139   [code_abbrev]: "product A B = A \<times> B"
  1140 
  1141 hide_const (open) product
  1142 
  1143 lemma member_product:
  1144   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1145   by (simp add: product_def)
  1146 
  1147 text {* The following @{const map_prod} lemmas are due to Joachim Breitner: *}
  1148 
  1149 lemma map_prod_inj_on:
  1150   assumes "inj_on f A" and "inj_on g B"
  1151   shows "inj_on (map_prod f g) (A \<times> B)"
  1152 proof (rule inj_onI)
  1153   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1154   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1155   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1156   assume "map_prod f g x = map_prod f g y"
  1157   hence "fst (map_prod f g x) = fst (map_prod f g y)" by (auto)
  1158   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1159   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1160   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1161   moreover from `map_prod f g x = map_prod f g y`
  1162   have "snd (map_prod f g x) = snd (map_prod f g y)" by (auto)
  1163   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1164   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1165   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1166   ultimately show "x = y" by(rule prod_eqI)
  1167 qed
  1168 
  1169 lemma map_prod_surj:
  1170   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1171   assumes "surj f" and "surj g"
  1172   shows "surj (map_prod f g)"
  1173 unfolding surj_def
  1174 proof
  1175   fix y :: "'b \<times> 'd"
  1176   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1177   moreover
  1178   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1179   ultimately have "(fst y, snd y) = map_prod f g (a,b)" by auto
  1180   thus "\<exists>x. y = map_prod f g x" by auto
  1181 qed
  1182 
  1183 lemma map_prod_surj_on:
  1184   assumes "f ` A = A'" and "g ` B = B'"
  1185   shows "map_prod f g ` (A \<times> B) = A' \<times> B'"
  1186 unfolding image_def
  1187 proof(rule set_eqI,rule iffI)
  1188   fix x :: "'a \<times> 'c"
  1189   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_prod f g x}"
  1190   then obtain y where "y \<in> A \<times> B" and "x = map_prod f g y" by blast
  1191   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1192   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1193   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1194   with `x = map_prod f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1195 next
  1196   fix x :: "'a \<times> 'c"
  1197   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1198   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1199   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1200   moreover from `image g B = B'` and `snd x \<in> B'`
  1201   obtain b where "b \<in> B" and "snd x = g b" by auto
  1202   ultimately have "(fst x, snd x) = map_prod f g (a,b)" by auto
  1203   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1204   ultimately have "\<exists>y \<in> A \<times> B. x = map_prod f g y" by auto
  1205   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_prod f g y}" by auto
  1206 qed
  1207 
  1208 
  1209 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1210 
  1211 ML_file "Tools/set_comprehension_pointfree.ML"
  1212 
  1213 setup {*
  1214   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1215     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1216     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1217 *}
  1218 
  1219 
  1220 subsection {* Inductively defined sets *}
  1221 
  1222 ML_file "Tools/inductive_set.ML"
  1223 setup Inductive_Set.setup
  1224 
  1225 
  1226 subsection {* Legacy theorem bindings and duplicates *}
  1227 
  1228 lemma PairE:
  1229   obtains x y where "p = (x, y)"
  1230   by (fact prod.exhaust)
  1231 
  1232 lemmas Pair_eq = prod.inject
  1233 lemmas fst_conv = prod.sel(1)
  1234 lemmas snd_conv = prod.sel(2)
  1235 lemmas pair_collapse = prod.collapse
  1236 lemmas split = split_conv
  1237 lemmas Pair_fst_snd_eq = prod_eq_iff
  1238 
  1239 hide_const (open) prod
  1240 
  1241 end