src/HOL/Nat.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 35064 1bdef0c013d3
child 35121 36c0a6dd8c6f
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Product_Type Fields
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 subsection {* Type nat *}
    34 
    35 text {* Type definition *}
    36 
    37 inductive Nat :: "ind \<Rightarrow> bool"
    38 where
    39     Zero_RepI: "Nat Zero_Rep"
    40   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    41 
    42 global
    43 
    44 typedef (open Nat)
    45   nat = Nat
    46   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    47 
    48 constdefs
    49   Suc ::   "nat => nat"
    50   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    51 
    52 local
    53 
    54 instantiation nat :: zero
    55 begin
    56 
    57 definition Zero_nat_def [code del]:
    58   "0 = Abs_Nat Zero_Rep"
    59 
    60 instance ..
    61 
    62 end
    63 
    64 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    65   by (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    66     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 rep_datatype "0 \<Colon> nat" Suc
    75   apply (unfold Zero_nat_def Suc_def)
    76      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    77      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    78      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    79     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    80       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    81       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    82       Suc_Rep_inject' Rep_Nat_inject)
    83   done
    84 
    85 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    86   -- {* for backward compatibility -- names of variables differ *}
    87   fixes n
    88   assumes "P 0"
    89     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    90   shows "P n"
    91   using assms by (rule nat.induct)
    92 
    93 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    94 
    95 lemmas nat_rec_0 = nat.recs(1)
    96   and nat_rec_Suc = nat.recs(2)
    97 
    98 lemmas nat_case_0 = nat.cases(1)
    99   and nat_case_Suc = nat.cases(2)
   100    
   101 
   102 text {* Injectiveness and distinctness lemmas *}
   103 
   104 lemma inj_Suc[simp]: "inj_on Suc N"
   105   by (simp add: inj_on_def)
   106 
   107 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   108 by (rule notE, rule Suc_not_Zero)
   109 
   110 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   111 by (rule Suc_neq_Zero, erule sym)
   112 
   113 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   114 by (rule inj_Suc [THEN injD])
   115 
   116 lemma n_not_Suc_n: "n \<noteq> Suc n"
   117 by (induct n) simp_all
   118 
   119 lemma Suc_n_not_n: "Suc n \<noteq> n"
   120 by (rule not_sym, rule n_not_Suc_n)
   121 
   122 text {* A special form of induction for reasoning
   123   about @{term "m < n"} and @{term "m - n"} *}
   124 
   125 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   126     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   127   apply (rule_tac x = m in spec)
   128   apply (induct n)
   129   prefer 2
   130   apply (rule allI)
   131   apply (induct_tac x, iprover+)
   132   done
   133 
   134 
   135 subsection {* Arithmetic operators *}
   136 
   137 instantiation nat :: "{minus, comm_monoid_add}"
   138 begin
   139 
   140 primrec plus_nat
   141 where
   142   add_0:      "0 + n = (n\<Colon>nat)"
   143   | add_Suc:  "Suc m + n = Suc (m + n)"
   144 
   145 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   146   by (induct m) simp_all
   147 
   148 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   149   by (induct m) simp_all
   150 
   151 declare add_0 [code]
   152 
   153 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   154   by simp
   155 
   156 primrec minus_nat
   157 where
   158   diff_0:     "m - 0 = (m\<Colon>nat)"
   159   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   160 
   161 declare diff_Suc [simp del]
   162 declare diff_0 [code]
   163 
   164 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   165   by (induct n) (simp_all add: diff_Suc)
   166 
   167 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   168   by (induct n) (simp_all add: diff_Suc)
   169 
   170 instance proof
   171   fix n m q :: nat
   172   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   173   show "n + m = m + n" by (induct n) simp_all
   174   show "0 + n = n" by simp
   175 qed
   176 
   177 end
   178 
   179 hide (open) fact add_0 add_0_right diff_0
   180 
   181 instantiation nat :: comm_semiring_1_cancel
   182 begin
   183 
   184 definition
   185   One_nat_def [simp]: "1 = Suc 0"
   186 
   187 primrec times_nat
   188 where
   189   mult_0:     "0 * n = (0\<Colon>nat)"
   190   | mult_Suc: "Suc m * n = n + (m * n)"
   191 
   192 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   193   by (induct m) simp_all
   194 
   195 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   196   by (induct m) (simp_all add: add_left_commute)
   197 
   198 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   199   by (induct m) (simp_all add: add_assoc)
   200 
   201 instance proof
   202   fix n m q :: nat
   203   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   204   show "1 * n = n" unfolding One_nat_def by simp
   205   show "n * m = m * n" by (induct n) simp_all
   206   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   207   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   208   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   209 qed
   210 
   211 end
   212 
   213 subsubsection {* Addition *}
   214 
   215 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   216   by (rule add_assoc)
   217 
   218 lemma nat_add_commute: "m + n = n + (m::nat)"
   219   by (rule add_commute)
   220 
   221 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   222   by (rule add_left_commute)
   223 
   224 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   225   by (rule add_left_cancel)
   226 
   227 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   228   by (rule add_right_cancel)
   229 
   230 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   231 
   232 lemma add_is_0 [iff]:
   233   fixes m n :: nat
   234   shows "(m + n = 0) = (m = 0 & n = 0)"
   235   by (cases m) simp_all
   236 
   237 lemma add_is_1:
   238   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   239   by (cases m) simp_all
   240 
   241 lemma one_is_add:
   242   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   243   by (rule trans, rule eq_commute, rule add_is_1)
   244 
   245 lemma add_eq_self_zero:
   246   fixes m n :: nat
   247   shows "m + n = m \<Longrightarrow> n = 0"
   248   by (induct m) simp_all
   249 
   250 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   251   apply (induct k)
   252    apply simp
   253   apply(drule comp_inj_on[OF _ inj_Suc])
   254   apply (simp add:o_def)
   255   done
   256 
   257 
   258 subsubsection {* Difference *}
   259 
   260 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   261   by (induct m) simp_all
   262 
   263 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   264   by (induct i j rule: diff_induct) simp_all
   265 
   266 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   267   by (simp add: diff_diff_left)
   268 
   269 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   270   by (simp add: diff_diff_left add_commute)
   271 
   272 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   273   by (induct n) simp_all
   274 
   275 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   276   by (simp add: diff_add_inverse add_commute [of m n])
   277 
   278 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   279   by (induct k) simp_all
   280 
   281 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   282   by (simp add: diff_cancel add_commute)
   283 
   284 lemma diff_add_0: "n - (n + m) = (0::nat)"
   285   by (induct n) simp_all
   286 
   287 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   288   unfolding One_nat_def by simp
   289 
   290 text {* Difference distributes over multiplication *}
   291 
   292 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   293 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   294 
   295 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   296 by (simp add: diff_mult_distrib mult_commute [of k])
   297   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   298 
   299 
   300 subsubsection {* Multiplication *}
   301 
   302 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   303   by (rule mult_assoc)
   304 
   305 lemma nat_mult_commute: "m * n = n * (m::nat)"
   306   by (rule mult_commute)
   307 
   308 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   309   by (rule right_distrib)
   310 
   311 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   312   by (induct m) auto
   313 
   314 lemmas nat_distrib =
   315   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   316 
   317 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   318   apply (induct m)
   319    apply simp
   320   apply (induct n)
   321    apply auto
   322   done
   323 
   324 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   325   apply (rule trans)
   326   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   327   done
   328 
   329 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   330   unfolding One_nat_def by (rule mult_eq_1_iff)
   331 
   332 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   333   unfolding One_nat_def by (rule one_eq_mult_iff)
   334 
   335 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   336 proof -
   337   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   338   proof (induct n arbitrary: m)
   339     case 0 then show "m = 0" by simp
   340   next
   341     case (Suc n) then show "m = Suc n"
   342       by (cases m) (simp_all add: eq_commute [of "0"])
   343   qed
   344   then show ?thesis by auto
   345 qed
   346 
   347 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   348   by (simp add: mult_commute)
   349 
   350 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   351   by (subst mult_cancel1) simp
   352 
   353 
   354 subsection {* Orders on @{typ nat} *}
   355 
   356 subsubsection {* Operation definition *}
   357 
   358 instantiation nat :: linorder
   359 begin
   360 
   361 primrec less_eq_nat where
   362   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   363   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   364 
   365 declare less_eq_nat.simps [simp del]
   366 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   367 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   368 
   369 definition less_nat where
   370   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   371 
   372 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   373   by (simp add: less_eq_nat.simps(2))
   374 
   375 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   376   unfolding less_eq_Suc_le ..
   377 
   378 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   379   by (induct n) (simp_all add: less_eq_nat.simps(2))
   380 
   381 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   382   by (simp add: less_eq_Suc_le)
   383 
   384 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   385   by simp
   386 
   387 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   388   by (simp add: less_eq_Suc_le)
   389 
   390 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   391   by (simp add: less_eq_Suc_le)
   392 
   393 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   394   by (induct m arbitrary: n)
   395     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   396 
   397 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   398   by (cases n) (auto intro: le_SucI)
   399 
   400 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   401   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   402 
   403 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   404   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   405 
   406 instance
   407 proof
   408   fix n m :: nat
   409   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   410   proof (induct n arbitrary: m)
   411     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   412   next
   413     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   414   qed
   415 next
   416   fix n :: nat show "n \<le> n" by (induct n) simp_all
   417 next
   418   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   419   then show "n = m"
   420     by (induct n arbitrary: m)
   421       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   422 next
   423   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   424   then show "n \<le> q"
   425   proof (induct n arbitrary: m q)
   426     case 0 show ?case by simp
   427   next
   428     case (Suc n) then show ?case
   429       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   430         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   431         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   432   qed
   433 next
   434   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   435     by (induct n arbitrary: m)
   436       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   437 qed
   438 
   439 end
   440 
   441 instantiation nat :: bot
   442 begin
   443 
   444 definition bot_nat :: nat where
   445   "bot_nat = 0"
   446 
   447 instance proof
   448 qed (simp add: bot_nat_def)
   449 
   450 end
   451 
   452 subsubsection {* Introduction properties *}
   453 
   454 lemma lessI [iff]: "n < Suc n"
   455   by (simp add: less_Suc_eq_le)
   456 
   457 lemma zero_less_Suc [iff]: "0 < Suc n"
   458   by (simp add: less_Suc_eq_le)
   459 
   460 
   461 subsubsection {* Elimination properties *}
   462 
   463 lemma less_not_refl: "~ n < (n::nat)"
   464   by (rule order_less_irrefl)
   465 
   466 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   467   by (rule not_sym) (rule less_imp_neq) 
   468 
   469 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   470   by (rule less_imp_neq)
   471 
   472 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   473   by (rule notE, rule less_not_refl)
   474 
   475 lemma less_zeroE: "(n::nat) < 0 ==> R"
   476   by (rule notE) (rule not_less0)
   477 
   478 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   479   unfolding less_Suc_eq_le le_less ..
   480 
   481 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   482   by (simp add: less_Suc_eq)
   483 
   484 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   485   unfolding One_nat_def by (rule less_Suc0)
   486 
   487 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   488   by simp
   489 
   490 text {* "Less than" is antisymmetric, sort of *}
   491 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   492   unfolding not_less less_Suc_eq_le by (rule antisym)
   493 
   494 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   495   by (rule linorder_neq_iff)
   496 
   497 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   498   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   499   shows "P n m"
   500   apply (rule less_linear [THEN disjE])
   501   apply (erule_tac [2] disjE)
   502   apply (erule lessCase)
   503   apply (erule sym [THEN eqCase])
   504   apply (erule major)
   505   done
   506 
   507 
   508 subsubsection {* Inductive (?) properties *}
   509 
   510 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   511   unfolding less_eq_Suc_le [of m] le_less by simp 
   512 
   513 lemma lessE:
   514   assumes major: "i < k"
   515   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   516   shows P
   517 proof -
   518   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   519     unfolding less_eq_Suc_le by (induct k) simp_all
   520   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   521     by (clarsimp simp add: less_le)
   522   with p1 p2 show P by auto
   523 qed
   524 
   525 lemma less_SucE: assumes major: "m < Suc n"
   526   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   527   apply (rule major [THEN lessE])
   528   apply (rule eq, blast)
   529   apply (rule less, blast)
   530   done
   531 
   532 lemma Suc_lessE: assumes major: "Suc i < k"
   533   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   534   apply (rule major [THEN lessE])
   535   apply (erule lessI [THEN minor])
   536   apply (erule Suc_lessD [THEN minor], assumption)
   537   done
   538 
   539 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   540   by simp
   541 
   542 lemma less_trans_Suc:
   543   assumes le: "i < j" shows "j < k ==> Suc i < k"
   544   apply (induct k, simp_all)
   545   apply (insert le)
   546   apply (simp add: less_Suc_eq)
   547   apply (blast dest: Suc_lessD)
   548   done
   549 
   550 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   551 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   552   unfolding not_less less_Suc_eq_le ..
   553 
   554 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   555   unfolding not_le Suc_le_eq ..
   556 
   557 text {* Properties of "less than or equal" *}
   558 
   559 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   560   unfolding less_Suc_eq_le .
   561 
   562 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   563   unfolding not_le less_Suc_eq_le ..
   564 
   565 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   566   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   567 
   568 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   569   by (drule le_Suc_eq [THEN iffD1], iprover+)
   570 
   571 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   572   unfolding Suc_le_eq .
   573 
   574 text {* Stronger version of @{text Suc_leD} *}
   575 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   576   unfolding Suc_le_eq .
   577 
   578 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   579   unfolding less_eq_Suc_le by (rule Suc_leD)
   580 
   581 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   582 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   583 
   584 
   585 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   586 
   587 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   588   unfolding le_less .
   589 
   590 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   591   by (rule le_less)
   592 
   593 text {* Useful with @{text blast}. *}
   594 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   595   by auto
   596 
   597 lemma le_refl: "n \<le> (n::nat)"
   598   by simp
   599 
   600 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   601   by (rule order_trans)
   602 
   603 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   604   by (rule antisym)
   605 
   606 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   607   by (rule less_le)
   608 
   609 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   610   unfolding less_le ..
   611 
   612 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   613   by (rule linear)
   614 
   615 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   616 
   617 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   618   unfolding less_Suc_eq_le by auto
   619 
   620 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   621   unfolding not_less by (rule le_less_Suc_eq)
   622 
   623 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   624 
   625 text {* These two rules ease the use of primitive recursion.
   626 NOTE USE OF @{text "=="} *}
   627 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   628 by simp
   629 
   630 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   631 by simp
   632 
   633 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   634 by (cases n) simp_all
   635 
   636 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   637 by (cases n) simp_all
   638 
   639 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   640 by (cases n) simp_all
   641 
   642 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   643 by (cases n) simp_all
   644 
   645 text {* This theorem is useful with @{text blast} *}
   646 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   647 by (rule neq0_conv[THEN iffD1], iprover)
   648 
   649 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   650 by (fast intro: not0_implies_Suc)
   651 
   652 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   653 using neq0_conv by blast
   654 
   655 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   656 by (induct m') simp_all
   657 
   658 text {* Useful in certain inductive arguments *}
   659 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   660 by (cases m) simp_all
   661 
   662 
   663 subsubsection {* @{term min} and @{term max} *}
   664 
   665 lemma mono_Suc: "mono Suc"
   666 by (rule monoI) simp
   667 
   668 lemma min_0L [simp]: "min 0 n = (0::nat)"
   669 by (rule min_leastL) simp
   670 
   671 lemma min_0R [simp]: "min n 0 = (0::nat)"
   672 by (rule min_leastR) simp
   673 
   674 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   675 by (simp add: mono_Suc min_of_mono)
   676 
   677 lemma min_Suc1:
   678    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   679 by (simp split: nat.split)
   680 
   681 lemma min_Suc2:
   682    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   683 by (simp split: nat.split)
   684 
   685 lemma max_0L [simp]: "max 0 n = (n::nat)"
   686 by (rule max_leastL) simp
   687 
   688 lemma max_0R [simp]: "max n 0 = (n::nat)"
   689 by (rule max_leastR) simp
   690 
   691 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   692 by (simp add: mono_Suc max_of_mono)
   693 
   694 lemma max_Suc1:
   695    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   696 by (simp split: nat.split)
   697 
   698 lemma max_Suc2:
   699    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   700 by (simp split: nat.split)
   701 
   702 
   703 subsubsection {* Monotonicity of Addition *}
   704 
   705 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   706 by (simp add: diff_Suc split: nat.split)
   707 
   708 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   709 unfolding One_nat_def by (rule Suc_pred)
   710 
   711 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   712 by (induct k) simp_all
   713 
   714 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   715 by (induct k) simp_all
   716 
   717 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   718 by(auto dest:gr0_implies_Suc)
   719 
   720 text {* strict, in 1st argument *}
   721 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   722 by (induct k) simp_all
   723 
   724 text {* strict, in both arguments *}
   725 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   726   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   727   apply (induct j, simp_all)
   728   done
   729 
   730 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   731 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   732   apply (induct n)
   733   apply (simp_all add: order_le_less)
   734   apply (blast elim!: less_SucE
   735                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   736   done
   737 
   738 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   739 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   740 apply(auto simp: gr0_conv_Suc)
   741 apply (induct_tac m)
   742 apply (simp_all add: add_less_mono)
   743 done
   744 
   745 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   746 instance nat :: linordered_semidom
   747 proof
   748   fix i j k :: nat
   749   show "0 < (1::nat)" by simp
   750   show "i \<le> j ==> k + i \<le> k + j" by simp
   751   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   752 qed
   753 
   754 instance nat :: no_zero_divisors
   755 proof
   756   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   757 qed
   758 
   759 lemma nat_mult_1: "(1::nat) * n = n"
   760 by simp
   761 
   762 lemma nat_mult_1_right: "n * (1::nat) = n"
   763 by simp
   764 
   765 
   766 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   767 
   768 text {* Complete induction, aka course-of-values induction *}
   769 
   770 instance nat :: wellorder proof
   771   fix P and n :: nat
   772   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   773   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   774   proof (induct n)
   775     case (0 n)
   776     have "P 0" by (rule step) auto
   777     thus ?case using 0 by auto
   778   next
   779     case (Suc m n)
   780     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   781     thus ?case
   782     proof
   783       assume "n \<le> m" thus "P n" by (rule Suc(1))
   784     next
   785       assume n: "n = Suc m"
   786       show "P n"
   787         by (rule step) (rule Suc(1), simp add: n le_simps)
   788     qed
   789   qed
   790   then show "P n" by auto
   791 qed
   792 
   793 lemma Least_Suc:
   794      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   795   apply (case_tac "n", auto)
   796   apply (frule LeastI)
   797   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   798   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   799   apply (erule_tac [2] Least_le)
   800   apply (case_tac "LEAST x. P x", auto)
   801   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   802   apply (blast intro: order_antisym)
   803   done
   804 
   805 lemma Least_Suc2:
   806    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   807   apply (erule (1) Least_Suc [THEN ssubst])
   808   apply simp
   809   done
   810 
   811 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   812   apply (cases n)
   813    apply blast
   814   apply (rule_tac x="LEAST k. P(k)" in exI)
   815   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   816   done
   817 
   818 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   819   unfolding One_nat_def
   820   apply (cases n)
   821    apply blast
   822   apply (frule (1) ex_least_nat_le)
   823   apply (erule exE)
   824   apply (case_tac k)
   825    apply simp
   826   apply (rename_tac k1)
   827   apply (rule_tac x=k1 in exI)
   828   apply (auto simp add: less_eq_Suc_le)
   829   done
   830 
   831 lemma nat_less_induct:
   832   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   833   using assms less_induct by blast
   834 
   835 lemma measure_induct_rule [case_names less]:
   836   fixes f :: "'a \<Rightarrow> nat"
   837   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   838   shows "P a"
   839 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   840 
   841 text {* old style induction rules: *}
   842 lemma measure_induct:
   843   fixes f :: "'a \<Rightarrow> nat"
   844   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   845   by (rule measure_induct_rule [of f P a]) iprover
   846 
   847 lemma full_nat_induct:
   848   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   849   shows "P n"
   850   by (rule less_induct) (auto intro: step simp:le_simps)
   851 
   852 text{*An induction rule for estabilishing binary relations*}
   853 lemma less_Suc_induct:
   854   assumes less:  "i < j"
   855      and  step:  "!!i. P i (Suc i)"
   856      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   857   shows "P i j"
   858 proof -
   859   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   860   have "P i (Suc (i + k))"
   861   proof (induct k)
   862     case 0
   863     show ?case by (simp add: step)
   864   next
   865     case (Suc k)
   866     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   867     hence "i < Suc (i + k)" by (simp add: add_commute)
   868     from trans[OF this lessI Suc step]
   869     show ?case by simp
   870   qed
   871   thus "P i j" by (simp add: j)
   872 qed
   873 
   874 text {* The method of infinite descent, frequently used in number theory.
   875 Provided by Roelof Oosterhuis.
   876 $P(n)$ is true for all $n\in\mathbb{N}$ if
   877 \begin{itemize}
   878   \item case ``0'': given $n=0$ prove $P(n)$,
   879   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   880         a smaller integer $m$ such that $\neg P(m)$.
   881 \end{itemize} *}
   882 
   883 text{* A compact version without explicit base case: *}
   884 lemma infinite_descent:
   885   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   886 by (induct n rule: less_induct, auto)
   887 
   888 lemma infinite_descent0[case_names 0 smaller]: 
   889   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   890 by (rule infinite_descent) (case_tac "n>0", auto)
   891 
   892 text {*
   893 Infinite descent using a mapping to $\mathbb{N}$:
   894 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   895 \begin{itemize}
   896 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   897 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   898 \end{itemize}
   899 NB: the proof also shows how to use the previous lemma. *}
   900 
   901 corollary infinite_descent0_measure [case_names 0 smaller]:
   902   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   903     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   904   shows "P x"
   905 proof -
   906   obtain n where "n = V x" by auto
   907   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   908   proof (induct n rule: infinite_descent0)
   909     case 0 -- "i.e. $V(x) = 0$"
   910     with A0 show "P x" by auto
   911   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   912     case (smaller n)
   913     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   914     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   915     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   916     then show ?case by auto
   917   qed
   918   ultimately show "P x" by auto
   919 qed
   920 
   921 text{* Again, without explicit base case: *}
   922 lemma infinite_descent_measure:
   923 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   924 proof -
   925   from assms obtain n where "n = V x" by auto
   926   moreover have "!!x. V x = n \<Longrightarrow> P x"
   927   proof (induct n rule: infinite_descent, auto)
   928     fix x assume "\<not> P x"
   929     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   930   qed
   931   ultimately show "P x" by auto
   932 qed
   933 
   934 text {* A [clumsy] way of lifting @{text "<"}
   935   monotonicity to @{text "\<le>"} monotonicity *}
   936 lemma less_mono_imp_le_mono:
   937   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   938 by (simp add: order_le_less) (blast)
   939 
   940 
   941 text {* non-strict, in 1st argument *}
   942 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   943 by (rule add_right_mono)
   944 
   945 text {* non-strict, in both arguments *}
   946 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   947 by (rule add_mono)
   948 
   949 lemma le_add2: "n \<le> ((m + n)::nat)"
   950 by (insert add_right_mono [of 0 m n], simp)
   951 
   952 lemma le_add1: "n \<le> ((n + m)::nat)"
   953 by (simp add: add_commute, rule le_add2)
   954 
   955 lemma less_add_Suc1: "i < Suc (i + m)"
   956 by (rule le_less_trans, rule le_add1, rule lessI)
   957 
   958 lemma less_add_Suc2: "i < Suc (m + i)"
   959 by (rule le_less_trans, rule le_add2, rule lessI)
   960 
   961 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   962 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   963 
   964 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   965 by (rule le_trans, assumption, rule le_add1)
   966 
   967 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   968 by (rule le_trans, assumption, rule le_add2)
   969 
   970 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   971 by (rule less_le_trans, assumption, rule le_add1)
   972 
   973 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   974 by (rule less_le_trans, assumption, rule le_add2)
   975 
   976 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   977 apply (rule le_less_trans [of _ "i+j"])
   978 apply (simp_all add: le_add1)
   979 done
   980 
   981 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   982 apply (rule notI)
   983 apply (drule add_lessD1)
   984 apply (erule less_irrefl [THEN notE])
   985 done
   986 
   987 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   988 by (simp add: add_commute)
   989 
   990 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   991 apply (rule order_trans [of _ "m+k"])
   992 apply (simp_all add: le_add1)
   993 done
   994 
   995 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   996 apply (simp add: add_commute)
   997 apply (erule add_leD1)
   998 done
   999 
  1000 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1001 by (blast dest: add_leD1 add_leD2)
  1002 
  1003 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1004 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1005 by (force simp del: add_Suc_right
  1006     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1007 
  1008 
  1009 subsubsection {* More results about difference *}
  1010 
  1011 text {* Addition is the inverse of subtraction:
  1012   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1013 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1014 by (induct m n rule: diff_induct) simp_all
  1015 
  1016 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1017 by (simp add: add_diff_inverse linorder_not_less)
  1018 
  1019 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1020 by (simp add: add_commute)
  1021 
  1022 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1023 by (induct m n rule: diff_induct) simp_all
  1024 
  1025 lemma diff_less_Suc: "m - n < Suc m"
  1026 apply (induct m n rule: diff_induct)
  1027 apply (erule_tac [3] less_SucE)
  1028 apply (simp_all add: less_Suc_eq)
  1029 done
  1030 
  1031 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1032 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1033 
  1034 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1035   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1036 
  1037 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1038 by (rule le_less_trans, rule diff_le_self)
  1039 
  1040 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1041 by (cases n) (auto simp add: le_simps)
  1042 
  1043 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1044 by (induct j k rule: diff_induct) simp_all
  1045 
  1046 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1047 by (simp add: add_commute diff_add_assoc)
  1048 
  1049 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1050 by (auto simp add: diff_add_inverse2)
  1051 
  1052 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1053 by (induct m n rule: diff_induct) simp_all
  1054 
  1055 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1056 by (rule iffD2, rule diff_is_0_eq)
  1057 
  1058 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1059 by (induct m n rule: diff_induct) simp_all
  1060 
  1061 lemma less_imp_add_positive:
  1062   assumes "i < j"
  1063   shows "\<exists>k::nat. 0 < k & i + k = j"
  1064 proof
  1065   from assms show "0 < j - i & i + (j - i) = j"
  1066     by (simp add: order_less_imp_le)
  1067 qed
  1068 
  1069 text {* a nice rewrite for bounded subtraction *}
  1070 lemma nat_minus_add_max:
  1071   fixes n m :: nat
  1072   shows "n - m + m = max n m"
  1073     by (simp add: max_def not_le order_less_imp_le)
  1074 
  1075 lemma nat_diff_split:
  1076   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1077     -- {* elimination of @{text -} on @{text nat} *}
  1078 by (cases "a < b")
  1079   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1080     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1081 
  1082 lemma nat_diff_split_asm:
  1083   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1084     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1085 by (auto split: nat_diff_split)
  1086 
  1087 
  1088 subsubsection {* Monotonicity of Multiplication *}
  1089 
  1090 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1091 by (simp add: mult_right_mono)
  1092 
  1093 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1094 by (simp add: mult_left_mono)
  1095 
  1096 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1097 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1098 by (simp add: mult_mono)
  1099 
  1100 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1101 by (simp add: mult_strict_right_mono)
  1102 
  1103 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1104       there are no negative numbers.*}
  1105 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1106   apply (induct m)
  1107    apply simp
  1108   apply (case_tac n)
  1109    apply simp_all
  1110   done
  1111 
  1112 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1113   apply (induct m)
  1114    apply simp
  1115   apply (case_tac n)
  1116    apply simp_all
  1117   done
  1118 
  1119 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1120   apply (safe intro!: mult_less_mono1)
  1121   apply (case_tac k, auto)
  1122   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1123   apply (blast intro: mult_le_mono1)
  1124   done
  1125 
  1126 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1127 by (simp add: mult_commute [of k])
  1128 
  1129 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1130 by (simp add: linorder_not_less [symmetric], auto)
  1131 
  1132 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1133 by (simp add: linorder_not_less [symmetric], auto)
  1134 
  1135 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1136 by (subst mult_less_cancel1) simp
  1137 
  1138 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1139 by (subst mult_le_cancel1) simp
  1140 
  1141 lemma le_square: "m \<le> m * (m::nat)"
  1142   by (cases m) (auto intro: le_add1)
  1143 
  1144 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1145   by (cases m) (auto intro: le_add1)
  1146 
  1147 text {* Lemma for @{text gcd} *}
  1148 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1149   apply (drule sym)
  1150   apply (rule disjCI)
  1151   apply (rule nat_less_cases, erule_tac [2] _)
  1152    apply (drule_tac [2] mult_less_mono2)
  1153     apply (auto)
  1154   done
  1155 
  1156 text {* the lattice order on @{typ nat} *}
  1157 
  1158 instantiation nat :: distrib_lattice
  1159 begin
  1160 
  1161 definition
  1162   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1163 
  1164 definition
  1165   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1166 
  1167 instance by intro_classes
  1168   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1169     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1170 
  1171 end
  1172 
  1173 
  1174 subsection {* Natural operation of natural numbers on functions *}
  1175 
  1176 text {*
  1177   We use the same logical constant for the power operations on
  1178   functions and relations, in order to share the same syntax.
  1179 *}
  1180 
  1181 consts compow :: "nat \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
  1182 
  1183 abbreviation compower :: "('a \<Rightarrow> 'b) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'b" (infixr "^^" 80) where
  1184   "f ^^ n \<equiv> compow n f"
  1185 
  1186 notation (latex output)
  1187   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1188 
  1189 notation (HTML output)
  1190   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1191 
  1192 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1193 
  1194 overloading
  1195   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1196 begin
  1197 
  1198 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1199     "funpow 0 f = id"
  1200   | "funpow (Suc n) f = f o funpow n f"
  1201 
  1202 end
  1203 
  1204 text {* for code generation *}
  1205 
  1206 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1207   funpow_code_def [code_post]: "funpow = compow"
  1208 
  1209 lemmas [code_unfold] = funpow_code_def [symmetric]
  1210 
  1211 lemma [code]:
  1212   "funpow 0 f = id"
  1213   "funpow (Suc n) f = f o funpow n f"
  1214   unfolding funpow_code_def by simp_all
  1215 
  1216 hide (open) const funpow
  1217 
  1218 lemma funpow_add:
  1219   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1220   by (induct m) simp_all
  1221 
  1222 lemma funpow_swap1:
  1223   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1224 proof -
  1225   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1226   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1227   also have "\<dots> = (f ^^ n) (f x)" by simp
  1228   finally show ?thesis .
  1229 qed
  1230 
  1231 
  1232 subsection {* Embedding of the Naturals into any
  1233   @{text semiring_1}: @{term of_nat} *}
  1234 
  1235 context semiring_1
  1236 begin
  1237 
  1238 primrec
  1239   of_nat :: "nat \<Rightarrow> 'a"
  1240 where
  1241   of_nat_0:     "of_nat 0 = 0"
  1242   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1243 
  1244 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1245   unfolding One_nat_def by simp
  1246 
  1247 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1248   by (induct m) (simp_all add: add_ac)
  1249 
  1250 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1251   by (induct m) (simp_all add: add_ac left_distrib)
  1252 
  1253 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1254   "of_nat_aux inc 0 i = i"
  1255   | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1256 
  1257 lemma of_nat_code:
  1258   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1259 proof (induct n)
  1260   case 0 then show ?case by simp
  1261 next
  1262   case (Suc n)
  1263   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1264     by (induct n) simp_all
  1265   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1266     by simp
  1267   with Suc show ?case by (simp add: add_commute)
  1268 qed
  1269 
  1270 end
  1271 
  1272 declare of_nat_code [code, code_unfold, code_inline del]
  1273 
  1274 text{*Class for unital semirings with characteristic zero.
  1275  Includes non-ordered rings like the complex numbers.*}
  1276 
  1277 class semiring_char_0 = semiring_1 +
  1278   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1279 begin
  1280 
  1281 text{*Special cases where either operand is zero*}
  1282 
  1283 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1284   by (rule of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1285 
  1286 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1287   by (rule of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1288 
  1289 lemma inj_of_nat: "inj of_nat"
  1290   by (simp add: inj_on_def)
  1291 
  1292 end
  1293 
  1294 context linordered_semidom
  1295 begin
  1296 
  1297 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1298   apply (induct m, simp_all)
  1299   apply (erule order_trans)
  1300   apply (rule ord_le_eq_trans [OF _ add_commute])
  1301   apply (rule less_add_one [THEN less_imp_le])
  1302   done
  1303 
  1304 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1305   apply (induct m n rule: diff_induct, simp_all)
  1306   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1307   done
  1308 
  1309 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1310   apply (induct m n rule: diff_induct, simp_all)
  1311   apply (insert zero_le_imp_of_nat)
  1312   apply (force simp add: not_less [symmetric])
  1313   done
  1314 
  1315 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1316   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1317 
  1318 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1319   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1320 
  1321 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1322 
  1323 subclass semiring_char_0
  1324   proof qed (simp add: eq_iff order_eq_iff)
  1325 
  1326 text{*Special cases where either operand is zero*}
  1327 
  1328 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1329   by (rule of_nat_le_iff [of 0, simplified])
  1330 
  1331 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1332   by (rule of_nat_le_iff [of _ 0, simplified])
  1333 
  1334 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1335   by (rule of_nat_less_iff [of 0, simplified])
  1336 
  1337 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1338   by (rule of_nat_less_iff [of _ 0, simplified])
  1339 
  1340 end
  1341 
  1342 context ring_1
  1343 begin
  1344 
  1345 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1346 by (simp add: algebra_simps of_nat_add [symmetric])
  1347 
  1348 end
  1349 
  1350 context linordered_idom
  1351 begin
  1352 
  1353 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1354   unfolding abs_if by auto
  1355 
  1356 end
  1357 
  1358 lemma of_nat_id [simp]: "of_nat n = n"
  1359   by (induct n) (auto simp add: One_nat_def)
  1360 
  1361 lemma of_nat_eq_id [simp]: "of_nat = id"
  1362   by (auto simp add: expand_fun_eq)
  1363 
  1364 
  1365 subsection {* The Set of Natural Numbers *}
  1366 
  1367 context semiring_1
  1368 begin
  1369 
  1370 definition
  1371   Nats  :: "'a set" where
  1372   [code del]: "Nats = range of_nat"
  1373 
  1374 notation (xsymbols)
  1375   Nats  ("\<nat>")
  1376 
  1377 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1378   by (simp add: Nats_def)
  1379 
  1380 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1381 apply (simp add: Nats_def)
  1382 apply (rule range_eqI)
  1383 apply (rule of_nat_0 [symmetric])
  1384 done
  1385 
  1386 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1387 apply (simp add: Nats_def)
  1388 apply (rule range_eqI)
  1389 apply (rule of_nat_1 [symmetric])
  1390 done
  1391 
  1392 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1393 apply (auto simp add: Nats_def)
  1394 apply (rule range_eqI)
  1395 apply (rule of_nat_add [symmetric])
  1396 done
  1397 
  1398 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1399 apply (auto simp add: Nats_def)
  1400 apply (rule range_eqI)
  1401 apply (rule of_nat_mult [symmetric])
  1402 done
  1403 
  1404 end
  1405 
  1406 
  1407 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1408 
  1409 lemma subst_equals:
  1410   assumes 1: "t = s" and 2: "u = t"
  1411   shows "u = s"
  1412   using 2 1 by (rule trans)
  1413 
  1414 setup Arith_Data.setup
  1415 
  1416 use "Tools/nat_arith.ML"
  1417 declaration {* K Nat_Arith.setup *}
  1418 
  1419 use "Tools/lin_arith.ML"
  1420 setup {* Lin_Arith.global_setup *}
  1421 declaration {* K Lin_Arith.setup *}
  1422 
  1423 lemmas [arith_split] = nat_diff_split split_min split_max
  1424 
  1425 context order
  1426 begin
  1427 
  1428 lemma lift_Suc_mono_le:
  1429   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1430   shows "f n \<le> f n'"
  1431 proof (cases "n < n'")
  1432   case True
  1433   thus ?thesis
  1434     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1435 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1436 
  1437 lemma lift_Suc_mono_less:
  1438   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1439   shows "f n < f n'"
  1440 using `n < n'`
  1441 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1442 
  1443 lemma lift_Suc_mono_less_iff:
  1444   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1445 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1446          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1447 
  1448 end
  1449 
  1450 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1451 unfolding mono_def
  1452 by (auto intro:lift_Suc_mono_le[of f])
  1453 
  1454 lemma mono_nat_linear_lb:
  1455   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1456 apply(induct_tac k)
  1457  apply simp
  1458 apply(erule_tac x="m+n" in meta_allE)
  1459 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1460 apply simp
  1461 done
  1462 
  1463 
  1464 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1465 
  1466 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1467 by arith
  1468 
  1469 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1470 by arith
  1471 
  1472 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1473 by arith
  1474 
  1475 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1476 by arith
  1477 
  1478 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1479 by arith
  1480 
  1481 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1482 by arith
  1483 
  1484 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1485   second premise n\<le>m*)
  1486 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1487 by arith
  1488 
  1489 text {* Simplification of relational expressions involving subtraction *}
  1490 
  1491 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1492 by (simp split add: nat_diff_split)
  1493 
  1494 hide (open) fact diff_diff_eq
  1495 
  1496 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1497 by (auto split add: nat_diff_split)
  1498 
  1499 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1500 by (auto split add: nat_diff_split)
  1501 
  1502 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1503 by (auto split add: nat_diff_split)
  1504 
  1505 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1506 
  1507 (* Monotonicity of subtraction in first argument *)
  1508 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1509 by (simp split add: nat_diff_split)
  1510 
  1511 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1512 by (simp split add: nat_diff_split)
  1513 
  1514 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1515 by (simp split add: nat_diff_split)
  1516 
  1517 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1518 by (simp split add: nat_diff_split)
  1519 
  1520 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1521 by auto
  1522 
  1523 lemma inj_on_diff_nat: 
  1524   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1525   shows "inj_on (\<lambda>n. n - k) N"
  1526 proof (rule inj_onI)
  1527   fix x y
  1528   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1529   with k_le_n have "x - k + k = y - k + k" by auto
  1530   with a k_le_n show "x = y" by auto
  1531 qed
  1532 
  1533 text{*Rewriting to pull differences out*}
  1534 
  1535 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1536 by arith
  1537 
  1538 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1539 by arith
  1540 
  1541 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1542 by arith
  1543 
  1544 text{*Lemmas for ex/Factorization*}
  1545 
  1546 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1547 by (cases m) auto
  1548 
  1549 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1550 by (cases m) auto
  1551 
  1552 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1553 by (cases m) auto
  1554 
  1555 text {* Specialized induction principles that work "backwards": *}
  1556 
  1557 lemma inc_induct[consumes 1, case_names base step]:
  1558   assumes less: "i <= j"
  1559   assumes base: "P j"
  1560   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1561   shows "P i"
  1562   using less
  1563 proof (induct d=="j - i" arbitrary: i)
  1564   case (0 i)
  1565   hence "i = j" by simp
  1566   with base show ?case by simp
  1567 next
  1568   case (Suc d i)
  1569   hence "i < j" "P (Suc i)"
  1570     by simp_all
  1571   thus "P i" by (rule step)
  1572 qed
  1573 
  1574 lemma strict_inc_induct[consumes 1, case_names base step]:
  1575   assumes less: "i < j"
  1576   assumes base: "!!i. j = Suc i ==> P i"
  1577   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1578   shows "P i"
  1579   using less
  1580 proof (induct d=="j - i - 1" arbitrary: i)
  1581   case (0 i)
  1582   with `i < j` have "j = Suc i" by simp
  1583   with base show ?case by simp
  1584 next
  1585   case (Suc d i)
  1586   hence "i < j" "P (Suc i)"
  1587     by simp_all
  1588   thus "P i" by (rule step)
  1589 qed
  1590 
  1591 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1592   using inc_induct[of "k - i" k P, simplified] by blast
  1593 
  1594 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1595   using inc_induct[of 0 k P] by blast
  1596 
  1597 (*The others are
  1598       i - j - k = i - (j + k),
  1599       k \<le> j ==> j - k + i = j + i - k,
  1600       k \<le> j ==> i + (j - k) = i + j - k *)
  1601 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1602 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1603 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1604 
  1605 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1606 Least_Suc}, since there appears to be no need.*}
  1607 
  1608 
  1609 subsection {* The divides relation on @{typ nat} *}
  1610 
  1611 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1612 unfolding dvd_def by simp
  1613 
  1614 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1615 by (simp add: dvd_def)
  1616 
  1617 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1618 by (simp add: dvd_def)
  1619 
  1620 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1621   unfolding dvd_def
  1622   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc mult_eq_1_iff)
  1623 
  1624 text {* @{term "op dvd"} is a partial order *}
  1625 
  1626 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1627   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1628 
  1629 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1630 unfolding dvd_def
  1631 by (blast intro: diff_mult_distrib2 [symmetric])
  1632 
  1633 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1634   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1635   apply (blast intro: dvd_add)
  1636   done
  1637 
  1638 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1639 by (drule_tac m = m in dvd_diff_nat, auto)
  1640 
  1641 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1642   apply (rule iffI)
  1643    apply (erule_tac [2] dvd_add)
  1644    apply (rule_tac [2] dvd_refl)
  1645   apply (subgoal_tac "n = (n+k) -k")
  1646    prefer 2 apply simp
  1647   apply (erule ssubst)
  1648   apply (erule dvd_diff_nat)
  1649   apply (rule dvd_refl)
  1650   done
  1651 
  1652 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1653   unfolding dvd_def
  1654   apply (erule exE)
  1655   apply (simp add: mult_ac)
  1656   done
  1657 
  1658 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1659   apply auto
  1660    apply (subgoal_tac "m*n dvd m*1")
  1661    apply (drule dvd_mult_cancel, auto)
  1662   done
  1663 
  1664 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1665   apply (subst mult_commute)
  1666   apply (erule dvd_mult_cancel1)
  1667   done
  1668 
  1669 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1670 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1671 
  1672 lemma nat_dvd_not_less:
  1673   fixes m n :: nat
  1674   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1675 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1676 
  1677 
  1678 subsection {* size of a datatype value *}
  1679 
  1680 class size =
  1681   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1682 
  1683 
  1684 subsection {* code module namespace *}
  1685 
  1686 code_modulename SML
  1687   Nat Arith
  1688 
  1689 code_modulename OCaml
  1690   Nat Arith
  1691 
  1692 code_modulename Haskell
  1693   Nat Arith
  1694 
  1695 end