src/HOL/Library/FuncSet.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 33271 7be66dee1a5a
child 38656 d5d342611edb
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma PiE [elim]:
    67   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    68 by(auto simp: Pi_def)
    69 
    70 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    71   by (auto intro: Pi_I)
    72 
    73 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    74   by (simp add: Pi_def)
    75 
    76 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    77 by auto
    78 
    79 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    80 apply (simp add: Pi_def, auto)
    81 txt{*Converse direction requires Axiom of Choice to exhibit a function
    82 picking an element from each non-empty @{term "B x"}*}
    83 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    84 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    85 done
    86 
    87 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    88 by (simp add: Pi_def)
    89 
    90 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    91 by (simp add: Pi_def)
    92 (*
    93 lemma funcset_id [simp]: "(%x. x): A -> A"
    94   by (simp add: Pi_def)
    95 *)
    96 text{*Covariance of Pi-sets in their second argument*}
    97 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    98 by auto
    99 
   100 text{*Contravariance of Pi-sets in their first argument*}
   101 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   102 by auto
   103 
   104 lemma prod_final:
   105   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   106   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   107 proof (rule Pi_I) 
   108   fix z
   109   assume z: "z \<in> A" 
   110   have "f z = (fst (f z), snd (f z))" 
   111     by simp
   112   also have "...  \<in> B z \<times> C z"
   113     by (metis SigmaI PiE o_apply 1 2 z) 
   114   finally show "f z \<in> B z \<times> C z" .
   115 qed
   116 
   117 
   118 subsection{*Composition With a Restricted Domain: @{term compose}*}
   119 
   120 lemma funcset_compose:
   121   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   122 by (simp add: Pi_def compose_def restrict_def)
   123 
   124 lemma compose_assoc:
   125     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   126       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   127 by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
   128 
   129 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   130 by (simp add: compose_def restrict_def)
   131 
   132 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   133   by (auto simp add: image_def compose_eq)
   134 
   135 
   136 subsection{*Bounded Abstraction: @{term restrict}*}
   137 
   138 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   139   by (simp add: Pi_def restrict_def)
   140 
   141 lemma restrictI[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   142   by (simp add: Pi_def restrict_def)
   143 
   144 lemma restrict_apply [simp]:
   145     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   146   by (simp add: restrict_def)
   147 
   148 lemma restrict_ext:
   149     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   150   by (simp add: expand_fun_eq Pi_def restrict_def)
   151 
   152 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   153   by (simp add: inj_on_def restrict_def)
   154 
   155 lemma Id_compose:
   156     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   157   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   158 
   159 lemma compose_Id:
   160     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   161   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   162 
   163 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   164   by (auto simp add: restrict_def)
   165 
   166 
   167 subsection{*Bijections Between Sets*}
   168 
   169 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   170 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   171 
   172 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   173 by (auto simp add: bij_betw_def)
   174 
   175 lemma inj_on_compose:
   176   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   177 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   178 
   179 lemma bij_betw_compose:
   180   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   181 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   182 apply (auto simp add: compose_def image_def)
   183 done
   184 
   185 lemma bij_betw_restrict_eq [simp]:
   186   "bij_betw (restrict f A) A B = bij_betw f A B"
   187 by (simp add: bij_betw_def)
   188 
   189 
   190 subsection{*Extensionality*}
   191 
   192 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   193 by (simp add: extensional_def)
   194 
   195 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   196 by (simp add: restrict_def extensional_def)
   197 
   198 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   199 by (simp add: compose_def)
   200 
   201 lemma extensionalityI:
   202   "[| f \<in> extensional A; g \<in> extensional A;
   203       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   204 by (force simp add: expand_fun_eq extensional_def)
   205 
   206 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   207 by (unfold inv_into_def) (fast intro: someI2)
   208 
   209 lemma compose_inv_into_id:
   210   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   211 apply (simp add: bij_betw_def compose_def)
   212 apply (rule restrict_ext, auto)
   213 done
   214 
   215 lemma compose_id_inv_into:
   216   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   217 apply (simp add: compose_def)
   218 apply (rule restrict_ext)
   219 apply (simp add: f_inv_into_f)
   220 done
   221 
   222 
   223 subsection{*Cardinality*}
   224 
   225 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   226 by (rule card_inj_on_le) auto
   227 
   228 lemma card_bij:
   229   "[|f \<in> A\<rightarrow>B; inj_on f A;
   230      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   231 by (blast intro: card_inj order_antisym)
   232 
   233 end