src/HOL/BNF_Greatest_Fixpoint.thy
author blanchet
Mon Sep 01 16:34:40 2014 +0200 (2014-09-01)
changeset 58128 43a1ba26a8cb
parent 58104 src/HOL/BNF_GFP.thy@c5316f843f72
child 58352 37745650a3f4
permissions -rw-r--r--
renamed BNF theories
     1 (*  Title:      HOL/BNF_Greatest_Fixpoint.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Lorenz Panny, TU Muenchen
     4     Author:     Jasmin Blanchette, TU Muenchen
     5     Copyright   2012, 2013, 2014
     6 
     7 Greatest fixed point operation on bounded natural functors.
     8 *)
     9 
    10 header {* Greatest Fixed Point Operation on Bounded Natural Functors *}
    11 
    12 theory BNF_Greatest_Fixpoint
    13 imports BNF_Fixpoint_Base String
    14 keywords
    15   "codatatype" :: thy_decl and
    16   "primcorecursive" :: thy_goal and
    17   "primcorec" :: thy_decl
    18 begin
    19 
    20 setup {*
    21 Sign.const_alias @{binding proj} @{const_name Equiv_Relations.proj}
    22 *}
    23 
    24 lemma one_pointE: "\<lbrakk>\<And>x. s = x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
    25   by simp
    26 
    27 lemma obj_sumE: "\<lbrakk>\<forall>x. s = Inl x \<longrightarrow> P; \<forall>x. s = Inr x \<longrightarrow> P\<rbrakk> \<Longrightarrow> P"
    28   by (cases s) auto
    29 
    30 lemma not_TrueE: "\<not> True \<Longrightarrow> P"
    31   by (erule notE, rule TrueI)
    32 
    33 lemma neq_eq_eq_contradict: "\<lbrakk>t \<noteq> u; s = t; s = u\<rbrakk> \<Longrightarrow> P"
    34   by fast
    35 
    36 lemma case_sum_expand_Inr: "f o Inl = g \<Longrightarrow> f x = case_sum g (f o Inr) x"
    37   by (auto split: sum.splits)
    38 
    39 lemma case_sum_expand_Inr': "f o Inl = g \<Longrightarrow> h = f o Inr \<longleftrightarrow> case_sum g h = f"
    40   apply rule
    41    apply (rule ext, force split: sum.split)
    42   by (rule ext, metis case_sum_o_inj(2))
    43 
    44 lemma converse_Times: "(A \<times> B) ^-1 = B \<times> A"
    45   by fast
    46 
    47 lemma equiv_proj:
    48   assumes e: "equiv A R" and m: "z \<in> R"
    49   shows "(proj R o fst) z = (proj R o snd) z"
    50 proof -
    51   from m have z: "(fst z, snd z) \<in> R" by auto
    52   with e have "\<And>x. (fst z, x) \<in> R \<Longrightarrow> (snd z, x) \<in> R" "\<And>x. (snd z, x) \<in> R \<Longrightarrow> (fst z, x) \<in> R"
    53     unfolding equiv_def sym_def trans_def by blast+
    54   then show ?thesis unfolding proj_def[abs_def] by auto
    55 qed
    56 
    57 (* Operators: *)
    58 definition image2 where "image2 A f g = {(f a, g a) | a. a \<in> A}"
    59 
    60 lemma Id_on_Gr: "Id_on A = Gr A id"
    61   unfolding Id_on_def Gr_def by auto
    62 
    63 lemma image2_eqI: "\<lbrakk>b = f x; c = g x; x \<in> A\<rbrakk> \<Longrightarrow> (b, c) \<in> image2 A f g"
    64   unfolding image2_def by auto
    65 
    66 lemma IdD: "(a, b) \<in> Id \<Longrightarrow> a = b"
    67   by auto
    68 
    69 lemma image2_Gr: "image2 A f g = (Gr A f)^-1 O (Gr A g)"
    70   unfolding image2_def Gr_def by auto
    71 
    72 lemma GrD1: "(x, fx) \<in> Gr A f \<Longrightarrow> x \<in> A"
    73   unfolding Gr_def by simp
    74 
    75 lemma GrD2: "(x, fx) \<in> Gr A f \<Longrightarrow> f x = fx"
    76   unfolding Gr_def by simp
    77 
    78 lemma Gr_incl: "Gr A f \<subseteq> A <*> B \<longleftrightarrow> f ` A \<subseteq> B"
    79   unfolding Gr_def by auto
    80 
    81 lemma subset_Collect_iff: "B \<subseteq> A \<Longrightarrow> (B \<subseteq> {x \<in> A. P x}) = (\<forall>x \<in> B. P x)"
    82   by blast
    83 
    84 lemma subset_CollectI: "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> Q x \<Longrightarrow> P x) \<Longrightarrow> ({x \<in> B. Q x} \<subseteq> {x \<in> A. P x})"
    85   by blast
    86 
    87 lemma in_rel_Collect_split_eq: "in_rel (Collect (split X)) = X"
    88   unfolding fun_eq_iff by auto
    89 
    90 lemma Collect_split_in_rel_leI: "X \<subseteq> Y \<Longrightarrow> X \<subseteq> Collect (split (in_rel Y))"
    91   by auto
    92 
    93 lemma Collect_split_in_rel_leE: "X \<subseteq> Collect (split (in_rel Y)) \<Longrightarrow> (X \<subseteq> Y \<Longrightarrow> R) \<Longrightarrow> R"
    94   by force
    95 
    96 lemma conversep_in_rel: "(in_rel R)\<inverse>\<inverse> = in_rel (R\<inverse>)"
    97   unfolding fun_eq_iff by auto
    98 
    99 lemma relcompp_in_rel: "in_rel R OO in_rel S = in_rel (R O S)"
   100   unfolding fun_eq_iff by auto
   101 
   102 lemma in_rel_Gr: "in_rel (Gr A f) = Grp A f"
   103   unfolding Gr_def Grp_def fun_eq_iff by auto
   104 
   105 definition relImage where
   106   "relImage R f \<equiv> {(f a1, f a2) | a1 a2. (a1,a2) \<in> R}"
   107 
   108 definition relInvImage where
   109   "relInvImage A R f \<equiv> {(a1, a2) | a1 a2. a1 \<in> A \<and> a2 \<in> A \<and> (f a1, f a2) \<in> R}"
   110 
   111 lemma relImage_Gr:
   112   "\<lbrakk>R \<subseteq> A \<times> A\<rbrakk> \<Longrightarrow> relImage R f = (Gr A f)^-1 O R O Gr A f"
   113   unfolding relImage_def Gr_def relcomp_def by auto
   114 
   115 lemma relInvImage_Gr: "\<lbrakk>R \<subseteq> B \<times> B\<rbrakk> \<Longrightarrow> relInvImage A R f = Gr A f O R O (Gr A f)^-1"
   116   unfolding Gr_def relcomp_def image_def relInvImage_def by auto
   117 
   118 lemma relImage_mono:
   119   "R1 \<subseteq> R2 \<Longrightarrow> relImage R1 f \<subseteq> relImage R2 f"
   120   unfolding relImage_def by auto
   121 
   122 lemma relInvImage_mono:
   123   "R1 \<subseteq> R2 \<Longrightarrow> relInvImage A R1 f \<subseteq> relInvImage A R2 f"
   124   unfolding relInvImage_def by auto
   125 
   126 lemma relInvImage_Id_on:
   127   "(\<And>a1 a2. f a1 = f a2 \<longleftrightarrow> a1 = a2) \<Longrightarrow> relInvImage A (Id_on B) f \<subseteq> Id"
   128   unfolding relInvImage_def Id_on_def by auto
   129 
   130 lemma relInvImage_UNIV_relImage:
   131   "R \<subseteq> relInvImage UNIV (relImage R f) f"
   132   unfolding relInvImage_def relImage_def by auto
   133 
   134 lemma relImage_proj:
   135   assumes "equiv A R"
   136   shows "relImage R (proj R) \<subseteq> Id_on (A//R)"
   137   unfolding relImage_def Id_on_def
   138   using proj_iff[OF assms] equiv_class_eq_iff[OF assms]
   139   by (auto simp: proj_preserves)
   140 
   141 lemma relImage_relInvImage:
   142   assumes "R \<subseteq> f ` A <*> f ` A"
   143   shows "relImage (relInvImage A R f) f = R"
   144   using assms unfolding relImage_def relInvImage_def by fast
   145 
   146 lemma subst_Pair: "P x y \<Longrightarrow> a = (x, y) \<Longrightarrow> P (fst a) (snd a)"
   147   by simp
   148 
   149 lemma fst_diag_id: "(fst \<circ> (%x. (x, x))) z = id z" by simp
   150 lemma snd_diag_id: "(snd \<circ> (%x. (x, x))) z = id z" by simp
   151 
   152 lemma fst_diag_fst: "fst o ((\<lambda>x. (x, x)) o fst) = fst" by auto
   153 lemma snd_diag_fst: "snd o ((\<lambda>x. (x, x)) o fst) = fst" by auto
   154 lemma fst_diag_snd: "fst o ((\<lambda>x. (x, x)) o snd) = snd" by auto
   155 lemma snd_diag_snd: "snd o ((\<lambda>x. (x, x)) o snd) = snd" by auto
   156 
   157 definition Succ where "Succ Kl kl = {k . kl @ [k] \<in> Kl}"
   158 definition Shift where "Shift Kl k = {kl. k # kl \<in> Kl}"
   159 definition shift where "shift lab k = (\<lambda>kl. lab (k # kl))"
   160 
   161 lemma empty_Shift: "\<lbrakk>[] \<in> Kl; k \<in> Succ Kl []\<rbrakk> \<Longrightarrow> [] \<in> Shift Kl k"
   162   unfolding Shift_def Succ_def by simp
   163 
   164 lemma SuccD: "k \<in> Succ Kl kl \<Longrightarrow> kl @ [k] \<in> Kl"
   165   unfolding Succ_def by simp
   166 
   167 lemmas SuccE = SuccD[elim_format]
   168 
   169 lemma SuccI: "kl @ [k] \<in> Kl \<Longrightarrow> k \<in> Succ Kl kl"
   170   unfolding Succ_def by simp
   171 
   172 lemma ShiftD: "kl \<in> Shift Kl k \<Longrightarrow> k # kl \<in> Kl"
   173   unfolding Shift_def by simp
   174 
   175 lemma Succ_Shift: "Succ (Shift Kl k) kl = Succ Kl (k # kl)"
   176   unfolding Succ_def Shift_def by auto
   177 
   178 lemma length_Cons: "length (x # xs) = Suc (length xs)"
   179   by simp
   180 
   181 lemma length_append_singleton: "length (xs @ [x]) = Suc (length xs)"
   182   by simp
   183 
   184 (*injection into the field of a cardinal*)
   185 definition "toCard_pred A r f \<equiv> inj_on f A \<and> f ` A \<subseteq> Field r \<and> Card_order r"
   186 definition "toCard A r \<equiv> SOME f. toCard_pred A r f"
   187 
   188 lemma ex_toCard_pred:
   189   "\<lbrakk>|A| \<le>o r; Card_order r\<rbrakk> \<Longrightarrow> \<exists> f. toCard_pred A r f"
   190   unfolding toCard_pred_def
   191   using card_of_ordLeq[of A "Field r"]
   192     ordLeq_ordIso_trans[OF _ card_of_unique[of "Field r" r], of "|A|"]
   193   by blast
   194 
   195 lemma toCard_pred_toCard:
   196   "\<lbrakk>|A| \<le>o r; Card_order r\<rbrakk> \<Longrightarrow> toCard_pred A r (toCard A r)"
   197   unfolding toCard_def using someI_ex[OF ex_toCard_pred] .
   198 
   199 lemma toCard_inj: "\<lbrakk>|A| \<le>o r; Card_order r; x \<in> A; y \<in> A\<rbrakk> \<Longrightarrow> toCard A r x = toCard A r y \<longleftrightarrow> x = y"
   200   using toCard_pred_toCard unfolding inj_on_def toCard_pred_def by blast
   201 
   202 definition "fromCard A r k \<equiv> SOME b. b \<in> A \<and> toCard A r b = k"
   203 
   204 lemma fromCard_toCard:
   205   "\<lbrakk>|A| \<le>o r; Card_order r; b \<in> A\<rbrakk> \<Longrightarrow> fromCard A r (toCard A r b) = b"
   206   unfolding fromCard_def by (rule some_equality) (auto simp add: toCard_inj)
   207 
   208 lemma Inl_Field_csum: "a \<in> Field r \<Longrightarrow> Inl a \<in> Field (r +c s)"
   209   unfolding Field_card_of csum_def by auto
   210 
   211 lemma Inr_Field_csum: "a \<in> Field s \<Longrightarrow> Inr a \<in> Field (r +c s)"
   212   unfolding Field_card_of csum_def by auto
   213 
   214 lemma rec_nat_0_imp: "f = rec_nat f1 (%n rec. f2 n rec) \<Longrightarrow> f 0 = f1"
   215   by auto
   216 
   217 lemma rec_nat_Suc_imp: "f = rec_nat f1 (%n rec. f2 n rec) \<Longrightarrow> f (Suc n) = f2 n (f n)"
   218   by auto
   219 
   220 lemma rec_list_Nil_imp: "f = rec_list f1 (%x xs rec. f2 x xs rec) \<Longrightarrow> f [] = f1"
   221   by auto
   222 
   223 lemma rec_list_Cons_imp: "f = rec_list f1 (%x xs rec. f2 x xs rec) \<Longrightarrow> f (x # xs) = f2 x xs (f xs)"
   224   by auto
   225 
   226 lemma not_arg_cong_Inr: "x \<noteq> y \<Longrightarrow> Inr x \<noteq> Inr y"
   227   by simp
   228 
   229 definition image2p where
   230   "image2p f g R = (\<lambda>x y. \<exists>x' y'. R x' y' \<and> f x' = x \<and> g y' = y)"
   231 
   232 lemma image2pI: "R x y \<Longrightarrow> image2p f g R (f x) (g y)"
   233   unfolding image2p_def by blast
   234 
   235 lemma image2pE: "\<lbrakk>image2p f g R fx gy; (\<And>x y. fx = f x \<Longrightarrow> gy = g y \<Longrightarrow> R x y \<Longrightarrow> P)\<rbrakk> \<Longrightarrow> P"
   236   unfolding image2p_def by blast
   237 
   238 lemma rel_fun_iff_geq_image2p: "rel_fun R S f g = (image2p f g R \<le> S)"
   239   unfolding rel_fun_def image2p_def by auto
   240 
   241 lemma rel_fun_image2p: "rel_fun R (image2p f g R) f g"
   242   unfolding rel_fun_def image2p_def by auto
   243 
   244 
   245 subsection {* Equivalence relations, quotients, and Hilbert's choice *}
   246 
   247 lemma equiv_Eps_in:
   248 "\<lbrakk>equiv A r; X \<in> A//r\<rbrakk> \<Longrightarrow> Eps (%x. x \<in> X) \<in> X"
   249   apply (rule someI2_ex)
   250   using in_quotient_imp_non_empty by blast
   251 
   252 lemma equiv_Eps_preserves:
   253   assumes ECH: "equiv A r" and X: "X \<in> A//r"
   254   shows "Eps (%x. x \<in> X) \<in> A"
   255   apply (rule in_mono[rule_format])
   256    using assms apply (rule in_quotient_imp_subset)
   257   by (rule equiv_Eps_in) (rule assms)+
   258 
   259 lemma proj_Eps:
   260   assumes "equiv A r" and "X \<in> A//r"
   261   shows "proj r (Eps (%x. x \<in> X)) = X"
   262 unfolding proj_def
   263 proof auto
   264   fix x assume x: "x \<in> X"
   265   thus "(Eps (%x. x \<in> X), x) \<in> r" using assms equiv_Eps_in in_quotient_imp_in_rel by fast
   266 next
   267   fix x assume "(Eps (%x. x \<in> X),x) \<in> r"
   268   thus "x \<in> X" using in_quotient_imp_closed[OF assms equiv_Eps_in[OF assms]] by fast
   269 qed
   270 
   271 definition univ where "univ f X == f (Eps (%x. x \<in> X))"
   272 
   273 lemma univ_commute:
   274 assumes ECH: "equiv A r" and RES: "f respects r" and x: "x \<in> A"
   275 shows "(univ f) (proj r x) = f x"
   276 proof (unfold univ_def)
   277   have prj: "proj r x \<in> A//r" using x proj_preserves by fast
   278   hence "Eps (%y. y \<in> proj r x) \<in> A" using ECH equiv_Eps_preserves by fast
   279   moreover have "proj r (Eps (%y. y \<in> proj r x)) = proj r x" using ECH prj proj_Eps by fast
   280   ultimately have "(x, Eps (%y. y \<in> proj r x)) \<in> r" using x ECH proj_iff by fast
   281   thus "f (Eps (%y. y \<in> proj r x)) = f x" using RES unfolding congruent_def by fastforce
   282 qed
   283 
   284 lemma univ_preserves:
   285   assumes ECH: "equiv A r" and RES: "f respects r" and PRES: "\<forall>x \<in> A. f x \<in> B"
   286   shows "\<forall>X \<in> A//r. univ f X \<in> B"
   287 proof
   288   fix X assume "X \<in> A//r"
   289   then obtain x where x: "x \<in> A" and X: "X = proj r x" using ECH proj_image[of r A] by blast
   290   hence "univ f X = f x" using ECH RES univ_commute by fastforce
   291   thus "univ f X \<in> B" using x PRES by simp
   292 qed
   293 
   294 ML_file "Tools/BNF/bnf_gfp_util.ML"
   295 ML_file "Tools/BNF/bnf_gfp_tactics.ML"
   296 ML_file "Tools/BNF/bnf_gfp.ML"
   297 ML_file "Tools/BNF/bnf_gfp_rec_sugar_tactics.ML"
   298 ML_file "Tools/BNF/bnf_gfp_rec_sugar.ML"
   299 
   300 end