src/HOL/Library/Product_Vector.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 34110 4c113c744b86
child 36332 3ddb2bc07784
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation "*" :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: expand_prod_eq scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: expand_prod_eq scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: expand_prod_eq)
    36   show "scaleR 1 x = x"
    37     by (simp add: expand_prod_eq)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation
    45   "*" :: (topological_space, topological_space) topological_space
    46 begin
    47 
    48 definition open_prod_def:
    49   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
    50     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
    51 
    52 instance proof
    53   show "open (UNIV :: ('a \<times> 'b) set)"
    54     unfolding open_prod_def by auto
    55 next
    56   fix S T :: "('a \<times> 'b) set"
    57   assume "open S" "open T" thus "open (S \<inter> T)"
    58     unfolding open_prod_def
    59     apply clarify
    60     apply (drule (1) bspec)+
    61     apply (clarify, rename_tac Sa Ta Sb Tb)
    62     apply (rule_tac x="Sa \<inter> Ta" in exI)
    63     apply (rule_tac x="Sb \<inter> Tb" in exI)
    64     apply (simp add: open_Int)
    65     apply fast
    66     done
    67 next
    68   fix K :: "('a \<times> 'b) set set"
    69   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
    70     unfolding open_prod_def by fast
    71 qed
    72 
    73 end
    74 
    75 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
    76 unfolding open_prod_def by auto
    77 
    78 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
    79 by auto
    80 
    81 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
    82 by auto
    83 
    84 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
    85 by (simp add: fst_vimage_eq_Times open_Times)
    86 
    87 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
    88 by (simp add: snd_vimage_eq_Times open_Times)
    89 
    90 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
    91 unfolding closed_open vimage_Compl [symmetric]
    92 by (rule open_vimage_fst)
    93 
    94 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
    95 unfolding closed_open vimage_Compl [symmetric]
    96 by (rule open_vimage_snd)
    97 
    98 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
    99 proof -
   100   have "S \<times> T = (fst -` S) \<inter> (snd -` T)" by auto
   101   thus "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   102     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
   103 qed
   104 
   105 lemma openI: (* TODO: move *)
   106   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
   107   shows "open S"
   108 proof -
   109   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
   110   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
   111   ultimately show "open S" by simp
   112 qed
   113 
   114 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
   115   unfolding image_def subset_eq by force
   116 
   117 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
   118   unfolding image_def subset_eq by force
   119 
   120 lemma open_image_fst: assumes "open S" shows "open (fst ` S)"
   121 proof (rule openI)
   122   fix x assume "x \<in> fst ` S"
   123   then obtain y where "(x, y) \<in> S" by auto
   124   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   125     using `open S` unfolding open_prod_def by auto
   126   from `A \<times> B \<subseteq> S` `y \<in> B` have "A \<subseteq> fst ` S" by (rule subset_fst_imageI)
   127   with `open A` `x \<in> A` have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S" by simp
   128   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" by - (rule exI)
   129 qed
   130 
   131 lemma open_image_snd: assumes "open S" shows "open (snd ` S)"
   132 proof (rule openI)
   133   fix y assume "y \<in> snd ` S"
   134   then obtain x where "(x, y) \<in> S" by auto
   135   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   136     using `open S` unfolding open_prod_def by auto
   137   from `A \<times> B \<subseteq> S` `x \<in> A` have "B \<subseteq> snd ` S" by (rule subset_snd_imageI)
   138   with `open B` `y \<in> B` have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S" by simp
   139   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" by - (rule exI)
   140 qed
   141 
   142 subsection {* Product is a metric space *}
   143 
   144 instantiation
   145   "*" :: (metric_space, metric_space) metric_space
   146 begin
   147 
   148 definition dist_prod_def:
   149   "dist (x::'a \<times> 'b) y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
   150 
   151 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
   152   unfolding dist_prod_def by simp
   153 
   154 instance proof
   155   fix x y :: "'a \<times> 'b"
   156   show "dist x y = 0 \<longleftrightarrow> x = y"
   157     unfolding dist_prod_def expand_prod_eq by simp
   158 next
   159   fix x y z :: "'a \<times> 'b"
   160   show "dist x y \<le> dist x z + dist y z"
   161     unfolding dist_prod_def
   162     by (intro order_trans [OF _ real_sqrt_sum_squares_triangle_ineq]
   163         real_sqrt_le_mono add_mono power_mono dist_triangle2 zero_le_dist)
   164 next
   165   (* FIXME: long proof! *)
   166   (* Maybe it would be easier to define topological spaces *)
   167   (* in terms of neighborhoods instead of open sets? *)
   168   fix S :: "('a \<times> 'b) set"
   169   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   170   proof
   171     assume "open S" thus "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   172     unfolding open_prod_def open_dist
   173     apply safe
   174     apply (drule (1) bspec)
   175     apply clarify
   176     apply (drule (1) bspec)+
   177     apply (clarify, rename_tac r s)
   178     apply (rule_tac x="min r s" in exI, simp)
   179     apply (clarify, rename_tac c d)
   180     apply (erule subsetD)
   181     apply (simp add: dist_Pair_Pair)
   182     apply (rule conjI)
   183     apply (drule spec, erule mp)
   184     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge1])
   185     apply (drule spec, erule mp)
   186     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge2])
   187     done
   188   next
   189     assume "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" thus "open S"
   190     unfolding open_prod_def open_dist
   191     apply safe
   192     apply (drule (1) bspec)
   193     apply clarify
   194     apply (subgoal_tac "\<exists>r>0. \<exists>s>0. e = sqrt (r\<twosuperior> + s\<twosuperior>)")
   195     apply clarify
   196     apply (rule_tac x="{y. dist y a < r}" in exI)
   197     apply (rule_tac x="{y. dist y b < s}" in exI)
   198     apply (rule conjI)
   199     apply clarify
   200     apply (rule_tac x="r - dist x a" in exI, rule conjI, simp)
   201     apply clarify
   202     apply (simp add: less_diff_eq)
   203     apply (erule le_less_trans [OF dist_triangle])
   204     apply (rule conjI)
   205     apply clarify
   206     apply (rule_tac x="s - dist x b" in exI, rule conjI, simp)
   207     apply clarify
   208     apply (simp add: less_diff_eq)
   209     apply (erule le_less_trans [OF dist_triangle])
   210     apply (rule conjI)
   211     apply simp
   212     apply (clarify, rename_tac c d)
   213     apply (drule spec, erule mp)
   214     apply (simp add: dist_Pair_Pair add_strict_mono power_strict_mono)
   215     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   216     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   217     apply (simp add: power_divide)
   218     done
   219   qed
   220 qed
   221 
   222 end
   223 
   224 subsection {* Continuity of operations *}
   225 
   226 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   227 unfolding dist_prod_def by simp
   228 
   229 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   230 unfolding dist_prod_def by simp
   231 
   232 lemma tendsto_fst [tendsto_intros]:
   233   assumes "(f ---> a) net"
   234   shows "((\<lambda>x. fst (f x)) ---> fst a) net"
   235 proof (rule topological_tendstoI)
   236   fix S assume "open S" "fst a \<in> S"
   237   then have "open (fst -` S)" "a \<in> fst -` S"
   238     unfolding open_prod_def
   239     apply simp_all
   240     apply clarify
   241     apply (rule exI, erule conjI)
   242     apply (rule exI, rule conjI [OF open_UNIV])
   243     apply auto
   244     done
   245   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) net"
   246     by (rule topological_tendstoD)
   247   then show "eventually (\<lambda>x. fst (f x) \<in> S) net"
   248     by simp
   249 qed
   250 
   251 lemma tendsto_snd [tendsto_intros]:
   252   assumes "(f ---> a) net"
   253   shows "((\<lambda>x. snd (f x)) ---> snd a) net"
   254 proof (rule topological_tendstoI)
   255   fix S assume "open S" "snd a \<in> S"
   256   then have "open (snd -` S)" "a \<in> snd -` S"
   257     unfolding open_prod_def
   258     apply simp_all
   259     apply clarify
   260     apply (rule exI, rule conjI [OF open_UNIV])
   261     apply (rule exI, erule conjI)
   262     apply auto
   263     done
   264   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) net"
   265     by (rule topological_tendstoD)
   266   then show "eventually (\<lambda>x. snd (f x) \<in> S) net"
   267     by simp
   268 qed
   269 
   270 lemma tendsto_Pair [tendsto_intros]:
   271   assumes "(f ---> a) net" and "(g ---> b) net"
   272   shows "((\<lambda>x. (f x, g x)) ---> (a, b)) net"
   273 proof (rule topological_tendstoI)
   274   fix S assume "open S" "(a, b) \<in> S"
   275   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
   276     unfolding open_prod_def by auto
   277   have "eventually (\<lambda>x. f x \<in> A) net"
   278     using `(f ---> a) net` `open A` `a \<in> A`
   279     by (rule topological_tendstoD)
   280   moreover
   281   have "eventually (\<lambda>x. g x \<in> B) net"
   282     using `(g ---> b) net` `open B` `b \<in> B`
   283     by (rule topological_tendstoD)
   284   ultimately
   285   show "eventually (\<lambda>x. (f x, g x) \<in> S) net"
   286     by (rule eventually_elim2)
   287        (simp add: subsetD [OF `A \<times> B \<subseteq> S`])
   288 qed
   289 
   290 lemma LIMSEQ_fst: "(X ----> a) \<Longrightarrow> (\<lambda>n. fst (X n)) ----> fst a"
   291 unfolding LIMSEQ_conv_tendsto by (rule tendsto_fst)
   292 
   293 lemma LIMSEQ_snd: "(X ----> a) \<Longrightarrow> (\<lambda>n. snd (X n)) ----> snd a"
   294 unfolding LIMSEQ_conv_tendsto by (rule tendsto_snd)
   295 
   296 lemma LIMSEQ_Pair:
   297   assumes "X ----> a" and "Y ----> b"
   298   shows "(\<lambda>n. (X n, Y n)) ----> (a, b)"
   299 using assms unfolding LIMSEQ_conv_tendsto
   300 by (rule tendsto_Pair)
   301 
   302 lemma LIM_fst: "f -- x --> a \<Longrightarrow> (\<lambda>x. fst (f x)) -- x --> fst a"
   303 unfolding LIM_conv_tendsto by (rule tendsto_fst)
   304 
   305 lemma LIM_snd: "f -- x --> a \<Longrightarrow> (\<lambda>x. snd (f x)) -- x --> snd a"
   306 unfolding LIM_conv_tendsto by (rule tendsto_snd)
   307 
   308 lemma LIM_Pair:
   309   assumes "f -- x --> a" and "g -- x --> b"
   310   shows "(\<lambda>x. (f x, g x)) -- x --> (a, b)"
   311 using assms unfolding LIM_conv_tendsto
   312 by (rule tendsto_Pair)
   313 
   314 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   315 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   316 
   317 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   318 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   319 
   320 lemma Cauchy_Pair:
   321   assumes "Cauchy X" and "Cauchy Y"
   322   shows "Cauchy (\<lambda>n. (X n, Y n))"
   323 proof (rule metric_CauchyI)
   324   fix r :: real assume "0 < r"
   325   then have "0 < r / sqrt 2" (is "0 < ?s")
   326     by (simp add: divide_pos_pos)
   327   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   328     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   329   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   330     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   331   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   332     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   333   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   334 qed
   335 
   336 lemma isCont_Pair [simp]:
   337   "\<lbrakk>isCont f x; isCont g x\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) x"
   338   unfolding isCont_def by (rule LIM_Pair)
   339 
   340 subsection {* Product is a complete metric space *}
   341 
   342 instance "*" :: (complete_space, complete_space) complete_space
   343 proof
   344   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   345   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   346     using Cauchy_fst [OF `Cauchy X`]
   347     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   348   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   349     using Cauchy_snd [OF `Cauchy X`]
   350     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   351   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   352     using LIMSEQ_Pair [OF 1 2] by simp
   353   then show "convergent X"
   354     by (rule convergentI)
   355 qed
   356 
   357 subsection {* Product is a normed vector space *}
   358 
   359 instantiation
   360   "*" :: (real_normed_vector, real_normed_vector) real_normed_vector
   361 begin
   362 
   363 definition norm_prod_def:
   364   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
   365 
   366 definition sgn_prod_def:
   367   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   368 
   369 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
   370   unfolding norm_prod_def by simp
   371 
   372 instance proof
   373   fix r :: real and x y :: "'a \<times> 'b"
   374   show "0 \<le> norm x"
   375     unfolding norm_prod_def by simp
   376   show "norm x = 0 \<longleftrightarrow> x = 0"
   377     unfolding norm_prod_def
   378     by (simp add: expand_prod_eq)
   379   show "norm (x + y) \<le> norm x + norm y"
   380     unfolding norm_prod_def
   381     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   382     apply (simp add: add_mono power_mono norm_triangle_ineq)
   383     done
   384   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   385     unfolding norm_prod_def
   386     apply (simp add: power_mult_distrib)
   387     apply (simp add: right_distrib [symmetric])
   388     apply (simp add: real_sqrt_mult_distrib)
   389     done
   390   show "sgn x = scaleR (inverse (norm x)) x"
   391     by (rule sgn_prod_def)
   392   show "dist x y = norm (x - y)"
   393     unfolding dist_prod_def norm_prod_def
   394     by (simp add: dist_norm)
   395 qed
   396 
   397 end
   398 
   399 instance "*" :: (banach, banach) banach ..
   400 
   401 subsection {* Product is an inner product space *}
   402 
   403 instantiation "*" :: (real_inner, real_inner) real_inner
   404 begin
   405 
   406 definition inner_prod_def:
   407   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   408 
   409 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   410   unfolding inner_prod_def by simp
   411 
   412 instance proof
   413   fix r :: real
   414   fix x y z :: "'a::real_inner * 'b::real_inner"
   415   show "inner x y = inner y x"
   416     unfolding inner_prod_def
   417     by (simp add: inner_commute)
   418   show "inner (x + y) z = inner x z + inner y z"
   419     unfolding inner_prod_def
   420     by (simp add: inner_add_left)
   421   show "inner (scaleR r x) y = r * inner x y"
   422     unfolding inner_prod_def
   423     by (simp add: right_distrib)
   424   show "0 \<le> inner x x"
   425     unfolding inner_prod_def
   426     by (intro add_nonneg_nonneg inner_ge_zero)
   427   show "inner x x = 0 \<longleftrightarrow> x = 0"
   428     unfolding inner_prod_def expand_prod_eq
   429     by (simp add: add_nonneg_eq_0_iff)
   430   show "norm x = sqrt (inner x x)"
   431     unfolding norm_prod_def inner_prod_def
   432     by (simp add: power2_norm_eq_inner)
   433 qed
   434 
   435 end
   436 
   437 subsection {* Pair operations are linear *}
   438 
   439 interpretation fst: bounded_linear fst
   440   apply (unfold_locales)
   441   apply (rule fst_add)
   442   apply (rule fst_scaleR)
   443   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   444   done
   445 
   446 interpretation snd: bounded_linear snd
   447   apply (unfold_locales)
   448   apply (rule snd_add)
   449   apply (rule snd_scaleR)
   450   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   451   done
   452 
   453 text {* TODO: move to NthRoot *}
   454 lemma sqrt_add_le_add_sqrt:
   455   assumes x: "0 \<le> x" and y: "0 \<le> y"
   456   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   457 apply (rule power2_le_imp_le)
   458 apply (simp add: real_sum_squared_expand add_nonneg_nonneg x y)
   459 apply (simp add: mult_nonneg_nonneg x y)
   460 apply (simp add: add_nonneg_nonneg x y)
   461 done
   462 
   463 lemma bounded_linear_Pair:
   464   assumes f: "bounded_linear f"
   465   assumes g: "bounded_linear g"
   466   shows "bounded_linear (\<lambda>x. (f x, g x))"
   467 proof
   468   interpret f: bounded_linear f by fact
   469   interpret g: bounded_linear g by fact
   470   fix x y and r :: real
   471   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   472     by (simp add: f.add g.add)
   473   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   474     by (simp add: f.scaleR g.scaleR)
   475   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   476     using f.pos_bounded by fast
   477   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   478     using g.pos_bounded by fast
   479   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   480     apply (rule allI)
   481     apply (simp add: norm_Pair)
   482     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   483     apply (simp add: right_distrib)
   484     apply (rule add_mono [OF norm_f norm_g])
   485     done
   486   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   487 qed
   488 
   489 subsection {* Frechet derivatives involving pairs *}
   490 
   491 lemma FDERIV_Pair:
   492   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
   493   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
   494 apply (rule FDERIV_I)
   495 apply (rule bounded_linear_Pair)
   496 apply (rule FDERIV_bounded_linear [OF f])
   497 apply (rule FDERIV_bounded_linear [OF g])
   498 apply (simp add: norm_Pair)
   499 apply (rule real_LIM_sandwich_zero)
   500 apply (rule LIM_add_zero)
   501 apply (rule FDERIV_D [OF f])
   502 apply (rule FDERIV_D [OF g])
   503 apply (rename_tac h)
   504 apply (simp add: divide_nonneg_pos)
   505 apply (rename_tac h)
   506 apply (subst add_divide_distrib [symmetric])
   507 apply (rule divide_right_mono [OF _ norm_ge_zero])
   508 apply (rule order_trans [OF sqrt_add_le_add_sqrt])
   509 apply simp
   510 apply simp
   511 apply simp
   512 done
   513 
   514 end