src/Pure/library.ML
author wenzelm
Tue Jul 11 14:21:07 2006 +0200 (2006-07-11)
changeset 20095 432e914a0e95
parent 20006 0f507e799938
child 20108 289050bdfff5
permissions -rw-r--r--
replaced read_radixint by read_intinf;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 *)
     9 
    10 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    11 infix 2 ?;
    12 infix 3 o oo ooo oooo;
    13 
    14 infix 4 ~~ upto downto;
    15 infix orf andf \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    16   union_string inter inter_int inter_string subset subset_int subset_string;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    34   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    35   val tap: ('b -> 'a) -> 'b -> 'b
    36   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    37   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    38   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    39   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    40 
    41   (*options*)
    42   val the: 'a option -> 'a
    43   val these: 'a list option -> 'a list
    44   val the_default: 'a -> 'a option -> 'a
    45   val the_list: 'a option -> 'a list
    46   val is_some: 'a option -> bool
    47   val is_none: 'a option -> bool
    48   val perhaps: ('a -> 'a option) -> 'a -> 'a
    49   val merge_opt: ('a * 'a -> bool) -> 'a option * 'a option -> 'a option
    50 
    51   (*exceptions*)
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   exception EXCEPTION of exn * string
    55   val do_transform_failure: bool ref
    56   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    57   datatype 'a result = Result of 'a | Exn of exn
    58   val capture: ('a -> 'b) -> 'a -> 'b result
    59   val release: 'a result -> 'a
    60   val get_result: 'a result -> 'a option
    61   val get_exn: 'a result -> exn option
    62 
    63   (*errors*)
    64   exception SYS_ERROR of string
    65   val sys_error: string -> 'a
    66   exception ERROR of string
    67   val error: string -> 'a
    68   val cat_error: string -> string -> 'a
    69   val assert: bool -> string -> unit
    70   val deny: bool -> string -> unit
    71   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    72 
    73   (*pairs*)
    74   val pair: 'a -> 'b -> 'a * 'b
    75   val rpair: 'a -> 'b -> 'b * 'a
    76   val fst: 'a * 'b -> 'a
    77   val snd: 'a * 'b -> 'b
    78   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    79   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    80   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    81   val swap: 'a * 'b -> 'b * 'a
    82   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    83   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    84   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    85   val string_of_pair: ('a -> string) -> ('b -> string) -> 'a * 'b -> string
    86 
    87   (*booleans*)
    88   val equal: ''a -> ''a -> bool
    89   val not_equal: ''a -> ''a -> bool
    90   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    91   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    92   val exists: ('a -> bool) -> 'a list -> bool
    93   val forall: ('a -> bool) -> 'a list -> bool
    94   val set: bool ref -> bool
    95   val reset: bool ref -> bool
    96   val toggle: bool ref -> bool
    97   val change: 'a ref -> ('a -> 'a) -> unit
    98   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    99   val conditional: bool -> (unit -> unit) -> unit
   100 
   101   (*lists*)
   102   exception UnequalLengths
   103   val cons: 'a -> 'a list -> 'a list
   104   val single: 'a -> 'a list
   105   val singleton: ('a list -> 'b list) -> 'a -> 'b
   106   val append: 'a list -> 'a list -> 'a list
   107   val apply: ('a -> 'a) list -> 'a -> 'a
   108   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   109   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   110   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   111   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   112   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   113   val flat: 'a list list -> 'a list
   114   val maps: ('a -> 'b list) -> 'a list -> 'b list
   115   val unflat: 'a list list -> 'b list -> 'b list list
   116   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
   117   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
   118   val chop: int -> 'a list -> 'a list * 'a list
   119   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   120   val nth: 'a list -> int -> 'a
   121   val nth_update: int * 'a -> 'a list -> 'a list
   122   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   123   val nth_list: 'a list list -> int -> 'a list
   124   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
   125   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   126   val split_last: 'a list -> 'a list * 'a
   127   val find_index: ('a -> bool) -> 'a list -> int
   128   val find_index_eq: ''a -> ''a list -> int
   129   val find_first: ('a -> bool) -> 'a list -> 'a option
   130   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   131   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   132   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   133   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   134   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   135   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   136   val ~~ : 'a list * 'b list -> ('a * 'b) list
   137   val split_list: ('a * 'b) list -> 'a list * 'b list
   138   val separate: 'a -> 'a list -> 'a list
   139   val replicate: int -> 'a -> 'a list
   140   val multiply: 'a list -> 'a list list -> 'a list list
   141   val product: 'a list -> 'b list -> ('a * 'b) list
   142   val filter: ('a -> bool) -> 'a list -> 'a list
   143   val filter_out: ('a -> bool) -> 'a list -> 'a list
   144   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   145   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   146   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   147   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   148   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   149   val prefixes1: 'a list -> 'a list list
   150   val prefixes: 'a list -> 'a list list
   151   val suffixes1: 'a list -> 'a list list
   152   val suffixes: 'a list -> 'a list list
   153 
   154   (*integers*)
   155   val gcd: IntInf.int * IntInf.int -> IntInf.int
   156   val lcm: IntInf.int * IntInf.int -> IntInf.int
   157   val inc: int ref -> int
   158   val dec: int ref -> int
   159   val upto: int * int -> int list
   160   val downto: int * int -> int list
   161   val downto0: int list * int -> bool
   162   val radixpand: int * int -> int list
   163   val radixstring: int * string * int -> string
   164   val string_of_int: int -> string
   165   val string_of_indexname: string * int -> string
   166   val read_intinf: int -> string list -> IntInf.int * string list
   167   val read_int: string list -> int * string list
   168   val oct_char: string -> string
   169 
   170   (*strings*)
   171   val nth_string: string -> int -> string
   172   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   173   val exists_string: (string -> bool) -> string -> bool
   174   val forall_string: (string -> bool) -> string -> bool
   175   val enclose: string -> string -> string -> string
   176   val unenclose: string -> string
   177   val quote: string -> string
   178   val space_implode: string -> string list -> string
   179   val commas: string list -> string
   180   val commas_quote: string list -> string
   181   val cat_lines: string list -> string
   182   val space_explode: string -> string -> string list
   183   val split_lines: string -> string list
   184   val prefix_lines: string -> string -> string
   185   val untabify: string list -> string list
   186   val prefix: string -> string -> string
   187   val suffix: string -> string -> string
   188   val unprefix: string -> string -> string
   189   val unsuffix: string -> string -> string
   190   val replicate_string: int -> string -> string
   191   val translate_string: (string -> string) -> string -> string
   192   val string_of_list: ('a -> string) -> 'a list -> string
   193   val string_of_option: ('a -> string) -> 'a option -> string
   194 
   195   (*lists as sets -- see also Pure/General/ord_list.ML*)
   196   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   197   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   198   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   199   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   200   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   201   val mem: ''a * ''a list -> bool
   202   val mem_int: int * int list -> bool
   203   val mem_string: string * string list -> bool
   204   val ins: ''a * ''a list -> ''a list
   205   val ins_int: int * int list -> int list
   206   val ins_string: string * string list -> string list
   207   val union: ''a list * ''a list -> ''a list
   208   val union_int: int list * int list -> int list
   209   val union_string: string list * string list -> string list
   210   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   211   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   212   val inter: ''a list * ''a list -> ''a list
   213   val inter_int: int list * int list -> int list
   214   val inter_string: string list * string list -> string list
   215   val subset: ''a list * ''a list -> bool
   216   val subset_int: int list * int list -> bool
   217   val subset_string: string list * string list -> bool
   218   val eq_set: ''a list * ''a list -> bool
   219   val eq_set_string: string list * string list -> bool
   220   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   221   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   222   val \ : ''a list * ''a -> ''a list
   223   val \\ : ''a list * ''a list -> ''a list
   224   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   225   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   226   val findrep: ''a list -> ''a list
   227   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   228   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   229   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   230 
   231   (*lists as tables -- see also Pure/General/alist.ML*)
   232   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   233   val merge_lists: ''a list -> ''a list -> ''a list
   234   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   235 
   236   (*balanced trees*)
   237   exception Balance
   238   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   239   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   240   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   241 
   242   (*orders*)
   243   val is_equal: order -> bool
   244   val rev_order: order -> order
   245   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   246   val int_ord: int * int -> order
   247   val string_ord: string * string -> order
   248   val fast_string_ord: string * string -> order
   249   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   250   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   251   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   252   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   253   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   254   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   255   val sort_strings: string list -> string list
   256   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   257 
   258   (*random numbers*)
   259   exception RANDOM
   260   val random: unit -> real
   261   val random_range: int -> int -> int
   262   val one_of: 'a list -> 'a
   263   val frequency: (int * 'a) list -> 'a
   264 
   265   (*current directory*)
   266   val cd: string -> unit
   267   val pwd: unit -> string
   268 
   269   (*misc*)
   270   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   271   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   272   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   273   val gensym: string -> string
   274   val scanwords: (string -> bool) -> string list -> string list
   275   type stamp
   276   val stamp: unit -> stamp
   277   type serial
   278   val serial: unit -> serial
   279   val serial_string: unit -> string
   280   structure Object: sig type T end
   281 end;
   282 
   283 signature LIBRARY =
   284 sig
   285   include BASIC_LIBRARY
   286   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   287   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   288   val take: int * 'a list -> 'a list
   289   val drop: int * 'a list -> 'a list
   290   val last_elem: 'a list -> 'a
   291   val seq: ('a -> unit) -> 'a list -> unit
   292 end;
   293 
   294 structure Library: LIBRARY =
   295 struct
   296 
   297 
   298 (** functions **)
   299 
   300 fun I x = x;
   301 fun K x = fn _ => x;
   302 fun curry f x y = f (x, y);
   303 fun uncurry f (x, y) = f x y;
   304 
   305 (*reverse application and structured results*)
   306 fun x |> f = f x;
   307 fun (x, y) |-> f = f x y;
   308 fun (x, y) |>> f = (f x, y);
   309 fun (x, y) ||> f = (x, f y);
   310 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   311 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   312 
   313 (*reverse composition*)
   314 fun f #> g = g o f;
   315 fun f #-> g = uncurry g o f;
   316 
   317 (*conditional application*)
   318 fun b ? f = fn x => if b x then f x else x;
   319 
   320 (*view results*)
   321 fun `f = fn x => (f x, x);
   322 fun tap f = fn x => (f x; x);
   323 
   324 (*composition with multiple args*)
   325 fun (f oo g) x y = f (g x y);
   326 fun (f ooo g) x y z = f (g x y z);
   327 fun (f oooo g) x y z w = f (g x y z w);
   328 
   329 (*function exponentiation: f(...(f x)...) with n applications of f*)
   330 fun funpow n f x =
   331   let fun rep (0, x) = x
   332         | rep (n, x) = rep (n - 1, f x)
   333   in rep (n, x) end;
   334 
   335 
   336 (** options **)
   337 
   338 val the = Option.valOf;
   339 
   340 fun these (SOME x) = x
   341   | these _ = [];
   342 
   343 fun the_default x (SOME y) = y
   344   | the_default x _ = x;
   345 
   346 fun the_list (SOME x) = [x]
   347   | the_list _ = []
   348 
   349 fun is_some (SOME _) = true
   350   | is_some NONE = false;
   351 
   352 fun is_none (SOME _) = false
   353   | is_none NONE = true;
   354 
   355 fun perhaps f x = the_default x (f x);
   356 
   357 fun merge_opt _ (NONE, y) = y
   358   | merge_opt _ (x, NONE) = x
   359   | merge_opt eq (SOME x, SOME y) = if eq (x, y) then SOME y else raise Option;
   360 
   361 
   362 (* exceptions *)
   363 
   364 val do_transform_failure = ref true;
   365 
   366 fun transform_failure exn f x =
   367   if ! do_transform_failure then
   368     f x handle Interrupt => raise Interrupt | e => raise exn e
   369   else f x;
   370 
   371 exception EXCEPTION of exn * string;
   372 
   373 
   374 fun try f x = SOME (f x)
   375   handle Interrupt => raise Interrupt | _ => NONE;
   376 
   377 fun can f x = is_some (try f x);
   378 
   379 
   380 datatype 'a result =
   381   Result of 'a |
   382   Exn of exn;
   383 
   384 fun capture f x = Result (f x) handle e => Exn e;
   385 
   386 fun release (Result y) = y
   387   | release (Exn e) = raise e;
   388 
   389 fun get_result (Result x) = SOME x
   390   | get_result _ = NONE;
   391 
   392 fun get_exn (Exn exn) = SOME exn
   393   | get_exn _ = NONE;
   394 
   395 
   396 (* errors *)
   397 
   398 exception SYS_ERROR of string;
   399 fun sys_error msg = raise SYS_ERROR msg;
   400 
   401 exception ERROR of string;
   402 fun error msg = raise ERROR msg;
   403 
   404 fun cat_error "" msg = error msg
   405   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   406 
   407 fun assert p msg = if p then () else error msg;
   408 fun deny p msg = if p then error msg else ();
   409 
   410 fun assert_all pred list msg =
   411   let
   412     fun ass [] = ()
   413       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   414   in ass list end;
   415 
   416 
   417 (** pairs **)
   418 
   419 fun pair x y = (x, y);
   420 fun rpair x y = (y, x);
   421 
   422 fun fst (x, y) = x;
   423 fun snd (x, y) = y;
   424 
   425 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   426 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   427 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   428 
   429 fun swap (x, y) = (y, x);
   430 
   431 (*apply function to components*)
   432 fun apfst f (x, y) = (f x, y);
   433 fun apsnd f (x, y) = (x, f y);
   434 fun pairself f (x, y) = (f x, f y);
   435 
   436 fun string_of_pair f1 f2 (x, y) = "(" ^ f1 x ^ ", " ^ f2 y ^ ")";
   437 
   438 
   439 (** booleans **)
   440 
   441 (* equality *)
   442 
   443 fun equal x y = x = y;
   444 fun not_equal x y = x <> y;
   445 
   446 (* operators for combining predicates *)
   447 
   448 fun p orf q = fn x => p x orelse q x;
   449 fun p andf q = fn x => p x andalso q x;
   450 
   451 (* predicates on lists *)
   452 
   453 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   454 fun exists (pred: 'a -> bool) : 'a list -> bool =
   455   let fun boolf [] = false
   456         | boolf (x :: xs) = pred x orelse boolf xs
   457   in boolf end;
   458 
   459 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   460 fun forall (pred: 'a -> bool) : 'a list -> bool =
   461   let fun boolf [] = true
   462         | boolf (x :: xs) = pred x andalso boolf xs
   463   in boolf end;
   464 
   465 
   466 (* flags *)
   467 
   468 fun set flag = (flag := true; true);
   469 fun reset flag = (flag := false; false);
   470 fun toggle flag = (flag := not (! flag); ! flag);
   471 
   472 fun change r f = r := f (! r);
   473 
   474 (*temporarily set flag during execution*)
   475 fun setmp flag value f x =
   476   let
   477     val orig_value = ! flag;
   478     val _ = flag := value;
   479     val result = capture f x;
   480     val _ = flag := orig_value;
   481   in release result end;
   482 
   483 
   484 (* conditional execution *)
   485 
   486 fun conditional b f = if b then f () else ();
   487 
   488 
   489 (** lists **)
   490 
   491 exception UnequalLengths;
   492 
   493 fun cons x xs = x :: xs;
   494 fun single x = [x];
   495 
   496 fun singleton f x = (case f [x] of [y] => y | _ => raise Empty);
   497 
   498 fun append xs ys = xs @ ys;
   499 
   500 fun apply [] x = x
   501   | apply (f :: fs) x = apply fs (f x);
   502 
   503 
   504 (* fold *)
   505 
   506 fun fold f =
   507   let
   508     fun fold_aux [] y = y
   509       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   510   in fold_aux end;
   511 
   512 fun fold_rev f =
   513   let
   514     fun fold_aux [] y = y
   515       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   516   in fold_aux end;
   517 
   518 fun fold_map f =
   519   let
   520     fun fold_aux [] y = ([], y)
   521       | fold_aux (x :: xs) y =
   522           let
   523             val (x', y') = f x y;
   524             val (xs', y'') = fold_aux xs y';
   525           in (x' :: xs', y'') end;
   526   in fold_aux end;
   527 
   528 (*the following versions of fold are designed to fit nicely with infixes*)
   529 
   530 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   531     for operators that associate to the left (TAIL RECURSIVE)*)
   532 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   533   let fun itl (e, [])  = e
   534         | itl (e, a::l) = itl (f(e, a), l)
   535   in  itl end;
   536 
   537 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   538     for operators that associate to the right (not tail recursive)*)
   539 fun foldr f (l, e) =
   540   let fun itr [] = e
   541         | itr (a::l) = f(a, itr l)
   542   in  itr l  end;
   543 
   544 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   545     for n > 0, operators that associate to the right (not tail recursive)*)
   546 fun foldr1 f l =
   547   let fun itr [x] = x
   548         | itr (x::l) = f(x, itr l)
   549   in  itr l  end;
   550 
   551 fun fold_index f =
   552   let
   553     fun fold_aux _ [] y = y
   554       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   555   in fold_aux 0 end;
   556 
   557 fun foldl_map f =
   558   let
   559     fun fold_aux (x, []) = (x, [])
   560       | fold_aux (x, y :: ys) =
   561           let
   562             val (x', y') = f (x, y);
   563             val (x'', ys') = fold_aux (x', ys);
   564           in (x'', y' :: ys') end;
   565   in fold_aux end;
   566 
   567 
   568 (* basic list functions *)
   569 
   570 fun maps f [] = []
   571   | maps f (x :: xs) = f x @ maps f xs;
   572 
   573 fun chop 0 xs = ([], xs)
   574   | chop _ [] = ([], [])
   575   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   576 
   577 (*take the first n elements from a list*)
   578 fun take (n, []) = []
   579   | take (n, x :: xs) =
   580       if n > 0 then x :: take (n - 1, xs) else [];
   581 
   582 (*drop the first n elements from a list*)
   583 fun drop (n, []) = []
   584   | drop (n, x :: xs) =
   585       if n > 0 then drop (n - 1, xs) else x :: xs;
   586 
   587 fun dropwhile P [] = []
   588   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   589 
   590 (*return nth element of a list, where 0 designates the first element;
   591   raise Subscript if list too short*)
   592 fun nth xs i = List.nth (xs, i);
   593 
   594 fun nth_list xss i = nth xss i handle Subscript => [];
   595 
   596 (*update nth element*)
   597 fun nth_update (n, x) xs =
   598   (case chop n xs of
   599     (_, []) => raise Subscript
   600   | (prfx, _ :: sffx') => prfx @ (x :: sffx'));
   601 
   602 fun nth_map 0 f (x :: xs) = f x :: xs
   603   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   604   | nth_map _ _ [] = raise Subscript;
   605 
   606 fun map_index f =
   607   let
   608     fun mapp _ [] = []
   609       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   610   in mapp 0 end;
   611 
   612 val last_elem = List.last;
   613 
   614 (*rear decomposition*)
   615 fun split_last [] = raise Empty
   616   | split_last [x] = ([], x)
   617   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   618 
   619 (*find the position of an element in a list*)
   620 fun find_index pred =
   621   let fun find _ [] = ~1
   622         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   623   in find 0 end;
   624 
   625 fun find_index_eq x = find_index (equal x);
   626 
   627 (*find first element satisfying predicate*)
   628 fun find_first _ [] = NONE
   629   | find_first pred (x :: xs) =
   630       if pred x then SOME x else find_first pred xs;
   631 
   632 (*get first element by lookup function*)
   633 fun get_first _ [] = NONE
   634   | get_first f (x :: xs) =
   635       (case f x of
   636         NONE => get_first f xs
   637       | some => some);
   638 
   639 fun get_index f =
   640   let
   641     fun get _ [] = NONE
   642       | get i (x :: xs) =
   643           case f x
   644            of NONE => get (i + 1) xs
   645             | SOME y => SOME (i, y)
   646   in get 0 end;
   647 
   648 fun eq_list _ ([], []) = true
   649   | eq_list eq (x :: xs, y :: ys) = eq (x, y) andalso eq_list eq (xs, ys)
   650   | eq_list _ _ = false;
   651 
   652 val flat = List.concat;
   653 
   654 fun unflat (xs :: xss) ys =
   655       let val (ps, qs) = chop (length xs) ys
   656       in ps :: unflat xss qs end
   657   | unflat [] [] = []
   658   | unflat _ _ = raise UnequalLengths;
   659 
   660 fun burrow f xss =
   661   unflat xss ((f o flat) xss);
   662 
   663 fun fold_burrow f xss s =
   664   apfst (unflat xss) (f (flat xss) s);
   665 
   666 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   667   (proc x1; ...; proc xn) for side effects*)
   668 val seq = List.app;
   669 
   670 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   671 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   672   | separate _ xs = xs;
   673 
   674 (*make the list [x, x, ..., x] of length n*)
   675 fun replicate n (x: 'a) : 'a list =
   676   let fun rep (0, xs) = xs
   677         | rep (n, xs) = rep (n - 1, x :: xs)
   678   in
   679     if n < 0 then raise Subscript
   680     else rep (n, [])
   681   end;
   682 
   683 fun translate_string f = String.translate (f o String.str);
   684 
   685 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   686 fun multiply [] _ = []
   687   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   688 
   689 (*direct product*)
   690 fun product _ [] = []
   691   | product [] _ = []
   692   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   693 
   694 
   695 (* filter *)
   696 
   697 (*copy the list preserving elements that satisfy the predicate*)
   698 val filter = List.filter;
   699 fun filter_out f = filter (not o f);
   700 val map_filter = List.mapPartial;
   701 
   702 
   703 (* lists of pairs *)
   704 
   705 exception UnequalLengths;
   706 
   707 fun map2 _ [] [] = []
   708   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   709   | map2 _ _ _ = raise UnequalLengths;
   710 
   711 fun fold2 f =
   712   let
   713     fun fold_aux [] [] z = z
   714       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   715       | fold_aux _ _ _ = raise UnequalLengths;
   716   in fold_aux end;
   717 
   718 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   719   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   720   | zip_options _ [] = []
   721   | zip_options [] _ = raise UnequalLengths;
   722 
   723 (*combine two lists forming a list of pairs:
   724   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   725 fun [] ~~ [] = []
   726   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   727   | _ ~~ _ = raise UnequalLengths;
   728 
   729 (*inverse of ~~; the old 'split':
   730   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   731 val split_list = ListPair.unzip;
   732 
   733 fun equal_lists eq (xs, ys) =
   734   let
   735     fun eq' [] [] = true
   736       | eq' (x :: xs) (y :: ys) = eq (x, y) andalso eq' xs ys
   737   in length xs = length ys andalso eq' xs ys end;
   738 
   739 
   740 (* prefixes, suffixes *)
   741 
   742 fun is_prefix _ [] _ = true
   743   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   744   | is_prefix eq _ _ = false;
   745 
   746 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   747    where xi is the first element that does not satisfy the predicate*)
   748 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   749   let fun take (rxs, []) = (rev rxs, [])
   750         | take (rxs, x :: xs) =
   751             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   752   in  take([], xs)  end;
   753 
   754 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   755    where xi is the last element that does not satisfy the predicate*)
   756 fun take_suffix _ [] = ([], [])
   757   | take_suffix pred (x :: xs) =
   758       (case take_suffix pred xs of
   759         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   760       | (prfx, sffx) => (x :: prfx, sffx));
   761 
   762 fun prefixes1 [] = []
   763   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   764 
   765 fun prefixes xs = [] :: prefixes1 xs;
   766 
   767 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   768 fun suffixes xs = [] :: suffixes1 xs;
   769 
   770 
   771 (** integers **)
   772 
   773 fun gcd (x, y) =
   774   let fun gxd x y : IntInf.int =
   775     if y = 0 then x else gxd y (x mod y)
   776   in if x < y then gxd y x else gxd x y end;
   777 
   778 fun lcm (x, y) = (x * y) div gcd (x, y);
   779 
   780 fun inc i = (i := ! i + 1; ! i);
   781 fun dec i = (i := ! i - 1; ! i);
   782 
   783 
   784 (* lists of integers *)
   785 
   786 (*make the list [from, from + 1, ..., to]*)
   787 fun (from upto to) =
   788   if from > to then [] else from :: ((from + 1) upto to);
   789 
   790 (*make the list [from, from - 1, ..., to]*)
   791 fun (from downto to) =
   792   if from < to then [] else from :: ((from - 1) downto to);
   793 
   794 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   795 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   796   | downto0 ([], n) = n = ~1;
   797 
   798 
   799 (* convert integers to strings *)
   800 
   801 (*expand the number in the given base;
   802   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   803 fun radixpand (base, num) : int list =
   804   let
   805     fun radix (n, tail) =
   806       if n < base then n :: tail
   807       else radix (n div base, (n mod base) :: tail)
   808   in radix (num, []) end;
   809 
   810 (*expands a number into a string of characters starting from "zerochar";
   811   example: radixstring (2, "0", 8) gives "1000"*)
   812 fun radixstring (base, zerochar, num) =
   813   let val offset = ord zerochar;
   814       fun chrof n = chr (offset + n)
   815   in implode (map chrof (radixpand (base, num))) end;
   816 
   817 
   818 val string_of_int = Int.toString;
   819 
   820 fun string_of_indexname (a,0) = a
   821   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   822 
   823 
   824 (* read integers *)
   825 
   826 fun read_intinf radix cs =
   827   let
   828     val zero = ord "0";
   829     val limit = zero + radix;
   830     fun scan (num, []) = (num, [])
   831       | scan (num, c :: cs) =
   832         if zero <= ord c andalso ord c < limit then
   833           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   834         else (num, c :: cs);
   835   in scan (0, cs) end;
   836 
   837 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   838 
   839 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   840 
   841 
   842 
   843 (** strings **)
   844 
   845 (* functions tuned for strings, avoiding explode *)
   846 
   847 fun nth_string str i =
   848   (case try String.substring (str, i, 1) of
   849     SOME s => s
   850   | NONE => raise Subscript);
   851 
   852 fun fold_string f str x0 =
   853   let
   854     val n = size str;
   855     fun iter (x, i) =
   856       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   857   in iter (x0, 0) end;
   858 
   859 fun exists_string pred str =
   860   let
   861     val n = size str;
   862     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   863   in ex 0 end;
   864 
   865 fun forall_string pred = not o exists_string (not o pred);
   866 
   867 (*enclose in brackets*)
   868 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   869 fun unenclose str = String.substring (str, 1, size str - 2);
   870 
   871 (*simple quoting (does not escape special chars)*)
   872 val quote = enclose "\"" "\"";
   873 
   874 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   875 fun space_implode a bs = implode (separate a bs);
   876 
   877 val commas = space_implode ", ";
   878 val commas_quote = commas o map quote;
   879 
   880 (*concatenate messages, one per line, into a string*)
   881 val cat_lines = space_implode "\n";
   882 
   883 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   884 fun space_explode _ "" = []
   885   | space_explode sep str =
   886       let
   887         fun expl chs =
   888           (case take_prefix (fn s => s <> sep) chs of
   889             (cs, []) => [implode cs]
   890           | (cs, _ :: cs') => implode cs :: expl cs');
   891       in expl (explode str) end;
   892 
   893 val split_lines = space_explode "\n";
   894 
   895 fun prefix_lines "" txt = txt
   896   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   897 
   898 fun untabify chs =
   899   let
   900     val tab_width = 8;
   901 
   902     fun untab (_, "\n") = (0, ["\n"])
   903       | untab (pos, "\t") =
   904           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   905       | untab (pos, c) = (pos + 1, [c]);
   906   in
   907     if not (exists (fn c => c = "\t") chs) then chs
   908     else flat (#2 (foldl_map untab (0, chs)))
   909   end;
   910 
   911 fun prefix prfx s = prfx ^ s;
   912 fun suffix sffx s = s ^ sffx;
   913 
   914 fun unprefix prfx s =
   915   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   916   else raise Fail "unprefix";
   917 
   918 fun unsuffix sffx s =
   919   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   920   else raise Fail "unsuffix";
   921 
   922 fun replicate_string 0 _ = ""
   923   | replicate_string 1 a = a
   924   | replicate_string k a =
   925       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   926       else replicate_string (k div 2) (a ^ a) ^ a;
   927 
   928 fun string_of_list f = enclose "[" "]" o commas o map f;
   929 
   930 fun string_of_option f NONE = "NONE"
   931   | string_of_option f (SOME x) = "SOME (" ^ f x ^ ")";
   932 
   933 
   934 
   935 (** lists as sets -- see also Pure/General/ord_list.ML **)
   936 
   937 (*canonical member, insert, remove*)
   938 fun member eq list x =
   939   let
   940     fun memb [] = false
   941       | memb (y :: ys) = eq (x, y) orelse memb ys;
   942   in memb list end;
   943 
   944 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   945 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   946 
   947 fun subtract eq = fold (remove eq);
   948 
   949 fun merge _ ([], ys) = ys
   950   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   951 
   952 (*old-style infixes*)
   953 fun x mem xs = member (op =) xs x;
   954 fun (x: int) mem_int xs = member (op =) xs x;
   955 fun (x: string) mem_string xs = member (op =) xs x;
   956 
   957 fun x ins xs = insert (op =) x xs;
   958 fun (x: int) ins_int xs = insert (op =) x xs;
   959 fun (x: string) ins_string xs = insert (op =) x xs;
   960 
   961 
   962 (*union of sets represented as lists: no repetitions*)
   963 fun xs union [] = xs
   964   | [] union ys = ys
   965   | (x :: xs) union ys = xs union (x ins ys);
   966 
   967 (*union of sets, optimized version for ints*)
   968 fun (xs:int list) union_int [] = xs
   969   | [] union_int ys = ys
   970   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   971 
   972 (*union of sets, optimized version for strings*)
   973 fun (xs:string list) union_string [] = xs
   974   | [] union_string ys = ys
   975   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   976 
   977 (*generalized union*)
   978 fun gen_union eq (xs, []) = xs
   979   | gen_union eq ([], ys) = ys
   980   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   981 
   982 
   983 (*intersection*)
   984 fun [] inter ys = []
   985   | (x :: xs) inter ys =
   986       if x mem ys then x :: (xs inter ys) else xs inter ys;
   987 
   988 (*intersection, optimized version for ints*)
   989 fun ([]:int list) inter_int ys = []
   990   | (x :: xs) inter_int ys =
   991       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   992 
   993 (*intersection, optimized version for strings *)
   994 fun ([]:string list) inter_string ys = []
   995   | (x :: xs) inter_string ys =
   996       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   997 
   998 (*generalized intersection*)
   999 fun gen_inter eq ([], ys) = []
  1000   | gen_inter eq (x::xs, ys) =
  1001       if member eq ys x then x :: gen_inter eq (xs, ys)
  1002       else gen_inter eq (xs, ys);
  1003 
  1004 
  1005 (*subset*)
  1006 fun [] subset ys = true
  1007   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
  1008 
  1009 (*subset, optimized version for ints*)
  1010 fun ([]: int list) subset_int ys = true
  1011   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
  1012 
  1013 (*subset, optimized version for strings*)
  1014 fun ([]: string list) subset_string ys = true
  1015   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
  1016 
  1017 (*set equality*)
  1018 fun eq_set (xs, ys) =
  1019   xs = ys orelse (xs subset ys andalso ys subset xs);
  1020 
  1021 (*set equality for strings*)
  1022 fun eq_set_string ((xs: string list), ys) =
  1023   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
  1024 
  1025 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
  1026 
  1027 fun gen_eq_set eq (xs, ys) =
  1028   equal_lists eq (xs, ys) orelse
  1029     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
  1030 
  1031 
  1032 (*removing an element from a list WITHOUT duplicates*)
  1033 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
  1034   | [] \ x = [];
  1035 
  1036 fun ys \\ xs = foldl (op \) (ys,xs);
  1037 
  1038 (*removing an element from a list -- possibly WITH duplicates*)
  1039 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
  1040 fun gen_rems eq (xs, ys) = filter_out (member eq ys) xs;
  1041 
  1042 (*returns the tail beginning with the first repeated element, or []*)
  1043 fun findrep [] = []
  1044   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1045 
  1046 
  1047 (*makes a list of the distinct members of the input; preserves order, takes
  1048   first of equal elements*)
  1049 fun distinct eq lst =
  1050   let
  1051     fun dist (rev_seen, []) = rev rev_seen
  1052       | dist (rev_seen, x :: xs) =
  1053           if member eq rev_seen x then dist (rev_seen, xs)
  1054           else dist (x :: rev_seen, xs);
  1055   in dist ([], lst) end;
  1056 
  1057 (*returns a list containing all repeated elements exactly once; preserves
  1058   order, takes first of equal elements*)
  1059 fun duplicates eq lst =
  1060   let
  1061     fun dups (rev_dups, []) = rev rev_dups
  1062       | dups (rev_dups, x :: xs) =
  1063           if member eq rev_dups x orelse not (member eq xs x) then
  1064             dups (rev_dups, xs)
  1065           else dups (x :: rev_dups, xs);
  1066   in dups ([], lst) end;
  1067 
  1068 fun has_duplicates eq =
  1069   let
  1070     fun dups [] = false
  1071       | dups (x :: xs) = member eq xs x orelse dups xs;
  1072   in dups end;
  1073 
  1074 
  1075 (** association lists -- legacy operations **)
  1076 
  1077 fun gen_merge_lists _ xs [] = xs
  1078   | gen_merge_lists _ [] ys = ys
  1079   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1080 
  1081 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1082 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1083 
  1084 
  1085 (** balanced trees **)
  1086 
  1087 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1088 
  1089 (*balanced folding; avoids deep nesting*)
  1090 fun fold_bal f [x] = x
  1091   | fold_bal f [] = raise Balance
  1092   | fold_bal f xs =
  1093       let val (ps, qs) = chop (length xs div 2) xs
  1094       in  f (fold_bal f ps, fold_bal f qs)  end;
  1095 
  1096 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1097 fun access_bal (f, g, x) n i =
  1098   let fun acc n i =     (*1<=i<=n*)
  1099           if n=1 then x else
  1100           let val n2 = n div 2
  1101           in  if i<=n2 then f (acc n2 i)
  1102                        else g (acc (n-n2) (i-n2))
  1103           end
  1104   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1105 
  1106 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1107 fun accesses_bal (f, g, x) n =
  1108   let fun acc n =
  1109           if n=1 then [x] else
  1110           let val n2 = n div 2
  1111               val acc2 = acc n2
  1112           in  if n-n2=n2 then map f acc2 @ map g acc2
  1113                          else map f acc2 @ map g (acc (n-n2)) end
  1114   in  if 1<=n then acc n else raise Balance  end;
  1115 
  1116 
  1117 
  1118 (** orders **)
  1119 
  1120 fun is_equal EQUAL = true
  1121   | is_equal _ = false;
  1122 
  1123 fun rev_order LESS = GREATER
  1124   | rev_order EQUAL = EQUAL
  1125   | rev_order GREATER = LESS;
  1126 
  1127 (*assume rel is a linear strict order*)
  1128 fun make_ord rel (x, y) =
  1129   if rel (x, y) then LESS
  1130   else if rel (y, x) then GREATER
  1131   else EQUAL;
  1132 
  1133 val int_ord = Int.compare;
  1134 val string_ord = String.compare;
  1135 
  1136 fun fast_string_ord (s1, s2) =
  1137   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1138 
  1139 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1140   | option_ord _ (NONE, NONE) = EQUAL
  1141   | option_ord _ (NONE, SOME _) = LESS
  1142   | option_ord _ (SOME _, NONE) = GREATER;
  1143 
  1144 (*lexicographic product*)
  1145 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1146   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1147 
  1148 (*dictionary order -- in general NOT well-founded!*)
  1149 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1150       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1151   | dict_ord _ ([], []) = EQUAL
  1152   | dict_ord _ ([], _ :: _) = LESS
  1153   | dict_ord _ (_ :: _, []) = GREATER;
  1154 
  1155 (*lexicographic product of lists*)
  1156 fun list_ord elem_ord (xs, ys) =
  1157   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1158 
  1159 
  1160 (* sorting *)
  1161 
  1162 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1163 fun quicksort unique ord =
  1164   let
  1165     fun qsort [] = []
  1166       | qsort (xs as [_]) = xs
  1167       | qsort (xs as [x, y]) =
  1168           (case ord (x, y) of
  1169             LESS => xs
  1170           | EQUAL => if unique then [x] else xs
  1171           | GREATER => [y, x])
  1172       | qsort xs =
  1173           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1174           in qsort lts @ eqs @ qsort gts end
  1175     and part _ [] = ([], [], [])
  1176       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1177     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1178       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1179       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1180       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1181   in qsort end;
  1182 
  1183 fun sort ord = quicksort false ord;
  1184 fun sort_distinct ord = quicksort true ord;
  1185 
  1186 val sort_strings = sort string_ord;
  1187 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1188 
  1189 
  1190 
  1191 (** random numbers **)
  1192 
  1193 exception RANDOM;
  1194 
  1195 fun rmod x y = x - y * Real.realFloor (x / y);
  1196 
  1197 local
  1198   val a = 16807.0;
  1199   val m = 2147483647.0;
  1200   val random_seed = ref 1.0;
  1201 in
  1202 
  1203 fun random () =
  1204   let val r = rmod (a * !random_seed) m
  1205   in (random_seed := r; r) end;
  1206 
  1207 end;
  1208 
  1209 fun random_range l h =
  1210   if h < l orelse l < 0 then raise RANDOM
  1211   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1212 
  1213 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1214 
  1215 fun frequency xs =
  1216   let
  1217     val sum = foldl op + (0, map fst xs);
  1218     fun pick n ((k: int, x) :: xs) =
  1219       if n <= k then x else pick (n - k) xs
  1220   in pick (random_range 1 sum) xs end;
  1221 
  1222 
  1223 (** current directory **)
  1224 
  1225 val cd = OS.FileSys.chDir;
  1226 val pwd = OS.FileSys.getDir;
  1227 
  1228 
  1229 
  1230 (** misc **)
  1231 
  1232 fun divide_and_conquer decomp x =
  1233   let val (ys, recomb) = decomp x
  1234   in recomb (map (divide_and_conquer decomp) ys) end;
  1235 
  1236 
  1237 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1238    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1239 fun partition_list p i j =
  1240   let fun part k xs =
  1241             if k>j then
  1242               (case xs of [] => []
  1243                          | _ => raise Fail "partition_list")
  1244             else
  1245             let val (ns, rest) = List.partition (p k) xs;
  1246             in  ns :: part(k+1)rest  end
  1247   in  part i end;
  1248 
  1249 fun partition_eq (eq:'a * 'a -> bool) =
  1250   let
  1251     fun part [] = []
  1252       | part (x :: ys) =
  1253           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1254           in (x::xs)::(part xs') end
  1255   in part end;
  1256 
  1257 
  1258 
  1259 (* generating identifiers *)
  1260 
  1261 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1262 local
  1263 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1264 fun char i =      if i<26 then chr (ord "A" + i)
  1265              else if i<52 then chr (ord "a" + i - 26)
  1266              else if i<62 then chr (ord"0" + i - 52)
  1267              else if i=62 then "_"
  1268              else  (*i=63*)    "'";
  1269 
  1270 val charVec = Vector.tabulate (64, char);
  1271 
  1272 fun newid n =
  1273   let
  1274   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1275 
  1276 val seedr = ref 0;
  1277 
  1278 in
  1279 
  1280 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1281 
  1282 end;
  1283 
  1284 
  1285 (* lexical scanning *)
  1286 
  1287 (*scan a list of characters into "words" composed of "letters" (recognized by
  1288   is_let) and separated by any number of non-"letters"*)
  1289 fun scanwords is_let cs =
  1290   let fun scan1 [] = []
  1291         | scan1 cs =
  1292             let val (lets, rest) = take_prefix is_let cs
  1293             in implode lets :: scanwords is_let rest end;
  1294   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1295 
  1296 
  1297 (* stamps and serial numbers *)
  1298 
  1299 type stamp = unit ref;
  1300 val stamp: unit -> stamp = ref;
  1301 
  1302 type serial = int;
  1303 local val count = ref 0
  1304 in fun serial () = inc count end;
  1305 
  1306 val serial_string = string_of_int o serial;
  1307 
  1308 
  1309 (* generic objects *)
  1310 
  1311 (*note that the builtin exception datatype may be extended by new
  1312   constructors at any time*)
  1313 structure Object = struct type T = exn end;
  1314 
  1315 end;
  1316 
  1317 structure BasicLibrary: BASIC_LIBRARY = Library;
  1318 open BasicLibrary;