src/HOL/Library/List_Prefix.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 30663 0b6aff7451b2
child 37474 ce943f9edf5e
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title:      HOL/Library/List_Prefix.thy
     2     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 header {* List prefixes and postfixes *}
     6 
     7 theory List_Prefix
     8 imports List Main
     9 begin
    10 
    11 subsection {* Prefix order on lists *}
    12 
    13 instantiation list :: (type) order
    14 begin
    15 
    16 definition
    17   prefix_def [code del]: "xs \<le> ys = (\<exists>zs. ys = xs @ zs)"
    18 
    19 definition
    20   strict_prefix_def [code del]: "xs < ys = (xs \<le> ys \<and> xs \<noteq> (ys::'a list))"
    21 
    22 instance
    23   by intro_classes (auto simp add: prefix_def strict_prefix_def)
    24 
    25 end
    26 
    27 lemma prefixI [intro?]: "ys = xs @ zs ==> xs \<le> ys"
    28   unfolding prefix_def by blast
    29 
    30 lemma prefixE [elim?]:
    31   assumes "xs \<le> ys"
    32   obtains zs where "ys = xs @ zs"
    33   using assms unfolding prefix_def by blast
    34 
    35 lemma strict_prefixI' [intro?]: "ys = xs @ z # zs ==> xs < ys"
    36   unfolding strict_prefix_def prefix_def by blast
    37 
    38 lemma strict_prefixE' [elim?]:
    39   assumes "xs < ys"
    40   obtains z zs where "ys = xs @ z # zs"
    41 proof -
    42   from `xs < ys` obtain us where "ys = xs @ us" and "xs \<noteq> ys"
    43     unfolding strict_prefix_def prefix_def by blast
    44   with that show ?thesis by (auto simp add: neq_Nil_conv)
    45 qed
    46 
    47 lemma strict_prefixI [intro?]: "xs \<le> ys ==> xs \<noteq> ys ==> xs < (ys::'a list)"
    48   unfolding strict_prefix_def by blast
    49 
    50 lemma strict_prefixE [elim?]:
    51   fixes xs ys :: "'a list"
    52   assumes "xs < ys"
    53   obtains "xs \<le> ys" and "xs \<noteq> ys"
    54   using assms unfolding strict_prefix_def by blast
    55 
    56 
    57 subsection {* Basic properties of prefixes *}
    58 
    59 theorem Nil_prefix [iff]: "[] \<le> xs"
    60   by (simp add: prefix_def)
    61 
    62 theorem prefix_Nil [simp]: "(xs \<le> []) = (xs = [])"
    63   by (induct xs) (simp_all add: prefix_def)
    64 
    65 lemma prefix_snoc [simp]: "(xs \<le> ys @ [y]) = (xs = ys @ [y] \<or> xs \<le> ys)"
    66 proof
    67   assume "xs \<le> ys @ [y]"
    68   then obtain zs where zs: "ys @ [y] = xs @ zs" ..
    69   show "xs = ys @ [y] \<or> xs \<le> ys"
    70     by (metis append_Nil2 butlast_append butlast_snoc prefixI zs)
    71 next
    72   assume "xs = ys @ [y] \<or> xs \<le> ys"
    73   then show "xs \<le> ys @ [y]"
    74     by (metis order_eq_iff strict_prefixE strict_prefixI' xt1(7))
    75 qed
    76 
    77 lemma Cons_prefix_Cons [simp]: "(x # xs \<le> y # ys) = (x = y \<and> xs \<le> ys)"
    78   by (auto simp add: prefix_def)
    79 
    80 lemma same_prefix_prefix [simp]: "(xs @ ys \<le> xs @ zs) = (ys \<le> zs)"
    81   by (induct xs) simp_all
    82 
    83 lemma same_prefix_nil [iff]: "(xs @ ys \<le> xs) = (ys = [])"
    84   by (metis append_Nil2 append_self_conv order_eq_iff prefixI)
    85 
    86 lemma prefix_prefix [simp]: "xs \<le> ys ==> xs \<le> ys @ zs"
    87   by (metis order_le_less_trans prefixI strict_prefixE strict_prefixI)
    88 
    89 lemma append_prefixD: "xs @ ys \<le> zs \<Longrightarrow> xs \<le> zs"
    90   by (auto simp add: prefix_def)
    91 
    92 theorem prefix_Cons: "(xs \<le> y # ys) = (xs = [] \<or> (\<exists>zs. xs = y # zs \<and> zs \<le> ys))"
    93   by (cases xs) (auto simp add: prefix_def)
    94 
    95 theorem prefix_append:
    96   "(xs \<le> ys @ zs) = (xs \<le> ys \<or> (\<exists>us. xs = ys @ us \<and> us \<le> zs))"
    97   apply (induct zs rule: rev_induct)
    98    apply force
    99   apply (simp del: append_assoc add: append_assoc [symmetric])
   100   apply (metis append_eq_appendI)
   101   done
   102 
   103 lemma append_one_prefix:
   104   "xs \<le> ys ==> length xs < length ys ==> xs @ [ys ! length xs] \<le> ys"
   105   unfolding prefix_def
   106   by (metis Cons_eq_appendI append_eq_appendI append_eq_conv_conj
   107     eq_Nil_appendI nth_drop')
   108 
   109 theorem prefix_length_le: "xs \<le> ys ==> length xs \<le> length ys"
   110   by (auto simp add: prefix_def)
   111 
   112 lemma prefix_same_cases:
   113   "(xs\<^isub>1::'a list) \<le> ys \<Longrightarrow> xs\<^isub>2 \<le> ys \<Longrightarrow> xs\<^isub>1 \<le> xs\<^isub>2 \<or> xs\<^isub>2 \<le> xs\<^isub>1"
   114   unfolding prefix_def by (metis append_eq_append_conv2)
   115 
   116 lemma set_mono_prefix: "xs \<le> ys \<Longrightarrow> set xs \<subseteq> set ys"
   117   by (auto simp add: prefix_def)
   118 
   119 lemma take_is_prefix: "take n xs \<le> xs"
   120   unfolding prefix_def by (metis append_take_drop_id)
   121 
   122 lemma map_prefixI: "xs \<le> ys \<Longrightarrow> map f xs \<le> map f ys"
   123   by (auto simp: prefix_def)
   124 
   125 lemma prefix_length_less: "xs < ys \<Longrightarrow> length xs < length ys"
   126   by (auto simp: strict_prefix_def prefix_def)
   127 
   128 lemma strict_prefix_simps [simp]:
   129     "xs < [] = False"
   130     "[] < (x # xs) = True"
   131     "(x # xs) < (y # ys) = (x = y \<and> xs < ys)"
   132   by (simp_all add: strict_prefix_def cong: conj_cong)
   133 
   134 lemma take_strict_prefix: "xs < ys \<Longrightarrow> take n xs < ys"
   135   apply (induct n arbitrary: xs ys)
   136    apply (case_tac ys, simp_all)[1]
   137   apply (metis order_less_trans strict_prefixI take_is_prefix)
   138   done
   139 
   140 lemma not_prefix_cases:
   141   assumes pfx: "\<not> ps \<le> ls"
   142   obtains
   143     (c1) "ps \<noteq> []" and "ls = []"
   144   | (c2) a as x xs where "ps = a#as" and "ls = x#xs" and "x = a" and "\<not> as \<le> xs"
   145   | (c3) a as x xs where "ps = a#as" and "ls = x#xs" and "x \<noteq> a"
   146 proof (cases ps)
   147   case Nil then show ?thesis using pfx by simp
   148 next
   149   case (Cons a as)
   150   note c = `ps = a#as`
   151   show ?thesis
   152   proof (cases ls)
   153     case Nil then show ?thesis by (metis append_Nil2 pfx c1 same_prefix_nil)
   154   next
   155     case (Cons x xs)
   156     show ?thesis
   157     proof (cases "x = a")
   158       case True
   159       have "\<not> as \<le> xs" using pfx c Cons True by simp
   160       with c Cons True show ?thesis by (rule c2)
   161     next
   162       case False
   163       with c Cons show ?thesis by (rule c3)
   164     qed
   165   qed
   166 qed
   167 
   168 lemma not_prefix_induct [consumes 1, case_names Nil Neq Eq]:
   169   assumes np: "\<not> ps \<le> ls"
   170     and base: "\<And>x xs. P (x#xs) []"
   171     and r1: "\<And>x xs y ys. x \<noteq> y \<Longrightarrow> P (x#xs) (y#ys)"
   172     and r2: "\<And>x xs y ys. \<lbrakk> x = y; \<not> xs \<le> ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys)"
   173   shows "P ps ls" using np
   174 proof (induct ls arbitrary: ps)
   175   case Nil then show ?case
   176     by (auto simp: neq_Nil_conv elim!: not_prefix_cases intro!: base)
   177 next
   178   case (Cons y ys)
   179   then have npfx: "\<not> ps \<le> (y # ys)" by simp
   180   then obtain x xs where pv: "ps = x # xs"
   181     by (rule not_prefix_cases) auto
   182   show ?case by (metis Cons.hyps Cons_prefix_Cons npfx pv r1 r2)
   183 qed
   184 
   185 
   186 subsection {* Parallel lists *}
   187 
   188 definition
   189   parallel :: "'a list => 'a list => bool"  (infixl "\<parallel>" 50) where
   190   "(xs \<parallel> ys) = (\<not> xs \<le> ys \<and> \<not> ys \<le> xs)"
   191 
   192 lemma parallelI [intro]: "\<not> xs \<le> ys ==> \<not> ys \<le> xs ==> xs \<parallel> ys"
   193   unfolding parallel_def by blast
   194 
   195 lemma parallelE [elim]:
   196   assumes "xs \<parallel> ys"
   197   obtains "\<not> xs \<le> ys \<and> \<not> ys \<le> xs"
   198   using assms unfolding parallel_def by blast
   199 
   200 theorem prefix_cases:
   201   obtains "xs \<le> ys" | "ys < xs" | "xs \<parallel> ys"
   202   unfolding parallel_def strict_prefix_def by blast
   203 
   204 theorem parallel_decomp:
   205   "xs \<parallel> ys ==> \<exists>as b bs c cs. b \<noteq> c \<and> xs = as @ b # bs \<and> ys = as @ c # cs"
   206 proof (induct xs rule: rev_induct)
   207   case Nil
   208   then have False by auto
   209   then show ?case ..
   210 next
   211   case (snoc x xs)
   212   show ?case
   213   proof (rule prefix_cases)
   214     assume le: "xs \<le> ys"
   215     then obtain ys' where ys: "ys = xs @ ys'" ..
   216     show ?thesis
   217     proof (cases ys')
   218       assume "ys' = []"
   219       then show ?thesis by (metis append_Nil2 parallelE prefixI snoc.prems ys)
   220     next
   221       fix c cs assume ys': "ys' = c # cs"
   222       then show ?thesis
   223         by (metis Cons_eq_appendI eq_Nil_appendI parallelE prefixI
   224           same_prefix_prefix snoc.prems ys)
   225     qed
   226   next
   227     assume "ys < xs" then have "ys \<le> xs @ [x]" by (simp add: strict_prefix_def)
   228     with snoc have False by blast
   229     then show ?thesis ..
   230   next
   231     assume "xs \<parallel> ys"
   232     with snoc obtain as b bs c cs where neq: "(b::'a) \<noteq> c"
   233       and xs: "xs = as @ b # bs" and ys: "ys = as @ c # cs"
   234       by blast
   235     from xs have "xs @ [x] = as @ b # (bs @ [x])" by simp
   236     with neq ys show ?thesis by blast
   237   qed
   238 qed
   239 
   240 lemma parallel_append: "a \<parallel> b \<Longrightarrow> a @ c \<parallel> b @ d"
   241   apply (rule parallelI)
   242     apply (erule parallelE, erule conjE,
   243       induct rule: not_prefix_induct, simp+)+
   244   done
   245 
   246 lemma parallel_appendI: "xs \<parallel> ys \<Longrightarrow> x = xs @ xs' \<Longrightarrow> y = ys @ ys' \<Longrightarrow> x \<parallel> y"
   247   by (simp add: parallel_append)
   248 
   249 lemma parallel_commute: "a \<parallel> b \<longleftrightarrow> b \<parallel> a"
   250   unfolding parallel_def by auto
   251 
   252 
   253 subsection {* Postfix order on lists *}
   254 
   255 definition
   256   postfix :: "'a list => 'a list => bool"  ("(_/ >>= _)" [51, 50] 50) where
   257   "(xs >>= ys) = (\<exists>zs. xs = zs @ ys)"
   258 
   259 lemma postfixI [intro?]: "xs = zs @ ys ==> xs >>= ys"
   260   unfolding postfix_def by blast
   261 
   262 lemma postfixE [elim?]:
   263   assumes "xs >>= ys"
   264   obtains zs where "xs = zs @ ys"
   265   using assms unfolding postfix_def by blast
   266 
   267 lemma postfix_refl [iff]: "xs >>= xs"
   268   by (auto simp add: postfix_def)
   269 lemma postfix_trans: "\<lbrakk>xs >>= ys; ys >>= zs\<rbrakk> \<Longrightarrow> xs >>= zs"
   270   by (auto simp add: postfix_def)
   271 lemma postfix_antisym: "\<lbrakk>xs >>= ys; ys >>= xs\<rbrakk> \<Longrightarrow> xs = ys"
   272   by (auto simp add: postfix_def)
   273 
   274 lemma Nil_postfix [iff]: "xs >>= []"
   275   by (simp add: postfix_def)
   276 lemma postfix_Nil [simp]: "([] >>= xs) = (xs = [])"
   277   by (auto simp add: postfix_def)
   278 
   279 lemma postfix_ConsI: "xs >>= ys \<Longrightarrow> x#xs >>= ys"
   280   by (auto simp add: postfix_def)
   281 lemma postfix_ConsD: "xs >>= y#ys \<Longrightarrow> xs >>= ys"
   282   by (auto simp add: postfix_def)
   283 
   284 lemma postfix_appendI: "xs >>= ys \<Longrightarrow> zs @ xs >>= ys"
   285   by (auto simp add: postfix_def)
   286 lemma postfix_appendD: "xs >>= zs @ ys \<Longrightarrow> xs >>= ys"
   287   by (auto simp add: postfix_def)
   288 
   289 lemma postfix_is_subset: "xs >>= ys ==> set ys \<subseteq> set xs"
   290 proof -
   291   assume "xs >>= ys"
   292   then obtain zs where "xs = zs @ ys" ..
   293   then show ?thesis by (induct zs) auto
   294 qed
   295 
   296 lemma postfix_ConsD2: "x#xs >>= y#ys ==> xs >>= ys"
   297 proof -
   298   assume "x#xs >>= y#ys"
   299   then obtain zs where "x#xs = zs @ y#ys" ..
   300   then show ?thesis
   301     by (induct zs) (auto intro!: postfix_appendI postfix_ConsI)
   302 qed
   303 
   304 lemma postfix_to_prefix: "xs >>= ys \<longleftrightarrow> rev ys \<le> rev xs"
   305 proof
   306   assume "xs >>= ys"
   307   then obtain zs where "xs = zs @ ys" ..
   308   then have "rev xs = rev ys @ rev zs" by simp
   309   then show "rev ys <= rev xs" ..
   310 next
   311   assume "rev ys <= rev xs"
   312   then obtain zs where "rev xs = rev ys @ zs" ..
   313   then have "rev (rev xs) = rev zs @ rev (rev ys)" by simp
   314   then have "xs = rev zs @ ys" by simp
   315   then show "xs >>= ys" ..
   316 qed
   317 
   318 lemma distinct_postfix: "distinct xs \<Longrightarrow> xs >>= ys \<Longrightarrow> distinct ys"
   319   by (clarsimp elim!: postfixE)
   320 
   321 lemma postfix_map: "xs >>= ys \<Longrightarrow> map f xs >>= map f ys"
   322   by (auto elim!: postfixE intro: postfixI)
   323 
   324 lemma postfix_drop: "as >>= drop n as"
   325   unfolding postfix_def
   326   apply (rule exI [where x = "take n as"])
   327   apply simp
   328   done
   329 
   330 lemma postfix_take: "xs >>= ys \<Longrightarrow> xs = take (length xs - length ys) xs @ ys"
   331   by (clarsimp elim!: postfixE)
   332 
   333 lemma parallelD1: "x \<parallel> y \<Longrightarrow> \<not> x \<le> y"
   334   by blast
   335 
   336 lemma parallelD2: "x \<parallel> y \<Longrightarrow> \<not> y \<le> x"
   337   by blast
   338 
   339 lemma parallel_Nil1 [simp]: "\<not> x \<parallel> []"
   340   unfolding parallel_def by simp
   341 
   342 lemma parallel_Nil2 [simp]: "\<not> [] \<parallel> x"
   343   unfolding parallel_def by simp
   344 
   345 lemma Cons_parallelI1: "a \<noteq> b \<Longrightarrow> a # as \<parallel> b # bs"
   346   by auto
   347 
   348 lemma Cons_parallelI2: "\<lbrakk> a = b; as \<parallel> bs \<rbrakk> \<Longrightarrow> a # as \<parallel> b # bs"
   349   by (metis Cons_prefix_Cons parallelE parallelI)
   350 
   351 lemma not_equal_is_parallel:
   352   assumes neq: "xs \<noteq> ys"
   353     and len: "length xs = length ys"
   354   shows "xs \<parallel> ys"
   355   using len neq
   356 proof (induct rule: list_induct2)
   357   case Nil
   358   then show ?case by simp
   359 next
   360   case (Cons a as b bs)
   361   have ih: "as \<noteq> bs \<Longrightarrow> as \<parallel> bs" by fact
   362   show ?case
   363   proof (cases "a = b")
   364     case True
   365     then have "as \<noteq> bs" using Cons by simp
   366     then show ?thesis by (rule Cons_parallelI2 [OF True ih])
   367   next
   368     case False
   369     then show ?thesis by (rule Cons_parallelI1)
   370   qed
   371 qed
   372 
   373 
   374 subsection {* Executable code *}
   375 
   376 lemma less_eq_code [code]:
   377     "([]\<Colon>'a\<Colon>{eq, ord} list) \<le> xs \<longleftrightarrow> True"
   378     "(x\<Colon>'a\<Colon>{eq, ord}) # xs \<le> [] \<longleftrightarrow> False"
   379     "(x\<Colon>'a\<Colon>{eq, ord}) # xs \<le> y # ys \<longleftrightarrow> x = y \<and> xs \<le> ys"
   380   by simp_all
   381 
   382 lemma less_code [code]:
   383     "xs < ([]\<Colon>'a\<Colon>{eq, ord} list) \<longleftrightarrow> False"
   384     "[] < (x\<Colon>'a\<Colon>{eq, ord})# xs \<longleftrightarrow> True"
   385     "(x\<Colon>'a\<Colon>{eq, ord}) # xs < y # ys \<longleftrightarrow> x = y \<and> xs < ys"
   386   unfolding strict_prefix_def by auto
   387 
   388 lemmas [code] = postfix_to_prefix
   389 
   390 end