src/HOL/Log.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 33716 c7b42ad3fadf
child 36622 e393a91f86df
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title       : Log.thy
     2     Author      : Jacques D. Fleuriot
     3                   Additional contributions by Jeremy Avigad
     4     Copyright   : 2000,2001 University of Edinburgh
     5 *)
     6 
     7 header{*Logarithms: Standard Version*}
     8 
     9 theory Log
    10 imports Transcendental
    11 begin
    12 
    13 definition
    14   powr  :: "[real,real] => real"     (infixr "powr" 80) where
    15     --{*exponentation with real exponent*}
    16   "x powr a = exp(a * ln x)"
    17 
    18 definition
    19   log :: "[real,real] => real" where
    20     --{*logarithm of @{term x} to base @{term a}*}
    21   "log a x = ln x / ln a"
    22 
    23 
    24 
    25 lemma powr_one_eq_one [simp]: "1 powr a = 1"
    26 by (simp add: powr_def)
    27 
    28 lemma powr_zero_eq_one [simp]: "x powr 0 = 1"
    29 by (simp add: powr_def)
    30 
    31 lemma powr_one_gt_zero_iff [simp]: "(x powr 1 = x) = (0 < x)"
    32 by (simp add: powr_def)
    33 declare powr_one_gt_zero_iff [THEN iffD2, simp]
    34 
    35 lemma powr_mult: 
    36       "[| 0 < x; 0 < y |] ==> (x * y) powr a = (x powr a) * (y powr a)"
    37 by (simp add: powr_def exp_add [symmetric] ln_mult right_distrib)
    38 
    39 lemma powr_gt_zero [simp]: "0 < x powr a"
    40 by (simp add: powr_def)
    41 
    42 lemma powr_ge_pzero [simp]: "0 <= x powr y"
    43 by (rule order_less_imp_le, rule powr_gt_zero)
    44 
    45 lemma powr_not_zero [simp]: "x powr a \<noteq> 0"
    46 by (simp add: powr_def)
    47 
    48 lemma powr_divide:
    49      "[| 0 < x; 0 < y |] ==> (x / y) powr a = (x powr a)/(y powr a)"
    50 apply (simp add: divide_inverse positive_imp_inverse_positive powr_mult)
    51 apply (simp add: powr_def exp_minus [symmetric] exp_add [symmetric] ln_inverse)
    52 done
    53 
    54 lemma powr_divide2: "x powr a / x powr b = x powr (a - b)"
    55   apply (simp add: powr_def)
    56   apply (subst exp_diff [THEN sym])
    57   apply (simp add: left_diff_distrib)
    58 done
    59 
    60 lemma powr_add: "x powr (a + b) = (x powr a) * (x powr b)"
    61 by (simp add: powr_def exp_add [symmetric] left_distrib)
    62 
    63 lemma powr_powr: "(x powr a) powr b = x powr (a * b)"
    64 by (simp add: powr_def)
    65 
    66 lemma powr_powr_swap: "(x powr a) powr b = (x powr b) powr a"
    67 by (simp add: powr_powr real_mult_commute)
    68 
    69 lemma powr_minus: "x powr (-a) = inverse (x powr a)"
    70 by (simp add: powr_def exp_minus [symmetric])
    71 
    72 lemma powr_minus_divide: "x powr (-a) = 1/(x powr a)"
    73 by (simp add: divide_inverse powr_minus)
    74 
    75 lemma powr_less_mono: "[| a < b; 1 < x |] ==> x powr a < x powr b"
    76 by (simp add: powr_def)
    77 
    78 lemma powr_less_cancel: "[| x powr a < x powr b; 1 < x |] ==> a < b"
    79 by (simp add: powr_def)
    80 
    81 lemma powr_less_cancel_iff [simp]: "1 < x ==> (x powr a < x powr b) = (a < b)"
    82 by (blast intro: powr_less_cancel powr_less_mono)
    83 
    84 lemma powr_le_cancel_iff [simp]: "1 < x ==> (x powr a \<le> x powr b) = (a \<le> b)"
    85 by (simp add: linorder_not_less [symmetric])
    86 
    87 lemma log_ln: "ln x = log (exp(1)) x"
    88 by (simp add: log_def)
    89 
    90 lemma DERIV_log: "x > 0 ==> DERIV (%y. log b y) x :> 1 / (ln b * x)"
    91   apply (subst log_def)
    92   apply (subgoal_tac "(%y. ln y / ln b) = (%y. (1 / ln b) * ln y)")
    93   apply (erule ssubst)
    94   apply (subgoal_tac "1 / (ln b * x) = (1 / ln b) * (1 / x)")
    95   apply (erule ssubst)
    96   apply (rule DERIV_cmult)
    97   apply (erule DERIV_ln_divide)
    98   apply auto
    99 done
   100 
   101 lemma powr_log_cancel [simp]:
   102      "[| 0 < a; a \<noteq> 1; 0 < x |] ==> a powr (log a x) = x"
   103 by (simp add: powr_def log_def)
   104 
   105 lemma log_powr_cancel [simp]: "[| 0 < a; a \<noteq> 1 |] ==> log a (a powr y) = y"
   106 by (simp add: log_def powr_def)
   107 
   108 lemma log_mult: 
   109      "[| 0 < a; a \<noteq> 1; 0 < x; 0 < y |]  
   110       ==> log a (x * y) = log a x + log a y"
   111 by (simp add: log_def ln_mult divide_inverse left_distrib)
   112 
   113 lemma log_eq_div_ln_mult_log: 
   114      "[| 0 < a; a \<noteq> 1; 0 < b; b \<noteq> 1; 0 < x |]  
   115       ==> log a x = (ln b/ln a) * log b x"
   116 by (simp add: log_def divide_inverse)
   117 
   118 text{*Base 10 logarithms*}
   119 lemma log_base_10_eq1: "0 < x ==> log 10 x = (ln (exp 1) / ln 10) * ln x"
   120 by (simp add: log_def)
   121 
   122 lemma log_base_10_eq2: "0 < x ==> log 10 x = (log 10 (exp 1)) * ln x"
   123 by (simp add: log_def)
   124 
   125 lemma log_one [simp]: "log a 1 = 0"
   126 by (simp add: log_def)
   127 
   128 lemma log_eq_one [simp]: "[| 0 < a; a \<noteq> 1 |] ==> log a a = 1"
   129 by (simp add: log_def)
   130 
   131 lemma log_inverse:
   132      "[| 0 < a; a \<noteq> 1; 0 < x |] ==> log a (inverse x) = - log a x"
   133 apply (rule_tac a1 = "log a x" in add_left_cancel [THEN iffD1])
   134 apply (simp add: log_mult [symmetric])
   135 done
   136 
   137 lemma log_divide:
   138      "[|0 < a; a \<noteq> 1; 0 < x; 0 < y|] ==> log a (x/y) = log a x - log a y"
   139 by (simp add: log_mult divide_inverse log_inverse)
   140 
   141 lemma log_less_cancel_iff [simp]:
   142      "[| 1 < a; 0 < x; 0 < y |] ==> (log a x < log a y) = (x < y)"
   143 apply safe
   144 apply (rule_tac [2] powr_less_cancel)
   145 apply (drule_tac a = "log a x" in powr_less_mono, auto)
   146 done
   147 
   148 lemma log_le_cancel_iff [simp]:
   149      "[| 1 < a; 0 < x; 0 < y |] ==> (log a x \<le> log a y) = (x \<le> y)"
   150 by (simp add: linorder_not_less [symmetric])
   151 
   152 
   153 lemma powr_realpow: "0 < x ==> x powr (real n) = x^n"
   154   apply (induct n, simp)
   155   apply (subgoal_tac "real(Suc n) = real n + 1")
   156   apply (erule ssubst)
   157   apply (subst powr_add, simp, simp)
   158 done
   159 
   160 lemma powr_realpow2: "0 <= x ==> 0 < n ==> x^n = (if (x = 0) then 0
   161   else x powr (real n))"
   162   apply (case_tac "x = 0", simp, simp)
   163   apply (rule powr_realpow [THEN sym], simp)
   164 done
   165 
   166 lemma ln_powr: "0 < x ==> 0 < y ==> ln(x powr y) = y * ln x"
   167 by (unfold powr_def, simp)
   168 
   169 lemma log_powr: "0 < x ==> 0 \<le> y ==> log b (x powr y) = y * log b x"
   170   apply (case_tac "y = 0")
   171   apply force
   172   apply (auto simp add: log_def ln_powr field_simps)
   173 done
   174 
   175 lemma log_nat_power: "0 < x ==> log b (x^n) = real n * log b x"
   176   apply (subst powr_realpow [symmetric])
   177   apply (auto simp add: log_powr)
   178 done
   179 
   180 lemma ln_bound: "1 <= x ==> ln x <= x"
   181   apply (subgoal_tac "ln(1 + (x - 1)) <= x - 1")
   182   apply simp
   183   apply (rule ln_add_one_self_le_self, simp)
   184 done
   185 
   186 lemma powr_mono: "a <= b ==> 1 <= x ==> x powr a <= x powr b"
   187   apply (case_tac "x = 1", simp)
   188   apply (case_tac "a = b", simp)
   189   apply (rule order_less_imp_le)
   190   apply (rule powr_less_mono, auto)
   191 done
   192 
   193 lemma ge_one_powr_ge_zero: "1 <= x ==> 0 <= a ==> 1 <= x powr a"
   194   apply (subst powr_zero_eq_one [THEN sym])
   195   apply (rule powr_mono, assumption+)
   196 done
   197 
   198 lemma powr_less_mono2: "0 < a ==> 0 < x ==> x < y ==> x powr a <
   199     y powr a"
   200   apply (unfold powr_def)
   201   apply (rule exp_less_mono)
   202   apply (rule mult_strict_left_mono)
   203   apply (subst ln_less_cancel_iff, assumption)
   204   apply (rule order_less_trans)
   205   prefer 2
   206   apply assumption+
   207 done
   208 
   209 lemma powr_less_mono2_neg: "a < 0 ==> 0 < x ==> x < y ==> y powr a <
   210     x powr a"
   211   apply (unfold powr_def)
   212   apply (rule exp_less_mono)
   213   apply (rule mult_strict_left_mono_neg)
   214   apply (subst ln_less_cancel_iff)
   215   apply assumption
   216   apply (rule order_less_trans)
   217   prefer 2
   218   apply assumption+
   219 done
   220 
   221 lemma powr_mono2: "0 <= a ==> 0 < x ==> x <= y ==> x powr a <= y powr a"
   222   apply (case_tac "a = 0", simp)
   223   apply (case_tac "x = y", simp)
   224   apply (rule order_less_imp_le)
   225   apply (rule powr_less_mono2, auto)
   226 done
   227 
   228 lemma ln_powr_bound: "1 <= x ==> 0 < a ==> ln x <= (x powr a) / a"
   229   apply (rule mult_imp_le_div_pos)
   230   apply (assumption)
   231   apply (subst mult_commute)
   232   apply (subst ln_powr [THEN sym])
   233   apply auto
   234   apply (rule ln_bound)
   235   apply (erule ge_one_powr_ge_zero)
   236   apply (erule order_less_imp_le)
   237 done
   238 
   239 lemma ln_powr_bound2: "1 < x ==> 0 < a ==> (ln x) powr a <= (a powr a) * x"
   240 proof -
   241   assume "1 < x" and "0 < a"
   242   then have "ln x <= (x powr (1 / a)) / (1 / a)"
   243     apply (intro ln_powr_bound)
   244     apply (erule order_less_imp_le)
   245     apply (rule divide_pos_pos)
   246     apply simp_all
   247     done
   248   also have "... = a * (x powr (1 / a))"
   249     by simp
   250   finally have "(ln x) powr a <= (a * (x powr (1 / a))) powr a"
   251     apply (intro powr_mono2)
   252     apply (rule order_less_imp_le, rule prems)
   253     apply (rule ln_gt_zero)
   254     apply (rule prems)
   255     apply assumption
   256     done
   257   also have "... = (a powr a) * ((x powr (1 / a)) powr a)"
   258     apply (rule powr_mult)
   259     apply (rule prems)
   260     apply (rule powr_gt_zero)
   261     done
   262   also have "(x powr (1 / a)) powr a = x powr ((1 / a) * a)"
   263     by (rule powr_powr)
   264   also have "... = x"
   265     apply simp
   266     apply (subgoal_tac "a ~= 0")
   267     apply (insert prems, auto)
   268     done
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma LIMSEQ_neg_powr: "0 < s ==> (%x. (real x) powr - s) ----> 0"
   273   apply (unfold LIMSEQ_iff)
   274   apply clarsimp
   275   apply (rule_tac x = "natfloor(r powr (1 / - s)) + 1" in exI)
   276   apply clarify
   277   proof -
   278     fix r fix n
   279     assume "0 < s" and "0 < r" and "natfloor (r powr (1 / - s)) + 1 <= n"
   280     have "r powr (1 / - s) < real(natfloor(r powr (1 / - s))) + 1"
   281       by (rule real_natfloor_add_one_gt)
   282     also have "... = real(natfloor(r powr (1 / -s)) + 1)"
   283       by simp
   284     also have "... <= real n"
   285       apply (subst real_of_nat_le_iff)
   286       apply (rule prems)
   287       done
   288     finally have "r powr (1 / - s) < real n".
   289     then have "real n powr (- s) < (r powr (1 / - s)) powr - s" 
   290       apply (intro powr_less_mono2_neg)
   291       apply (auto simp add: prems)
   292       done
   293     also have "... = r"
   294       by (simp add: powr_powr prems less_imp_neq [THEN not_sym])
   295     finally show "real n powr - s < r" .
   296   qed
   297 
   298 end