src/HOL/Analysis/Linear_Algebra.thy
author immler
Thu Dec 27 21:32:36 2018 +0100 (4 months ago)
changeset 69513 42e08052dae8
parent 69510 0f31dd2e540d
child 69516 09bb8f470959
permissions -rw-r--r--
moved lemmas up
     1 (*  Title:      HOL/Analysis/Linear_Algebra.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>Elementary linear algebra on Euclidean spaces\<close>
     6 
     7 theory Linear_Algebra
     8 imports
     9   Euclidean_Space
    10   "HOL-Library.Infinite_Set"
    11 begin
    12 
    13 lemma linear_simps:
    14   assumes "bounded_linear f"
    15   shows
    16     "f (a + b) = f a + f b"
    17     "f (a - b) = f a - f b"
    18     "f 0 = 0"
    19     "f (- a) = - f a"
    20     "f (s *\<^sub>R v) = s *\<^sub>R (f v)"
    21 proof -
    22   interpret f: bounded_linear f by fact
    23   show "f (a + b) = f a + f b" by (rule f.add)
    24   show "f (a - b) = f a - f b" by (rule f.diff)
    25   show "f 0 = 0" by (rule f.zero)
    26   show "f (- a) = - f a" by (rule f.neg)
    27   show "f (s *\<^sub>R v) = s *\<^sub>R (f v)" by (rule f.scale)
    28 qed
    29 
    30 lemma finite_Atleast_Atmost_nat[simp]: "finite {f x |x. x \<in> (UNIV::'a::finite set)}"
    31   using finite finite_image_set by blast
    32 
    33 
    34 subsection%unimportant \<open>More interesting properties of the norm\<close>
    35 
    36 notation inner (infix "\<bullet>" 70)
    37 
    38 text\<open>Equality of vectors in terms of @{term "(\<bullet>)"} products.\<close>
    39 
    40 lemma linear_componentwise:
    41   fixes f:: "'a::euclidean_space \<Rightarrow> 'b::real_inner"
    42   assumes lf: "linear f"
    43   shows "(f x) \<bullet> j = (\<Sum>i\<in>Basis. (x\<bullet>i) * (f i\<bullet>j))" (is "?lhs = ?rhs")
    44 proof -
    45   interpret linear f by fact
    46   have "?rhs = (\<Sum>i\<in>Basis. (x\<bullet>i) *\<^sub>R (f i))\<bullet>j"
    47     by (simp add: inner_sum_left)
    48   then show ?thesis
    49     by (simp add: euclidean_representation sum[symmetric] scale[symmetric])
    50 qed
    51 
    52 lemma vector_eq: "x = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y \<and> y \<bullet> y = x \<bullet> x"
    53   (is "?lhs \<longleftrightarrow> ?rhs")
    54 proof
    55   assume ?lhs
    56   then show ?rhs by simp
    57 next
    58   assume ?rhs
    59   then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y \<bullet> y = 0"
    60     by simp
    61   then have "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0"
    62     by (simp add: inner_diff inner_commute)
    63   then have "(x - y) \<bullet> (x - y) = 0"
    64     by (simp add: field_simps inner_diff inner_commute)
    65   then show "x = y" by simp
    66 qed
    67 
    68 lemma norm_triangle_half_r:
    69   "norm (y - x1) < e / 2 \<Longrightarrow> norm (y - x2) < e / 2 \<Longrightarrow> norm (x1 - x2) < e"
    70   using dist_triangle_half_r unfolding dist_norm[symmetric] by auto
    71 
    72 lemma norm_triangle_half_l:
    73   assumes "norm (x - y) < e / 2"
    74     and "norm (x' - y) < e / 2"
    75   shows "norm (x - x') < e"
    76   using dist_triangle_half_l[OF assms[unfolded dist_norm[symmetric]]]
    77   unfolding dist_norm[symmetric] .
    78 
    79 lemma abs_triangle_half_r:
    80   fixes y :: "'a::linordered_field"
    81   shows "abs (y - x1) < e / 2 \<Longrightarrow> abs (y - x2) < e / 2 \<Longrightarrow> abs (x1 - x2) < e"
    82   by linarith
    83 
    84 lemma abs_triangle_half_l:
    85   fixes y :: "'a::linordered_field"
    86   assumes "abs (x - y) < e / 2"
    87     and "abs (x' - y) < e / 2"
    88   shows "abs (x - x') < e"
    89   using assms by linarith
    90 
    91 lemma sum_clauses:
    92   shows "sum f {} = 0"
    93     and "finite S \<Longrightarrow> sum f (insert x S) = (if x \<in> S then sum f S else f x + sum f S)"
    94   by (auto simp add: insert_absorb)
    95 
    96 lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = z"
    97 proof
    98   assume "\<forall>x. x \<bullet> y = x \<bullet> z"
    99   then have "\<forall>x. x \<bullet> (y - z) = 0"
   100     by (simp add: inner_diff)
   101   then have "(y - z) \<bullet> (y - z) = 0" ..
   102   then show "y = z" by simp
   103 qed simp
   104 
   105 lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = y"
   106 proof
   107   assume "\<forall>z. x \<bullet> z = y \<bullet> z"
   108   then have "\<forall>z. (x - y) \<bullet> z = 0"
   109     by (simp add: inner_diff)
   110   then have "(x - y) \<bullet> (x - y) = 0" ..
   111   then show "x = y" by simp
   112 qed simp
   113 
   114 
   115 subsection \<open>Orthogonality\<close>
   116 
   117 definition%important (in real_inner) "orthogonal x y \<longleftrightarrow> x \<bullet> y = 0"
   118 
   119 context real_inner
   120 begin
   121 
   122 lemma orthogonal_self: "orthogonal x x \<longleftrightarrow> x = 0"
   123   by (simp add: orthogonal_def)
   124 
   125 lemma orthogonal_clauses:
   126   "orthogonal a 0"
   127   "orthogonal a x \<Longrightarrow> orthogonal a (c *\<^sub>R x)"
   128   "orthogonal a x \<Longrightarrow> orthogonal a (- x)"
   129   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x + y)"
   130   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x - y)"
   131   "orthogonal 0 a"
   132   "orthogonal x a \<Longrightarrow> orthogonal (c *\<^sub>R x) a"
   133   "orthogonal x a \<Longrightarrow> orthogonal (- x) a"
   134   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x + y) a"
   135   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x - y) a"
   136   unfolding orthogonal_def inner_add inner_diff by auto
   137 
   138 end
   139 
   140 lemma orthogonal_commute: "orthogonal x y \<longleftrightarrow> orthogonal y x"
   141   by (simp add: orthogonal_def inner_commute)
   142 
   143 lemma orthogonal_scaleR [simp]: "c \<noteq> 0 \<Longrightarrow> orthogonal (c *\<^sub>R x) = orthogonal x"
   144   by (rule ext) (simp add: orthogonal_def)
   145 
   146 lemma pairwise_ortho_scaleR:
   147     "pairwise (\<lambda>i j. orthogonal (f i) (g j)) B
   148     \<Longrightarrow> pairwise (\<lambda>i j. orthogonal (a i *\<^sub>R f i) (a j *\<^sub>R g j)) B"
   149   by (auto simp: pairwise_def orthogonal_clauses)
   150 
   151 lemma orthogonal_rvsum:
   152     "\<lbrakk>finite s; \<And>y. y \<in> s \<Longrightarrow> orthogonal x (f y)\<rbrakk> \<Longrightarrow> orthogonal x (sum f s)"
   153   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
   154 
   155 lemma orthogonal_lvsum:
   156     "\<lbrakk>finite s; \<And>x. x \<in> s \<Longrightarrow> orthogonal (f x) y\<rbrakk> \<Longrightarrow> orthogonal (sum f s) y"
   157   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
   158 
   159 lemma norm_add_Pythagorean:
   160   assumes "orthogonal a b"
   161     shows "norm(a + b) ^ 2 = norm a ^ 2 + norm b ^ 2"
   162 proof -
   163   from assms have "(a - (0 - b)) \<bullet> (a - (0 - b)) = a \<bullet> a - (0 - b \<bullet> b)"
   164     by (simp add: algebra_simps orthogonal_def inner_commute)
   165   then show ?thesis
   166     by (simp add: power2_norm_eq_inner)
   167 qed
   168 
   169 lemma norm_sum_Pythagorean:
   170   assumes "finite I" "pairwise (\<lambda>i j. orthogonal (f i) (f j)) I"
   171     shows "(norm (sum f I))\<^sup>2 = (\<Sum>i\<in>I. (norm (f i))\<^sup>2)"
   172 using assms
   173 proof (induction I rule: finite_induct)
   174   case empty then show ?case by simp
   175 next
   176   case (insert x I)
   177   then have "orthogonal (f x) (sum f I)"
   178     by (metis pairwise_insert orthogonal_rvsum)
   179   with insert show ?case
   180     by (simp add: pairwise_insert norm_add_Pythagorean)
   181 qed
   182 
   183 
   184 subsection \<open>Bilinear functions\<close>
   185 
   186 definition%important "bilinear f \<longleftrightarrow> (\<forall>x. linear (\<lambda>y. f x y)) \<and> (\<forall>y. linear (\<lambda>x. f x y))"
   187 
   188 lemma bilinear_ladd: "bilinear h \<Longrightarrow> h (x + y) z = h x z + h y z"
   189   by (simp add: bilinear_def linear_iff)
   190 
   191 lemma bilinear_radd: "bilinear h \<Longrightarrow> h x (y + z) = h x y + h x z"
   192   by (simp add: bilinear_def linear_iff)
   193 
   194 lemma bilinear_lmul: "bilinear h \<Longrightarrow> h (c *\<^sub>R x) y = c *\<^sub>R h x y"
   195   by (simp add: bilinear_def linear_iff)
   196 
   197 lemma bilinear_rmul: "bilinear h \<Longrightarrow> h x (c *\<^sub>R y) = c *\<^sub>R h x y"
   198   by (simp add: bilinear_def linear_iff)
   199 
   200 lemma bilinear_lneg: "bilinear h \<Longrightarrow> h (- x) y = - h x y"
   201   by (drule bilinear_lmul [of _ "- 1"]) simp
   202 
   203 lemma bilinear_rneg: "bilinear h \<Longrightarrow> h x (- y) = - h x y"
   204   by (drule bilinear_rmul [of _ _ "- 1"]) simp
   205 
   206 lemma (in ab_group_add) eq_add_iff: "x = x + y \<longleftrightarrow> y = 0"
   207   using add_left_imp_eq[of x y 0] by auto
   208 
   209 lemma bilinear_lzero:
   210   assumes "bilinear h"
   211   shows "h 0 x = 0"
   212   using bilinear_ladd [OF assms, of 0 0 x] by (simp add: eq_add_iff field_simps)
   213 
   214 lemma bilinear_rzero:
   215   assumes "bilinear h"
   216   shows "h x 0 = 0"
   217   using bilinear_radd [OF assms, of x 0 0 ] by (simp add: eq_add_iff field_simps)
   218 
   219 lemma bilinear_lsub: "bilinear h \<Longrightarrow> h (x - y) z = h x z - h y z"
   220   using bilinear_ladd [of h x "- y"] by (simp add: bilinear_lneg)
   221 
   222 lemma bilinear_rsub: "bilinear h \<Longrightarrow> h z (x - y) = h z x - h z y"
   223   using bilinear_radd [of h _ x "- y"] by (simp add: bilinear_rneg)
   224 
   225 lemma bilinear_sum:
   226   assumes "bilinear h"
   227   shows "h (sum f S) (sum g T) = sum (\<lambda>(i,j). h (f i) (g j)) (S \<times> T) "
   228 proof -
   229   interpret l: linear "\<lambda>x. h x y" for y using assms by (simp add: bilinear_def)
   230   interpret r: linear "\<lambda>y. h x y" for x using assms by (simp add: bilinear_def)
   231   have "h (sum f S) (sum g T) = sum (\<lambda>x. h (f x) (sum g T)) S"
   232     by (simp add: l.sum)
   233   also have "\<dots> = sum (\<lambda>x. sum (\<lambda>y. h (f x) (g y)) T) S"
   234     by (rule sum.cong) (simp_all add: r.sum)
   235   finally show ?thesis
   236     unfolding sum.cartesian_product .
   237 qed
   238 
   239 
   240 subsection \<open>Adjoints\<close>
   241 
   242 definition%important "adjoint f = (SOME f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y)"
   243 
   244 lemma adjoint_unique:
   245   assumes "\<forall>x y. inner (f x) y = inner x (g y)"
   246   shows "adjoint f = g"
   247   unfolding adjoint_def
   248 proof (rule some_equality)
   249   show "\<forall>x y. inner (f x) y = inner x (g y)"
   250     by (rule assms)
   251 next
   252   fix h
   253   assume "\<forall>x y. inner (f x) y = inner x (h y)"
   254   then have "\<forall>x y. inner x (g y) = inner x (h y)"
   255     using assms by simp
   256   then have "\<forall>x y. inner x (g y - h y) = 0"
   257     by (simp add: inner_diff_right)
   258   then have "\<forall>y. inner (g y - h y) (g y - h y) = 0"
   259     by simp
   260   then have "\<forall>y. h y = g y"
   261     by simp
   262   then show "h = g" by (simp add: ext)
   263 qed
   264 
   265 text \<open>TODO: The following lemmas about adjoints should hold for any
   266   Hilbert space (i.e. complete inner product space).
   267   (see \<^url>\<open>https://en.wikipedia.org/wiki/Hermitian_adjoint\<close>)
   268 \<close>
   269 
   270 lemma adjoint_works:
   271   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   272   assumes lf: "linear f"
   273   shows "x \<bullet> adjoint f y = f x \<bullet> y"
   274 proof -
   275   interpret linear f by fact
   276   have "\<forall>y. \<exists>w. \<forall>x. f x \<bullet> y = x \<bullet> w"
   277   proof (intro allI exI)
   278     fix y :: "'m" and x
   279     let ?w = "(\<Sum>i\<in>Basis. (f i \<bullet> y) *\<^sub>R i) :: 'n"
   280     have "f x \<bullet> y = f (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R i) \<bullet> y"
   281       by (simp add: euclidean_representation)
   282     also have "\<dots> = (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R f i) \<bullet> y"
   283       by (simp add: sum scale)
   284     finally show "f x \<bullet> y = x \<bullet> ?w"
   285       by (simp add: inner_sum_left inner_sum_right mult.commute)
   286   qed
   287   then show ?thesis
   288     unfolding adjoint_def choice_iff
   289     by (intro someI2_ex[where Q="\<lambda>f'. x \<bullet> f' y = f x \<bullet> y"]) auto
   290 qed
   291 
   292 lemma adjoint_clauses:
   293   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   294   assumes lf: "linear f"
   295   shows "x \<bullet> adjoint f y = f x \<bullet> y"
   296     and "adjoint f y \<bullet> x = y \<bullet> f x"
   297   by (simp_all add: adjoint_works[OF lf] inner_commute)
   298 
   299 lemma adjoint_linear:
   300   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   301   assumes lf: "linear f"
   302   shows "linear (adjoint f)"
   303   by (simp add: lf linear_iff euclidean_eq_iff[where 'a='n] euclidean_eq_iff[where 'a='m]
   304     adjoint_clauses[OF lf] inner_distrib)
   305 
   306 lemma adjoint_adjoint:
   307   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   308   assumes lf: "linear f"
   309   shows "adjoint (adjoint f) = f"
   310   by (rule adjoint_unique, simp add: adjoint_clauses [OF lf])
   311 
   312 
   313 subsection%unimportant \<open>Interlude: Some properties of real sets\<close>
   314 
   315 lemma seq_mono_lemma:
   316   assumes "\<forall>(n::nat) \<ge> m. (d n :: real) < e n"
   317     and "\<forall>n \<ge> m. e n \<le> e m"
   318   shows "\<forall>n \<ge> m. d n < e m"
   319   using assms by force
   320 
   321 lemma infinite_enumerate:
   322   assumes fS: "infinite S"
   323   shows "\<exists>r::nat\<Rightarrow>nat. strict_mono r \<and> (\<forall>n. r n \<in> S)"
   324   unfolding strict_mono_def
   325   using enumerate_in_set[OF fS] enumerate_mono[of _ _ S] fS by auto
   326 
   327 lemma approachable_lt_le: "(\<exists>(d::real) > 0. \<forall>x. f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> P x)"
   328   apply auto
   329   apply (rule_tac x="d/2" in exI)
   330   apply auto
   331   done
   332 
   333 lemma approachable_lt_le2:  \<comment> \<open>like the above, but pushes aside an extra formula\<close>
   334     "(\<exists>(d::real) > 0. \<forall>x. Q x \<longrightarrow> f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> Q x \<longrightarrow> P x)"
   335   apply auto
   336   apply (rule_tac x="d/2" in exI, auto)
   337   done
   338 
   339 lemma triangle_lemma:
   340   fixes x y z :: real
   341   assumes x: "0 \<le> x"
   342     and y: "0 \<le> y"
   343     and z: "0 \<le> z"
   344     and xy: "x\<^sup>2 \<le> y\<^sup>2 + z\<^sup>2"
   345   shows "x \<le> y + z"
   346 proof -
   347   have "y\<^sup>2 + z\<^sup>2 \<le> y\<^sup>2 + 2 * y * z + z\<^sup>2"
   348     using z y by simp
   349   with xy have th: "x\<^sup>2 \<le> (y + z)\<^sup>2"
   350     by (simp add: power2_eq_square field_simps)
   351   from y z have yz: "y + z \<ge> 0"
   352     by arith
   353   from power2_le_imp_le[OF th yz] show ?thesis .
   354 qed
   355 
   356 
   357 
   358 subsection \<open>Archimedean properties and useful consequences\<close>
   359 
   360 text\<open>Bernoulli's inequality\<close>
   361 proposition Bernoulli_inequality:
   362   fixes x :: real
   363   assumes "-1 \<le> x"
   364     shows "1 + n * x \<le> (1 + x) ^ n"
   365 proof (induct n)
   366   case 0
   367   then show ?case by simp
   368 next
   369   case (Suc n)
   370   have "1 + Suc n * x \<le> 1 + (Suc n)*x + n * x^2"
   371     by (simp add: algebra_simps)
   372   also have "... = (1 + x) * (1 + n*x)"
   373     by (auto simp: power2_eq_square algebra_simps  of_nat_Suc)
   374   also have "... \<le> (1 + x) ^ Suc n"
   375     using Suc.hyps assms mult_left_mono by fastforce
   376   finally show ?case .
   377 qed
   378 
   379 corollary Bernoulli_inequality_even:
   380   fixes x :: real
   381   assumes "even n"
   382     shows "1 + n * x \<le> (1 + x) ^ n"
   383 proof (cases "-1 \<le> x \<or> n=0")
   384   case True
   385   then show ?thesis
   386     by (auto simp: Bernoulli_inequality)
   387 next
   388   case False
   389   then have "real n \<ge> 1"
   390     by simp
   391   with False have "n * x \<le> -1"
   392     by (metis linear minus_zero mult.commute mult.left_neutral mult_left_mono_neg neg_le_iff_le order_trans zero_le_one)
   393   then have "1 + n * x \<le> 0"
   394     by auto
   395   also have "... \<le> (1 + x) ^ n"
   396     using assms
   397     using zero_le_even_power by blast
   398   finally show ?thesis .
   399 qed
   400 
   401 corollary real_arch_pow:
   402   fixes x :: real
   403   assumes x: "1 < x"
   404   shows "\<exists>n. y < x^n"
   405 proof -
   406   from x have x0: "x - 1 > 0"
   407     by arith
   408   from reals_Archimedean3[OF x0, rule_format, of y]
   409   obtain n :: nat where n: "y < real n * (x - 1)" by metis
   410   from x0 have x00: "x- 1 \<ge> -1" by arith
   411   from Bernoulli_inequality[OF x00, of n] n
   412   have "y < x^n" by auto
   413   then show ?thesis by metis
   414 qed
   415 
   416 corollary real_arch_pow_inv:
   417   fixes x y :: real
   418   assumes y: "y > 0"
   419     and x1: "x < 1"
   420   shows "\<exists>n. x^n < y"
   421 proof (cases "x > 0")
   422   case True
   423   with x1 have ix: "1 < 1/x" by (simp add: field_simps)
   424   from real_arch_pow[OF ix, of "1/y"]
   425   obtain n where n: "1/y < (1/x)^n" by blast
   426   then show ?thesis using y \<open>x > 0\<close>
   427     by (auto simp add: field_simps)
   428 next
   429   case False
   430   with y x1 show ?thesis
   431     by (metis less_le_trans not_less power_one_right)
   432 qed
   433 
   434 lemma forall_pos_mono:
   435   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
   436     (\<And>n::nat. n \<noteq> 0 \<Longrightarrow> P (inverse (real n))) \<Longrightarrow> (\<And>e. 0 < e \<Longrightarrow> P e)"
   437   by (metis real_arch_inverse)
   438 
   439 lemma forall_pos_mono_1:
   440   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
   441     (\<And>n. P (inverse (real (Suc n)))) \<Longrightarrow> 0 < e \<Longrightarrow> P e"
   442   apply (rule forall_pos_mono)
   443   apply auto
   444   apply (metis Suc_pred of_nat_Suc)
   445   done
   446 
   447 
   448 subsection%unimportant \<open>Euclidean Spaces as Typeclass\<close>
   449 
   450 lemma independent_Basis: "independent Basis"
   451   by (rule independent_Basis)
   452 
   453 lemma span_Basis [simp]: "span Basis = UNIV"
   454   by (rule span_Basis)
   455 
   456 lemma in_span_Basis: "x \<in> span Basis"
   457   unfolding span_Basis ..
   458 
   459 
   460 subsection%unimportant \<open>Linearity and Bilinearity continued\<close>
   461 
   462 lemma linear_bounded:
   463   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   464   assumes lf: "linear f"
   465   shows "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
   466 proof
   467   interpret linear f by fact
   468   let ?B = "\<Sum>b\<in>Basis. norm (f b)"
   469   show "\<forall>x. norm (f x) \<le> ?B * norm x"
   470   proof
   471     fix x :: 'a
   472     let ?g = "\<lambda>b. (x \<bullet> b) *\<^sub>R f b"
   473     have "norm (f x) = norm (f (\<Sum>b\<in>Basis. (x \<bullet> b) *\<^sub>R b))"
   474       unfolding euclidean_representation ..
   475     also have "\<dots> = norm (sum ?g Basis)"
   476       by (simp add: sum scale)
   477     finally have th0: "norm (f x) = norm (sum ?g Basis)" .
   478     have th: "norm (?g i) \<le> norm (f i) * norm x" if "i \<in> Basis" for i
   479     proof -
   480       from Basis_le_norm[OF that, of x]
   481       show "norm (?g i) \<le> norm (f i) * norm x"
   482         unfolding norm_scaleR  by (metis mult.commute mult_left_mono norm_ge_zero)
   483     qed
   484     from sum_norm_le[of _ ?g, OF th]
   485     show "norm (f x) \<le> ?B * norm x"
   486       unfolding th0 sum_distrib_right by metis
   487   qed
   488 qed
   489 
   490 lemma linear_conv_bounded_linear:
   491   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   492   shows "linear f \<longleftrightarrow> bounded_linear f"
   493 proof
   494   assume "linear f"
   495   then interpret f: linear f .
   496   show "bounded_linear f"
   497   proof
   498     have "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
   499       using \<open>linear f\<close> by (rule linear_bounded)
   500     then show "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
   501       by (simp add: mult.commute)
   502   qed
   503 next
   504   assume "bounded_linear f"
   505   then interpret f: bounded_linear f .
   506   show "linear f" ..
   507 qed
   508 
   509 lemmas linear_linear = linear_conv_bounded_linear[symmetric]
   510 
   511 lemma linear_bounded_pos:
   512   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   513   assumes lf: "linear f"
   514  obtains B where "B > 0" "\<And>x. norm (f x) \<le> B * norm x"
   515 proof -
   516   have "\<exists>B > 0. \<forall>x. norm (f x) \<le> norm x * B"
   517     using lf unfolding linear_conv_bounded_linear
   518     by (rule bounded_linear.pos_bounded)
   519   with that show ?thesis
   520     by (auto simp: mult.commute)
   521 qed
   522 
   523 lemma linear_invertible_bounded_below_pos:
   524   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
   525   assumes "linear f" "linear g" "g \<circ> f = id"
   526   obtains B where "B > 0" "\<And>x. B * norm x \<le> norm(f x)"
   527 proof -
   528   obtain B where "B > 0" and B: "\<And>x. norm (g x) \<le> B * norm x"
   529     using linear_bounded_pos [OF \<open>linear g\<close>] by blast
   530   show thesis
   531   proof
   532     show "0 < 1/B"
   533       by (simp add: \<open>B > 0\<close>)
   534     show "1/B * norm x \<le> norm (f x)" for x
   535     proof -
   536       have "1/B * norm x = 1/B * norm (g (f x))"
   537         using assms by (simp add: pointfree_idE)
   538       also have "\<dots> \<le> norm (f x)"
   539         using B [of "f x"] by (simp add: \<open>B > 0\<close> mult.commute pos_divide_le_eq)
   540       finally show ?thesis .
   541     qed
   542   qed
   543 qed
   544 
   545 lemma linear_inj_bounded_below_pos:
   546   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
   547   assumes "linear f" "inj f"
   548   obtains B where "B > 0" "\<And>x. B * norm x \<le> norm(f x)"
   549   using linear_injective_left_inverse [OF assms]
   550     linear_invertible_bounded_below_pos assms by blast
   551 
   552 lemma bounded_linearI':
   553   fixes f ::"'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   554   assumes "\<And>x y. f (x + y) = f x + f y"
   555     and "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
   556   shows "bounded_linear f"
   557   using assms linearI linear_conv_bounded_linear by blast
   558 
   559 lemma bilinear_bounded:
   560   fixes h :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'k::real_normed_vector"
   561   assumes bh: "bilinear h"
   562   shows "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
   563 proof (clarify intro!: exI[of _ "\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)"])
   564   fix x :: 'm
   565   fix y :: 'n
   566   have "norm (h x y) = norm (h (sum (\<lambda>i. (x \<bullet> i) *\<^sub>R i) Basis) (sum (\<lambda>i. (y \<bullet> i) *\<^sub>R i) Basis))"
   567     by (simp add: euclidean_representation)
   568   also have "\<dots> = norm (sum (\<lambda> (i,j). h ((x \<bullet> i) *\<^sub>R i) ((y \<bullet> j) *\<^sub>R j)) (Basis \<times> Basis))"
   569     unfolding bilinear_sum[OF bh] ..
   570   finally have th: "norm (h x y) = \<dots>" .
   571   have "\<And>i j. \<lbrakk>i \<in> Basis; j \<in> Basis\<rbrakk>
   572            \<Longrightarrow> \<bar>x \<bullet> i\<bar> * (\<bar>y \<bullet> j\<bar> * norm (h i j)) \<le> norm x * (norm y * norm (h i j))"
   573     by (auto simp add: zero_le_mult_iff Basis_le_norm mult_mono)
   574   then show "norm (h x y) \<le> (\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)) * norm x * norm y"
   575     unfolding sum_distrib_right th sum.cartesian_product
   576     by (clarsimp simp add: bilinear_rmul[OF bh] bilinear_lmul[OF bh]
   577       field_simps simp del: scaleR_scaleR intro!: sum_norm_le)
   578 qed
   579 
   580 lemma bilinear_conv_bounded_bilinear:
   581   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
   582   shows "bilinear h \<longleftrightarrow> bounded_bilinear h"
   583 proof
   584   assume "bilinear h"
   585   show "bounded_bilinear h"
   586   proof
   587     fix x y z
   588     show "h (x + y) z = h x z + h y z"
   589       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
   590   next
   591     fix x y z
   592     show "h x (y + z) = h x y + h x z"
   593       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
   594   next
   595     show "h (scaleR r x) y = scaleR r (h x y)" "h x (scaleR r y) = scaleR r (h x y)" for r x y
   596       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff
   597       by simp_all
   598   next
   599     have "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
   600       using \<open>bilinear h\<close> by (rule bilinear_bounded)
   601     then show "\<exists>K. \<forall>x y. norm (h x y) \<le> norm x * norm y * K"
   602       by (simp add: ac_simps)
   603   qed
   604 next
   605   assume "bounded_bilinear h"
   606   then interpret h: bounded_bilinear h .
   607   show "bilinear h"
   608     unfolding bilinear_def linear_conv_bounded_linear
   609     using h.bounded_linear_left h.bounded_linear_right by simp
   610 qed
   611 
   612 lemma bilinear_bounded_pos:
   613   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
   614   assumes bh: "bilinear h"
   615   shows "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
   616 proof -
   617   have "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> norm x * norm y * B"
   618     using bh [unfolded bilinear_conv_bounded_bilinear]
   619     by (rule bounded_bilinear.pos_bounded)
   620   then show ?thesis
   621     by (simp only: ac_simps)
   622 qed
   623 
   624 lemma bounded_linear_imp_has_derivative: "bounded_linear f \<Longrightarrow> (f has_derivative f) net"
   625   by (auto simp add: has_derivative_def linear_diff linear_linear linear_def
   626       dest: bounded_linear.linear)
   627 
   628 lemma linear_imp_has_derivative:
   629   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   630   shows "linear f \<Longrightarrow> (f has_derivative f) net"
   631   by (simp add: bounded_linear_imp_has_derivative linear_conv_bounded_linear)
   632 
   633 lemma bounded_linear_imp_differentiable: "bounded_linear f \<Longrightarrow> f differentiable net"
   634   using bounded_linear_imp_has_derivative differentiable_def by blast
   635 
   636 lemma linear_imp_differentiable:
   637   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   638   shows "linear f \<Longrightarrow> f differentiable net"
   639   by (metis linear_imp_has_derivative differentiable_def)
   640 
   641 
   642 subsection%unimportant \<open>We continue\<close>
   643 
   644 lemma independent_bound:
   645   fixes S :: "'a::euclidean_space set"
   646   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> DIM('a)"
   647   by (metis dim_subset_UNIV finiteI_independent dim_span_eq_card_independent)
   648 
   649 lemmas independent_imp_finite = finiteI_independent
   650 
   651 corollary
   652   fixes S :: "'a::euclidean_space set"
   653   assumes "independent S"
   654   shows independent_card_le:"card S \<le> DIM('a)"
   655   using assms independent_bound by auto
   656 
   657 lemma dependent_biggerset:
   658   fixes S :: "'a::euclidean_space set"
   659   shows "(finite S \<Longrightarrow> card S > DIM('a)) \<Longrightarrow> dependent S"
   660   by (metis independent_bound not_less)
   661 
   662 text \<open>Picking an orthogonal replacement for a spanning set.\<close>
   663 
   664 lemma vector_sub_project_orthogonal:
   665   fixes b x :: "'a::euclidean_space"
   666   shows "b \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *\<^sub>R b) = 0"
   667   unfolding inner_simps by auto
   668 
   669 lemma pairwise_orthogonal_insert:
   670   assumes "pairwise orthogonal S"
   671     and "\<And>y. y \<in> S \<Longrightarrow> orthogonal x y"
   672   shows "pairwise orthogonal (insert x S)"
   673   using assms unfolding pairwise_def
   674   by (auto simp add: orthogonal_commute)
   675 
   676 lemma basis_orthogonal:
   677   fixes B :: "'a::real_inner set"
   678   assumes fB: "finite B"
   679   shows "\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C"
   680   (is " \<exists>C. ?P B C")
   681   using fB
   682 proof (induct rule: finite_induct)
   683   case empty
   684   then show ?case
   685     apply (rule exI[where x="{}"])
   686     apply (auto simp add: pairwise_def)
   687     done
   688 next
   689   case (insert a B)
   690   note fB = \<open>finite B\<close> and aB = \<open>a \<notin> B\<close>
   691   from \<open>\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C\<close>
   692   obtain C where C: "finite C" "card C \<le> card B"
   693     "span C = span B" "pairwise orthogonal C" by blast
   694   let ?a = "a - sum (\<lambda>x. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x) C"
   695   let ?C = "insert ?a C"
   696   from C(1) have fC: "finite ?C"
   697     by simp
   698   from fB aB C(1,2) have cC: "card ?C \<le> card (insert a B)"
   699     by (simp add: card_insert_if)
   700   {
   701     fix x k
   702     have th0: "\<And>(a::'a) b c. a - (b - c) = c + (a - b)"
   703       by (simp add: field_simps)
   704     have "x - k *\<^sub>R (a - (\<Sum>x\<in>C. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x)) \<in> span C \<longleftrightarrow> x - k *\<^sub>R a \<in> span C"
   705       apply (simp only: scaleR_right_diff_distrib th0)
   706       apply (rule span_add_eq)
   707       apply (rule span_scale)
   708       apply (rule span_sum)
   709       apply (rule span_scale)
   710       apply (rule span_base)
   711       apply assumption
   712       done
   713   }
   714   then have SC: "span ?C = span (insert a B)"
   715     unfolding set_eq_iff span_breakdown_eq C(3)[symmetric] by auto
   716   {
   717     fix y
   718     assume yC: "y \<in> C"
   719     then have Cy: "C = insert y (C - {y})"
   720       by blast
   721     have fth: "finite (C - {y})"
   722       using C by simp
   723     have "orthogonal ?a y"
   724       unfolding orthogonal_def
   725       unfolding inner_diff inner_sum_left right_minus_eq
   726       unfolding sum.remove [OF \<open>finite C\<close> \<open>y \<in> C\<close>]
   727       apply (clarsimp simp add: inner_commute[of y a])
   728       apply (rule sum.neutral)
   729       apply clarsimp
   730       apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
   731       using \<open>y \<in> C\<close> by auto
   732   }
   733   with \<open>pairwise orthogonal C\<close> have CPO: "pairwise orthogonal ?C"
   734     by (rule pairwise_orthogonal_insert)
   735   from fC cC SC CPO have "?P (insert a B) ?C"
   736     by blast
   737   then show ?case by blast
   738 qed
   739 
   740 lemma orthogonal_basis_exists:
   741   fixes V :: "('a::euclidean_space) set"
   742   shows "\<exists>B. independent B \<and> B \<subseteq> span V \<and> V \<subseteq> span B \<and>
   743   (card B = dim V) \<and> pairwise orthogonal B"
   744 proof -
   745   from basis_exists[of V] obtain B where
   746     B: "B \<subseteq> V" "independent B" "V \<subseteq> span B" "card B = dim V"
   747     by force
   748   from B have fB: "finite B" "card B = dim V"
   749     using independent_bound by auto
   750   from basis_orthogonal[OF fB(1)] obtain C where
   751     C: "finite C" "card C \<le> card B" "span C = span B" "pairwise orthogonal C"
   752     by blast
   753   from C B have CSV: "C \<subseteq> span V"
   754     by (metis span_superset span_mono subset_trans)
   755   from span_mono[OF B(3)] C have SVC: "span V \<subseteq> span C"
   756     by (simp add: span_span)
   757   from card_le_dim_spanning[OF CSV SVC C(1)] C(2,3) fB
   758   have iC: "independent C"
   759     by (simp add: dim_span)
   760   from C fB have "card C \<le> dim V"
   761     by simp
   762   moreover have "dim V \<le> card C"
   763     using span_card_ge_dim[OF CSV SVC C(1)]
   764     by simp
   765   ultimately have CdV: "card C = dim V"
   766     using C(1) by simp
   767   from C B CSV CdV iC show ?thesis
   768     by auto
   769 qed
   770 
   771 text \<open>Low-dimensional subset is in a hyperplane (weak orthogonal complement).\<close>
   772 
   773 lemma span_not_univ_orthogonal:
   774   fixes S :: "'a::euclidean_space set"
   775   assumes sU: "span S \<noteq> UNIV"
   776   shows "\<exists>a::'a. a \<noteq> 0 \<and> (\<forall>x \<in> span S. a \<bullet> x = 0)"
   777 proof -
   778   from sU obtain a where a: "a \<notin> span S"
   779     by blast
   780   from orthogonal_basis_exists obtain B where
   781     B: "independent B" "B \<subseteq> span S" "S \<subseteq> span B"
   782     "card B = dim S" "pairwise orthogonal B"
   783     by blast
   784   from B have fB: "finite B" "card B = dim S"
   785     using independent_bound by auto
   786   from span_mono[OF B(2)] span_mono[OF B(3)]
   787   have sSB: "span S = span B"
   788     by (simp add: span_span)
   789   let ?a = "a - sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B"
   790   have "sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B \<in> span S"
   791     unfolding sSB
   792     apply (rule span_sum)
   793     apply (rule span_scale)
   794     apply (rule span_base)
   795     apply assumption
   796     done
   797   with a have a0:"?a  \<noteq> 0"
   798     by auto
   799   have "?a \<bullet> x = 0" if "x\<in>span B" for x
   800   proof (rule span_induct [OF that])
   801     show "subspace {x. ?a \<bullet> x = 0}"
   802       by (auto simp add: subspace_def inner_add)
   803   next
   804     {
   805       fix x
   806       assume x: "x \<in> B"
   807       from x have B': "B = insert x (B - {x})"
   808         by blast
   809       have fth: "finite (B - {x})"
   810         using fB by simp
   811       have "?a \<bullet> x = 0"
   812         apply (subst B')
   813         using fB fth
   814         unfolding sum_clauses(2)[OF fth]
   815         apply simp unfolding inner_simps
   816         apply (clarsimp simp add: inner_add inner_sum_left)
   817         apply (rule sum.neutral, rule ballI)
   818         apply (simp only: inner_commute)
   819         apply (auto simp add: x field_simps
   820           intro: B(5)[unfolded pairwise_def orthogonal_def, rule_format])
   821         done
   822     }
   823     then show "?a \<bullet> x = 0" if "x \<in> B" for x
   824       using that by blast
   825     qed
   826   with a0 show ?thesis
   827     unfolding sSB by (auto intro: exI[where x="?a"])
   828 qed
   829 
   830 lemma span_not_univ_subset_hyperplane:
   831   fixes S :: "'a::euclidean_space set"
   832   assumes SU: "span S \<noteq> UNIV"
   833   shows "\<exists> a. a \<noteq>0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
   834   using span_not_univ_orthogonal[OF SU] by auto
   835 
   836 lemma lowdim_subset_hyperplane:
   837   fixes S :: "'a::euclidean_space set"
   838   assumes d: "dim S < DIM('a)"
   839   shows "\<exists>a::'a. a \<noteq> 0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
   840 proof -
   841   {
   842     assume "span S = UNIV"
   843     then have "dim (span S) = dim (UNIV :: ('a) set)"
   844       by simp
   845     then have "dim S = DIM('a)"
   846       by (metis Euclidean_Space.dim_UNIV dim_span)
   847     with d have False by arith
   848   }
   849   then have th: "span S \<noteq> UNIV"
   850     by blast
   851   from span_not_univ_subset_hyperplane[OF th] show ?thesis .
   852 qed
   853 
   854 lemma linear_eq_stdbasis:
   855   fixes f :: "'a::euclidean_space \<Rightarrow> _"
   856   assumes lf: "linear f"
   857     and lg: "linear g"
   858     and fg: "\<And>b. b \<in> Basis \<Longrightarrow> f b = g b"
   859   shows "f = g"
   860   using linear_eq_on_span[OF lf lg, of Basis] fg
   861   by auto
   862 
   863 
   864 text \<open>Similar results for bilinear functions.\<close>
   865 
   866 lemma bilinear_eq:
   867   assumes bf: "bilinear f"
   868     and bg: "bilinear g"
   869     and SB: "S \<subseteq> span B"
   870     and TC: "T \<subseteq> span C"
   871     and "x\<in>S" "y\<in>T"
   872     and fg: "\<And>x y. \<lbrakk>x \<in> B; y\<in> C\<rbrakk> \<Longrightarrow> f x y = g x y"
   873   shows "f x y = g x y"
   874 proof -
   875   let ?P = "{x. \<forall>y\<in> span C. f x y = g x y}"
   876   from bf bg have sp: "subspace ?P"
   877     unfolding bilinear_def linear_iff subspace_def bf bg
   878     by (auto simp add: span_zero bilinear_lzero[OF bf] bilinear_lzero[OF bg]
   879         span_add Ball_def
   880       intro: bilinear_ladd[OF bf])
   881   have sfg: "\<And>x. x \<in> B \<Longrightarrow> subspace {a. f x a = g x a}"
   882     apply (auto simp add: subspace_def)
   883     using bf bg unfolding bilinear_def linear_iff
   884       apply (auto simp add: span_zero bilinear_rzero[OF bf] bilinear_rzero[OF bg]
   885         span_add Ball_def
   886       intro: bilinear_ladd[OF bf])
   887     done
   888   have "\<forall>y\<in> span C. f x y = g x y" if "x \<in> span B" for x
   889     apply (rule span_induct [OF that sp])
   890     using fg sfg span_induct by blast
   891   then show ?thesis
   892     using SB TC assms by auto
   893 qed
   894 
   895 lemma bilinear_eq_stdbasis:
   896   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> _"
   897   assumes bf: "bilinear f"
   898     and bg: "bilinear g"
   899     and fg: "\<And>i j. i \<in> Basis \<Longrightarrow> j \<in> Basis \<Longrightarrow> f i j = g i j"
   900   shows "f = g"
   901   using bilinear_eq[OF bf bg equalityD2[OF span_Basis] equalityD2[OF span_Basis]] fg by blast
   902 
   903 subsection \<open>Infinity norm\<close>
   904 
   905 definition%important "infnorm (x::'a::euclidean_space) = Sup {\<bar>x \<bullet> b\<bar> |b. b \<in> Basis}"
   906 
   907 lemma infnorm_set_image:
   908   fixes x :: "'a::euclidean_space"
   909   shows "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} = (\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
   910   by blast
   911 
   912 lemma infnorm_Max:
   913   fixes x :: "'a::euclidean_space"
   914   shows "infnorm x = Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis)"
   915   by (simp add: infnorm_def infnorm_set_image cSup_eq_Max)
   916 
   917 lemma infnorm_set_lemma:
   918   fixes x :: "'a::euclidean_space"
   919   shows "finite {\<bar>x \<bullet> i\<bar> |i. i \<in> Basis}"
   920     and "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} \<noteq> {}"
   921   unfolding infnorm_set_image
   922   by auto
   923 
   924 lemma infnorm_pos_le:
   925   fixes x :: "'a::euclidean_space"
   926   shows "0 \<le> infnorm x"
   927   by (simp add: infnorm_Max Max_ge_iff ex_in_conv)
   928 
   929 lemma infnorm_triangle:
   930   fixes x :: "'a::euclidean_space"
   931   shows "infnorm (x + y) \<le> infnorm x + infnorm y"
   932 proof -
   933   have *: "\<And>a b c d :: real. \<bar>a\<bar> \<le> c \<Longrightarrow> \<bar>b\<bar> \<le> d \<Longrightarrow> \<bar>a + b\<bar> \<le> c + d"
   934     by simp
   935   show ?thesis
   936     by (auto simp: infnorm_Max inner_add_left intro!: *)
   937 qed
   938 
   939 lemma infnorm_eq_0:
   940   fixes x :: "'a::euclidean_space"
   941   shows "infnorm x = 0 \<longleftrightarrow> x = 0"
   942 proof -
   943   have "infnorm x \<le> 0 \<longleftrightarrow> x = 0"
   944     unfolding infnorm_Max by (simp add: euclidean_all_zero_iff)
   945   then show ?thesis
   946     using infnorm_pos_le[of x] by simp
   947 qed
   948 
   949 lemma infnorm_0: "infnorm 0 = 0"
   950   by (simp add: infnorm_eq_0)
   951 
   952 lemma infnorm_neg: "infnorm (- x) = infnorm x"
   953   unfolding infnorm_def by simp
   954 
   955 lemma infnorm_sub: "infnorm (x - y) = infnorm (y - x)"
   956   by (metis infnorm_neg minus_diff_eq)
   957 
   958 lemma absdiff_infnorm: "\<bar>infnorm x - infnorm y\<bar> \<le> infnorm (x - y)"
   959 proof -
   960   have *: "\<And>(nx::real) n ny. nx \<le> n + ny \<Longrightarrow> ny \<le> n + nx \<Longrightarrow> \<bar>nx - ny\<bar> \<le> n"
   961     by arith
   962   show ?thesis
   963   proof (rule *)
   964     from infnorm_triangle[of "x - y" " y"] infnorm_triangle[of "x - y" "-x"]
   965     show "infnorm x \<le> infnorm (x - y) + infnorm y" "infnorm y \<le> infnorm (x - y) + infnorm x"
   966       by (simp_all add: field_simps infnorm_neg)
   967   qed
   968 qed
   969 
   970 lemma real_abs_infnorm: "\<bar>infnorm x\<bar> = infnorm x"
   971   using infnorm_pos_le[of x] by arith
   972 
   973 lemma Basis_le_infnorm:
   974   fixes x :: "'a::euclidean_space"
   975   shows "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> infnorm x"
   976   by (simp add: infnorm_Max)
   977 
   978 lemma infnorm_mul: "infnorm (a *\<^sub>R x) = \<bar>a\<bar> * infnorm x"
   979   unfolding infnorm_Max
   980 proof (safe intro!: Max_eqI)
   981   let ?B = "(\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
   982   { fix b :: 'a
   983     assume "b \<in> Basis"
   984     then show "\<bar>a *\<^sub>R x \<bullet> b\<bar> \<le> \<bar>a\<bar> * Max ?B"
   985       by (simp add: abs_mult mult_left_mono)
   986   next
   987     from Max_in[of ?B] obtain b where "b \<in> Basis" "Max ?B = \<bar>x \<bullet> b\<bar>"
   988       by (auto simp del: Max_in)
   989     then show "\<bar>a\<bar> * Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis) \<in> (\<lambda>i. \<bar>a *\<^sub>R x \<bullet> i\<bar>) ` Basis"
   990       by (intro image_eqI[where x=b]) (auto simp: abs_mult)
   991   }
   992 qed simp
   993 
   994 lemma infnorm_mul_lemma: "infnorm (a *\<^sub>R x) \<le> \<bar>a\<bar> * infnorm x"
   995   unfolding infnorm_mul ..
   996 
   997 lemma infnorm_pos_lt: "infnorm x > 0 \<longleftrightarrow> x \<noteq> 0"
   998   using infnorm_pos_le[of x] infnorm_eq_0[of x] by arith
   999 
  1000 text \<open>Prove that it differs only up to a bound from Euclidean norm.\<close>
  1001 
  1002 lemma infnorm_le_norm: "infnorm x \<le> norm x"
  1003   by (simp add: Basis_le_norm infnorm_Max)
  1004 
  1005 lemma norm_le_infnorm:
  1006   fixes x :: "'a::euclidean_space"
  1007   shows "norm x \<le> sqrt DIM('a) * infnorm x"
  1008   unfolding norm_eq_sqrt_inner id_def 
  1009 proof (rule real_le_lsqrt[OF inner_ge_zero])
  1010   show "sqrt DIM('a) * infnorm x \<ge> 0"
  1011     by (simp add: zero_le_mult_iff infnorm_pos_le)
  1012   have "x \<bullet> x \<le> (\<Sum>b\<in>Basis. x \<bullet> b * (x \<bullet> b))"
  1013     by (metis euclidean_inner order_refl)
  1014   also have "... \<le> DIM('a) * \<bar>infnorm x\<bar>\<^sup>2"
  1015     by (rule sum_bounded_above) (metis Basis_le_infnorm abs_le_square_iff power2_eq_square real_abs_infnorm)
  1016   also have "... \<le> (sqrt DIM('a) * infnorm x)\<^sup>2"
  1017     by (simp add: power_mult_distrib)
  1018   finally show "x \<bullet> x \<le> (sqrt DIM('a) * infnorm x)\<^sup>2" .
  1019 qed
  1020 
  1021 lemma tendsto_infnorm [tendsto_intros]:
  1022   assumes "(f \<longlongrightarrow> a) F"
  1023   shows "((\<lambda>x. infnorm (f x)) \<longlongrightarrow> infnorm a) F"
  1024 proof (rule tendsto_compose [OF LIM_I assms])
  1025   fix r :: real
  1026   assume "r > 0"
  1027   then show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (infnorm x - infnorm a) < r"
  1028     by (metis real_norm_def le_less_trans absdiff_infnorm infnorm_le_norm)
  1029 qed
  1030 
  1031 text \<open>Equality in Cauchy-Schwarz and triangle inequalities.\<close>
  1032 
  1033 lemma norm_cauchy_schwarz_eq: "x \<bullet> y = norm x * norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  1034   (is "?lhs \<longleftrightarrow> ?rhs")
  1035 proof (cases "x=0")
  1036   case True
  1037   then show ?thesis 
  1038     by auto
  1039 next
  1040   case False
  1041   from inner_eq_zero_iff[of "norm y *\<^sub>R x - norm x *\<^sub>R y"]
  1042   have "?rhs \<longleftrightarrow>
  1043       (norm y * (norm y * norm x * norm x - norm x * (x \<bullet> y)) -
  1044         norm x * (norm y * (y \<bullet> x) - norm x * norm y * norm y) =  0)"
  1045     using False unfolding inner_simps
  1046     by (auto simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
  1047   also have "\<dots> \<longleftrightarrow> (2 * norm x * norm y * (norm x * norm y - x \<bullet> y) = 0)" 
  1048     using False  by (simp add: field_simps inner_commute)
  1049   also have "\<dots> \<longleftrightarrow> ?lhs" 
  1050     using False by auto
  1051   finally show ?thesis by metis
  1052 qed
  1053 
  1054 lemma norm_cauchy_schwarz_abs_eq:
  1055   "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow>
  1056     norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm x *\<^sub>R y = - norm y *\<^sub>R x"
  1057   (is "?lhs \<longleftrightarrow> ?rhs")
  1058 proof -
  1059   have th: "\<And>(x::real) a. a \<ge> 0 \<Longrightarrow> \<bar>x\<bar> = a \<longleftrightarrow> x = a \<or> x = - a"
  1060     by arith
  1061   have "?rhs \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm (- x) *\<^sub>R y = norm y *\<^sub>R (- x)"
  1062     by simp
  1063   also have "\<dots> \<longleftrightarrow> (x \<bullet> y = norm x * norm y \<or> (- x) \<bullet> y = norm x * norm y)"
  1064     unfolding norm_cauchy_schwarz_eq[symmetric]
  1065     unfolding norm_minus_cancel norm_scaleR ..
  1066   also have "\<dots> \<longleftrightarrow> ?lhs"
  1067     unfolding th[OF mult_nonneg_nonneg, OF norm_ge_zero[of x] norm_ge_zero[of y]] inner_simps
  1068     by auto
  1069   finally show ?thesis ..
  1070 qed
  1071 
  1072 lemma norm_triangle_eq:
  1073   fixes x y :: "'a::real_inner"
  1074   shows "norm (x + y) = norm x + norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  1075 proof (cases "x = 0 \<or> y = 0")
  1076   case True
  1077   then show ?thesis 
  1078     by force
  1079 next
  1080   case False
  1081   then have n: "norm x > 0" "norm y > 0"
  1082     by auto
  1083   have "norm (x + y) = norm x + norm y \<longleftrightarrow> (norm (x + y))\<^sup>2 = (norm x + norm y)\<^sup>2"
  1084     by simp
  1085   also have "\<dots> \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  1086     unfolding norm_cauchy_schwarz_eq[symmetric]
  1087     unfolding power2_norm_eq_inner inner_simps
  1088     by (simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
  1089   finally show ?thesis .
  1090 qed
  1091 
  1092 
  1093 subsection \<open>Collinearity\<close>
  1094 
  1095 definition%important collinear :: "'a::real_vector set \<Rightarrow> bool"
  1096   where "collinear S \<longleftrightarrow> (\<exists>u. \<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u)"
  1097 
  1098 lemma collinear_alt:
  1099      "collinear S \<longleftrightarrow> (\<exists>u v. \<forall>x \<in> S. \<exists>c. x = u + c *\<^sub>R v)" (is "?lhs = ?rhs")
  1100 proof
  1101   assume ?lhs
  1102   then show ?rhs
  1103     unfolding collinear_def by (metis Groups.add_ac(2) diff_add_cancel)
  1104 next
  1105   assume ?rhs
  1106   then obtain u v where *: "\<And>x. x \<in> S \<Longrightarrow> \<exists>c. x = u + c *\<^sub>R v"
  1107     by (auto simp: )
  1108   have "\<exists>c. x - y = c *\<^sub>R v" if "x \<in> S" "y \<in> S" for x y
  1109         by (metis *[OF \<open>x \<in> S\<close>] *[OF \<open>y \<in> S\<close>] scaleR_left.diff add_diff_cancel_left)
  1110   then show ?lhs
  1111     using collinear_def by blast
  1112 qed
  1113 
  1114 lemma collinear:
  1115   fixes S :: "'a::{perfect_space,real_vector} set"
  1116   shows "collinear S \<longleftrightarrow> (\<exists>u. u \<noteq> 0 \<and> (\<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u))"
  1117 proof -
  1118   have "\<exists>v. v \<noteq> 0 \<and> (\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v)"
  1119     if "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R u" "u=0" for u
  1120   proof -
  1121     have "\<forall>x\<in>S. \<forall>y\<in>S. x = y"
  1122       using that by auto
  1123     moreover
  1124     obtain v::'a where "v \<noteq> 0"
  1125       using UNIV_not_singleton [of 0] by auto
  1126     ultimately have "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v"
  1127       by auto
  1128     then show ?thesis
  1129       using \<open>v \<noteq> 0\<close> by blast
  1130   qed
  1131   then show ?thesis
  1132     apply (clarsimp simp: collinear_def)
  1133     by (metis scaleR_zero_right vector_fraction_eq_iff)
  1134 qed
  1135 
  1136 lemma collinear_subset: "\<lbrakk>collinear T; S \<subseteq> T\<rbrakk> \<Longrightarrow> collinear S"
  1137   by (meson collinear_def subsetCE)
  1138 
  1139 lemma collinear_empty [iff]: "collinear {}"
  1140   by (simp add: collinear_def)
  1141 
  1142 lemma collinear_sing [iff]: "collinear {x}"
  1143   by (simp add: collinear_def)
  1144 
  1145 lemma collinear_2 [iff]: "collinear {x, y}"
  1146   apply (simp add: collinear_def)
  1147   apply (rule exI[where x="x - y"])
  1148   by (metis minus_diff_eq scaleR_left.minus scaleR_one)
  1149 
  1150 lemma collinear_lemma: "collinear {0, x, y} \<longleftrightarrow> x = 0 \<or> y = 0 \<or> (\<exists>c. y = c *\<^sub>R x)"
  1151   (is "?lhs \<longleftrightarrow> ?rhs")
  1152 proof (cases "x = 0 \<or> y = 0")
  1153   case True
  1154   then show ?thesis
  1155     by (auto simp: insert_commute)
  1156 next
  1157   case False
  1158   show ?thesis 
  1159   proof
  1160     assume h: "?lhs"
  1161     then obtain u where u: "\<forall> x\<in> {0,x,y}. \<forall>y\<in> {0,x,y}. \<exists>c. x - y = c *\<^sub>R u"
  1162       unfolding collinear_def by blast
  1163     from u[rule_format, of x 0] u[rule_format, of y 0]
  1164     obtain cx and cy where
  1165       cx: "x = cx *\<^sub>R u" and cy: "y = cy *\<^sub>R u"
  1166       by auto
  1167     from cx cy False have cx0: "cx \<noteq> 0" and cy0: "cy \<noteq> 0" by auto
  1168     let ?d = "cy / cx"
  1169     from cx cy cx0 have "y = ?d *\<^sub>R x"
  1170       by simp
  1171     then show ?rhs using False by blast
  1172   next
  1173     assume h: "?rhs"
  1174     then obtain c where c: "y = c *\<^sub>R x"
  1175       using False by blast
  1176     show ?lhs
  1177       unfolding collinear_def c
  1178       apply (rule exI[where x=x])
  1179       apply auto
  1180           apply (rule exI[where x="- 1"], simp)
  1181          apply (rule exI[where x= "-c"], simp)
  1182         apply (rule exI[where x=1], simp)
  1183        apply (rule exI[where x="1 - c"], simp add: scaleR_left_diff_distrib)
  1184       apply (rule exI[where x="c - 1"], simp add: scaleR_left_diff_distrib)
  1185       done
  1186   qed
  1187 qed
  1188 
  1189 lemma norm_cauchy_schwarz_equal: "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow> collinear {0, x, y}"
  1190 proof (cases "x=0")
  1191   case True
  1192   then show ?thesis
  1193     by (auto simp: insert_commute)
  1194 next
  1195   case False
  1196   then have nnz: "norm x \<noteq> 0"
  1197     by auto
  1198   show ?thesis
  1199   proof
  1200     assume "\<bar>x \<bullet> y\<bar> = norm x * norm y"
  1201     then show "collinear {0, x, y}"
  1202       unfolding norm_cauchy_schwarz_abs_eq collinear_lemma 
  1203       by (meson eq_vector_fraction_iff nnz)
  1204   next
  1205     assume "collinear {0, x, y}"
  1206     with False show "\<bar>x \<bullet> y\<bar> = norm x * norm y"
  1207       unfolding norm_cauchy_schwarz_abs_eq collinear_lemma  by (auto simp: abs_if)
  1208   qed
  1209 qed
  1210 
  1211 end