src/HOL/Orderings.thy
author wenzelm
Tue Jun 19 23:15:23 2007 +0200 (2007-06-19)
changeset 23417 42c1a89b45c1
parent 23263 0c227412b285
child 23881 851c74f1bb69
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports HOL
    10 uses
    11   (*"~~/src/Provers/quasi.ML"*)
    12   "~~/src/Provers/order.ML"
    13 begin
    14 
    15 subsection {* Order syntax *}
    16 
    17 class ord = type +
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
    19     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
    20 begin
    21 
    22 notation
    23   less_eq  ("op \<^loc><=") and
    24   less_eq  ("(_/ \<^loc><= _)" [51, 51] 50) and
    25   less  ("op \<^loc><") and
    26   less  ("(_/ \<^loc>< _)"  [51, 51] 50)
    27   
    28 notation (xsymbols)
    29   less_eq  ("op \<^loc>\<le>") and
    30   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    31 
    32 notation (HTML output)
    33   less_eq  ("op \<^loc>\<le>") and
    34   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    35 
    36 abbreviation (input)
    37   greater  (infix "\<^loc>>" 50) where
    38   "x \<^loc>> y \<equiv> y \<^loc>< x"
    39 
    40 abbreviation (input)
    41   greater_eq  (infix "\<^loc>>=" 50) where
    42   "x \<^loc>>= y \<equiv> y \<^loc><= x"
    43 
    44 notation (input)
    45   greater_eq  (infix "\<^loc>\<ge>" 50)
    46 
    47 text {*
    48   syntactic min/max -- these definitions reach
    49   their usual semantics in class linorder ahead.
    50 *}
    51 
    52 definition
    53   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
    54   "min a b = (if a \<^loc>\<le> b then a else b)"
    55 
    56 definition
    57   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
    58   "max a b = (if a \<^loc>\<le> b then b else a)"
    59 
    60 end
    61 
    62 notation
    63   less_eq  ("op <=") and
    64   less_eq  ("(_/ <= _)" [51, 51] 50) and
    65   less  ("op <") and
    66   less  ("(_/ < _)"  [51, 51] 50)
    67   
    68 notation (xsymbols)
    69   less_eq  ("op \<le>") and
    70   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    71 
    72 notation (HTML output)
    73   less_eq  ("op \<le>") and
    74   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    75 
    76 abbreviation (input)
    77   greater  (infix ">" 50) where
    78   "x > y \<equiv> y < x"
    79 
    80 abbreviation (input)
    81   greater_eq  (infix ">=" 50) where
    82   "x >= y \<equiv> y <= x"
    83 
    84 notation (input)
    85   greater_eq  (infix "\<ge>" 50)
    86 
    87 lemmas min_def [code func, code unfold, code inline del] = min_def [folded ord_class.min]
    88 lemmas max_def [code func, code unfold, code inline del] = max_def [folded ord_class.max]
    89 
    90 
    91 subsection {* Partial orders *}
    92 
    93 class order = ord +
    94   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    95   and order_refl [iff]: "x \<sqsubseteq> x"
    96   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    97   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    98 
    99 begin
   100 
   101 text {* Reflexivity. *}
   102 
   103 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
   104     -- {* This form is useful with the classical reasoner. *}
   105 by (erule ssubst) (rule order_refl)
   106 
   107 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
   108 by (simp add: less_le)
   109 
   110 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
   111     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   112 by (simp add: less_le) blast
   113 
   114 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
   115 unfolding less_le by blast
   116 
   117 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
   118 unfolding less_le by blast
   119 
   120 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
   121 by (erule contrapos_pn, erule subst, rule less_irrefl)
   122 
   123 
   124 text {* Useful for simplification, but too risky to include by default. *}
   125 
   126 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   127 by auto
   128 
   129 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   130 by auto
   131 
   132 
   133 text {* Transitivity rules for calculational reasoning *}
   134 
   135 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
   136 by (simp add: less_le)
   137 
   138 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
   139 by (simp add: less_le)
   140 
   141 
   142 text {* Asymmetry. *}
   143 
   144 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
   145 by (simp add: less_le antisym)
   146 
   147 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
   148 by (drule less_not_sym, erule contrapos_np) simp
   149 
   150 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
   151 by (blast intro: antisym)
   152 
   153 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   154 by (blast intro: antisym)
   155 
   156 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
   157 by (erule contrapos_pn, erule subst, rule less_irrefl)
   158 
   159 
   160 text {* Transitivity. *}
   161 
   162 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
   163 by (simp add: less_le) (blast intro: order_trans antisym)
   164 
   165 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
   166 by (simp add: less_le) (blast intro: order_trans antisym)
   167 
   168 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
   169 by (simp add: less_le) (blast intro: order_trans antisym)
   170 
   171 
   172 text {* Useful for simplification, but too risky to include by default. *}
   173 
   174 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
   175 by (blast elim: less_asym)
   176 
   177 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   178 by (blast elim: less_asym)
   179 
   180 
   181 text {* Transitivity rules for calculational reasoning *}
   182 
   183 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   184 by (rule less_asym)
   185 
   186 
   187 text {* Reverse order *}
   188 
   189 lemma order_reverse:
   190   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   191 by unfold_locales
   192    (simp add: less_le, auto intro: antisym order_trans)
   193 
   194 end
   195 
   196 
   197 subsection {* Linear (total) orders *}
   198 
   199 class linorder = order +
   200   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   201 begin
   202 
   203 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   204 unfolding less_le using less_le linear by blast
   205 
   206 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   207 by (simp add: le_less less_linear)
   208 
   209 lemma le_cases [case_names le ge]:
   210   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   211 using linear by blast
   212 
   213 lemma linorder_cases [case_names less equal greater]:
   214   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   215 using less_linear by blast
   216 
   217 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   218 apply (simp add: less_le)
   219 using linear apply (blast intro: antisym)
   220 done
   221 
   222 lemma not_less_iff_gr_or_eq:
   223  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   224 apply(simp add:not_less le_less)
   225 apply blast
   226 done
   227 
   228 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   229 apply (simp add: less_le)
   230 using linear apply (blast intro: antisym)
   231 done
   232 
   233 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   234 by (cut_tac x = x and y = y in less_linear, auto)
   235 
   236 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   237 by (simp add: neq_iff) blast
   238 
   239 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   240 by (blast intro: antisym dest: not_less [THEN iffD1])
   241 
   242 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   243 by (blast intro: antisym dest: not_less [THEN iffD1])
   244 
   245 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   246 by (blast intro: antisym dest: not_less [THEN iffD1])
   247 
   248 text{*Replacing the old Nat.leI*}
   249 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   250 unfolding not_less .
   251 
   252 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   253 unfolding not_less .
   254 
   255 (*FIXME inappropriate name (or delete altogether)*)
   256 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   257 unfolding not_le .
   258 
   259 
   260 text {* Reverse order *}
   261 
   262 lemma linorder_reverse:
   263   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   264 by unfold_locales
   265   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   266 
   267 
   268 text {* min/max properties *}
   269 
   270 lemma min_le_iff_disj:
   271   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   272 unfolding min_def using linear by (auto intro: order_trans)
   273 
   274 lemma le_max_iff_disj:
   275   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   276 unfolding max_def using linear by (auto intro: order_trans)
   277 
   278 lemma min_less_iff_disj:
   279   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   280 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   281 
   282 lemma less_max_iff_disj:
   283   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   284 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   285 
   286 lemma min_less_iff_conj [simp]:
   287   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   288 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   289 
   290 lemma max_less_iff_conj [simp]:
   291   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   292 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   293 
   294 lemma split_min:
   295   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   296 by (simp add: min_def)
   297 
   298 lemma split_max:
   299   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   300 by (simp add: max_def)
   301 
   302 end
   303 
   304 subsection {* Name duplicates -- including min/max interpretation *}
   305 
   306 lemmas order_less_le = less_le
   307 lemmas order_eq_refl = order_class.eq_refl
   308 lemmas order_less_irrefl = order_class.less_irrefl
   309 lemmas order_le_less = order_class.le_less
   310 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   311 lemmas order_less_imp_le = order_class.less_imp_le
   312 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   313 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   314 lemmas order_neq_le_trans = order_class.neq_le_trans
   315 lemmas order_le_neq_trans = order_class.le_neq_trans
   316 
   317 lemmas order_antisym = antisym
   318 lemmas order_less_not_sym = order_class.less_not_sym
   319 lemmas order_less_asym = order_class.less_asym
   320 lemmas order_eq_iff = order_class.eq_iff
   321 lemmas order_antisym_conv = order_class.antisym_conv
   322 lemmas order_less_trans = order_class.less_trans
   323 lemmas order_le_less_trans = order_class.le_less_trans
   324 lemmas order_less_le_trans = order_class.less_le_trans
   325 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   326 lemmas order_less_imp_triv = order_class.less_imp_triv
   327 lemmas order_less_asym' = order_class.less_asym'
   328 
   329 lemmas linorder_linear = linear
   330 lemmas linorder_less_linear = linorder_class.less_linear
   331 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   332 lemmas linorder_le_cases = linorder_class.le_cases
   333 lemmas linorder_not_less = linorder_class.not_less
   334 lemmas linorder_not_le = linorder_class.not_le
   335 lemmas linorder_neq_iff = linorder_class.neq_iff
   336 lemmas linorder_neqE = linorder_class.neqE
   337 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   338 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   339 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   340 
   341 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj [folded ord_class.min]
   342 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj [folded ord_class.max]
   343 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj [folded ord_class.min]
   344 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj [folded ord_class.max]
   345 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj [folded ord_class.min]
   346 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj [folded ord_class.max]
   347 lemmas split_min = linorder_class.split_min [folded ord_class.min]
   348 lemmas split_max = linorder_class.split_max [folded ord_class.max]
   349 
   350 
   351 subsection {* Reasoning tools setup *}
   352 
   353 ML {*
   354 local
   355 
   356 fun decomp_gen sort thy (Trueprop $ t) =
   357   let
   358     fun of_sort t =
   359       let
   360         val T = type_of t
   361       in
   362         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   363         T <> HOLogic.natT andalso T <> HOLogic.intT
   364           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   365       end;
   366     fun dec (Const (@{const_name Not}, _) $ t) = (case dec t
   367           of NONE => NONE
   368            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   369       | dec (Const (@{const_name "op ="},  _) $ t1 $ t2) =
   370           if of_sort t1
   371           then SOME (t1, "=", t2)
   372           else NONE
   373       | dec (Const (@{const_name Orderings.less_eq},  _) $ t1 $ t2) =
   374           if of_sort t1
   375           then SOME (t1, "<=", t2)
   376           else NONE
   377       | dec (Const (@{const_name Orderings.less},  _) $ t1 $ t2) =
   378           if of_sort t1
   379           then SOME (t1, "<", t2)
   380           else NONE
   381       | dec _ = NONE;
   382   in dec t end;
   383 
   384 in
   385 
   386 (* sorry - there is no preorder class
   387 structure Quasi_Tac = Quasi_Tac_Fun (
   388 struct
   389   val le_trans = thm "order_trans";
   390   val le_refl = thm "order_refl";
   391   val eqD1 = thm "order_eq_refl";
   392   val eqD2 = thm "sym" RS thm "order_eq_refl";
   393   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   394   val less_imp_le = thm "order_less_imp_le";
   395   val le_neq_trans = thm "order_le_neq_trans";
   396   val neq_le_trans = thm "order_neq_le_trans";
   397   val less_imp_neq = thm "less_imp_neq";
   398   val decomp_trans = decomp_gen ["Orderings.preorder"];
   399   val decomp_quasi = decomp_gen ["Orderings.preorder"];
   400 end);*)
   401 
   402 structure Order_Tac = Order_Tac_Fun (
   403 struct
   404   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   405   val le_refl = thm "order_refl";
   406   val less_imp_le = thm "order_less_imp_le";
   407   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   408   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   409   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   410   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   411   val eqI = thm "order_antisym";
   412   val eqD1 = thm "order_eq_refl";
   413   val eqD2 = thm "sym" RS thm "order_eq_refl";
   414   val less_trans = thm "order_less_trans";
   415   val less_le_trans = thm "order_less_le_trans";
   416   val le_less_trans = thm "order_le_less_trans";
   417   val le_trans = thm "order_trans";
   418   val le_neq_trans = thm "order_le_neq_trans";
   419   val neq_le_trans = thm "order_neq_le_trans";
   420   val less_imp_neq = thm "less_imp_neq";
   421   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   422   val not_sym = thm "not_sym";
   423   val decomp_part = decomp_gen ["Orderings.order"];
   424   val decomp_lin = decomp_gen ["Orderings.linorder"];
   425 end);
   426 
   427 end;
   428 *}
   429 
   430 setup {*
   431 let
   432 
   433 fun prp t thm = (#prop (rep_thm thm) = t);
   434 
   435 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   436   let val prems = prems_of_ss ss;
   437       val less = Const (@{const_name less}, T);
   438       val t = HOLogic.mk_Trueprop(le $ s $ r);
   439   in case find_first (prp t) prems of
   440        NONE =>
   441          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   442          in case find_first (prp t) prems of
   443               NONE => NONE
   444             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv1}))
   445          end
   446      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_antisym_conv}))
   447   end
   448   handle THM _ => NONE;
   449 
   450 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   451   let val prems = prems_of_ss ss;
   452       val le = Const (@{const_name less_eq}, T);
   453       val t = HOLogic.mk_Trueprop(le $ r $ s);
   454   in case find_first (prp t) prems of
   455        NONE =>
   456          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   457          in case find_first (prp t) prems of
   458               NONE => NONE
   459             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv3}))
   460          end
   461      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv2}))
   462   end
   463   handle THM _ => NONE;
   464 
   465 fun add_simprocs procs thy =
   466   (Simplifier.change_simpset_of thy (fn ss => ss
   467     addsimprocs (map (fn (name, raw_ts, proc) =>
   468       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   469 fun add_solver name tac thy =
   470   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   471     (mk_solver name (K tac))); thy);
   472 
   473 in
   474   add_simprocs [
   475        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   476        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   477      ]
   478   #> add_solver "Trans_linear" Order_Tac.linear_tac
   479   #> add_solver "Trans_partial" Order_Tac.partial_tac
   480   (* Adding the transitivity reasoners also as safe solvers showed a slight
   481      speed up, but the reasoning strength appears to be not higher (at least
   482      no breaking of additional proofs in the entire HOL distribution, as
   483      of 5 March 2004, was observed). *)
   484 end
   485 *}
   486 
   487 
   488 subsection {* Bounded quantifiers *}
   489 
   490 syntax
   491   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   492   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   493   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   494   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   495 
   496   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   497   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   498   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   499   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   500 
   501 syntax (xsymbols)
   502   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   503   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   504   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   505   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   506 
   507   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   508   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   509   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   510   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   511 
   512 syntax (HOL)
   513   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   514   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   515   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   516   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   517 
   518 syntax (HTML output)
   519   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   520   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   521   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   522   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   523 
   524   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   525   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   526   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   527   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   528 
   529 translations
   530   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   531   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   532   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   533   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   534   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   535   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   536   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   537   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   538 
   539 print_translation {*
   540 let
   541   val All_binder = Syntax.binder_name @{const_syntax All};
   542   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   543   val impl = @{const_syntax "op -->"};
   544   val conj = @{const_syntax "op &"};
   545   val less = @{const_syntax less};
   546   val less_eq = @{const_syntax less_eq};
   547 
   548   val trans =
   549    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   550     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   551     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   552     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   553 
   554   fun matches_bound v t = 
   555      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   556               | _ => false
   557   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   558   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   559 
   560   fun tr' q = (q,
   561     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   562       (case AList.lookup (op =) trans (q, c, d) of
   563         NONE => raise Match
   564       | SOME (l, g) =>
   565           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   566           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   567           else raise Match)
   568      | _ => raise Match);
   569 in [tr' All_binder, tr' Ex_binder] end
   570 *}
   571 
   572 
   573 subsection {* Transitivity reasoning *}
   574 
   575 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   576 by (rule subst)
   577 
   578 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   579 by (rule ssubst)
   580 
   581 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   582 by (rule subst)
   583 
   584 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   585 by (rule ssubst)
   586 
   587 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   588   (!!x y. x < y ==> f x < f y) ==> f a < c"
   589 proof -
   590   assume r: "!!x y. x < y ==> f x < f y"
   591   assume "a < b" hence "f a < f b" by (rule r)
   592   also assume "f b < c"
   593   finally (order_less_trans) show ?thesis .
   594 qed
   595 
   596 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   597   (!!x y. x < y ==> f x < f y) ==> a < f c"
   598 proof -
   599   assume r: "!!x y. x < y ==> f x < f y"
   600   assume "a < f b"
   601   also assume "b < c" hence "f b < f c" by (rule r)
   602   finally (order_less_trans) show ?thesis .
   603 qed
   604 
   605 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   606   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   607 proof -
   608   assume r: "!!x y. x <= y ==> f x <= f y"
   609   assume "a <= b" hence "f a <= f b" by (rule r)
   610   also assume "f b < c"
   611   finally (order_le_less_trans) show ?thesis .
   612 qed
   613 
   614 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   615   (!!x y. x < y ==> f x < f y) ==> a < f c"
   616 proof -
   617   assume r: "!!x y. x < y ==> f x < f y"
   618   assume "a <= f b"
   619   also assume "b < c" hence "f b < f c" by (rule r)
   620   finally (order_le_less_trans) show ?thesis .
   621 qed
   622 
   623 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   624   (!!x y. x < y ==> f x < f y) ==> f a < c"
   625 proof -
   626   assume r: "!!x y. x < y ==> f x < f y"
   627   assume "a < b" hence "f a < f b" by (rule r)
   628   also assume "f b <= c"
   629   finally (order_less_le_trans) show ?thesis .
   630 qed
   631 
   632 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   633   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   634 proof -
   635   assume r: "!!x y. x <= y ==> f x <= f y"
   636   assume "a < f b"
   637   also assume "b <= c" hence "f b <= f c" by (rule r)
   638   finally (order_less_le_trans) show ?thesis .
   639 qed
   640 
   641 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   642   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   643 proof -
   644   assume r: "!!x y. x <= y ==> f x <= f y"
   645   assume "a <= f b"
   646   also assume "b <= c" hence "f b <= f c" by (rule r)
   647   finally (order_trans) show ?thesis .
   648 qed
   649 
   650 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   651   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   652 proof -
   653   assume r: "!!x y. x <= y ==> f x <= f y"
   654   assume "a <= b" hence "f a <= f b" by (rule r)
   655   also assume "f b <= c"
   656   finally (order_trans) show ?thesis .
   657 qed
   658 
   659 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   660   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   661 proof -
   662   assume r: "!!x y. x <= y ==> f x <= f y"
   663   assume "a <= b" hence "f a <= f b" by (rule r)
   664   also assume "f b = c"
   665   finally (ord_le_eq_trans) show ?thesis .
   666 qed
   667 
   668 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   669   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   670 proof -
   671   assume r: "!!x y. x <= y ==> f x <= f y"
   672   assume "a = f b"
   673   also assume "b <= c" hence "f b <= f c" by (rule r)
   674   finally (ord_eq_le_trans) show ?thesis .
   675 qed
   676 
   677 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   678   (!!x y. x < y ==> f x < f y) ==> f a < c"
   679 proof -
   680   assume r: "!!x y. x < y ==> f x < f y"
   681   assume "a < b" hence "f a < f b" by (rule r)
   682   also assume "f b = c"
   683   finally (ord_less_eq_trans) show ?thesis .
   684 qed
   685 
   686 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   687   (!!x y. x < y ==> f x < f y) ==> a < f c"
   688 proof -
   689   assume r: "!!x y. x < y ==> f x < f y"
   690   assume "a = f b"
   691   also assume "b < c" hence "f b < f c" by (rule r)
   692   finally (ord_eq_less_trans) show ?thesis .
   693 qed
   694 
   695 text {*
   696   Note that this list of rules is in reverse order of priorities.
   697 *}
   698 
   699 lemmas order_trans_rules [trans] =
   700   order_less_subst2
   701   order_less_subst1
   702   order_le_less_subst2
   703   order_le_less_subst1
   704   order_less_le_subst2
   705   order_less_le_subst1
   706   order_subst2
   707   order_subst1
   708   ord_le_eq_subst
   709   ord_eq_le_subst
   710   ord_less_eq_subst
   711   ord_eq_less_subst
   712   forw_subst
   713   back_subst
   714   rev_mp
   715   mp
   716   order_neq_le_trans
   717   order_le_neq_trans
   718   order_less_trans
   719   order_less_asym'
   720   order_le_less_trans
   721   order_less_le_trans
   722   order_trans
   723   order_antisym
   724   ord_le_eq_trans
   725   ord_eq_le_trans
   726   ord_less_eq_trans
   727   ord_eq_less_trans
   728   trans
   729 
   730 
   731 (* FIXME cleanup *)
   732 
   733 text {* These support proving chains of decreasing inequalities
   734     a >= b >= c ... in Isar proofs. *}
   735 
   736 lemma xt1:
   737   "a = b ==> b > c ==> a > c"
   738   "a > b ==> b = c ==> a > c"
   739   "a = b ==> b >= c ==> a >= c"
   740   "a >= b ==> b = c ==> a >= c"
   741   "(x::'a::order) >= y ==> y >= x ==> x = y"
   742   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   743   "(x::'a::order) > y ==> y >= z ==> x > z"
   744   "(x::'a::order) >= y ==> y > z ==> x > z"
   745   "(a::'a::order) > b ==> b > a ==> P"
   746   "(x::'a::order) > y ==> y > z ==> x > z"
   747   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   748   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   749   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   750   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   751   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   752   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   753 by auto
   754 
   755 lemma xt2:
   756   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   757 by (subgoal_tac "f b >= f c", force, force)
   758 
   759 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   760     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   761 by (subgoal_tac "f a >= f b", force, force)
   762 
   763 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   764   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   765 by (subgoal_tac "f b >= f c", force, force)
   766 
   767 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   768     (!!x y. x > y ==> f x > f y) ==> f a > c"
   769 by (subgoal_tac "f a > f b", force, force)
   770 
   771 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   772     (!!x y. x > y ==> f x > f y) ==> a > f c"
   773 by (subgoal_tac "f b > f c", force, force)
   774 
   775 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   776     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   777 by (subgoal_tac "f a >= f b", force, force)
   778 
   779 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   780     (!!x y. x > y ==> f x > f y) ==> a > f c"
   781 by (subgoal_tac "f b > f c", force, force)
   782 
   783 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   784     (!!x y. x > y ==> f x > f y) ==> f a > c"
   785 by (subgoal_tac "f a > f b", force, force)
   786 
   787 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   788 
   789 (* 
   790   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   791   for the wrong thing in an Isar proof.
   792 
   793   The extra transitivity rules can be used as follows: 
   794 
   795 lemma "(a::'a::order) > z"
   796 proof -
   797   have "a >= b" (is "_ >= ?rhs")
   798     sorry
   799   also have "?rhs >= c" (is "_ >= ?rhs")
   800     sorry
   801   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   802     sorry
   803   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   804     sorry
   805   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   806     sorry
   807   also (xtrans) have "?rhs > z"
   808     sorry
   809   finally (xtrans) show ?thesis .
   810 qed
   811 
   812   Alternatively, one can use "declare xtrans [trans]" and then
   813   leave out the "(xtrans)" above.
   814 *)
   815 
   816 subsection {* Order on bool *}
   817 
   818 instance bool :: order 
   819   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   820   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   821   by intro_classes (auto simp add: le_bool_def less_bool_def)
   822 
   823 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   824 by (simp add: le_bool_def)
   825 
   826 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   827 by (simp add: le_bool_def)
   828 
   829 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   830 by (simp add: le_bool_def)
   831 
   832 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   833 by (simp add: le_bool_def)
   834 
   835 lemma [code func]:
   836   "False \<le> b \<longleftrightarrow> True"
   837   "True \<le> b \<longleftrightarrow> b"
   838   "False < b \<longleftrightarrow> b"
   839   "True < b \<longleftrightarrow> False"
   840   unfolding le_bool_def less_bool_def by simp_all
   841 
   842 
   843 subsection {* Monotonicity, syntactic least value operator and min/max *}
   844 
   845 locale mono =
   846   fixes f
   847   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   848 
   849 lemmas monoI [intro?] = mono.intro
   850   and monoD [dest?] = mono.mono
   851 
   852 constdefs
   853   Least :: "('a::ord => bool) => 'a"               (binder "LEAST " 10)
   854   "Least P == THE x. P x & (ALL y. P y --> x <= y)"
   855     -- {* We can no longer use LeastM because the latter requires Hilbert-AC. *}
   856 
   857 lemma LeastI2_order:
   858   "[| P (x::'a::order);
   859       !!y. P y ==> x <= y;
   860       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   861    ==> Q (Least P)"
   862 apply (unfold Least_def)
   863 apply (rule theI2)
   864   apply (blast intro: order_antisym)+
   865 done
   866 
   867 lemma Least_equality:
   868   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   869 apply (simp add: Least_def)
   870 apply (rule the_equality)
   871 apply (auto intro!: order_antisym)
   872 done
   873 
   874 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   875 by (simp add: min_def)
   876 
   877 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   878 by (simp add: max_def)
   879 
   880 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   881 apply (simp add: min_def)
   882 apply (blast intro: order_antisym)
   883 done
   884 
   885 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   886 apply (simp add: max_def)
   887 apply (blast intro: order_antisym)
   888 done
   889 
   890 lemma min_of_mono:
   891   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   892 by (simp add: min_def)
   893 
   894 lemma max_of_mono:
   895   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   896 by (simp add: max_def)
   897 
   898 
   899 subsection {* legacy ML bindings *}
   900 
   901 ML {*
   902 val monoI = @{thm monoI};
   903 *}
   904 
   905 end