src/Pure/theory.ML
author wenzelm
Thu Apr 13 12:01:06 2006 +0200 (2006-04-13)
changeset 19428 43bfe55759b0
parent 19135 2de31ba562d7
child 19482 9f11af8f7ef9
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   type theory
    11   type theory_ref
    12   val sign_of: theory -> theory    (*obsolete*)
    13   val rep_theory: theory ->
    14    {axioms: term NameSpace.table,
    15     defs: Defs.T,
    16     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    17   val parents_of: theory -> theory list
    18   val ancestors_of: theory -> theory list
    19   val eq_thy: theory * theory -> bool
    20   val subthy: theory * theory -> bool
    21   val cert_axm: theory -> string * term -> string * term
    22   val read_def_axm: theory * (indexname -> typ option) * (indexname -> sort option) ->
    23     string list -> string * string -> string * term
    24   val read_axm: theory -> string * string -> string * term
    25   val inferT_axm: theory -> string * term -> string * term
    26 end
    27 
    28 signature THEORY =
    29 sig
    30   include BASIC_THEORY
    31   include SIGN_THEORY
    32   val begin_theory: string -> theory list -> theory
    33   val end_theory: theory -> theory
    34   val checkpoint: theory -> theory
    35   val copy: theory -> theory
    36   val init_data: theory -> theory
    37   val axiom_space: theory -> NameSpace.T
    38   val oracle_space: theory -> NameSpace.T
    39   val axioms_of: theory -> (string * term) list
    40   val all_axioms_of: theory -> (string * term) list
    41   val defs_of : theory -> Defs.T
    42   val self_ref: theory -> theory_ref
    43   val deref: theory_ref -> theory
    44   val merge: theory * theory -> theory                     (*exception TERM*)
    45   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    46   val requires: theory -> string -> string -> unit
    47   val assert_super: theory -> theory -> theory
    48   val add_axioms: (bstring * string) list -> theory -> theory
    49   val add_axioms_i: (bstring * term) list -> theory -> theory
    50   val add_defs: bool -> (bstring * string) list -> theory -> theory
    51   val add_defs_i: bool -> (bstring * term) list -> theory -> theory
    52   val add_finals: bool -> string list -> theory -> theory
    53   val add_finals_i: bool -> term list -> theory -> theory
    54   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    55 end
    56 
    57 structure Theory: THEORY =
    58 struct
    59 
    60 (** type theory **)
    61 
    62 (* context operations *)
    63 
    64 type theory = Context.theory;
    65 type theory_ref = Context.theory_ref;
    66 
    67 val eq_thy = Context.eq_thy;
    68 val subthy = Context.subthy;
    69 
    70 val parents_of = Context.parents_of;
    71 val ancestors_of = Context.ancestors_of;
    72 
    73 val self_ref = Context.self_ref;
    74 val deref = Context.deref;
    75 val merge = Context.merge;
    76 val merge_refs = Context.merge_refs;
    77 
    78 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    79 val end_theory = Context.finish_thy;
    80 val checkpoint = Context.checkpoint_thy;
    81 val copy = Context.copy_thy;
    82 
    83 
    84 (* signature operations *)
    85 
    86 val sign_of = I;
    87 
    88 structure SignTheory: SIGN_THEORY = Sign;
    89 open SignTheory;
    90 
    91 
    92 
    93 (** datatype thy **)
    94 
    95 datatype thy = Thy of
    96  {axioms: term NameSpace.table,
    97   defs: Defs.T,
    98   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
    99 
   100 fun make_thy (axioms, defs, oracles) =
   101   Thy {axioms = axioms, defs = defs, oracles = oracles};
   102 
   103 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   104 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   105 
   106 structure ThyData = TheoryDataFun
   107 (struct
   108   val name = "Pure/theory";
   109   type T = thy;
   110   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   111   val copy = I;
   112 
   113   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   114 
   115   fun merge pp (thy1, thy2) =
   116     let
   117       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   118       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   119 
   120       val axioms = NameSpace.empty_table;
   121       val defs = Defs.merge pp (defs1, defs2);
   122       val oracles = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   123         handle Symtab.DUPS dups => err_dup_oras dups;
   124     in make_thy (axioms, defs, oracles) end;
   125 
   126   fun print _ _ = ();
   127 end);
   128 
   129 val init_data = ThyData.init;
   130 
   131 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   132 
   133 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   134   make_thy (f (axioms, defs, oracles)));
   135 
   136 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   137 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   138 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   139 
   140 
   141 (* basic operations *)
   142 
   143 val axiom_space = #1 o #axioms o rep_theory;
   144 val oracle_space = #1 o #oracles o rep_theory;
   145 
   146 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   147 fun all_axioms_of thy = List.concat (map axioms_of (thy :: ancestors_of thy));
   148 
   149 val defs_of = #defs o rep_theory;
   150 
   151 fun requires thy name what =
   152   if Context.exists_name name thy then ()
   153   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   154 
   155 fun assert_super thy1 thy2 =
   156   if subthy (thy1, thy2) then thy2
   157   else raise THEORY ("Not a super theory", [thy1, thy2]);
   158 
   159 
   160 
   161 (** add axioms **)
   162 
   163 (* prepare axioms *)
   164 
   165 fun err_in_axm msg name =
   166   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   167 
   168 fun cert_axm thy (name, raw_tm) =
   169   let
   170     val (t, T, _) = Sign.certify_prop thy raw_tm
   171       handle TYPE (msg, _, _) => error msg
   172         | TERM (msg, _) => error msg;
   173   in
   174     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   175     (name, Sign.no_vars (Sign.pp thy) t)
   176   end;
   177 
   178 fun read_def_axm (thy, types, sorts) used (name, str) =
   179   let
   180     val ts = Syntax.read (Context.Theory thy) (Sign.is_logtype thy) (Sign.syn_of thy) propT str;
   181     val (t, _) =
   182       Sign.infer_types (Sign.pp thy) thy (Sign.consts_of thy) types sorts used true (ts, propT);
   183   in cert_axm thy (name, t) end
   184   handle ERROR msg => err_in_axm msg name;
   185 
   186 fun read_axm thy name_str = read_def_axm (thy, K NONE, K NONE) [] name_str;
   187 
   188 fun inferT_axm thy (name, pre_tm) =
   189   let
   190     val pp = Sign.pp thy;
   191     val (t, _) =
   192       Sign.infer_types pp thy (Sign.consts_of thy) (K NONE) (K NONE) [] true ([pre_tm], propT);
   193   in (name, Sign.no_vars pp t) end
   194   handle ERROR msg => err_in_axm msg name;
   195 
   196 
   197 (* add_axioms(_i) *)
   198 
   199 local
   200 
   201 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   202   let
   203     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   204     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   205       handle Symtab.DUPS dups => err_dup_axms dups;
   206   in axioms' end);
   207 
   208 in
   209 
   210 val add_axioms = gen_add_axioms read_axm;
   211 val add_axioms_i = gen_add_axioms cert_axm;
   212 
   213 end;
   214 
   215 
   216 
   217 (** add constant definitions **)
   218 
   219 fun prep_const thy (c, T) = (c, Compress.typ thy (Type.varifyT T));
   220 
   221 
   222 (* check_overloading *)
   223 
   224 fun check_overloading thy overloaded (c, T) =
   225   let
   226     val declT =
   227       (case Sign.const_constraint thy c of
   228         NONE => error ("Undeclared constant " ^ quote c)
   229       | SOME declT => declT);
   230     val T' = Type.varifyT T;
   231 
   232     fun message txt =
   233       [Pretty.block [Pretty.str "Specification of constant ",
   234         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   235         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   236   in
   237     if Sign.typ_instance thy (declT, T') then ()
   238     else if Type.raw_instance (declT, T') then
   239       error (Library.setmp show_sorts true
   240         message "imposes additional sort constraints on the constant declaration")
   241     else if overloaded then ()
   242     else warning (message "is strictly less general than the declared type");
   243     (c, T)
   244   end;
   245 
   246 
   247 (* check_def *)
   248 
   249 fun check_def thy overloaded (bname, tm) defs =
   250   let
   251     val pp = Sign.pp thy;
   252     fun prt_const (c, T) =
   253      [Pretty.str c, Pretty.str " ::", Pretty.brk 1,
   254       Pretty.quote (Pretty.typ pp (Type.freeze_type T))];
   255 
   256     val name = Sign.full_name thy bname;
   257     val (lhs_const, rhs) = Sign.cert_def pp tm;
   258     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   259     val _ = check_overloading thy overloaded lhs_const;
   260   in
   261     defs |> Defs.define (Sign.the_const_type thy)
   262       ((true, Context.theory_name thy), name) (prep_const thy lhs_const)
   263       (map (prep_const thy) rhs_consts)
   264   end
   265   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   266    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   267     Pretty.fbrk, Pretty.quote (Pretty.term (Sign.pp thy) tm)]));
   268 
   269 
   270 (* add_defs(_i) *)
   271 
   272 local
   273 
   274 fun gen_add_defs prep_axm overloaded raw_axms thy =
   275   let val axms = map (prep_axm thy) raw_axms in
   276     thy
   277     |> map_defs (fold (check_def thy overloaded) axms)
   278     |> add_axioms_i axms
   279   end;
   280 
   281 in
   282 
   283 val add_defs_i = gen_add_defs cert_axm;
   284 val add_defs = gen_add_defs read_axm;
   285 
   286 end;
   287 
   288 
   289 (* add_finals(_i) *)
   290 
   291 local
   292 
   293 fun gen_add_finals prep_term overloaded args thy =
   294   let
   295     fun const_of (Const const) = const
   296       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   297       | const_of _ = error "Attempt to finalize non-constant term";
   298     fun specify (c, T) = Defs.define (Sign.the_const_type thy)
   299       ((false, Context.theory_name thy), c ^ " axiom") (prep_const thy (c, T)) [];
   300     val finalize = specify o check_overloading thy overloaded o
   301       const_of o Sign.no_vars (Sign.pp thy) o prep_term thy;
   302   in thy |> map_defs (fold finalize args) end;
   303 
   304 in
   305 
   306 val add_finals = gen_add_finals Sign.read_term;
   307 val add_finals_i = gen_add_finals Sign.cert_term;
   308 
   309 end;
   310 
   311 
   312 
   313 (** add oracle **)
   314 
   315 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   316   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   317     handle Symtab.DUPS dups => err_dup_oras dups);
   318 
   319 end;
   320 
   321 structure BasicTheory: BASIC_THEORY = Theory;
   322 open BasicTheory;