src/HOL/Real_Vector_Spaces.thy
author wenzelm
Fri Mar 07 22:30:58 2014 +0100 (2014-03-07)
changeset 55990 41c6b99c5fb7
parent 55719 cdddd073bff8
child 56194 9ffbb4004c81
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult_commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult_commute)
   259 
   260 lemma nonzero_of_real_inverse:
   261   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   262    inverse (of_real x :: 'a::real_div_algebra)"
   263 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   264 
   265 lemma of_real_inverse [simp]:
   266   "of_real (inverse x) =
   267    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   268 by (simp add: of_real_def inverse_scaleR_distrib)
   269 
   270 lemma nonzero_of_real_divide:
   271   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   272    (of_real x / of_real y :: 'a::real_field)"
   273 by (simp add: divide_inverse nonzero_of_real_inverse)
   274 
   275 lemma of_real_divide [simp]:
   276   "of_real (x / y) =
   277    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   278 by (simp add: divide_inverse)
   279 
   280 lemma of_real_power [simp]:
   281   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   282 by (induct n) simp_all
   283 
   284 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   285 by (simp add: of_real_def)
   286 
   287 lemma inj_of_real:
   288   "inj of_real"
   289   by (auto intro: injI)
   290 
   291 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   292 
   293 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   294 proof
   295   fix r
   296   show "of_real r = id r"
   297     by (simp add: of_real_def)
   298 qed
   299 
   300 text{*Collapse nested embeddings*}
   301 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   302 by (induct n) auto
   303 
   304 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   305 by (cases z rule: int_diff_cases, simp)
   306 
   307 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   308 using of_real_of_int_eq [of "numeral w"] by simp
   309 
   310 lemma of_real_neg_numeral: "of_real (- numeral w) = - numeral w"
   311 using of_real_of_int_eq [of "- numeral w"] by simp
   312 
   313 text{*Every real algebra has characteristic zero*}
   314 
   315 instance real_algebra_1 < ring_char_0
   316 proof
   317   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   318   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   319 qed
   320 
   321 instance real_field < field_char_0 ..
   322 
   323 
   324 subsection {* The Set of Real Numbers *}
   325 
   326 definition Reals :: "'a::real_algebra_1 set" where
   327   "Reals = range of_real"
   328 
   329 notation (xsymbols)
   330   Reals  ("\<real>")
   331 
   332 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   333 by (simp add: Reals_def)
   334 
   335 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   336 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   337 
   338 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   339 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   340 
   341 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   342 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   343 
   344 lemma Reals_0 [simp]: "0 \<in> Reals"
   345 apply (unfold Reals_def)
   346 apply (rule range_eqI)
   347 apply (rule of_real_0 [symmetric])
   348 done
   349 
   350 lemma Reals_1 [simp]: "1 \<in> Reals"
   351 apply (unfold Reals_def)
   352 apply (rule range_eqI)
   353 apply (rule of_real_1 [symmetric])
   354 done
   355 
   356 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   357 apply (auto simp add: Reals_def)
   358 apply (rule range_eqI)
   359 apply (rule of_real_add [symmetric])
   360 done
   361 
   362 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   363 apply (auto simp add: Reals_def)
   364 apply (rule range_eqI)
   365 apply (rule of_real_minus [symmetric])
   366 done
   367 
   368 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   369 apply (auto simp add: Reals_def)
   370 apply (rule range_eqI)
   371 apply (rule of_real_diff [symmetric])
   372 done
   373 
   374 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   375 apply (auto simp add: Reals_def)
   376 apply (rule range_eqI)
   377 apply (rule of_real_mult [symmetric])
   378 done
   379 
   380 lemma nonzero_Reals_inverse:
   381   fixes a :: "'a::real_div_algebra"
   382   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   383 apply (auto simp add: Reals_def)
   384 apply (rule range_eqI)
   385 apply (erule nonzero_of_real_inverse [symmetric])
   386 done
   387 
   388 lemma Reals_inverse:
   389   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   390   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   391 apply (auto simp add: Reals_def)
   392 apply (rule range_eqI)
   393 apply (rule of_real_inverse [symmetric])
   394 done
   395 
   396 lemma Reals_inverse_iff [simp]: 
   397   fixes x:: "'a :: {real_div_algebra, division_ring_inverse_zero}"
   398   shows "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   399 by (metis Reals_inverse inverse_inverse_eq)
   400 
   401 lemma nonzero_Reals_divide:
   402   fixes a b :: "'a::real_field"
   403   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   404 apply (auto simp add: Reals_def)
   405 apply (rule range_eqI)
   406 apply (erule nonzero_of_real_divide [symmetric])
   407 done
   408 
   409 lemma Reals_divide [simp]:
   410   fixes a b :: "'a::{real_field, field_inverse_zero}"
   411   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   412 apply (auto simp add: Reals_def)
   413 apply (rule range_eqI)
   414 apply (rule of_real_divide [symmetric])
   415 done
   416 
   417 lemma Reals_power [simp]:
   418   fixes a :: "'a::{real_algebra_1}"
   419   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   420 apply (auto simp add: Reals_def)
   421 apply (rule range_eqI)
   422 apply (rule of_real_power [symmetric])
   423 done
   424 
   425 lemma Reals_cases [cases set: Reals]:
   426   assumes "q \<in> \<real>"
   427   obtains (of_real) r where "q = of_real r"
   428   unfolding Reals_def
   429 proof -
   430   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   431   then obtain r where "q = of_real r" ..
   432   then show thesis ..
   433 qed
   434 
   435 lemma setsum_in_Reals: assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setsum f s \<in> \<real>"
   436 proof (cases "finite s")
   437   case True then show ?thesis using assms
   438     by (induct s rule: finite_induct) auto
   439 next
   440   case False then show ?thesis using assms
   441     by (metis Reals_0 setsum_infinite)
   442 qed
   443 
   444 lemma setprod_in_Reals: assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setprod f s \<in> \<real>"
   445 proof (cases "finite s")
   446   case True then show ?thesis using assms
   447     by (induct s rule: finite_induct) auto
   448 next
   449   case False then show ?thesis using assms
   450     by (metis Reals_1 setprod_infinite)
   451 qed
   452 
   453 lemma Reals_induct [case_names of_real, induct set: Reals]:
   454   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   455   by (rule Reals_cases) auto
   456 
   457 subsection {* Ordered real vector spaces *}
   458 
   459 class ordered_real_vector = real_vector + ordered_ab_group_add +
   460   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   461   assumes scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   462 begin
   463 
   464 lemma scaleR_mono:
   465   "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   466 apply (erule scaleR_right_mono [THEN order_trans], assumption)
   467 apply (erule scaleR_left_mono, assumption)
   468 done
   469 
   470 lemma scaleR_mono':
   471   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   472   by (rule scaleR_mono) (auto intro: order.trans)
   473 
   474 lemma pos_le_divideRI:
   475   assumes "0 < c"
   476   assumes "c *\<^sub>R a \<le> b"
   477   shows "a \<le> b /\<^sub>R c"
   478 proof -
   479   from scaleR_left_mono[OF assms(2)] assms(1)
   480   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   481     by simp
   482   with assms show ?thesis
   483     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   484 qed
   485 
   486 lemma pos_le_divideR_eq:
   487   assumes "0 < c"
   488   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   489 proof rule
   490   assume "a \<le> b /\<^sub>R c"
   491   from scaleR_left_mono[OF this] assms
   492   have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   493     by simp
   494   with assms show "c *\<^sub>R a \<le> b"
   495     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   496 qed (rule pos_le_divideRI[OF assms])
   497 
   498 lemma scaleR_image_atLeastAtMost:
   499   "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   500   apply (auto intro!: scaleR_left_mono)
   501   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   502   apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   503   done
   504 
   505 end
   506 
   507 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   508   using scaleR_left_mono [of 0 x a]
   509   by simp
   510 
   511 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> (x::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   512   using scaleR_left_mono [of x 0 a] by simp
   513 
   514 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   515   using scaleR_right_mono [of a 0 x] by simp
   516 
   517 lemma split_scaleR_neg_le: "(0 \<le> a & x \<le> 0) | (a \<le> 0 & 0 \<le> x) \<Longrightarrow>
   518   a *\<^sub>R (x::'a::ordered_real_vector) \<le> 0"
   519   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   520 
   521 lemma le_add_iff1:
   522   fixes c d e::"'a::ordered_real_vector"
   523   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   524   by (simp add: algebra_simps)
   525 
   526 lemma le_add_iff2:
   527   fixes c d e::"'a::ordered_real_vector"
   528   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   529   by (simp add: algebra_simps)
   530 
   531 lemma scaleR_left_mono_neg:
   532   fixes a b::"'a::ordered_real_vector"
   533   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   534   apply (drule scaleR_left_mono [of _ _ "- c"])
   535   apply simp_all
   536   done
   537 
   538 lemma scaleR_right_mono_neg:
   539   fixes c::"'a::ordered_real_vector"
   540   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   541   apply (drule scaleR_right_mono [of _ _ "- c"])
   542   apply simp_all
   543   done
   544 
   545 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> (b::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   546 using scaleR_right_mono_neg [of a 0 b] by simp
   547 
   548 lemma split_scaleR_pos_le:
   549   fixes b::"'a::ordered_real_vector"
   550   shows "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   551   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   552 
   553 lemma zero_le_scaleR_iff:
   554   fixes b::"'a::ordered_real_vector"
   555   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0" (is "?lhs = ?rhs")
   556 proof cases
   557   assume "a \<noteq> 0"
   558   show ?thesis
   559   proof
   560     assume lhs: ?lhs
   561     {
   562       assume "0 < a"
   563       with lhs have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   564         by (intro scaleR_mono) auto
   565       hence ?rhs using `0 < a`
   566         by simp
   567     } moreover {
   568       assume "0 > a"
   569       with lhs have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   570         by (intro scaleR_mono) auto
   571       hence ?rhs using `0 > a`
   572         by simp
   573     } ultimately show ?rhs using `a \<noteq> 0` by arith
   574   qed (auto simp: not_le `a \<noteq> 0` intro!: split_scaleR_pos_le)
   575 qed simp
   576 
   577 lemma scaleR_le_0_iff:
   578   fixes b::"'a::ordered_real_vector"
   579   shows "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   580   by (insert zero_le_scaleR_iff [of "-a" b]) force
   581 
   582 lemma scaleR_le_cancel_left:
   583   fixes b::"'a::ordered_real_vector"
   584   shows "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   585   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   586     dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   587 
   588 lemma scaleR_le_cancel_left_pos:
   589   fixes b::"'a::ordered_real_vector"
   590   shows "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   591   by (auto simp: scaleR_le_cancel_left)
   592 
   593 lemma scaleR_le_cancel_left_neg:
   594   fixes b::"'a::ordered_real_vector"
   595   shows "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   596   by (auto simp: scaleR_le_cancel_left)
   597 
   598 lemma scaleR_left_le_one_le:
   599   fixes x::"'a::ordered_real_vector" and a::real
   600   shows "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   601   using scaleR_right_mono[of a 1 x] by simp
   602 
   603 
   604 subsection {* Real normed vector spaces *}
   605 
   606 class dist =
   607   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   608 
   609 class norm =
   610   fixes norm :: "'a \<Rightarrow> real"
   611 
   612 class sgn_div_norm = scaleR + norm + sgn +
   613   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   614 
   615 class dist_norm = dist + norm + minus +
   616   assumes dist_norm: "dist x y = norm (x - y)"
   617 
   618 class open_dist = "open" + dist +
   619   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   620 
   621 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   622   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   623   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   624   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   625 begin
   626 
   627 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   628 proof -
   629   have "0 = norm (x + -1 *\<^sub>R x)" 
   630     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   631   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   632   finally show ?thesis by simp
   633 qed
   634 
   635 end
   636 
   637 class real_normed_algebra = real_algebra + real_normed_vector +
   638   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   639 
   640 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   641   assumes norm_one [simp]: "norm 1 = 1"
   642 
   643 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   644   assumes norm_mult: "norm (x * y) = norm x * norm y"
   645 
   646 class real_normed_field = real_field + real_normed_div_algebra
   647 
   648 instance real_normed_div_algebra < real_normed_algebra_1
   649 proof
   650   fix x y :: 'a
   651   show "norm (x * y) \<le> norm x * norm y"
   652     by (simp add: norm_mult)
   653 next
   654   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   655     by (rule norm_mult)
   656   thus "norm (1::'a) = 1" by simp
   657 qed
   658 
   659 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   660 by simp
   661 
   662 lemma zero_less_norm_iff [simp]:
   663   fixes x :: "'a::real_normed_vector"
   664   shows "(0 < norm x) = (x \<noteq> 0)"
   665 by (simp add: order_less_le)
   666 
   667 lemma norm_not_less_zero [simp]:
   668   fixes x :: "'a::real_normed_vector"
   669   shows "\<not> norm x < 0"
   670 by (simp add: linorder_not_less)
   671 
   672 lemma norm_le_zero_iff [simp]:
   673   fixes x :: "'a::real_normed_vector"
   674   shows "(norm x \<le> 0) = (x = 0)"
   675 by (simp add: order_le_less)
   676 
   677 lemma norm_minus_cancel [simp]:
   678   fixes x :: "'a::real_normed_vector"
   679   shows "norm (- x) = norm x"
   680 proof -
   681   have "norm (- x) = norm (scaleR (- 1) x)"
   682     by (simp only: scaleR_minus_left scaleR_one)
   683   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   684     by (rule norm_scaleR)
   685   finally show ?thesis by simp
   686 qed
   687 
   688 lemma norm_minus_commute:
   689   fixes a b :: "'a::real_normed_vector"
   690   shows "norm (a - b) = norm (b - a)"
   691 proof -
   692   have "norm (- (b - a)) = norm (b - a)"
   693     by (rule norm_minus_cancel)
   694   thus ?thesis by simp
   695 qed
   696 
   697 lemma norm_triangle_ineq2:
   698   fixes a b :: "'a::real_normed_vector"
   699   shows "norm a - norm b \<le> norm (a - b)"
   700 proof -
   701   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   702     by (rule norm_triangle_ineq)
   703   thus ?thesis by simp
   704 qed
   705 
   706 lemma norm_triangle_ineq3:
   707   fixes a b :: "'a::real_normed_vector"
   708   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   709 apply (subst abs_le_iff)
   710 apply auto
   711 apply (rule norm_triangle_ineq2)
   712 apply (subst norm_minus_commute)
   713 apply (rule norm_triangle_ineq2)
   714 done
   715 
   716 lemma norm_triangle_ineq4:
   717   fixes a b :: "'a::real_normed_vector"
   718   shows "norm (a - b) \<le> norm a + norm b"
   719 proof -
   720   have "norm (a + - b) \<le> norm a + norm (- b)"
   721     by (rule norm_triangle_ineq)
   722   then show ?thesis by simp
   723 qed
   724 
   725 lemma norm_diff_ineq:
   726   fixes a b :: "'a::real_normed_vector"
   727   shows "norm a - norm b \<le> norm (a + b)"
   728 proof -
   729   have "norm a - norm (- b) \<le> norm (a - - b)"
   730     by (rule norm_triangle_ineq2)
   731   thus ?thesis by simp
   732 qed
   733 
   734 lemma norm_diff_triangle_ineq:
   735   fixes a b c d :: "'a::real_normed_vector"
   736   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   737 proof -
   738   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   739     by (simp add: algebra_simps)
   740   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   741     by (rule norm_triangle_ineq)
   742   finally show ?thesis .
   743 qed
   744 
   745 lemma norm_triangle_mono: 
   746   fixes a b :: "'a::real_normed_vector"
   747   shows "\<lbrakk>norm a \<le> r; norm b \<le> s\<rbrakk> \<Longrightarrow> norm (a + b) \<le> r + s"
   748 by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   749 
   750 lemma abs_norm_cancel [simp]:
   751   fixes a :: "'a::real_normed_vector"
   752   shows "\<bar>norm a\<bar> = norm a"
   753 by (rule abs_of_nonneg [OF norm_ge_zero])
   754 
   755 lemma norm_add_less:
   756   fixes x y :: "'a::real_normed_vector"
   757   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   758 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   759 
   760 lemma norm_mult_less:
   761   fixes x y :: "'a::real_normed_algebra"
   762   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   763 apply (rule order_le_less_trans [OF norm_mult_ineq])
   764 apply (simp add: mult_strict_mono')
   765 done
   766 
   767 lemma norm_of_real [simp]:
   768   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   769 unfolding of_real_def by simp
   770 
   771 lemma norm_numeral [simp]:
   772   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   773 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   774 
   775 lemma norm_neg_numeral [simp]:
   776   "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   777 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   778 
   779 lemma norm_of_int [simp]:
   780   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   781 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   782 
   783 lemma norm_of_nat [simp]:
   784   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   785 apply (subst of_real_of_nat_eq [symmetric])
   786 apply (subst norm_of_real, simp)
   787 done
   788 
   789 lemma nonzero_norm_inverse:
   790   fixes a :: "'a::real_normed_div_algebra"
   791   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   792 apply (rule inverse_unique [symmetric])
   793 apply (simp add: norm_mult [symmetric])
   794 done
   795 
   796 lemma norm_inverse:
   797   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   798   shows "norm (inverse a) = inverse (norm a)"
   799 apply (case_tac "a = 0", simp)
   800 apply (erule nonzero_norm_inverse)
   801 done
   802 
   803 lemma nonzero_norm_divide:
   804   fixes a b :: "'a::real_normed_field"
   805   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   806 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   807 
   808 lemma norm_divide:
   809   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   810   shows "norm (a / b) = norm a / norm b"
   811 by (simp add: divide_inverse norm_mult norm_inverse)
   812 
   813 lemma norm_power_ineq:
   814   fixes x :: "'a::{real_normed_algebra_1}"
   815   shows "norm (x ^ n) \<le> norm x ^ n"
   816 proof (induct n)
   817   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   818 next
   819   case (Suc n)
   820   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   821     by (rule norm_mult_ineq)
   822   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   823     using norm_ge_zero by (rule mult_left_mono)
   824   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   825     by simp
   826 qed
   827 
   828 lemma norm_power:
   829   fixes x :: "'a::{real_normed_div_algebra}"
   830   shows "norm (x ^ n) = norm x ^ n"
   831 by (induct n) (simp_all add: norm_mult)
   832 
   833 lemma setprod_norm:
   834   fixes f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
   835   shows "setprod (\<lambda>x. norm(f x)) A = norm (setprod f A)"
   836 proof (cases "finite A")
   837   case True then show ?thesis 
   838     by (induct A rule: finite_induct) (auto simp: norm_mult)
   839 next
   840   case False then show ?thesis
   841     by (metis norm_one setprod.infinite) 
   842 qed
   843 
   844 
   845 subsection {* Metric spaces *}
   846 
   847 class metric_space = open_dist +
   848   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   849   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   850 begin
   851 
   852 lemma dist_self [simp]: "dist x x = 0"
   853 by simp
   854 
   855 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   856 using dist_triangle2 [of x x y] by simp
   857 
   858 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   859 by (simp add: less_le)
   860 
   861 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   862 by (simp add: not_less)
   863 
   864 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   865 by (simp add: le_less)
   866 
   867 lemma dist_commute: "dist x y = dist y x"
   868 proof (rule order_antisym)
   869   show "dist x y \<le> dist y x"
   870     using dist_triangle2 [of x y x] by simp
   871   show "dist y x \<le> dist x y"
   872     using dist_triangle2 [of y x y] by simp
   873 qed
   874 
   875 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   876 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   877 
   878 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   879 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   880 
   881 lemma dist_triangle_alt:
   882   shows "dist y z <= dist x y + dist x z"
   883 by (rule dist_triangle3)
   884 
   885 lemma dist_pos_lt:
   886   shows "x \<noteq> y ==> 0 < dist x y"
   887 by (simp add: zero_less_dist_iff)
   888 
   889 lemma dist_nz:
   890   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   891 by (simp add: zero_less_dist_iff)
   892 
   893 lemma dist_triangle_le:
   894   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   895 by (rule order_trans [OF dist_triangle2])
   896 
   897 lemma dist_triangle_lt:
   898   shows "dist x z + dist y z < e ==> dist x y < e"
   899 by (rule le_less_trans [OF dist_triangle2])
   900 
   901 lemma dist_triangle_half_l:
   902   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   903 by (rule dist_triangle_lt [where z=y], simp)
   904 
   905 lemma dist_triangle_half_r:
   906   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   907 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   908 
   909 subclass topological_space
   910 proof
   911   have "\<exists>e::real. 0 < e"
   912     by (fast intro: zero_less_one)
   913   then show "open UNIV"
   914     unfolding open_dist by simp
   915 next
   916   fix S T assume "open S" "open T"
   917   then show "open (S \<inter> T)"
   918     unfolding open_dist
   919     apply clarify
   920     apply (drule (1) bspec)+
   921     apply (clarify, rename_tac r s)
   922     apply (rule_tac x="min r s" in exI, simp)
   923     done
   924 next
   925   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   926     unfolding open_dist by fast
   927 qed
   928 
   929 lemma open_ball: "open {y. dist x y < d}"
   930 proof (unfold open_dist, intro ballI)
   931   fix y assume *: "y \<in> {y. dist x y < d}"
   932   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   933     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   934 qed
   935 
   936 subclass first_countable_topology
   937 proof
   938   fix x 
   939   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   940   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
   941     fix S assume "open S" "x \<in> S"
   942     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
   943       by (auto simp: open_dist subset_eq dist_commute)
   944     moreover
   945     from e obtain i where "inverse (Suc i) < e"
   946       by (auto dest!: reals_Archimedean)
   947     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
   948       by auto
   949     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
   950       by blast
   951   qed (auto intro: open_ball)
   952 qed
   953 
   954 end
   955 
   956 instance metric_space \<subseteq> t2_space
   957 proof
   958   fix x y :: "'a::metric_space"
   959   assume xy: "x \<noteq> y"
   960   let ?U = "{y'. dist x y' < dist x y / 2}"
   961   let ?V = "{x'. dist y x' < dist x y / 2}"
   962   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
   963                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
   964   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
   965     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
   966     using open_ball[of _ "dist x y / 2"] by auto
   967   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   968     by blast
   969 qed
   970 
   971 text {* Every normed vector space is a metric space. *}
   972 
   973 instance real_normed_vector < metric_space
   974 proof
   975   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   976     unfolding dist_norm by simp
   977 next
   978   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
   979     unfolding dist_norm
   980     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
   981 qed
   982 
   983 subsection {* Class instances for real numbers *}
   984 
   985 instantiation real :: real_normed_field
   986 begin
   987 
   988 definition dist_real_def:
   989   "dist x y = \<bar>x - y\<bar>"
   990 
   991 definition open_real_def [code del]:
   992   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   993 
   994 definition real_norm_def [simp]:
   995   "norm r = \<bar>r\<bar>"
   996 
   997 instance
   998 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   999 apply (rule dist_real_def)
  1000 apply (rule open_real_def)
  1001 apply (simp add: sgn_real_def)
  1002 apply (rule abs_eq_0)
  1003 apply (rule abs_triangle_ineq)
  1004 apply (rule abs_mult)
  1005 apply (rule abs_mult)
  1006 done
  1007 
  1008 end
  1009 
  1010 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1011 
  1012 instance real :: linorder_topology
  1013 proof
  1014   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1015   proof (rule ext, safe)
  1016     fix S :: "real set" assume "open S"
  1017     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1018       unfolding open_real_def bchoice_iff ..
  1019     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1020       by (fastforce simp: dist_real_def)
  1021     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1022       apply (subst *)
  1023       apply (intro generate_topology_Union generate_topology.Int)
  1024       apply (auto intro: generate_topology.Basis)
  1025       done
  1026   next
  1027     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1028     moreover have "\<And>a::real. open {..<a}"
  1029       unfolding open_real_def dist_real_def
  1030     proof clarify
  1031       fix x a :: real assume "x < a"
  1032       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1033       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1034     qed
  1035     moreover have "\<And>a::real. open {a <..}"
  1036       unfolding open_real_def dist_real_def
  1037     proof clarify
  1038       fix x a :: real assume "a < x"
  1039       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1040       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1041     qed
  1042     ultimately show "open S"
  1043       by induct auto
  1044   qed
  1045 qed
  1046 
  1047 instance real :: linear_continuum_topology ..
  1048 
  1049 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1050 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1051 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1052 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1053 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1054 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1055 
  1056 subsection {* Extra type constraints *}
  1057 
  1058 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1059 
  1060 setup {* Sign.add_const_constraint
  1061   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1062 
  1063 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1064 
  1065 setup {* Sign.add_const_constraint
  1066   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1067 
  1068 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1069 
  1070 setup {* Sign.add_const_constraint
  1071   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1072 
  1073 subsection {* Sign function *}
  1074 
  1075 lemma norm_sgn:
  1076   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1077 by (simp add: sgn_div_norm)
  1078 
  1079 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1080 by (simp add: sgn_div_norm)
  1081 
  1082 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1083 by (simp add: sgn_div_norm)
  1084 
  1085 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1086 by (simp add: sgn_div_norm)
  1087 
  1088 lemma sgn_scaleR:
  1089   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1090 by (simp add: sgn_div_norm mult_ac)
  1091 
  1092 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1093 by (simp add: sgn_div_norm)
  1094 
  1095 lemma sgn_of_real:
  1096   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1097 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1098 
  1099 lemma sgn_mult:
  1100   fixes x y :: "'a::real_normed_div_algebra"
  1101   shows "sgn (x * y) = sgn x * sgn y"
  1102 by (simp add: sgn_div_norm norm_mult mult_commute)
  1103 
  1104 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1105 by (simp add: sgn_div_norm divide_inverse)
  1106 
  1107 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1108 unfolding real_sgn_eq by simp
  1109 
  1110 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1111 unfolding real_sgn_eq by simp
  1112 
  1113 lemma norm_conv_dist: "norm x = dist x 0"
  1114   unfolding dist_norm by simp
  1115 
  1116 subsection {* Bounded Linear and Bilinear Operators *}
  1117 
  1118 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1119   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1120 
  1121 lemma linearI:
  1122   assumes "\<And>x y. f (x + y) = f x + f y"
  1123   assumes "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1124   shows "linear f"
  1125   by default (rule assms)+
  1126 
  1127 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1128   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1129 begin
  1130 
  1131 lemma pos_bounded:
  1132   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1133 proof -
  1134   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1135     using bounded by fast
  1136   show ?thesis
  1137   proof (intro exI impI conjI allI)
  1138     show "0 < max 1 K"
  1139       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1140   next
  1141     fix x
  1142     have "norm (f x) \<le> norm x * K" using K .
  1143     also have "\<dots> \<le> norm x * max 1 K"
  1144       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1145     finally show "norm (f x) \<le> norm x * max 1 K" .
  1146   qed
  1147 qed
  1148 
  1149 lemma nonneg_bounded:
  1150   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1151 proof -
  1152   from pos_bounded
  1153   show ?thesis by (auto intro: order_less_imp_le)
  1154 qed
  1155 
  1156 end
  1157 
  1158 lemma bounded_linear_intro:
  1159   assumes "\<And>x y. f (x + y) = f x + f y"
  1160   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1161   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1162   shows "bounded_linear f"
  1163   by default (fast intro: assms)+
  1164 
  1165 locale bounded_bilinear =
  1166   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1167                  \<Rightarrow> 'c::real_normed_vector"
  1168     (infixl "**" 70)
  1169   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1170   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1171   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1172   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1173   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1174 begin
  1175 
  1176 lemma pos_bounded:
  1177   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1178 apply (cut_tac bounded, erule exE)
  1179 apply (rule_tac x="max 1 K" in exI, safe)
  1180 apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1181 apply (drule spec, drule spec, erule order_trans)
  1182 apply (rule mult_left_mono [OF max.cobounded2])
  1183 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1184 done
  1185 
  1186 lemma nonneg_bounded:
  1187   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1188 proof -
  1189   from pos_bounded
  1190   show ?thesis by (auto intro: order_less_imp_le)
  1191 qed
  1192 
  1193 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1194 by (rule additive.intro, rule add_right)
  1195 
  1196 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1197 by (rule additive.intro, rule add_left)
  1198 
  1199 lemma zero_left: "prod 0 b = 0"
  1200 by (rule additive.zero [OF additive_left])
  1201 
  1202 lemma zero_right: "prod a 0 = 0"
  1203 by (rule additive.zero [OF additive_right])
  1204 
  1205 lemma minus_left: "prod (- a) b = - prod a b"
  1206 by (rule additive.minus [OF additive_left])
  1207 
  1208 lemma minus_right: "prod a (- b) = - prod a b"
  1209 by (rule additive.minus [OF additive_right])
  1210 
  1211 lemma diff_left:
  1212   "prod (a - a') b = prod a b - prod a' b"
  1213 by (rule additive.diff [OF additive_left])
  1214 
  1215 lemma diff_right:
  1216   "prod a (b - b') = prod a b - prod a b'"
  1217 by (rule additive.diff [OF additive_right])
  1218 
  1219 lemma bounded_linear_left:
  1220   "bounded_linear (\<lambda>a. a ** b)"
  1221 apply (cut_tac bounded, safe)
  1222 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1223 apply (rule add_left)
  1224 apply (rule scaleR_left)
  1225 apply (simp add: mult_ac)
  1226 done
  1227 
  1228 lemma bounded_linear_right:
  1229   "bounded_linear (\<lambda>b. a ** b)"
  1230 apply (cut_tac bounded, safe)
  1231 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1232 apply (rule add_right)
  1233 apply (rule scaleR_right)
  1234 apply (simp add: mult_ac)
  1235 done
  1236 
  1237 lemma prod_diff_prod:
  1238   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1239 by (simp add: diff_left diff_right)
  1240 
  1241 end
  1242 
  1243 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1244   by default (auto intro!: exI[of _ 1])
  1245 
  1246 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1247   by default (auto intro!: exI[of _ 1])
  1248 
  1249 lemma bounded_linear_add:
  1250   assumes "bounded_linear f"
  1251   assumes "bounded_linear g"
  1252   shows "bounded_linear (\<lambda>x. f x + g x)"
  1253 proof -
  1254   interpret f: bounded_linear f by fact
  1255   interpret g: bounded_linear g by fact
  1256   show ?thesis
  1257   proof
  1258     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1259     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1260     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1261       using add_mono[OF Kf Kg]
  1262       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1263   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1264 qed
  1265 
  1266 lemma bounded_linear_minus:
  1267   assumes "bounded_linear f"
  1268   shows "bounded_linear (\<lambda>x. - f x)"
  1269 proof -
  1270   interpret f: bounded_linear f by fact
  1271   show ?thesis apply (unfold_locales)
  1272     apply (simp add: f.add)
  1273     apply (simp add: f.scaleR)
  1274     apply (simp add: f.bounded)
  1275     done
  1276 qed
  1277 
  1278 lemma bounded_linear_compose:
  1279   assumes "bounded_linear f"
  1280   assumes "bounded_linear g"
  1281   shows "bounded_linear (\<lambda>x. f (g x))"
  1282 proof -
  1283   interpret f: bounded_linear f by fact
  1284   interpret g: bounded_linear g by fact
  1285   show ?thesis proof (unfold_locales)
  1286     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1287       by (simp only: f.add g.add)
  1288   next
  1289     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1290       by (simp only: f.scaleR g.scaleR)
  1291   next
  1292     from f.pos_bounded
  1293     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1294     from g.pos_bounded
  1295     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1296     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1297     proof (intro exI allI)
  1298       fix x
  1299       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1300         using f .
  1301       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1302         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1303       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1304         by (rule mult_assoc)
  1305       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1306     qed
  1307   qed
  1308 qed
  1309 
  1310 lemma bounded_bilinear_mult:
  1311   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1312 apply (rule bounded_bilinear.intro)
  1313 apply (rule distrib_right)
  1314 apply (rule distrib_left)
  1315 apply (rule mult_scaleR_left)
  1316 apply (rule mult_scaleR_right)
  1317 apply (rule_tac x="1" in exI)
  1318 apply (simp add: norm_mult_ineq)
  1319 done
  1320 
  1321 lemma bounded_linear_mult_left:
  1322   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1323   using bounded_bilinear_mult
  1324   by (rule bounded_bilinear.bounded_linear_left)
  1325 
  1326 lemma bounded_linear_mult_right:
  1327   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1328   using bounded_bilinear_mult
  1329   by (rule bounded_bilinear.bounded_linear_right)
  1330 
  1331 lemmas bounded_linear_mult_const =
  1332   bounded_linear_mult_left [THEN bounded_linear_compose]
  1333 
  1334 lemmas bounded_linear_const_mult =
  1335   bounded_linear_mult_right [THEN bounded_linear_compose]
  1336 
  1337 lemma bounded_linear_divide:
  1338   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1339   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1340 
  1341 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1342 apply (rule bounded_bilinear.intro)
  1343 apply (rule scaleR_left_distrib)
  1344 apply (rule scaleR_right_distrib)
  1345 apply simp
  1346 apply (rule scaleR_left_commute)
  1347 apply (rule_tac x="1" in exI, simp)
  1348 done
  1349 
  1350 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1351   using bounded_bilinear_scaleR
  1352   by (rule bounded_bilinear.bounded_linear_left)
  1353 
  1354 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1355   using bounded_bilinear_scaleR
  1356   by (rule bounded_bilinear.bounded_linear_right)
  1357 
  1358 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1359   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1360 
  1361 lemma real_bounded_linear:
  1362   fixes f :: "real \<Rightarrow> real"
  1363   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1364 proof -
  1365   { fix x assume "bounded_linear f"
  1366     then interpret bounded_linear f .
  1367     from scaleR[of x 1] have "f x = x * f 1"
  1368       by simp }
  1369   then show ?thesis
  1370     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1371 qed
  1372 
  1373 instance real_normed_algebra_1 \<subseteq> perfect_space
  1374 proof
  1375   fix x::'a
  1376   show "\<not> open {x}"
  1377     unfolding open_dist dist_norm
  1378     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1379 qed
  1380 
  1381 subsection {* Filters and Limits on Metric Space *}
  1382 
  1383 lemma eventually_nhds_metric:
  1384   fixes a :: "'a :: metric_space"
  1385   shows "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1386 unfolding eventually_nhds open_dist
  1387 apply safe
  1388 apply fast
  1389 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
  1390 apply clarsimp
  1391 apply (rule_tac x="d - dist x a" in exI, clarsimp)
  1392 apply (simp only: less_diff_eq)
  1393 apply (erule le_less_trans [OF dist_triangle])
  1394 done
  1395 
  1396 lemma eventually_at:
  1397   fixes a :: "'a :: metric_space"
  1398   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1399   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1400 
  1401 lemma eventually_at_le:
  1402   fixes a :: "'a::metric_space"
  1403   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1404   unfolding eventually_at_filter eventually_nhds_metric
  1405   apply auto
  1406   apply (rule_tac x="d / 2" in exI)
  1407   apply auto
  1408   done
  1409 
  1410 lemma tendstoI:
  1411   fixes l :: "'a :: metric_space"
  1412   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1413   shows "(f ---> l) F"
  1414   apply (rule topological_tendstoI)
  1415   apply (simp add: open_dist)
  1416   apply (drule (1) bspec, clarify)
  1417   apply (drule assms)
  1418   apply (erule eventually_elim1, simp)
  1419   done
  1420 
  1421 lemma tendstoD:
  1422   fixes l :: "'a :: metric_space"
  1423   shows "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1424   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
  1425   apply (clarsimp simp add: open_dist)
  1426   apply (rule_tac x="e - dist x l" in exI, clarsimp)
  1427   apply (simp only: less_diff_eq)
  1428   apply (erule le_less_trans [OF dist_triangle])
  1429   apply simp
  1430   apply simp
  1431   done
  1432 
  1433 lemma tendsto_iff:
  1434   fixes l :: "'a :: metric_space"
  1435   shows "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1436   using tendstoI tendstoD by fast
  1437 
  1438 lemma metric_tendsto_imp_tendsto:
  1439   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1440   assumes f: "(f ---> a) F"
  1441   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1442   shows "(g ---> b) F"
  1443 proof (rule tendstoI)
  1444   fix e :: real assume "0 < e"
  1445   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1446   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1447     using le_less_trans by (rule eventually_elim2)
  1448 qed
  1449 
  1450 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1451   unfolding filterlim_at_top
  1452   apply (intro allI)
  1453   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1454   apply (auto simp: natceiling_le_eq)
  1455   done
  1456 
  1457 subsubsection {* Limits of Sequences *}
  1458 
  1459 lemma LIMSEQ_def: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1460   unfolding tendsto_iff eventually_sequentially ..
  1461 
  1462 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1463   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
  1464 
  1465 lemma metric_LIMSEQ_I:
  1466   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1467 by (simp add: LIMSEQ_def)
  1468 
  1469 lemma metric_LIMSEQ_D:
  1470   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1471 by (simp add: LIMSEQ_def)
  1472 
  1473 
  1474 subsubsection {* Limits of Functions *}
  1475 
  1476 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1477      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1478         --> dist (f x) L < r)"
  1479   unfolding tendsto_iff eventually_at by simp
  1480 
  1481 lemma metric_LIM_I:
  1482   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1483     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1484 by (simp add: LIM_def)
  1485 
  1486 lemma metric_LIM_D:
  1487   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1488     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1489 by (simp add: LIM_def)
  1490 
  1491 lemma metric_LIM_imp_LIM:
  1492   assumes f: "f -- a --> (l::'a::metric_space)"
  1493   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1494   shows "g -- a --> (m::'b::metric_space)"
  1495   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1496 
  1497 lemma metric_LIM_equal2:
  1498   assumes 1: "0 < R"
  1499   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1500   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1501 apply (rule topological_tendstoI)
  1502 apply (drule (2) topological_tendstoD)
  1503 apply (simp add: eventually_at, safe)
  1504 apply (rule_tac x="min d R" in exI, safe)
  1505 apply (simp add: 1)
  1506 apply (simp add: 2)
  1507 done
  1508 
  1509 lemma metric_LIM_compose2:
  1510   assumes f: "f -- (a::'a::metric_space) --> b"
  1511   assumes g: "g -- b --> c"
  1512   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1513   shows "(\<lambda>x. g (f x)) -- a --> c"
  1514   using inj
  1515   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1516 
  1517 lemma metric_isCont_LIM_compose2:
  1518   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1519   assumes f [unfolded isCont_def]: "isCont f a"
  1520   assumes g: "g -- f a --> l"
  1521   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1522   shows "(\<lambda>x. g (f x)) -- a --> l"
  1523 by (rule metric_LIM_compose2 [OF f g inj])
  1524 
  1525 subsection {* Complete metric spaces *}
  1526 
  1527 subsection {* Cauchy sequences *}
  1528 
  1529 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1530   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1531 
  1532 subsection {* Cauchy Sequences *}
  1533 
  1534 lemma metric_CauchyI:
  1535   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1536   by (simp add: Cauchy_def)
  1537 
  1538 lemma metric_CauchyD:
  1539   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1540   by (simp add: Cauchy_def)
  1541 
  1542 lemma metric_Cauchy_iff2:
  1543   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1544 apply (simp add: Cauchy_def, auto)
  1545 apply (drule reals_Archimedean, safe)
  1546 apply (drule_tac x = n in spec, auto)
  1547 apply (rule_tac x = M in exI, auto)
  1548 apply (drule_tac x = m in spec, simp)
  1549 apply (drule_tac x = na in spec, auto)
  1550 done
  1551 
  1552 lemma Cauchy_iff2:
  1553   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1554   unfolding metric_Cauchy_iff2 dist_real_def ..
  1555 
  1556 lemma Cauchy_subseq_Cauchy:
  1557   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1558 apply (auto simp add: Cauchy_def)
  1559 apply (drule_tac x=e in spec, clarify)
  1560 apply (rule_tac x=M in exI, clarify)
  1561 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1562 done
  1563 
  1564 theorem LIMSEQ_imp_Cauchy:
  1565   assumes X: "X ----> a" shows "Cauchy X"
  1566 proof (rule metric_CauchyI)
  1567   fix e::real assume "0 < e"
  1568   hence "0 < e/2" by simp
  1569   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1570   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1571   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1572   proof (intro exI allI impI)
  1573     fix m assume "N \<le> m"
  1574     hence m: "dist (X m) a < e/2" using N by fast
  1575     fix n assume "N \<le> n"
  1576     hence n: "dist (X n) a < e/2" using N by fast
  1577     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1578       by (rule dist_triangle2)
  1579     also from m n have "\<dots> < e" by simp
  1580     finally show "dist (X m) (X n) < e" .
  1581   qed
  1582 qed
  1583 
  1584 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1585 unfolding convergent_def
  1586 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1587 
  1588 subsubsection {* Cauchy Sequences are Convergent *}
  1589 
  1590 class complete_space = metric_space +
  1591   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1592 
  1593 lemma Cauchy_convergent_iff:
  1594   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1595   shows "Cauchy X = convergent X"
  1596 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1597 
  1598 subsection {* The set of real numbers is a complete metric space *}
  1599 
  1600 text {*
  1601 Proof that Cauchy sequences converge based on the one from
  1602 @{url "http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html"}
  1603 *}
  1604 
  1605 text {*
  1606   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1607   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1608 *}
  1609 
  1610 lemma increasing_LIMSEQ:
  1611   fixes f :: "nat \<Rightarrow> real"
  1612   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1613       and bdd: "\<And>n. f n \<le> l"
  1614       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1615   shows "f ----> l"
  1616 proof (rule increasing_tendsto)
  1617   fix x assume "x < l"
  1618   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1619     by auto
  1620   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1621     by (auto simp: field_simps)
  1622   with `e < l - x` `0 < e` have "x < f n" by simp
  1623   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1624     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1625 qed (insert bdd, auto)
  1626 
  1627 lemma real_Cauchy_convergent:
  1628   fixes X :: "nat \<Rightarrow> real"
  1629   assumes X: "Cauchy X"
  1630   shows "convergent X"
  1631 proof -
  1632   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1633   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1634 
  1635   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1636   fix y::real assume "y \<in> S"
  1637   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1638     by (simp add: S_def)
  1639   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1640   hence "y < X (max M N)" by simp
  1641   also have "\<dots> < x" using N by simp
  1642   finally have "y \<le> x"
  1643     by (rule order_less_imp_le) }
  1644   note bound_isUb = this 
  1645 
  1646   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1647     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1648   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1649   have [simp]: "S \<noteq> {}"
  1650   proof (intro exI ex_in_conv[THEN iffD1])
  1651     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1652       by (simp add: abs_diff_less_iff dist_real_def)
  1653     thus "X N - 1 \<in> S" by (rule mem_S)
  1654   qed
  1655   have [simp]: "bdd_above S"
  1656   proof
  1657     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1658       by (simp add: abs_diff_less_iff dist_real_def)
  1659     thus "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  1660       by (rule bound_isUb)
  1661   qed
  1662   have "X ----> Sup S"
  1663   proof (rule metric_LIMSEQ_I)
  1664   fix r::real assume "0 < r"
  1665   hence r: "0 < r/2" by simp
  1666   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1667     using metric_CauchyD [OF X r] by auto
  1668   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1669   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1670     by (simp only: dist_real_def abs_diff_less_iff)
  1671 
  1672   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1673   hence "X N - r/2 \<in> S" by (rule mem_S)
  1674   hence 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  1675 
  1676   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1677   from bound_isUb[OF this]
  1678   have 2: "Sup S \<le> X N + r/2"
  1679     by (intro cSup_least) simp_all
  1680 
  1681   show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  1682   proof (intro exI allI impI)
  1683     fix n assume n: "N \<le> n"
  1684     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1685     thus "dist (X n) (Sup S) < r" using 1 2
  1686       by (simp add: abs_diff_less_iff dist_real_def)
  1687   qed
  1688   qed
  1689   then show ?thesis unfolding convergent_def by auto
  1690 qed
  1691 
  1692 instance real :: complete_space
  1693   by intro_classes (rule real_Cauchy_convergent)
  1694 
  1695 class banach = real_normed_vector + complete_space
  1696 
  1697 instance real :: banach by default
  1698 
  1699 lemma tendsto_at_topI_sequentially:
  1700   fixes f :: "real \<Rightarrow> real"
  1701   assumes mono: "mono f"
  1702   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1703   shows "(f ---> y) at_top"
  1704 proof (rule tendstoI)
  1705   fix e :: real assume "0 < e"
  1706   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1707     by (auto simp: LIMSEQ_def dist_real_def)
  1708   { fix x :: real
  1709     obtain n where "x \<le> real_of_nat n"
  1710       using ex_le_of_nat[of x] ..
  1711     note monoD[OF mono this]
  1712     also have "f (real_of_nat n) \<le> y"
  1713       by (rule LIMSEQ_le_const[OF limseq])
  1714          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1715     finally have "f x \<le> y" . }
  1716   note le = this
  1717   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1718     by (rule eventually_ge_at_top)
  1719   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1720   proof eventually_elim
  1721     fix x assume N': "real N \<le> x"
  1722     with N[of N] le have "y - f (real N) < e" by auto
  1723     moreover note monoD[OF mono N']
  1724     ultimately show "dist (f x) y < e"
  1725       using le[of x] by (auto simp: dist_real_def field_simps)
  1726   qed
  1727 qed
  1728 
  1729 end