src/HOL/Set.thy
author nipkow
Thu Jun 04 19:44:06 2009 +0200 (2009-06-04)
changeset 31441 428e4caf2299
parent 31197 c1c163ec6c44
child 31461 d54b743b52a3
permissions -rw-r--r--
finite lemmas
     1 (*  Title:      HOL/Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3 *)
     4 
     5 header {* Set theory for higher-order logic *}
     6 
     7 theory Set
     8 imports Lattices
     9 begin
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 types 'a set = "'a => bool"
    19 
    20 consts
    21   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    22   "op :"        :: "'a => 'a set => bool"                -- "membership"
    23   insert        :: "'a => 'a set => 'a set"
    24   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    25   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    26   Bex1          :: "'a set => ('a => bool) => bool"      -- "bounded unique existential quantifiers"
    27   Pow           :: "'a set => 'a set set"                -- "powerset"
    28   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    29 
    30 local
    31 
    32 notation
    33   "op :"  ("op :") and
    34   "op :"  ("(_/ : _)" [50, 51] 50)
    35 
    36 abbreviation
    37   "not_mem x A == ~ (x : A)" -- "non-membership"
    38 
    39 notation
    40   not_mem  ("op ~:") and
    41   not_mem  ("(_/ ~: _)" [50, 51] 50)
    42 
    43 notation (xsymbols)
    44   "op :"  ("op \<in>") and
    45   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    46   not_mem  ("op \<notin>") and
    47   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    48 
    49 notation (HTML output)
    50   "op :"  ("op \<in>") and
    51   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    52   not_mem  ("op \<notin>") and
    53   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    54 
    55 syntax
    56   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    57 
    58 translations
    59   "{x. P}"      == "Collect (%x. P)"
    60 
    61 definition empty :: "'a set" ("{}") where
    62   "empty \<equiv> {x. False}"
    63 
    64 definition UNIV :: "'a set" where
    65   "UNIV \<equiv> {x. True}"
    66 
    67 syntax
    68   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    69 
    70 translations
    71   "{x, xs}"     == "insert x {xs}"
    72   "{x}"         == "insert x {}"
    73 
    74 definition Int :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Int" 70) where
    75   "A Int B \<equiv> {x. x \<in> A \<and> x \<in> B}"
    76 
    77 definition Un :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Un" 65) where
    78   "A Un B \<equiv> {x. x \<in> A \<or> x \<in> B}"
    79 
    80 notation (xsymbols)
    81   "Int"  (infixl "\<inter>" 70) and
    82   "Un"  (infixl "\<union>" 65)
    83 
    84 notation (HTML output)
    85   "Int"  (infixl "\<inter>" 70) and
    86   "Un"  (infixl "\<union>" 65)
    87 
    88 syntax
    89   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    90   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    91   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
    92   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax (HOL)
    95   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    96   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    97   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
    98 
    99 syntax (xsymbols)
   100   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   101   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   102   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   103   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   104 
   105 syntax (HTML output)
   106   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   107   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   108   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   109 
   110 translations
   111   "ALL x:A. P"  == "Ball A (%x. P)"
   112   "EX x:A. P"   == "Bex A (%x. P)"
   113   "EX! x:A. P"  == "Bex1 A (%x. P)"
   114   "LEAST x:A. P" => "LEAST x. x:A & P"
   115 
   116 definition INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   117   "INTER A B \<equiv> {y. \<forall>x\<in>A. y \<in> B x}"
   118 
   119 definition UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   120   "UNION A B \<equiv> {y. \<exists>x\<in>A. y \<in> B x}"
   121 
   122 definition Inter :: "'a set set \<Rightarrow> 'a set" where
   123   "Inter S \<equiv> INTER S (\<lambda>x. x)"
   124 
   125 definition Union :: "'a set set \<Rightarrow> 'a set" where
   126   "Union S \<equiv> UNION S (\<lambda>x. x)"
   127 
   128 notation (xsymbols)
   129   Inter  ("\<Inter>_" [90] 90) and
   130   Union  ("\<Union>_" [90] 90)
   131 
   132 
   133 subsection {* Additional concrete syntax *}
   134 
   135 syntax
   136   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
   137   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ :/ _./ _})")
   138   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   139   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   140   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 10] 10)
   141   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 10] 10)
   142 
   143 syntax (xsymbols)
   144   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ \<in>/ _./ _})")
   145   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   146   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   147   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 10] 10)
   148   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 10] 10)
   149 
   150 syntax (latex output)
   151   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   152   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   153   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   154   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   155 
   156 translations
   157   "{x:A. P}"    => "{x. x:A & P}"
   158   "INT x y. B"  == "INT x. INT y. B"
   159   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   160   "INT x. B"    == "INT x:CONST UNIV. B"
   161   "INT x:A. B"  == "CONST INTER A (%x. B)"
   162   "UN x y. B"   == "UN x. UN y. B"
   163   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   164   "UN x. B"     == "UN x:CONST UNIV. B"
   165   "UN x:A. B"   == "CONST UNION A (%x. B)"
   166 
   167 text {*
   168   Note the difference between ordinary xsymbol syntax of indexed
   169   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   170   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   171   former does not make the index expression a subscript of the
   172   union/intersection symbol because this leads to problems with nested
   173   subscripts in Proof General.
   174 *}
   175 
   176 abbreviation
   177   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   178   "subset \<equiv> less"
   179 
   180 abbreviation
   181   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   182   "subset_eq \<equiv> less_eq"
   183 
   184 notation (output)
   185   subset  ("op <") and
   186   subset  ("(_/ < _)" [50, 51] 50) and
   187   subset_eq  ("op <=") and
   188   subset_eq  ("(_/ <= _)" [50, 51] 50)
   189 
   190 notation (xsymbols)
   191   subset  ("op \<subset>") and
   192   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   193   subset_eq  ("op \<subseteq>") and
   194   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   195 
   196 notation (HTML output)
   197   subset  ("op \<subset>") and
   198   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   199   subset_eq  ("op \<subseteq>") and
   200   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   201 
   202 abbreviation (input)
   203   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   204   "supset \<equiv> greater"
   205 
   206 abbreviation (input)
   207   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   208   "supset_eq \<equiv> greater_eq"
   209 
   210 notation (xsymbols)
   211   supset  ("op \<supset>") and
   212   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   213   supset_eq  ("op \<supseteq>") and
   214   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   215 
   216 abbreviation
   217   range :: "('a => 'b) => 'b set" where -- "of function"
   218   "range f == f ` UNIV"
   219 
   220 
   221 subsubsection "Bounded quantifiers"
   222 
   223 syntax (output)
   224   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   225   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   226   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   227   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   228   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   229 
   230 syntax (xsymbols)
   231   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   232   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   233   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   234   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   235   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   236 
   237 syntax (HOL output)
   238   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   239   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   240   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   241   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   242   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   243 
   244 syntax (HTML output)
   245   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   246   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   247   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   248   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   249   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   250 
   251 translations
   252  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   253  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   254  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   255  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   256  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   257 
   258 print_translation {*
   259 let
   260   val Type (set_type, _) = @{typ "'a set"};
   261   val All_binder = Syntax.binder_name @{const_syntax "All"};
   262   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   263   val impl = @{const_syntax "op -->"};
   264   val conj = @{const_syntax "op &"};
   265   val sbset = @{const_syntax "subset"};
   266   val sbset_eq = @{const_syntax "subset_eq"};
   267 
   268   val trans =
   269    [((All_binder, impl, sbset), "_setlessAll"),
   270     ((All_binder, impl, sbset_eq), "_setleAll"),
   271     ((Ex_binder, conj, sbset), "_setlessEx"),
   272     ((Ex_binder, conj, sbset_eq), "_setleEx")];
   273 
   274   fun mk v v' c n P =
   275     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   276     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   277 
   278   fun tr' q = (q,
   279     fn [Const ("_bound", _) $ Free (v, Type (T, _)), Const (c, _) $ (Const (d, _) $ (Const ("_bound", _) $ Free (v', _)) $ n) $ P] =>
   280          if T = (set_type) then case AList.lookup (op =) trans (q, c, d)
   281           of NONE => raise Match
   282            | SOME l => mk v v' l n P
   283          else raise Match
   284      | _ => raise Match);
   285 in
   286   [tr' All_binder, tr' Ex_binder]
   287 end
   288 *}
   289 
   290 
   291 text {*
   292   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   293   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   294   only translated if @{text "[0..n] subset bvs(e)"}.
   295 *}
   296 
   297 parse_translation {*
   298   let
   299     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   300 
   301     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   302       | nvars _ = 1;
   303 
   304     fun setcompr_tr [e, idts, b] =
   305       let
   306         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   307         val P = Syntax.const "op &" $ eq $ b;
   308         val exP = ex_tr [idts, P];
   309       in Syntax.const "Collect" $ Term.absdummy (dummyT, exP) end;
   310 
   311   in [("@SetCompr", setcompr_tr)] end;
   312 *}
   313 
   314 (* To avoid eta-contraction of body: *)
   315 print_translation {*
   316 let
   317   fun btr' syn [A, Abs abs] =
   318     let val (x, t) = atomic_abs_tr' abs
   319     in Syntax.const syn $ x $ A $ t end
   320 in
   321 [(@{const_syntax Ball}, btr' "_Ball"), (@{const_syntax Bex}, btr' "_Bex"),
   322  (@{const_syntax UNION}, btr' "@UNION"),(@{const_syntax INTER}, btr' "@INTER")]
   323 end
   324 *}
   325 
   326 print_translation {*
   327 let
   328   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   329 
   330   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   331     let
   332       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   333         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   334             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   335             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   336         | check _ = false
   337 
   338         fun tr' (_ $ abs) =
   339           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   340           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   341     in if check (P, 0) then tr' P
   342        else let val (x as _ $ Free(xN,_), t) = atomic_abs_tr' abs
   343                 val M = Syntax.const "@Coll" $ x $ t
   344             in case t of
   345                  Const("op &",_)
   346                    $ (Const("op :",_) $ (Const("_bound",_) $ Free(yN,_)) $ A)
   347                    $ P =>
   348                    if xN=yN then Syntax.const "@Collect" $ x $ A $ P else M
   349                | _ => M
   350             end
   351     end;
   352   in [("Collect", setcompr_tr')] end;
   353 *}
   354 
   355 
   356 subsection {* Rules and definitions *}
   357 
   358 text {* Isomorphisms between predicates and sets. *}
   359 
   360 defs
   361   mem_def [code]: "x : S == S x"
   362   Collect_def [code]: "Collect P == P"
   363 
   364 defs
   365   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   366   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   367   Bex1_def:     "Bex1 A P       == EX! x. x:A & P(x)"
   368 
   369 instantiation "fun" :: (type, minus) minus
   370 begin
   371 
   372 definition
   373   fun_diff_def: "A - B = (%x. A x - B x)"
   374 
   375 instance ..
   376 
   377 end
   378 
   379 instantiation bool :: minus
   380 begin
   381 
   382 definition
   383   bool_diff_def: "A - B = (A & ~ B)"
   384 
   385 instance ..
   386 
   387 end
   388 
   389 instantiation "fun" :: (type, uminus) uminus
   390 begin
   391 
   392 definition
   393   fun_Compl_def: "- A = (%x. - A x)"
   394 
   395 instance ..
   396 
   397 end
   398 
   399 instantiation bool :: uminus
   400 begin
   401 
   402 definition
   403   bool_Compl_def: "- A = (~ A)"
   404 
   405 instance ..
   406 
   407 end
   408 
   409 defs
   410   Pow_def:      "Pow A          == {B. B <= A}"
   411   insert_def:   "insert a B     == {x. x=a} Un B"
   412   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   413 
   414 
   415 subsection {* Lemmas and proof tool setup *}
   416 
   417 subsubsection {* Relating predicates and sets *}
   418 
   419 lemma mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   420   by (simp add: Collect_def mem_def)
   421 
   422 lemma Collect_mem_eq [simp]: "{x. x:A} = A"
   423   by (simp add: Collect_def mem_def)
   424 
   425 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   426   by simp
   427 
   428 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   429   by simp
   430 
   431 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   432   by simp
   433 
   434 lemmas CollectE = CollectD [elim_format]
   435 
   436 
   437 subsubsection {* Bounded quantifiers *}
   438 
   439 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   440   by (simp add: Ball_def)
   441 
   442 lemmas strip = impI allI ballI
   443 
   444 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   445   by (simp add: Ball_def)
   446 
   447 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   448   by (unfold Ball_def) blast
   449 
   450 ML {* bind_thm ("rev_ballE", permute_prems 1 1 @{thm ballE}) *}
   451 
   452 text {*
   453   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   454   @{prop "a:A"}; creates assumption @{prop "P a"}.
   455 *}
   456 
   457 ML {*
   458   fun ball_tac i = etac @{thm ballE} i THEN contr_tac (i + 1)
   459 *}
   460 
   461 text {*
   462   Gives better instantiation for bound:
   463 *}
   464 
   465 declaration {* fn _ =>
   466   Classical.map_cs (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   467 *}
   468 
   469 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   470   -- {* Normally the best argument order: @{prop "P x"} constrains the
   471     choice of @{prop "x:A"}. *}
   472   by (unfold Bex_def) blast
   473 
   474 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   475   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   476   by (unfold Bex_def) blast
   477 
   478 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   479   by (unfold Bex_def) blast
   480 
   481 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   482   by (unfold Bex_def) blast
   483 
   484 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   485   -- {* Trival rewrite rule. *}
   486   by (simp add: Ball_def)
   487 
   488 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   489   -- {* Dual form for existentials. *}
   490   by (simp add: Bex_def)
   491 
   492 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   493   by blast
   494 
   495 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   496   by blast
   497 
   498 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   499   by blast
   500 
   501 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   502   by blast
   503 
   504 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   505   by blast
   506 
   507 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   508   by blast
   509 
   510 ML {*
   511   local
   512     val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   513     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   514     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   515 
   516     val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   517     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   518     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   519   in
   520     val defBEX_regroup = Simplifier.simproc (the_context ())
   521       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   522     val defBALL_regroup = Simplifier.simproc (the_context ())
   523       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   524   end;
   525 
   526   Addsimprocs [defBALL_regroup, defBEX_regroup];
   527 *}
   528 
   529 
   530 subsubsection {* Congruence rules *}
   531 
   532 lemma ball_cong:
   533   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   534     (ALL x:A. P x) = (ALL x:B. Q x)"
   535   by (simp add: Ball_def)
   536 
   537 lemma strong_ball_cong [cong]:
   538   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   539     (ALL x:A. P x) = (ALL x:B. Q x)"
   540   by (simp add: simp_implies_def Ball_def)
   541 
   542 lemma bex_cong:
   543   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   544     (EX x:A. P x) = (EX x:B. Q x)"
   545   by (simp add: Bex_def cong: conj_cong)
   546 
   547 lemma strong_bex_cong [cong]:
   548   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   549     (EX x:A. P x) = (EX x:B. Q x)"
   550   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   551 
   552 
   553 subsubsection {* Subsets *}
   554 
   555 lemma subsetI [atp,intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   556   by (auto simp add: mem_def intro: predicate1I)
   557 
   558 text {*
   559   \medskip Map the type @{text "'a set => anything"} to just @{typ
   560   'a}; for overloading constants whose first argument has type @{typ
   561   "'a set"}.
   562 *}
   563 
   564 lemma subsetD [elim, intro?]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   565   -- {* Rule in Modus Ponens style. *}
   566   by (unfold mem_def) blast
   567 
   568 lemma rev_subsetD [intro?]: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   569   -- {* The same, with reversed premises for use with @{text erule} --
   570       cf @{text rev_mp}. *}
   571   by (rule subsetD)
   572 
   573 text {*
   574   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   575 *}
   576 
   577 ML {*
   578   fun impOfSubs th = th RSN (2, @{thm rev_subsetD})
   579 *}
   580 
   581 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   582   -- {* Classical elimination rule. *}
   583   by (unfold mem_def) blast
   584 
   585 lemma subset_eq: "A \<le> B = (\<forall>x\<in>A. x \<in> B)" by blast
   586 
   587 text {*
   588   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   589   creates the assumption @{prop "c \<in> B"}.
   590 *}
   591 
   592 ML {*
   593   fun set_mp_tac i = etac @{thm subsetCE} i THEN mp_tac i
   594 *}
   595 
   596 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   597   by blast
   598 
   599 lemma subset_refl [simp,atp]: "A \<subseteq> A"
   600   by fast
   601 
   602 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   603   by blast
   604 
   605 
   606 subsubsection {* Equality *}
   607 
   608 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   609   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   610    apply (rule Collect_mem_eq)
   611   apply (rule Collect_mem_eq)
   612   done
   613 
   614 (* Due to Brian Huffman *)
   615 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   616 by(auto intro:set_ext)
   617 
   618 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   619   -- {* Anti-symmetry of the subset relation. *}
   620   by (iprover intro: set_ext subsetD)
   621 
   622 text {*
   623   \medskip Equality rules from ZF set theory -- are they appropriate
   624   here?
   625 *}
   626 
   627 lemma equalityD1: "A = B ==> A \<subseteq> B"
   628   by (simp add: subset_refl)
   629 
   630 lemma equalityD2: "A = B ==> B \<subseteq> A"
   631   by (simp add: subset_refl)
   632 
   633 text {*
   634   \medskip Be careful when adding this to the claset as @{text
   635   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   636   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   637 *}
   638 
   639 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   640   by (simp add: subset_refl)
   641 
   642 lemma equalityCE [elim]:
   643     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   644   by blast
   645 
   646 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   647   by simp
   648 
   649 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   650   by simp
   651 
   652 
   653 subsubsection {* The universal set -- UNIV *}
   654 
   655 lemma UNIV_I [simp]: "x : UNIV"
   656   by (simp add: UNIV_def)
   657 
   658 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   659 
   660 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   661   by simp
   662 
   663 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   664   by (rule subsetI) (rule UNIV_I)
   665 
   666 text {*
   667   \medskip Eta-contracting these two rules (to remove @{text P})
   668   causes them to be ignored because of their interaction with
   669   congruence rules.
   670 *}
   671 
   672 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   673   by (simp add: Ball_def)
   674 
   675 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   676   by (simp add: Bex_def)
   677 
   678 lemma UNIV_eq_I: "(\<And>x. x \<in> A) \<Longrightarrow> UNIV = A"
   679   by auto
   680 
   681 
   682 subsubsection {* The empty set *}
   683 
   684 lemma empty_iff [simp]: "(c : {}) = False"
   685   by (simp add: empty_def)
   686 
   687 lemma emptyE [elim!]: "a : {} ==> P"
   688   by simp
   689 
   690 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   691     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   692   by blast
   693 
   694 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   695   by blast
   696 
   697 lemma equals0D: "A = {} ==> a \<notin> A"
   698     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   699   by blast
   700 
   701 lemma ball_empty [simp]: "Ball {} P = True"
   702   by (simp add: Ball_def)
   703 
   704 lemma bex_empty [simp]: "Bex {} P = False"
   705   by (simp add: Bex_def)
   706 
   707 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   708   by (blast elim: equalityE)
   709 
   710 
   711 subsubsection {* The Powerset operator -- Pow *}
   712 
   713 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   714   by (simp add: Pow_def)
   715 
   716 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   717   by (simp add: Pow_def)
   718 
   719 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   720   by (simp add: Pow_def)
   721 
   722 lemma Pow_bottom: "{} \<in> Pow B"
   723   by simp
   724 
   725 lemma Pow_top: "A \<in> Pow A"
   726   by (simp add: subset_refl)
   727 
   728 
   729 subsubsection {* Set complement *}
   730 
   731 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   732   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   733 
   734 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   735   by (unfold mem_def fun_Compl_def bool_Compl_def) blast
   736 
   737 text {*
   738   \medskip This form, with negated conclusion, works well with the
   739   Classical prover.  Negated assumptions behave like formulae on the
   740   right side of the notional turnstile ... *}
   741 
   742 lemma ComplD [dest!]: "c : -A ==> c~:A"
   743   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   744 
   745 lemmas ComplE = ComplD [elim_format]
   746 
   747 lemma Compl_eq: "- A = {x. ~ x : A}" by blast
   748 
   749 
   750 subsubsection {* Binary union -- Un *}
   751 
   752 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   753   by (unfold Un_def) blast
   754 
   755 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   756   by simp
   757 
   758 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   759   by simp
   760 
   761 text {*
   762   \medskip Classical introduction rule: no commitment to @{prop A} vs
   763   @{prop B}.
   764 *}
   765 
   766 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   767   by auto
   768 
   769 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   770   by (unfold Un_def) blast
   771 
   772 
   773 subsubsection {* Binary intersection -- Int *}
   774 
   775 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   776   by (unfold Int_def) blast
   777 
   778 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   779   by simp
   780 
   781 lemma IntD1: "c : A Int B ==> c:A"
   782   by simp
   783 
   784 lemma IntD2: "c : A Int B ==> c:B"
   785   by simp
   786 
   787 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   788   by simp
   789 
   790 
   791 subsubsection {* Set difference *}
   792 
   793 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   794   by (simp add: mem_def fun_diff_def bool_diff_def)
   795 
   796 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   797   by simp
   798 
   799 lemma DiffD1: "c : A - B ==> c : A"
   800   by simp
   801 
   802 lemma DiffD2: "c : A - B ==> c : B ==> P"
   803   by simp
   804 
   805 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   806   by simp
   807 
   808 lemma set_diff_eq: "A - B = {x. x : A & ~ x : B}" by blast
   809 
   810 lemma Compl_eq_Diff_UNIV: "-A = (UNIV - A)"
   811 by blast
   812 
   813 
   814 subsubsection {* Augmenting a set -- insert *}
   815 
   816 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   817   by (unfold insert_def) blast
   818 
   819 lemma insertI1: "a : insert a B"
   820   by simp
   821 
   822 lemma insertI2: "a : B ==> a : insert b B"
   823   by simp
   824 
   825 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   826   by (unfold insert_def) blast
   827 
   828 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   829   -- {* Classical introduction rule. *}
   830   by auto
   831 
   832 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   833   by auto
   834 
   835 lemma set_insert:
   836   assumes "x \<in> A"
   837   obtains B where "A = insert x B" and "x \<notin> B"
   838 proof
   839   from assms show "A = insert x (A - {x})" by blast
   840 next
   841   show "x \<notin> A - {x}" by blast
   842 qed
   843 
   844 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   845 by auto
   846 
   847 subsubsection {* Singletons, using insert *}
   848 
   849 lemma singletonI [intro!,noatp]: "a : {a}"
   850     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   851   by (rule insertI1)
   852 
   853 lemma singletonD [dest!,noatp]: "b : {a} ==> b = a"
   854   by blast
   855 
   856 lemmas singletonE = singletonD [elim_format]
   857 
   858 lemma singleton_iff: "(b : {a}) = (b = a)"
   859   by blast
   860 
   861 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   862   by blast
   863 
   864 lemma singleton_insert_inj_eq [iff,noatp]:
   865      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   866   by blast
   867 
   868 lemma singleton_insert_inj_eq' [iff,noatp]:
   869      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   870   by blast
   871 
   872 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   873   by fast
   874 
   875 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   876   by blast
   877 
   878 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   879   by blast
   880 
   881 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   882   by blast
   883 
   884 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   885   by (blast elim: equalityE)
   886 
   887 
   888 subsubsection {* Unions of families *}
   889 
   890 text {*
   891   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   892 *}
   893 
   894 declare UNION_def [noatp]
   895 
   896 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   897   by (unfold UNION_def) blast
   898 
   899 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   900   -- {* The order of the premises presupposes that @{term A} is rigid;
   901     @{term b} may be flexible. *}
   902   by auto
   903 
   904 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   905   by (unfold UNION_def) blast
   906 
   907 lemma UN_cong [cong]:
   908     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   909   by (simp add: UNION_def)
   910 
   911 lemma strong_UN_cong:
   912     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   913   by (simp add: UNION_def simp_implies_def)
   914 
   915 
   916 subsubsection {* Intersections of families *}
   917 
   918 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   919 
   920 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   921   by (unfold INTER_def) blast
   922 
   923 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   924   by (unfold INTER_def) blast
   925 
   926 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   927   by auto
   928 
   929 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   930   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   931   by (unfold INTER_def) blast
   932 
   933 lemma INT_cong [cong]:
   934     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   935   by (simp add: INTER_def)
   936 
   937 
   938 subsubsection {* Union *}
   939 
   940 lemma Union_iff [simp,noatp]: "(A : Union C) = (EX X:C. A:X)"
   941   by (unfold Union_def) blast
   942 
   943 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   944   -- {* The order of the premises presupposes that @{term C} is rigid;
   945     @{term A} may be flexible. *}
   946   by auto
   947 
   948 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   949   by (unfold Union_def) blast
   950 
   951 
   952 subsubsection {* Inter *}
   953 
   954 lemma Inter_iff [simp,noatp]: "(A : Inter C) = (ALL X:C. A:X)"
   955   by (unfold Inter_def) blast
   956 
   957 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   958   by (simp add: Inter_def)
   959 
   960 text {*
   961   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   962   contains @{term A} as an element, but @{prop "A:X"} can hold when
   963   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   964 *}
   965 
   966 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   967   by auto
   968 
   969 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   970   -- {* ``Classical'' elimination rule -- does not require proving
   971     @{prop "X:C"}. *}
   972   by (unfold Inter_def) blast
   973 
   974 text {*
   975   \medskip Image of a set under a function.  Frequently @{term b} does
   976   not have the syntactic form of @{term "f x"}.
   977 *}
   978 
   979 declare image_def [noatp]
   980 
   981 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   982   by (unfold image_def) blast
   983 
   984 lemma imageI: "x : A ==> f x : f ` A"
   985   by (rule image_eqI) (rule refl)
   986 
   987 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   988   -- {* This version's more effective when we already have the
   989     required @{term x}. *}
   990   by (unfold image_def) blast
   991 
   992 lemma imageE [elim!]:
   993   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   994   -- {* The eta-expansion gives variable-name preservation. *}
   995   by (unfold image_def) blast
   996 
   997 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   998   by blast
   999 
  1000 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
  1001   by blast
  1002 
  1003 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
  1004   by blast
  1005 
  1006 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
  1007   -- {* This rewrite rule would confuse users if made default. *}
  1008   by blast
  1009 
  1010 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
  1011   apply safe
  1012    prefer 2 apply fast
  1013   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
  1014   done
  1015 
  1016 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
  1017   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
  1018     @{text hypsubst}, but breaks too many existing proofs. *}
  1019   by blast
  1020 
  1021 text {*
  1022   \medskip Range of a function -- just a translation for image!
  1023 *}
  1024 
  1025 lemma range_eqI: "b = f x ==> b \<in> range f"
  1026   by simp
  1027 
  1028 lemma rangeI: "f x \<in> range f"
  1029   by simp
  1030 
  1031 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
  1032   by blast
  1033 
  1034 
  1035 subsubsection {* Set reasoning tools *}
  1036 
  1037 text{* Elimination of @{text"{x. \<dots> & x=t & \<dots>}"}. *}
  1038 
  1039 lemma Collect_conv_if: "{x. x=a & P x} = (if P a then {a} else {})"
  1040 by auto
  1041 
  1042 lemma Collect_conv_if2: "{x. a=x & P x} = (if P a then {a} else {})"
  1043 by auto
  1044 
  1045 text {*
  1046 Simproc for pulling @{text "x=t"} in @{text "{x. \<dots> & x=t & \<dots>}"}
  1047 to the front (and similarly for @{text "t=x"}):
  1048 *}
  1049 
  1050 ML{*
  1051   local
  1052     val Coll_perm_tac = rtac @{thm Collect_cong} 1 THEN rtac @{thm iffI} 1 THEN
  1053     ALLGOALS(EVERY'[REPEAT_DETERM o (etac @{thm conjE}),
  1054                     DEPTH_SOLVE_1 o (ares_tac [@{thm conjI}])])
  1055   in
  1056     val defColl_regroup = Simplifier.simproc (the_context ())
  1057       "defined Collect" ["{x. P x & Q x}"]
  1058       (Quantifier1.rearrange_Coll Coll_perm_tac)
  1059   end;
  1060 
  1061   Addsimprocs [defColl_regroup];
  1062 *}
  1063 
  1064 text {*
  1065   Rewrite rules for boolean case-splitting: faster than @{text
  1066   "split_if [split]"}.
  1067 *}
  1068 
  1069 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
  1070   by (rule split_if)
  1071 
  1072 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
  1073   by (rule split_if)
  1074 
  1075 text {*
  1076   Split ifs on either side of the membership relation.  Not for @{text
  1077   "[simp]"} -- can cause goals to blow up!
  1078 *}
  1079 
  1080 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
  1081   by (rule split_if)
  1082 
  1083 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
  1084   by (rule split_if [where P="%S. a : S"])
  1085 
  1086 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
  1087 
  1088 (*Would like to add these, but the existing code only searches for the
  1089   outer-level constant, which in this case is just "op :"; we instead need
  1090   to use term-nets to associate patterns with rules.  Also, if a rule fails to
  1091   apply, then the formula should be kept.
  1092   [("HOL.uminus", Compl_iff RS iffD1), ("HOL.minus", [Diff_iff RS iffD1]),
  1093    ("Int", [IntD1,IntD2]),
  1094    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
  1095  *)
  1096 
  1097 ML {*
  1098   val mksimps_pairs = [(@{const_name Ball}, @{thms bspec})] @ mksimps_pairs;
  1099 *}
  1100 declaration {* fn _ =>
  1101   Simplifier.map_ss (fn ss => ss setmksimps (mksimps mksimps_pairs))
  1102 *}
  1103 
  1104 
  1105 subsubsection {* The ``proper subset'' relation *}
  1106 
  1107 lemma psubsetI [intro!,noatp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
  1108   by (unfold less_le) blast
  1109 
  1110 lemma psubsetE [elim!,noatp]: 
  1111     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
  1112   by (unfold less_le) blast
  1113 
  1114 lemma psubset_insert_iff:
  1115   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1116   by (auto simp add: less_le subset_insert_iff)
  1117 
  1118 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1119   by (simp only: less_le)
  1120 
  1121 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1122   by (simp add: psubset_eq)
  1123 
  1124 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1125 apply (unfold less_le)
  1126 apply (auto dest: subset_antisym)
  1127 done
  1128 
  1129 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1130 apply (unfold less_le)
  1131 apply (auto dest: subsetD)
  1132 done
  1133 
  1134 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1135   by (auto simp add: psubset_eq)
  1136 
  1137 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1138   by (auto simp add: psubset_eq)
  1139 
  1140 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1141   by (unfold less_le) blast
  1142 
  1143 lemma atomize_ball:
  1144     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1145   by (simp only: Ball_def atomize_all atomize_imp)
  1146 
  1147 lemmas [symmetric, rulify] = atomize_ball
  1148   and [symmetric, defn] = atomize_ball
  1149 
  1150 
  1151 subsection {* Further set-theory lemmas *}
  1152 
  1153 subsubsection {* Derived rules involving subsets. *}
  1154 
  1155 text {* @{text insert}. *}
  1156 
  1157 lemma subset_insertI: "B \<subseteq> insert a B"
  1158   by (rule subsetI) (erule insertI2)
  1159 
  1160 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1161   by blast
  1162 
  1163 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1164   by blast
  1165 
  1166 
  1167 text {* \medskip Big Union -- least upper bound of a set. *}
  1168 
  1169 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
  1170   by (iprover intro: subsetI UnionI)
  1171 
  1172 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
  1173   by (iprover intro: subsetI elim: UnionE dest: subsetD)
  1174 
  1175 
  1176 text {* \medskip General union. *}
  1177 
  1178 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1179   by blast
  1180 
  1181 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
  1182   by (iprover intro: subsetI elim: UN_E dest: subsetD)
  1183 
  1184 
  1185 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
  1186 
  1187 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
  1188   by blast
  1189 
  1190 lemma Inter_subset:
  1191   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
  1192   by blast
  1193 
  1194 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
  1195   by (iprover intro: InterI subsetI dest: subsetD)
  1196 
  1197 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1198   by blast
  1199 
  1200 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1201   by (iprover intro: INT_I subsetI dest: subsetD)
  1202 
  1203 
  1204 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1205 
  1206 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1207   by blast
  1208 
  1209 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1210   by blast
  1211 
  1212 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1213   by blast
  1214 
  1215 
  1216 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1217 
  1218 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1219   by blast
  1220 
  1221 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1222   by blast
  1223 
  1224 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1225   by blast
  1226 
  1227 
  1228 text {* \medskip Set difference. *}
  1229 
  1230 lemma Diff_subset: "A - B \<subseteq> A"
  1231   by blast
  1232 
  1233 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1234 by blast
  1235 
  1236 
  1237 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1238 
  1239 text {* @{text "{}"}. *}
  1240 
  1241 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1242   -- {* supersedes @{text "Collect_False_empty"} *}
  1243   by auto
  1244 
  1245 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1246   by blast
  1247 
  1248 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1249   by (unfold less_le) blast
  1250 
  1251 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1252 by blast
  1253 
  1254 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1255 by blast
  1256 
  1257 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1258   by blast
  1259 
  1260 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1261   by blast
  1262 
  1263 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1264   by blast
  1265 
  1266 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1267   by blast
  1268 
  1269 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1270   by blast
  1271 
  1272 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1273   by blast
  1274 
  1275 lemma Collect_ex_eq [noatp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1276   by blast
  1277 
  1278 lemma Collect_bex_eq [noatp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1279   by blast
  1280 
  1281 
  1282 text {* \medskip @{text insert}. *}
  1283 
  1284 lemma insert_is_Un: "insert a A = {a} Un A"
  1285   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1286   by blast
  1287 
  1288 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1289   by blast
  1290 
  1291 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1292 declare empty_not_insert [simp]
  1293 
  1294 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1295   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1296   -- {* with \emph{quadratic} running time *}
  1297   by blast
  1298 
  1299 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1300   by blast
  1301 
  1302 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1303   by blast
  1304 
  1305 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1306   by blast
  1307 
  1308 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1309   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1310   apply (rule_tac x = "A - {a}" in exI, blast)
  1311   done
  1312 
  1313 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1314   by auto
  1315 
  1316 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1317   by blast
  1318 
  1319 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1320   by blast
  1321 
  1322 lemma insert_disjoint [simp,noatp]:
  1323  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1324  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1325   by auto
  1326 
  1327 lemma disjoint_insert [simp,noatp]:
  1328  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1329  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1330   by auto
  1331 
  1332 text {* \medskip @{text image}. *}
  1333 
  1334 lemma image_empty [simp]: "f`{} = {}"
  1335   by blast
  1336 
  1337 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1338   by blast
  1339 
  1340 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1341   by auto
  1342 
  1343 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1344 by auto
  1345 
  1346 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1347 by blast
  1348 
  1349 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1350 by blast
  1351 
  1352 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1353 by blast
  1354 
  1355 lemma empty_is_image[iff]: "({} = f ` A) = (A = {})"
  1356 by blast
  1357 
  1358 
  1359 lemma image_Collect [noatp]: "f ` {x. P x} = {f x | x. P x}"
  1360   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1361       with its implicit quantifier and conjunction.  Also image enjoys better
  1362       equational properties than does the RHS. *}
  1363   by blast
  1364 
  1365 lemma if_image_distrib [simp]:
  1366   "(\<lambda>x. if P x then f x else g x) ` S
  1367     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1368   by (auto simp add: image_def)
  1369 
  1370 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1371   by (simp add: image_def)
  1372 
  1373 
  1374 text {* \medskip @{text range}. *}
  1375 
  1376 lemma full_SetCompr_eq [noatp]: "{u. \<exists>x. u = f x} = range f"
  1377   by auto
  1378 
  1379 lemma range_composition: "range (\<lambda>x. f (g x)) = f`range g"
  1380 by (subst image_image, simp)
  1381 
  1382 
  1383 text {* \medskip @{text Int} *}
  1384 
  1385 lemma Int_absorb [simp]: "A \<inter> A = A"
  1386   by blast
  1387 
  1388 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1389   by blast
  1390 
  1391 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1392   by blast
  1393 
  1394 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1395   by blast
  1396 
  1397 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1398   by blast
  1399 
  1400 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1401   -- {* Intersection is an AC-operator *}
  1402 
  1403 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1404   by blast
  1405 
  1406 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1407   by blast
  1408 
  1409 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1410   by blast
  1411 
  1412 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1413   by blast
  1414 
  1415 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1416   by blast
  1417 
  1418 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1419   by blast
  1420 
  1421 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1422   by blast
  1423 
  1424 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1425   by blast
  1426 
  1427 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1428   by blast
  1429 
  1430 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1431   by blast
  1432 
  1433 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1434   by blast
  1435 
  1436 lemma Int_UNIV [simp,noatp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1437   by blast
  1438 
  1439 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1440   by blast
  1441 
  1442 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1443   by blast
  1444 
  1445 
  1446 text {* \medskip @{text Un}. *}
  1447 
  1448 lemma Un_absorb [simp]: "A \<union> A = A"
  1449   by blast
  1450 
  1451 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1452   by blast
  1453 
  1454 lemma Un_commute: "A \<union> B = B \<union> A"
  1455   by blast
  1456 
  1457 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1458   by blast
  1459 
  1460 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1461   by blast
  1462 
  1463 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1464   -- {* Union is an AC-operator *}
  1465 
  1466 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1467   by blast
  1468 
  1469 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1470   by blast
  1471 
  1472 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1473   by blast
  1474 
  1475 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1476   by blast
  1477 
  1478 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1479   by blast
  1480 
  1481 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1482   by blast
  1483 
  1484 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1485   by blast
  1486 
  1487 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1488   by blast
  1489 
  1490 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1491   by blast
  1492 
  1493 lemma Int_insert_left:
  1494     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1495   by auto
  1496 
  1497 lemma Int_insert_right:
  1498     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1499   by auto
  1500 
  1501 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1502   by blast
  1503 
  1504 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1505   by blast
  1506 
  1507 lemma Un_Int_crazy:
  1508     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1509   by blast
  1510 
  1511 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1512   by blast
  1513 
  1514 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1515   by blast
  1516 
  1517 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1518   by blast
  1519 
  1520 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1521   by blast
  1522 
  1523 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1524   by blast
  1525 
  1526 
  1527 text {* \medskip Set complement *}
  1528 
  1529 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1530   by blast
  1531 
  1532 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1533   by blast
  1534 
  1535 lemma Compl_partition: "A \<union> -A = UNIV"
  1536   by blast
  1537 
  1538 lemma Compl_partition2: "-A \<union> A = UNIV"
  1539   by blast
  1540 
  1541 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1542   by blast
  1543 
  1544 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1545   by blast
  1546 
  1547 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1548   by blast
  1549 
  1550 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1551   by blast
  1552 
  1553 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1554   by blast
  1555 
  1556 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1557   by blast
  1558 
  1559 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1560   -- {* Halmos, Naive Set Theory, page 16. *}
  1561   by blast
  1562 
  1563 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1564   by blast
  1565 
  1566 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1567   by blast
  1568 
  1569 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1570   by blast
  1571 
  1572 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1573   by blast
  1574 
  1575 
  1576 text {* \medskip @{text Union}. *}
  1577 
  1578 lemma Union_empty [simp]: "Union({}) = {}"
  1579   by blast
  1580 
  1581 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1582   by blast
  1583 
  1584 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1585   by blast
  1586 
  1587 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1588   by blast
  1589 
  1590 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1591   by blast
  1592 
  1593 lemma Union_empty_conv [simp,noatp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1594   by blast
  1595 
  1596 lemma empty_Union_conv [simp,noatp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1597   by blast
  1598 
  1599 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1600   by blast
  1601 
  1602 
  1603 text {* \medskip @{text Inter}. *}
  1604 
  1605 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1606   by blast
  1607 
  1608 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1609   by blast
  1610 
  1611 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1612   by blast
  1613 
  1614 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1615   by blast
  1616 
  1617 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1618   by blast
  1619 
  1620 lemma Inter_UNIV_conv [simp,noatp]:
  1621   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1622   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1623   by blast+
  1624 
  1625 
  1626 text {*
  1627   \medskip @{text UN} and @{text INT}.
  1628 
  1629   Basic identities: *}
  1630 
  1631 lemma UN_empty [simp,noatp]: "(\<Union>x\<in>{}. B x) = {}"
  1632   by blast
  1633 
  1634 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1635   by blast
  1636 
  1637 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1638   by blast
  1639 
  1640 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1641   by auto
  1642 
  1643 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1644   by blast
  1645 
  1646 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1647   by blast
  1648 
  1649 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1650   by blast
  1651 
  1652 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1653   by blast
  1654 
  1655 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1656   by blast
  1657 
  1658 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1659   by blast
  1660 
  1661 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1662   by blast
  1663 
  1664 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1665   by blast
  1666 
  1667 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1668   by blast
  1669 
  1670 lemma INT_insert_distrib:
  1671     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1672   by blast
  1673 
  1674 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1675   by blast
  1676 
  1677 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1678   by blast
  1679 
  1680 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1681   by blast
  1682 
  1683 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1684   by auto
  1685 
  1686 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1687   by auto
  1688 
  1689 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1690   by blast
  1691 
  1692 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1693   -- {* Look: it has an \emph{existential} quantifier *}
  1694   by blast
  1695 
  1696 lemma UNION_empty_conv[simp]:
  1697   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1698   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1699 by blast+
  1700 
  1701 lemma INTER_UNIV_conv[simp]:
  1702  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1703  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1704 by blast+
  1705 
  1706 
  1707 text {* \medskip Distributive laws: *}
  1708 
  1709 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1710   by blast
  1711 
  1712 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1713   by blast
  1714 
  1715 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1716   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1717   -- {* Union of a family of unions *}
  1718   by blast
  1719 
  1720 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1721   -- {* Equivalent version *}
  1722   by blast
  1723 
  1724 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1725   by blast
  1726 
  1727 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1728   by blast
  1729 
  1730 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1731   -- {* Equivalent version *}
  1732   by blast
  1733 
  1734 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1735   -- {* Halmos, Naive Set Theory, page 35. *}
  1736   by blast
  1737 
  1738 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1739   by blast
  1740 
  1741 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1742   by blast
  1743 
  1744 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1745   by blast
  1746 
  1747 
  1748 text {* \medskip Bounded quantifiers.
  1749 
  1750   The following are not added to the default simpset because
  1751   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1752 
  1753 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1754   by blast
  1755 
  1756 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1757   by blast
  1758 
  1759 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1760   by blast
  1761 
  1762 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1763   by blast
  1764 
  1765 
  1766 text {* \medskip Set difference. *}
  1767 
  1768 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1769   by blast
  1770 
  1771 lemma Diff_eq_empty_iff [simp,noatp]: "(A - B = {}) = (A \<subseteq> B)"
  1772   by blast
  1773 
  1774 lemma Diff_cancel [simp]: "A - A = {}"
  1775   by blast
  1776 
  1777 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1778 by blast
  1779 
  1780 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1781   by (blast elim: equalityE)
  1782 
  1783 lemma empty_Diff [simp]: "{} - A = {}"
  1784   by blast
  1785 
  1786 lemma Diff_empty [simp]: "A - {} = A"
  1787   by blast
  1788 
  1789 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1790   by blast
  1791 
  1792 lemma Diff_insert0 [simp,noatp]: "x \<notin> A ==> A - insert x B = A - B"
  1793   by blast
  1794 
  1795 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1796   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1797   by blast
  1798 
  1799 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1800   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1801   by blast
  1802 
  1803 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1804   by auto
  1805 
  1806 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1807   by blast
  1808 
  1809 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1810 by blast
  1811 
  1812 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1813   by blast
  1814 
  1815 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1816   by auto
  1817 
  1818 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1819   by blast
  1820 
  1821 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1822   by blast
  1823 
  1824 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1825   by blast
  1826 
  1827 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1828   by blast
  1829 
  1830 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1831   by blast
  1832 
  1833 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1834   by blast
  1835 
  1836 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1837   by blast
  1838 
  1839 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1840   by blast
  1841 
  1842 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1843   by blast
  1844 
  1845 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1846   by blast
  1847 
  1848 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1849   by blast
  1850 
  1851 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1852   by auto
  1853 
  1854 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1855   by blast
  1856 
  1857 
  1858 text {* \medskip Quantification over type @{typ bool}. *}
  1859 
  1860 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1861   by (cases x) auto
  1862 
  1863 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1864   by (auto intro: bool_induct)
  1865 
  1866 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1867   by (cases x) auto
  1868 
  1869 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1870   by (auto intro: bool_contrapos)
  1871 
  1872 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1873   by (auto simp add: split_if_mem2)
  1874 
  1875 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1876   by (auto intro: bool_contrapos)
  1877 
  1878 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1879   by (auto intro: bool_induct)
  1880 
  1881 text {* \medskip @{text Pow} *}
  1882 
  1883 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1884   by (auto simp add: Pow_def)
  1885 
  1886 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1887   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1888 
  1889 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1890   by (blast intro: exI [where ?x = "- u", standard])
  1891 
  1892 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1893   by blast
  1894 
  1895 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1896   by blast
  1897 
  1898 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1899   by blast
  1900 
  1901 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1902   by blast
  1903 
  1904 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1905   by blast
  1906 
  1907 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1908   by blast
  1909 
  1910 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1911   by blast
  1912 
  1913 
  1914 text {* \medskip Miscellany. *}
  1915 
  1916 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1917   by blast
  1918 
  1919 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1920   by blast
  1921 
  1922 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1923   by (unfold less_le) blast
  1924 
  1925 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1926   by blast
  1927 
  1928 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1929   by blast
  1930 
  1931 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1932   by iprover
  1933 
  1934 
  1935 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1936            and Intersections. *}
  1937 
  1938 lemma UN_simps [simp]:
  1939   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1940   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1941   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1942   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1943   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1944   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1945   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1946   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1947   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1948   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1949   by auto
  1950 
  1951 lemma INT_simps [simp]:
  1952   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1953   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1954   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1955   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1956   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1957   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1958   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1959   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1960   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1961   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1962   by auto
  1963 
  1964 lemma ball_simps [simp,noatp]:
  1965   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1966   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1967   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1968   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1969   "!!P. (ALL x:{}. P x) = True"
  1970   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1971   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1972   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1973   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1974   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1975   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1976   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1977   by auto
  1978 
  1979 lemma bex_simps [simp,noatp]:
  1980   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1981   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1982   "!!P. (EX x:{}. P x) = False"
  1983   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1984   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1985   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1986   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1987   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1988   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1989   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1990   by auto
  1991 
  1992 lemma ball_conj_distrib:
  1993   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1994   by blast
  1995 
  1996 lemma bex_disj_distrib:
  1997   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1998   by blast
  1999 
  2000 
  2001 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  2002 
  2003 lemma UN_extend_simps:
  2004   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  2005   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  2006   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  2007   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  2008   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  2009   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  2010   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  2011   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  2012   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  2013   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  2014   by auto
  2015 
  2016 lemma INT_extend_simps:
  2017   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  2018   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  2019   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  2020   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  2021   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  2022   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  2023   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  2024   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  2025   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  2026   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  2027   by auto
  2028 
  2029 
  2030 subsubsection {* Monotonicity of various operations *}
  2031 
  2032 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  2033   by blast
  2034 
  2035 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  2036   by blast
  2037 
  2038 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  2039   by blast
  2040 
  2041 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  2042   by blast
  2043 
  2044 lemma UN_mono:
  2045   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2046     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  2047   by (blast dest: subsetD)
  2048 
  2049 lemma INT_anti_mono:
  2050   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2051     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  2052   -- {* The last inclusion is POSITIVE! *}
  2053   by (blast dest: subsetD)
  2054 
  2055 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  2056   by blast
  2057 
  2058 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  2059   by blast
  2060 
  2061 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  2062   by blast
  2063 
  2064 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  2065   by blast
  2066 
  2067 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  2068   by blast
  2069 
  2070 text {* \medskip Monotonicity of implications. *}
  2071 
  2072 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  2073   apply (rule impI)
  2074   apply (erule subsetD, assumption)
  2075   done
  2076 
  2077 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  2078   by iprover
  2079 
  2080 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  2081   by iprover
  2082 
  2083 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  2084   by iprover
  2085 
  2086 lemma imp_refl: "P --> P" ..
  2087 
  2088 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  2089   by iprover
  2090 
  2091 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  2092   by iprover
  2093 
  2094 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  2095   by blast
  2096 
  2097 lemma Int_Collect_mono:
  2098     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  2099   by blast
  2100 
  2101 lemmas basic_monos =
  2102   subset_refl imp_refl disj_mono conj_mono
  2103   ex_mono Collect_mono in_mono
  2104 
  2105 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  2106   by iprover
  2107 
  2108 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  2109   by iprover
  2110 
  2111 
  2112 subsection {* Inverse image of a function *}
  2113 
  2114 constdefs
  2115   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  2116   [code del]: "f -` B == {x. f x : B}"
  2117 
  2118 
  2119 subsubsection {* Basic rules *}
  2120 
  2121 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  2122   by (unfold vimage_def) blast
  2123 
  2124 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  2125   by simp
  2126 
  2127 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  2128   by (unfold vimage_def) blast
  2129 
  2130 lemma vimageI2: "f a : A ==> a : f -` A"
  2131   by (unfold vimage_def) fast
  2132 
  2133 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  2134   by (unfold vimage_def) blast
  2135 
  2136 lemma vimageD: "a : f -` A ==> f a : A"
  2137   by (unfold vimage_def) fast
  2138 
  2139 
  2140 subsubsection {* Equations *}
  2141 
  2142 lemma vimage_empty [simp]: "f -` {} = {}"
  2143   by blast
  2144 
  2145 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  2146   by blast
  2147 
  2148 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  2149   by blast
  2150 
  2151 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  2152   by fast
  2153 
  2154 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  2155   by blast
  2156 
  2157 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  2158   by blast
  2159 
  2160 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  2161   by blast
  2162 
  2163 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  2164   by blast
  2165 
  2166 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  2167   by blast
  2168 
  2169 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  2170   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  2171   by blast
  2172 
  2173 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  2174   by blast
  2175 
  2176 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  2177   by blast
  2178 
  2179 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  2180   -- {* NOT suitable for rewriting *}
  2181   by blast
  2182 
  2183 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  2184   -- {* monotonicity *}
  2185   by blast
  2186 
  2187 lemma vimage_image_eq [noatp]: "f -` (f ` A) = {y. EX x:A. f x = f y}"
  2188 by (blast intro: sym)
  2189 
  2190 lemma image_vimage_subset: "f ` (f -` A) <= A"
  2191 by blast
  2192 
  2193 lemma image_vimage_eq [simp]: "f ` (f -` A) = A Int range f"
  2194 by blast
  2195 
  2196 lemma image_Int_subset: "f`(A Int B) <= f`A Int f`B"
  2197 by blast
  2198 
  2199 lemma image_diff_subset: "f`A - f`B <= f`(A - B)"
  2200 by blast
  2201 
  2202 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
  2203 by blast
  2204 
  2205 
  2206 subsection {* Getting the Contents of a Singleton Set *}
  2207 
  2208 definition contents :: "'a set \<Rightarrow> 'a" where
  2209   [code del]: "contents X = (THE x. X = {x})"
  2210 
  2211 lemma contents_eq [simp]: "contents {x} = x"
  2212   by (simp add: contents_def)
  2213 
  2214 
  2215 subsection {* Transitivity rules for calculational reasoning *}
  2216 
  2217 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  2218   by (rule subsetD)
  2219 
  2220 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  2221   by (rule subsetD)
  2222 
  2223 lemmas basic_trans_rules [trans] =
  2224   order_trans_rules set_rev_mp set_mp
  2225 
  2226 
  2227 subsection {* Least value operator *}
  2228 
  2229 lemma Least_mono:
  2230   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  2231     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  2232     -- {* Courtesy of Stephan Merz *}
  2233   apply clarify
  2234   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  2235   apply (rule LeastI2_order)
  2236   apply (auto elim: monoD intro!: order_antisym)
  2237   done
  2238 
  2239 
  2240 subsection {* Rudimentary code generation *}
  2241 
  2242 lemma empty_code [code]: "{} x \<longleftrightarrow> False"
  2243   unfolding empty_def Collect_def ..
  2244 
  2245 lemma UNIV_code [code]: "UNIV x \<longleftrightarrow> True"
  2246   unfolding UNIV_def Collect_def ..
  2247 
  2248 lemma insert_code [code]: "insert y A x \<longleftrightarrow> y = x \<or> A x"
  2249   unfolding insert_def Collect_def mem_def Un_def by auto
  2250 
  2251 lemma inter_code [code]: "(A \<inter> B) x \<longleftrightarrow> A x \<and> B x"
  2252   unfolding Int_def Collect_def mem_def ..
  2253 
  2254 lemma union_code [code]: "(A \<union> B) x \<longleftrightarrow> A x \<or> B x"
  2255   unfolding Un_def Collect_def mem_def ..
  2256 
  2257 lemma vimage_code [code]: "(f -` A) x = A (f x)"
  2258   unfolding vimage_def Collect_def mem_def ..
  2259 
  2260 
  2261 subsection {* Complete lattices *}
  2262 
  2263 notation
  2264   less_eq  (infix "\<sqsubseteq>" 50) and
  2265   less (infix "\<sqsubset>" 50) and
  2266   inf  (infixl "\<sqinter>" 70) and
  2267   sup  (infixl "\<squnion>" 65)
  2268 
  2269 class complete_lattice = lattice + bot + top +
  2270   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
  2271     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
  2272   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
  2273      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
  2274   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
  2275      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
  2276 begin
  2277 
  2278 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<le> a}"
  2279   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2280 
  2281 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<le> b}"
  2282   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2283 
  2284 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
  2285   unfolding Sup_Inf by auto
  2286 
  2287 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
  2288   unfolding Inf_Sup by auto
  2289 
  2290 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
  2291   by (auto intro: antisym Inf_greatest Inf_lower)
  2292 
  2293 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
  2294   by (auto intro: antisym Sup_least Sup_upper)
  2295 
  2296 lemma Inf_singleton [simp]:
  2297   "\<Sqinter>{a} = a"
  2298   by (auto intro: antisym Inf_lower Inf_greatest)
  2299 
  2300 lemma Sup_singleton [simp]:
  2301   "\<Squnion>{a} = a"
  2302   by (auto intro: antisym Sup_upper Sup_least)
  2303 
  2304 lemma Inf_insert_simp:
  2305   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
  2306   by (cases "A = {}") (simp_all, simp add: Inf_insert)
  2307 
  2308 lemma Sup_insert_simp:
  2309   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
  2310   by (cases "A = {}") (simp_all, simp add: Sup_insert)
  2311 
  2312 lemma Inf_binary:
  2313   "\<Sqinter>{a, b} = a \<sqinter> b"
  2314   by (simp add: Inf_insert_simp)
  2315 
  2316 lemma Sup_binary:
  2317   "\<Squnion>{a, b} = a \<squnion> b"
  2318   by (simp add: Sup_insert_simp)
  2319 
  2320 lemma bot_def:
  2321   "bot = \<Squnion>{}"
  2322   by (auto intro: antisym Sup_least)
  2323 
  2324 lemma top_def:
  2325   "top = \<Sqinter>{}"
  2326   by (auto intro: antisym Inf_greatest)
  2327 
  2328 lemma sup_bot [simp]:
  2329   "x \<squnion> bot = x"
  2330   using bot_least [of x] by (simp add: le_iff_sup sup_commute)
  2331 
  2332 lemma inf_top [simp]:
  2333   "x \<sqinter> top = x"
  2334   using top_greatest [of x] by (simp add: le_iff_inf inf_commute)
  2335 
  2336 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2337   "SUPR A f == \<Squnion> (f ` A)"
  2338 
  2339 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2340   "INFI A f == \<Sqinter> (f ` A)"
  2341 
  2342 end
  2343 
  2344 syntax
  2345   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
  2346   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
  2347   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
  2348   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
  2349 
  2350 translations
  2351   "SUP x y. B"   == "SUP x. SUP y. B"
  2352   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
  2353   "SUP x. B"     == "SUP x:CONST UNIV. B"
  2354   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
  2355   "INF x y. B"   == "INF x. INF y. B"
  2356   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
  2357   "INF x. B"     == "INF x:CONST UNIV. B"
  2358   "INF x:A. B"   == "CONST INFI A (%x. B)"
  2359 
  2360 (* To avoid eta-contraction of body: *)
  2361 print_translation {*
  2362 let
  2363   fun btr' syn (A :: Abs abs :: ts) =
  2364     let val (x,t) = atomic_abs_tr' abs
  2365     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
  2366   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
  2367 in
  2368 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
  2369 end
  2370 *}
  2371 
  2372 context complete_lattice
  2373 begin
  2374 
  2375 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
  2376   by (auto simp add: SUPR_def intro: Sup_upper)
  2377 
  2378 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
  2379   by (auto simp add: SUPR_def intro: Sup_least)
  2380 
  2381 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
  2382   by (auto simp add: INFI_def intro: Inf_lower)
  2383 
  2384 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
  2385   by (auto simp add: INFI_def intro: Inf_greatest)
  2386 
  2387 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
  2388   by (auto intro: antisym SUP_leI le_SUPI)
  2389 
  2390 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
  2391   by (auto intro: antisym INF_leI le_INFI)
  2392 
  2393 end
  2394 
  2395 
  2396 subsection {* Bool as complete lattice *}
  2397 
  2398 instantiation bool :: complete_lattice
  2399 begin
  2400 
  2401 definition
  2402   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
  2403 
  2404 definition
  2405   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
  2406 
  2407 instance
  2408   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
  2409 
  2410 end
  2411 
  2412 lemma Inf_empty_bool [simp]:
  2413   "\<Sqinter>{}"
  2414   unfolding Inf_bool_def by auto
  2415 
  2416 lemma not_Sup_empty_bool [simp]:
  2417   "\<not> \<Squnion>{}"
  2418   unfolding Sup_bool_def by auto
  2419 
  2420 
  2421 subsection {* Fun as complete lattice *}
  2422 
  2423 instantiation "fun" :: (type, complete_lattice) complete_lattice
  2424 begin
  2425 
  2426 definition
  2427   Inf_fun_def [code del]: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
  2428 
  2429 definition
  2430   Sup_fun_def [code del]: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
  2431 
  2432 instance
  2433   by intro_classes
  2434     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
  2435       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
  2436 
  2437 end
  2438 
  2439 lemma Inf_empty_fun:
  2440   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
  2441   by rule (auto simp add: Inf_fun_def)
  2442 
  2443 lemma Sup_empty_fun:
  2444   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
  2445   by rule (auto simp add: Sup_fun_def)
  2446 
  2447 
  2448 subsection {* Set as lattice *}
  2449 
  2450 lemma inf_set_eq: "A \<sqinter> B = A \<inter> B"
  2451   apply (rule subset_antisym)
  2452   apply (rule Int_greatest)
  2453   apply (rule inf_le1)
  2454   apply (rule inf_le2)
  2455   apply (rule inf_greatest)
  2456   apply (rule Int_lower1)
  2457   apply (rule Int_lower2)
  2458   done
  2459 
  2460 lemma sup_set_eq: "A \<squnion> B = A \<union> B"
  2461   apply (rule subset_antisym)
  2462   apply (rule sup_least)
  2463   apply (rule Un_upper1)
  2464   apply (rule Un_upper2)
  2465   apply (rule Un_least)
  2466   apply (rule sup_ge1)
  2467   apply (rule sup_ge2)
  2468   done
  2469 
  2470 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
  2471   apply (fold inf_set_eq sup_set_eq)
  2472   apply (erule mono_inf)
  2473   done
  2474 
  2475 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
  2476   apply (fold inf_set_eq sup_set_eq)
  2477   apply (erule mono_sup)
  2478   done
  2479 
  2480 lemma Inf_set_eq: "\<Sqinter>S = \<Inter>S"
  2481   apply (rule subset_antisym)
  2482   apply (rule Inter_greatest)
  2483   apply (erule Inf_lower)
  2484   apply (rule Inf_greatest)
  2485   apply (erule Inter_lower)
  2486   done
  2487 
  2488 lemma Sup_set_eq: "\<Squnion>S = \<Union>S"
  2489   apply (rule subset_antisym)
  2490   apply (rule Sup_least)
  2491   apply (erule Union_upper)
  2492   apply (rule Union_least)
  2493   apply (erule Sup_upper)
  2494   done
  2495   
  2496 lemma top_set_eq: "top = UNIV"
  2497   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
  2498 
  2499 lemma bot_set_eq: "bot = {}"
  2500   by (iprover intro!: subset_antisym empty_subsetI bot_least)
  2501 
  2502 no_notation
  2503   less_eq  (infix "\<sqsubseteq>" 50) and
  2504   less (infix "\<sqsubset>" 50) and
  2505   inf  (infixl "\<sqinter>" 70) and
  2506   sup  (infixl "\<squnion>" 65) and
  2507   Inf  ("\<Sqinter>_" [900] 900) and
  2508   Sup  ("\<Squnion>_" [900] 900)
  2509 
  2510 
  2511 subsection {* Misc theorem and ML bindings *}
  2512 
  2513 lemmas equalityI = subset_antisym
  2514 lemmas mem_simps =
  2515   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  2516   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  2517   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  2518 
  2519 ML {*
  2520 val Ball_def = @{thm Ball_def}
  2521 val Bex_def = @{thm Bex_def}
  2522 val CollectD = @{thm CollectD}
  2523 val CollectE = @{thm CollectE}
  2524 val CollectI = @{thm CollectI}
  2525 val Collect_conj_eq = @{thm Collect_conj_eq}
  2526 val Collect_mem_eq = @{thm Collect_mem_eq}
  2527 val IntD1 = @{thm IntD1}
  2528 val IntD2 = @{thm IntD2}
  2529 val IntE = @{thm IntE}
  2530 val IntI = @{thm IntI}
  2531 val Int_Collect = @{thm Int_Collect}
  2532 val UNIV_I = @{thm UNIV_I}
  2533 val UNIV_witness = @{thm UNIV_witness}
  2534 val UnE = @{thm UnE}
  2535 val UnI1 = @{thm UnI1}
  2536 val UnI2 = @{thm UnI2}
  2537 val ballE = @{thm ballE}
  2538 val ballI = @{thm ballI}
  2539 val bexCI = @{thm bexCI}
  2540 val bexE = @{thm bexE}
  2541 val bexI = @{thm bexI}
  2542 val bex_triv = @{thm bex_triv}
  2543 val bspec = @{thm bspec}
  2544 val contra_subsetD = @{thm contra_subsetD}
  2545 val distinct_lemma = @{thm distinct_lemma}
  2546 val eq_to_mono = @{thm eq_to_mono}
  2547 val eq_to_mono2 = @{thm eq_to_mono2}
  2548 val equalityCE = @{thm equalityCE}
  2549 val equalityD1 = @{thm equalityD1}
  2550 val equalityD2 = @{thm equalityD2}
  2551 val equalityE = @{thm equalityE}
  2552 val equalityI = @{thm equalityI}
  2553 val imageE = @{thm imageE}
  2554 val imageI = @{thm imageI}
  2555 val image_Un = @{thm image_Un}
  2556 val image_insert = @{thm image_insert}
  2557 val insert_commute = @{thm insert_commute}
  2558 val insert_iff = @{thm insert_iff}
  2559 val mem_Collect_eq = @{thm mem_Collect_eq}
  2560 val rangeE = @{thm rangeE}
  2561 val rangeI = @{thm rangeI}
  2562 val range_eqI = @{thm range_eqI}
  2563 val subsetCE = @{thm subsetCE}
  2564 val subsetD = @{thm subsetD}
  2565 val subsetI = @{thm subsetI}
  2566 val subset_refl = @{thm subset_refl}
  2567 val subset_trans = @{thm subset_trans}
  2568 val vimageD = @{thm vimageD}
  2569 val vimageE = @{thm vimageE}
  2570 val vimageI = @{thm vimageI}
  2571 val vimageI2 = @{thm vimageI2}
  2572 val vimage_Collect = @{thm vimage_Collect}
  2573 val vimage_Int = @{thm vimage_Int}
  2574 val vimage_Un = @{thm vimage_Un}
  2575 *}
  2576 
  2577 end