src/Provers/splitter.ML
author berghofe
Mon May 06 15:19:50 1996 +0200 (1996-05-06)
changeset 1721 445654b6cb95
parent 1686 c67d543bc395
child 2143 093bbe6d333b
permissions -rw-r--r--
Rewrote mk_cntxt_splitthm. Added function mk_case_split_inside_tac.
     1 (*  Title:      Provers/splitter
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     Copyright   1995  TU Munich
     5 
     6 Generic case-splitter, suitable for most logics.
     7 
     8 Use:
     9 
    10 val split_tac = mk_case_split_tac iffD;
    11 
    12 by(case_split_tac splits i);
    13 
    14 where splits = [P(elim(...)) == rhs, ...]
    15       iffD  = [| P <-> Q; Q |] ==> P (* is called iffD2 in HOL *)
    16 
    17 *)
    18 
    19 local
    20 
    21 fun mk_case_split_tac_2 iffD order =
    22 let
    23 
    24 
    25 (************************************************************
    26    Create lift-theorem "trlift" :
    27 
    28    [| !! x. Q(x)==R(x) ; P(R) == C |] ==> P(Q)==C
    29 
    30 *************************************************************)
    31  
    32 val lift =
    33   let val ct = read_cterm (#sign(rep_thm iffD))
    34            ("[| !!x::'b::logic. Q(x) == R(x) |] ==> \
    35             \P(%x.Q(x)) == P(%x.R(x))::'a::logic",propT)
    36   in prove_goalw_cterm [] ct
    37      (fn [prem] => [rewtac prem, rtac reflexive_thm 1])
    38   end;
    39 
    40 val trlift = lift RS transitive_thm;
    41 val _ $ (Var(P,PT)$_) $ _ = concl_of trlift;
    42 
    43 
    44 (************************************************************************ 
    45    Set up term for instantiation of P in the lift-theorem
    46    
    47    Ts    : types of parameters (i.e. variables bound by meta-quantifiers)
    48    t     : lefthand side of meta-equality in subgoal
    49            the lift theorem is applied to (see select)
    50    pos   : "path" leading to abstraction, coded as a list
    51    T     : type of body of P(...)
    52    maxi  : maximum index of Vars
    53 *************************************************************************)
    54 
    55 fun mk_cntxt Ts t pos T maxi =
    56   let fun var (t,i) = Var(("X",i),type_of1(Ts,t));
    57       fun down [] t i = Bound 0
    58         | down (p::ps) t i =
    59             let val (h,ts) = strip_comb t
    60                 val v1 = map var (take(p,ts) ~~ (i upto (i+p-1)))
    61                 val u::us = drop(p,ts)
    62                 val v2 = map var (us ~~ ((i+p) upto (i+length(ts)-2)))
    63       in list_comb(h,v1@[down ps u (i+length ts)]@v2) end;
    64   in Abs("", T, down (rev pos) t maxi) end;
    65 
    66 
    67 (************************************************************************ 
    68    Set up term for instantiation of P in the split-theorem
    69    P(...) == rhs
    70 
    71    Ts    : types of parameters (i.e. variables bound by meta-quantifiers)
    72    t     : lefthand side of meta-equality in subgoal
    73            the split theorem is applied to (see select)
    74    T     : type of body of P(...)
    75    tt    : the term  Const(..,..) $ ...
    76    maxi  : maximum index of Vars
    77 
    78    lev   : abstraction level
    79 *************************************************************************)
    80 
    81 fun mk_cntxt_splitthm Ts t tt T maxi =
    82   let fun down lev (Abs(v,T2,t)) = Abs(v,T2,down (lev+1) t)
    83         | down lev (Bound i) = if i >= lev
    84                                then Var(("X",maxi+i-lev),nth_elem(i-lev,Ts))
    85                                else Bound i 
    86         | down lev t = 
    87             let val (h,ts) = strip_comb t
    88                 val h2 = (case h of Bound _ => down lev h | _ => h)
    89             in if incr_bv(lev,0,tt)=t 
    90                then
    91                  Bound (lev)
    92                else
    93                  list_comb(h2,map (down lev) ts)
    94             end;
    95   in Abs("",T,down 0 t) end;
    96 
    97 
    98 (* add all loose bound variables in t to list is *)
    99 fun add_lbnos(is,t) = add_loose_bnos(t,0,is);
   100 
   101 (* check if the innermost quantifier that needs to be removed
   102    has a body of type T; otherwise the expansion thm will fail later on
   103 *)
   104 fun type_test(T,lbnos,apsns) =
   105   let val (_,U,_) = nth_elem(min lbnos,apsns)
   106   in T=U end;
   107 
   108 (*************************************************************************
   109    Create a "split_pack".
   110 
   111    thm   : the relevant split-theorem, i.e. P(...) == rhs , where P(...)
   112            is of the form
   113            P( Const(key,...) $ t_1 $ ... $ t_n )      (e.g. key = "if")
   114    T     : type of P(...)
   115    n     : number of arguments expected by Const(key,...)
   116    ts    : list of arguments actually found
   117    apsns : list of tuples of the form (T,U,pos), one tuple for each
   118            abstraction that is encountered on the way to the position where 
   119            Const(key, ...) $ ...  occurs, where
   120            T   : type of the variable bound by the abstraction
   121            U   : type of the abstraction's body
   122            pos : "path" leading to the body of the abstraction
   123    pos   : "path" leading to the position where Const(key, ...) $ ...  occurs.
   124    TB    : type of  Const(key,...) $ t_1 $ ... $ t_n
   125    t     : the term Const(key,...) $ t_1 $ ... $ t_n
   126 
   127    A split pack is a tuple of the form
   128    (thm, apsns, pos, TB)
   129    Note : apsns is reversed, so that the outermost quantifier's position
   130           comes first ! If the terms in ts don't contain variables bound
   131           by other than meta-quantifiers, apsns is empty, because no further
   132           lifting is required before applying the split-theorem.
   133 ******************************************************************************) 
   134 
   135 fun mk_split_pack(thm,T,n,ts,apsns,pos,TB,t) =
   136   if n > length ts then []
   137   else let val lev = length apsns
   138            val lbnos = foldl add_lbnos ([],take(n,ts))
   139            val flbnos = filter (fn i => i < lev) lbnos
   140            val tt = incr_bv(~lev,0,t)
   141        in if null flbnos then [(thm,[],pos,TB,tt)]
   142           else if type_test(T,flbnos,apsns) then [(thm, rev apsns,pos,TB,tt)] else []
   143        end;
   144 
   145 
   146 (****************************************************************************
   147    Recursively scans term for occurences of Const(key,...) $ ...
   148    Returns a list of "split-packs" (one for each occurence of Const(key,...) )
   149 
   150    cmap : association list of split-theorems that should be tried.
   151           The elements have the format (key,(thm,T,n)) , where
   152           key : the theorem's key constant ( Const(key,...) $ ... )
   153           thm : the theorem itself
   154           T   : type of P( Const(key,...) $ ... )
   155           n   : number of arguments expected by Const(key,...)
   156    Ts   : types of parameters
   157    t    : the term to be scanned
   158 ******************************************************************************)
   159 
   160 fun split_posns cmap Ts t =
   161   let fun posns Ts pos apsns (Abs(_,T,t)) =
   162             let val U = fastype_of1(T::Ts,t)
   163             in posns (T::Ts) (0::pos) ((T,U,pos)::apsns) t end
   164         | posns Ts pos apsns t =
   165             let val (h,ts) = strip_comb t
   166                 fun iter((i,a),t) = (i+1, (posns Ts (i::pos) apsns t) @ a);
   167                 val a = case h of
   168                   Const(c,_) =>
   169                     (case assoc(cmap,c) of
   170                        Some(thm,T,n) => mk_split_pack(thm,T,n,ts,apsns,pos,type_of1(Ts,t),t)
   171                      | None => [])
   172                 | _ => []
   173              in snd(foldl iter ((0,a),ts)) end
   174   in posns Ts [] [] t end;
   175 
   176 
   177 fun nth_subgoal i thm = nth_elem(i-1,prems_of thm);
   178 
   179 fun shorter((_,ps,pos,_,_),(_,qs,qos,_,_)) =
   180   let val ms = length ps and ns = length qs
   181   in ms < ns orelse (ms = ns andalso order(length pos,length qos)) end;
   182 
   183 
   184 (************************************************************
   185    call split_posns with appropriate parameters
   186 *************************************************************)
   187 
   188 fun select cmap state i =
   189   let val goali = nth_subgoal i state
   190       val Ts = rev(map #2 (Logic.strip_params goali))
   191       val _ $ t $ _ = Logic.strip_assums_concl goali;
   192   in (Ts,t,sort shorter (split_posns cmap Ts t)) end;
   193 
   194 
   195 (*************************************************************
   196    instantiate lift theorem
   197 
   198    if t is of the form
   199    ... ( Const(...,...) $ Abs( .... ) ) ...
   200    then
   201    P = %a.  ... ( Const(...,...) $ a ) ...
   202    where a has type T --> U
   203 
   204    Ts      : types of parameters
   205    t       : lefthand side of meta-equality in subgoal
   206              the split theorem is applied to (see cmap)
   207    T,U,pos : see mk_split_pack
   208    state   : current proof state
   209    lift    : the lift theorem
   210    i       : no. of subgoal
   211 **************************************************************)
   212 
   213 fun inst_lift Ts t (T,U,pos) state lift i =
   214   let val sg = #sign(rep_thm state)
   215       val tsig = #tsig(Sign.rep_sg sg)
   216       val cntxt = mk_cntxt Ts t pos (T-->U) (#maxidx(rep_thm lift))
   217       val cu = cterm_of sg cntxt
   218       val uT = #T(rep_cterm cu)
   219       val cP' = cterm_of sg (Var(P,uT))
   220       val ixnTs = Type.typ_match tsig ([],(PT,uT));
   221       val ixncTs = map (fn (x,y) => (x,ctyp_of sg y)) ixnTs;
   222   in instantiate (ixncTs, [(cP',cu)]) lift end;
   223 
   224 
   225 (*************************************************************
   226    instantiate split theorem
   227 
   228    Ts    : types of parameters
   229    t     : lefthand side of meta-equality in subgoal
   230            the split theorem is applied to (see cmap)
   231    pos   : "path" to the body of P(...)
   232    thm   : the split theorem
   233    TB    : type of body of P(...)
   234    state : current proof state
   235 **************************************************************)
   236 
   237 fun inst_split Ts t tt thm TB state =
   238   let val _$((Var(P2,PT2))$_)$_ = concl_of thm
   239       val sg = #sign(rep_thm state)
   240       val tsig = #tsig(Sign.rep_sg sg)
   241       val cntxt = mk_cntxt_splitthm Ts t tt TB (#maxidx(rep_thm thm))
   242       val cu = cterm_of sg cntxt
   243       val uT = #T(rep_cterm cu)
   244       val cP' = cterm_of sg (Var(P2,uT))
   245       val ixnTs = Type.typ_match tsig ([],(PT2,uT));
   246       val ixncTs = map (fn (x,y) => (x,ctyp_of sg y)) ixnTs;
   247   in instantiate (ixncTs, [(cP',cu)]) thm end;
   248 
   249 
   250 (*****************************************************************************
   251    The split-tactic
   252    
   253    splits : list of split-theorems to be tried
   254    i      : number of subgoal the tactic should be applied to
   255 *****************************************************************************)
   256 
   257 fun split_tac [] i = no_tac
   258   | split_tac splits i =
   259   let fun const(thm) = let val _$(t as _$lhs)$_ = concl_of thm
   260                            val (Const(a,_),args) = strip_comb lhs
   261                        in (a,(thm,fastype_of t,length args)) end
   262       val cmap = map const splits;
   263       fun lift Ts t p state = rtac (inst_lift Ts t p state trlift i) i
   264       fun lift_split state =
   265             let val (Ts,t,splits) = select cmap state i
   266             in case splits of
   267                  [] => no_tac
   268                | (thm,apsns,pos,TB,tt)::_ =>
   269                    (case apsns of
   270                       [] => STATE(fn state => rtac (inst_split Ts t tt thm TB state) i)
   271                     | p::_ => EVERY[STATE(lift Ts t p),
   272                                     rtac reflexive_thm (i+1),
   273                                     STATE lift_split])
   274             end
   275   in STATE(fn thm =>
   276        if i <= nprems_of thm then rtac iffD i THEN STATE lift_split
   277        else no_tac)
   278   end;
   279 
   280 in split_tac end;
   281 
   282 in
   283 
   284 fun mk_case_split_tac iffD = mk_case_split_tac_2 iffD (op <=) ;
   285 
   286 fun mk_case_split_inside_tac iffD = mk_case_split_tac_2 iffD (op >=) ;
   287 
   288 end;