src/HOL/SetInterval.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 33434 e9de8d69c1b9
child 35171 28f824c7addc
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
     1 (*  Title:      HOL/SetInterval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 *)
     8 
     9 header {* Set intervals *}
    10 
    11 theory SetInterval
    12 imports Int Nat_Transfer
    13 begin
    14 
    15 context ord
    16 begin
    17 definition
    18   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    19   "{..<u} == {x. x < u}"
    20 
    21 definition
    22   atMost      :: "'a => 'a set" ("(1{.._})") where
    23   "{..u} == {x. x \<le> u}"
    24 
    25 definition
    26   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    27   "{l<..} == {x. l<x}"
    28 
    29 definition
    30   atLeast     :: "'a => 'a set" ("(1{_..})") where
    31   "{l..} == {x. l\<le>x}"
    32 
    33 definition
    34   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    35   "{l<..<u} == {l<..} Int {..<u}"
    36 
    37 definition
    38   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    39   "{l..<u} == {l..} Int {..<u}"
    40 
    41 definition
    42   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    43   "{l<..u} == {l<..} Int {..u}"
    44 
    45 definition
    46   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    47   "{l..u} == {l..} Int {..u}"
    48 
    49 end
    50 
    51 
    52 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    53 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    54 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    55 
    56 syntax
    57   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    58   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    59   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    60   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    61 
    62 syntax (xsymbols)
    63   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    64   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    65   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    66   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    67 
    68 syntax (latex output)
    69   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" 10)
    70   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" 10)
    71   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" 10)
    72   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" 10)
    73 
    74 translations
    75   "UN i<=n. A"  == "UN i:{..n}. A"
    76   "UN i<n. A"   == "UN i:{..<n}. A"
    77   "INT i<=n. A" == "INT i:{..n}. A"
    78   "INT i<n. A"  == "INT i:{..<n}. A"
    79 
    80 
    81 subsection {* Various equivalences *}
    82 
    83 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    84 by (simp add: lessThan_def)
    85 
    86 lemma Compl_lessThan [simp]:
    87     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    88 apply (auto simp add: lessThan_def atLeast_def)
    89 done
    90 
    91 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    92 by auto
    93 
    94 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    95 by (simp add: greaterThan_def)
    96 
    97 lemma Compl_greaterThan [simp]:
    98     "!!k:: 'a::linorder. -greaterThan k = atMost k"
    99   by (auto simp add: greaterThan_def atMost_def)
   100 
   101 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   102 apply (subst Compl_greaterThan [symmetric])
   103 apply (rule double_complement)
   104 done
   105 
   106 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   107 by (simp add: atLeast_def)
   108 
   109 lemma Compl_atLeast [simp]:
   110     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   111   by (auto simp add: lessThan_def atLeast_def)
   112 
   113 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   114 by (simp add: atMost_def)
   115 
   116 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   117 by (blast intro: order_antisym)
   118 
   119 
   120 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   121 
   122 lemma atLeast_subset_iff [iff]:
   123      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   124 by (blast intro: order_trans)
   125 
   126 lemma atLeast_eq_iff [iff]:
   127      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   128 by (blast intro: order_antisym order_trans)
   129 
   130 lemma greaterThan_subset_iff [iff]:
   131      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   132 apply (auto simp add: greaterThan_def)
   133  apply (subst linorder_not_less [symmetric], blast)
   134 done
   135 
   136 lemma greaterThan_eq_iff [iff]:
   137      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   138 apply (rule iffI)
   139  apply (erule equalityE)
   140  apply simp_all
   141 done
   142 
   143 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   144 by (blast intro: order_trans)
   145 
   146 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   147 by (blast intro: order_antisym order_trans)
   148 
   149 lemma lessThan_subset_iff [iff]:
   150      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   151 apply (auto simp add: lessThan_def)
   152  apply (subst linorder_not_less [symmetric], blast)
   153 done
   154 
   155 lemma lessThan_eq_iff [iff]:
   156      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   157 apply (rule iffI)
   158  apply (erule equalityE)
   159  apply simp_all
   160 done
   161 
   162 
   163 subsection {*Two-sided intervals*}
   164 
   165 context ord
   166 begin
   167 
   168 lemma greaterThanLessThan_iff [simp,noatp]:
   169   "(i : {l<..<u}) = (l < i & i < u)"
   170 by (simp add: greaterThanLessThan_def)
   171 
   172 lemma atLeastLessThan_iff [simp,noatp]:
   173   "(i : {l..<u}) = (l <= i & i < u)"
   174 by (simp add: atLeastLessThan_def)
   175 
   176 lemma greaterThanAtMost_iff [simp,noatp]:
   177   "(i : {l<..u}) = (l < i & i <= u)"
   178 by (simp add: greaterThanAtMost_def)
   179 
   180 lemma atLeastAtMost_iff [simp,noatp]:
   181   "(i : {l..u}) = (l <= i & i <= u)"
   182 by (simp add: atLeastAtMost_def)
   183 
   184 text {* The above four lemmas could be declared as iffs. Unfortunately this
   185 breaks many proofs. Since it only helps blast, it is better to leave well
   186 alone *}
   187 
   188 end
   189 
   190 subsubsection{* Emptyness, singletons, subset *}
   191 
   192 context order
   193 begin
   194 
   195 lemma atLeastatMost_empty[simp]:
   196   "b < a \<Longrightarrow> {a..b} = {}"
   197 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   198 
   199 lemma atLeastatMost_empty_iff[simp]:
   200   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   201 by auto (blast intro: order_trans)
   202 
   203 lemma atLeastatMost_empty_iff2[simp]:
   204   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   205 by auto (blast intro: order_trans)
   206 
   207 lemma atLeastLessThan_empty[simp]:
   208   "b <= a \<Longrightarrow> {a..<b} = {}"
   209 by(auto simp: atLeastLessThan_def)
   210 
   211 lemma atLeastLessThan_empty_iff[simp]:
   212   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   213 by auto (blast intro: le_less_trans)
   214 
   215 lemma atLeastLessThan_empty_iff2[simp]:
   216   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   217 by auto (blast intro: le_less_trans)
   218 
   219 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   220 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   221 
   222 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   223 by auto (blast intro: less_le_trans)
   224 
   225 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   226 by auto (blast intro: less_le_trans)
   227 
   228 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   229 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   230 
   231 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   232 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   233 
   234 lemma atLeastatMost_subset_iff[simp]:
   235   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   236 unfolding atLeastAtMost_def atLeast_def atMost_def
   237 by (blast intro: order_trans)
   238 
   239 lemma atLeastatMost_psubset_iff:
   240   "{a..b} < {c..d} \<longleftrightarrow>
   241    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   242 by(simp add: psubset_eq expand_set_eq less_le_not_le)(blast intro: order_trans)
   243 
   244 end
   245 
   246 lemma (in linorder) atLeastLessThan_subset_iff:
   247   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   248 apply (auto simp:subset_eq Ball_def)
   249 apply(frule_tac x=a in spec)
   250 apply(erule_tac x=d in allE)
   251 apply (simp add: less_imp_le)
   252 done
   253 
   254 subsubsection {* Intersection *}
   255 
   256 context linorder
   257 begin
   258 
   259 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   260 by auto
   261 
   262 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   263 by auto
   264 
   265 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   266 by auto
   267 
   268 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   269 by auto
   270 
   271 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   272 by auto
   273 
   274 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   275 by auto
   276 
   277 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   278 by auto
   279 
   280 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   281 by auto
   282 
   283 end
   284 
   285 
   286 subsection {* Intervals of natural numbers *}
   287 
   288 subsubsection {* The Constant @{term lessThan} *}
   289 
   290 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   291 by (simp add: lessThan_def)
   292 
   293 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   294 by (simp add: lessThan_def less_Suc_eq, blast)
   295 
   296 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   297 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   298 
   299 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   300 by blast
   301 
   302 subsubsection {* The Constant @{term greaterThan} *}
   303 
   304 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   305 apply (simp add: greaterThan_def)
   306 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   307 done
   308 
   309 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   310 apply (simp add: greaterThan_def)
   311 apply (auto elim: linorder_neqE)
   312 done
   313 
   314 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   315 by blast
   316 
   317 subsubsection {* The Constant @{term atLeast} *}
   318 
   319 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   320 by (unfold atLeast_def UNIV_def, simp)
   321 
   322 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   323 apply (simp add: atLeast_def)
   324 apply (simp add: Suc_le_eq)
   325 apply (simp add: order_le_less, blast)
   326 done
   327 
   328 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   329   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   330 
   331 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   332 by blast
   333 
   334 subsubsection {* The Constant @{term atMost} *}
   335 
   336 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   337 by (simp add: atMost_def)
   338 
   339 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   340 apply (simp add: atMost_def)
   341 apply (simp add: less_Suc_eq order_le_less, blast)
   342 done
   343 
   344 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   345 by blast
   346 
   347 subsubsection {* The Constant @{term atLeastLessThan} *}
   348 
   349 text{*The orientation of the following 2 rules is tricky. The lhs is
   350 defined in terms of the rhs.  Hence the chosen orientation makes sense
   351 in this theory --- the reverse orientation complicates proofs (eg
   352 nontermination). But outside, when the definition of the lhs is rarely
   353 used, the opposite orientation seems preferable because it reduces a
   354 specific concept to a more general one. *}
   355 
   356 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   357 by(simp add:lessThan_def atLeastLessThan_def)
   358 
   359 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   360 by(simp add:atMost_def atLeastAtMost_def)
   361 
   362 declare atLeast0LessThan[symmetric, code_unfold]
   363         atLeast0AtMost[symmetric, code_unfold]
   364 
   365 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   366 by (simp add: atLeastLessThan_def)
   367 
   368 subsubsection {* Intervals of nats with @{term Suc} *}
   369 
   370 text{*Not a simprule because the RHS is too messy.*}
   371 lemma atLeastLessThanSuc:
   372     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   373 by (auto simp add: atLeastLessThan_def)
   374 
   375 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   376 by (auto simp add: atLeastLessThan_def)
   377 (*
   378 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   379 by (induct k, simp_all add: atLeastLessThanSuc)
   380 
   381 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   382 by (auto simp add: atLeastLessThan_def)
   383 *)
   384 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   385   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   386 
   387 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   388   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   389     greaterThanAtMost_def)
   390 
   391 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   392   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   393     greaterThanLessThan_def)
   394 
   395 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   396 by (auto simp add: atLeastAtMost_def)
   397 
   398 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   399   apply (induct k) 
   400   apply (simp_all add: atLeastLessThanSuc)   
   401   done
   402 
   403 subsubsection {* Image *}
   404 
   405 lemma image_add_atLeastAtMost:
   406   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   407 proof
   408   show "?A \<subseteq> ?B" by auto
   409 next
   410   show "?B \<subseteq> ?A"
   411   proof
   412     fix n assume a: "n : ?B"
   413     hence "n - k : {i..j}" by auto
   414     moreover have "n = (n - k) + k" using a by auto
   415     ultimately show "n : ?A" by blast
   416   qed
   417 qed
   418 
   419 lemma image_add_atLeastLessThan:
   420   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   421 proof
   422   show "?A \<subseteq> ?B" by auto
   423 next
   424   show "?B \<subseteq> ?A"
   425   proof
   426     fix n assume a: "n : ?B"
   427     hence "n - k : {i..<j}" by auto
   428     moreover have "n = (n - k) + k" using a by auto
   429     ultimately show "n : ?A" by blast
   430   qed
   431 qed
   432 
   433 corollary image_Suc_atLeastAtMost[simp]:
   434   "Suc ` {i..j} = {Suc i..Suc j}"
   435 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   436 
   437 corollary image_Suc_atLeastLessThan[simp]:
   438   "Suc ` {i..<j} = {Suc i..<Suc j}"
   439 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   440 
   441 lemma image_add_int_atLeastLessThan:
   442     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   443   apply (auto simp add: image_def)
   444   apply (rule_tac x = "x - l" in bexI)
   445   apply auto
   446   done
   447 
   448 
   449 subsubsection {* Finiteness *}
   450 
   451 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   452   by (induct k) (simp_all add: lessThan_Suc)
   453 
   454 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   455   by (induct k) (simp_all add: atMost_Suc)
   456 
   457 lemma finite_greaterThanLessThan [iff]:
   458   fixes l :: nat shows "finite {l<..<u}"
   459 by (simp add: greaterThanLessThan_def)
   460 
   461 lemma finite_atLeastLessThan [iff]:
   462   fixes l :: nat shows "finite {l..<u}"
   463 by (simp add: atLeastLessThan_def)
   464 
   465 lemma finite_greaterThanAtMost [iff]:
   466   fixes l :: nat shows "finite {l<..u}"
   467 by (simp add: greaterThanAtMost_def)
   468 
   469 lemma finite_atLeastAtMost [iff]:
   470   fixes l :: nat shows "finite {l..u}"
   471 by (simp add: atLeastAtMost_def)
   472 
   473 text {* A bounded set of natural numbers is finite. *}
   474 lemma bounded_nat_set_is_finite:
   475   "(ALL i:N. i < (n::nat)) ==> finite N"
   476 apply (rule finite_subset)
   477  apply (rule_tac [2] finite_lessThan, auto)
   478 done
   479 
   480 text {* A set of natural numbers is finite iff it is bounded. *}
   481 lemma finite_nat_set_iff_bounded:
   482   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   483 proof
   484   assume f:?F  show ?B
   485     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   486 next
   487   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   488 qed
   489 
   490 lemma finite_nat_set_iff_bounded_le:
   491   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   492 apply(simp add:finite_nat_set_iff_bounded)
   493 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   494 done
   495 
   496 lemma finite_less_ub:
   497      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   498 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   499 
   500 text{* Any subset of an interval of natural numbers the size of the
   501 subset is exactly that interval. *}
   502 
   503 lemma subset_card_intvl_is_intvl:
   504   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   505 proof cases
   506   assume "finite A"
   507   thus "PROP ?P"
   508   proof(induct A rule:finite_linorder_max_induct)
   509     case empty thus ?case by auto
   510   next
   511     case (insert b A)
   512     moreover hence "b ~: A" by auto
   513     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   514       using `b ~: A` insert by fastsimp+
   515     ultimately show ?case by auto
   516   qed
   517 next
   518   assume "~finite A" thus "PROP ?P" by simp
   519 qed
   520 
   521 
   522 subsubsection {* Proving Inclusions and Equalities between Unions *}
   523 
   524 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
   525   by (auto simp add: atLeast0LessThan) 
   526 
   527 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
   528   by (subst UN_UN_finite_eq [symmetric]) blast
   529 
   530 lemma UN_finite2_subset: 
   531      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
   532   apply (rule UN_finite_subset)
   533   apply (subst UN_UN_finite_eq [symmetric, of B]) 
   534   apply blast
   535   done
   536 
   537 lemma UN_finite2_eq:
   538   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
   539   apply (rule subset_antisym)
   540    apply (rule UN_finite2_subset, blast)
   541  apply (rule UN_finite2_subset [where k=k])
   542  apply (force simp add: atLeastLessThan_add_Un [of 0] UN_Un) 
   543  done
   544 
   545 
   546 subsubsection {* Cardinality *}
   547 
   548 lemma card_lessThan [simp]: "card {..<u} = u"
   549   by (induct u, simp_all add: lessThan_Suc)
   550 
   551 lemma card_atMost [simp]: "card {..u} = Suc u"
   552   by (simp add: lessThan_Suc_atMost [THEN sym])
   553 
   554 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   555   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   556   apply (erule ssubst, rule card_lessThan)
   557   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   558   apply (erule subst)
   559   apply (rule card_image)
   560   apply (simp add: inj_on_def)
   561   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   562   apply (rule_tac x = "x - l" in exI)
   563   apply arith
   564   done
   565 
   566 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   567   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   568 
   569 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   570   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   571 
   572 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   573   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   574 
   575 lemma ex_bij_betw_nat_finite:
   576   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   577 apply(drule finite_imp_nat_seg_image_inj_on)
   578 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   579 done
   580 
   581 lemma ex_bij_betw_finite_nat:
   582   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   583 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   584 
   585 lemma finite_same_card_bij:
   586   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
   587 apply(drule ex_bij_betw_finite_nat)
   588 apply(drule ex_bij_betw_nat_finite)
   589 apply(auto intro!:bij_betw_trans)
   590 done
   591 
   592 lemma ex_bij_betw_nat_finite_1:
   593   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
   594 by (rule finite_same_card_bij) auto
   595 
   596 
   597 subsection {* Intervals of integers *}
   598 
   599 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   600   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   601 
   602 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   603   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   604 
   605 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   606     "{l+1..<u} = {l<..<u::int}"
   607   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   608 
   609 subsubsection {* Finiteness *}
   610 
   611 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   612     {(0::int)..<u} = int ` {..<nat u}"
   613   apply (unfold image_def lessThan_def)
   614   apply auto
   615   apply (rule_tac x = "nat x" in exI)
   616   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   617   done
   618 
   619 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   620   apply (case_tac "0 \<le> u")
   621   apply (subst image_atLeastZeroLessThan_int, assumption)
   622   apply (rule finite_imageI)
   623   apply auto
   624   done
   625 
   626 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   627   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   628   apply (erule subst)
   629   apply (rule finite_imageI)
   630   apply (rule finite_atLeastZeroLessThan_int)
   631   apply (rule image_add_int_atLeastLessThan)
   632   done
   633 
   634 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   635   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   636 
   637 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   638   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   639 
   640 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   641   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   642 
   643 
   644 subsubsection {* Cardinality *}
   645 
   646 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   647   apply (case_tac "0 \<le> u")
   648   apply (subst image_atLeastZeroLessThan_int, assumption)
   649   apply (subst card_image)
   650   apply (auto simp add: inj_on_def)
   651   done
   652 
   653 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   654   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   655   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   656   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   657   apply (erule subst)
   658   apply (rule card_image)
   659   apply (simp add: inj_on_def)
   660   apply (rule image_add_int_atLeastLessThan)
   661   done
   662 
   663 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   664 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   665 apply (auto simp add: algebra_simps)
   666 done
   667 
   668 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   669 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   670 
   671 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   672 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   673 
   674 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   675 proof -
   676   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   677   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   678 qed
   679 
   680 lemma card_less:
   681 assumes zero_in_M: "0 \<in> M"
   682 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   683 proof -
   684   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   685   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   686 qed
   687 
   688 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   689 apply (rule card_bij_eq [of "Suc" _ _ "\<lambda>x. x - Suc 0"])
   690 apply simp
   691 apply fastsimp
   692 apply auto
   693 apply (rule inj_on_diff_nat)
   694 apply auto
   695 apply (case_tac x)
   696 apply auto
   697 apply (case_tac xa)
   698 apply auto
   699 apply (case_tac xa)
   700 apply auto
   701 done
   702 
   703 lemma card_less_Suc:
   704   assumes zero_in_M: "0 \<in> M"
   705     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   706 proof -
   707   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   708   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   709     by (auto simp only: insert_Diff)
   710   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   711   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   712     apply (subst card_insert)
   713     apply simp_all
   714     apply (subst b)
   715     apply (subst card_less_Suc2[symmetric])
   716     apply simp_all
   717     done
   718   with c show ?thesis by simp
   719 qed
   720 
   721 
   722 subsection {*Lemmas useful with the summation operator setsum*}
   723 
   724 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   725 
   726 subsubsection {* Disjoint Unions *}
   727 
   728 text {* Singletons and open intervals *}
   729 
   730 lemma ivl_disj_un_singleton:
   731   "{l::'a::linorder} Un {l<..} = {l..}"
   732   "{..<u} Un {u::'a::linorder} = {..u}"
   733   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   734   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   735   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   736   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   737 by auto
   738 
   739 text {* One- and two-sided intervals *}
   740 
   741 lemma ivl_disj_un_one:
   742   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   743   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   744   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   745   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   746   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   747   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   748   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   749   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   750 by auto
   751 
   752 text {* Two- and two-sided intervals *}
   753 
   754 lemma ivl_disj_un_two:
   755   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   756   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   757   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   758   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   759   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   760   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   761   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   762   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   763 by auto
   764 
   765 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   766 
   767 subsubsection {* Disjoint Intersections *}
   768 
   769 text {* One- and two-sided intervals *}
   770 
   771 lemma ivl_disj_int_one:
   772   "{..l::'a::order} Int {l<..<u} = {}"
   773   "{..<l} Int {l..<u} = {}"
   774   "{..l} Int {l<..u} = {}"
   775   "{..<l} Int {l..u} = {}"
   776   "{l<..u} Int {u<..} = {}"
   777   "{l<..<u} Int {u..} = {}"
   778   "{l..u} Int {u<..} = {}"
   779   "{l..<u} Int {u..} = {}"
   780   by auto
   781 
   782 text {* Two- and two-sided intervals *}
   783 
   784 lemma ivl_disj_int_two:
   785   "{l::'a::order<..<m} Int {m..<u} = {}"
   786   "{l<..m} Int {m<..<u} = {}"
   787   "{l..<m} Int {m..<u} = {}"
   788   "{l..m} Int {m<..<u} = {}"
   789   "{l<..<m} Int {m..u} = {}"
   790   "{l<..m} Int {m<..u} = {}"
   791   "{l..<m} Int {m..u} = {}"
   792   "{l..m} Int {m<..u} = {}"
   793   by auto
   794 
   795 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
   796 
   797 subsubsection {* Some Differences *}
   798 
   799 lemma ivl_diff[simp]:
   800  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   801 by(auto)
   802 
   803 
   804 subsubsection {* Some Subset Conditions *}
   805 
   806 lemma ivl_subset [simp,noatp]:
   807  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   808 apply(auto simp:linorder_not_le)
   809 apply(rule ccontr)
   810 apply(insert linorder_le_less_linear[of i n])
   811 apply(clarsimp simp:linorder_not_le)
   812 apply(fastsimp)
   813 done
   814 
   815 
   816 subsection {* Summation indexed over intervals *}
   817 
   818 syntax
   819   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   820   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   821   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   822   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   823 syntax (xsymbols)
   824   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   825   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   826   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   827   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   828 syntax (HTML output)
   829   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   830   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   831   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   832   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   833 syntax (latex_sum output)
   834   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   835  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   836   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   837  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   838   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   839  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   840   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   841  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   842 
   843 translations
   844   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
   845   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
   846   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
   847   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
   848 
   849 text{* The above introduces some pretty alternative syntaxes for
   850 summation over intervals:
   851 \begin{center}
   852 \begin{tabular}{lll}
   853 Old & New & \LaTeX\\
   854 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   855 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   856 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   857 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   858 \end{tabular}
   859 \end{center}
   860 The left column shows the term before introduction of the new syntax,
   861 the middle column shows the new (default) syntax, and the right column
   862 shows a special syntax. The latter is only meaningful for latex output
   863 and has to be activated explicitly by setting the print mode to
   864 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   865 antiquotations). It is not the default \LaTeX\ output because it only
   866 works well with italic-style formulae, not tt-style.
   867 
   868 Note that for uniformity on @{typ nat} it is better to use
   869 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   870 not provide all lemmas available for @{term"{m..<n}"} also in the
   871 special form for @{term"{..<n}"}. *}
   872 
   873 text{* This congruence rule should be used for sums over intervals as
   874 the standard theorem @{text[source]setsum_cong} does not work well
   875 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   876 the context. *}
   877 
   878 lemma setsum_ivl_cong:
   879  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   880  setsum f {a..<b} = setsum g {c..<d}"
   881 by(rule setsum_cong, simp_all)
   882 
   883 (* FIXME why are the following simp rules but the corresponding eqns
   884 on intervals are not? *)
   885 
   886 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   887 by (simp add:atMost_Suc add_ac)
   888 
   889 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   890 by (simp add:lessThan_Suc add_ac)
   891 
   892 lemma setsum_cl_ivl_Suc[simp]:
   893   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   894 by (auto simp:add_ac atLeastAtMostSuc_conv)
   895 
   896 lemma setsum_op_ivl_Suc[simp]:
   897   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   898 by (auto simp:add_ac atLeastLessThanSuc)
   899 (*
   900 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   901     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   902 by (auto simp:add_ac atLeastAtMostSuc_conv)
   903 *)
   904 
   905 lemma setsum_head:
   906   fixes n :: nat
   907   assumes mn: "m <= n" 
   908   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   909 proof -
   910   from mn
   911   have "{m..n} = {m} \<union> {m<..n}"
   912     by (auto intro: ivl_disj_un_singleton)
   913   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   914     by (simp add: atLeast0LessThan)
   915   also have "\<dots> = ?rhs" by simp
   916   finally show ?thesis .
   917 qed
   918 
   919 lemma setsum_head_Suc:
   920   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
   921 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
   922 
   923 lemma setsum_head_upt_Suc:
   924   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
   925 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
   926 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
   927 done
   928 
   929 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
   930   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
   931 proof-
   932   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
   933   thus ?thesis by (auto simp: ivl_disj_int setsum_Un_disjoint
   934     atLeastSucAtMost_greaterThanAtMost)
   935 qed
   936 
   937 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   938   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   939 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   940 
   941 lemma setsum_diff_nat_ivl:
   942 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   943 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   944   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   945 using setsum_add_nat_ivl [of m n p f,symmetric]
   946 apply (simp add: add_ac)
   947 done
   948 
   949 lemma setsum_natinterval_difff:
   950   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
   951   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
   952           (if m <= n then f m - f(n + 1) else 0)"
   953 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
   954 
   955 lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]
   956 
   957 lemma setsum_setsum_restrict:
   958   "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
   959   by (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
   960      (rule setsum_commute)
   961 
   962 lemma setsum_image_gen: assumes fS: "finite S"
   963   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
   964 proof-
   965   { fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto }
   966   hence "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
   967     by simp
   968   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
   969     by (rule setsum_setsum_restrict[OF fS finite_imageI[OF fS]])
   970   finally show ?thesis .
   971 qed
   972 
   973 lemma setsum_multicount_gen:
   974   assumes "finite s" "finite t" "\<forall>j\<in>t. (card {i\<in>s. R i j} = k j)"
   975   shows "setsum (\<lambda>i. (card {j\<in>t. R i j})) s = setsum k t" (is "?l = ?r")
   976 proof-
   977   have "?l = setsum (\<lambda>i. setsum (\<lambda>x.1) {j\<in>t. R i j}) s" by auto
   978   also have "\<dots> = ?r" unfolding setsum_setsum_restrict[OF assms(1-2)]
   979     using assms(3) by auto
   980   finally show ?thesis .
   981 qed
   982 
   983 lemma setsum_multicount:
   984   assumes "finite S" "finite T" "\<forall>j\<in>T. (card {i\<in>S. R i j} = k)"
   985   shows "setsum (\<lambda>i. card {j\<in>T. R i j}) S = k * card T" (is "?l = ?r")
   986 proof-
   987   have "?l = setsum (\<lambda>i. k) T" by(rule setsum_multicount_gen)(auto simp:assms)
   988   also have "\<dots> = ?r" by(simp add: setsum_constant mult_commute)
   989   finally show ?thesis by auto
   990 qed
   991 
   992 
   993 subsection{* Shifting bounds *}
   994 
   995 lemma setsum_shift_bounds_nat_ivl:
   996   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   997 by (induct "n", auto simp:atLeastLessThanSuc)
   998 
   999 lemma setsum_shift_bounds_cl_nat_ivl:
  1000   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1001 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
  1002 apply (simp add:image_add_atLeastAtMost o_def)
  1003 done
  1004 
  1005 corollary setsum_shift_bounds_cl_Suc_ivl:
  1006   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1007 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1008 
  1009 corollary setsum_shift_bounds_Suc_ivl:
  1010   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1011 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1012 
  1013 lemma setsum_shift_lb_Suc0_0:
  1014   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1015 by(simp add:setsum_head_Suc)
  1016 
  1017 lemma setsum_shift_lb_Suc0_0_upt:
  1018   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1019 apply(cases k)apply simp
  1020 apply(simp add:setsum_head_upt_Suc)
  1021 done
  1022 
  1023 subsection {* The formula for geometric sums *}
  1024 
  1025 lemma geometric_sum:
  1026   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
  1027   (x ^ n - 1) / (x - 1::'a::{field})"
  1028 by (induct "n") (simp_all add:field_simps power_Suc)
  1029 
  1030 subsection {* The formula for arithmetic sums *}
  1031 
  1032 lemma gauss_sum:
  1033   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
  1034    of_nat n*((of_nat n)+1)"
  1035 proof (induct n)
  1036   case 0
  1037   show ?case by simp
  1038 next
  1039   case (Suc n)
  1040   then show ?case by (simp add: algebra_simps)
  1041 qed
  1042 
  1043 theorem arith_series_general:
  1044   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1045   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1046 proof cases
  1047   assume ngt1: "n > 1"
  1048   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1049   have
  1050     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1051      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1052     by (rule setsum_addf)
  1053   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1054   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1055     unfolding One_nat_def
  1056     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
  1057   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
  1058     by (simp add: left_distrib right_distrib)
  1059   also from ngt1 have "{1..<n} = {1..n - 1}"
  1060     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1061   also from ngt1
  1062   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
  1063     by (simp only: mult_ac gauss_sum [of "n - 1"], unfold One_nat_def)
  1064        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
  1065   finally show ?thesis by (simp add: algebra_simps)
  1066 next
  1067   assume "\<not>(n > 1)"
  1068   hence "n = 1 \<or> n = 0" by auto
  1069   thus ?thesis by (auto simp: algebra_simps)
  1070 qed
  1071 
  1072 lemma arith_series_nat:
  1073   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1074 proof -
  1075   have
  1076     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1077     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1078     by (rule arith_series_general)
  1079   thus ?thesis
  1080     unfolding One_nat_def by (auto simp add: of_nat_id)
  1081 qed
  1082 
  1083 lemma arith_series_int:
  1084   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1085   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1086 proof -
  1087   have
  1088     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1089     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1090     by (rule arith_series_general)
  1091   thus ?thesis by simp
  1092 qed
  1093 
  1094 lemma sum_diff_distrib:
  1095   fixes P::"nat\<Rightarrow>nat"
  1096   shows
  1097   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1098   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1099 proof (induct n)
  1100   case 0 show ?case by simp
  1101 next
  1102   case (Suc n)
  1103 
  1104   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1105   let ?rhs = "\<Sum>x<n. P x - Q x"
  1106 
  1107   from Suc have "?lhs = ?rhs" by simp
  1108   moreover
  1109   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1110   moreover
  1111   from Suc have
  1112     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1113     by (subst diff_diff_left[symmetric],
  1114         subst diff_add_assoc2)
  1115        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1116   ultimately
  1117   show ?case by simp
  1118 qed
  1119 
  1120 subsection {* Products indexed over intervals *}
  1121 
  1122 syntax
  1123   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1124   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1125   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1126   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1127 syntax (xsymbols)
  1128   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1129   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1130   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1131   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1132 syntax (HTML output)
  1133   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1134   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1135   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1136   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1137 syntax (latex_prod output)
  1138   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1139  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1140   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1141  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1142   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1143  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1144   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1145  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1146 
  1147 translations
  1148   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1149   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1150   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1151   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1152 
  1153 subsection {* Transfer setup *}
  1154 
  1155 lemma transfer_nat_int_set_functions:
  1156     "{..n} = nat ` {0..int n}"
  1157     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1158   apply (auto simp add: image_def)
  1159   apply (rule_tac x = "int x" in bexI)
  1160   apply auto
  1161   apply (rule_tac x = "int x" in bexI)
  1162   apply auto
  1163   done
  1164 
  1165 lemma transfer_nat_int_set_function_closures:
  1166     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1167   by (simp add: nat_set_def)
  1168 
  1169 declare TransferMorphism_nat_int[transfer add
  1170   return: transfer_nat_int_set_functions
  1171     transfer_nat_int_set_function_closures
  1172 ]
  1173 
  1174 lemma transfer_int_nat_set_functions:
  1175     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1176   by (simp only: is_nat_def transfer_nat_int_set_functions
  1177     transfer_nat_int_set_function_closures
  1178     transfer_nat_int_set_return_embed nat_0_le
  1179     cong: transfer_nat_int_set_cong)
  1180 
  1181 lemma transfer_int_nat_set_function_closures:
  1182     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1183   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1184 
  1185 declare TransferMorphism_int_nat[transfer add
  1186   return: transfer_int_nat_set_functions
  1187     transfer_int_nat_set_function_closures
  1188 ]
  1189 
  1190 end