src/HOL/Set_Interval.thy
author huffman
Tue Apr 03 15:15:00 2012 +0200 (2012-04-03)
changeset 47317 432b29a96f61
parent 47222 src/HOL/SetInterval.thy@1b7c909a6fad
child 47988 e4b69e10b990
permissions -rw-r--r--
modernized obsolete old-style theory name with proper new-style underscore
     1 (*  Title:      HOL/Set_Interval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 *)
     8 
     9 header {* Set intervals *}
    10 
    11 theory Set_Interval
    12 imports Int Nat_Transfer
    13 begin
    14 
    15 context ord
    16 begin
    17 
    18 definition
    19   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    20   "{..<u} == {x. x < u}"
    21 
    22 definition
    23   atMost      :: "'a => 'a set" ("(1{.._})") where
    24   "{..u} == {x. x \<le> u}"
    25 
    26 definition
    27   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    28   "{l<..} == {x. l<x}"
    29 
    30 definition
    31   atLeast     :: "'a => 'a set" ("(1{_..})") where
    32   "{l..} == {x. l\<le>x}"
    33 
    34 definition
    35   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    36   "{l<..<u} == {l<..} Int {..<u}"
    37 
    38 definition
    39   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    40   "{l..<u} == {l..} Int {..<u}"
    41 
    42 definition
    43   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    44   "{l<..u} == {l<..} Int {..u}"
    45 
    46 definition
    47   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    48   "{l..u} == {l..} Int {..u}"
    49 
    50 end
    51 
    52 
    53 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    54 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    55 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    56 
    57 syntax
    58   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" [0, 0, 10] 10)
    59   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" [0, 0, 10] 10)
    60   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" [0, 0, 10] 10)
    61   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" [0, 0, 10] 10)
    62 
    63 syntax (xsymbols)
    64   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" [0, 0, 10] 10)
    65   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" [0, 0, 10] 10)
    66   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" [0, 0, 10] 10)
    67   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" [0, 0, 10] 10)
    68 
    69 syntax (latex output)
    70   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    71   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" [0, 0, 10] 10)
    72   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    73   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" [0, 0, 10] 10)
    74 
    75 translations
    76   "UN i<=n. A"  == "UN i:{..n}. A"
    77   "UN i<n. A"   == "UN i:{..<n}. A"
    78   "INT i<=n. A" == "INT i:{..n}. A"
    79   "INT i<n. A"  == "INT i:{..<n}. A"
    80 
    81 
    82 subsection {* Various equivalences *}
    83 
    84 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    85 by (simp add: lessThan_def)
    86 
    87 lemma Compl_lessThan [simp]:
    88     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    89 apply (auto simp add: lessThan_def atLeast_def)
    90 done
    91 
    92 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    93 by auto
    94 
    95 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    96 by (simp add: greaterThan_def)
    97 
    98 lemma Compl_greaterThan [simp]:
    99     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   100   by (auto simp add: greaterThan_def atMost_def)
   101 
   102 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   103 apply (subst Compl_greaterThan [symmetric])
   104 apply (rule double_complement)
   105 done
   106 
   107 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   108 by (simp add: atLeast_def)
   109 
   110 lemma Compl_atLeast [simp]:
   111     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   112   by (auto simp add: lessThan_def atLeast_def)
   113 
   114 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   115 by (simp add: atMost_def)
   116 
   117 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   118 by (blast intro: order_antisym)
   119 
   120 
   121 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   122 
   123 lemma atLeast_subset_iff [iff]:
   124      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   125 by (blast intro: order_trans)
   126 
   127 lemma atLeast_eq_iff [iff]:
   128      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   129 by (blast intro: order_antisym order_trans)
   130 
   131 lemma greaterThan_subset_iff [iff]:
   132      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   133 apply (auto simp add: greaterThan_def)
   134  apply (subst linorder_not_less [symmetric], blast)
   135 done
   136 
   137 lemma greaterThan_eq_iff [iff]:
   138      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   139 apply (rule iffI)
   140  apply (erule equalityE)
   141  apply simp_all
   142 done
   143 
   144 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   145 by (blast intro: order_trans)
   146 
   147 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   148 by (blast intro: order_antisym order_trans)
   149 
   150 lemma lessThan_subset_iff [iff]:
   151      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   152 apply (auto simp add: lessThan_def)
   153  apply (subst linorder_not_less [symmetric], blast)
   154 done
   155 
   156 lemma lessThan_eq_iff [iff]:
   157      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   158 apply (rule iffI)
   159  apply (erule equalityE)
   160  apply simp_all
   161 done
   162 
   163 lemma lessThan_strict_subset_iff:
   164   fixes m n :: "'a::linorder"
   165   shows "{..<m} < {..<n} \<longleftrightarrow> m < n"
   166   by (metis leD lessThan_subset_iff linorder_linear not_less_iff_gr_or_eq psubset_eq)
   167 
   168 subsection {*Two-sided intervals*}
   169 
   170 context ord
   171 begin
   172 
   173 lemma greaterThanLessThan_iff [simp,no_atp]:
   174   "(i : {l<..<u}) = (l < i & i < u)"
   175 by (simp add: greaterThanLessThan_def)
   176 
   177 lemma atLeastLessThan_iff [simp,no_atp]:
   178   "(i : {l..<u}) = (l <= i & i < u)"
   179 by (simp add: atLeastLessThan_def)
   180 
   181 lemma greaterThanAtMost_iff [simp,no_atp]:
   182   "(i : {l<..u}) = (l < i & i <= u)"
   183 by (simp add: greaterThanAtMost_def)
   184 
   185 lemma atLeastAtMost_iff [simp,no_atp]:
   186   "(i : {l..u}) = (l <= i & i <= u)"
   187 by (simp add: atLeastAtMost_def)
   188 
   189 text {* The above four lemmas could be declared as iffs. Unfortunately this
   190 breaks many proofs. Since it only helps blast, it is better to leave well
   191 alone *}
   192 
   193 end
   194 
   195 subsubsection{* Emptyness, singletons, subset *}
   196 
   197 context order
   198 begin
   199 
   200 lemma atLeastatMost_empty[simp]:
   201   "b < a \<Longrightarrow> {a..b} = {}"
   202 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   203 
   204 lemma atLeastatMost_empty_iff[simp]:
   205   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   206 by auto (blast intro: order_trans)
   207 
   208 lemma atLeastatMost_empty_iff2[simp]:
   209   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   210 by auto (blast intro: order_trans)
   211 
   212 lemma atLeastLessThan_empty[simp]:
   213   "b <= a \<Longrightarrow> {a..<b} = {}"
   214 by(auto simp: atLeastLessThan_def)
   215 
   216 lemma atLeastLessThan_empty_iff[simp]:
   217   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   218 by auto (blast intro: le_less_trans)
   219 
   220 lemma atLeastLessThan_empty_iff2[simp]:
   221   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   222 by auto (blast intro: le_less_trans)
   223 
   224 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   225 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   226 
   227 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   228 by auto (blast intro: less_le_trans)
   229 
   230 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   231 by auto (blast intro: less_le_trans)
   232 
   233 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   234 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   235 
   236 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   237 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   238 
   239 lemma atLeastAtMost_singleton': "a = b \<Longrightarrow> {a .. b} = {a}" by simp
   240 
   241 lemma atLeastatMost_subset_iff[simp]:
   242   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   243 unfolding atLeastAtMost_def atLeast_def atMost_def
   244 by (blast intro: order_trans)
   245 
   246 lemma atLeastatMost_psubset_iff:
   247   "{a..b} < {c..d} \<longleftrightarrow>
   248    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   249 by(simp add: psubset_eq set_eq_iff less_le_not_le)(blast intro: order_trans)
   250 
   251 lemma atLeastAtMost_singleton_iff[simp]:
   252   "{a .. b} = {c} \<longleftrightarrow> a = b \<and> b = c"
   253 proof
   254   assume "{a..b} = {c}"
   255   hence "\<not> (\<not> a \<le> b)" unfolding atLeastatMost_empty_iff[symmetric] by simp
   256   moreover with `{a..b} = {c}` have "c \<le> a \<and> b \<le> c" by auto
   257   ultimately show "a = b \<and> b = c" by auto
   258 qed simp
   259 
   260 end
   261 
   262 context dense_linorder
   263 begin
   264 
   265 lemma greaterThanLessThan_empty_iff[simp]:
   266   "{ a <..< b } = {} \<longleftrightarrow> b \<le> a"
   267   using dense[of a b] by (cases "a < b") auto
   268 
   269 lemma greaterThanLessThan_empty_iff2[simp]:
   270   "{} = { a <..< b } \<longleftrightarrow> b \<le> a"
   271   using dense[of a b] by (cases "a < b") auto
   272 
   273 lemma atLeastLessThan_subseteq_atLeastAtMost_iff:
   274   "{a ..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   275   using dense[of "max a d" "b"]
   276   by (force simp: subset_eq Ball_def not_less[symmetric])
   277 
   278 lemma greaterThanAtMost_subseteq_atLeastAtMost_iff:
   279   "{a <.. b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   280   using dense[of "a" "min c b"]
   281   by (force simp: subset_eq Ball_def not_less[symmetric])
   282 
   283 lemma greaterThanLessThan_subseteq_atLeastAtMost_iff:
   284   "{a <..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   285   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   286   by (force simp: subset_eq Ball_def not_less[symmetric])
   287 
   288 lemma atLeastAtMost_subseteq_atLeastLessThan_iff:
   289   "{a .. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a \<le> b \<longrightarrow> c \<le> a \<and> b < d)"
   290   using dense[of "max a d" "b"]
   291   by (force simp: subset_eq Ball_def not_less[symmetric])
   292 
   293 lemma greaterThanAtMost_subseteq_atLeastLessThan_iff:
   294   "{a <.. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b < d)"
   295   using dense[of "a" "min c b"]
   296   by (force simp: subset_eq Ball_def not_less[symmetric])
   297 
   298 lemma greaterThanLessThan_subseteq_atLeastLessThan_iff:
   299   "{a <..< b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   300   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   301   by (force simp: subset_eq Ball_def not_less[symmetric])
   302 
   303 end
   304 
   305 lemma (in linorder) atLeastLessThan_subset_iff:
   306   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   307 apply (auto simp:subset_eq Ball_def)
   308 apply(frule_tac x=a in spec)
   309 apply(erule_tac x=d in allE)
   310 apply (simp add: less_imp_le)
   311 done
   312 
   313 lemma atLeastLessThan_inj:
   314   fixes a b c d :: "'a::linorder"
   315   assumes eq: "{a ..< b} = {c ..< d}" and "a < b" "c < d"
   316   shows "a = c" "b = d"
   317 using assms by (metis atLeastLessThan_subset_iff eq less_le_not_le linorder_antisym_conv2 subset_refl)+
   318 
   319 lemma atLeastLessThan_eq_iff:
   320   fixes a b c d :: "'a::linorder"
   321   assumes "a < b" "c < d"
   322   shows "{a ..< b} = {c ..< d} \<longleftrightarrow> a = c \<and> b = d"
   323   using atLeastLessThan_inj assms by auto
   324 
   325 subsubsection {* Intersection *}
   326 
   327 context linorder
   328 begin
   329 
   330 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   331 by auto
   332 
   333 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   334 by auto
   335 
   336 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   337 by auto
   338 
   339 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   340 by auto
   341 
   342 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   343 by auto
   344 
   345 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   346 by auto
   347 
   348 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   349 by auto
   350 
   351 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   352 by auto
   353 
   354 end
   355 
   356 
   357 subsection {* Intervals of natural numbers *}
   358 
   359 subsubsection {* The Constant @{term lessThan} *}
   360 
   361 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   362 by (simp add: lessThan_def)
   363 
   364 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   365 by (simp add: lessThan_def less_Suc_eq, blast)
   366 
   367 text {* The following proof is convenient in induction proofs where
   368 new elements get indices at the beginning. So it is used to transform
   369 @{term "{..<Suc n}"} to @{term "0::nat"} and @{term "{..< n}"}. *}
   370 
   371 lemma lessThan_Suc_eq_insert_0: "{..<Suc n} = insert 0 (Suc ` {..<n})"
   372 proof safe
   373   fix x assume "x < Suc n" "x \<notin> Suc ` {..<n}"
   374   then have "x \<noteq> Suc (x - 1)" by auto
   375   with `x < Suc n` show "x = 0" by auto
   376 qed
   377 
   378 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   379 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   380 
   381 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   382 by blast
   383 
   384 subsubsection {* The Constant @{term greaterThan} *}
   385 
   386 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   387 apply (simp add: greaterThan_def)
   388 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   389 done
   390 
   391 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   392 apply (simp add: greaterThan_def)
   393 apply (auto elim: linorder_neqE)
   394 done
   395 
   396 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   397 by blast
   398 
   399 subsubsection {* The Constant @{term atLeast} *}
   400 
   401 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   402 by (unfold atLeast_def UNIV_def, simp)
   403 
   404 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   405 apply (simp add: atLeast_def)
   406 apply (simp add: Suc_le_eq)
   407 apply (simp add: order_le_less, blast)
   408 done
   409 
   410 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   411   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   412 
   413 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   414 by blast
   415 
   416 subsubsection {* The Constant @{term atMost} *}
   417 
   418 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   419 by (simp add: atMost_def)
   420 
   421 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   422 apply (simp add: atMost_def)
   423 apply (simp add: less_Suc_eq order_le_less, blast)
   424 done
   425 
   426 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   427 by blast
   428 
   429 subsubsection {* The Constant @{term atLeastLessThan} *}
   430 
   431 text{*The orientation of the following 2 rules is tricky. The lhs is
   432 defined in terms of the rhs.  Hence the chosen orientation makes sense
   433 in this theory --- the reverse orientation complicates proofs (eg
   434 nontermination). But outside, when the definition of the lhs is rarely
   435 used, the opposite orientation seems preferable because it reduces a
   436 specific concept to a more general one. *}
   437 
   438 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   439 by(simp add:lessThan_def atLeastLessThan_def)
   440 
   441 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   442 by(simp add:atMost_def atLeastAtMost_def)
   443 
   444 declare atLeast0LessThan[symmetric, code_unfold]
   445         atLeast0AtMost[symmetric, code_unfold]
   446 
   447 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   448 by (simp add: atLeastLessThan_def)
   449 
   450 subsubsection {* Intervals of nats with @{term Suc} *}
   451 
   452 text{*Not a simprule because the RHS is too messy.*}
   453 lemma atLeastLessThanSuc:
   454     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   455 by (auto simp add: atLeastLessThan_def)
   456 
   457 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   458 by (auto simp add: atLeastLessThan_def)
   459 (*
   460 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   461 by (induct k, simp_all add: atLeastLessThanSuc)
   462 
   463 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   464 by (auto simp add: atLeastLessThan_def)
   465 *)
   466 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   467   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   468 
   469 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   470   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   471     greaterThanAtMost_def)
   472 
   473 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   474   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   475     greaterThanLessThan_def)
   476 
   477 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   478 by (auto simp add: atLeastAtMost_def)
   479 
   480 lemma atLeastAtMost_insertL: "m \<le> n \<Longrightarrow> insert m {Suc m..n} = {m ..n}"
   481 by auto
   482 
   483 text {* The analogous result is useful on @{typ int}: *}
   484 (* here, because we don't have an own int section *)
   485 lemma atLeastAtMostPlus1_int_conv:
   486   "m <= 1+n \<Longrightarrow> {m..1+n} = insert (1+n) {m..n::int}"
   487   by (auto intro: set_eqI)
   488 
   489 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   490   apply (induct k) 
   491   apply (simp_all add: atLeastLessThanSuc)   
   492   done
   493 
   494 subsubsection {* Image *}
   495 
   496 lemma image_add_atLeastAtMost:
   497   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   498 proof
   499   show "?A \<subseteq> ?B" by auto
   500 next
   501   show "?B \<subseteq> ?A"
   502   proof
   503     fix n assume a: "n : ?B"
   504     hence "n - k : {i..j}" by auto
   505     moreover have "n = (n - k) + k" using a by auto
   506     ultimately show "n : ?A" by blast
   507   qed
   508 qed
   509 
   510 lemma image_add_atLeastLessThan:
   511   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   512 proof
   513   show "?A \<subseteq> ?B" by auto
   514 next
   515   show "?B \<subseteq> ?A"
   516   proof
   517     fix n assume a: "n : ?B"
   518     hence "n - k : {i..<j}" by auto
   519     moreover have "n = (n - k) + k" using a by auto
   520     ultimately show "n : ?A" by blast
   521   qed
   522 qed
   523 
   524 corollary image_Suc_atLeastAtMost[simp]:
   525   "Suc ` {i..j} = {Suc i..Suc j}"
   526 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   527 
   528 corollary image_Suc_atLeastLessThan[simp]:
   529   "Suc ` {i..<j} = {Suc i..<Suc j}"
   530 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   531 
   532 lemma image_add_int_atLeastLessThan:
   533     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   534   apply (auto simp add: image_def)
   535   apply (rule_tac x = "x - l" in bexI)
   536   apply auto
   537   done
   538 
   539 lemma image_minus_const_atLeastLessThan_nat:
   540   fixes c :: nat
   541   shows "(\<lambda>i. i - c) ` {x ..< y} =
   542       (if c < y then {x - c ..< y - c} else if x < y then {0} else {})"
   543     (is "_ = ?right")
   544 proof safe
   545   fix a assume a: "a \<in> ?right"
   546   show "a \<in> (\<lambda>i. i - c) ` {x ..< y}"
   547   proof cases
   548     assume "c < y" with a show ?thesis
   549       by (auto intro!: image_eqI[of _ _ "a + c"])
   550   next
   551     assume "\<not> c < y" with a show ?thesis
   552       by (auto intro!: image_eqI[of _ _ x] split: split_if_asm)
   553   qed
   554 qed auto
   555 
   556 context ordered_ab_group_add
   557 begin
   558 
   559 lemma
   560   fixes x :: 'a
   561   shows image_uminus_greaterThan[simp]: "uminus ` {x<..} = {..<-x}"
   562   and image_uminus_atLeast[simp]: "uminus ` {x..} = {..-x}"
   563 proof safe
   564   fix y assume "y < -x"
   565   hence *:  "x < -y" using neg_less_iff_less[of "-y" x] by simp
   566   have "- (-y) \<in> uminus ` {x<..}"
   567     by (rule imageI) (simp add: *)
   568   thus "y \<in> uminus ` {x<..}" by simp
   569 next
   570   fix y assume "y \<le> -x"
   571   have "- (-y) \<in> uminus ` {x..}"
   572     by (rule imageI) (insert `y \<le> -x`[THEN le_imp_neg_le], simp)
   573   thus "y \<in> uminus ` {x..}" by simp
   574 qed simp_all
   575 
   576 lemma
   577   fixes x :: 'a
   578   shows image_uminus_lessThan[simp]: "uminus ` {..<x} = {-x<..}"
   579   and image_uminus_atMost[simp]: "uminus ` {..x} = {-x..}"
   580 proof -
   581   have "uminus ` {..<x} = uminus ` uminus ` {-x<..}"
   582     and "uminus ` {..x} = uminus ` uminus ` {-x..}" by simp_all
   583   thus "uminus ` {..<x} = {-x<..}" and "uminus ` {..x} = {-x..}"
   584     by (simp_all add: image_image
   585         del: image_uminus_greaterThan image_uminus_atLeast)
   586 qed
   587 
   588 lemma
   589   fixes x :: 'a
   590   shows image_uminus_atLeastAtMost[simp]: "uminus ` {x..y} = {-y..-x}"
   591   and image_uminus_greaterThanAtMost[simp]: "uminus ` {x<..y} = {-y..<-x}"
   592   and image_uminus_atLeastLessThan[simp]: "uminus ` {x..<y} = {-y<..-x}"
   593   and image_uminus_greaterThanLessThan[simp]: "uminus ` {x<..<y} = {-y<..<-x}"
   594   by (simp_all add: atLeastAtMost_def greaterThanAtMost_def atLeastLessThan_def
   595       greaterThanLessThan_def image_Int[OF inj_uminus] Int_commute)
   596 end
   597 
   598 subsubsection {* Finiteness *}
   599 
   600 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   601   by (induct k) (simp_all add: lessThan_Suc)
   602 
   603 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   604   by (induct k) (simp_all add: atMost_Suc)
   605 
   606 lemma finite_greaterThanLessThan [iff]:
   607   fixes l :: nat shows "finite {l<..<u}"
   608 by (simp add: greaterThanLessThan_def)
   609 
   610 lemma finite_atLeastLessThan [iff]:
   611   fixes l :: nat shows "finite {l..<u}"
   612 by (simp add: atLeastLessThan_def)
   613 
   614 lemma finite_greaterThanAtMost [iff]:
   615   fixes l :: nat shows "finite {l<..u}"
   616 by (simp add: greaterThanAtMost_def)
   617 
   618 lemma finite_atLeastAtMost [iff]:
   619   fixes l :: nat shows "finite {l..u}"
   620 by (simp add: atLeastAtMost_def)
   621 
   622 text {* A bounded set of natural numbers is finite. *}
   623 lemma bounded_nat_set_is_finite:
   624   "(ALL i:N. i < (n::nat)) ==> finite N"
   625 apply (rule finite_subset)
   626  apply (rule_tac [2] finite_lessThan, auto)
   627 done
   628 
   629 text {* A set of natural numbers is finite iff it is bounded. *}
   630 lemma finite_nat_set_iff_bounded:
   631   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   632 proof
   633   assume f:?F  show ?B
   634     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   635 next
   636   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   637 qed
   638 
   639 lemma finite_nat_set_iff_bounded_le:
   640   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   641 apply(simp add:finite_nat_set_iff_bounded)
   642 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   643 done
   644 
   645 lemma finite_less_ub:
   646      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   647 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   648 
   649 text{* Any subset of an interval of natural numbers the size of the
   650 subset is exactly that interval. *}
   651 
   652 lemma subset_card_intvl_is_intvl:
   653   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   654 proof cases
   655   assume "finite A"
   656   thus "PROP ?P"
   657   proof(induct A rule:finite_linorder_max_induct)
   658     case empty thus ?case by auto
   659   next
   660     case (insert b A)
   661     moreover hence "b ~: A" by auto
   662     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   663       using `b ~: A` insert by fastforce+
   664     ultimately show ?case by auto
   665   qed
   666 next
   667   assume "~finite A" thus "PROP ?P" by simp
   668 qed
   669 
   670 
   671 subsubsection {* Proving Inclusions and Equalities between Unions *}
   672 
   673 lemma UN_le_eq_Un0:
   674   "(\<Union>i\<le>n::nat. M i) = (\<Union>i\<in>{1..n}. M i) \<union> M 0" (is "?A = ?B")
   675 proof
   676   show "?A <= ?B"
   677   proof
   678     fix x assume "x : ?A"
   679     then obtain i where i: "i\<le>n" "x : M i" by auto
   680     show "x : ?B"
   681     proof(cases i)
   682       case 0 with i show ?thesis by simp
   683     next
   684       case (Suc j) with i show ?thesis by auto
   685     qed
   686   qed
   687 next
   688   show "?B <= ?A" by auto
   689 qed
   690 
   691 lemma UN_le_add_shift:
   692   "(\<Union>i\<le>n::nat. M(i+k)) = (\<Union>i\<in>{k..n+k}. M i)" (is "?A = ?B")
   693 proof
   694   show "?A <= ?B" by fastforce
   695 next
   696   show "?B <= ?A"
   697   proof
   698     fix x assume "x : ?B"
   699     then obtain i where i: "i : {k..n+k}" "x : M(i)" by auto
   700     hence "i-k\<le>n & x : M((i-k)+k)" by auto
   701     thus "x : ?A" by blast
   702   qed
   703 qed
   704 
   705 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
   706   by (auto simp add: atLeast0LessThan) 
   707 
   708 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
   709   by (subst UN_UN_finite_eq [symmetric]) blast
   710 
   711 lemma UN_finite2_subset: 
   712      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
   713   apply (rule UN_finite_subset)
   714   apply (subst UN_UN_finite_eq [symmetric, of B]) 
   715   apply blast
   716   done
   717 
   718 lemma UN_finite2_eq:
   719   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
   720   apply (rule subset_antisym)
   721    apply (rule UN_finite2_subset, blast)
   722  apply (rule UN_finite2_subset [where k=k])
   723  apply (force simp add: atLeastLessThan_add_Un [of 0])
   724  done
   725 
   726 
   727 subsubsection {* Cardinality *}
   728 
   729 lemma card_lessThan [simp]: "card {..<u} = u"
   730   by (induct u, simp_all add: lessThan_Suc)
   731 
   732 lemma card_atMost [simp]: "card {..u} = Suc u"
   733   by (simp add: lessThan_Suc_atMost [THEN sym])
   734 
   735 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   736   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   737   apply (erule ssubst, rule card_lessThan)
   738   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   739   apply (erule subst)
   740   apply (rule card_image)
   741   apply (simp add: inj_on_def)
   742   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   743   apply (rule_tac x = "x - l" in exI)
   744   apply arith
   745   done
   746 
   747 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   748   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   749 
   750 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   751   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   752 
   753 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   754   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   755 
   756 lemma ex_bij_betw_nat_finite:
   757   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   758 apply(drule finite_imp_nat_seg_image_inj_on)
   759 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   760 done
   761 
   762 lemma ex_bij_betw_finite_nat:
   763   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   764 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   765 
   766 lemma finite_same_card_bij:
   767   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
   768 apply(drule ex_bij_betw_finite_nat)
   769 apply(drule ex_bij_betw_nat_finite)
   770 apply(auto intro!:bij_betw_trans)
   771 done
   772 
   773 lemma ex_bij_betw_nat_finite_1:
   774   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
   775 by (rule finite_same_card_bij) auto
   776 
   777 lemma bij_betw_iff_card:
   778   assumes FIN: "finite A" and FIN': "finite B"
   779   shows BIJ: "(\<exists>f. bij_betw f A B) \<longleftrightarrow> (card A = card B)"
   780 using assms
   781 proof(auto simp add: bij_betw_same_card)
   782   assume *: "card A = card B"
   783   obtain f where "bij_betw f A {0 ..< card A}"
   784   using FIN ex_bij_betw_finite_nat by blast
   785   moreover obtain g where "bij_betw g {0 ..< card B} B"
   786   using FIN' ex_bij_betw_nat_finite by blast
   787   ultimately have "bij_betw (g o f) A B"
   788   using * by (auto simp add: bij_betw_trans)
   789   thus "(\<exists>f. bij_betw f A B)" by blast
   790 qed
   791 
   792 lemma inj_on_iff_card_le:
   793   assumes FIN: "finite A" and FIN': "finite B"
   794   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> B) = (card A \<le> card B)"
   795 proof (safe intro!: card_inj_on_le)
   796   assume *: "card A \<le> card B"
   797   obtain f where 1: "inj_on f A" and 2: "f ` A = {0 ..< card A}"
   798   using FIN ex_bij_betw_finite_nat unfolding bij_betw_def by force
   799   moreover obtain g where "inj_on g {0 ..< card B}" and 3: "g ` {0 ..< card B} = B"
   800   using FIN' ex_bij_betw_nat_finite unfolding bij_betw_def by force
   801   ultimately have "inj_on g (f ` A)" using subset_inj_on[of g _ "f ` A"] * by force
   802   hence "inj_on (g o f) A" using 1 comp_inj_on by blast
   803   moreover
   804   {have "{0 ..< card A} \<le> {0 ..< card B}" using * by force
   805    with 2 have "f ` A  \<le> {0 ..< card B}" by blast
   806    hence "(g o f) ` A \<le> B" unfolding comp_def using 3 by force
   807   }
   808   ultimately show "(\<exists>f. inj_on f A \<and> f ` A \<le> B)" by blast
   809 qed (insert assms, auto)
   810 
   811 subsection {* Intervals of integers *}
   812 
   813 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   814   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   815 
   816 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   817   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   818 
   819 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   820     "{l+1..<u} = {l<..<u::int}"
   821   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   822 
   823 subsubsection {* Finiteness *}
   824 
   825 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   826     {(0::int)..<u} = int ` {..<nat u}"
   827   apply (unfold image_def lessThan_def)
   828   apply auto
   829   apply (rule_tac x = "nat x" in exI)
   830   apply (auto simp add: zless_nat_eq_int_zless [THEN sym])
   831   done
   832 
   833 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   834   apply (case_tac "0 \<le> u")
   835   apply (subst image_atLeastZeroLessThan_int, assumption)
   836   apply (rule finite_imageI)
   837   apply auto
   838   done
   839 
   840 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   841   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   842   apply (erule subst)
   843   apply (rule finite_imageI)
   844   apply (rule finite_atLeastZeroLessThan_int)
   845   apply (rule image_add_int_atLeastLessThan)
   846   done
   847 
   848 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   849   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   850 
   851 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   852   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   853 
   854 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   855   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   856 
   857 
   858 subsubsection {* Cardinality *}
   859 
   860 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   861   apply (case_tac "0 \<le> u")
   862   apply (subst image_atLeastZeroLessThan_int, assumption)
   863   apply (subst card_image)
   864   apply (auto simp add: inj_on_def)
   865   done
   866 
   867 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   868   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   869   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   870   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   871   apply (erule subst)
   872   apply (rule card_image)
   873   apply (simp add: inj_on_def)
   874   apply (rule image_add_int_atLeastLessThan)
   875   done
   876 
   877 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   878 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   879 apply (auto simp add: algebra_simps)
   880 done
   881 
   882 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   883 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   884 
   885 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   886 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   887 
   888 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   889 proof -
   890   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   891   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   892 qed
   893 
   894 lemma card_less:
   895 assumes zero_in_M: "0 \<in> M"
   896 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   897 proof -
   898   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   899   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   900 qed
   901 
   902 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   903 apply (rule card_bij_eq [of Suc _ _ "\<lambda>x. x - Suc 0"])
   904 apply simp
   905 apply fastforce
   906 apply auto
   907 apply (rule inj_on_diff_nat)
   908 apply auto
   909 apply (case_tac x)
   910 apply auto
   911 apply (case_tac xa)
   912 apply auto
   913 apply (case_tac xa)
   914 apply auto
   915 done
   916 
   917 lemma card_less_Suc:
   918   assumes zero_in_M: "0 \<in> M"
   919     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   920 proof -
   921   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   922   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   923     by (auto simp only: insert_Diff)
   924   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   925   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   926     apply (subst card_insert)
   927     apply simp_all
   928     apply (subst b)
   929     apply (subst card_less_Suc2[symmetric])
   930     apply simp_all
   931     done
   932   with c show ?thesis by simp
   933 qed
   934 
   935 
   936 subsection {*Lemmas useful with the summation operator setsum*}
   937 
   938 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   939 
   940 subsubsection {* Disjoint Unions *}
   941 
   942 text {* Singletons and open intervals *}
   943 
   944 lemma ivl_disj_un_singleton:
   945   "{l::'a::linorder} Un {l<..} = {l..}"
   946   "{..<u} Un {u::'a::linorder} = {..u}"
   947   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   948   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   949   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   950   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   951 by auto
   952 
   953 text {* One- and two-sided intervals *}
   954 
   955 lemma ivl_disj_un_one:
   956   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   957   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   958   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   959   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   960   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   961   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   962   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   963   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   964 by auto
   965 
   966 text {* Two- and two-sided intervals *}
   967 
   968 lemma ivl_disj_un_two:
   969   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   970   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   971   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   972   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   973   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   974   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   975   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   976   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   977 by auto
   978 
   979 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   980 
   981 subsubsection {* Disjoint Intersections *}
   982 
   983 text {* One- and two-sided intervals *}
   984 
   985 lemma ivl_disj_int_one:
   986   "{..l::'a::order} Int {l<..<u} = {}"
   987   "{..<l} Int {l..<u} = {}"
   988   "{..l} Int {l<..u} = {}"
   989   "{..<l} Int {l..u} = {}"
   990   "{l<..u} Int {u<..} = {}"
   991   "{l<..<u} Int {u..} = {}"
   992   "{l..u} Int {u<..} = {}"
   993   "{l..<u} Int {u..} = {}"
   994   by auto
   995 
   996 text {* Two- and two-sided intervals *}
   997 
   998 lemma ivl_disj_int_two:
   999   "{l::'a::order<..<m} Int {m..<u} = {}"
  1000   "{l<..m} Int {m<..<u} = {}"
  1001   "{l..<m} Int {m..<u} = {}"
  1002   "{l..m} Int {m<..<u} = {}"
  1003   "{l<..<m} Int {m..u} = {}"
  1004   "{l<..m} Int {m<..u} = {}"
  1005   "{l..<m} Int {m..u} = {}"
  1006   "{l..m} Int {m<..u} = {}"
  1007   by auto
  1008 
  1009 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
  1010 
  1011 subsubsection {* Some Differences *}
  1012 
  1013 lemma ivl_diff[simp]:
  1014  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
  1015 by(auto)
  1016 
  1017 
  1018 subsubsection {* Some Subset Conditions *}
  1019 
  1020 lemma ivl_subset [simp,no_atp]:
  1021  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
  1022 apply(auto simp:linorder_not_le)
  1023 apply(rule ccontr)
  1024 apply(insert linorder_le_less_linear[of i n])
  1025 apply(clarsimp simp:linorder_not_le)
  1026 apply(fastforce)
  1027 done
  1028 
  1029 
  1030 subsection {* Summation indexed over intervals *}
  1031 
  1032 syntax
  1033   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
  1034   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
  1035   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
  1036   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
  1037 syntax (xsymbols)
  1038   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1039   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1040   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1041   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1042 syntax (HTML output)
  1043   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1044   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1045   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1046   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1047 syntax (latex_sum output)
  1048   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1049  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1050   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1051  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1052   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1053  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1054   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1055  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1056 
  1057 translations
  1058   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
  1059   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
  1060   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
  1061   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
  1062 
  1063 text{* The above introduces some pretty alternative syntaxes for
  1064 summation over intervals:
  1065 \begin{center}
  1066 \begin{tabular}{lll}
  1067 Old & New & \LaTeX\\
  1068 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
  1069 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
  1070 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
  1071 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
  1072 \end{tabular}
  1073 \end{center}
  1074 The left column shows the term before introduction of the new syntax,
  1075 the middle column shows the new (default) syntax, and the right column
  1076 shows a special syntax. The latter is only meaningful for latex output
  1077 and has to be activated explicitly by setting the print mode to
  1078 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
  1079 antiquotations). It is not the default \LaTeX\ output because it only
  1080 works well with italic-style formulae, not tt-style.
  1081 
  1082 Note that for uniformity on @{typ nat} it is better to use
  1083 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
  1084 not provide all lemmas available for @{term"{m..<n}"} also in the
  1085 special form for @{term"{..<n}"}. *}
  1086 
  1087 text{* This congruence rule should be used for sums over intervals as
  1088 the standard theorem @{text[source]setsum_cong} does not work well
  1089 with the simplifier who adds the unsimplified premise @{term"x:B"} to
  1090 the context. *}
  1091 
  1092 lemma setsum_ivl_cong:
  1093  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
  1094  setsum f {a..<b} = setsum g {c..<d}"
  1095 by(rule setsum_cong, simp_all)
  1096 
  1097 (* FIXME why are the following simp rules but the corresponding eqns
  1098 on intervals are not? *)
  1099 
  1100 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
  1101 by (simp add:atMost_Suc add_ac)
  1102 
  1103 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
  1104 by (simp add:lessThan_Suc add_ac)
  1105 
  1106 lemma setsum_cl_ivl_Suc[simp]:
  1107   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
  1108 by (auto simp:add_ac atLeastAtMostSuc_conv)
  1109 
  1110 lemma setsum_op_ivl_Suc[simp]:
  1111   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
  1112 by (auto simp:add_ac atLeastLessThanSuc)
  1113 (*
  1114 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
  1115     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
  1116 by (auto simp:add_ac atLeastAtMostSuc_conv)
  1117 *)
  1118 
  1119 lemma setsum_head:
  1120   fixes n :: nat
  1121   assumes mn: "m <= n" 
  1122   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
  1123 proof -
  1124   from mn
  1125   have "{m..n} = {m} \<union> {m<..n}"
  1126     by (auto intro: ivl_disj_un_singleton)
  1127   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
  1128     by (simp add: atLeast0LessThan)
  1129   also have "\<dots> = ?rhs" by simp
  1130   finally show ?thesis .
  1131 qed
  1132 
  1133 lemma setsum_head_Suc:
  1134   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
  1135 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
  1136 
  1137 lemma setsum_head_upt_Suc:
  1138   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
  1139 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
  1140 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
  1141 done
  1142 
  1143 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
  1144   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
  1145 proof-
  1146   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
  1147   thus ?thesis by (auto simp: ivl_disj_int setsum_Un_disjoint
  1148     atLeastSucAtMost_greaterThanAtMost)
  1149 qed
  1150 
  1151 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1152   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
  1153 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
  1154 
  1155 lemma setsum_diff_nat_ivl:
  1156 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1157 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1158   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
  1159 using setsum_add_nat_ivl [of m n p f,symmetric]
  1160 apply (simp add: add_ac)
  1161 done
  1162 
  1163 lemma setsum_natinterval_difff:
  1164   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  1165   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
  1166           (if m <= n then f m - f(n + 1) else 0)"
  1167 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
  1168 
  1169 lemma setsum_restrict_set':
  1170   "finite A \<Longrightarrow> setsum f {x \<in> A. x \<in> B} = (\<Sum>x\<in>A. if x \<in> B then f x else 0)"
  1171   by (simp add: setsum_restrict_set [symmetric] Int_def)
  1172 
  1173 lemma setsum_restrict_set'':
  1174   "finite A \<Longrightarrow> setsum f {x \<in> A. P x} = (\<Sum>x\<in>A. if P x  then f x else 0)"
  1175   by (simp add: setsum_restrict_set' [of A f "{x. P x}", simplified mem_Collect_eq])
  1176 
  1177 lemma setsum_setsum_restrict:
  1178   "finite S \<Longrightarrow> finite T \<Longrightarrow>
  1179     setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y \<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
  1180   by (simp add: setsum_restrict_set'') (rule setsum_commute)
  1181 
  1182 lemma setsum_image_gen: assumes fS: "finite S"
  1183   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1184 proof-
  1185   { fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto }
  1186   hence "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
  1187     by simp
  1188   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1189     by (rule setsum_setsum_restrict[OF fS finite_imageI[OF fS]])
  1190   finally show ?thesis .
  1191 qed
  1192 
  1193 lemma setsum_le_included:
  1194   fixes f :: "'a \<Rightarrow> 'b::ordered_comm_monoid_add"
  1195   assumes "finite s" "finite t"
  1196   and "\<forall>y\<in>t. 0 \<le> g y" "(\<forall>x\<in>s. \<exists>y\<in>t. i y = x \<and> f x \<le> g y)"
  1197   shows "setsum f s \<le> setsum g t"
  1198 proof -
  1199   have "setsum f s \<le> setsum (\<lambda>y. setsum g {x. x\<in>t \<and> i x = y}) s"
  1200   proof (rule setsum_mono)
  1201     fix y assume "y \<in> s"
  1202     with assms obtain z where z: "z \<in> t" "y = i z" "f y \<le> g z" by auto
  1203     with assms show "f y \<le> setsum g {x \<in> t. i x = y}" (is "?A y \<le> ?B y")
  1204       using order_trans[of "?A (i z)" "setsum g {z}" "?B (i z)", intro]
  1205       by (auto intro!: setsum_mono2)
  1206   qed
  1207   also have "... \<le> setsum (\<lambda>y. setsum g {x. x\<in>t \<and> i x = y}) (i ` t)"
  1208     using assms(2-4) by (auto intro!: setsum_mono2 setsum_nonneg)
  1209   also have "... \<le> setsum g t"
  1210     using assms by (auto simp: setsum_image_gen[symmetric])
  1211   finally show ?thesis .
  1212 qed
  1213 
  1214 lemma setsum_multicount_gen:
  1215   assumes "finite s" "finite t" "\<forall>j\<in>t. (card {i\<in>s. R i j} = k j)"
  1216   shows "setsum (\<lambda>i. (card {j\<in>t. R i j})) s = setsum k t" (is "?l = ?r")
  1217 proof-
  1218   have "?l = setsum (\<lambda>i. setsum (\<lambda>x.1) {j\<in>t. R i j}) s" by auto
  1219   also have "\<dots> = ?r" unfolding setsum_setsum_restrict[OF assms(1-2)]
  1220     using assms(3) by auto
  1221   finally show ?thesis .
  1222 qed
  1223 
  1224 lemma setsum_multicount:
  1225   assumes "finite S" "finite T" "\<forall>j\<in>T. (card {i\<in>S. R i j} = k)"
  1226   shows "setsum (\<lambda>i. card {j\<in>T. R i j}) S = k * card T" (is "?l = ?r")
  1227 proof-
  1228   have "?l = setsum (\<lambda>i. k) T" by(rule setsum_multicount_gen)(auto simp:assms)
  1229   also have "\<dots> = ?r" by(simp add: mult_commute)
  1230   finally show ?thesis by auto
  1231 qed
  1232 
  1233 
  1234 subsection{* Shifting bounds *}
  1235 
  1236 lemma setsum_shift_bounds_nat_ivl:
  1237   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
  1238 by (induct "n", auto simp:atLeastLessThanSuc)
  1239 
  1240 lemma setsum_shift_bounds_cl_nat_ivl:
  1241   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1242 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
  1243 apply (simp add:image_add_atLeastAtMost o_def)
  1244 done
  1245 
  1246 corollary setsum_shift_bounds_cl_Suc_ivl:
  1247   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1248 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1249 
  1250 corollary setsum_shift_bounds_Suc_ivl:
  1251   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1252 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1253 
  1254 lemma setsum_shift_lb_Suc0_0:
  1255   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1256 by(simp add:setsum_head_Suc)
  1257 
  1258 lemma setsum_shift_lb_Suc0_0_upt:
  1259   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1260 apply(cases k)apply simp
  1261 apply(simp add:setsum_head_upt_Suc)
  1262 done
  1263 
  1264 subsection {* The formula for geometric sums *}
  1265 
  1266 lemma geometric_sum:
  1267   assumes "x \<noteq> 1"
  1268   shows "(\<Sum>i=0..<n. x ^ i) = (x ^ n - 1) / (x - 1::'a::field)"
  1269 proof -
  1270   from assms obtain y where "y = x - 1" and "y \<noteq> 0" by simp_all
  1271   moreover have "(\<Sum>i=0..<n. (y + 1) ^ i) = ((y + 1) ^ n - 1) / y"
  1272   proof (induct n)
  1273     case 0 then show ?case by simp
  1274   next
  1275     case (Suc n)
  1276     moreover with `y \<noteq> 0` have "(1 + y) ^ n = (y * inverse y) * (1 + y) ^ n" by simp 
  1277     ultimately show ?case by (simp add: field_simps divide_inverse)
  1278   qed
  1279   ultimately show ?thesis by simp
  1280 qed
  1281 
  1282 
  1283 subsection {* The formula for arithmetic sums *}
  1284 
  1285 lemma gauss_sum:
  1286   "(2::'a::comm_semiring_1)*(\<Sum>i\<in>{1..n}. of_nat i) =
  1287    of_nat n*((of_nat n)+1)"
  1288 proof (induct n)
  1289   case 0
  1290   show ?case by simp
  1291 next
  1292   case (Suc n)
  1293   then show ?case
  1294     by (simp add: algebra_simps add: one_add_one [symmetric] del: one_add_one)
  1295       (* FIXME: make numeral cancellation simprocs work for semirings *)
  1296 qed
  1297 
  1298 theorem arith_series_general:
  1299   "(2::'a::comm_semiring_1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1300   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1301 proof cases
  1302   assume ngt1: "n > 1"
  1303   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1304   have
  1305     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1306      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1307     by (rule setsum_addf)
  1308   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1309   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1310     unfolding One_nat_def
  1311     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
  1312   also have "2*\<dots> = 2*?n*a + d*2*(\<Sum>i\<in>{1..<n}. ?I i)"
  1313     by (simp add: algebra_simps)
  1314   also from ngt1 have "{1..<n} = {1..n - 1}"
  1315     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1316   also from ngt1
  1317   have "2*?n*a + d*2*(\<Sum>i\<in>{1..n - 1}. ?I i) = (2*?n*a + d*?I (n - 1)*?I n)"
  1318     by (simp only: mult_ac gauss_sum [of "n - 1"], unfold One_nat_def)
  1319        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
  1320   finally show ?thesis
  1321     unfolding mult_2 by (simp add: algebra_simps)
  1322 next
  1323   assume "\<not>(n > 1)"
  1324   hence "n = 1 \<or> n = 0" by auto
  1325   thus ?thesis by (auto simp: mult_2)
  1326 qed
  1327 
  1328 lemma arith_series_nat:
  1329   "(2::nat) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1330 proof -
  1331   have
  1332     "2 * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1333     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1334     by (rule arith_series_general)
  1335   thus ?thesis
  1336     unfolding One_nat_def by auto
  1337 qed
  1338 
  1339 lemma arith_series_int:
  1340   "2 * (\<Sum>i\<in>{..<n}. a + int i * d) = int n * (a + (a + int(n - 1)*d))"
  1341   by (fact arith_series_general) (* FIXME: duplicate *)
  1342 
  1343 lemma sum_diff_distrib:
  1344   fixes P::"nat\<Rightarrow>nat"
  1345   shows
  1346   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1347   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1348 proof (induct n)
  1349   case 0 show ?case by simp
  1350 next
  1351   case (Suc n)
  1352 
  1353   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1354   let ?rhs = "\<Sum>x<n. P x - Q x"
  1355 
  1356   from Suc have "?lhs = ?rhs" by simp
  1357   moreover
  1358   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1359   moreover
  1360   from Suc have
  1361     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1362     by (subst diff_diff_left[symmetric],
  1363         subst diff_add_assoc2)
  1364        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1365   ultimately
  1366   show ?case by simp
  1367 qed
  1368 
  1369 subsection {* Products indexed over intervals *}
  1370 
  1371 syntax
  1372   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1373   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1374   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1375   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1376 syntax (xsymbols)
  1377   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1378   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1379   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1380   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1381 syntax (HTML output)
  1382   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1383   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1384   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1385   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1386 syntax (latex_prod output)
  1387   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1388  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1389   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1390  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1391   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1392  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1393   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1394  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1395 
  1396 translations
  1397   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1398   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1399   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1400   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1401 
  1402 subsection {* Transfer setup *}
  1403 
  1404 lemma transfer_nat_int_set_functions:
  1405     "{..n} = nat ` {0..int n}"
  1406     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1407   apply (auto simp add: image_def)
  1408   apply (rule_tac x = "int x" in bexI)
  1409   apply auto
  1410   apply (rule_tac x = "int x" in bexI)
  1411   apply auto
  1412   done
  1413 
  1414 lemma transfer_nat_int_set_function_closures:
  1415     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1416   by (simp add: nat_set_def)
  1417 
  1418 declare transfer_morphism_nat_int[transfer add
  1419   return: transfer_nat_int_set_functions
  1420     transfer_nat_int_set_function_closures
  1421 ]
  1422 
  1423 lemma transfer_int_nat_set_functions:
  1424     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1425   by (simp only: is_nat_def transfer_nat_int_set_functions
  1426     transfer_nat_int_set_function_closures
  1427     transfer_nat_int_set_return_embed nat_0_le
  1428     cong: transfer_nat_int_set_cong)
  1429 
  1430 lemma transfer_int_nat_set_function_closures:
  1431     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1432   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1433 
  1434 declare transfer_morphism_int_nat[transfer add
  1435   return: transfer_int_nat_set_functions
  1436     transfer_int_nat_set_function_closures
  1437 ]
  1438 
  1439 end