src/HOL/Tools/ATP/atp_proof.ML
author blanchet
Tue Nov 07 15:16:41 2017 +0100 (17 months ago)
changeset 67021 41f1f8c4259b
parent 66545 97c441c8665d
child 67022 49309fe530fd
permissions -rw-r--r--
integrated Leo-III in Sledgehammer (thanks to Alexander Steen for the patch)
     1 (*  Title:      HOL/Tools/ATP/atp_proof.ML
     2     Author:     Lawrence C. Paulson, Cambridge University Computer Laboratory
     3     Author:     Claire Quigley, Cambridge University Computer Laboratory
     4     Author:     Jasmin Blanchette, TU Muenchen
     5     Author:     Mathias Fleury, ENS Rennes
     6 
     7 Abstract representation of ATP proofs and TSTP/SPASS syntax.
     8 *)
     9 
    10 signature ATP_PROOF =
    11 sig
    12   type 'a atp_type = 'a ATP_Problem.atp_type
    13   type ('a, 'b) atp_term = ('a, 'b) ATP_Problem.atp_term
    14   type atp_formula_role = ATP_Problem.atp_formula_role
    15   type ('a, 'b, 'c, 'd) atp_formula = ('a, 'b, 'c, 'd) ATP_Problem.atp_formula
    16   type 'a atp_problem = 'a ATP_Problem.atp_problem
    17 
    18   exception UNRECOGNIZED_ATP_PROOF of unit
    19 
    20   datatype atp_failure =
    21     MaybeUnprovable |
    22     Unprovable |
    23     GaveUp |
    24     ProofMissing |
    25     ProofIncomplete |
    26     ProofUnparsable |
    27     UnsoundProof of bool * string list |
    28     CantConnect |
    29     TimedOut |
    30     Inappropriate |
    31     OutOfResources |
    32     NoPerl |
    33     NoLibwwwPerl |
    34     MalformedInput |
    35     MalformedOutput |
    36     Interrupted |
    37     Crashed |
    38     InternalError |
    39     UnknownError of string
    40 
    41   type atp_step_name = string * string list
    42   type ('a, 'b) atp_step =
    43     atp_step_name * atp_formula_role * 'a * 'b * atp_step_name list
    44 
    45   type 'a atp_proof = (('a, 'a, ('a, 'a atp_type) atp_term, 'a) atp_formula, string) atp_step list
    46 
    47   (* Named ATPs *)
    48   val agsyholN : string
    49   val alt_ergoN : string
    50   val dummy_thfN : string
    51   val dummy_thf_mlN : string
    52   val eN : string
    53   val e_malesN : string
    54   val e_parN : string
    55   val e_sineN : string
    56   val e_tofofN : string
    57   val iproverN : string
    58   val iprover_eqN : string
    59   val leo2N : string
    60   val leo3N : string
    61   val pirateN : string
    62   val satallaxN : string
    63   val snarkN : string
    64   val spassN : string
    65   val vampireN : string
    66   val waldmeisterN : string
    67   val waldmeister_newN : string
    68   val z3_tptpN : string
    69   val zipperpositionN : string
    70   val remote_prefix : string
    71 
    72   val agsyhol_core_rule : string
    73   val spass_input_rule : string
    74   val spass_pre_skolemize_rule : string
    75   val spass_skolemize_rule : string
    76   val z3_tptp_core_rule : string
    77 
    78   val short_output : bool -> string -> string
    79   val string_of_atp_failure : atp_failure -> string
    80   val extract_important_message : string -> string
    81   val extract_known_atp_failure : (atp_failure * string) list -> string -> atp_failure option
    82   val extract_tstplike_proof_and_outcome :
    83     bool -> (string * string) list -> (atp_failure * string) list -> string
    84     -> string * atp_failure option
    85   val is_same_atp_step : atp_step_name -> atp_step_name -> bool
    86   val scan_general_id : string list -> string * string list
    87   val parse_formula : string list ->
    88     (string, string atp_type, (string, string atp_type) atp_term, string) atp_formula * string list
    89   val clean_up_atp_proof_dependencies : string atp_proof -> string atp_proof
    90   val map_term_names_in_atp_proof : (string -> string) -> string atp_proof -> string atp_proof
    91   val nasty_atp_proof : string Symtab.table -> string atp_proof -> string atp_proof
    92 
    93   val skip_term: string list -> string * string list
    94   val parse_thf0_formula :string list ->
    95     ('a, 'b, (string, string ATP_Problem.atp_type) ATP_Problem.atp_term, 'c) ATP_Problem.atp_formula *
    96     string list
    97   val dummy_atype : string ATP_Problem.atp_type
    98   val role_of_tptp_string: string -> ATP_Problem.atp_formula_role
    99   val parse_line: string -> ('a * string ATP_Problem.atp_problem_line list) list ->
   100     string list -> ((string * string list) * ATP_Problem.atp_formula_role *
   101     (string, 'b, (string, string ATP_Problem.atp_type) ATP_Problem.atp_term,
   102       'c) ATP_Problem.atp_formula
   103     * string * (string * 'd list) list) list * string list
   104   val core_inference : 'a -> 'b -> ('b * 'b list) * ATP_Problem.atp_formula_role *
   105     ('c, 'd, (string, 'e) ATP_Problem.atp_term, 'f) ATP_Problem.atp_formula * 'a * 'g list
   106   val vampire_step_name_ord : (string * 'a) * (string * 'a) -> order
   107   val core_of_agsyhol_proof :  string -> string list option
   108 end;
   109 
   110 structure ATP_Proof : ATP_PROOF =
   111 struct
   112 
   113 open ATP_Util
   114 open ATP_Problem
   115 
   116 (* Named ATPs *)
   117 
   118 val agsyholN = "agsyhol"
   119 val alt_ergoN = "alt_ergo"
   120 val dummy_thfN = "dummy_thf" (* for experiments *)
   121 val dummy_thf_mlN = "dummy_thf_ml" (* for experiments *)
   122 val eN = "e"
   123 val e_malesN = "e_males"
   124 val e_parN = "e_par"
   125 val e_sineN = "e_sine"
   126 val e_tofofN = "e_tofof"
   127 val iproverN = "iprover"
   128 val iprover_eqN = "iprover_eq"
   129 val leo2N = "leo2"
   130 val leo3N = "leo3"
   131 val pirateN = "pirate"
   132 val satallaxN = "satallax"
   133 val snarkN = "snark"
   134 val spassN = "spass"
   135 val vampireN = "vampire"
   136 val waldmeisterN = "waldmeister"
   137 val waldmeister_newN = "waldmeister_new"
   138 val z3_tptpN = "z3_tptp"
   139 val zipperpositionN = "zipperposition"
   140 val remote_prefix = "remote_"
   141 
   142 val agsyhol_core_rule = "__agsyhol_core" (* arbitrary *)
   143 val spass_input_rule = "Inp"
   144 val spass_pre_skolemize_rule = "__Sko0" (* arbitrary *)
   145 val spass_skolemize_rule = "__Sko" (* arbitrary *)
   146 val z3_tptp_core_rule = "__z3_tptp_core" (* arbitrary *)
   147 
   148 exception UNRECOGNIZED_ATP_PROOF of unit
   149 
   150 datatype atp_failure =
   151   MaybeUnprovable |
   152   Unprovable |
   153   GaveUp |
   154   ProofMissing |
   155   ProofIncomplete |
   156   ProofUnparsable |
   157   UnsoundProof of bool * string list |
   158   CantConnect |
   159   TimedOut |
   160   Inappropriate |
   161   OutOfResources |
   162   NoPerl |
   163   NoLibwwwPerl |
   164   MalformedInput |
   165   MalformedOutput |
   166   Interrupted |
   167   Crashed |
   168   InternalError |
   169   UnknownError of string
   170 
   171 fun short_output verbose output =
   172   if verbose then
   173     if output = "" then "No details available" else elide_string 1000 output
   174   else
   175     ""
   176 
   177 val missing_message_tail =
   178   " appears to be missing; you will need to install it if you want to invoke \
   179   \remote provers"
   180 
   181 fun from_lemmas [] = ""
   182   | from_lemmas ss = " from " ^ space_implode " " (Try.serial_commas "and" (map quote ss))
   183 
   184 fun string_of_atp_failure MaybeUnprovable = "The generated problem is maybe unprovable"
   185   | string_of_atp_failure Unprovable = "The generated problem is unprovable"
   186   | string_of_atp_failure GaveUp = "The prover gave up"
   187   | string_of_atp_failure ProofMissing =
   188     "The prover claims the conjecture is a theorem but did not provide a proof"
   189   | string_of_atp_failure ProofIncomplete =
   190     "The prover claims the conjecture is a theorem but provided an incomplete proof"
   191   | string_of_atp_failure ProofUnparsable =
   192     "The prover claims the conjecture is a theorem but provided an unparsable proof"
   193   | string_of_atp_failure (UnsoundProof (false, ss)) =
   194     "The prover derived \"False\"" ^ from_lemmas ss ^
   195     "; specify a sound type encoding or omit the \"type_enc\" option"
   196   | string_of_atp_failure (UnsoundProof (true, ss)) =
   197     "The prover derived \"False\"" ^ from_lemmas ss ^
   198     ", which could be due to a bug in Sledgehammer or to inconsistent axioms (including \"sorry\"s)"
   199   | string_of_atp_failure CantConnect = "Cannot connect to server"
   200   | string_of_atp_failure TimedOut = "Timed out"
   201   | string_of_atp_failure Inappropriate =
   202     "The generated problem lies outside the prover's scope"
   203   | string_of_atp_failure OutOfResources = "The prover ran out of resources"
   204   | string_of_atp_failure NoPerl = "Perl" ^ missing_message_tail
   205   | string_of_atp_failure NoLibwwwPerl =
   206     "The Perl module \"libwww-perl\"" ^ missing_message_tail
   207   | string_of_atp_failure MalformedInput = "The generated problem is malformed"
   208   | string_of_atp_failure MalformedOutput = "The prover output is malformed"
   209   | string_of_atp_failure Interrupted = "The prover was interrupted"
   210   | string_of_atp_failure Crashed = "The prover crashed"
   211   | string_of_atp_failure InternalError = "An internal prover error occurred"
   212   | string_of_atp_failure (UnknownError s) =
   213     "A prover error occurred" ^
   214     (if s = "" then " (pass the \"verbose\" option for details)" else ":\n" ^ s)
   215 
   216 fun extract_delimited (begin_delim, end_delim) output =
   217   (case first_field begin_delim output of
   218     SOME (_, tail) =>
   219     (case first_field "\n" tail of
   220       SOME (_, tail') =>
   221       if end_delim = "" then
   222         tail'
   223       else
   224         (case first_field end_delim tail' of
   225           SOME (body, _) => body
   226         | NONE => "")
   227     | NONE => "")
   228   | NONE => "")
   229 
   230 val tstp_important_message_delims =
   231   ("% SZS start RequiredInformation", "% SZS end RequiredInformation")
   232 
   233 fun extract_important_message output =
   234   (case extract_delimited tstp_important_message_delims output of
   235     "" => ""
   236   | s => s |> space_explode "\n" |> filter_out (curry (op =) "")
   237            |> map (perhaps (try (unprefix "%")))
   238            |> map (perhaps (try (unprefix " ")))
   239            |> space_implode "\n " |> quote)
   240 
   241 (* Splits by the first possible of a list of delimiters. *)
   242 fun extract_tstplike_proof delims output =
   243   (case apply2 (find_first (fn s => String.isSubstring s output)) (ListPair.unzip delims) of
   244     (SOME begin_delim, SOME end_delim) => extract_delimited (begin_delim, end_delim) output
   245   | _ => "")
   246 
   247 fun extract_known_atp_failure known_failures output =
   248   known_failures
   249   |> find_first (fn (_, pattern) => String.isSubstring pattern output)
   250   |> Option.map fst
   251 
   252 fun extract_tstplike_proof_and_outcome verbose proof_delims known_failures output =
   253   (case (extract_tstplike_proof proof_delims output,
   254       extract_known_atp_failure known_failures output) of
   255     (_, SOME ProofIncomplete) => ("", NONE)
   256   | (_, SOME ProofUnparsable) => ("", NONE)
   257   | ("", SOME ProofMissing) => ("", NONE)
   258   | ("", NONE) => ("", SOME (UnknownError (short_output verbose output)))
   259   | res as ("", _) => res
   260   | (tstplike_proof, _) => (tstplike_proof, NONE))
   261 
   262 type atp_step_name = string * string list
   263 
   264 fun is_same_atp_step (s1, _) (s2, _) = s1 = s2
   265 
   266 val vampire_fact_prefix = "f"
   267 
   268 fun vampire_step_name_ord p =
   269   let val q = apply2 fst p in
   270     (* The "unprefix" part is to cope with Vampire's output. *)
   271     (case apply2 (Int.fromString o perhaps (try (unprefix vampire_fact_prefix))) q of
   272       (SOME i, SOME j) => int_ord (i, j)
   273     | _ => raise Fail "not Vampire")
   274   end
   275 
   276 type ('a, 'b) atp_step = atp_step_name * atp_formula_role * 'a * 'b * atp_step_name list
   277 
   278 type 'a atp_proof = (('a, 'a, ('a, 'a atp_type) atp_term, 'a) atp_formula, string) atp_step list
   279 
   280 (**** PARSING OF TSTP FORMAT ****)
   281 
   282 (* Strings enclosed in single quotes (e.g., file names), identifiers possibly starting
   283    with "$" and possibly with "!" in them (for "z3_tptp"). *)
   284 val scan_general_id =
   285   $$ "'" |-- Scan.repeat (~$$ "'") --| $$ "'" >> implode
   286   || (Scan.repeat ($$ "$") -- Scan.many1 Symbol.is_letdig >> (op ^ o apply2 implode))
   287     -- Scan.optional (Scan.repeat ($$ "!") -- Scan.many1 Symbol.is_letdig >> (op ^ o apply2 implode)) ""
   288     >> op ^
   289 
   290 val skip_term =
   291   let
   292     fun skip _ accum [] = (accum, [])
   293       | skip n accum (ss as s :: ss') =
   294         if (s = "," orelse s = ".") andalso n = 0 then
   295           (accum, ss)
   296         else if member (op =) [")", "]"] s then
   297           if n = 0 then (accum, ss) else skip (n - 1) (s :: accum) ss'
   298         else if member (op =) ["(", "["] s then
   299           skip (n + 1) (s :: accum) ss'
   300         else
   301           skip n (s :: accum) ss'
   302   in
   303     skip 0 [] #>> (rev #> implode)
   304   end
   305 
   306 datatype source =
   307   File_Source of string * string option |
   308   Inference_Source of string * string list |
   309   Introduced_Source of string
   310 
   311 val dummy_phi = AAtom (ATerm (("", []), []))
   312 val dummy_inference = Inference_Source ("", [])
   313 val dummy_atype = AType (("", []), [])
   314 
   315 (* "skip_term" is there to cope with Waldmeister nonsense such as "theory(equality)". *)
   316 fun parse_dependency x =
   317   (parse_inference_source >> snd
   318    || scan_general_id --| skip_term >> single) x
   319 and parse_dependencies x =
   320   (Scan.repeats (Scan.option ($$ ",") |-- parse_dependency)
   321    >> (filter_out (curry (op =) "theory"))) x
   322 and parse_file_source x =
   323   (Scan.this_string "file" |-- $$ "(" |-- scan_general_id
   324    -- Scan.option ($$ "," |-- scan_general_id
   325      --| Scan.option ($$ "," |-- $$ "[" -- Scan.option scan_general_id --| $$ "]")) --| $$ ")") x
   326 and parse_inference_source x =
   327   (Scan.this_string "inference" |-- $$ "(" |-- scan_general_id
   328    --| skip_term --| $$ "," --| skip_term --| $$ "," --| $$ "["
   329    -- parse_dependencies --| $$ "]" --| $$ ")") x
   330 and parse_introduced_source x =
   331   (Scan.this_string "introduced" |-- $$ "(" |-- scan_general_id
   332    --| Scan.option ($$ "," |-- skip_term) --| $$ ")") x
   333 and parse_source x =
   334   (parse_file_source >> File_Source
   335    || parse_inference_source >> Inference_Source
   336    || parse_introduced_source >> Introduced_Source
   337    || scan_general_id >> (fn s => Inference_Source ("", [s])) (* for E *)
   338    || skip_term >> K dummy_inference) x
   339 
   340 fun list_app (f, args) = fold (fn arg => fn f => ATerm ((tptp_app, []), [f, arg])) args f
   341 
   342 fun parse_class x = scan_general_id x
   343 and parse_classes x = (parse_class ::: Scan.repeat ($$ "&" |-- parse_class)) x
   344 
   345 fun parse_type x =
   346   (($$ "(" |-- parse_type --| $$ ")"
   347     || (scan_general_id -- Scan.optional ($$ "{" |-- parse_classes --| $$ "}") [])
   348         -- Scan.optional ($$ "(" |-- parse_types --| $$ ")") []
   349        >> AType)
   350    -- Scan.option (($$ tptp_fun_type || $$ tptp_product_type) -- parse_type)
   351   >> (fn (a, NONE) => a
   352        | (a, SOME (fun_or_product, b)) =>
   353          if fun_or_product = tptp_fun_type then AFun (a, b)
   354          else AType ((tptp_product_type, []), [a, b]))) x
   355 and parse_types x =
   356   (parse_type ::: Scan.repeat ($$ "," |-- parse_type)) x
   357 
   358 (* We currently half ignore types. *)
   359 fun parse_optional_type_signature x =
   360   (Scan.option ($$ tptp_has_type |-- parse_type)
   361    >> (fn some as SOME (AType ((s, []), [])) => if s = dfg_individual_type then NONE else some
   362         | res => res)) x
   363 and parse_arg x =
   364   ($$ "(" |-- parse_term --| $$ ")" --| parse_optional_type_signature
   365    || scan_general_id -- parse_optional_type_signature
   366        -- Scan.optional ($$ "<" |-- parse_types --| $$ ">") []
   367        -- Scan.optional ($$ "(" |-- parse_terms --| $$ ")") []
   368      >> (fn (((s, ty_opt), tyargs), args) =>
   369        if is_tptp_variable s andalso null tyargs andalso null args andalso is_some ty_opt then
   370          ATerm ((s, the_list ty_opt), [])
   371        else
   372          ATerm ((s, tyargs), args))) x
   373 and parse_term x =
   374   (parse_arg -- Scan.repeat ($$ tptp_app |-- parse_arg)
   375    --| parse_optional_type_signature >> list_app) x
   376 and parse_terms x = (parse_term ::: Scan.repeat ($$ "," |-- parse_term)) x
   377 
   378 fun parse_atom x =
   379   (parse_term -- Scan.option (Scan.option ($$ tptp_not_infix) --| $$ tptp_equal -- parse_term)
   380    >> (fn (u1, NONE) => AAtom u1
   381         | (u1, SOME (neg, u2)) =>
   382           AAtom (ATerm (("equal", []), [u1, u2])) |> is_some neg ? mk_anot)) x
   383 
   384 (* TPTP formulas are fully parenthesized, so we don't need to worry about operator precedence. *)
   385 fun parse_literal x =
   386   ((Scan.repeat ($$ tptp_not) >> length)
   387       -- ($$ "(" |-- parse_formula --| $$ ")"
   388           || parse_quantified_formula
   389           || parse_atom)
   390       >> (fn (n, phi) => phi |> n mod 2 = 1 ? mk_anot)) x
   391 and parse_formula x =
   392   (parse_literal
   393    -- Scan.option ((Scan.this_string tptp_implies
   394                     || Scan.this_string tptp_iff
   395                     || Scan.this_string tptp_not_iff
   396                     || Scan.this_string tptp_if
   397                     || $$ tptp_or
   398                     || $$ tptp_and) -- parse_formula)
   399    >> (fn (phi1, NONE) => phi1
   400         | (phi1, SOME (c, phi2)) =>
   401           if c = tptp_implies then mk_aconn AImplies phi1 phi2
   402           else if c = tptp_iff then mk_aconn AIff phi1 phi2
   403           else if c = tptp_not_iff then mk_anot (mk_aconn AIff phi1 phi2)
   404           else if c = tptp_if then mk_aconn AImplies phi2 phi1
   405           else if c = tptp_or then mk_aconn AOr phi1 phi2
   406           else if c = tptp_and then mk_aconn AAnd phi1 phi2
   407           else raise Fail ("impossible connective " ^ quote c))) x
   408 and parse_quantified_formula x =
   409   (($$ tptp_forall >> K AForall || $$ tptp_exists >> K AExists)
   410    --| $$ "[" -- parse_terms --| $$ "]" --| $$ ":" -- parse_literal
   411    >> (fn ((q, ts), phi) => AQuant (q, map (fn ATerm ((s, _), _) => (s, NONE)) ts, phi))) x
   412 
   413 val parse_tstp_extra_arguments =
   414   Scan.optional ($$ "," |-- parse_source --| Scan.option ($$ "," |-- skip_term)) dummy_inference
   415 
   416 val waldmeister_conjecture_name = "conjecture_1"
   417 
   418 val tofof_fact_prefix = "fof_"
   419 
   420 fun is_same_term subst tm1 tm2 =
   421   let
   422     fun do_term_pair (AAbs (((var1, typ1), body1), args1)) (AAbs (((var2, typ2), body2), args2))
   423           (SOME subst) =
   424         if typ1 <> typ2 andalso length args1 = length args2 then NONE
   425         else
   426           let val ls = length subst in
   427             SOME ((var1, var2) :: subst)
   428             |> do_term_pair body1 body2
   429             |> (fn SOME subst => SOME (nth_drop (length subst - ls - 1) subst)
   430                  | NONE => NONE)
   431             |> (if length args1 = length args2
   432               then fold2 do_term_pair args1 args2
   433               else K NONE)
   434           end
   435       | do_term_pair (ATerm ((s1, _), args1)) (ATerm ((s2, _), args2)) (SOME subst) =
   436         (case apply2 is_tptp_variable (s1, s2) of
   437           (true, true) =>
   438           (case AList.lookup (op =) subst s1 of
   439             SOME s2' => if s2' = s2 then SOME subst else NONE
   440           | NONE =>
   441             if null (AList.find (op =) subst s2) then SOME ((s1, s2) :: subst)
   442             else NONE)
   443         | (false, false) =>
   444           if s1 = s2 then
   445             SOME subst
   446           else
   447             NONE
   448         | _ => NONE) |> (if length args1 = length args2
   449                        then fold2 do_term_pair args1 args2
   450                        else K NONE)
   451       | do_term_pair _ _ _ = NONE
   452   in
   453     SOME subst |> do_term_pair tm1 tm2 |> is_some
   454   end
   455 
   456 fun is_same_formula comm subst (AQuant (q1, xs1, phi1)) (AQuant (q2, xs2, phi2)) =
   457     q1 = q2 andalso length xs1 = length xs2 andalso
   458     is_same_formula comm ((map fst xs1 ~~ map fst xs2) @ subst) phi1 phi2
   459   | is_same_formula comm subst (AConn (c1, phis1)) (AConn (c2, phis2)) =
   460     c1 = c2 andalso length phis1 = length phis2 andalso
   461     forall (uncurry (is_same_formula comm subst)) (phis1 ~~ phis2)
   462   | is_same_formula comm subst (AAtom (tm1 as ATerm (("equal", tys), [tm11, tm12]))) (AAtom tm2) =
   463     is_same_term subst tm1 tm2 orelse
   464     (comm andalso is_same_term subst (ATerm (("equal", tys), [tm12, tm11])) tm2)
   465   | is_same_formula _ subst (AAtom tm1) (AAtom tm2) = is_same_term subst tm1 tm2
   466   | is_same_formula _ _ _ _ = false
   467 
   468 fun matching_formula_line_identifier phi (Formula ((ident, _), _, phi', _, _)) =
   469     if is_same_formula true [] phi phi' then SOME (ident, phi') else NONE
   470   | matching_formula_line_identifier _ _ = NONE
   471 
   472 fun find_formula_in_problem phi =
   473   maps snd
   474   #> map_filter (matching_formula_line_identifier phi)
   475   #> try (single o hd)
   476   #> the_default []
   477 
   478 fun commute_eq (AAtom (ATerm ((s, tys), tms))) = AAtom (ATerm ((s, tys), rev tms))
   479   | commute_eq _ = raise Fail "expected equation"
   480 
   481 fun role_of_tptp_string "axiom" = Axiom
   482   | role_of_tptp_string "definition" = Definition
   483   | role_of_tptp_string "lemma" = Lemma
   484   | role_of_tptp_string "hypothesis" = Hypothesis
   485   | role_of_tptp_string "conjecture" = Conjecture
   486   | role_of_tptp_string "negated_conjecture" = Negated_Conjecture
   487   | role_of_tptp_string "plain" = Plain
   488   | role_of_tptp_string "type" = Type_Role
   489   | role_of_tptp_string _ = Unknown
   490 
   491 val tptp_binary_ops =
   492   [tptp_and, tptp_not_and, tptp_or, tptp_not_or, tptp_implies, tptp_if, tptp_iff, tptp_not_iff,
   493    tptp_equal, tptp_not_equal, tptp_app]
   494 
   495 fun parse_one_in_list xs =
   496   foldl1 (op ||) (map Scan.this_string xs)
   497 
   498 fun parse_binary_op x =
   499   (parse_one_in_list tptp_binary_ops
   500    >> (fn c => if c = tptp_equal then "equal" else c)) x
   501 
   502 val parse_fo_quantifier =
   503    parse_one_in_list [tptp_forall, tptp_exists, tptp_lambda, tptp_hilbert_choice, tptp_hilbert_the]
   504 
   505 val parse_ho_quantifier =
   506    parse_one_in_list [tptp_ho_forall, tptp_ho_exists, tptp_hilbert_choice, tptp_hilbert_the]
   507 
   508 fun mk_ho_of_fo_quant q =
   509   if q = tptp_forall then tptp_ho_forall
   510   else if q = tptp_exists then tptp_ho_exists
   511   else if q = tptp_hilbert_choice then tptp_hilbert_choice
   512   else if q = tptp_hilbert_the then tptp_hilbert_the
   513   else raise Fail ("unrecognized quantification: " ^ q)
   514 
   515 fun remove_thf_app (ATerm ((x, ty), arg)) =
   516     if x = tptp_app then
   517       (case arg of
   518         ATerm ((x, ty), arg) :: t => remove_thf_app (ATerm ((x, ty), map remove_thf_app arg @ t))
   519       | [AAbs ((var, tvar), phi), t] =>
   520         remove_thf_app (AAbs ((var, tvar), map remove_thf_app phi @ [t])))
   521     else
   522       ATerm ((x, ty), map remove_thf_app arg)
   523   | remove_thf_app (AAbs (((x, ty), arg), t)) = AAbs (((x, ty), remove_thf_app arg), t)
   524 
   525 fun parse_typed_var x =
   526   (Scan.repeat (scan_general_id -- Scan.option ($$ tptp_has_type |-- parse_type)
   527      --| Scan.option (Scan.this_string ","))
   528    || $$ "(" |-- parse_typed_var --| $$ ")") x
   529 
   530 fun parse_simple_thf0_term x =
   531   (parse_fo_quantifier -- ($$ "[" |-- parse_typed_var --| $$ "]" --| $$ ":") -- parse_thf0_term
   532       >> (fn ((q, ys), t) =>
   533           fold_rev
   534             (fn (var, ty) => fn r =>
   535                 AAbs (((var, the_default dummy_atype ty), r), [])
   536                 |> (if tptp_lambda <> q then
   537                       mk_app (q |> mk_ho_of_fo_quant
   538                                 |> mk_simple_aterm)
   539                     else I))
   540             ys t)
   541   || Scan.this_string tptp_not |-- parse_thf0_term >> mk_app (mk_simple_aterm tptp_not)
   542   || scan_general_id -- Scan.option ($$ tptp_has_type |-- parse_type)
   543     >> (fn (var, typ_opt) => ATerm ((var, the_list typ_opt), []))
   544   || parse_ho_quantifier >> mk_simple_aterm
   545   || $$ "(" |-- parse_thf0_term --| $$ ")"
   546   || parse_binary_op >> mk_simple_aterm) x
   547 and parse_thf0_term x =
   548   (parse_simple_thf0_term -- Scan.option (parse_binary_op -- parse_thf0_term)
   549     >> (fn (t1, SOME (c, t2)) =>
   550            if c = tptp_app then mk_app t1 t2 else mk_apps (mk_simple_aterm c) [t1, t2]
   551          | (t, NONE) => t)) x
   552 
   553 fun parse_thf0_formula x = (parse_thf0_term #>> remove_thf_app #>> AAtom) x
   554 
   555 fun parse_tstp_thf0_line problem =
   556   (Scan.this_string tptp_thf -- $$ "(") |-- scan_general_id --| $$ ","
   557   -- Symbol.scan_ascii_id --| $$ "," -- parse_thf0_formula -- parse_tstp_extra_arguments --| $$ ")"
   558   --| $$ "."
   559   >> (fn (((num, role), phi), deps) =>
   560       let
   561         val role' = role_of_tptp_string role
   562         val ((name, phi), rule, deps) =
   563           (case deps of
   564             File_Source (_, SOME s) =>
   565             if role' = Definition then
   566               (((num, map fst (find_formula_in_problem phi problem)), phi), "", [])
   567             else
   568               (((num, [s |> perhaps (try (unprefix tofof_fact_prefix))]), phi), "", [])
   569           | Inference_Source (rule, deps) => (((num, []), phi), rule, deps))
   570       in
   571         [(name, role', phi, rule, map (rpair []) deps)]
   572       end)
   573 
   574 (* Syntax: (cnf|fof|tff|thf)\(<num>, <formula_role>, <formula> <extra_arguments>\).
   575    The <num> could be an identifier, but we assume integers. *)
   576 fun parse_tstp_line problem =
   577   ((Scan.this_string tptp_cnf || Scan.this_string tptp_fof
   578     || Scan.this_string tptp_tff || Scan.this_string tptp_thf) -- $$ "(")
   579     |-- scan_general_id --| $$ "," -- Symbol.scan_ascii_id --| $$ ","
   580     -- (parse_formula || skip_term >> K dummy_phi) -- parse_tstp_extra_arguments
   581     --| $$ ")" --| $$ "."
   582    >> (fn (((num, role0), phi), src) =>
   583           let
   584             val role = role_of_tptp_string role0
   585             val ((name, phi), role', rule, deps) =
   586               (* Waldmeister isn't exactly helping. *)
   587               (case src of
   588                 File_Source (_, SOME s) =>
   589                 (if s = waldmeister_conjecture_name then
   590                    (case find_formula_in_problem (mk_anot phi) problem of
   591                      (* Waldmeister hack: Get the original orientation of the equation to avoid
   592                         confusing Isar. *)
   593                      [(s, phi')] =>
   594                      ((num, [s]),
   595                       phi |> not (is_same_formula false [] (mk_anot phi) phi') ? commute_eq)
   596                    | _ => ((num, []), phi))
   597                  else
   598                    ((num, [s |> perhaps (try (unprefix tofof_fact_prefix))]),
   599                     phi),
   600                  role, "", [])
   601               | File_Source _ =>
   602                 (((num, map fst (find_formula_in_problem phi problem)), phi), role, "", [])
   603               | Inference_Source (rule, deps) => (((num, []), phi), role, rule, deps)
   604               | Introduced_Source rule => (((num, []), phi), Lemma, rule, []))
   605 
   606             fun mk_step () = (name, role', phi, rule, map (rpair []) deps)
   607           in
   608             [(case role' of
   609                Definition =>
   610                (case phi of
   611                  AAtom (ATerm (("equal", _), _)) =>
   612                   (* Vampire's equality proxy axiom *)
   613                   (name, Definition, phi, rule, map (rpair []) deps)
   614                | _ => mk_step ())
   615              | _ => mk_step ())]
   616           end)
   617 
   618 (**** PARSING OF SPASS OUTPUT ****)
   619 
   620 (* SPASS returns clause references of the form "x.y". We ignore "y". *)
   621 val parse_dot_name = scan_general_id --| $$ "." --| scan_general_id
   622 
   623 val parse_spass_annotations =
   624   Scan.optional ($$ ":" |-- Scan.repeat (parse_dot_name --| Scan.option ($$ ","))) []
   625 
   626 (* We ignore the stars and the pluses that follow literals. *)
   627 fun parse_decorated_atom x =
   628   (parse_atom --| Scan.repeat ($$ "*" || $$ "+" || $$ " ")) x
   629 
   630 fun mk_horn ([], []) = AAtom (ATerm (("c_False", []), []))
   631   | mk_horn (neg_lits, pos_lits) = foldr1 (uncurry (mk_aconn AOr)) (map mk_anot neg_lits @ pos_lits)
   632 
   633 fun parse_horn_clause x =
   634   (Scan.repeat parse_decorated_atom --| $$ "|" --| $$ "|"
   635      -- Scan.repeat parse_decorated_atom --| $$ "-" --| $$ ">"
   636      -- Scan.repeat parse_decorated_atom
   637    >> (mk_horn o apfst (op @))) x
   638 
   639 val parse_spass_debug =
   640   Scan.option ($$ "(" |-- Scan.repeat (scan_general_id --| Scan.option ($$ ",")) --| $$ ")")
   641 
   642 (* Syntax: <num>[0:<inference><annotations>] <atoms> || <atoms> -> <atoms> .
   643            derived from formulae <ident>* *)
   644 fun parse_spass_line x =
   645   (parse_spass_debug |-- scan_general_id --| $$ "[" --| Scan.many1 Symbol.is_digit --| $$ ":"
   646      -- Symbol.scan_ascii_id -- parse_spass_annotations --| $$ "]" -- parse_horn_clause --| $$ "."
   647      -- Scan.option (Scan.this_string "derived from formulae "
   648                      |-- Scan.repeat (scan_general_id --| Scan.option ($$ " ")))
   649    >> (fn ((((num, rule), deps), u), names) =>
   650           [((num, these names), Unknown, u, rule, map (rpair []) deps)])) x
   651 
   652 fun parse_pirate_dependency x = (Scan.option ($$ "-") |-- scan_general_id) x
   653 fun parse_pirate_dependencies x =
   654   Scan.repeat (parse_pirate_dependency --| Scan.option ($$ "," || $$ " ")) x
   655 fun parse_pirate_file_source x =
   656   ((Scan.this_string "Input" || Scan.this_string "Conj") |-- $$ "(" |-- scan_general_id
   657      --| $$ ")") x
   658 fun parse_pirate_inference_source x =
   659   (scan_general_id -- ($$ "(" |-- parse_pirate_dependencies --| $$ ")")) x
   660 fun parse_pirate_source x =
   661   (parse_pirate_file_source >> (fn s => File_Source ("", SOME s))
   662    || parse_pirate_inference_source >> Inference_Source) x
   663 
   664 (* Syntax: <num> <stuff> || <atoms> -> <atoms> . origin\(<origin>\) *)
   665 fun parse_pirate_line x =
   666   (scan_general_id --| Scan.repeat (~$$ "|") -- parse_horn_clause --| $$ "."
   667      --| Scan.this_string "origin" --| $$ "(" -- parse_pirate_source --| $$ ")"
   668    >> (fn ((((num, u), source))) =>
   669      let
   670        val (names, rule, deps) =
   671          (case source of
   672            File_Source (_, SOME s) => ([s], spass_input_rule, [])
   673          | Inference_Source (rule, deps) => ([], rule, deps))
   674      in
   675        [((num, names), Unknown, u, rule, map (rpair []) deps)]
   676      end)) x
   677 
   678 fun core_inference inf fact = ((fact, [fact]), Unknown, dummy_phi, inf, [])
   679 
   680 (* Syntax: SZS core <name> ... <name> *)
   681 fun parse_z3_tptp_core_line x =
   682   (Scan.this_string "SZS core" |-- Scan.repeat ($$ " " |-- scan_general_id)
   683    >> map (core_inference z3_tptp_core_rule)) x
   684 
   685 fun parse_line local_name problem =
   686   if local_name = leo2N orelse local_name = leo3N then parse_tstp_thf0_line problem
   687   else if local_name = spassN then parse_spass_line
   688   else if local_name = pirateN then parse_pirate_line
   689   else if local_name = z3_tptpN then parse_z3_tptp_core_line
   690   else parse_tstp_line problem
   691 
   692 fun core_of_agsyhol_proof s =
   693   (case split_lines s of
   694     "The transformed problem consists of the following conjectures:" :: conj ::
   695     _ :: proof_term :: _ => SOME (unprefix " " conj :: find_enclosed "<<" ">>" proof_term)
   696   | _ => NONE)
   697 
   698 fun clean_up_dependencies _ [] = []
   699   | clean_up_dependencies seen ((name, role, u, rule, deps) :: steps) =
   700     (name, role, u, rule, map_filter (fn dep => find_first (is_same_atp_step dep) seen) deps) ::
   701     clean_up_dependencies (name :: seen) steps
   702 
   703 fun clean_up_atp_proof_dependencies proof = clean_up_dependencies [] proof
   704 
   705 fun map_term_names_in_atp_proof f =
   706   let
   707     fun map_type (AType ((s, clss), tys)) = AType ((f s, map f clss), map map_type tys)
   708       | map_type (AFun (ty, ty')) = AFun (map_type ty, map_type ty')
   709       | map_type (APi (ss, ty)) = APi (map f ss, map_type ty)
   710 
   711     fun map_term (ATerm ((s, tys), ts)) = ATerm ((f s, map map_type tys), map map_term ts)
   712       | map_term (AAbs (((s, ty), tm), args)) =
   713         AAbs (((f s, map_type ty), map_term tm), map map_term args)
   714 
   715     fun map_formula (AQuant (q, xs, phi)) = AQuant (q, map (apfst f) xs, map_formula phi)
   716       | map_formula (AConn (c, phis)) = AConn (c, map map_formula phis)
   717       | map_formula (AAtom t) = AAtom (map_term t)
   718 
   719     fun map_step (name, role, phi, rule, deps) = (name, role, map_formula phi, rule, deps)
   720   in
   721     map map_step
   722   end
   723 
   724 fun nasty_name pool s = Symtab.lookup pool s |> the_default s
   725 
   726 fun nasty_atp_proof pool =
   727   not (Symtab.is_empty pool) ? map_term_names_in_atp_proof (nasty_name pool)
   728 
   729 end;