src/Pure/pattern.ML
author berghofe
Fri Oct 11 12:47:52 2002 +0200 (2002-10-11)
changeset 13645 430310b12c5b
parent 13642 a3d97348ceb6
child 13891 ae9a2a433388
permissions -rw-r--r--
norm_typ -> Envir.norm_type
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Unification of Higher-Order Patterns.
     7 
     8 See also:
     9 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
    10 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    11 
    12 TODO: optimize red by special-casing it
    13 *)
    14 
    15 infix aeconv;
    16 
    17 signature PATTERN =
    18   sig
    19   type type_sig
    20   type sg
    21   type env
    22   val trace_unify_fail  : bool ref
    23   val aeconv            : term * term -> bool
    24   val eta_contract      : term -> term
    25   val beta_eta_contract : term -> term
    26   val eta_contract_atom : term -> term
    27   val match             : type_sig -> term * term
    28                           -> (indexname*typ)list * (indexname*term)list
    29   val first_order_match : type_sig -> term * term
    30                           -> (indexname*typ)list * (indexname*term)list
    31   val matches           : type_sig -> term * term -> bool
    32   val matches_subterm   : type_sig -> term * term -> bool
    33   val unify             : sg * env * (term * term)list -> env
    34   val first_order       : term -> bool
    35   val pattern           : term -> bool
    36   val rewrite_term      : type_sig -> (term * term) list -> (term -> term option) list
    37                           -> term -> term
    38   exception Unif
    39   exception MATCH
    40   exception Pattern
    41   end;
    42 
    43 structure Pattern : PATTERN =
    44 struct
    45 
    46 type type_sig = Type.type_sig
    47 type sg = Sign.sg
    48 type env = Envir.env
    49 
    50 exception Unif;
    51 exception Pattern;
    52 
    53 val trace_unify_fail = ref false;
    54 
    55 (* Only for communication between unification and error message printing *)
    56 val sgr = ref Sign.pre_pure
    57 
    58 fun string_of_term env binders t = Sign.string_of_term (!sgr)
    59   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    60 
    61 fun bname binders i = fst(nth_elem(i,binders));
    62 fun bnames binders is = space_implode " " (map (bname binders) is);
    63 
    64 fun typ_clash(tye,T,U) =
    65   if !trace_unify_fail
    66   then let val t = Sign.string_of_typ (!sgr) (Envir.norm_type tye T)
    67            and u = Sign.string_of_typ (!sgr) (Envir.norm_type tye U)
    68        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    69   else ()
    70 
    71 fun clash a b =
    72   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    73 
    74 fun boundVar binders i =
    75   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    76 
    77 fun clashBB binders i j =
    78   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    79   else ()
    80 
    81 fun clashB binders i s =
    82   if !trace_unify_fail then clash (boundVar binders i) s
    83   else ()
    84 
    85 fun proj_fail(env,binders,F,is,t) =
    86   if !trace_unify_fail
    87   then let val f = Syntax.string_of_vname F
    88            val xs = bnames binders is
    89            val u = string_of_term env binders t
    90            val ys = bnames binders (loose_bnos t \\ is)
    91        in tracing("Cannot unify variable " ^ f ^
    92                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    93                "\nTerm contains additional bound variable(s) " ^ ys)
    94        end
    95   else ()
    96 
    97 fun ocheck_fail(F,t,binders,env) =
    98   if !trace_unify_fail
    99   then let val f = Syntax.string_of_vname F
   100            val u = string_of_term env binders t
   101        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
   102                   "\nCannot unify!\n")
   103        end
   104   else ()
   105 
   106 fun occurs(F,t,env) =
   107     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
   108                                  Some(t) => occ t
   109                                | None    => F=G)
   110           | occ(t1$t2)      = occ t1 orelse occ t2
   111           | occ(Abs(_,_,t)) = occ t
   112           | occ _           = false
   113     in occ t end;
   114 
   115 
   116 fun mapbnd f =
   117     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   118           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   119           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   120           | mpb _ atom           = atom
   121     in mpb 0 end;
   122 
   123 fun idx [] j     = ~10000
   124   | idx(i::is) j = if i=j then length is else idx is j;
   125 
   126 fun at xs i = nth_elem (i,xs);
   127 
   128 fun mkabs (binders,is,t)  =
   129     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
   130                         in Abs(x,T,mk is) end
   131           | mk []     = t
   132     in mk is end;
   133 
   134 val incr = mapbnd (fn i => i+1);
   135 
   136 fun ints_of []             = []
   137   | ints_of (Bound i ::bs) =
   138       let val is = ints_of bs
   139       in if i mem_int is then raise Pattern else i::is end
   140   | ints_of _              = raise Pattern;
   141 
   142 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   143 
   144 
   145 fun app (s,(i::is)) = app (s$Bound(i),is)
   146   | app (s,[])      = s;
   147 
   148 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   149   | red t            []      [] = t
   150   | red t            is      jn = app (mapbnd (at jn) t,is);
   151 
   152 
   153 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   154 fun split_type (T,0,Ts)                    = (Ts,T)
   155   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   156   | split_type _                           = error("split_type");
   157 
   158 fun type_of_G (T,n,is) =
   159   let val (Ts,U) = split_type(T,n,[]) in map(at Ts)is ---> U end;
   160 
   161 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   162 
   163 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   164   let val (env',G) = Envir.genvar a (env,type_of_G(T,length is,js))
   165   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   166 
   167 
   168 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   169 fun mk_proj_list is =
   170     let fun mk(i::is,j) = if i >= 0 then j :: mk(is,j-1) else mk(is,j-1)
   171           | mk([],_)    = []
   172     in mk(is,length is - 1) end;
   173 
   174 fun proj(s,env,binders,is) =
   175     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   176         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   177               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   178                             in (Abs(a,T,t'),env') end
   179             | t => (case strip_comb t of
   180                 (c as Const _,ts) =>
   181                          let val (ts',env') = prs(ts,env,d,binders)
   182                          in (list_comb(c,ts'),env') end
   183                  | (f as Free _,ts) =>
   184                          let val (ts',env') = prs(ts,env,d,binders)
   185                          in (list_comb(f,ts'),env') end
   186                  | (Bound(i),ts) =>
   187                          let val j = trans d i
   188                          in if j < 0 then raise Unif
   189                             else let val (ts',env') = prs(ts,env,d,binders)
   190                                  in (list_comb(Bound j,ts'),env') end
   191                          end
   192                  | (Var(F as (a,_),Fty),ts) =>
   193                       let val js = ints_of' env ts;
   194                           val js' = map (trans d) js;
   195                           val ks = mk_proj_list js';
   196                           val ls = filter (fn i => i >= 0) js'
   197                           val Hty = type_of_G(Fty,length js,ks)
   198                           val (env',H) = Envir.genvar a (env,Hty)
   199                           val env'' =
   200                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   201                       in (app(H,ls),env'') end
   202                  | _  => raise Pattern))
   203         and prs(s::ss,env,d,binders) =
   204               let val (s',env1) = pr(s,env,d,binders)
   205                   val (ss',env2) = prs(ss,env1,d,binders)
   206               in (s'::ss',env2) end
   207           | prs([],env,_,_) = ([],env)
   208    in if downto0(is,length binders - 1) then (s,env)
   209       else pr(s,env,0,binders)
   210    end;
   211 
   212 
   213 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   214 fun mk_ff_list(is,js) =
   215     let fun mk([],[],_)        = []
   216           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   217                                         else mk(is,js,k-1)
   218           | mk _               = error"mk_ff_list"
   219     in mk(is,js,length is-1) end;
   220 
   221 fun flexflex1(env,binders,F,Fty,is,js) =
   222   if is=js then env
   223   else let val ks = mk_ff_list(is,js)
   224        in mknewhnf(env,binders,is,F,Fty,ks) end;
   225 
   226 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   227   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   228             if js subset_int is
   229             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   230                  in Envir.update((F,t),env) end
   231             else let val ks = is inter_int js
   232                      val Hty = type_of_G(Fty,length is,map (idx is) ks)
   233                      val (env',H) = Envir.genvar a (env,Hty)
   234                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   235                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   236                  end;
   237   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   238 
   239 val tsgr = ref(Type.tsig0);
   240 
   241 fun unify_types(T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   242   if T=U then env
   243   else let val (iTs',maxidx') = Type.unify (!tsgr) (iTs, maxidx) (U, T)
   244        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   245        handle Type.TUNIFY => (typ_clash(iTs,T,U); raise Unif);
   246 
   247 fun unif binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   248       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   249          let val name = if ns = "" then nt else ns
   250          in unif ((name,Ts)::binders) (env,(ts,tt)) end
   251     | (Abs(ns,Ts,ts),t) => unif ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   252     | (t,Abs(nt,Tt,tt)) => unif ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   253     | p => cases(binders,env,p)
   254 
   255 and cases(binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   256        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   257          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   258                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   259       | ((Var(F,_),ss),_)             => flexrigid(env,binders,F,ints_of' env ss,t)
   260       | (_,(Var(F,_),ts))             => flexrigid(env,binders,F,ints_of' env ts,s)
   261       | ((Const c,ss),(Const d,ts))   => rigidrigid(env,binders,c,d,ss,ts)
   262       | ((Free(f),ss),(Free(g),ts))   => rigidrigid(env,binders,f,g,ss,ts)
   263       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB (env,binders,i,j,ss,ts)
   264       | ((Abs(_),_),_)                => raise Pattern
   265       | (_,(Abs(_),_))                => raise Pattern
   266       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   267       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   268       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   269       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   270       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   271       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   272 
   273 
   274 and rigidrigid (env,binders,(a,Ta),(b,Tb),ss,ts) =
   275       if a<>b then (clash a b; raise Unif)
   276       else foldl (unif binders) (unify_types(Ta,Tb,env), ss~~ts)
   277 
   278 and rigidrigidB (env,binders,i,j,ss,ts) =
   279      if i <> j then (clashBB binders i j; raise Unif)
   280      else foldl (unif binders) (env ,ss~~ts)
   281 
   282 and flexrigid (params as (env,binders,F,is,t)) =
   283       if occurs(F,t,env) then (ocheck_fail(F,t,binders,env); raise Unif)
   284       else (let val (u,env') = proj(t,env,binders,is)
   285             in Envir.update((F,mkabs(binders,is,u)),env') end
   286             handle Unif => (proj_fail params; raise Unif));
   287 
   288 fun unify(sg,env,tus) = (sgr := sg; tsgr := #tsig(Sign.rep_sg sg);
   289                          foldl (unif []) (env,tus));
   290 
   291 
   292 (*Eta-contract a term (fully)*)
   293 
   294 fun eta_contract t =
   295   let
   296     exception SAME;
   297     fun eta (Abs (a, T, body)) = 
   298       ((case eta body of
   299           body' as (f $ Bound 0) => 
   300 	    if loose_bvar1 (f, 0) then Abs(a, T, body')
   301 	    else incr_boundvars ~1 f
   302         | body' => Abs (a, T, body')) handle SAME =>
   303        (case body of
   304           (f $ Bound 0) => 
   305 	    if loose_bvar1 (f, 0) then raise SAME
   306 	    else incr_boundvars ~1 f
   307         | _ => raise SAME))
   308       | eta (f $ t) =
   309           (let val f' = eta f
   310            in f' $ etah t end handle SAME => f $ eta t)
   311       | eta _ = raise SAME
   312     and etah t = (eta t handle SAME => t)
   313   in etah t end;
   314 
   315 val beta_eta_contract = eta_contract o Envir.beta_norm;
   316 
   317 (*Eta-contract a term from outside: just enough to reduce it to an atom
   318 DOESN'T QUITE WORK!
   319 *)
   320 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   321       (case  eta_contract2 body  of
   322         body' as (f $ Bound 0) =>
   323             if loose_bvar1(f,0) then Abs(a,T,body')
   324             else eta_contract_atom (incr_boundvars ~1 f)
   325       | _ => t0)
   326   | eta_contract_atom t = t
   327 and eta_contract2 (f$t) = f $ eta_contract_atom t
   328   | eta_contract2 t     = eta_contract_atom t;
   329 
   330 
   331 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   332   Note that Consts and Vars may have more than one type.*)
   333 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   334 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   335   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   336   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   337   | aconv_aux (Bound i,    Bound j)    = i=j
   338   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   339   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   340   | aconv_aux _ =  false;
   341 
   342 
   343 (*** Matching ***)
   344 
   345 exception MATCH;
   346 
   347 fun typ_match tsig args = (Type.typ_match tsig args)
   348                           handle Type.TYPE_MATCH => raise MATCH;
   349 
   350 (*First-order matching;
   351   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   352   The pattern and object may have variables in common.
   353   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   354   Object is eta-contracted on the fly (by eta-expanding the pattern).
   355   Precondition: the pattern is already eta-contracted!
   356   Note: types are matched on the fly *)
   357 fun fomatch tsig =
   358   let
   359     fun mtch (instsp as (tyinsts,insts)) = fn
   360         (Var(ixn,T), t)  =>
   361           if loose_bvar(t,0) then raise MATCH
   362           else (case assoc_string_int(insts,ixn) of
   363                   None => (typ_match tsig (tyinsts, (T, fastype_of t)),
   364                            (ixn,t)::insts)
   365                 | Some u => if t aeconv u then instsp else raise MATCH)
   366       | (Free (a,T), Free (b,U)) =>
   367           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   368       | (Const (a,T), Const (b,U))  =>
   369           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   370       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   371       | (Abs(_,T,t), Abs(_,U,u))  =>
   372           mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   373       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   374       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   375       | _ => raise MATCH
   376   in mtch end;
   377 
   378 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   379 
   380 (* Matching of higher-order patterns *)
   381 
   382 fun match_bind(itms,binders,ixn,is,t) =
   383   let val js = loose_bnos t
   384   in if null is
   385      then if null js then (ixn,t)::itms else raise MATCH
   386      else if js subset_int is
   387           then let val t' = if downto0(is,length binders - 1) then t
   388                             else mapbnd (idx is) t
   389                in (ixn, mkabs(binders,is,t')) :: itms end
   390           else raise MATCH
   391   end;
   392 
   393 fun match tsg (po as (pat,obj)) =
   394 let
   395   (* Pre: pat and obj have same type *)
   396   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   397     case pat of
   398       Abs(ns,Ts,ts) =>
   399         (case obj of
   400            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   401          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   402                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   403     | _ => (case obj of
   404               Abs(nt,Tt,tt) =>
   405                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   406             | _ => cases(binders,env,pat,obj))
   407 
   408   and cases(binders,env as (iTs,itms),pat,obj) =
   409     let val (ph,pargs) = strip_comb pat
   410         fun rigrig1(iTs,oargs) =
   411               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   412         fun rigrig2((a,Ta),(b,Tb),oargs) =
   413               if a<> b then raise MATCH
   414               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   415     in case ph of
   416          Var(ixn,_) =>
   417            let val is = ints_of pargs
   418            in case assoc_string_int(itms,ixn) of
   419                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   420               | Some u => if obj aeconv (red u is []) then env
   421                           else raise MATCH
   422            end
   423        | _ =>
   424            let val (oh,oargs) = strip_comb obj
   425            in case (ph,oh) of
   426                 (Const c,Const d) => rigrig2(c,d,oargs)
   427               | (Free f,Free g)   => rigrig2(f,g,oargs)
   428               | (Bound i,Bound j) => if i<>j then raise MATCH
   429                                      else rigrig1(iTs,oargs)
   430               | (Abs _, _)        => raise Pattern
   431               | (_, Abs _)        => raise Pattern
   432               | _                 => raise MATCH
   433            end
   434     end;
   435 
   436   val pT = fastype_of pat
   437   and oT = fastype_of obj
   438   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   439   val insts2 = (iTs,[])
   440 
   441 in apfst Vartab.dest (mtch [] (insts2, po)
   442    handle Pattern => fomatch tsg insts2 po)
   443 end;
   444 
   445 (*Predicate: does the pattern match the object?*)
   446 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   447 
   448 (* Does pat match a subterm of obj? *)
   449 fun matches_subterm tsig (pat,obj) =
   450   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   451             case obj of
   452               Abs(x,T,t) => let val y = variant bounds x
   453                                 val f = Free(":" ^ y,T)
   454                             in msub(x::bounds,subst_bound(f,t)) end
   455             | s$t => msub(bounds,s) orelse msub(bounds,t)
   456             | _ => false
   457   in msub([],obj) end;
   458 
   459 fun first_order(Abs(_,_,t)) = first_order t
   460   | first_order(t $ u) = first_order t andalso first_order u andalso
   461                          not(is_Var t)
   462   | first_order _ = true;
   463 
   464 fun pattern(Abs(_,_,t)) = pattern t
   465   | pattern(t) = let val (head,args) = strip_comb t
   466                  in if is_Var head
   467                     then let val _ = ints_of args in true end
   468                          handle Pattern => false
   469                     else forall pattern args
   470                  end;
   471 
   472 
   473 (* rewriting -- simple but fast *)
   474 
   475 fun rewrite_term tsig rules procs tm =
   476   let
   477     val skel0 = Bound 0;
   478 
   479     val rhs_names =
   480       foldr (fn ((_, rhs), names) => add_term_free_names (rhs, names)) (rules, []);
   481 
   482     fun variant_absfree (x, T, t) =
   483       let
   484         val x' = variant (add_term_free_names (t, rhs_names)) x;
   485         val t' = subst_bound (Free (x', T), t);
   486       in (fn u => Abs (x, T, abstract_over (Free (x', T), u)), t') end;
   487 
   488     fun match_rew tm (tm1, tm2) =
   489       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2
   490       in Some (subst_vars (match tsig (tm1, tm)) rtm, rtm)
   491         handle MATCH => None
   492       end;
   493 
   494     fun rew (Abs (_, _, body) $ t) = Some (subst_bound (t, body), skel0)
   495       | rew tm = (case get_first (match_rew tm) rules of
   496           None => apsome (rpair skel0) (get_first (fn p => p tm) procs)
   497         | x => x);
   498 
   499     fun rew1 (Var _) _ = None
   500       | rew1 skel tm = (case rew2 skel tm of
   501           Some tm1 => (case rew tm1 of
   502               Some (tm2, skel') => Some (if_none (rew1 skel' tm2) tm2)
   503             | None => Some tm1)
   504         | None => (case rew tm of
   505               Some (tm1, skel') => Some (if_none (rew1 skel' tm1) tm1)
   506             | None => None))
   507 
   508     and rew2 skel (tm1 $ tm2) = (case tm1 of
   509             Abs (_, _, body) =>
   510               let val tm' = subst_bound (tm2, body)
   511               in Some (if_none (rew2 skel0 tm') tm') end
   512           | _ => 
   513             let val (skel1, skel2) = (case skel of
   514                 skel1 $ skel2 => (skel1, skel2)
   515               | _ => (skel0, skel0))
   516             in case rew1 skel1 tm1 of
   517                 Some tm1' => (case rew1 skel2 tm2 of
   518                     Some tm2' => Some (tm1' $ tm2')
   519                   | None => Some (tm1' $ tm2))
   520               | None => (case rew1 skel2 tm2 of
   521                     Some tm2' => Some (tm1 $ tm2')
   522                   | None => None)
   523             end)
   524       | rew2 skel (Abs (x, T, tm)) =
   525           let
   526             val (abs, tm') = variant_absfree (x, T, tm);
   527             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   528           in case rew1 skel' tm' of
   529               Some tm'' => Some (abs tm'')
   530             | None => None
   531           end
   532       | rew2 _ _ = None
   533 
   534   in if_none (rew1 skel0 tm) tm end;
   535 
   536 end;
   537 
   538 val trace_unify_fail = Pattern.trace_unify_fail;