src/HOL/HOL.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 34991 1adaefa63c5a
child 35364 b8c62d60195c
child 35416 d8d7d1b785af
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/IsaPlanner/zipper.ML"
    12   "~~/src/Tools/IsaPlanner/isand.ML"
    13   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    14   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    15   "~~/src/Tools/intuitionistic.ML"
    16   "~~/src/Tools/project_rule.ML"
    17   "~~/src/Tools/cong_tac.ML"
    18   "~~/src/Provers/hypsubst.ML"
    19   "~~/src/Provers/splitter.ML"
    20   "~~/src/Provers/classical.ML"
    21   "~~/src/Provers/blast.ML"
    22   "~~/src/Provers/clasimp.ML"
    23   "~~/src/Tools/coherent.ML"
    24   "~~/src/Tools/eqsubst.ML"
    25   "~~/src/Provers/quantifier1.ML"
    26   "Tools/res_blacklist.ML"
    27   ("Tools/simpdata.ML")
    28   "~~/src/Tools/random_word.ML"
    29   "~~/src/Tools/atomize_elim.ML"
    30   "~~/src/Tools/induct.ML"
    31   ("~~/src/Tools/induct_tacs.ML")
    32   ("Tools/recfun_codegen.ML")
    33   "~~/src/Tools/more_conv.ML"
    34 begin
    35 
    36 setup {* Intuitionistic.method_setup @{binding iprover} *}
    37 
    38 setup Res_Blacklist.setup
    39 
    40 
    41 subsection {* Primitive logic *}
    42 
    43 subsubsection {* Core syntax *}
    44 
    45 classes type
    46 defaultsort type
    47 setup {* ObjectLogic.add_base_sort @{sort type} *}
    48 
    49 arities
    50   "fun" :: (type, type) type
    51   itself :: (type) type
    52 
    53 global
    54 
    55 typedecl bool
    56 
    57 judgment
    58   Trueprop      :: "bool => prop"                   ("(_)" 5)
    59 
    60 consts
    61   Not           :: "bool => bool"                   ("~ _" [40] 40)
    62   True          :: bool
    63   False         :: bool
    64 
    65   The           :: "('a => bool) => 'a"
    66   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    67   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    68   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    69   Let           :: "['a, 'a => 'b] => 'b"
    70 
    71   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    72   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    73   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    74   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    75 
    76 local
    77 
    78 consts
    79   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    80 
    81 
    82 subsubsection {* Additional concrete syntax *}
    83 
    84 notation (output)
    85   "op ="  (infix "=" 50)
    86 
    87 abbreviation
    88   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    89   "x ~= y == ~ (x = y)"
    90 
    91 notation (output)
    92   not_equal  (infix "~=" 50)
    93 
    94 notation (xsymbols)
    95   Not  ("\<not> _" [40] 40) and
    96   "op &"  (infixr "\<and>" 35) and
    97   "op |"  (infixr "\<or>" 30) and
    98   "op -->"  (infixr "\<longrightarrow>" 25) and
    99   not_equal  (infix "\<noteq>" 50)
   100 
   101 notation (HTML output)
   102   Not  ("\<not> _" [40] 40) and
   103   "op &"  (infixr "\<and>" 35) and
   104   "op |"  (infixr "\<or>" 30) and
   105   not_equal  (infix "\<noteq>" 50)
   106 
   107 abbreviation (iff)
   108   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   109   "A <-> B == A = B"
   110 
   111 notation (xsymbols)
   112   iff  (infixr "\<longleftrightarrow>" 25)
   113 
   114 nonterminals
   115   letbinds  letbind
   116   case_syn  cases_syn
   117 
   118 syntax
   119   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   120 
   121   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   122   ""            :: "letbind => letbinds"                 ("_")
   123   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   124   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   125 
   126   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   127   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   128   ""            :: "case_syn => cases_syn"               ("_")
   129   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   130 
   131 translations
   132   "THE x. P"              == "CONST The (%x. P)"
   133   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   134   "let x = a in e"        == "CONST Let a (%x. e)"
   135 
   136 print_translation {*
   137   [(@{const_syntax The}, fn [Abs abs] =>
   138       let val (x, t) = atomic_abs_tr' abs
   139       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   140 *}  -- {* To avoid eta-contraction of body *}
   141 
   142 syntax (xsymbols)
   143   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   144 
   145 notation (xsymbols)
   146   All  (binder "\<forall>" 10) and
   147   Ex  (binder "\<exists>" 10) and
   148   Ex1  (binder "\<exists>!" 10)
   149 
   150 notation (HTML output)
   151   All  (binder "\<forall>" 10) and
   152   Ex  (binder "\<exists>" 10) and
   153   Ex1  (binder "\<exists>!" 10)
   154 
   155 notation (HOL)
   156   All  (binder "! " 10) and
   157   Ex  (binder "? " 10) and
   158   Ex1  (binder "?! " 10)
   159 
   160 
   161 subsubsection {* Axioms and basic definitions *}
   162 
   163 axioms
   164   refl:           "t = (t::'a)"
   165   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   166   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   167     -- {*Extensionality is built into the meta-logic, and this rule expresses
   168          a related property.  It is an eta-expanded version of the traditional
   169          rule, and similar to the ABS rule of HOL*}
   170 
   171   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   172 
   173   impI:           "(P ==> Q) ==> P-->Q"
   174   mp:             "[| P-->Q;  P |] ==> Q"
   175 
   176 
   177 defs
   178   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   179   All_def:      "All(P)    == (P = (%x. True))"
   180   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   181   False_def:    "False     == (!P. P)"
   182   not_def:      "~ P       == P-->False"
   183   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   184   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   185   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   186 
   187 axioms
   188   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   189   True_or_False:  "(P=True) | (P=False)"
   190 
   191 defs
   192   Let_def [code]: "Let s f == f(s)"
   193   if_def:         "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   194 
   195 finalconsts
   196   "op ="
   197   "op -->"
   198   The
   199 
   200 axiomatization
   201   undefined :: 'a
   202 
   203 class default =
   204   fixes default :: 'a
   205 
   206 
   207 subsection {* Fundamental rules *}
   208 
   209 subsubsection {* Equality *}
   210 
   211 lemma sym: "s = t ==> t = s"
   212   by (erule subst) (rule refl)
   213 
   214 lemma ssubst: "t = s ==> P s ==> P t"
   215   by (drule sym) (erule subst)
   216 
   217 lemma trans: "[| r=s; s=t |] ==> r=t"
   218   by (erule subst)
   219 
   220 lemma meta_eq_to_obj_eq: 
   221   assumes meq: "A == B"
   222   shows "A = B"
   223   by (unfold meq) (rule refl)
   224 
   225 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   226      (* a = b
   227         |   |
   228         c = d   *)
   229 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   230 apply (rule trans)
   231 apply (rule trans)
   232 apply (rule sym)
   233 apply assumption+
   234 done
   235 
   236 text {* For calculational reasoning: *}
   237 
   238 lemma forw_subst: "a = b ==> P b ==> P a"
   239   by (rule ssubst)
   240 
   241 lemma back_subst: "P a ==> a = b ==> P b"
   242   by (rule subst)
   243 
   244 
   245 subsubsection {* Congruence rules for application *}
   246 
   247 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   248 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   249 apply (erule subst)
   250 apply (rule refl)
   251 done
   252 
   253 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   254 lemma arg_cong: "x=y ==> f(x)=f(y)"
   255 apply (erule subst)
   256 apply (rule refl)
   257 done
   258 
   259 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   260 apply (erule ssubst)+
   261 apply (rule refl)
   262 done
   263 
   264 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   265 apply (erule subst)+
   266 apply (rule refl)
   267 done
   268 
   269 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   270 
   271 
   272 subsubsection {* Equality of booleans -- iff *}
   273 
   274 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   275   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   276 
   277 lemma iffD2: "[| P=Q; Q |] ==> P"
   278   by (erule ssubst)
   279 
   280 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   281   by (erule iffD2)
   282 
   283 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   284   by (drule sym) (rule iffD2)
   285 
   286 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   287   by (drule sym) (rule rev_iffD2)
   288 
   289 lemma iffE:
   290   assumes major: "P=Q"
   291     and minor: "[| P --> Q; Q --> P |] ==> R"
   292   shows R
   293   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   294 
   295 
   296 subsubsection {*True*}
   297 
   298 lemma TrueI: "True"
   299   unfolding True_def by (rule refl)
   300 
   301 lemma eqTrueI: "P ==> P = True"
   302   by (iprover intro: iffI TrueI)
   303 
   304 lemma eqTrueE: "P = True ==> P"
   305   by (erule iffD2) (rule TrueI)
   306 
   307 
   308 subsubsection {*Universal quantifier*}
   309 
   310 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   311   unfolding All_def by (iprover intro: ext eqTrueI assms)
   312 
   313 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   314 apply (unfold All_def)
   315 apply (rule eqTrueE)
   316 apply (erule fun_cong)
   317 done
   318 
   319 lemma allE:
   320   assumes major: "ALL x. P(x)"
   321     and minor: "P(x) ==> R"
   322   shows R
   323   by (iprover intro: minor major [THEN spec])
   324 
   325 lemma all_dupE:
   326   assumes major: "ALL x. P(x)"
   327     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   328   shows R
   329   by (iprover intro: minor major major [THEN spec])
   330 
   331 
   332 subsubsection {* False *}
   333 
   334 text {*
   335   Depends upon @{text spec}; it is impossible to do propositional
   336   logic before quantifiers!
   337 *}
   338 
   339 lemma FalseE: "False ==> P"
   340   apply (unfold False_def)
   341   apply (erule spec)
   342   done
   343 
   344 lemma False_neq_True: "False = True ==> P"
   345   by (erule eqTrueE [THEN FalseE])
   346 
   347 
   348 subsubsection {* Negation *}
   349 
   350 lemma notI:
   351   assumes "P ==> False"
   352   shows "~P"
   353   apply (unfold not_def)
   354   apply (iprover intro: impI assms)
   355   done
   356 
   357 lemma False_not_True: "False ~= True"
   358   apply (rule notI)
   359   apply (erule False_neq_True)
   360   done
   361 
   362 lemma True_not_False: "True ~= False"
   363   apply (rule notI)
   364   apply (drule sym)
   365   apply (erule False_neq_True)
   366   done
   367 
   368 lemma notE: "[| ~P;  P |] ==> R"
   369   apply (unfold not_def)
   370   apply (erule mp [THEN FalseE])
   371   apply assumption
   372   done
   373 
   374 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   375   by (erule notE [THEN notI]) (erule meta_mp)
   376 
   377 
   378 subsubsection {*Implication*}
   379 
   380 lemma impE:
   381   assumes "P-->Q" "P" "Q ==> R"
   382   shows "R"
   383 by (iprover intro: assms mp)
   384 
   385 (* Reduces Q to P-->Q, allowing substitution in P. *)
   386 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   387 by (iprover intro: mp)
   388 
   389 lemma contrapos_nn:
   390   assumes major: "~Q"
   391       and minor: "P==>Q"
   392   shows "~P"
   393 by (iprover intro: notI minor major [THEN notE])
   394 
   395 (*not used at all, but we already have the other 3 combinations *)
   396 lemma contrapos_pn:
   397   assumes major: "Q"
   398       and minor: "P ==> ~Q"
   399   shows "~P"
   400 by (iprover intro: notI minor major notE)
   401 
   402 lemma not_sym: "t ~= s ==> s ~= t"
   403   by (erule contrapos_nn) (erule sym)
   404 
   405 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   406   by (erule subst, erule ssubst, assumption)
   407 
   408 (*still used in HOLCF*)
   409 lemma rev_contrapos:
   410   assumes pq: "P ==> Q"
   411       and nq: "~Q"
   412   shows "~P"
   413 apply (rule nq [THEN contrapos_nn])
   414 apply (erule pq)
   415 done
   416 
   417 subsubsection {*Existential quantifier*}
   418 
   419 lemma exI: "P x ==> EX x::'a. P x"
   420 apply (unfold Ex_def)
   421 apply (iprover intro: allI allE impI mp)
   422 done
   423 
   424 lemma exE:
   425   assumes major: "EX x::'a. P(x)"
   426       and minor: "!!x. P(x) ==> Q"
   427   shows "Q"
   428 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   429 apply (iprover intro: impI [THEN allI] minor)
   430 done
   431 
   432 
   433 subsubsection {*Conjunction*}
   434 
   435 lemma conjI: "[| P; Q |] ==> P&Q"
   436 apply (unfold and_def)
   437 apply (iprover intro: impI [THEN allI] mp)
   438 done
   439 
   440 lemma conjunct1: "[| P & Q |] ==> P"
   441 apply (unfold and_def)
   442 apply (iprover intro: impI dest: spec mp)
   443 done
   444 
   445 lemma conjunct2: "[| P & Q |] ==> Q"
   446 apply (unfold and_def)
   447 apply (iprover intro: impI dest: spec mp)
   448 done
   449 
   450 lemma conjE:
   451   assumes major: "P&Q"
   452       and minor: "[| P; Q |] ==> R"
   453   shows "R"
   454 apply (rule minor)
   455 apply (rule major [THEN conjunct1])
   456 apply (rule major [THEN conjunct2])
   457 done
   458 
   459 lemma context_conjI:
   460   assumes "P" "P ==> Q" shows "P & Q"
   461 by (iprover intro: conjI assms)
   462 
   463 
   464 subsubsection {*Disjunction*}
   465 
   466 lemma disjI1: "P ==> P|Q"
   467 apply (unfold or_def)
   468 apply (iprover intro: allI impI mp)
   469 done
   470 
   471 lemma disjI2: "Q ==> P|Q"
   472 apply (unfold or_def)
   473 apply (iprover intro: allI impI mp)
   474 done
   475 
   476 lemma disjE:
   477   assumes major: "P|Q"
   478       and minorP: "P ==> R"
   479       and minorQ: "Q ==> R"
   480   shows "R"
   481 by (iprover intro: minorP minorQ impI
   482                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   483 
   484 
   485 subsubsection {*Classical logic*}
   486 
   487 lemma classical:
   488   assumes prem: "~P ==> P"
   489   shows "P"
   490 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   491 apply assumption
   492 apply (rule notI [THEN prem, THEN eqTrueI])
   493 apply (erule subst)
   494 apply assumption
   495 done
   496 
   497 lemmas ccontr = FalseE [THEN classical, standard]
   498 
   499 (*notE with premises exchanged; it discharges ~R so that it can be used to
   500   make elimination rules*)
   501 lemma rev_notE:
   502   assumes premp: "P"
   503       and premnot: "~R ==> ~P"
   504   shows "R"
   505 apply (rule ccontr)
   506 apply (erule notE [OF premnot premp])
   507 done
   508 
   509 (*Double negation law*)
   510 lemma notnotD: "~~P ==> P"
   511 apply (rule classical)
   512 apply (erule notE)
   513 apply assumption
   514 done
   515 
   516 lemma contrapos_pp:
   517   assumes p1: "Q"
   518       and p2: "~P ==> ~Q"
   519   shows "P"
   520 by (iprover intro: classical p1 p2 notE)
   521 
   522 
   523 subsubsection {*Unique existence*}
   524 
   525 lemma ex1I:
   526   assumes "P a" "!!x. P(x) ==> x=a"
   527   shows "EX! x. P(x)"
   528 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   529 
   530 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   531 lemma ex_ex1I:
   532   assumes ex_prem: "EX x. P(x)"
   533       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   534   shows "EX! x. P(x)"
   535 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   536 
   537 lemma ex1E:
   538   assumes major: "EX! x. P(x)"
   539       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   540   shows "R"
   541 apply (rule major [unfolded Ex1_def, THEN exE])
   542 apply (erule conjE)
   543 apply (iprover intro: minor)
   544 done
   545 
   546 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   547 apply (erule ex1E)
   548 apply (rule exI)
   549 apply assumption
   550 done
   551 
   552 
   553 subsubsection {*THE: definite description operator*}
   554 
   555 lemma the_equality:
   556   assumes prema: "P a"
   557       and premx: "!!x. P x ==> x=a"
   558   shows "(THE x. P x) = a"
   559 apply (rule trans [OF _ the_eq_trivial])
   560 apply (rule_tac f = "The" in arg_cong)
   561 apply (rule ext)
   562 apply (rule iffI)
   563  apply (erule premx)
   564 apply (erule ssubst, rule prema)
   565 done
   566 
   567 lemma theI:
   568   assumes "P a" and "!!x. P x ==> x=a"
   569   shows "P (THE x. P x)"
   570 by (iprover intro: assms the_equality [THEN ssubst])
   571 
   572 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   573 apply (erule ex1E)
   574 apply (erule theI)
   575 apply (erule allE)
   576 apply (erule mp)
   577 apply assumption
   578 done
   579 
   580 (*Easier to apply than theI: only one occurrence of P*)
   581 lemma theI2:
   582   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   583   shows "Q (THE x. P x)"
   584 by (iprover intro: assms theI)
   585 
   586 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   587 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   588            elim:allE impE)
   589 
   590 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   591 apply (rule the_equality)
   592 apply  assumption
   593 apply (erule ex1E)
   594 apply (erule all_dupE)
   595 apply (drule mp)
   596 apply  assumption
   597 apply (erule ssubst)
   598 apply (erule allE)
   599 apply (erule mp)
   600 apply assumption
   601 done
   602 
   603 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   604 apply (rule the_equality)
   605 apply (rule refl)
   606 apply (erule sym)
   607 done
   608 
   609 
   610 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   611 
   612 lemma disjCI:
   613   assumes "~Q ==> P" shows "P|Q"
   614 apply (rule classical)
   615 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   616 done
   617 
   618 lemma excluded_middle: "~P | P"
   619 by (iprover intro: disjCI)
   620 
   621 text {*
   622   case distinction as a natural deduction rule.
   623   Note that @{term "~P"} is the second case, not the first
   624 *}
   625 lemma case_split [case_names True False]:
   626   assumes prem1: "P ==> Q"
   627       and prem2: "~P ==> Q"
   628   shows "Q"
   629 apply (rule excluded_middle [THEN disjE])
   630 apply (erule prem2)
   631 apply (erule prem1)
   632 done
   633 
   634 (*Classical implies (-->) elimination. *)
   635 lemma impCE:
   636   assumes major: "P-->Q"
   637       and minor: "~P ==> R" "Q ==> R"
   638   shows "R"
   639 apply (rule excluded_middle [of P, THEN disjE])
   640 apply (iprover intro: minor major [THEN mp])+
   641 done
   642 
   643 (*This version of --> elimination works on Q before P.  It works best for
   644   those cases in which P holds "almost everywhere".  Can't install as
   645   default: would break old proofs.*)
   646 lemma impCE':
   647   assumes major: "P-->Q"
   648       and minor: "Q ==> R" "~P ==> R"
   649   shows "R"
   650 apply (rule excluded_middle [of P, THEN disjE])
   651 apply (iprover intro: minor major [THEN mp])+
   652 done
   653 
   654 (*Classical <-> elimination. *)
   655 lemma iffCE:
   656   assumes major: "P=Q"
   657       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   658   shows "R"
   659 apply (rule major [THEN iffE])
   660 apply (iprover intro: minor elim: impCE notE)
   661 done
   662 
   663 lemma exCI:
   664   assumes "ALL x. ~P(x) ==> P(a)"
   665   shows "EX x. P(x)"
   666 apply (rule ccontr)
   667 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   668 done
   669 
   670 
   671 subsubsection {* Intuitionistic Reasoning *}
   672 
   673 lemma impE':
   674   assumes 1: "P --> Q"
   675     and 2: "Q ==> R"
   676     and 3: "P --> Q ==> P"
   677   shows R
   678 proof -
   679   from 3 and 1 have P .
   680   with 1 have Q by (rule impE)
   681   with 2 show R .
   682 qed
   683 
   684 lemma allE':
   685   assumes 1: "ALL x. P x"
   686     and 2: "P x ==> ALL x. P x ==> Q"
   687   shows Q
   688 proof -
   689   from 1 have "P x" by (rule spec)
   690   from this and 1 show Q by (rule 2)
   691 qed
   692 
   693 lemma notE':
   694   assumes 1: "~ P"
   695     and 2: "~ P ==> P"
   696   shows R
   697 proof -
   698   from 2 and 1 have P .
   699   with 1 show R by (rule notE)
   700 qed
   701 
   702 lemma TrueE: "True ==> P ==> P" .
   703 lemma notFalseE: "~ False ==> P ==> P" .
   704 
   705 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   706   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   707   and [Pure.elim 2] = allE notE' impE'
   708   and [Pure.intro] = exI disjI2 disjI1
   709 
   710 lemmas [trans] = trans
   711   and [sym] = sym not_sym
   712   and [Pure.elim?] = iffD1 iffD2 impE
   713 
   714 use "Tools/hologic.ML"
   715 
   716 
   717 subsubsection {* Atomizing meta-level connectives *}
   718 
   719 axiomatization where
   720   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   721 
   722 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   723 proof
   724   assume "!!x. P x"
   725   then show "ALL x. P x" ..
   726 next
   727   assume "ALL x. P x"
   728   then show "!!x. P x" by (rule allE)
   729 qed
   730 
   731 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   732 proof
   733   assume r: "A ==> B"
   734   show "A --> B" by (rule impI) (rule r)
   735 next
   736   assume "A --> B" and A
   737   then show B by (rule mp)
   738 qed
   739 
   740 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   741 proof
   742   assume r: "A ==> False"
   743   show "~A" by (rule notI) (rule r)
   744 next
   745   assume "~A" and A
   746   then show False by (rule notE)
   747 qed
   748 
   749 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   750 proof
   751   assume "x == y"
   752   show "x = y" by (unfold `x == y`) (rule refl)
   753 next
   754   assume "x = y"
   755   then show "x == y" by (rule eq_reflection)
   756 qed
   757 
   758 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   759 proof
   760   assume conj: "A &&& B"
   761   show "A & B"
   762   proof (rule conjI)
   763     from conj show A by (rule conjunctionD1)
   764     from conj show B by (rule conjunctionD2)
   765   qed
   766 next
   767   assume conj: "A & B"
   768   show "A &&& B"
   769   proof -
   770     from conj show A ..
   771     from conj show B ..
   772   qed
   773 qed
   774 
   775 lemmas [symmetric, rulify] = atomize_all atomize_imp
   776   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   777 
   778 
   779 subsubsection {* Atomizing elimination rules *}
   780 
   781 setup AtomizeElim.setup
   782 
   783 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   784   by rule iprover+
   785 
   786 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   787   by rule iprover+
   788 
   789 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   790   by rule iprover+
   791 
   792 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   793 
   794 
   795 subsection {* Package setup *}
   796 
   797 subsubsection {* Classical Reasoner setup *}
   798 
   799 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   800   by (rule classical) iprover
   801 
   802 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   803   by (rule classical) iprover
   804 
   805 lemma thin_refl:
   806   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   807 
   808 ML {*
   809 structure Hypsubst = HypsubstFun(
   810 struct
   811   structure Simplifier = Simplifier
   812   val dest_eq = HOLogic.dest_eq
   813   val dest_Trueprop = HOLogic.dest_Trueprop
   814   val dest_imp = HOLogic.dest_imp
   815   val eq_reflection = @{thm eq_reflection}
   816   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   817   val imp_intr = @{thm impI}
   818   val rev_mp = @{thm rev_mp}
   819   val subst = @{thm subst}
   820   val sym = @{thm sym}
   821   val thin_refl = @{thm thin_refl};
   822   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   823                      by (unfold prop_def) (drule eq_reflection, unfold)}
   824 end);
   825 open Hypsubst;
   826 
   827 structure Classical = ClassicalFun(
   828 struct
   829   val imp_elim = @{thm imp_elim}
   830   val not_elim = @{thm notE}
   831   val swap = @{thm swap}
   832   val classical = @{thm classical}
   833   val sizef = Drule.size_of_thm
   834   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   835 end);
   836 
   837 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   838 open Basic_Classical;
   839 
   840 ML_Antiquote.value "claset"
   841   (Scan.succeed "Classical.claset_of (ML_Context.the_local_context ())");
   842 *}
   843 
   844 setup Classical.setup
   845 
   846 setup {*
   847 let
   848   (*prevent substitution on bool*)
   849   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   850     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   851       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   852 in
   853   Hypsubst.hypsubst_setup
   854   #> Context_Rules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   855 end
   856 *}
   857 
   858 declare iffI [intro!]
   859   and notI [intro!]
   860   and impI [intro!]
   861   and disjCI [intro!]
   862   and conjI [intro!]
   863   and TrueI [intro!]
   864   and refl [intro!]
   865 
   866 declare iffCE [elim!]
   867   and FalseE [elim!]
   868   and impCE [elim!]
   869   and disjE [elim!]
   870   and conjE [elim!]
   871 
   872 declare ex_ex1I [intro!]
   873   and allI [intro!]
   874   and the_equality [intro]
   875   and exI [intro]
   876 
   877 declare exE [elim!]
   878   allE [elim]
   879 
   880 ML {* val HOL_cs = @{claset} *}
   881 
   882 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   883   apply (erule swap)
   884   apply (erule (1) meta_mp)
   885   done
   886 
   887 declare ex_ex1I [rule del, intro! 2]
   888   and ex1I [intro]
   889 
   890 lemmas [intro?] = ext
   891   and [elim?] = ex1_implies_ex
   892 
   893 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   894 lemma alt_ex1E [elim!]:
   895   assumes major: "\<exists>!x. P x"
   896       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   897   shows R
   898 apply (rule ex1E [OF major])
   899 apply (rule prem)
   900 apply (tactic {* ares_tac @{thms allI} 1 *})+
   901 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   902 apply iprover
   903 done
   904 
   905 ML {*
   906 structure Blast = Blast
   907 (
   908   val thy = @{theory}
   909   type claset = Classical.claset
   910   val equality_name = @{const_name "op ="}
   911   val not_name = @{const_name Not}
   912   val notE = @{thm notE}
   913   val ccontr = @{thm ccontr}
   914   val contr_tac = Classical.contr_tac
   915   val dup_intr = Classical.dup_intr
   916   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   917   val rep_cs = Classical.rep_cs
   918   val cla_modifiers = Classical.cla_modifiers
   919   val cla_meth' = Classical.cla_meth'
   920 );
   921 val blast_tac = Blast.blast_tac;
   922 *}
   923 
   924 setup Blast.setup
   925 
   926 
   927 subsubsection {* Simplifier *}
   928 
   929 lemma eta_contract_eq: "(%s. f s) = f" ..
   930 
   931 lemma simp_thms:
   932   shows not_not: "(~ ~ P) = P"
   933   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   934   and
   935     "(P ~= Q) = (P = (~Q))"
   936     "(P | ~P) = True"    "(~P | P) = True"
   937     "(x = x) = True"
   938   and not_True_eq_False [code]: "(\<not> True) = False"
   939   and not_False_eq_True [code]: "(\<not> False) = True"
   940   and
   941     "(~P) ~= P"  "P ~= (~P)"
   942     "(True=P) = P"
   943   and eq_True: "(P = True) = P"
   944   and "(False=P) = (~P)"
   945   and eq_False: "(P = False) = (\<not> P)"
   946   and
   947     "(True --> P) = P"  "(False --> P) = True"
   948     "(P --> True) = True"  "(P --> P) = True"
   949     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   950     "(P & True) = P"  "(True & P) = P"
   951     "(P & False) = False"  "(False & P) = False"
   952     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   953     "(P & ~P) = False"    "(~P & P) = False"
   954     "(P | True) = True"  "(True | P) = True"
   955     "(P | False) = P"  "(False | P) = P"
   956     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   957     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   958   and
   959     "!!P. (EX x. x=t & P(x)) = P(t)"
   960     "!!P. (EX x. t=x & P(x)) = P(t)"
   961     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   962     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   963   by (blast, blast, blast, blast, blast, iprover+)
   964 
   965 lemma disj_absorb: "(A | A) = A"
   966   by blast
   967 
   968 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   969   by blast
   970 
   971 lemma conj_absorb: "(A & A) = A"
   972   by blast
   973 
   974 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   975   by blast
   976 
   977 lemma eq_ac:
   978   shows eq_commute: "(a=b) = (b=a)"
   979     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   980     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
   981 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
   982 
   983 lemma conj_comms:
   984   shows conj_commute: "(P&Q) = (Q&P)"
   985     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
   986 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
   987 
   988 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   989 
   990 lemma disj_comms:
   991   shows disj_commute: "(P|Q) = (Q|P)"
   992     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
   993 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
   994 
   995 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   996 
   997 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
   998 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
   999 
  1000 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1001 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1002 
  1003 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1004 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1005 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1006 
  1007 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1008 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1009 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1010 
  1011 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1012 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1013 
  1014 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1015   by iprover
  1016 
  1017 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1018 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1019 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1020 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1021 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1022 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1023   by blast
  1024 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1025 
  1026 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1027 
  1028 
  1029 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1030   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1031   -- {* cases boil down to the same thing. *}
  1032   by blast
  1033 
  1034 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1035 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1036 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1037 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1038 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1039 
  1040 declare All_def [noatp]
  1041 
  1042 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1043 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1044 
  1045 text {*
  1046   \medskip The @{text "&"} congruence rule: not included by default!
  1047   May slow rewrite proofs down by as much as 50\% *}
  1048 
  1049 lemma conj_cong:
  1050     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1051   by iprover
  1052 
  1053 lemma rev_conj_cong:
  1054     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1055   by iprover
  1056 
  1057 text {* The @{text "|"} congruence rule: not included by default! *}
  1058 
  1059 lemma disj_cong:
  1060     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1061   by blast
  1062 
  1063 
  1064 text {* \medskip if-then-else rules *}
  1065 
  1066 lemma if_True [code]: "(if True then x else y) = x"
  1067   by (unfold if_def) blast
  1068 
  1069 lemma if_False [code]: "(if False then x else y) = y"
  1070   by (unfold if_def) blast
  1071 
  1072 lemma if_P: "P ==> (if P then x else y) = x"
  1073   by (unfold if_def) blast
  1074 
  1075 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1076   by (unfold if_def) blast
  1077 
  1078 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1079   apply (rule case_split [of Q])
  1080    apply (simplesubst if_P)
  1081     prefer 3 apply (simplesubst if_not_P, blast+)
  1082   done
  1083 
  1084 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1085 by (simplesubst split_if, blast)
  1086 
  1087 lemmas if_splits [noatp] = split_if split_if_asm
  1088 
  1089 lemma if_cancel: "(if c then x else x) = x"
  1090 by (simplesubst split_if, blast)
  1091 
  1092 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1093 by (simplesubst split_if, blast)
  1094 
  1095 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1096   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1097   by (rule split_if)
  1098 
  1099 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1100   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1101   apply (simplesubst split_if, blast)
  1102   done
  1103 
  1104 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1105 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1106 
  1107 text {* \medskip let rules for simproc *}
  1108 
  1109 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1110   by (unfold Let_def)
  1111 
  1112 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1113   by (unfold Let_def)
  1114 
  1115 text {*
  1116   The following copy of the implication operator is useful for
  1117   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1118   its premise.
  1119 *}
  1120 
  1121 constdefs
  1122   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1123   [code del]: "simp_implies \<equiv> op ==>"
  1124 
  1125 lemma simp_impliesI:
  1126   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1127   shows "PROP P =simp=> PROP Q"
  1128   apply (unfold simp_implies_def)
  1129   apply (rule PQ)
  1130   apply assumption
  1131   done
  1132 
  1133 lemma simp_impliesE:
  1134   assumes PQ: "PROP P =simp=> PROP Q"
  1135   and P: "PROP P"
  1136   and QR: "PROP Q \<Longrightarrow> PROP R"
  1137   shows "PROP R"
  1138   apply (rule QR)
  1139   apply (rule PQ [unfolded simp_implies_def])
  1140   apply (rule P)
  1141   done
  1142 
  1143 lemma simp_implies_cong:
  1144   assumes PP' :"PROP P == PROP P'"
  1145   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1146   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1147 proof (unfold simp_implies_def, rule equal_intr_rule)
  1148   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1149   and P': "PROP P'"
  1150   from PP' [symmetric] and P' have "PROP P"
  1151     by (rule equal_elim_rule1)
  1152   then have "PROP Q" by (rule PQ)
  1153   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1154 next
  1155   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1156   and P: "PROP P"
  1157   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1158   then have "PROP Q'" by (rule P'Q')
  1159   with P'QQ' [OF P', symmetric] show "PROP Q"
  1160     by (rule equal_elim_rule1)
  1161 qed
  1162 
  1163 lemma uncurry:
  1164   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1165   shows "P \<and> Q \<longrightarrow> R"
  1166   using assms by blast
  1167 
  1168 lemma iff_allI:
  1169   assumes "\<And>x. P x = Q x"
  1170   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1171   using assms by blast
  1172 
  1173 lemma iff_exI:
  1174   assumes "\<And>x. P x = Q x"
  1175   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1176   using assms by blast
  1177 
  1178 lemma all_comm:
  1179   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1180   by blast
  1181 
  1182 lemma ex_comm:
  1183   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1184   by blast
  1185 
  1186 use "Tools/simpdata.ML"
  1187 ML {* open Simpdata *}
  1188 
  1189 setup {*
  1190   Simplifier.method_setup Splitter.split_modifiers
  1191   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1192   #> Splitter.setup
  1193   #> clasimp_setup
  1194   #> EqSubst.setup
  1195 *}
  1196 
  1197 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1198 
  1199 simproc_setup neq ("x = y") = {* fn _ =>
  1200 let
  1201   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1202   fun is_neq eq lhs rhs thm =
  1203     (case Thm.prop_of thm of
  1204       _ $ (Not $ (eq' $ l' $ r')) =>
  1205         Not = HOLogic.Not andalso eq' = eq andalso
  1206         r' aconv lhs andalso l' aconv rhs
  1207     | _ => false);
  1208   fun proc ss ct =
  1209     (case Thm.term_of ct of
  1210       eq $ lhs $ rhs =>
  1211         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1212           SOME thm => SOME (thm RS neq_to_EQ_False)
  1213         | NONE => NONE)
  1214      | _ => NONE);
  1215 in proc end;
  1216 *}
  1217 
  1218 simproc_setup let_simp ("Let x f") = {*
  1219 let
  1220   val (f_Let_unfold, x_Let_unfold) =
  1221     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1222     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1223   val (f_Let_folded, x_Let_folded) =
  1224     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1225     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1226   val g_Let_folded =
  1227     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1228     in cterm_of @{theory} g end;
  1229   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1230     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1231     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1232     | count_loose _ _ = 0;
  1233   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1234    case t
  1235     of Abs (_, _, t') => count_loose t' 0 <= 1
  1236      | _ => true;
  1237 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1238   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1239   else let (*Norbert Schirmer's case*)
  1240     val ctxt = Simplifier.the_context ss;
  1241     val thy = ProofContext.theory_of ctxt;
  1242     val t = Thm.term_of ct;
  1243     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1244   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1245     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1246       if is_Free x orelse is_Bound x orelse is_Const x
  1247       then SOME @{thm Let_def}
  1248       else
  1249         let
  1250           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1251           val cx = cterm_of thy x;
  1252           val {T = xT, ...} = rep_cterm cx;
  1253           val cf = cterm_of thy f;
  1254           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1255           val (_ $ _ $ g) = prop_of fx_g;
  1256           val g' = abstract_over (x,g);
  1257         in (if (g aconv g')
  1258              then
  1259                 let
  1260                   val rl =
  1261                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1262                 in SOME (rl OF [fx_g]) end
  1263              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1264              else let
  1265                    val abs_g'= Abs (n,xT,g');
  1266                    val g'x = abs_g'$x;
  1267                    val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1268                    val rl = cterm_instantiate
  1269                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1270                               (g_Let_folded, cterm_of thy abs_g')]
  1271                              @{thm Let_folded};
  1272                  in SOME (rl OF [transitive fx_g g_g'x])
  1273                  end)
  1274         end
  1275     | _ => NONE)
  1276   end
  1277 end *}
  1278 
  1279 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1280 proof
  1281   assume "True \<Longrightarrow> PROP P"
  1282   from this [OF TrueI] show "PROP P" .
  1283 next
  1284   assume "PROP P"
  1285   then show "PROP P" .
  1286 qed
  1287 
  1288 lemma ex_simps:
  1289   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1290   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1291   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1292   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1293   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1294   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1295   -- {* Miniscoping: pushing in existential quantifiers. *}
  1296   by (iprover | blast)+
  1297 
  1298 lemma all_simps:
  1299   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1300   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1301   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1302   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1303   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1304   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1305   -- {* Miniscoping: pushing in universal quantifiers. *}
  1306   by (iprover | blast)+
  1307 
  1308 lemmas [simp] =
  1309   triv_forall_equality (*prunes params*)
  1310   True_implies_equals  (*prune asms `True'*)
  1311   if_True
  1312   if_False
  1313   if_cancel
  1314   if_eq_cancel
  1315   imp_disjL
  1316   (*In general it seems wrong to add distributive laws by default: they
  1317     might cause exponential blow-up.  But imp_disjL has been in for a while
  1318     and cannot be removed without affecting existing proofs.  Moreover,
  1319     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1320     grounds that it allows simplification of R in the two cases.*)
  1321   conj_assoc
  1322   disj_assoc
  1323   de_Morgan_conj
  1324   de_Morgan_disj
  1325   imp_disj1
  1326   imp_disj2
  1327   not_imp
  1328   disj_not1
  1329   not_all
  1330   not_ex
  1331   cases_simp
  1332   the_eq_trivial
  1333   the_sym_eq_trivial
  1334   ex_simps
  1335   all_simps
  1336   simp_thms
  1337 
  1338 lemmas [cong] = imp_cong simp_implies_cong
  1339 lemmas [split] = split_if
  1340 
  1341 ML {* val HOL_ss = @{simpset} *}
  1342 
  1343 text {* Simplifies x assuming c and y assuming ~c *}
  1344 lemma if_cong:
  1345   assumes "b = c"
  1346       and "c \<Longrightarrow> x = u"
  1347       and "\<not> c \<Longrightarrow> y = v"
  1348   shows "(if b then x else y) = (if c then u else v)"
  1349   unfolding if_def using assms by simp
  1350 
  1351 text {* Prevents simplification of x and y:
  1352   faster and allows the execution of functional programs. *}
  1353 lemma if_weak_cong [cong]:
  1354   assumes "b = c"
  1355   shows "(if b then x else y) = (if c then x else y)"
  1356   using assms by (rule arg_cong)
  1357 
  1358 text {* Prevents simplification of t: much faster *}
  1359 lemma let_weak_cong:
  1360   assumes "a = b"
  1361   shows "(let x = a in t x) = (let x = b in t x)"
  1362   using assms by (rule arg_cong)
  1363 
  1364 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1365 lemma eq_cong2:
  1366   assumes "u = u'"
  1367   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1368   using assms by simp
  1369 
  1370 lemma if_distrib:
  1371   "f (if c then x else y) = (if c then f x else f y)"
  1372   by simp
  1373 
  1374 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1375   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1376 lemma restrict_to_left:
  1377   assumes "x = y"
  1378   shows "(x = z) = (y = z)"
  1379   using assms by simp
  1380 
  1381 
  1382 subsubsection {* Generic cases and induction *}
  1383 
  1384 text {* Rule projections: *}
  1385 
  1386 ML {*
  1387 structure Project_Rule = Project_Rule
  1388 (
  1389   val conjunct1 = @{thm conjunct1}
  1390   val conjunct2 = @{thm conjunct2}
  1391   val mp = @{thm mp}
  1392 )
  1393 *}
  1394 
  1395 constdefs
  1396   induct_forall where "induct_forall P == \<forall>x. P x"
  1397   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1398   induct_equal where "induct_equal x y == x = y"
  1399   induct_conj where "induct_conj A B == A \<and> B"
  1400   induct_true where "induct_true == True"
  1401   induct_false where "induct_false == False"
  1402 
  1403 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1404   by (unfold atomize_all induct_forall_def)
  1405 
  1406 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1407   by (unfold atomize_imp induct_implies_def)
  1408 
  1409 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1410   by (unfold atomize_eq induct_equal_def)
  1411 
  1412 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1413   by (unfold atomize_conj induct_conj_def)
  1414 
  1415 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1416 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1417 lemmas induct_rulify' [symmetric, standard] = induct_atomize'
  1418 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1419 lemmas induct_rulify_fallback =
  1420   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1421   induct_true_def induct_false_def
  1422 
  1423 
  1424 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1425     induct_conj (induct_forall A) (induct_forall B)"
  1426   by (unfold induct_forall_def induct_conj_def) iprover
  1427 
  1428 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1429     induct_conj (induct_implies C A) (induct_implies C B)"
  1430   by (unfold induct_implies_def induct_conj_def) iprover
  1431 
  1432 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1433 proof
  1434   assume r: "induct_conj A B ==> PROP C" and A B
  1435   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1436 next
  1437   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1438   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1439 qed
  1440 
  1441 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1442 
  1443 lemma induct_trueI: "induct_true"
  1444   by (simp add: induct_true_def)
  1445 
  1446 text {* Method setup. *}
  1447 
  1448 ML {*
  1449 structure Induct = Induct
  1450 (
  1451   val cases_default = @{thm case_split}
  1452   val atomize = @{thms induct_atomize}
  1453   val rulify = @{thms induct_rulify'}
  1454   val rulify_fallback = @{thms induct_rulify_fallback}
  1455   val equal_def = @{thm induct_equal_def}
  1456   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1457     | dest_def _ = NONE
  1458   val trivial_tac = match_tac @{thms induct_trueI}
  1459 )
  1460 *}
  1461 
  1462 setup {*
  1463   Induct.setup #>
  1464   Context.theory_map (Induct.map_simpset (fn ss => ss
  1465     setmksimps (Simpdata.mksimps Simpdata.mksimps_pairs #>
  1466       map (Simplifier.rewrite_rule (map Thm.symmetric
  1467         @{thms induct_rulify_fallback induct_true_def induct_false_def})))
  1468     addsimprocs
  1469       [Simplifier.simproc @{theory} "swap_induct_false"
  1470          ["induct_false ==> PROP P ==> PROP Q"]
  1471          (fn _ => fn _ =>
  1472             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1473                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1474               | _ => NONE)),
  1475        Simplifier.simproc @{theory} "induct_equal_conj_curry"
  1476          ["induct_conj P Q ==> PROP R"]
  1477          (fn _ => fn _ =>
  1478             (fn _ $ (_ $ P) $ _ =>
  1479                 let
  1480                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1481                         is_conj P andalso is_conj Q
  1482                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1483                     | is_conj @{const induct_true} = true
  1484                     | is_conj @{const induct_false} = true
  1485                     | is_conj _ = false
  1486                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1487               | _ => NONE))]))
  1488 *}
  1489 
  1490 text {* Pre-simplification of induction and cases rules *}
  1491 
  1492 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1493   unfolding induct_equal_def
  1494 proof
  1495   assume R: "!!x. x = t ==> PROP P x"
  1496   show "PROP P t" by (rule R [OF refl])
  1497 next
  1498   fix x assume "PROP P t" "x = t"
  1499   then show "PROP P x" by simp
  1500 qed
  1501 
  1502 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1503   unfolding induct_equal_def
  1504 proof
  1505   assume R: "!!x. t = x ==> PROP P x"
  1506   show "PROP P t" by (rule R [OF refl])
  1507 next
  1508   fix x assume "PROP P t" "t = x"
  1509   then show "PROP P x" by simp
  1510 qed
  1511 
  1512 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1513   unfolding induct_false_def induct_true_def
  1514   by (iprover intro: equal_intr_rule)
  1515 
  1516 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1517   unfolding induct_true_def
  1518 proof
  1519   assume R: "True \<Longrightarrow> PROP P"
  1520   from TrueI show "PROP P" by (rule R)
  1521 next
  1522   assume "PROP P"
  1523   then show "PROP P" .
  1524 qed
  1525 
  1526 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1527   unfolding induct_true_def
  1528   by (iprover intro: equal_intr_rule)
  1529 
  1530 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1531   unfolding induct_true_def
  1532   by (iprover intro: equal_intr_rule)
  1533 
  1534 lemma [induct_simp]: "induct_implies induct_true P == P"
  1535   by (simp add: induct_implies_def induct_true_def)
  1536 
  1537 lemma [induct_simp]: "(x = x) = True" 
  1538   by (rule simp_thms)
  1539 
  1540 hide const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1541 
  1542 use "~~/src/Tools/induct_tacs.ML"
  1543 setup InductTacs.setup
  1544 
  1545 
  1546 subsubsection {* Coherent logic *}
  1547 
  1548 ML {*
  1549 structure Coherent = Coherent
  1550 (
  1551   val atomize_elimL = @{thm atomize_elimL}
  1552   val atomize_exL = @{thm atomize_exL}
  1553   val atomize_conjL = @{thm atomize_conjL}
  1554   val atomize_disjL = @{thm atomize_disjL}
  1555   val operator_names =
  1556     [@{const_name "op |"}, @{const_name "op &"}, @{const_name "Ex"}]
  1557 );
  1558 *}
  1559 
  1560 setup Coherent.setup
  1561 
  1562 
  1563 subsubsection {* Reorienting equalities *}
  1564 
  1565 ML {*
  1566 signature REORIENT_PROC =
  1567 sig
  1568   val add : (term -> bool) -> theory -> theory
  1569   val proc : morphism -> simpset -> cterm -> thm option
  1570 end;
  1571 
  1572 structure Reorient_Proc : REORIENT_PROC =
  1573 struct
  1574   structure Data = Theory_Data
  1575   (
  1576     type T = ((term -> bool) * stamp) list;
  1577     val empty = [];
  1578     val extend = I;
  1579     fun merge data : T = Library.merge (eq_snd op =) data;
  1580   );
  1581   fun add m = Data.map (cons (m, stamp ()));
  1582   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1583 
  1584   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1585   fun proc phi ss ct =
  1586     let
  1587       val ctxt = Simplifier.the_context ss;
  1588       val thy = ProofContext.theory_of ctxt;
  1589     in
  1590       case Thm.term_of ct of
  1591         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1592       | _ => NONE
  1593     end;
  1594 end;
  1595 *}
  1596 
  1597 
  1598 subsection {* Other simple lemmas and lemma duplicates *}
  1599 
  1600 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1601   by blast+
  1602 
  1603 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1604   apply (rule iffI)
  1605   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1606   apply (fast dest!: theI')
  1607   apply (fast intro: ext the1_equality [symmetric])
  1608   apply (erule ex1E)
  1609   apply (rule allI)
  1610   apply (rule ex1I)
  1611   apply (erule spec)
  1612   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1613   apply (erule impE)
  1614   apply (rule allI)
  1615   apply (case_tac "xa = x")
  1616   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1617   done
  1618 
  1619 lemmas eq_sym_conv = eq_commute
  1620 
  1621 lemma nnf_simps:
  1622   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1623   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1624   "(\<not> \<not>(P)) = P"
  1625 by blast+
  1626 
  1627 
  1628 subsection {* Basic ML bindings *}
  1629 
  1630 ML {*
  1631 val FalseE = @{thm FalseE}
  1632 val Let_def = @{thm Let_def}
  1633 val TrueI = @{thm TrueI}
  1634 val allE = @{thm allE}
  1635 val allI = @{thm allI}
  1636 val all_dupE = @{thm all_dupE}
  1637 val arg_cong = @{thm arg_cong}
  1638 val box_equals = @{thm box_equals}
  1639 val ccontr = @{thm ccontr}
  1640 val classical = @{thm classical}
  1641 val conjE = @{thm conjE}
  1642 val conjI = @{thm conjI}
  1643 val conjunct1 = @{thm conjunct1}
  1644 val conjunct2 = @{thm conjunct2}
  1645 val disjCI = @{thm disjCI}
  1646 val disjE = @{thm disjE}
  1647 val disjI1 = @{thm disjI1}
  1648 val disjI2 = @{thm disjI2}
  1649 val eq_reflection = @{thm eq_reflection}
  1650 val ex1E = @{thm ex1E}
  1651 val ex1I = @{thm ex1I}
  1652 val ex1_implies_ex = @{thm ex1_implies_ex}
  1653 val exE = @{thm exE}
  1654 val exI = @{thm exI}
  1655 val excluded_middle = @{thm excluded_middle}
  1656 val ext = @{thm ext}
  1657 val fun_cong = @{thm fun_cong}
  1658 val iffD1 = @{thm iffD1}
  1659 val iffD2 = @{thm iffD2}
  1660 val iffI = @{thm iffI}
  1661 val impE = @{thm impE}
  1662 val impI = @{thm impI}
  1663 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1664 val mp = @{thm mp}
  1665 val notE = @{thm notE}
  1666 val notI = @{thm notI}
  1667 val not_all = @{thm not_all}
  1668 val not_ex = @{thm not_ex}
  1669 val not_iff = @{thm not_iff}
  1670 val not_not = @{thm not_not}
  1671 val not_sym = @{thm not_sym}
  1672 val refl = @{thm refl}
  1673 val rev_mp = @{thm rev_mp}
  1674 val spec = @{thm spec}
  1675 val ssubst = @{thm ssubst}
  1676 val subst = @{thm subst}
  1677 val sym = @{thm sym}
  1678 val trans = @{thm trans}
  1679 *}
  1680 
  1681 
  1682 subsection {* Code generator setup *}
  1683 
  1684 subsubsection {* SML code generator setup *}
  1685 
  1686 use "Tools/recfun_codegen.ML"
  1687 
  1688 setup {*
  1689   Codegen.setup
  1690   #> RecfunCodegen.setup
  1691   #> Codegen.map_unfold (K HOL_basic_ss)
  1692 *}
  1693 
  1694 types_code
  1695   "bool"  ("bool")
  1696 attach (term_of) {*
  1697 fun term_of_bool b = if b then HOLogic.true_const else HOLogic.false_const;
  1698 *}
  1699 attach (test) {*
  1700 fun gen_bool i =
  1701   let val b = one_of [false, true]
  1702   in (b, fn () => term_of_bool b) end;
  1703 *}
  1704   "prop"  ("bool")
  1705 attach (term_of) {*
  1706 fun term_of_prop b =
  1707   HOLogic.mk_Trueprop (if b then HOLogic.true_const else HOLogic.false_const);
  1708 *}
  1709 
  1710 consts_code
  1711   "Trueprop" ("(_)")
  1712   "True"    ("true")
  1713   "False"   ("false")
  1714   "Not"     ("Bool.not")
  1715   "op |"    ("(_ orelse/ _)")
  1716   "op &"    ("(_ andalso/ _)")
  1717   "If"      ("(if _/ then _/ else _)")
  1718 
  1719 setup {*
  1720 let
  1721 
  1722 fun eq_codegen thy defs dep thyname b t gr =
  1723     (case strip_comb t of
  1724        (Const ("op =", Type (_, [Type ("fun", _), _])), _) => NONE
  1725      | (Const ("op =", _), [t, u]) =>
  1726           let
  1727             val (pt, gr') = Codegen.invoke_codegen thy defs dep thyname false t gr;
  1728             val (pu, gr'') = Codegen.invoke_codegen thy defs dep thyname false u gr';
  1729             val (_, gr''') = Codegen.invoke_tycodegen thy defs dep thyname false HOLogic.boolT gr'';
  1730           in
  1731             SOME (Codegen.parens
  1732               (Pretty.block [pt, Codegen.str " =", Pretty.brk 1, pu]), gr''')
  1733           end
  1734      | (t as Const ("op =", _), ts) => SOME (Codegen.invoke_codegen
  1735          thy defs dep thyname b (Codegen.eta_expand t ts 2) gr)
  1736      | _ => NONE);
  1737 
  1738 in
  1739   Codegen.add_codegen "eq_codegen" eq_codegen
  1740 end
  1741 *}
  1742 
  1743 subsubsection {* Generic code generator preprocessor setup *}
  1744 
  1745 setup {*
  1746   Code_Preproc.map_pre (K HOL_basic_ss)
  1747   #> Code_Preproc.map_post (K HOL_basic_ss)
  1748 *}
  1749 
  1750 subsubsection {* Equality *}
  1751 
  1752 class eq =
  1753   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1754   assumes eq_equals: "eq x y \<longleftrightarrow> x = y"
  1755 begin
  1756 
  1757 lemma eq [code_unfold, code_inline del]: "eq = (op =)"
  1758   by (rule ext eq_equals)+
  1759 
  1760 lemma eq_refl: "eq x x \<longleftrightarrow> True"
  1761   unfolding eq by rule+
  1762 
  1763 lemma equals_eq: "(op =) \<equiv> eq"
  1764   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq_equals)
  1765 
  1766 declare equals_eq [symmetric, code_post]
  1767 
  1768 end
  1769 
  1770 declare equals_eq [code]
  1771 
  1772 setup {*
  1773   Code_Preproc.map_pre (fn simpset =>
  1774     simpset addsimprocs [Simplifier.simproc_i @{theory} "eq" [@{term "op ="}]
  1775       (fn thy => fn _ => fn t as Const (_, T) => case strip_type T
  1776         of ((T as Type _) :: _, _) => SOME @{thm equals_eq}
  1777          | _ => NONE)])
  1778 *}
  1779 
  1780 
  1781 subsubsection {* Generic code generator foundation *}
  1782 
  1783 text {* Datatypes *}
  1784 
  1785 code_datatype True False
  1786 
  1787 code_datatype "TYPE('a\<Colon>{})"
  1788 
  1789 code_datatype "prop" Trueprop
  1790 
  1791 text {* Code equations *}
  1792 
  1793 lemma [code]:
  1794   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1795     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1796     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1797 
  1798 lemma [code]:
  1799   shows "False \<and> P \<longleftrightarrow> False"
  1800     and "True \<and> P \<longleftrightarrow> P"
  1801     and "P \<and> False \<longleftrightarrow> False"
  1802     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1803 
  1804 lemma [code]:
  1805   shows "False \<or> P \<longleftrightarrow> P"
  1806     and "True \<or> P \<longleftrightarrow> True"
  1807     and "P \<or> False \<longleftrightarrow> P"
  1808     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1809 
  1810 lemma [code]:
  1811   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1812     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1813     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1814     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1815 
  1816 instantiation itself :: (type) eq
  1817 begin
  1818 
  1819 definition eq_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1820   "eq_itself x y \<longleftrightarrow> x = y"
  1821 
  1822 instance proof
  1823 qed (fact eq_itself_def)
  1824 
  1825 end
  1826 
  1827 lemma eq_itself_code [code]:
  1828   "eq_class.eq TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1829   by (simp add: eq)
  1830 
  1831 text {* Equality *}
  1832 
  1833 declare simp_thms(6) [code nbe]
  1834 
  1835 setup {*
  1836   Sign.add_const_constraint (@{const_name eq}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1837 *}
  1838 
  1839 lemma equals_alias_cert: "OFCLASS('a, eq_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> eq)" (is "?ofclass \<equiv> ?eq")
  1840 proof
  1841   assume "PROP ?ofclass"
  1842   show "PROP ?eq"
  1843     by (tactic {* ALLGOALS (rtac (Drule.unconstrainTs @{thm equals_eq})) *}) 
  1844       (fact `PROP ?ofclass`)
  1845 next
  1846   assume "PROP ?eq"
  1847   show "PROP ?ofclass" proof
  1848   qed (simp add: `PROP ?eq`)
  1849 qed
  1850   
  1851 setup {*
  1852   Sign.add_const_constraint (@{const_name eq}, SOME @{typ "'a\<Colon>eq \<Rightarrow> 'a \<Rightarrow> bool"})
  1853 *}
  1854 
  1855 setup {*
  1856   Nbe.add_const_alias @{thm equals_alias_cert}
  1857 *}
  1858 
  1859 hide (open) const eq
  1860 hide const eq
  1861 
  1862 text {* Cases *}
  1863 
  1864 lemma Let_case_cert:
  1865   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1866   shows "CASE x \<equiv> f x"
  1867   using assms by simp_all
  1868 
  1869 lemma If_case_cert:
  1870   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1871   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
  1872   using assms by simp_all
  1873 
  1874 setup {*
  1875   Code.add_case @{thm Let_case_cert}
  1876   #> Code.add_case @{thm If_case_cert}
  1877   #> Code.add_undefined @{const_name undefined}
  1878 *}
  1879 
  1880 code_abort undefined
  1881 
  1882 subsubsection {* Generic code generator target languages *}
  1883 
  1884 text {* type bool *}
  1885 
  1886 code_type bool
  1887   (SML "bool")
  1888   (OCaml "bool")
  1889   (Haskell "Bool")
  1890   (Scala "Boolean")
  1891 
  1892 code_const True and False and Not and "op &" and "op |" and If
  1893   (SML "true" and "false" and "not"
  1894     and infixl 1 "andalso" and infixl 0 "orelse"
  1895     and "!(if (_)/ then (_)/ else (_))")
  1896   (OCaml "true" and "false" and "not"
  1897     and infixl 4 "&&" and infixl 2 "||"
  1898     and "!(if (_)/ then (_)/ else (_))")
  1899   (Haskell "True" and "False" and "not"
  1900     and infixl 3 "&&" and infixl 2 "||"
  1901     and "!(if (_)/ then (_)/ else (_))")
  1902   (Scala "true" and "false" and "'! _"
  1903     and infixl 3 "&&" and infixl 1 "||"
  1904     and "!(if ((_))/ (_)/ else (_))")
  1905 
  1906 code_reserved SML
  1907   bool true false not
  1908 
  1909 code_reserved OCaml
  1910   bool not
  1911 
  1912 code_reserved Scala
  1913   Boolean
  1914 
  1915 text {* using built-in Haskell equality *}
  1916 
  1917 code_class eq
  1918   (Haskell "Eq")
  1919 
  1920 code_const "eq_class.eq"
  1921   (Haskell infixl 4 "==")
  1922 
  1923 code_const "op ="
  1924   (Haskell infixl 4 "==")
  1925 
  1926 text {* undefined *}
  1927 
  1928 code_const undefined
  1929   (SML "!(raise/ Fail/ \"undefined\")")
  1930   (OCaml "failwith/ \"undefined\"")
  1931   (Haskell "error/ \"undefined\"")
  1932   (Scala "!error(\"undefined\")")
  1933 
  1934 subsubsection {* Evaluation and normalization by evaluation *}
  1935 
  1936 setup {*
  1937   Value.add_evaluator ("SML", Codegen.eval_term o ProofContext.theory_of)
  1938 *}
  1939 
  1940 ML {*
  1941 structure Eval_Method =
  1942 struct
  1943 
  1944 val eval_ref : (unit -> bool) option Unsynchronized.ref = Unsynchronized.ref NONE;
  1945 
  1946 end;
  1947 *}
  1948 
  1949 oracle eval_oracle = {* fn ct =>
  1950   let
  1951     val thy = Thm.theory_of_cterm ct;
  1952     val t = Thm.term_of ct;
  1953     val dummy = @{cprop True};
  1954   in case try HOLogic.dest_Trueprop t
  1955    of SOME t' => if Code_Eval.eval NONE
  1956          ("Eval_Method.eval_ref", Eval_Method.eval_ref) (K I) thy t' [] 
  1957        then Thm.capply (Thm.capply @{cterm "op \<equiv> \<Colon> prop \<Rightarrow> prop \<Rightarrow> prop"} ct) dummy
  1958        else dummy
  1959     | NONE => dummy
  1960   end
  1961 *}
  1962 
  1963 ML {*
  1964 fun gen_eval_method conv ctxt = SIMPLE_METHOD'
  1965   (CONVERSION (Conv.params_conv (~1) (K (Conv.concl_conv (~1) conv)) ctxt)
  1966     THEN' rtac TrueI)
  1967 *}
  1968 
  1969 method_setup eval = {* Scan.succeed (gen_eval_method eval_oracle) *}
  1970   "solve goal by evaluation"
  1971 
  1972 method_setup evaluation = {* Scan.succeed (gen_eval_method Codegen.evaluation_conv) *}
  1973   "solve goal by evaluation"
  1974 
  1975 method_setup normalization = {*
  1976   Scan.succeed (K (SIMPLE_METHOD' (CONVERSION Nbe.norm_conv THEN' (fn k => TRY (rtac TrueI k)))))
  1977 *} "solve goal by normalization"
  1978 
  1979 
  1980 subsection {* Counterexample Search Units *}
  1981 
  1982 subsubsection {* Quickcheck *}
  1983 
  1984 quickcheck_params [size = 5, iterations = 50]
  1985 
  1986 
  1987 subsubsection {* Nitpick setup *}
  1988 
  1989 text {* This will be relocated once Nitpick is moved to HOL. *}
  1990 
  1991 ML {*
  1992 structure Nitpick_Defs = Named_Thms
  1993 (
  1994   val name = "nitpick_def"
  1995   val description = "alternative definitions of constants as needed by Nitpick"
  1996 )
  1997 structure Nitpick_Simps = Named_Thms
  1998 (
  1999   val name = "nitpick_simp"
  2000   val description = "equational specification of constants as needed by Nitpick"
  2001 )
  2002 structure Nitpick_Psimps = Named_Thms
  2003 (
  2004   val name = "nitpick_psimp"
  2005   val description = "partial equational specification of constants as needed by Nitpick"
  2006 )
  2007 structure Nitpick_Intros = Named_Thms
  2008 (
  2009   val name = "nitpick_intro"
  2010   val description = "introduction rules for (co)inductive predicates as needed by Nitpick"
  2011 )
  2012 *}
  2013 
  2014 setup {*
  2015   Nitpick_Defs.setup
  2016   #> Nitpick_Simps.setup
  2017   #> Nitpick_Psimps.setup
  2018   #> Nitpick_Intros.setup
  2019 *}
  2020 
  2021 
  2022 subsection {* Preprocessing for the predicate compiler *}
  2023 
  2024 ML {*
  2025 structure Predicate_Compile_Alternative_Defs = Named_Thms
  2026 (
  2027   val name = "code_pred_def"
  2028   val description = "alternative definitions of constants for the Predicate Compiler"
  2029 )
  2030 *}
  2031 
  2032 ML {*
  2033 structure Predicate_Compile_Inline_Defs = Named_Thms
  2034 (
  2035   val name = "code_pred_inline"
  2036   val description = "inlining definitions for the Predicate Compiler"
  2037 )
  2038 *}
  2039 
  2040 setup {*
  2041   Predicate_Compile_Alternative_Defs.setup
  2042   #> Predicate_Compile_Inline_Defs.setup
  2043 *}
  2044 
  2045 
  2046 subsection {* Legacy tactics and ML bindings *}
  2047 
  2048 ML {*
  2049 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2050 
  2051 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2052 local
  2053   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  2054     | wrong_prem (Bound _) = true
  2055     | wrong_prem _ = false;
  2056   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2057 in
  2058   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2059   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2060 end;
  2061 
  2062 val all_conj_distrib = thm "all_conj_distrib";
  2063 val all_simps = thms "all_simps";
  2064 val atomize_not = thm "atomize_not";
  2065 val case_split = thm "case_split";
  2066 val cases_simp = thm "cases_simp";
  2067 val choice_eq = thm "choice_eq"
  2068 val cong = thm "cong"
  2069 val conj_comms = thms "conj_comms";
  2070 val conj_cong = thm "conj_cong";
  2071 val de_Morgan_conj = thm "de_Morgan_conj";
  2072 val de_Morgan_disj = thm "de_Morgan_disj";
  2073 val disj_assoc = thm "disj_assoc";
  2074 val disj_comms = thms "disj_comms";
  2075 val disj_cong = thm "disj_cong";
  2076 val eq_ac = thms "eq_ac";
  2077 val eq_cong2 = thm "eq_cong2"
  2078 val Eq_FalseI = thm "Eq_FalseI";
  2079 val Eq_TrueI = thm "Eq_TrueI";
  2080 val Ex1_def = thm "Ex1_def"
  2081 val ex_disj_distrib = thm "ex_disj_distrib";
  2082 val ex_simps = thms "ex_simps";
  2083 val if_cancel = thm "if_cancel";
  2084 val if_eq_cancel = thm "if_eq_cancel";
  2085 val if_False = thm "if_False";
  2086 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  2087 val iff = thm "iff"
  2088 val if_splits = thms "if_splits";
  2089 val if_True = thm "if_True";
  2090 val if_weak_cong = thm "if_weak_cong"
  2091 val imp_all = thm "imp_all";
  2092 val imp_cong = thm "imp_cong";
  2093 val imp_conjL = thm "imp_conjL";
  2094 val imp_conjR = thm "imp_conjR";
  2095 val imp_conv_disj = thm "imp_conv_disj";
  2096 val simp_implies_def = thm "simp_implies_def";
  2097 val simp_thms = thms "simp_thms";
  2098 val split_if = thm "split_if";
  2099 val the1_equality = thm "the1_equality"
  2100 val theI = thm "theI"
  2101 val theI' = thm "theI'"
  2102 val True_implies_equals = thm "True_implies_equals";
  2103 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  2104 
  2105 *}
  2106 
  2107 end