src/HOL/SEQ.thy
author huffman
Tue Feb 24 11:12:58 2009 -0800 (2009-02-24)
changeset 30082 43c5b7bfc791
parent 29803 c56a5571f60a
child 30196 6ffaa79c352c
permissions -rw-r--r--
make more proofs work whether or not One_nat_def is a simp rule
     1 (*  Title       : SEQ.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Description : Convergence of sequences and series
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     Additional contributions by Jeremy Avigad and Brian Huffman
     7 *)
     8 
     9 header {* Sequences and Convergence *}
    10 
    11 theory SEQ
    12 imports RealVector RComplete
    13 begin
    14 
    15 definition
    16   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    17     --{*Standard definition of sequence converging to zero*}
    18   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    19 
    20 definition
    21   LIMSEQ :: "[nat => 'a::real_normed_vector, 'a] => bool"
    22     ("((_)/ ----> (_))" [60, 60] 60) where
    23     --{*Standard definition of convergence of sequence*}
    24   [code del]: "X ----> L = (\<forall>r. 0 < r --> (\<exists>no. \<forall>n. no \<le> n --> norm (X n - L) < r))"
    25 
    26 definition
    27   lim :: "(nat => 'a::real_normed_vector) => 'a" where
    28     --{*Standard definition of limit using choice operator*}
    29   "lim X = (THE L. X ----> L)"
    30 
    31 definition
    32   convergent :: "(nat => 'a::real_normed_vector) => bool" where
    33     --{*Standard definition of convergence*}
    34   "convergent X = (\<exists>L. X ----> L)"
    35 
    36 definition
    37   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    38     --{*Standard definition for bounded sequence*}
    39   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    40 
    41 definition
    42   monoseq :: "(nat=>real)=>bool" where
    43     --{*Definition for monotonicity*}
    44   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    45 
    46 definition
    47   subseq :: "(nat => nat) => bool" where
    48     --{*Definition of subsequence*}
    49   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    50 
    51 definition
    52   Cauchy :: "(nat => 'a::real_normed_vector) => bool" where
    53     --{*Standard definition of the Cauchy condition*}
    54   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. norm (X m - X n) < e)"
    55 
    56 
    57 subsection {* Bounded Sequences *}
    58 
    59 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    60 unfolding Bseq_def
    61 proof (intro exI conjI allI)
    62   show "0 < max K 1" by simp
    63 next
    64   fix n::nat
    65   have "norm (X n) \<le> K" by (rule K)
    66   thus "norm (X n) \<le> max K 1" by simp
    67 qed
    68 
    69 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    70 unfolding Bseq_def by auto
    71 
    72 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    73 proof (rule BseqI')
    74   let ?A = "norm ` X ` {..N}"
    75   have 1: "finite ?A" by simp
    76   fix n::nat
    77   show "norm (X n) \<le> max K (Max ?A)"
    78   proof (cases rule: linorder_le_cases)
    79     assume "n \<ge> N"
    80     hence "norm (X n) \<le> K" using K by simp
    81     thus "norm (X n) \<le> max K (Max ?A)" by simp
    82   next
    83     assume "n \<le> N"
    84     hence "norm (X n) \<in> ?A" by simp
    85     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
    86     thus "norm (X n) \<le> max K (Max ?A)" by simp
    87   qed
    88 qed
    89 
    90 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    91 unfolding Bseq_def by auto
    92 
    93 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    94 apply (erule BseqE)
    95 apply (rule_tac N="k" and K="K" in BseqI2')
    96 apply clarify
    97 apply (drule_tac x="n - k" in spec, simp)
    98 done
    99 
   100 
   101 subsection {* Sequences That Converge to Zero *}
   102 
   103 lemma ZseqI:
   104   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   105 unfolding Zseq_def by simp
   106 
   107 lemma ZseqD:
   108   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   109 unfolding Zseq_def by simp
   110 
   111 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   112 unfolding Zseq_def by simp
   113 
   114 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   115 unfolding Zseq_def by force
   116 
   117 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   118 unfolding Zseq_def by simp
   119 
   120 lemma Zseq_imp_Zseq:
   121   assumes X: "Zseq X"
   122   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   123   shows "Zseq (\<lambda>n. Y n)"
   124 proof (cases)
   125   assume K: "0 < K"
   126   show ?thesis
   127   proof (rule ZseqI)
   128     fix r::real assume "0 < r"
   129     hence "0 < r / K"
   130       using K by (rule divide_pos_pos)
   131     then obtain N where "\<forall>n\<ge>N. norm (X n) < r / K"
   132       using ZseqD [OF X] by fast
   133     hence "\<forall>n\<ge>N. norm (X n) * K < r"
   134       by (simp add: pos_less_divide_eq K)
   135     hence "\<forall>n\<ge>N. norm (Y n) < r"
   136       by (simp add: order_le_less_trans [OF Y])
   137     thus "\<exists>N. \<forall>n\<ge>N. norm (Y n) < r" ..
   138   qed
   139 next
   140   assume "\<not> 0 < K"
   141   hence K: "K \<le> 0" by (simp only: linorder_not_less)
   142   {
   143     fix n::nat
   144     have "norm (Y n) \<le> norm (X n) * K" by (rule Y)
   145     also have "\<dots> \<le> norm (X n) * 0"
   146       using K norm_ge_zero by (rule mult_left_mono)
   147     finally have "norm (Y n) = 0" by simp
   148   }
   149   thus ?thesis by (simp add: Zseq_zero)
   150 qed
   151 
   152 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   153 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   154 
   155 lemma Zseq_add:
   156   assumes X: "Zseq X"
   157   assumes Y: "Zseq Y"
   158   shows "Zseq (\<lambda>n. X n + Y n)"
   159 proof (rule ZseqI)
   160   fix r::real assume "0 < r"
   161   hence r: "0 < r / 2" by simp
   162   obtain M where M: "\<forall>n\<ge>M. norm (X n) < r/2"
   163     using ZseqD [OF X r] by fast
   164   obtain N where N: "\<forall>n\<ge>N. norm (Y n) < r/2"
   165     using ZseqD [OF Y r] by fast
   166   show "\<exists>N. \<forall>n\<ge>N. norm (X n + Y n) < r"
   167   proof (intro exI allI impI)
   168     fix n assume n: "max M N \<le> n"
   169     have "norm (X n + Y n) \<le> norm (X n) + norm (Y n)"
   170       by (rule norm_triangle_ineq)
   171     also have "\<dots> < r/2 + r/2"
   172     proof (rule add_strict_mono)
   173       from M n show "norm (X n) < r/2" by simp
   174       from N n show "norm (Y n) < r/2" by simp
   175     qed
   176     finally show "norm (X n + Y n) < r" by simp
   177   qed
   178 qed
   179 
   180 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   181 unfolding Zseq_def by simp
   182 
   183 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   184 by (simp only: diff_minus Zseq_add Zseq_minus)
   185 
   186 lemma (in bounded_linear) Zseq:
   187   assumes X: "Zseq X"
   188   shows "Zseq (\<lambda>n. f (X n))"
   189 proof -
   190   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   191     using bounded by fast
   192   with X show ?thesis
   193     by (rule Zseq_imp_Zseq)
   194 qed
   195 
   196 lemma (in bounded_bilinear) Zseq:
   197   assumes X: "Zseq X"
   198   assumes Y: "Zseq Y"
   199   shows "Zseq (\<lambda>n. X n ** Y n)"
   200 proof (rule ZseqI)
   201   fix r::real assume r: "0 < r"
   202   obtain K where K: "0 < K"
   203     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   204     using pos_bounded by fast
   205   from K have K': "0 < inverse K"
   206     by (rule positive_imp_inverse_positive)
   207   obtain M where M: "\<forall>n\<ge>M. norm (X n) < r"
   208     using ZseqD [OF X r] by fast
   209   obtain N where N: "\<forall>n\<ge>N. norm (Y n) < inverse K"
   210     using ZseqD [OF Y K'] by fast
   211   show "\<exists>N. \<forall>n\<ge>N. norm (X n ** Y n) < r"
   212   proof (intro exI allI impI)
   213     fix n assume n: "max M N \<le> n"
   214     have "norm (X n ** Y n) \<le> norm (X n) * norm (Y n) * K"
   215       by (rule norm_le)
   216     also have "norm (X n) * norm (Y n) * K < r * inverse K * K"
   217     proof (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero K)
   218       from M n show Xn: "norm (X n) < r" by simp
   219       from N n show Yn: "norm (Y n) < inverse K" by simp
   220     qed
   221     also from K have "r * inverse K * K = r" by simp
   222     finally show "norm (X n ** Y n) < r" .
   223   qed
   224 qed
   225 
   226 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   227   assumes X: "Zseq X"
   228   assumes Y: "Bseq Y"
   229   shows "Zseq (\<lambda>n. X n ** Y n)"
   230 proof -
   231   obtain K where K: "0 \<le> K"
   232     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   233     using nonneg_bounded by fast
   234   obtain B where B: "0 < B"
   235     and norm_Y: "\<And>n. norm (Y n) \<le> B"
   236     using Y [unfolded Bseq_def] by fast
   237   from X show ?thesis
   238   proof (rule Zseq_imp_Zseq)
   239     fix n::nat
   240     have "norm (X n ** Y n) \<le> norm (X n) * norm (Y n) * K"
   241       by (rule norm_le)
   242     also have "\<dots> \<le> norm (X n) * B * K"
   243       by (intro mult_mono' order_refl norm_Y norm_ge_zero
   244                 mult_nonneg_nonneg K)
   245     also have "\<dots> = norm (X n) * (B * K)"
   246       by (rule mult_assoc)
   247     finally show "norm (X n ** Y n) \<le> norm (X n) * (B * K)" .
   248   qed
   249 qed
   250 
   251 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   252   assumes X: "Bseq X"
   253   assumes Y: "Zseq Y"
   254   shows "Zseq (\<lambda>n. X n ** Y n)"
   255 proof -
   256   obtain K where K: "0 \<le> K"
   257     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   258     using nonneg_bounded by fast
   259   obtain B where B: "0 < B"
   260     and norm_X: "\<And>n. norm (X n) \<le> B"
   261     using X [unfolded Bseq_def] by fast
   262   from Y show ?thesis
   263   proof (rule Zseq_imp_Zseq)
   264     fix n::nat
   265     have "norm (X n ** Y n) \<le> norm (X n) * norm (Y n) * K"
   266       by (rule norm_le)
   267     also have "\<dots> \<le> B * norm (Y n) * K"
   268       by (intro mult_mono' order_refl norm_X norm_ge_zero
   269                 mult_nonneg_nonneg K)
   270     also have "\<dots> = norm (Y n) * (B * K)"
   271       by (simp only: mult_ac)
   272     finally show "norm (X n ** Y n) \<le> norm (Y n) * (B * K)" .
   273   qed
   274 qed
   275 
   276 lemma (in bounded_bilinear) Zseq_left:
   277   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   278 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   279 
   280 lemma (in bounded_bilinear) Zseq_right:
   281   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   282 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   283 
   284 lemmas Zseq_mult = mult.Zseq
   285 lemmas Zseq_mult_right = mult.Zseq_right
   286 lemmas Zseq_mult_left = mult.Zseq_left
   287 
   288 
   289 subsection {* Limits of Sequences *}
   290 
   291 lemma LIMSEQ_iff:
   292       "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   293 by (rule LIMSEQ_def)
   294 
   295 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   296 by (simp only: LIMSEQ_def Zseq_def)
   297 
   298 lemma LIMSEQ_I:
   299   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   300 by (simp add: LIMSEQ_def)
   301 
   302 lemma LIMSEQ_D:
   303   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   304 by (simp add: LIMSEQ_def)
   305 
   306 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   307 by (simp add: LIMSEQ_def)
   308 
   309 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l = (k = l)"
   310 by (simp add: LIMSEQ_Zseq_iff Zseq_const_iff)
   311 
   312 lemma LIMSEQ_norm: "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   313 apply (simp add: LIMSEQ_def, safe)
   314 apply (drule_tac x="r" in spec, safe)
   315 apply (rule_tac x="no" in exI, safe)
   316 apply (drule_tac x="n" in spec, safe)
   317 apply (erule order_le_less_trans [OF norm_triangle_ineq3])
   318 done
   319 
   320 lemma LIMSEQ_ignore_initial_segment:
   321   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   322 apply (rule LIMSEQ_I)
   323 apply (drule (1) LIMSEQ_D)
   324 apply (erule exE, rename_tac N)
   325 apply (rule_tac x=N in exI)
   326 apply simp
   327 done
   328 
   329 lemma LIMSEQ_offset:
   330   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   331 apply (rule LIMSEQ_I)
   332 apply (drule (1) LIMSEQ_D)
   333 apply (erule exE, rename_tac N)
   334 apply (rule_tac x="N + k" in exI)
   335 apply clarify
   336 apply (drule_tac x="n - k" in spec)
   337 apply (simp add: le_diff_conv2)
   338 done
   339 
   340 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   341 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   342 
   343 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   344 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   345 
   346 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   347 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   348 
   349 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   350   unfolding LIMSEQ_def
   351   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   352 
   353 
   354 lemma add_diff_add:
   355   fixes a b c d :: "'a::ab_group_add"
   356   shows "(a + c) - (b + d) = (a - b) + (c - d)"
   357 by simp
   358 
   359 lemma minus_diff_minus:
   360   fixes a b :: "'a::ab_group_add"
   361   shows "(- a) - (- b) = - (a - b)"
   362 by simp
   363 
   364 lemma LIMSEQ_add: "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   365 by (simp only: LIMSEQ_Zseq_iff add_diff_add Zseq_add)
   366 
   367 lemma LIMSEQ_minus: "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   368 by (simp only: LIMSEQ_Zseq_iff minus_diff_minus Zseq_minus)
   369 
   370 lemma LIMSEQ_minus_cancel: "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   371 by (drule LIMSEQ_minus, simp)
   372 
   373 lemma LIMSEQ_diff: "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   374 by (simp add: diff_minus LIMSEQ_add LIMSEQ_minus)
   375 
   376 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   377 by (drule (1) LIMSEQ_diff, simp add: LIMSEQ_const_iff)
   378 
   379 lemma (in bounded_linear) LIMSEQ:
   380   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   381 by (simp only: LIMSEQ_Zseq_iff diff [symmetric] Zseq)
   382 
   383 lemma (in bounded_bilinear) LIMSEQ:
   384   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   385 by (simp only: LIMSEQ_Zseq_iff prod_diff_prod
   386                Zseq_add Zseq Zseq_left Zseq_right)
   387 
   388 lemma LIMSEQ_mult:
   389   fixes a b :: "'a::real_normed_algebra"
   390   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   391 by (rule mult.LIMSEQ)
   392 
   393 lemma inverse_diff_inverse:
   394   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
   395    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   396 by (simp add: algebra_simps)
   397 
   398 lemma Bseq_inverse_lemma:
   399   fixes x :: "'a::real_normed_div_algebra"
   400   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   401 apply (subst nonzero_norm_inverse, clarsimp)
   402 apply (erule (1) le_imp_inverse_le)
   403 done
   404 
   405 lemma Bseq_inverse:
   406   fixes a :: "'a::real_normed_div_algebra"
   407   assumes X: "X ----> a"
   408   assumes a: "a \<noteq> 0"
   409   shows "Bseq (\<lambda>n. inverse (X n))"
   410 proof -
   411   from a have "0 < norm a" by simp
   412   hence "\<exists>r>0. r < norm a" by (rule dense)
   413   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   414   obtain N where N: "\<And>n. N \<le> n \<Longrightarrow> norm (X n - a) < r"
   415     using LIMSEQ_D [OF X r1] by fast
   416   show ?thesis
   417   proof (rule BseqI2' [rule_format])
   418     fix n assume n: "N \<le> n"
   419     hence 1: "norm (X n - a) < r" by (rule N)
   420     hence 2: "X n \<noteq> 0" using r2 by auto
   421     hence "norm (inverse (X n)) = inverse (norm (X n))"
   422       by (rule nonzero_norm_inverse)
   423     also have "\<dots> \<le> inverse (norm a - r)"
   424     proof (rule le_imp_inverse_le)
   425       show "0 < norm a - r" using r2 by simp
   426     next
   427       have "norm a - norm (X n) \<le> norm (a - X n)"
   428         by (rule norm_triangle_ineq2)
   429       also have "\<dots> = norm (X n - a)"
   430         by (rule norm_minus_commute)
   431       also have "\<dots> < r" using 1 .
   432       finally show "norm a - r \<le> norm (X n)" by simp
   433     qed
   434     finally show "norm (inverse (X n)) \<le> inverse (norm a - r)" .
   435   qed
   436 qed
   437 
   438 lemma LIMSEQ_inverse_lemma:
   439   fixes a :: "'a::real_normed_div_algebra"
   440   shows "\<lbrakk>X ----> a; a \<noteq> 0; \<forall>n. X n \<noteq> 0\<rbrakk>
   441          \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   442 apply (subst LIMSEQ_Zseq_iff)
   443 apply (simp add: inverse_diff_inverse nonzero_imp_inverse_nonzero)
   444 apply (rule Zseq_minus)
   445 apply (rule Zseq_mult_left)
   446 apply (rule mult.Bseq_prod_Zseq)
   447 apply (erule (1) Bseq_inverse)
   448 apply (simp add: LIMSEQ_Zseq_iff)
   449 done
   450 
   451 lemma LIMSEQ_inverse:
   452   fixes a :: "'a::real_normed_div_algebra"
   453   assumes X: "X ----> a"
   454   assumes a: "a \<noteq> 0"
   455   shows "(\<lambda>n. inverse (X n)) ----> inverse a"
   456 proof -
   457   from a have "0 < norm a" by simp
   458   then obtain k where "\<forall>n\<ge>k. norm (X n - a) < norm a"
   459     using LIMSEQ_D [OF X] by fast
   460   hence "\<forall>n\<ge>k. X n \<noteq> 0" by auto
   461   hence k: "\<forall>n. X (n + k) \<noteq> 0" by simp
   462 
   463   from X have "(\<lambda>n. X (n + k)) ----> a"
   464     by (rule LIMSEQ_ignore_initial_segment)
   465   hence "(\<lambda>n. inverse (X (n + k))) ----> inverse a"
   466     using a k by (rule LIMSEQ_inverse_lemma)
   467   thus "(\<lambda>n. inverse (X n)) ----> inverse a"
   468     by (rule LIMSEQ_offset)
   469 qed
   470 
   471 lemma LIMSEQ_divide:
   472   fixes a b :: "'a::real_normed_field"
   473   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   474 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   475 
   476 lemma LIMSEQ_pow:
   477   fixes a :: "'a::{real_normed_algebra,recpower}"
   478   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   479 by (induct m) (simp_all add: power_Suc LIMSEQ_const LIMSEQ_mult)
   480 
   481 lemma LIMSEQ_setsum:
   482   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   483   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   484 proof (cases "finite S")
   485   case True
   486   thus ?thesis using n
   487   proof (induct)
   488     case empty
   489     show ?case
   490       by (simp add: LIMSEQ_const)
   491   next
   492     case insert
   493     thus ?case
   494       by (simp add: LIMSEQ_add)
   495   qed
   496 next
   497   case False
   498   thus ?thesis
   499     by (simp add: LIMSEQ_const)
   500 qed
   501 
   502 lemma LIMSEQ_setprod:
   503   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   504   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   505   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   506 proof (cases "finite S")
   507   case True
   508   thus ?thesis using n
   509   proof (induct)
   510     case empty
   511     show ?case
   512       by (simp add: LIMSEQ_const)
   513   next
   514     case insert
   515     thus ?case
   516       by (simp add: LIMSEQ_mult)
   517   qed
   518 next
   519   case False
   520   thus ?thesis
   521     by (simp add: setprod_def LIMSEQ_const)
   522 qed
   523 
   524 lemma LIMSEQ_add_const: "f ----> a ==> (%n.(f n + b)) ----> a + b"
   525 by (simp add: LIMSEQ_add LIMSEQ_const)
   526 
   527 (* FIXME: delete *)
   528 lemma LIMSEQ_add_minus:
   529      "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   530 by (simp only: LIMSEQ_add LIMSEQ_minus)
   531 
   532 lemma LIMSEQ_diff_const: "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   533 by (simp add: LIMSEQ_diff LIMSEQ_const)
   534 
   535 lemma LIMSEQ_diff_approach_zero: 
   536   "g ----> L ==> (%x. f x - g x) ----> 0  ==>
   537      f ----> L"
   538   apply (drule LIMSEQ_add)
   539   apply assumption
   540   apply simp
   541 done
   542 
   543 lemma LIMSEQ_diff_approach_zero2: 
   544   "f ----> L ==> (%x. f x - g x) ----> 0  ==>
   545      g ----> L";
   546   apply (drule LIMSEQ_diff)
   547   apply assumption
   548   apply simp
   549 done
   550 
   551 text{*A sequence tends to zero iff its abs does*}
   552 lemma LIMSEQ_norm_zero: "((\<lambda>n. norm (X n)) ----> 0) = (X ----> 0)"
   553 by (simp add: LIMSEQ_def)
   554 
   555 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   556 by (simp add: LIMSEQ_def)
   557 
   558 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   559 by (drule LIMSEQ_norm, simp)
   560 
   561 text{*An unbounded sequence's inverse tends to 0*}
   562 
   563 lemma LIMSEQ_inverse_zero:
   564   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   565 apply (rule LIMSEQ_I)
   566 apply (drule_tac x="inverse r" in spec, safe)
   567 apply (rule_tac x="N" in exI, safe)
   568 apply (drule_tac x="n" in spec, safe)
   569 apply (frule positive_imp_inverse_positive)
   570 apply (frule (1) less_imp_inverse_less)
   571 apply (subgoal_tac "0 < X n", simp)
   572 apply (erule (1) order_less_trans)
   573 done
   574 
   575 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   576 
   577 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   578 apply (rule LIMSEQ_inverse_zero, safe)
   579 apply (cut_tac x = r in reals_Archimedean2)
   580 apply (safe, rule_tac x = n in exI)
   581 apply (auto simp add: real_of_nat_Suc)
   582 done
   583 
   584 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   585 infinity is now easily proved*}
   586 
   587 lemma LIMSEQ_inverse_real_of_nat_add:
   588      "(%n. r + inverse(real(Suc n))) ----> r"
   589 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   590 
   591 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   592      "(%n. r + -inverse(real(Suc n))) ----> r"
   593 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   594 
   595 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   596      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   597 by (cut_tac b=1 in
   598         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   599 
   600 lemma LIMSEQ_le_const:
   601   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   602 apply (rule ccontr, simp only: linorder_not_le)
   603 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   604 apply clarsimp
   605 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   606 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   607 apply simp
   608 done
   609 
   610 lemma LIMSEQ_le_const2:
   611   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   612 apply (subgoal_tac "- a \<le> - x", simp)
   613 apply (rule LIMSEQ_le_const)
   614 apply (erule LIMSEQ_minus)
   615 apply simp
   616 done
   617 
   618 lemma LIMSEQ_le:
   619   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   620 apply (subgoal_tac "0 \<le> y - x", simp)
   621 apply (rule LIMSEQ_le_const)
   622 apply (erule (1) LIMSEQ_diff)
   623 apply (simp add: le_diff_eq)
   624 done
   625 
   626 
   627 subsection {* Convergence *}
   628 
   629 lemma limI: "X ----> L ==> lim X = L"
   630 apply (simp add: lim_def)
   631 apply (blast intro: LIMSEQ_unique)
   632 done
   633 
   634 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   635 by (simp add: convergent_def)
   636 
   637 lemma convergentI: "(X ----> L) ==> convergent X"
   638 by (auto simp add: convergent_def)
   639 
   640 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   641 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   642 
   643 lemma convergent_minus_iff: "(convergent X) = (convergent (%n. -(X n)))"
   644 apply (simp add: convergent_def)
   645 apply (auto dest: LIMSEQ_minus)
   646 apply (drule LIMSEQ_minus, auto)
   647 done
   648 
   649 
   650 subsection {* Bounded Monotonic Sequences *}
   651 
   652 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   653 
   654 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   655 apply (simp add: subseq_def)
   656 apply (auto dest!: less_imp_Suc_add)
   657 apply (induct_tac k)
   658 apply (auto intro: less_trans)
   659 done
   660 
   661 lemma monoseq_Suc:
   662    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   663                  | (\<forall>n. X (Suc n) \<le> X n))"
   664 apply (simp add: monoseq_def)
   665 apply (auto dest!: le_imp_less_or_eq)
   666 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   667 apply (induct_tac "ka")
   668 apply (auto intro: order_trans)
   669 apply (erule contrapos_np)
   670 apply (induct_tac "k")
   671 apply (auto intro: order_trans)
   672 done
   673 
   674 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   675 by (simp add: monoseq_def)
   676 
   677 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   678 by (simp add: monoseq_def)
   679 
   680 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   681 by (simp add: monoseq_Suc)
   682 
   683 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   684 by (simp add: monoseq_Suc)
   685 
   686 lemma monoseq_minus: assumes "monoseq a"
   687   shows "monoseq (\<lambda> n. - a n)"
   688 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   689   case True
   690   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   691   thus ?thesis by (rule monoI2)
   692 next
   693   case False
   694   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   695   thus ?thesis by (rule monoI1)
   696 qed
   697 
   698 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   699   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   700          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   701 proof -
   702   { fix x n fix a :: "nat \<Rightarrow> real"
   703     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   704     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   705     have "a n \<le> x"
   706     proof (rule ccontr)
   707       assume "\<not> a n \<le> x" hence "x < a n" by auto
   708       hence "0 < a n - x" by auto
   709       from `a ----> x`[THEN LIMSEQ_D, OF this]
   710       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   711       hence "norm (a (max no n) - x) < a n - x" by auto
   712       moreover
   713       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   714       hence "x < a (max no n)" by auto
   715       ultimately
   716       have "a (max no n) < a n" by auto
   717       with monotone[where m=n and n="max no n"]
   718       show False by auto
   719     qed
   720   } note top_down = this
   721   { fix x n m fix a :: "nat \<Rightarrow> real"
   722     assume "a ----> x" and "monoseq a" and "a m < x"
   723     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   724     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   725       case True with top_down and `a ----> x` show ?thesis by auto
   726     next
   727       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   728       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   729       hence False using `a m < x` by auto
   730       thus ?thesis ..
   731     qed
   732   } note when_decided = this
   733 
   734   show ?thesis
   735   proof (cases "\<exists> m. a m \<noteq> x")
   736     case True then obtain m where "a m \<noteq> x" by auto
   737     show ?thesis
   738     proof (cases "a m < x")
   739       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   740       show ?thesis by blast
   741     next
   742       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   743       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   744       show ?thesis by auto
   745     qed
   746   qed auto
   747 qed
   748 
   749 text{*Bounded Sequence*}
   750 
   751 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   752 by (simp add: Bseq_def)
   753 
   754 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   755 by (auto simp add: Bseq_def)
   756 
   757 lemma lemma_NBseq_def:
   758      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   759       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   760 apply auto
   761  prefer 2 apply force
   762 apply (cut_tac x = K in reals_Archimedean2, clarify)
   763 apply (rule_tac x = n in exI, clarify)
   764 apply (drule_tac x = na in spec)
   765 apply (auto simp add: real_of_nat_Suc)
   766 done
   767 
   768 text{* alternative definition for Bseq *}
   769 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   770 apply (simp add: Bseq_def)
   771 apply (simp (no_asm) add: lemma_NBseq_def)
   772 done
   773 
   774 lemma lemma_NBseq_def2:
   775      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   776 apply (subst lemma_NBseq_def, auto)
   777 apply (rule_tac x = "Suc N" in exI)
   778 apply (rule_tac [2] x = N in exI)
   779 apply (auto simp add: real_of_nat_Suc)
   780  prefer 2 apply (blast intro: order_less_imp_le)
   781 apply (drule_tac x = n in spec, simp)
   782 done
   783 
   784 (* yet another definition for Bseq *)
   785 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   786 by (simp add: Bseq_def lemma_NBseq_def2)
   787 
   788 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   789 
   790 lemma Bseq_isUb:
   791   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   792 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   793 
   794 
   795 text{* Use completeness of reals (supremum property)
   796    to show that any bounded sequence has a least upper bound*}
   797 
   798 lemma Bseq_isLub:
   799   "!!(X::nat=>real). Bseq X ==>
   800    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   801 by (blast intro: reals_complete Bseq_isUb)
   802 
   803 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   804 
   805 lemma lemma_converg1:
   806      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   807                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   808                |] ==> \<forall>n \<ge> ma. X n = X ma"
   809 apply safe
   810 apply (drule_tac y = "X n" in isLubD2)
   811 apply (blast dest: order_antisym)+
   812 done
   813 
   814 text{* The best of both worlds: Easier to prove this result as a standard
   815    theorem and then use equivalence to "transfer" it into the
   816    equivalent nonstandard form if needed!*}
   817 
   818 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   819 apply (simp add: LIMSEQ_def)
   820 apply (rule_tac x = "X m" in exI, safe)
   821 apply (rule_tac x = m in exI, safe)
   822 apply (drule spec, erule impE, auto)
   823 done
   824 
   825 lemma lemma_converg2:
   826    "!!(X::nat=>real).
   827     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   828 apply safe
   829 apply (drule_tac y = "X m" in isLubD2)
   830 apply (auto dest!: order_le_imp_less_or_eq)
   831 done
   832 
   833 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   834 by (rule setleI [THEN isUbI], auto)
   835 
   836 text{* FIXME: @{term "U - T < U"} is redundant *}
   837 lemma lemma_converg4: "!!(X::nat=> real).
   838                [| \<forall>m. X m ~= U;
   839                   isLub UNIV {x. \<exists>n. X n = x} U;
   840                   0 < T;
   841                   U + - T < U
   842                |] ==> \<exists>m. U + -T < X m & X m < U"
   843 apply (drule lemma_converg2, assumption)
   844 apply (rule ccontr, simp)
   845 apply (simp add: linorder_not_less)
   846 apply (drule lemma_converg3)
   847 apply (drule isLub_le_isUb, assumption)
   848 apply (auto dest: order_less_le_trans)
   849 done
   850 
   851 text{*A standard proof of the theorem for monotone increasing sequence*}
   852 
   853 lemma Bseq_mono_convergent:
   854      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   855 apply (simp add: convergent_def)
   856 apply (frule Bseq_isLub, safe)
   857 apply (case_tac "\<exists>m. X m = U", auto)
   858 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   859 (* second case *)
   860 apply (rule_tac x = U in exI)
   861 apply (subst LIMSEQ_iff, safe)
   862 apply (frule lemma_converg2, assumption)
   863 apply (drule lemma_converg4, auto)
   864 apply (rule_tac x = m in exI, safe)
   865 apply (subgoal_tac "X m \<le> X n")
   866  prefer 2 apply blast
   867 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   868 done
   869 
   870 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   871 by (simp add: Bseq_def)
   872 
   873 text{*Main monotonicity theorem*}
   874 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   875 apply (simp add: monoseq_def, safe)
   876 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   877 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   878 apply (auto intro!: Bseq_mono_convergent)
   879 done
   880 
   881 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   882 
   883 text{*alternative formulation for boundedness*}
   884 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   885 apply (unfold Bseq_def, safe)
   886 apply (rule_tac [2] x = "k + norm x" in exI)
   887 apply (rule_tac x = K in exI, simp)
   888 apply (rule exI [where x = 0], auto)
   889 apply (erule order_less_le_trans, simp)
   890 apply (drule_tac x=n in spec, fold diff_def)
   891 apply (drule order_trans [OF norm_triangle_ineq2])
   892 apply simp
   893 done
   894 
   895 text{*alternative formulation for boundedness*}
   896 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   897 apply safe
   898 apply (simp add: Bseq_def, safe)
   899 apply (rule_tac x = "K + norm (X N)" in exI)
   900 apply auto
   901 apply (erule order_less_le_trans, simp)
   902 apply (rule_tac x = N in exI, safe)
   903 apply (drule_tac x = n in spec)
   904 apply (rule order_trans [OF norm_triangle_ineq], simp)
   905 apply (auto simp add: Bseq_iff2)
   906 done
   907 
   908 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   909 apply (simp add: Bseq_def)
   910 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   911 apply (drule_tac x = n in spec, arith)
   912 done
   913 
   914 
   915 subsection {* Cauchy Sequences *}
   916 
   917 lemma CauchyI:
   918   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
   919 by (simp add: Cauchy_def)
   920 
   921 lemma CauchyD:
   922   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
   923 by (simp add: Cauchy_def)
   924 
   925 subsubsection {* Cauchy Sequences are Bounded *}
   926 
   927 text{*A Cauchy sequence is bounded -- this is the standard
   928   proof mechanization rather than the nonstandard proof*}
   929 
   930 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
   931           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
   932 apply (clarify, drule spec, drule (1) mp)
   933 apply (simp only: norm_minus_commute)
   934 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
   935 apply simp
   936 done
   937 
   938 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
   939 apply (simp add: Cauchy_def)
   940 apply (drule spec, drule mp, rule zero_less_one, safe)
   941 apply (drule_tac x="M" in spec, simp)
   942 apply (drule lemmaCauchy)
   943 apply (rule_tac k="M" in Bseq_offset)
   944 apply (simp add: Bseq_def)
   945 apply (rule_tac x="1 + norm (X M)" in exI)
   946 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
   947 apply (simp add: order_less_imp_le)
   948 done
   949 
   950 subsubsection {* Cauchy Sequences are Convergent *}
   951 
   952 axclass banach \<subseteq> real_normed_vector
   953   Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
   954 
   955 theorem LIMSEQ_imp_Cauchy:
   956   assumes X: "X ----> a" shows "Cauchy X"
   957 proof (rule CauchyI)
   958   fix e::real assume "0 < e"
   959   hence "0 < e/2" by simp
   960   with X have "\<exists>N. \<forall>n\<ge>N. norm (X n - a) < e/2" by (rule LIMSEQ_D)
   961   then obtain N where N: "\<forall>n\<ge>N. norm (X n - a) < e/2" ..
   962   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < e"
   963   proof (intro exI allI impI)
   964     fix m assume "N \<le> m"
   965     hence m: "norm (X m - a) < e/2" using N by fast
   966     fix n assume "N \<le> n"
   967     hence n: "norm (X n - a) < e/2" using N by fast
   968     have "norm (X m - X n) = norm ((X m - a) - (X n - a))" by simp
   969     also have "\<dots> \<le> norm (X m - a) + norm (X n - a)"
   970       by (rule norm_triangle_ineq4)
   971     also from m n have "\<dots> < e" by(simp add:field_simps)
   972     finally show "norm (X m - X n) < e" .
   973   qed
   974 qed
   975 
   976 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
   977 unfolding convergent_def
   978 by (erule exE, erule LIMSEQ_imp_Cauchy)
   979 
   980 text {*
   981 Proof that Cauchy sequences converge based on the one from
   982 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
   983 *}
   984 
   985 text {*
   986   If sequence @{term "X"} is Cauchy, then its limit is the lub of
   987   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
   988 *}
   989 
   990 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
   991 by (simp add: isUbI setleI)
   992 
   993 lemma real_abs_diff_less_iff:
   994   "(\<bar>x - a\<bar> < (r::real)) = (a - r < x \<and> x < a + r)"
   995 by auto
   996 
   997 locale real_Cauchy =
   998   fixes X :: "nat \<Rightarrow> real"
   999   assumes X: "Cauchy X"
  1000   fixes S :: "real set"
  1001   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1002 
  1003 lemma real_CauchyI:
  1004   assumes "Cauchy X"
  1005   shows "real_Cauchy X"
  1006   proof qed (fact assms)
  1007 
  1008 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1009 by (unfold S_def, auto)
  1010 
  1011 lemma (in real_Cauchy) bound_isUb:
  1012   assumes N: "\<forall>n\<ge>N. X n < x"
  1013   shows "isUb UNIV S x"
  1014 proof (rule isUb_UNIV_I)
  1015   fix y::real assume "y \<in> S"
  1016   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1017     by (simp add: S_def)
  1018   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1019   hence "y < X (max M N)" by simp
  1020   also have "\<dots> < x" using N by simp
  1021   finally show "y \<le> x"
  1022     by (rule order_less_imp_le)
  1023 qed
  1024 
  1025 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1026 proof (rule reals_complete)
  1027   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1028     using CauchyD [OF X zero_less_one] by fast
  1029   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1030   show "\<exists>x. x \<in> S"
  1031   proof
  1032     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1033       by (simp add: real_abs_diff_less_iff)
  1034     thus "X N - 1 \<in> S" by (rule mem_S)
  1035   qed
  1036   show "\<exists>u. isUb UNIV S u"
  1037   proof
  1038     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1039       by (simp add: real_abs_diff_less_iff)
  1040     thus "isUb UNIV S (X N + 1)"
  1041       by (rule bound_isUb)
  1042   qed
  1043 qed
  1044 
  1045 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1046   assumes x: "isLub UNIV S x"
  1047   shows "X ----> x"
  1048 proof (rule LIMSEQ_I)
  1049   fix r::real assume "0 < r"
  1050   hence r: "0 < r/2" by simp
  1051   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1052     using CauchyD [OF X r] by fast
  1053   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1054   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1055     by (simp only: real_norm_def real_abs_diff_less_iff)
  1056 
  1057   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1058   hence "X N - r/2 \<in> S" by (rule mem_S)
  1059   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1060 
  1061   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1062   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1063   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1064 
  1065   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1066   proof (intro exI allI impI)
  1067     fix n assume n: "N \<le> n"
  1068     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1069     thus "norm (X n - x) < r" using 1 2
  1070       by (simp add: real_abs_diff_less_iff)
  1071   qed
  1072 qed
  1073 
  1074 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1075 proof -
  1076   obtain x where "isLub UNIV S x"
  1077     using isLub_ex by fast
  1078   hence "X ----> x"
  1079     by (rule isLub_imp_LIMSEQ)
  1080   thus ?thesis ..
  1081 qed
  1082 
  1083 lemma real_Cauchy_convergent:
  1084   fixes X :: "nat \<Rightarrow> real"
  1085   shows "Cauchy X \<Longrightarrow> convergent X"
  1086 unfolding convergent_def
  1087 by (rule real_Cauchy.LIMSEQ_ex)
  1088  (rule real_CauchyI)
  1089 
  1090 instance real :: banach
  1091 by intro_classes (rule real_Cauchy_convergent)
  1092 
  1093 lemma Cauchy_convergent_iff:
  1094   fixes X :: "nat \<Rightarrow> 'a::banach"
  1095   shows "Cauchy X = convergent X"
  1096 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1097 
  1098 
  1099 subsection {* Power Sequences *}
  1100 
  1101 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1102 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1103   also fact that bounded and monotonic sequence converges.*}
  1104 
  1105 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1106 apply (simp add: Bseq_def)
  1107 apply (rule_tac x = 1 in exI)
  1108 apply (simp add: power_abs)
  1109 apply (auto dest: power_mono)
  1110 done
  1111 
  1112 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1113 apply (clarify intro!: mono_SucI2)
  1114 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1115 done
  1116 
  1117 lemma convergent_realpow:
  1118   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1119 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1120 
  1121 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1122   fixes x :: real
  1123   assumes x: "0 \<le> x"
  1124   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1125 apply (induct n)
  1126 apply simp
  1127 apply simp
  1128 apply (rule order_trans)
  1129 prefer 2
  1130 apply (erule mult_left_mono)
  1131 apply (rule add_increasing [OF x], simp)
  1132 apply (simp add: real_of_nat_Suc)
  1133 apply (simp add: ring_distribs)
  1134 apply (simp add: mult_nonneg_nonneg x)
  1135 done
  1136 
  1137 lemma LIMSEQ_inverse_realpow_zero:
  1138   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1139 proof (rule LIMSEQ_inverse_zero [rule_format])
  1140   fix y :: real
  1141   assume x: "1 < x"
  1142   hence "0 < x - 1" by simp
  1143   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1144     by (rule reals_Archimedean3)
  1145   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1146   then obtain N::nat where "y < real N * (x - 1)" ..
  1147   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1148   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1149     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1150   also have "\<dots> = x ^ N" by simp
  1151   finally have "y < x ^ N" .
  1152   hence "\<forall>n\<ge>N. y < x ^ n"
  1153     apply clarify
  1154     apply (erule order_less_le_trans)
  1155     apply (erule power_increasing)
  1156     apply (rule order_less_imp_le [OF x])
  1157     done
  1158   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1159 qed
  1160 
  1161 lemma LIMSEQ_realpow_zero:
  1162   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1163 proof (cases)
  1164   assume "x = 0"
  1165   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1166   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1167 next
  1168   assume "0 \<le> x" and "x \<noteq> 0"
  1169   hence x0: "0 < x" by simp
  1170   assume x1: "x < 1"
  1171   from x0 x1 have "1 < inverse x"
  1172     by (rule real_inverse_gt_one)
  1173   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1174     by (rule LIMSEQ_inverse_realpow_zero)
  1175   thus ?thesis by (simp add: power_inverse)
  1176 qed
  1177 
  1178 lemma LIMSEQ_power_zero:
  1179   fixes x :: "'a::{real_normed_algebra_1,recpower}"
  1180   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1181 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1182 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1183 apply (simp add: power_abs norm_power_ineq)
  1184 done
  1185 
  1186 lemma LIMSEQ_divide_realpow_zero:
  1187   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1188 apply (cut_tac a = a and x1 = "inverse x" in
  1189         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1190 apply (auto simp add: divide_inverse power_inverse)
  1191 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1192 done
  1193 
  1194 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1195 
  1196 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1197 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1198 
  1199 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1200 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1201 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1202 done
  1203 
  1204 end